Программируя под 8.2, работающем в режиме управляемого приложения, я столкнулся с проблемой печати штрихкода. Для платформы 8.1 и платформы 8.2 в режиме обычного приложения такой проблемы не было: устанавливаем элемент «1С:Печать штрихкодов» в макет и наслаждаемся вертикальными черточками. В режиме управляемого приложения вываливается ошибка:

Код 1C v 8.2 УП

 ОбластьВывода.Рисунки.ШтрихКод.Объект – неопределено   

Что же случилось?
Дело в том, что для управляемого приложения внешние компоненты разрабатываются по другой технологии. Пример внешней компоненты для печати штрих-кода в 8.2 есть в демонстрационной конфигурации "Управляемое приложение" в макетах справочника Товары либо в конфигурации «1С:Управление торговлей» версии 11, макеты обработки «Печать этикеток и ценников».
Данная компонента, получив в качестве параметра строку штрихкода, возвращает картинку – штрихкод, которую программисту предлагается поместить в любое удобное место печатной формы.

Теперь как это сделать.
Всего обработок аж четыре штуки:
КомпонентаПечатиШтрихкодовWindows32
КомпонентаПечатиШтрихкодовWindows64
КомпонентаПечатиШтрихкодовLinux32
КомпонентаПечатиШтрихкодовLinux64

Все они загружены в одноименные макеты. Функция, подключающая внешнюю компоненту в зависимости от платформы может выглядеть так:

Код 1C v 8.х

 Функция ПодключитьВнешнююКомпонентуПечатиШтрихкода() Экспорт

	

	// В зависимости от типа платформы подключим соответствующую внешнюю компоненту

	СистемнаяИнформация = Новый СистемнаяИнформация;



	Если СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Windows_x86 Тогда

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовWindows32", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	ИначеЕсли СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Windows_x86_64 Тогда

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовWindows64", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	ИначеЕсли СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Linux_x86 Тогда

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовLinux32", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	Иначе

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовLinux64", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	КонецЕсли;



	// Создадим объект внешней компоненты

	Если ПодключениеВыполнено Тогда

		ВнешняяКомпонента = Новый("AddIn.КартинкаШтрихкода.Barcode");

	Иначе

		Возврат Неопределено;

	КонецЕсли;

	

	// Если нет возможности рисовать

	Если НЕ ВнешняяКомпонента.ГрафикаУстановлена Тогда

		// То картинку сформировать не сможем

		Возврат Неопределено;

	Иначе

		

		// Установим основные параметры компоненты

		

		// Если в системе установлен шрифт Tahoma

		Если ВнешняяКомпонента.НайтиШрифт("Tahoma") = Истина Тогда

			// Выбираем его как шрифт для формирования картинки

			ВнешняяКомпонента.Шрифт = "Tahoma";

		Иначе

			

			// Шрифт Tahoma в системе отсутствует

			// Обойдем все доступные компоненте шрифты

			Для Сч = 0 По ВнешняяКомпонента.КоличествоШрифтов -1 Цикл

				// Получим очередной шрифт, доступный компоненте

				ТекущийШрифт = ВнешняяКомпонента.ШрифтПоИндексу(Сч);

				// Если шрифт доступен

				Если ТекущийШрифт <> Неопределено Тогда

					// Они и будет шрифтом для формирования штри-кода

					ВнешняяКомпонента.Шрифт = ТекущийШрифт;

					Прервать;

				КонецЕсли;

			КонецЦикла;

		КонецЕсли;

		

		// Утановим размер шрифта

		ВнешняяКомпонента.РазмерШрифта = 10;

		

		Возврат ВнешняяКомпонента;

		

	КонецЕсли;

	

КонецФункции   

В коде выше все компоненты загружены в макеты обработки «ПечатьЭтикетокИЦенников». В принципе ничто не мешает поместить их в любое иное место. Вызов функции осуществляется командой:

Код 1C v 8.х

 ВнешняяКомпонента = ПодключитьВнешнююКомпонентуПечатиШтрихкода();   

Если что-то не получилось – возвращает НЕОПРЕДЕЛЕНО.

Далее опишем функцию, которая, получив данные, сформирует нужную нам картинку с штрихкодом:

Код 1C v 8.х

 Функция ПолучитьКартинкуШтрихкода(ВнешняяКомпонента, Штрихкод, Ширина, Высота) Экспорт

	

	// Зададим размер картинки

	ВнешняяКомпонента.Ширина =Ширина;

	ВнешняяКомпонента.Высота =Высота;

	

	// Разрешим компоненте самой определять тип кода

	ВнешняяКомпонента.АвтоТип = истина;

	

	// Если код содержит контрольный символ, обязательно указываем

	ВнешняяКомпонента.СодержитКС = СтрДлина(Штрихкод) = 13;

	

	// Если отображать контрольный символ не нужно

	// ВнешняяКомпонента.ВидимостьКС = Ложь;

	

	// Формируем картинку штрихкода

	ВнешняяКомпонента.ЗначениеКода = Штрихкод;

	

	// Если установленная нами ширина меньше минимально допустимой для этого штрихкода

	Если ВнешняяКомпонента.Ширина < ВнешняяКомпонента.МинимальнаяШиринаКода Тогда

		// Скорректируем ширину

		ВнешняяКомпонента.Ширина = ВнешняяКомпонента.МинимальнаяШиринаКода + 10;

	КонецЕсли;

	

	// Сформируем картинку

	ДвоичныеДанныеКартинки = ВнешняяКомпонента.ПолучитьШтрихкод();

	

	// Если картинка сформировалась

	Если ДвоичныеДанныеКартинки <> Неопределено Тогда

		// Формируем из двоичных данных

		Возврат Новый Картинка(ДвоичныеДанныеКартинки);

	КонецЕсли;

	

	Возврат Неопределено;

	

КонецФункции   

В данной функции используется автоопределение типа штрихкода командой

Код 1C v 8.х

 ВнешняяКомпонента.АвтоТип = истина;   

Можно тип штрихкода указать вручную:

Код 1C v 8.х

 ВнешняяКомпонента.АвтоТип = Ложь;

ВнешняяКомпонента.ТипКода = 1; // указан тип EAN13   

ТипКода - число от 0 до 15: 0 - EAN8, 1 - EAN13, 2 - EAN128. Вот полный список типов по порядку:
EAN8, EAN13, EAN128, Code39, Code128, Code16k, PDF417, Standart (Industrial) 2 of 5, Interleaved 2 of 5, Расширение Code39, Code93, ITF14, RSS14, CodaBar, EAN13 AddOn 2, EAN13 AddOn 5.

Кроме типа штрихкода, компонента имеет ряд других свойств, например ВнешняяКомпонента.ОтображатьТекст, ВнешняяКомпонента.РазмерШрифта и прочие, можно посмотреть в свойствах.

Наконец последнее - вывод штрихкода. Для этого в макет поместим картинку с именем «Штрихкод». Получаем и выводим штрихкод в область командой:

Код 1C v 8.х

 ОбластьЗначение.Рисунки.Штрихкод.Картинка = ПолучитьКартинкуШтрихкода(ВнешняяКомпонента, Штрихкод, 50, 30);   

Где Штрихкод – переменная, содержащая строку штрихкода номенклатуры, 50 – требуемая ширина, 30 – высота картинки. В макете размер картинки лучше всего поставить «Реальный размер».

Замечание. Сразу бросается в глаза то, что я вручную указываю размер требуемой картинки – 50 на 30. Возникает вопрос, а нельзя ли размеры требуемой картинки получить из картинки на макете? Конечно можно:

Код 1C v 8.х

 ОбластьЗначение.Рисунки.Штрихкод.Ширина

ОбластьЗначение.Рисунки.Штрихкод.Высота   

К сожалению, цифры получаемые этими командами почему-то слишком малы. Как получить реальный видимый размер картинки я пока не знаю, может кто подскажет?
Источник

 Массив = Справочники.ТипВсеСсылки().Типы();

Для Каждого ОчереднойТип из Массив Цикл

   Сообщить(ОчереднойТип);

КонецЦикла;   

Механизм распределенных информационных баз предназначен для создания территориально распределенных систем на основе идентичных конфигураций 1С:Предприятия 8. Этот механизм позволяет переносить как данные 1С: Предприятия, так и изменения конфигурации информационной базы.
В тех случаях, когда предприятие представляет собой территориально распределенную структуру, зачастую сохраняется потребность в ведении единой системы учета. То есть необходимо иметь возможность работать в едином пространстве документов, получать отчеты, отражающие состояние дел как в территориально удаленных подразделениях предприятия, так и на предприятии в целом и т.п. При этом не всегда имеется возможность организовать работу всех подразделений с единой информационной базой в режиме он-лайн.
Для решения подобных задач и предназначен встроенный механизм. Распределенная система в этом случае должна иметь древовидную структуру, в которой существует корневой узел и определено отношение "главный - подчиненный" для каждой пары связанных узлов. При этом система будет стремиться поддерживать одинаковое состояние объектов данных во всех узлах распределенной ИБ.
Обмен измененных объектов данных между каждым связанным узлом выполняется в формате ХML файлов. Перенос данных непосредственно между периферийными ИБ невозможен. Поэтому изменения данных, произведенные в одном из периферийных узлов распределенной ИБ попадают в другие периферийные узлы только через центральную ИБ.
В простейшем случае (по умолчанию) областью распространения изменений для всех объектов является вся распределенная ИБ. Таким образом, в случае если в течение какого-то времени изменения данных системы не будут производиться, и, в то же время, будут произведены все необходимые действия по обмену изменениями между узлами распределенной ИБ, то все узлы будут содержать абсолютно одинаковые данные.
Внесение изменений в конфигурацию возможно только в одном (корневом) узле распределенной системы. Изменения конфигурации передаются от главного узла к подчиненным.
Механизмы распространения изменений объектов работают полностью автоматически. Разработчик конфигурации лишен возможности вмешиваться в функционирование этих механизмов. Для того, чтобы механизмы распределенной ИБ начали работать, не нужно производить никаких специальных действий по конфигурированию системы.
Для того, чтобы документы, элементы справочников и другие объекты, созданные в разных узлах распределенной ИБ можно было различать, если это необходимо, в настройках программы можно указать префикс узла распределенной базы. В этом случае в при создании нового объекта (к примеру документа) будет автоматически добавляться указанный префикс.
В основе механизма распределенных информационных баз лежат универсальные механизмы обмена данными, такие как служба регистрации изменений, инфраструктура сообщений, XML-сериализация и чтение/запись XML-документов. Однако механизм распределенных информационных баз содержит ряд специфических возможностей, недоступных через универсальные механизмы обмена данными.
К таким возможностям относится интерактивное создание начального образа информационной базы, а также интерактивное чтение и запись изменений, которые могут быть выполнены сразу же, после указания того, что данный план обмена будет использовать механизм распределенных информационных баз. Таким образом, распределенная информационная база может быть создана без какого-либо дополнительного программирования, исключительно средствами визуального конструирования. При этом обмен в распределенной информационной базе будет осуществляться на основе некоторых алгоритмов, изначально заложенных в платформе.
Все действия, выполняемые при интерактивном обмене, могут быть продублированы программно, и кроме этого разработчик имеет возможность программно управлять принятием и отправкой изменений, а также выполнять реструктуризацию распределенной информационной базы, добавляя новые и удаляя существующие узлы.

Служба регистрации изменений
Суть регистрации изменений состоит в том, чтобы иметь перечень измененных элементов данных которые должны быть переданы в очередном сообщении тому или иному узлу, с которым производится обмен данными. При каждом изменении данных регистрируется, что имеются изменения, которые предстоит передать во все узлы, с которыми поддерживается обмен этими данными. При получении подтверждения приема сообщения, в котором были отправлены изменения, записи регистрации изменений должны быть удалены.
Состав данных, которыми осуществляется обмен, описывается в Плане обмена и представляет собой перечень элементов данных.
Для каждого элемента данных, указанного в плане обмена, ведется своя таблица регистрации изменений. Таблицы имеют разную структуру, в зависимости от того, для каких элементов данных регистрируются изменения, но все-таки структуры таблиц подобны. Каждая запись указывает на некоторый элемент данных, некоторый узел и содержит номер сообщения, в котором это изменение передано в первый раз.
При описании состава данных в плане обмена, для каждого элемента данных есть возможность указать признак Авторегистрации. Авторегистрацию можно «Разрешить» или «Запретить». Если авторегистрация разрешена, то при изменении данных регистрация изменений будет выполнена автоматически. Если запрещена, то регистрацию изменения можно выполнить «вручную», средствами встроенного языка.
Инфраструктура сообщений
С точки зрения плана обмена, между узлами происходит обмен сообщениями. Каждое сообщение содержит изменения данных, изменения конфигурации (если это распределенная информационная база) и ряд служебной информации. Каждое сообщение точно ассоциировано с планом обмена, имеет уникальный номер и имеет одного отправителя и одного получателя.
Сообщение оформляется как документ XML, имеющий определенную структуру. Инфраструктура сообщений позволяет формировать нужную структуру сообщения, и контролировать ее корректность. В частности, инфраструктура сообщений поддерживает нумерацию сообщений, и позволяет получать подтверждения от узла-получателя о приеме сообщений. Такое подтверждение содержится в каждом сообщении, приходящем от узла-получателя в виде номера последнего принятого сообщения.

Коллизии
При работе в реальных распределенных ИБ один и тот же объект может изменяться одновременно в различных узлах распределенной ИБ. И при переносе измененных объектов из одной ИБ в другую может случиться так, что в какую-либо ИБ будет загружаться объект, зарегистрированный в самой этой ИБ как измененный. Такая ситуация носит название коллизии.
Приведем описание действий системы в наиболее типовых вариантах коллизий:
Один и тот же объект изменен более чем в одной ИБ.
Общий принцип здесь состоит в том, что "главным" считается изменение, произведенное в центральной ИБ. Отработка ситуации различается в зависимости от того, на какой ИБ - центральной или периферийной коллизия обнаружена. Если коллизия обнаружена на центральной ИБ, то есть при загрузке файла переноса из периферийной ИБ обнаружено, что один из измененных объектов также изменен и в центральной ИБ, то изменения объекта в центральную ИБ не загружаются. При этом гарантируется, что при очередной выгрузке в адрес периферийной ИБ будет передано состояние объекта как оно есть в центральной ИБ. Если же коллизия обнаружена на периферийной ИБ, то изменения объекта, прибывшие из центральной ИБ загружаются.
Объект, измененный в одной ИБ, удален в другой.
В данном случае принцип заключается в том, что изменение всегда "главнее" удаления. В случае, если на центральную ИБ прибывает файл переноса, в котором содержится информация, что некоторый объект удален на периферийной ИБ, то в центральной ИБ объект не удаляется, а в записи таблицы регистрации изменений данный объект помечается как измененный. То есть при очередном обмене объект будет восстановлен в той ИБ, в которой он был удален, причем само содержание объекта будет соответствовать той ИБ, которая "отвергла" удаление.
Аналогичные действия производятся, если коллизия обнаружена на периферийной ИБ.
Объект, удаленный в одной ИБ, не может быть удален в другой по причине наличия ссылок на него.
При загрузке изменений, если загружается информация об удалении объектов, автоматически включается механизм контроля ссылочной целостности и выполняется проверка наличия ссылок в данной ИБ на объекты, которые переданы как удаленные.
В случае обнаружения коллизии такого рода, вне зависимости от того на какой из ИБ она была обнаружена, выполняется следующее: удаление не выполняется, а в таблицу регистрации изменений заносится запись о том, что объект должен быть перенесен в адрес той ИБ, из которой была прислана информация о его удалении.
При очередном обмене объект восстанавливается в той ИБ, в которой он был удален, однако само содержание объекта будет соответствовать той ИБ, которая "отвергла" удаление.
Таким образом на сегодняшний день платформа 1С:Предприятие предоставляет очень удобный механизм, использование которого относительно просто и не требуется никаких навыков в программировании, а благодаря механизму автоматического обмена от пользователя даже не требуется думать об актуальности его распределенной информационной базы.

В октябре 2009 года вышел в свет очередной релиз платформы 1С:Предприятия 8.2 под номером 8.2.9.356, а уже в ноябре планируется выход релиза номер 8.2.10. Столь уверенное развитие платформы естественно вызывает тягу к её изучению, а изучение, как правило, происходит параллельно с использованием уже проверенной версии. И так у нас возникла необходимость установки сервера предприятия 1С 8.2 на сервер с уже работающим сервером версии 8.1, без остановки последнего. В книге «1С:Предприятие 8.2. Клиент-серверный вариант. Руководство администратора» такая ситуация хоть и названа «достаточно редкой и специфичной», но допускается и рассматривается, как нормальная. Следуя рекомендациям книги и подсказкам всемирной сети, мы выполнили эту задачу и хотим поделиться своим опытом с вами в виде пошаговой инструкции.

В ветке реестра HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\1C:Enterprise 8.2 Server Agent Параметр ImagePath меняем номера портов, добавляя смещение: "C:\Program Files\1cv82\8.2.9.356\bin\ragent.exe" -srvc -agent -regport 1641 -port 1640 -range 1660:1691 -d "C:\Program Files\1cv82\srvinfo"

У кластера 8.1 они по умолчанию такие HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\1C:Enterprise 8.1 Server Agent "C:\Program Files\1cv81\bin\ragent.exe" -srvc -agent -regport 1541 -port 1540 -range 1560:1591 -d "C:\Program Files\1cv81\server"

Обращаем ваше внимание, что "C:\Program Files\1cv82\8.2.9.356» и "C:\Program Files\1cv81» - каталоги установки 8.2 и 8.1 по-умолчанию. Если у вас они другие, то обязательно должно выполняться условие различных каталогов служебных файлов, используемых разными агентами, в нашем случае «C:\Program Files\1cv82\srvinfo» и "C:\Program Files\1cv81\server".

Очищаем папку C:\Program Files\1cv82\srvinfo, проверяем доступ на запись в неё для пользователя USR1CV82 (при установке 1С 8.2 автоматически создается папка «reg_1541» и файл описания кластера с портом 1541, а при создании пользователя для старта сервера вручную он не обязательно может обладать правами на запись в «Program Files». И первое и второе приводит к остановке сервиса сразу после старта со следующей ошибкой "The Агент сервера 1С:Предприятия 8.2 service on Local Computer started and then stopped. Some services stop automatically if they have no work to do, for example, the Performance Logs and Alerts service.").

Стартуем второй ragent. с user name USR1CV82. Первый для 8.1 должен быть уже запущен.

В консоли управления серверами:
Создаем сервер с именем компьютера и портом 1640
Создаем кластер с портом 1641 (если его нет)
Создаем Рабочий сервер с портом 1640 и диапазоном 1660:1691 (если его нет)
Создаем Рабочий процесс
При добавлении базы в окне запуска 1С при записи Кластера серверов нужно указывать порт Пример: Имя_Компьютера:1641

Если запуск сервера планируется не от локальной системной записи, то лучше выбрать (создать предлагаемого USR1CV82) пользователя при установке 1С.

Все.

Кузнецов Александр Виталиевич
Управление программных разработок
Ведущий специалист ЗАТ "Спец-інвест"

Пример ярлык для запуска:
"C:\Program Files\1cv82\common\1cestart.exe" ENTERPRISE /S"server-1C:1641\BASAZUP"

Перебор элементов справочника принадлежащих элементу другого справочника, т.е когда один справочник подчинен другому справочнику.

Код 1C v 8.х

 // Получить выборку по указанному контрагенту. 

	Выборка = Справочники.КонтактныеЛица.Выбрать( , Контрагент); 

	Пока Выборка.Следующий() Цикл 

		ОчереднойПодчиненый = Выборка.Ссылка; 

	КонецЦикла; 



        Запрос = Новый Запрос; 

	Запрос.Текст = "ВЫБРАТЬ 

	|	КонтактныеЛица.Ссылка 

	|ИЗ 

	|	Справочник.КонтактныеЛица КАК КонтактныеЛица 

	|ГДЕ 

	|	КонтактныеЛица.Владелец = &Владелец"; 



	Запрос.УстановитьПараметр("Владелец", Контрагент); 



	Результат = Запрос.Выполнить(); 

	Выборка = Результат.Выбрать(); 



	Пока Выборка.Следующий() Цикл 

		ОчереднойПодчиненый = Выборка.Ссылка; 

	КонецЦикла; 

   

Код 1C v 7.x

  //При работе с подчиненным справочником (например, при переборе или поиске элементов) 

//требуется указать, для какого конкретно элемента-владельца получать подчиненные элементы.

//Для этого предназначена процедура ИспользоватьВладельца(ОбъектВладелец) 

//агрегатного типа данных Справочник.



// Пример 1

спр=СоздатьОбъект("Справочник.Модели");

спрМарка=СоздатьОбъект("Справочник.Марки");

спрМарка.НайтиПоНаименованию("BMW");

спр.ИспользоватьВладельца(спрМарка.ТекущийЭлемент());

спр.ВыбратьЭлементы();

Пока спр.ПолучитьЭлемент()=1 Цикл

   Сообщение(спр.ТекущийЭлемент().Наименование);

КонецЦикла;



// Пример 2

 Спр=СоздатьОбъект("Справочник.Контрагенты");

    Попытка

        дог=СоздатьОбъект("Справочник.Договоры");

    исключение

        Предупреждение("В конфигурации нет справочника ДОГОВОРЫ");

        возврат;

    конецПопытки;

    Спр.ВыбратьЭлементы();//перебираем справочник-владелец

    Пока спр.ПолучитьЭлемент()=1 Цикл     

        Если спр.ЭтоГруппа()=1  Тогда

            продолжить;//группы не имеют подчиненных элементов

        КонецЕсли;

        Сообщить("Контрагент "+спр.Наименование+ "  его договоры:");

        дог.ИспользоватьВладельца(Спр.ТекущийЭлемент());//будем перебирать только 

        //подчиненные владельцу

        дог.ВыбратьЭлементы(); //перебираем только подчиненные конкретному владельцу

        Пока дог.получитьЭлемент()=1 Цикл

            сообщить("----------"+дог.наименование);

        КонецЦикла;

    КонецЦикла;