ответнавопрос » Поиск

Результаты по ключевому слову: ответнавопрос

Как получить текст из html?

Один мой хороший клиент использует встроенный в 1С почтовый клиент.

До этого все работало хорошо, но недавно из-за установки нового банк-клиента на компьютере обновили Internet Explorer до 11 версии - стала появляться ошибка:

Поле объекта не обнаружено innerText

Пришлось немного доработать типовую функцию получения текста из html:

Код 1C v 8.х

 Функция ПреобразоватьТекстИзХТМЛФорматаВПростой(ТекстВФорматеХТМЛ) Экспорт

	Попытка

		НовыйHTMLДокумент = Новый COMОбъект("HtmlFile");

		НовыйHTMLДокумент.open("text/html");

		НовыйHTMLДокумент.write(ТекстВФорматеХТМЛ);

		НовыйHTMLДокумент.close();

		

		Возврат СтрЗаменить(НовыйHTMLДокумент.all.item(0).innerText, Символ(13), "");

	Исключение	

		Построитель = Новый ПостроительDOM;

		ЧтениеHTML = Новый ЧтениеHTML;

		ЧтениеHTML.УстановитьСтроку(ТекстВФорматеХТМЛ);

		ДокументHTML = Построитель.Прочитать(ЧтениеHTML);

		

		Возврат СокрЛП(ДокументHTML.Тело.ТекстовоеСодержимое);

	КонецПопытки;

КонецФункции

еще функции пример получения:

Код 1C v 8.х

 // Процедура изменяет признак формат текста письма (Текст, HТМЛ),

// и при этом конвертирует сам текст.

//

// Параметры:

//  ЭУHTML,ЭУТекст - Элементы управления формы, соответственно поле HTML и поле Текст

//  Кнопка - выбранная кнопка ее текст "Простой текст" или "HTML" новый вид текста письма

//  либо текст кнопки если пометку кнопки менять не требуется, соответственно 

//  вопрос о потере форматирования задаваться не будет

// Возвращаемое значение:

//  Булево, признак выполнения изменения формата

//

Функция удИзменитьФорматТекста(ЭУHTML,ЭУТекст, Кнопка) Экспорт

    Если ТипЗнч(Кнопка) = Тип("Строка") Тогда

        НовыйВидТекстаПисьма = Кнопка;

        ЕстьКнопка = Ложь;

    Иначе

        Если Кнопка.Пометка Тогда 

            Возврат Ложь; 

        КонецЕсли;

        НовыйВидТекстаПисьма = Кнопка.Текст;        

        ЕстьКнопка = Истина;

    КонецЕсли;     

        

    Если Найти(НовыйВидТекстаПисьма,"Простой текст") > 0 Тогда          

        ИсходныйТекст = ЭУHTML.ПолучитьТекст();

        НачалоBODY = Найти(ИсходныйТекст, "<BODY>");

        КонецBODY  = Найти(ИсходныйТекст, "</BODY>");

        Если ЕстьКнопка и (НачалоBODY > 0 И КонецBODY > 0 И (НачалоBODY + 6) < КонецBODY) Тогда

            СтрокаВопроса = "Будет потеряно форматирование текста. Продолжить?";

            ОтветНаВопрос = Вопрос(СтрокаВопроса, РежимДиалогаВопрос.ДаНет, , КодВозвратаДиалога.Нет);

            Если ОтветНаВопрос <> КодВозвратаДиалога.Да Тогда                

                Возврат Ложь;

            КонецЕсли;

        КонецЕсли;

        ФорматТекста = ЭУHTML.Документ.all.item(0).innerText;             

        ЭУТекст.Значение =  СтрЗаменить(ФорматТекста, Символ(13), "");

        ЭУТекст.Видимость = Истина;

        ЭУHTML.Видимость = Ложь;

        ЭУHTML.УстановитьТекст("");                        

    Иначе

        ФорматХТМЛ = СтрЗаменить(ЭУТекст.Значение, Символы.ПС, "<BR>");

    

        ЭУHTML.УстановитьТекст(ФорматХТМЛ);

        ЭУHTML.Видимость = Истина;

        ЭУТекст.Видимость = Ложь;

    КонецЕсли; 

    

    Если ЕстьКнопка Тогда

        Кнопка.Пометка = Истина;         

    КонецЕсли;   

    Возврат Истина;                     





КонецФункции // обИзменитьФорматТекста()

Категория: Работа с Интернет, Почтой (Mail), FTP

Пример хранения изображений в базе (отдельный справочник), в интерфейсе Такси и без модальности

Часто разрабатывая некую конфигурацию, пользователи хотят прикреплять к элементу справочника фото и чтобы они хранились в базе данных.

В этой статье я расскажу как к справочнику объекты строительства подключить хранилище фотографий в виде справочника Хранилище файлов.

Основные элементы конфигурации с которыми нам работать:

1. Справочник Объекты строительства - основной справочник в котором хранится инфо и к каждому элементу нужно подгружать фото

2. Справочник Хранилище Фалов, он подчинен справочнику Объекты строительства и в нем есть реквизит ДанныеХЗ - хранилище значений в котором мы будем хранить фото

Форма элемента Объекты строительства, добавим кнопку загрузить фото для списка Файлы (динамический список, в котором запросом отбирается по владельцу приложенные файлы)

Код команды Добавить Файлы (Код для отключенного режима модальности):

Код 1C v 8.3

 &НаКлиенте

Процедура ДобавитьФайлы()

//ПРОВЕРИМ - текущий элемент записан или нет

	Если ЗначениеЗаполнено(Объект.Ссылка) Тогда // Записан

		Оповещение  =  Новый ОписаниеОповещения("ОбработатьВыборФайла",   ЭтотОбъект);

		НачатьПомещениеФайла(Оповещение,   ,   ,   Истина,   УникальныйИдентификатор);

	Иначе // НЕ записан, нужно спросить пользователя

		Оповещение = Новый ОписаниеОповещения("ОтветНаВопросЗаписать", ЭтотОбъект);

		ТекстВопроса = "Элемент не записан, Записать?";

		ПоказатьВопрос(Оповещение, ТекстВопроса, РежимДиалогаВопрос.ДаНет);		

	КонецЕсли;	  

КонецПроцедуры



//вопрос пользователю

&НаКлиенте 

Процедура ОтветНаВопросЗаписать(Результат, ДополнительныеПараметры) Экспорт 

// Вопрос пользователю, если ДА, то записываем объект и снова вызываем добавить файлы

	Если Результат = КодВозвратаДиалога.Да Тогда

		 ЭтотОбъект.Записать();

		 ДобавитьФайлы();

	КонецЕсли;

КонецПроцедуры 



// После диалога выбора файла срабатывает это оповещение, в котором мы сохраняем файл с справочник Хранилище файлов

&НаКлиенте

Процедура ОбработатьВыборФайла(Результат, Адрес, ВыбранноеИмяФайла, ДополнительныеПараметры) Экспорт

Если Не Результат Тогда

 Возврат; 

КонецЕсли;

//Получим данные файла

ОписаниеФайла = Новый Файл(ВыбранноеИмяФайла);

//Сохраним в справочник ХранилищеФайлов

СохранитьФайлВХранилище(Адрес,Объект.Ссылка,ОписаниеФайла.ИмяБезРасширения);

//обновим список файлы, т.к. там добавися новый файл

Элементы.Файлы.Обновить();

ЭтаФорма.ОбновитьОтображениеДанных();

КонецПроцедуры



// Сохранение файла в справочник

&НаСервереБезКонтекста

Процедура СохранитьФайлВХранилище(Адрес,Владелец,Имя)

	НовФайл = Справочники.ХранилищеФайлов.СоздатьЭлемент();

	НовФайл.Владелец = Владелец;

	НовФайл.Наименование = Имя;

	НовФайл.ДанныеТекущаяДата = ТекущаяДата();

	НовФайл.ДанныеХЗ = Новый ХранилищеЗначения(ПолучитьИзВременногоХранилища(Адрес));

	НовФайл.Записать();

КонецПроцедуры

файлы записаны, далее если файлов много, то пользователь может перемещаться по списку файлов и ему должны показываться файлы

Добавим для списка файлы Событие ФайлыПриАктивизацииСтроки

Код 1C v 8.3

 &НаКлиенте

Процедура ФайлыПриАктивизацииСтроки(Элемент)

	Попытка

		ТекКартинка = ФайлыПриАктивизацииСтрокиНаСервере(Элемент.ТекущиеДанные.Ссылка); 

	Исключение

		//видимо нет еще фото

	КонецПопытки;	

КонецПроцедуры





&НаСервереБезКонтекста

Функция ФайлыПриАктивизацииСтрокиНаСервере(ЭлементС)

	Возврат ПолучитьНавигационнуюСсылку(ЭлементС, "ДанныеХЗ");

КонецФункции

+ чуть не забыл, т.к. файлы это динамический список с установленным запросом и параметром - необходимо при открытии задать параметр:

Установим параметр при открытии:

Код 1C v 8.3

 &НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

	Файлы.Параметры.УстановитьЗначениеПараметра("Владелец",Объект.Ссылка);

КонецПроцедуры

Результат:

Скачать DT с примером : Foto_V_BD.7z

Если у Вас есть вопросы или комментарии - пишите ниже, обсудим

Категория: 1С Общие вопросы - Управляемые формы и Такс…

Использование модальных окон в данном режиме запрещено! Модальные окна не работают, как быть?

В конфигураторе в свойства конфигурации, есть параметр «Режим использования модальности»

Режим использования модальности

Если установить Не использовать, то - принципе весь код, который после ОткрытьФормуМодально() Вопрос(), Предупреждение(), Выборов и диалогов открытия-сохранения станет работать с ошибками!

Рассмотрим пример с Использовать:

Код 1C v 8.3

 &НаКлиенте

Процедура КомандаВопрос(Команда)

	Ответ = Вопрос("Ну что скажешь? ", РежимДиалогаВопрос.ДаНет);	

	Если Ответ = КодВозвратаДиалога.Да Тогда                                   		

		Сообщить("Ответили ДА!");                                              		

	КонецЕсли;

КонецПроцедуры

В режиме Предприятие получаем

Тест модального окна Вопрос

Если мы поставим Режим использования модальности = Не использовать то получим ошибку: Использование модальных окон в данном режиме запрещено

получим ошибку: Использование модальных окон в данном режиме запрещено

Теперь код нужно писать по новому:

Код 1C v 8.3

 &НаКлиенте

Процедура КомандаВопросПоНовому(Команда)

	Оповещение = Новый ОписаниеОповещения("ОтветНаВопросЗавершение", ЭтотОбъект);

	ТекстВопроса = "Ну что скажешь?";

	ПоказатьВопрос(Оповещение, ТекстВопроса, РежимДиалогаВопрос.ДаНет);

КонецПроцедуры





&НаКлиенте 

Процедура ОтветНаВопросЗавершение(Результат, ДополнительныеПараметры) Экспорт 

	Если Результат = КодВозвратаДиалога.Да Тогда

		Сообщить("Ответили ДА");

	КонецЕсли;

КонецПроцедуры

в результате

Почему 1С решила отказаться от использования модальных окон ?

В наш век развития мобильных технологий все идет к тому - что скоро все будут работать на планшетах и телефонах. 1С сделала для этого «Web Клиент» и «Мобильное приложение». И чтобы успешно двигаться вперед нужно решать такие проблемы как, блокировка всплывающих окон. Ведь даже обычные браузеры по умолчанию блокируют модальные (всплывающие) окна!

Категория: 1С Общие вопросы - Управляемые формы и Такс…

Как программно выполнить задачу БП? Категория: Задачи