пару » Поиск

Результаты по ключевому слову: пару

Как выгрузить все дополнительные обработки и отчеты в каталог?

Выгрузить все дополнительные обработки и отчеты в каталог всего за пару кликов. Простейшая обработка в один реквизит и команду.

Набросайте элементы на форму и вставьте код в модуль формы обработки. И без всякого скачивания.

Работоспособность проверена на БП 3.0, Документооборот 1.4-2.0, платформы 1С 8.3.7, 8.3.8

Код 1C v 8.3

 #Область ВыборКаталогаДляВыгрузки





// процедура вешается на событие начало выбора у реквизита КаталогВыгрузки. 

// Чтобы при нажатии на кнопку выбора открылась форма выбора каталога файловой системы.

&НаКлиенте

Процедура КаталогВыгрузкиНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)

	

	//открываем диалог выбора файла

	ДопПараметры = новый Структура;

	ДопПараметры.Вставить("ИмяЭлемента","КаталогВыгрузки");	

	ОписаниеОповещения = Новый ОписаниеОповещения("ОбработатьВыборКаталога", ЭтаФорма,ДопПараметры);

	ДиалогОткрытияФайла = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.ВыборКаталога);

	ДиалогОткрытияФайла.МножественныйВыбор = Ложь;

	Если ЗначениеЗаполнено(Объект.КаталогВыгрузки) Тогда

		ДиалогОткрытияФайла.Каталог = Объект.КаталогВыгрузки;

	КонецЕсли;

	ДиалогОткрытияФайла.Показать(ОписаниеОповещения);





КонецПроцедуры





// окончание выбора каталога

&НаКлиенте

Процедура ОбработатьВыборКаталога(ВыбранныеФайлы, ДополнительныеПараметры) Экспорт

	

    Если ВыбранныеФайлы = Неопределено Тогда

        Возврат;

	КонецЕсли;

	Объект[ДополнительныеПараметры.ИмяЭлемента] = ВыбранныеФайлы[0];

	

КонецПроцедуры





#КонецОбласти





#Область НажатиеНаКнопку





// кнопка начала выгрузки

&НаКлиенте

Процедура Выгрузить(Команда)

	

	ОчиститьСообщения();

	// проверка на заполнение реквизита, существовавание каталога, на его "не пустоту"

	Если НЕ ЗначениеЗаполнено(Объект.КаталогВыгрузки) Тогда

		Сообщить("Укажите каталог для выгрузки");

		Возврат;

	КонецЕсли;

	Каталог = Новый Файл(Объект.КаталогВыгрузки);

	Если НЕ Каталог.Существует() Тогда

		Сообщить("Указанный каталог не существует");

		Возврат;

	КонецЕсли;

	МассивФайлов = НайтиФайлы(Объект.КаталогВыгрузки,"*.*");

	Если МассивФайлов.Количество()>0 Тогда

		ОписаниеОповещения = новый ОписаниеОповещения("ПодвержденияЗамещения",ЭтаФорма);

		ПоказатьВопрос(ОписаниеОповещения,"В каталоге есть файлы. При выгрузке будет выполнение замещение существующих."+Символы.ПС+"Начать выгрузку?",РежимДиалогаВопрос.ДаНет);

		Возврат;

	КонецЕсли;

	ВыгрузкаНачнись(); // проблем не обнаружили, давайте выгружать уже

	

КонецПроцедуры





// если пользователь передумал затирать файлы в каталоге, выгрузку делать не будем

&НаКлиенте

Процедура ПодвержденияЗамещения(ЧтоОтветилПользователь, Параметры) Экспорт

	

	Если ЧтоОтветилПользователь = КодВозвратаДиалога.Да Тогда

		ВыгрузкаНачнись();

	Иначе

		Возврат;

	КонецЕсли;

	

КонецПроцедуры





#КонецОбласти





#Область СамаВыгрузка





&НаКлиенте

Процедура ВыгрузкаНачнись()

	

	ПолучаемыеФайлы = ПодготовимФайлыНаСервере(ЭтаФорма.УникальныйИдентификатор);

	Обработчик = Новый ОписаниеОповещения("ОбработкаРезультатаВыгрузки", ЭтотОбъект);

	НачатьПолучениеФайлов(Обработчик, ПолучаемыеФайлы, Объект.КаталогВыгрузки, Ложь);





КонецПроцедуры





&НаСервере

Функция ПодготовимФайлыНаСервере(ИдентификаторФормы)

	

	Массив = Новый Массив;

	Выборка = Справочники.ДополнительныеОтчетыИОбработки.Выбрать(); // выберем все в справочнике.

	Пока Выборка.Следующий() Цикл

		Если ТипЗнч(Выборка.ХранилищеОбработки) = Тип("ХранилищеЗначения") Тогда

			Адрес = ПоместитьВоВременноеХранилище(Выборка.ХранилищеОбработки.Получить(),ИдентификаторФормы);

			Массив.Добавить(Новый ОписаниеПередаваемогоФайла(Выборка.ИмяФайла, Адрес));

		КонецЕсли;

	КонецЦикла;

	Возврат Массив;

	

КонецФункции





&НаКлиенте

Процедура ОбработкаРезультатаВыгрузки(ПолученныеФайлы, ДополнительныеПараметры) Экспорт

	

	ПоказатьПредупреждение(,"Выгрузка в каталог завершена",10); // все готово, шеф!

	

КонецПроцедуры





#КонецОбласти

Автор: Михали Задорнов (MZadornov)

Категория: Внешние печатные формы, отчеты и обработк�…

Установка 1с 8.3 и PostgreSQL 9.2.4 на CentOS 6.5

Как всегда, после установки первым делом выполняем обновление системы:

yum update

Установка необходимых пакетов, остальные будут взяты из зависимостей:

yum install openssl098e compat-readline5 compat-libtermcap

yum install readline krb5-libs openssl

yum install freetype webkitgtk unixODBCicu ImageMagick

Важно убедиться в корректности настроек DNS!

Установка postgresql

Предполагаем, что архив пакетов находится в отдельной папке, напр., /opt/inst/pgsql, а файлы БД будут в /opt/pgsql.

cd /opt/inst/pgsql

tar xvf postgresql_9_2_4_1_1C_x86_64_rpm_tar.bz2

yum install *.rpm

mkdir /opt/pgsql

chown postgres.postgres /opt/pgsql/ && chcon -t postgresql_db_t /opt/pgsql/

Инициализация:

su postgres -c '/usr/pgsql-9.2/bin/initdb -D /opt/pgsql --locale=ru_RU.UTF-8'

Исправить путь к файлам БД, переменная PGDATA:

vim /etc/rc.d/init.d/postgresql-9.2

Включение автозапуска и запуск демона PGSQL:

chkconfig postgresql-9.2 on && service postgresql-9.2 start

Создание пользователя БД

su - postgres

cd /usr/pgsql-9.2/bin

createuser --interactive -P

Введите имя новой роли:srv1c
Введите пароль для новой роли:
Повторите его:
Должна ли новая роль иметь полномочия суперпользователя? (y - да/n - нет) y
Новая роль должна иметь право создавать базы данных? (y - да/n - нет) y
Новая роль должна иметь право создавать другие роли? (y - да/n - нет) n

Краткая справка PGSQL

-bash-4.1$ psql

Изменение роли суперпользователя сервера БД
postgres=# ALTER USER srv1c WITH NOSUPERUSER;

postgres=# ALTER USER srv1c WITH SUPERUSER;

Список БД
postgres=# \l

Удаление БД
postgres=# DROP DATABASE base01;

Установка сервера 1С
Предполагаем, что архив пакетов находится в отдельной папке, напр., /opt/inst/1c-enterprise.

cd /opt/inst/1c-enterprise

tar xzf rpm64.tar.gz

yum install *.rpm

chkconfig srv1cv83 on && service srv1cv83 start

Лицензии

Предполагаем, что у нас уже есть работающий сервер сетевых лицензий.

mkdir /opt/1C/v8.3/x86_64/conf

vim /opt/1C/v8.3/x86_64/conf/nethasp.ini

chcon -R -u system_u -r object_r /opt/1C/v8.3/x86_64/conf

Пример файла
[NH_COMMON]
NH_TCPIP = Enabled
[NH_TCPIP]
NH_SERVER_ADDR = licsrv.your.domain

Безопасность

Отключение брандмауэра и расширений безопасности Linux - крайне вредная рекомендация. Более того, каких-то сложных настроек там нет, достаточно добавить пару разрешающих правил для входящего трафика.

vim /etc/sysconfig/iptables

#1C

-A INPUT -m state --state NEW -m tcp -p tcp --dport 1540:1541 -j ACCEPT

-A INPUT -m state --state NEW -m tcp -p tcp --dport 1560:1591 -j ACCEPT

Теперь можно подключаться к серверу из консоли администрирования.

Категория: Linux: CentOS, Debian, Ubuntu, ALT и д.р

Настройка и подключение сканера штрих кода к 1С

Нужно сделать РМК (рабочее место кассира) с работающим сканером и другим нужным функционалом.

Порядок действий:

1. Ставим 1с, конфигурацию.

Для начала сделаем пару пользователей, первый он всегда «Админ«, второго назовем «Кассир» и дадим ему полные права (для теста, по хорошему надо настраивать персональные права) .

В конфигураторе (от админа) подправим пользователя «Кассир». Ставим «тип запуска» & «обычное приложение»

Идем дальше, что бы в «Администрировании» появился пункт «Подключаемое оборудование» (иначе как мы его будем настраивать? ) нужно поставить галку на

«Использовать подключаемое оборудование» и «Использовать группы пользователей»

Администрирование & Настройка параметров учета.

Возможности пользователя в РМК настраиваем в Администрировании & Дополнительные права пользователя

2. Настраиваем сканер на эмуляцию com порта, это позволит нам работать в РМК со сканером без лишних заморочек.

Для этого мне потребовалось скачать драйвер Symbol COM Port Emulation Driver v 1.8.5

т.к. проверять уже не охота, а перед установкой драйвера была применена вот эта инструкция:

Настройка_сканеров_Symbol_в_1С прикладываю и ее, в ней показаны штрих кода для программирования сканера на эмуляцию и настройка в 1с сканера.

Ну и в принципе на этом настройка сканера завершена. Теперь в РМК будет перехватывать все сканированные штрихкода.

Все тоже самое только на Windows 7

Сканер установился автоматом. Заставить эмулировать его COM порт я не стал. Сканер работает как клавиатура. Для 1с пришлось настроить сканер что бы он сначала слал F7 (ввод по штриху) + сам штрих + enter.

Прежде чем купить сканер штрих кода обратите особое внимание на то, каким образом будет подключаться сканер к компьютеру.

Несмотря на обилие видов сканеров штрих кода на рынке все они, в конечном счете, подключаются через один из четырех типов коннекторов или интерфейсных портов:

- PS/2 Разрыв клавиатуры – из названия следует что сканер штрих кода подключается в разрыв между компьютером и клавиатурой.

- USB Эмуляция ( фактически подключение через порт usb а настройки как в PS/2)

- RS-232 Последовательный (Com) порт – подключается в Com порт компьютера, однако требует дополнительно блок питания.

- USB Эмуляция ( фактически подключение через порт usb а настройки как в RS-232)

Настройка сканера штрих-кода в программах 1С в разрыв клавиатуры

Настроить сканер штрих-кода 1С, подключаемый в разрыв клавиатуры, совсем не сложная задача. Первое что надо сделать - настроить префикс сканера штрих-кода. По умолчанию сканер штрих-кода, подключаемый в разрыв клавиатуры при сканировании штрих-кода товара он возвращает цифры штрих-кода и символ возврата – это аналогично тому, как если бы вы нажимали после сканирования клавишу ENTER на клавиатуре компьютера. Однако для сканирования штрих – кода товара в программе 1С нажать клавишу F7 - Возврат каретки необходимо. Чтобы постоянно не нажимать F7, нам и поможет добавление специального символа – префикса. Префиксом называется в данном случае некий набор символов, которые сканер отсылает перед отправкой штрих-кода. В качестве префикса в основном используют значение “150” - это ASCII-код клавиши F7. Этот способ подойдет и для USB-сканера в том случае, когда нет возможности установить драйвер эмуляции COM-порта.

Настройка сканера штрих-кода в программах 1С через порт USB.

Программа 1C не видит сканеры штрих-кода подключенные через USB-разъем, зато их прекрасно “видит” операционная система Windows. При первом включении сканера операционная система предложит установить его драйвер, но мы ей этого не позволим и откажемся от автоматической установки, а поставим драйвер вручную. Как правило, драйвер эмуляции COM-порта находится на диске из комплекта поставки сканера штрих-кода, там же есть и специализированные утилиты для настройки свойств самого сканера штрих-кода, такие как: громкость бипера, префикс, суфикс и т.п. Или же имеется специальное руководство пользователя с конфигурационными штрих-кодами, сканируя которые можно определенным образом настроить сканер. В процессе установки этого драйвера, операционная система создает виртуальный COM-порт. Далее нужно произвести конфигурирование порта. После того как настроен сам сканер – переходим к настройке в 1С. Для этого в меню Сервис?Настройки торгового оборудования?Находим закладку Сканеры и переходим в нее и устанавливаем новый сканер штрих-кодов. В качестве обработки обычно используют входящую в поставку стандартную обработку обслуживания «1CScanOPOSScan_v2.epf». Далее заходим в “Параметры” настраиваем COM-порт и параметр Скорость сканера. Сканер штрих-кода настроен!

Настройка сканера штрих кода в программах 1С через COM-порт.

Настройка сканера штрих-кода 1С производим как в предыдущем примере. После того как настроен сам сканер – переходим к настройке в 1С. Для этого в меню Сервис?Настройки торгового оборудования?Находим закладку Сканеры и переходим в нее и устанавливаем новый сканер штрих-кодов. В качестве обработки обычно используют входящую в поставку стандартную обработку обслуживания «1CScanOPOSScan_v2.epf». Далее заходим в “Параметры” настраиваем COM-порт и параметр Скорость сканера. Сканер штрих-кода настроен!

Категория: Торговое оборудование

Синтаксический анализ JSON - выражения средствами 1С 7.7

Код 1C v 7.x

 



Перем Л_Лев_Фиг_Скобка, Л_Прав_Фиг_Скобка, Л_Лев_Кв_Скобка, Л_Прав_Кв_Скобка, Л_Кавычка, Л_Экран, Л_Двоеточие, Л_Запятая, Л_Число, Л_Строка, Л_Константа, Л_Финиш;

Перем Цифры1_9, Цифры0_9, ПервыеСимволыКонстант, ОдносимвольныеЛексемы;

Перем НомЛексемы, ТекЛексема;

Перем JSON_Error;

Перем В_Массив, В_Объект, В_Значение;

//*****

Перем НомерСимвола;

Перем ФлагОшибки;

Перем СписокСтроковыхКонстант;

Перем СтекЛексем;

Перем АнализируемаяСтрока;

//*****

Перем ТекКаталог, ТекФайл;

//*****

Функция ПолучитьОбъект_ТЗ() Далее

Функция ПолучитьМассив_ТЗ() Далее

//*****

Функция ТекущиеСимволы(Сколько)

	Возврат Сред(АнализируемаяСтрока, НомерСимвола, Сколько);

КонецФункции

//*****

Функция ПрошлыйСимвол(Сдвиг)

	Возврат Сред(АнализируемаяСтрока, НомерСимвола - Сдвиг, 1);

КонецФункции

//*****

Процедура ДобавитьЛексему(Лексема, Значение, Сдвиг)

	СтекЛексем.НоваяСтрока();

	СтекЛексем.Лексема	= Лексема;

	СтекЛексем.Значение	= Значение;	

	НомерСимвола		= НомерСимвола + Сдвиг;

КонецПроцедуры

//*****

Процедура ОбвестиОбласть(Обл)

	Обл.РамкаСнизу(1);

	Обл.РамкаСверху(1);

	Обл.РамкаСлева(1);

	Обл.РамкаСправа(1);

КонецПроцедуры

//*****

Процедура НапечататьТЗ(Таб, ТЗ, НомС, НомК)

Перем Тип, Обл1, НС, КС, Ключ, Зн, Обл2;

	Тип = ТЗ.ПолучитьЗначение(1, 1);

	НомС = НомС + 1;

	Обл1 = Таб.Область(НомС, НомК);

	ОбвестиОбласть(Обл1);

	Если Тип = В_Значение Тогда

		ТипЗн = ТЗ.ПолучитьЗначение(2, 1);

		Обл1.Текст = ТЗ.ПолучитьЗначение(2, 2);

		Обл1.ГоризонтальноеПоложение(1);

		Если ТипЗн = Л_Число Тогда

			Обл1.ГоризонтальноеПоложение(2);

		ИначеЕсли ТипЗн = Л_Константа Тогда

			Обл1.Полужирный(1);

		ИначеЕсли ТипЗн = Л_Строка Тогда

			Обл1.Контроль(4);

		КонецЕсли;

		Возврат;

	ИначеЕсли (Тип = В_Объект) Или (Тип = В_Массив) Тогда

		Обл1.Текст = Тип;

		Обл1.Полужирный(1);

		Обл1.ЦветФона(12648447);

		Обл1.РамкаСнизу(5);

		КС = ТЗ.КоличествоСтрок();

		Для НС = 2 По КС Цикл

			НомС = НомС + 1;

			Обл2 = Таб.Область(НомС, НомК);

			Обл2.Текст = ТЗ.ПолучитьЗначение(НС, 1);

			Если Тип = В_Массив Тогда

				Обл2.ГоризонтальноеПоложение(2);

			КонецЕсли;

			ОбвестиОбласть(Обл2);

			НомС = НомС - 1;

			НапечататьТЗ(Таб, ТЗ.ПолучитьЗначение(НС, 2), НомС, НомК + 1);

		КонецЦикла;

	Иначе

		Сообщить("Фигня " + Тип, "!");

	КонецЕсли;

КонецПроцедуры

//*****

Процедура ВыравнятьТЗ(Таб, ОграничениеШирины)

Перем НомерКол, НомерСтр, МаксШирина, Обл, ТекШирина, ТекДлина;

	Для НомерКол = 1 По Таб.ШиринаТаблицы() Цикл

		МаксШирина = 0;

		Для НомерСтр = 1 По Таб.ВысотаТаблицы() Цикл

			Обл = Таб.Область(НомерСтр, НомерКол);

			ТекШирина = Обл.ШиринаСтолбца();

			ТекДлина = СтрДлина(СокрЛП(Обл.Текст));

			МаксШирина = Макс(МаксШирина, ТекШирина, ТекДлина);

		КонецЦикла;

		Таб.Область(, НомерКол).ШиринаСтолбца(Мин(МаксШирина, ОграничениеШирины));

	КонецЦикла;

КонецПроцедуры

//*****

Процедура Напечатать_ТЗ(ТЗ)

Перем Таб, НС, НК, МаксШирина, ТекДлина, Обл;	

	Таб = СоздатьОбъект("Таблица");

	МаксНК = 1;

	НС = 0;

	НК = 1;

	НапечататьТЗ(Таб, ТЗ, НС, НК);

	ВыравнятьТЗ(Таб, 30);

	Таб.Область(1, 1, Таб.ВысотаТаблицы(), Таб.ШиринаТаблицы()).ВертикальноеПоложение(2);

	Таб.Опции(0, 0);

	Таб.Показать("JSON");

КонецПроцедуры

//*****

Функция Ошибка()

	ФлагОшибки = 1;

	Возврат 0;

КонецФункции

//*****

Функция ЧитатьКонстанту(ПервСимвол)

Перем КонстантаСтр, ДлинаКонстанты;	

	КонстантаСтр = СписокСтроковыхКонстант.Получить(ПервСимвол);

	ДлинаКонстанты = СтрДлина(КонстантаСтр);

	Если ТекущиеСимволы(ДлинаКонстанты) = КонстантаСтр Тогда

		ДобавитьЛексему(Л_Константа, КонстантаСтр, ДлинаКонстанты);

		Возврат 1;

	Иначе

		Возврат Ошибка();

	КонецЕсли;

КонецФункции

//*****

Процедура ДописатьСимвол(Стр)

	Стр = Стр + ТекущиеСимволы(1);

	НомерСимвола = НомерСимвола + 1;

КонецПроцедуры

//*****

Функция ЧитатьЧисло() 

Перем ЧислоСтр;

	ЧислоСтр = "";

	Если ТекущиеСимволы(1) = "-" Тогда

		ДописатьСимвол(ЧислоСтр);

	КонецЕсли;

	Если Найти(Цифры1_9, ТекущиеСимволы(1)) > 0 Тогда // не с нуля

		ДописатьСимвол(ЧислоСтр);

		Пока Найти(Цифры0_9, ТекущиеСимволы(1)) > 0 Цикл  // любые цыфры 

			ДописатьСимвол(ЧислоСтр);

		КонецЦикла;		

	ИначеЕсли ТекущиеСимволы(1) = "0" Тогда //с нуля - ничего дальше 

		ДописатьСимвол(ЧислоСтр);

	Иначе

		Возврат Ошибка();

	КонецЕсли;

	Если ТекущиеСимволы(1) = "." Тогда // десятичная точка

		ДописатьСимвол(ЧислоСтр);

		Пока Найти(Цифры0_9, ТекущиеСимволы(1)) > 0 Цикл  // любые цыфры

			ДописатьСимвол(ЧислоСтр);

		КонецЦикла;		

	КонецЕсли;

	Если ВРег(ТекущиеСимволы(1)) = "E" Тогда // значок e больное или маленькое

		ДописатьСимвол(ЧислоСтр);

		Если Найти("+-", ТекущиеСимволы(1)) > 0 Тогда  // унарный знак для порядка

			ДописатьСимвол(ЧислоСтр);

		КонецЕсли;

		Пока Найти(Цифры0_9, ТекущиеСимволы(1)) > 0 Цикл  // любые цыфры

			ДописатьСимвол(ЧислоСтр);

		КонецЦикла;		

	КонецЕсли;

	ДобавитьЛексему(Л_Число, ЧислоСтр, 0);

	Возврат 1;

КонецФункции

//*****

Функция ЧитатьСтроку()

Перем СтрокаСтр;

	СтрокаСтр = "";

	НомерСимвола = НомерСимвола + 1;

	Пока (ТекущиеСимволы(1) <> Л_Кавычка) Или ((ТекущиеСимволы(1) = Л_Кавычка) И (ПрошлыйСимвол(1) = Л_Экран) И (ПрошлыйСимвол(2) <> Л_Экран)) Цикл

		ДописатьСимвол(СтрокаСтр);

	КонецЦикла;

	ДобавитьЛексему(Л_Строка, СтрокаСтр, 1); 

	Возврат 1;

КонецФункции 

//*****

Функция ПрочитатьФайл(ИмяФайла)

Перем Т, НомерСтрокиФайла, СтрокаРез;

	Т = СоздатьОбъект("Текст");

	Т.Открыть(ИмяФайла);

	СтрокаРез = "";

	Для НомерСтрокиФайла = 1 По Т.КоличествоСтрок() Цикл

		СтрокаРез = СтрокаРез + Т.ПолучитьСтроку(НомерСтрокиФайла);

	КонецЦикла;

	Возврат СтрокаРез;

КонецФункции

//*****

Функция СледующаяЛексема()

	НомЛексемы = НомЛексемы + 1;

	СтекЛексем.ПолучитьСтрокуПоНомеру(НомЛексемы);

	ТекЛексема = СтекЛексем.Лексема;

	Возврат 1;

КонецФункции

//*****

Функция ОшибкаЛексемы()

Перем РезСтр, НомСтр, ТЛ, ТС;

	Сообщить("Ошибочная лексема № " + НомЛексемы + " : <" + ТекЛексема + ">", "!");

	РезСтр = "";

	Для НомСтр = НомЛексемы + 1 По СтекЛексем.КоличествоСтрок() Цикл

		СтекЛексем.ПолучитьСтрокуПоНомеру(НомСтр);

		ТЛ = СтекЛексем.Лексема;

		Если ТЛ = Л_Строка Тогда 

			ТС = "<" + ТЛ + "(" + СтекЛексем.Значение + ")>";

		ИначеЕсли ТЛ = Л_Константа Тогда

			ТС = "<" + ТЛ + "(" + СтекЛексем.Значение + ")>";

		Иначе

			ТС = "<" + ТЛ + ">";

		КонецЕсли;

		РезСтр = РезСтр + ТС + ",";

	КонецЦикла;

	Сообщить(Лев(РезСтр, 400), "!");

	Возврат 0;

КонецФункции

//*****

Процедура ДобавитьПару(ТЗ, Ключ, Значение)

	ТЗ.НоваяСтрока();

	ТЗ.Ключ		= Ключ;

	ТЗ.Значение	= Значение;

КонецПроцедуры

//*****

Функция НоваяТЗ(Тип)

Перем _ТЗ;

	_ТЗ = СоздатьОбъект("ТаблицаЗначений");

	_ТЗ.НоваяКолонка("Ключ");

	_ТЗ.НоваяКолонка("Значение");

	ДобавитьПару(_ТЗ, Тип, "");

	Возврат _ТЗ;

КонецФункции

//*****

Функция ПолучитьПроизвольноеЗначение_ТЗ()

Перем ТЗ;	

	Если (ТекЛексема = Л_Строка) Или (ТекЛексема = Л_Число) Или (ТекЛексема = Л_Константа) Тогда

		ТЗ = НоваяТЗ(В_Значение);

		ДобавитьПару(ТЗ, ТекЛексема, СтекЛексем.Значение);

		СледующаяЛексема();

		Возврат ТЗ;

	ИначеЕсли ТекЛексема = Л_Лев_Фиг_Скобка Тогда

		Возврат ПолучитьОбъект_ТЗ();

	ИначеЕсли ТекЛексема = Л_Лев_Кв_Скобка 	Тогда

		Возврат ПолучитьМассив_ТЗ();					

	КонецЕсли;

	Возврат ОшибкаЛексемы();

КонецФункции

//*****

Функция ДобавитьКлючЗначение(ТЗ)

Перем НовКлюч, НовЗначение;

	Если ТекЛексема <> Л_Строка Тогда

		Возврат 0;

	КонецЕсли;

	НовКлюч = СтекЛексем.Значение;

	СледующаяЛексема();

	Если ТекЛексема <> Л_Двоеточие Тогда

		Возврат ОшибкаЛексемы();

	КонецЕсли;

	СледующаяЛексема();

	НовЗначение = ПолучитьПроизвольноеЗначение_ТЗ();

	Если НовЗначение = 0 Тогда

		Возврат 0;

	КонецЕсли;

	ДобавитьПару(ТЗ, НовКлюч, НовЗначение);

	Возврат 1;

КонецФункции

//*****

Функция ПолучитьОбъект_ТЗ()

Перем ТЗ;

	ТЗ = НоваяТЗ(В_Объект);

	СледующаяЛексема();

	Если ТекЛексема = Л_Прав_Фиг_Скобка Тогда // пустой объект

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	Если ДобавитьКлючЗначение(ТЗ) = 0 Тогда   // первая пара ключ-значение

		Возврат 0;

	КонецЕсли;	

	Пока ТекЛексема = Л_Запятая Цикл			// пока запятые

		СледующаяЛексема();

		Если ДобавитьКлючЗначение(ТЗ) = 0 Тогда	// пара ключ-значение

			Возврат 0;

		КонецЕсли;

	КонецЦикла;

	Если ТекЛексема = Л_Прав_Фиг_Скобка Тогда

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	Возврат 0;

КонецФункции

//*****

Функция ПолучитьМассив_ТЗ()

Перем ТЗ, _Ключ, _Значение;

	ТЗ = НоваяТЗ(В_Массив);

	СледующаяЛексема();

	Если ТекЛексема = Л_Прав_Кв_Скобка Тогда

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	_Значение = ПолучитьПроизвольноеЗначение_ТЗ();

	Если _Значение = 0 Тогда

		Возврат 0;

	КонецЕсли;

	_Ключ = 0; // JS - индексы массиворв с нуля

	ДобавитьПару(ТЗ, _Ключ, _Значение);	

	Пока ТекЛексема = Л_Запятая Цикл

		СледующаяЛексема();

		_Значение = ПолучитьПроизвольноеЗначение_ТЗ();

		Если _Значение = 0 Тогда

			Возврат 0;

		КонецЕсли;

		_Ключ = _Ключ + 1;

		ДобавитьПару(ТЗ, _Ключ, _Значение);

	КонецЦикла;

	Если ТекЛексема = Л_Прав_Кв_Скобка Тогда

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	Возврат 0;

КонецФункции

//*****

Функция ПрочитатьОбъект_ТЗ()

Перем Рез;	

	НомЛексемы = 0;

	СледующаяЛексема();

	Если ТекЛексема = Л_Лев_Фиг_Скобка Тогда

		Рез = ПолучитьОбъект_ТЗ();

	ИначеЕсли ТекЛексема = Л_Лев_Кв_Скобка Тогда

		Рез = ПолучитьМассив_ТЗ();

	Иначе

		Рез = ПолучитьПроизвольноеЗначение_ТЗ();

	КонецЕсли;

	Если (Рез = 0) Или (ТекЛексема <> Л_Финиш) Тогда

		ОшибкаЛексемы();

		Возврат 0;

	КонецЕсли;

	Возврат Рез;	

КонецФункции

//*****

Функция СгенерироватьТЗ(НачАнализируемаяСтрока)

Перем НачальныйСимвол, Рез;

	АнализируемаяСтрока = НачАнализируемаяСтрока;

	СтекЛексем = СоздатьОбъект("ТаблицаЗначений");

	СтекЛексем.НоваяКолонка("Лексема" , "Строка");

	СтекЛексем.НоваяКолонка("Значение", "Строка");

	ФлагОшибки = 0;

	НомерСимвола = 1;

	Пока НомерСимвола <= СтрДлина(АнализируемаяСтрока) Цикл

		НачальныйСимвол = ТекущиеСимволы(1);

		Если Найти(" " + Симв(9), НачальныйСимвол) > 0 Тогда  // пробелы и разделители строк пропускаем

			НомерСимвола = НомерСимвола + 1;

		ИначеЕсли НачальныйСимвол = Л_Кавычка	Тогда // кавычка - читаем строку

			ЧитатьСтроку();

		ИначеЕсли Найти(ОдносимвольныеЛексемы, НачальныйСимвол) > 0 Тогда

			ДобавитьЛексему(НачальныйСимвол, "", 1);

		ИначеЕсли Найти(ПервыеСимволыКонстант, НачальныйСимвол) > 0 Тогда // первая буква из начала константы - константа null, true, false

			Если ЧитатьКонстанту(НачальныйСимвол) = 0 Тогда

				Прервать;

			КонецЕсли;

		ИначеЕсли Найти("-" + Цифры0_9, НачальныйСимвол) > 0 Тогда // число

			Если ЧитатьЧисло() = 0 Тогда

				Прервать;

			КонецЕсли;

		Иначе		// иных вариантов нет

			Сообщить("========= " + НомерСимвола, "!");

			Сообщить(НачальныйСимвол, "!");

			Сообщить("<" + НачальныйСимвол + "> " + КодСимв(НачальныйСимвол), "!");

			Сообщить(ТекущиеСимволы(100), "!");

			Возврат 0;

		КонецЕсли;

	КонецЦикла;

	Если ФлагОшибки <> 0 Тогда

		Сообщить("Ошибка парсинга JSON - выражения", "!");

		Возврат 0;

	ИначеЕсли СтекЛексем.КоличествоСтрок() = 0 Тогда

		Сообщить("Пустой стек", "!");

		Возврат 0;

	КонецЕсли;

	ДобавитьЛексему(Л_Финиш, "", 0);

	Возврат ПрочитатьОбъект_ТЗ();

КонецФункции

//*****

Функция JSON_Error(Стр = "")

	Если Стр <> "" Тогда

		Сообщить("JSON-ОШИБКА: " + Стр, "!");

	КонецЕсли;

	Возврат JSON_Error;

КонецФункции

//*****

Функция JSON_Type(Парам)

	Если ТипЗначенияСтр(Парам) <> "ТаблицаЗначений" Тогда

		Возврат JSON_Error();

	ИначеЕсли Парам.КоличествоКолонок() <> 2 Тогда

		Возврат JSON_Error();

	ИначеЕсли Парам.КоличествоСтрок() < 2 Тогда

		Возврат JSON_Error();

	КонецЕсли;

	Возврат Парам.ПолучитьЗначение(1, 1);

КонецФункции

//*****

Функция JSON_GetValue(Парам, Keys)

Перем Тип, До, После, ПозЗакр, Л1, П2, Инд, ИндСтр, НС, КвоСтрок;

	Тип = JSON_Type(Парам);

	ПозЗакр = Найти(Keys, "]");

	Если ПозЗакр = 0 Тогда

		ПозЗакр = СтрДлина(Keys) + 1;

	КонецЕсли;	

	До = Лев(Keys, ПозЗакр);

	После = Сред(Keys, ПозЗакр + 1);

	Л1 = Лев(До, 1);

	П2 = Найти(До, "]");

	Если Тип = JSON_Error Тогда

		Возврат JSON_Error("Параметра");

	КонецЕсли;

	КвоСтрок = Парам.КоличествоСтрок();

	Если До = "" Тогда // сам объект

		Если (Тип = В_Массив) Или (Тип = В_Объект) Тогда

			Возврат JSON_Error();

		ИначеЕсли Тип = В_Значение Тогда

			Возврат Парам.ПолучитьЗначение(2, 2);

		Иначе

			Возврат JSON_Error("№ 1");

		КонецЕсли;		

	ИначеЕсли До = ".length" Тогда // размер массива или объекта. Для значения - ошибка

		Если (Тип = В_Массив) Или (Тип = В_Объект) Тогда

			Возврат Парам.КоличествоСтрок() - 1;

		Иначе

			Возврат JSON_Error("Длина скаляра");

		КонецЕсли;

	ИначеЕсли Л1 = "[" Тогда // размер массива или объекта. Для значения - ошибка

		Если П2 = 0 Тогда

			Возврат JSON_Error("Индексация: <" + До + ">");

		КонецЕсли;

		Инд = Сред(До, 2, П2 - 2);

		Если (Найти("'""", Лев(Инд, 1)) > 0) И (Найти("'""", Прав(Инд, 1)) > 0) Тогда // строковый только объект

			ИндСтр = Сред(Инд, 2, СтрДлина(Инд) - 2);

			Если Тип <> В_Объект Тогда

				Возврат JSON_Error("Строковый индекс <" + ИндСтр + "> только для Объекта");

			КонецЕсли;

			НС = 0;

			Если Парам.НайтиЗначение(ИндСтр, НС, 1) = 1 Тогда

				Возврат JSON_GetValue(Парам.ПолучитьЗначение(НС, 2), После);

			КонецЕсли;

			Возврат JSON_Error("Нет индекса <" + ИндСтр + ">");

		КонецЕсли;

		ИндЧис = 0 + Инд;

		Если "" + ИндЧис <> Инд Тогда // защита от <5D>

			Возврат JSON_Error("Ошибка 1 числового индекса <" + Инд + ">");

		ИначеЕсли Цел(ИндЧис) <> ИндЧис Тогда // защита от неЦелого индекса

			Возврат JSON_Error("Ошибка 2 числового индекса <" + Инд + "> (нецелый)");

		ИначеЕсли ИндЧис < 0 Тогда

			Возврат JSON_Error("Ошибка 3 числового индекса <" + Инд + "> (отрицательный)");

		ИначеЕсли ИндЧис > (КвоСтрок - 2) Тогда

			Возврат JSON_Error("Ошибка 4 числового индекса <" + Инд + "> (" + ИндЧис + ">" + (КвоСтрок - 2) + ")");

		КонецЕсли;

		Возврат JSON_GetValue(Парам.ПолучитьЗначение(ИндЧис + 1, 2), После);

	Иначе

		Возврат JSON_Error("Ошибка 5 <" + До + ">");

	КонецЕсли;

КонецФункции

//*****

Процедура ПриОткрытии()

Перем Рез1, ТипУзла1, Зн1, Значение;	

	ОчиститьОкноСообщений();

	СтатусВозврата(0);

	Рез1 = СгенерироватьТЗ(ПрочитатьФайл(ТекКаталог + "j1.json"));

	Напечатать_ТЗ(Рез1);

	ТипУзла1 = JSON_Type(Рез1);

	Сообщить("Тип узла: " + ТипУзла1);

	Зн1 = JSON_GetValue(Рез1, ".length");									Сообщить("1) Размер: " 		+ Зн1);

	Зн3 = JSON_GetValue(Рез1, "['1']");										Сообщить("3) ['1']: <" 		+ Зн3 + ">");

	Зн4 = JSON_GetValue(Рез1, "[1]");										Сообщить("4) [1]: <" 		+ Зн4 + ">");

	Зн5 = JSON_GetValue(Рез1, "['Массив'][6]");								Сообщить("5) [*]: <" + Зн5 + ">");

	Зн6 = JSON_GetValue(Рез1, "['Соответствие']['ДопустимоеИмяСвойства']");	Сообщить("6) [*]: <" + Зн6 + ">");

КонецПроцедуры

//*****

Процедура ДобавитьСтроковуюКонстанту(КонстантаСтр)

Перем ПервыйСимвол;	

	ПервыйСимвол = Лев(КонстантаСтр, 1);

	ПервыеСимволыКонстант = ПервыеСимволыКонстант + ПервыйСимвол;

	СписокСтроковыхКонстант.Установить(ПервыйСимвол, КонстантаСтр);

КонецПроцедуры

//*****

РасположениеФайла(ТекКаталог, ТекФайл);

//*****

Л_Лев_Фиг_Скобка	= "{";

Л_Прав_Фиг_Скобка	= "}";

Л_Лев_Кв_Скобка		= "["; 

Л_Прав_Кв_Скобка	= "]";

Л_Двоеточие			= ":";

Л_Запятая			= ",";

Л_Экран				= "\";

Л_Кавычка			= """";

Л_Финиш				= "";

Л_Число				= "number";

Л_Строка			= "string";

Л_Константа			= "const";

ОдносимвольныеЛексемы = Л_Лев_Фиг_Скобка + Л_Прав_Фиг_Скобка + Л_Лев_Кв_Скобка + Л_Прав_Кв_Скобка + Л_Двоеточие + Л_Запятая;

//*****

Цифры1_9 = "123456789";

Цифры0_9 = "0" + Цифры1_9;

//*****

В_Массив   = "###array";

В_Объект   = "###object";

В_Значение = "###value";

//*****

СписокСтроковыхКонстант	= СоздатьОбъект("СписокЗначений");

ПервыеСимволыКонстант	= "";

ДобавитьСтроковуюКонстанту("null");

ДобавитьСтроковуюКонстанту("false");

ДобавитьСтроковуюКонстанту("true");

JSON_Error = "ERROR";

В качестве примера взят файл j1.json :

{

"999": 88,

"Null": null,

"Сэкраном": "\"",

"Ложь": false,

"ОдинСимв": "1",

"1": "11111",

"Пустышка": "",

"Истина": true,

"Число (плавающая точка)": 1.001e-2,

"Число (плавающая)": -1.001e-2,

"Число (фиксированная точка)": -1000.001,

"Дата": "2011-01-01T12:00:00Z",

"Строка (двойная кавычка)": "Двойная кавычка",

"Строка (одинарная кавычка)": "Одинарная кавычка",

"Маскируемые символы": " \\ \/ \b \t \n \f \r \" ",

"Заковыристая строка": "\\n\\",

"Проблемные символы": "Спец. символы: \u0000, \u0001, \u0002, ... , \u001e, \u001f; Юникод символы: \u0421\u0430\u0448\u0430\u0020\u003a\u0029",

"Кириллические символы": "’АБВГҐДЂЃЕ?ЁЄЖЗЅИ?ІЇЙЈКЛЉМНЊОПРСТЋЌУЎФХЦЧЏШЩЪЫЬЭЮЯ",

"Идентификатор": "a763cfbb-f94f-4c67-8e13-0e96a3a7f353",

"Пустой массив": [],

"Пустой объект": {},

"Массив": [

null,

false,

true,

1.001e-2,

-1000.001,

"2011-01-01T12:00:00Z",

"Двойная кавычка",

"Одинарная кавычка",

"a763cfbb-f94f-4c67-8e13-0e96a3a7f353",

[

"Первый элемент",

"Второй элемент"

{

"Имя": "Александр",

"Отчество": "Владимирович",

"Фамилия": "Переверзев"

{

"ДопустимоеИмяСвойства": true,

"Недопустимое Имя Свойства": false

}

"Структура":

{

"Имя": "Александр",

"Отчество": "Владимирович",

"Фамилия": "Переверзев"

"Соответствие":

{

"ДопустимоеИмяСвойства": true,

"Недопустимое Имя Свойства": false

"Ссылка":

{

"Ссылка": "00000000-0000-0000-0000-000000000000",

"Представление": "Неизвестная ссылка"

"COMSafeArray": [

]

}

Категория: HTML, JS, VML

Запись во внешний источник данных из 1С 8.2

Начиная с платформы 8.2.14 в 1С появилась коллекция "Внешние источники данных". Использование объектов этой коллекции позволяет работать с внешними данными через ODBC. Стандартные механизмы платформы позволяют просматривать данные и использовать их в запросах. Тем не менее, на примере взаимодействия с SQL покажу возможность работы с внешними источниками на прямое добавление/изменение данных SQL из 1С.

Создадим для начала через консоль сервера SQL базу "test" с таблицей "assortment", строковые поля id, name, price. Сделаем ключевым поле id и внесем пару строк в таблицу. Потом создадим пустую базу 1С, в конфигураторе добавим внешний источник данных "ВнешнийSQL". На вкладке "Данные" добавим нашу таблицу. Можно ввести строку соединения, либо воспользоваться конструктором строки. В моей строке указаны явно учетная запись суперадминистратора (sa) и пароль к ней. Поскольку это сервер для тестов, вопросом безопасности можно пренебречь. Для реальной базы такого делать не стоит, либо можно завести отдельного пользователя с правами чтения/записи только на эту базу и хранить его данные.

После подключения находим в списке таблиц нашу, выбираем необходимые поля, в нашем случае все.

После добавляем формы для объекта и списка.

Если запустить нашу конфигурацию сейчас, то элементы формы списка будут открываться только на просмотр.

Теперь начинаем вносить изменения в формы, начнем с формы объекта. В свойствах реквизита "Объект" убираем галку "Сохраняемые данные", после этого реквизиты формы будут доступны для редактирования. Так же добавляем команду "ЗаписатьДанные" и прописываем код сохранения данных.

Код 1C v 8.3

 &НаСервере

Процедура ЗаписатьСервер()

 

 пСеанс = ВнешниеИсточникиДанных.ВнешнийSQL.ПолучитьОбщиеПараметрыСоединения();

 

 Если НЕ пСеанс.СУБД = "MSSQLServer" Тогда

  Возврат;

 КонецЕсли;

 

 ЗапросSQL = ?(Объект.Ссылка.Пустая(), ПолучитьЗапросДобавления(), ПолучитьЗапросОбновления());

 

 Connection  = Новый COMОбъект("ADODB.Connection");

 Command  = Новый COMОбъект("ADODB.Command");

 RecordSet  = Новый COMОбъект("ADODB.RecordSet");

 

 //учетка и пароль уже в строке подключения

 //иначе их необходимо добавить в строку

 Попытка

  Connection.Open(СокрЛП(пСеанс.СтрокаСоединения));

  Command.ActiveConnection   = Connection;

  Command.CommandText = ЗапросSQL;

  RecordSet = Command.Execute();

 Исключение

  Сообщить(ОписаниеОшибки());

 КонецПопытки;  





КонецПроцедуры // ЗаписатьСервер()





&НаСервере

Функция ПолучитьЗапросОбновления()

 

 мДанные = Объект.Ссылка.Метаданные();

 СтрокаПоля = "";

 СтрокаДанные = "";

 

 ДанныеОбъект = Объект.Ссылка.ПолучитьОбъект();

 

 Для Каждого мПоле Из мДанные.Поля Цикл

  Если Объект[мПоле.Имя] = ДанныеОбъект[мПоле.Имя] Тогда

   Продолжить;

  КонецЕсли;

  СтрокаДанные = СтрокаДанные + ?(ПустаяСтрока(СтрокаДанные), " SET ", ", ") + мПоле.Имя + "= '" + Объект[мПоле.Имя] + "'";

 КонецЦикла;

 

 //делаем UDPDATE по id, поскольку оно у нас ключевое

 ЗапросSQL = "UPDATE " + мДанные.ИмяВИсточникеДанных + СтрокаДанные + "WHERE (id = '" + ДанныеОбъект.id + "')";

 

 Возврат ЗапросSQL; 

 

КонецФункции





&НаСервере

Функция ПолучитьЗапросДобавления()

 

 мДанные = Объект.Ссылка.Метаданные();

 СтрокаПоля = "";

 СтрокаДанные = "";

 

 Для Каждого мПоле Из мДанные.Поля Цикл

  СтрокаПоля = СтрокаПоля + ?(ПустаяСтрока(СтрокаПоля), " (", ", ") + мПоле.Имя;

  СтрокаДанные = СтрокаДанные + ?(ПустаяСтрока(СтрокаДанные), " VALUES (", ", ") + "'" + Объект[мПоле.Имя] + "'";

 КонецЦикла;

 

 СтрокаПоля = СтрокаПоля + ")";

 СтрокаДанные = СтрокаДанные + ")";

 ЗапросSQL = "INSERT INTO " + мДанные.ИмяВИсточникеДанных + СтрокаПоля + СтрокаДанные;

 

 Возврат ЗапросSQL; 

 

КонецФункции





&НаКлиенте

Процедура ЗаписатьДанные(Команда)

 

 ЗаписатьСервер();

 //делаем оповещение для списка, поскольку он автоматически не обновляется

 Оповестить("ОбновитьВнешнийИсточникДанных");

 

КонецПроцедуры

Теперь в форме списка на панель вешаем команду "Добавить" и добавляем обработку оповещения.

Код 1C v 8.3

 &НаКлиенте

Процедура Добавить(Команда)





 ОткрытьФорму("ВнешнийИсточникДанных.ВнешнийSQL.Таблица.dbo_assortment.ФормаОбъекта");

 

КонецПроцедуры





&НаКлиенте

Процедура ОбработкаОповещения(ИмяСобытия, Параметр, Источник)

 

 Если ИмяСобытия = "ОбновитьВнешнийИсточникДанных" Тогда

  Элементы.Список.Обновить();

 КонецЕсли;

 

КонецПроцедуры

Вот и все, теперь мы можем как добавлять, так и редактировать данные таблицы. При необходимости можно добавить дополнительный контроль ввода, автонумерацию, удаление и прочие механизмы.

Источник

Категория: Внешние источники данных

Работа с изображениями (картинками) в интерфейсе Такси

Рассмотрим алгоритм работы с файлами и картинками в новом интерфейсе 1С:Предприятие 8.3 "Такси".

Во-первых, почему я решил написать эту статью: Новая концепция 1С - отказ от модальных окон, следовательно все методы и объекты, которые порождали открытие модальных окон в новом интерфейсе работать не смогут, точнее смогут, только если в свойствах конфигурации разрешить модальные окна.

Рассмотрим алгоритм работы с файлами и картинками в новом интерфейсе 1С:Предприятие 8.3 "Такси".

Однако, если разрешить модальные окна, то мы столкнемся с проблемами при работе в web-клиенте.

Во-вторых, о работе с картинками в управляемых формах часто спрашивают.

Итак, задача: в справочнике "Товары" необходимо сохранять и отображать в форме фотографию товара.

Исходная конфигурация не содержит ничего, кроме самого справочника с товарами, выкладывать ее не буду, просто создайте пустую конфигурацию в 8.3.

Для хранения самого графического файла, в справочнике создадим реквизит "ДанныеКартинки", с типом "Хранилище значений".

Если планируете выгружать картинку (файл) из информационной базы обратно в файловую систему, то добавьте еще реквизит, который будет хранить исходное имя файла и его тип.

Далее, займемся формой. Как видно на картинке, реквизит с типом хранилище значений в форме недоступен.

Как будем отображать картинку в форме? Нет, не декорацией с типом "картинка". А в виде реквизита формы с типом "строка". Да, да! Это очевидно, и странно, что мало кто об этом догадывается сам. ;)

Все дело в том, что если на форму вынести реквизит с типом "строка", который будет содержать навигационную ссылку на графические данные или адрес временного хранилища которое содержит такие данные, то форма сможет отобразить сами графические данные.

Добавим реквизит формы с именем "СсылкаНаКартинку", тип "строка", длина не ограничена. И поместим его в реквизиты формы.

По умолчанию, строка в форме будет выглядеть как поле ввода, нам нужно поменять это, в свойствах элемента формы. Выберем в свойстве "Вид" "Поле картинки".

Интерфейсная часть готова. Займемся кодингом. Создадим команду формы "ВыбратьФайлКартинки", в виде кнопки расположим ее на форме.

В модуле опишем обработчик события "Действие" для созданной команды формы:

Код 1C v 8.3

 &НаКлиенте

Процедура ВыбратьФайлКартинки(Команда)

//Создаем оповещение,   именно  процедура  "ОбработатьВыборФайла"  будет вызвана при закрытии окна выбора файла

 Оповещение  =  Новый ОписаниеОповещения("ОбработатьВыборФайла",   ЭтотОбъект);

//Открываем интерактивно  окно для выбора файла

НачатьПомещениеФайла(Оповещение,   ,   ,   Истина,   УникальныйИдентификатор);

КонецПроцедуры

Пару комментариев к вышеописанному коду:

Если бы мы не обращали внимание на режим модальности приложения, то могли вполне использовать метод "ПоместитьФайл", однако цель статьи показать работу с файлами именно в таком режиме.

Метод НачатьПомещениеФайла помещает выбранный файл во временное хранилище (если выбор файла был произведен) и вызывает процедуру "ОбработатьВыборФайла" в этом же модуле.

Обращаю внимание на выделенный "УникальныйИдентификатор", этим свойством мы связали временное хранилище с текущей формой. В противном случае файл в хранилище помещен будет, но само хранилище при серверном вызовет будет уничтожено, а нам оно еще понадобится, для записи файла в реквизит справочника.

Опишем процедуру "ОбработатьВыборФайла":

Код 1C v 8.3

 &НаКлиенте

Процедура ОбработатьВыборФайла(Результат, Адрес, ВыбранноеИмяФайла, ДополнительныеПараметры) Экспорт

Если Не Результат Тогда

 Возврат; 

КонецЕсли;

СсылкаНаКартинку = Адрес;

КонецПроцедуры

Если пользователь не отказался от выбора файла, то в реквизит формы "СсылкаНаКартинку" помещаем адрес во временном хранилище, куда были помещены данные картинки.

Вуаля!

Так, осталось теперь при записи элемента справочника записать данные из временного хранилища в реквизит элемента справочника. Описываем событие ПередЗаписьюНаСервере:

Код 1C v 8.3

 &НаСервере

Процедура Перед3аписьюНаСервере(Отказ, ТекущийОбьект, ПараметрыЗаписи)

Если ЭтоАдресВременногоХранилища(СсылкаНаКартинку) Тогда

 ТекущийОбьект.ДанныеКартинки = Новый ХранилищеЗначения( ПолучитьИзВремеиногоХранилища(СсылкаНаКартинку) );

КонецЕсли; 

КонецПроцедуры

Проверяем в реквизите формы у нас что? Если адрес временного хранилища, пишем данные в реквизит элемента справочника, обращаясь к "ТекущийОбъект", "ТекущийОбъект" - это сконвертированные данные формы, которые пишутся в базу в этот момент времени.

Осталось описать открытие формы, для отображения картинки уже сохраненной в реквизите элемента справочника.

Код 1C v 8.3

 &НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

 СсылкаНаКартинку = ПолучитьНавигационнуюСсылку(Объект.Ссылка, "ДанныеКартинки"); 

КонецПроцедуры

Автор: Павел Чистов Скачать архив DT

Категория: Работа с Хранилищем Значений

Этот хост неизвестен. Ошибка Windows Sockets - 11001

При подключении к базе, расположенной на сервере 1С:Предприятия, возникает ошибка "…Windows Sockets - 11001 (0x00002AF9). Этот хост неизвестен…". Как вылечить?

Виды ошибок:
title

или

Ошибка подключения к базе, расположенной на сервере 1С:Предприятия, возникает не всегда!
Подключение из Windows XP обычно проходит без особых проблем, при этом аналогичное подключение из Windows 7 может завершаться аварийно:
Ошибка 11001 - Windows Sockets
Лечится эта ошибка довольно просто! Достаточно внести изменения в файл hosts

Файл hosts представляет собой
Обычный текстовый файл (не имеющий расширения). В hosts-файле по умолчанию прописан всего один IP-адрес (127.0.0.1), зарезервированный для localhost, то есть для локального ПК. Файл hosts представляет собой обычный текстовый файл (не имеющий расширения).

Где находится файл hosts
• Windows 95/98/ME – WINDOWS;
• Windows NT/2000/XP/Vista/7 – Windows/System32/drivers/etc.

И так у нас Win7 открываем C:\WINDOWS\system32\drivers\etc\hosts, и добавляем в него ip-адрес вашего сервера.
Например так:
192.168.1.100 sermac

Сохраните, и попробуйте через пару минут запустить программу.

Категория: Администрирование

Передача файлов и данных на веб-сервер из 1С методами GET и POST

При интеграции 1С с веб-сайтами всегда встает вопрос о передачи некоторых данных на веб-сервер. Будь то это передача параметров запроса для получения данных от веб-сервера в 1С или же передача данных из 1С, которые должны быть сохранены или каким-то образом обработаны на веб-сервере. Передаваться могут как простые данные в виде строк, чисел, так и целые файлы (изображения, XML-файлы и прочее). Для передачи и получения файлов и данных на веб-сервер в 1С используется объект HTTPСоединение.

Создание и инициализация HTTP соединения в 1С
Для инициализации HTTP соединения в 1С необходимо создать объект HTTPСоединение и в конструкторе указать параметры HTTP соединения.

Код 1C v 8.х

 Новый HTTPСоединение(<Сервер>, <Порт>, <ИмяПользователя>, <Пароль>, <Прокси>, <ЗащищенноеСоединение>)

<Сервер> (обязательный) - адрес сервера, с которым необходимо установить соединение.
<Порт> (необязательный) - порт сервера, с которым устанавливается соединение.
Значение по умолчанию зависит от защищенности соединения (80 для незащищенного и 443 для SSL-соединения).
<ИмяПользователя> (необязательный) - имя пользователя на указанном сервере.
<Пароль> (необязательный) - пароль пользователя на указанном сервере.
<Прокси> (необязательный). Тип - ИнтернетПрокси. Прокси, используемый для соединения с сервером.
<ЗащищенноеСоединение> (необязательный). Тип - Булево. Определяет используемый протокол -
http или https. По умолчанию Ложь.
Ниже приведен примеры создания HTTPСоединения с сайтом http://www.mysite.ru/.

Код 1C v 8.х

 // соединение с параметрами по умолчанию

Соединение = Новый HTTPСоединение("www.mysite.ru");

 

// сервер использует порт 8080

Соединение = Новый HTTPСоединение("www.mysite.ru", 8080);

 

// сервер использует защищенное соединение (https),

// для подключения к серверу используется прокси

ПроксиСервер = Новый интернетПрокси;

ПроксиСервер.Пользователь = имяПользователя;

ПроксиСервер.Пароль       = парольПользователя;

 

Соединение = Новый HTTPСоединение("www.mysite.ru",,,, ПроксиСервер, Истина);

Передача данных на веб-сервер из 1С методом GET.
Для передачи данных на веб-сервер из 1С методом GET используется процедура Получить() объекта HTTPСоединение.

Код 1C v 8.х

 Получить(<Источник>, <ИмяВыходногоФайла>, <Заголовки>)

<Источник> (обязательный). Тип - Строка. Адрес ресурса на сервере.
<ИмяВыходногоФайла> (обязательный). Тип - Строка. Имя файла на диске, в который
помещаются данные, полученные от сервера (ответ сервера).
<Заголовки> (необязательный). Тип - Строка. Заголовки, добавляемые к запросу на сервер.
Текстовые пары вида <Заголовок>:<Значение>, разделенные комбинацией ВК + ПС.
(подробнее о заголовках будет сказано ниже).
Рассмотрим параметры процедуры Получить() более подробно:

В качестве источника указывается строка с адресом запроса, идущая после названия домена и символа "/". Так, если необходимо отправить данные на адрес https://www.mysite.com/getusers.php, то при создании HTTP соединения в конструкторе HTTPСоединение в поле "Сервер" указывается "www.mysite.com", признак защищенного соединения устанавливается в Истина, а в процедуре Получить() в параметре Источник указывается "getUsers.php".

В поле ИмяВыходногоФайла указывает имя файла на диске, в который будут сохранены данные, полученные от сервере в результате запроса. Так, например, если сервер возвращает список пользователей в формате XML, то на диск в указанный файл будет сохранен XML файл со списком пользователей.

О заголовках более подробно будет сказано ниже.

Так же, при запросе к веб-серверу зачастую передаются дополнительные данные (параметры) для этого запроса. Параметры от адреса источника отделяются символом "?". Каждый параметр задается в формате <Имя_Параметры>=<Значение_Параметры>. Параметры от адреса источника отделяются символом "?". Сами же параметры отделяются друг от друга символом "&". В результате строка адреса источника может выглядеть следующим образом: getUsers.php?owner_id=263544&count=100.

Ниже приведен пример, поясняющий все выше сказанное.

Код 1C v 8.х

 // необходимо выполнить запрос по адресу

// https://www.mysite.com/getUsers.php?owner_id=263544&amp;count=100

// ответ от сервера приходит в виде XML файла

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml");

 

Соединение = Новый HTTPСоединение("www.mysite.com",,,,, Истина);

Соединение.Получить("getUsers.php?owner_id=263544&amp;count=100", имяВыходногоФайла);

 

ЧтениеXML = Новый ЧтениеXML;

ЧтениеXML.ОткрытьФайл(имяВыходногоФайла);

 

Пока ЧтениеXML.Прочитать() Цикл

    // чтение ответа в виде XML файла

    ...

КонецЦикла;

 

ЧтениеXML.Закрыть();

 

// удаляем файл после использования

УдалитьФайлы(имяВыходногоФайла);

Заголовки HTTP
Ниже приведена общая информация о HTTP заголовках из википедии.
Заголовки HTTP (англ. HTTP Headers) — это строки в HTTP-сообщении, содержащие разделённую двоеточием пару имя-значение. Формат заголовков соответствует общему формату заголовков текстовых сетевых сообщений ARPA. Заголовки должны отделяться от тела сообщения хотя бы одной пустой строкой.

Все заголовки разделяются на четыре основных группы:

General Headers (рус. Основные заголовки) — должны включаться в любое сообщение клиента и сервера.
Request Headers (рус. Заголовки запроса) — используются только в запросах клиента.
Response Headers (рус. Заголовки ответа) — только для ответов от сервера.
Entity Headers (рус. Заголовки сущности) — сопровождают каждую сущность сообщения.
Именно в таком порядке рекомендуется посылать заголовки получателю.

Более подробно о заголовках HTTP можно прочитать здесь. Так же можно ознакомится со списком заголовков HTTP.

От себя лишь добавлю, что, если это явно не указано в требованиях к отправке данных веб-серверу заголовки HTTP для метода GET можно не указывать. Для метода POST обычно нужно указать заголовки Content-Type (тип передаваемых данных, например: "Content-Type: text/html;charset=utf-8") и Content-Length (размер передаваемых данных в байтах, например: "Content-Length: 1348").

Напомню, что HTTP заголовки в 1С указываются строкой в виде текстовых пар "<Заголовок>:<Значение>", разделенных комбинацией символов ВК+ПС.
Также заголовки можно задать типом Соответствие, где в качестве ключа указывается заголовок, а в качестве значения - значение заголовка.
Ниже приведены поясняющие примеры:

Код 1C v 8.х

 источник = "owner=263544&amp;count=100";

 

// Передача заголовков строкой

ЗаголовкиHTTP = "Content-Type:text/html;charset=utf-8" + Символ.ВК + Символ.ПС +

            "Content-Length: "+СтрДлина(источник);

Соединение.Получить("", имяВыходногоФайла, ЗаголовкиHTTP);

 

// Вставить символы ВК+ПС можно и таким способом

ЗаголовкиHTTP = "Content-Type:text/html;charset=utf-8

            |Content-Length: 1348";

Соединение.Получить("", имяВыходногоФайла, ЗаголовкиHTTP);

 

// Установка заголовков типом Соответствие

ЗаголовкиHTTP = Новый Соответствие;

ЗаголовкиHTTP.Вставить("Content-Type", "text/html;charset=utf-8");

ЗаголовкиHTTP.Вставить("Content-Length", СтрДлина(источник));

 

Соединение.Получить(источник, имяВыходногоФайла, ЗаголовкиHTTP);

Передача данных на веб-сервер из 1С методом POST.
Общие сведения.
Для передачи данных на веб-сервер из 1С методом POST используется процедура ОтправитьДляОбработки() объекта HTTPСоединение.

Код 1C v 8.х

 ОтправитьДляОбработки(<Источник>, <АдресРесурса>, <ИмяВыходногоФайла>, <Заголовки>)

<Источник> (обязательный) - Имя файла-источника, который будет отправлен
на сервер для обработки.
<АдресРесурса> (обязательный). Тип - строка. Адрес ресурса на сервере,
в который посылаются данные из источника.
<ИмяВыходногФайла> (обязательный) - Имя файла на диске, в который записываются
полученные с сервера данные.
<Заголовки> (необязательный). Тип - строка. Заголовки, добавляемые к запросу на сервер.
Текстовые пары вида <Заголовок>:<Значение>, разделенные комбинацией ВК + ПС.
(подробнее о заголовках будет сказано ниже).
Рассмотрим параметры процедуры ОтправитьДляОбработки() подробнее:

В качестве источника указывается файл, содержимое которого необходимо отправить на сервер для обработки. Подробнее о формировании содержимого файла-источника будет сказано ниже.

Поле АдресРесурса аналогично полю Источник процедуры Получить(), т.е. указывается строка с адресом запроса, идущая после имени домена и символа "/".

Поле ИмяВыходногоФайла также аналогично одноименному полю процедуры Получить(), т.е. содержит имя файла, в котором будут сохранены данные, полученные от сервера в результате обработки исходных данных.

О заголовках было упомянуто выше. Напомню лишь, что для метода POST обычно указываются заголовки Content-Type и Content-Length. В качестве параметра заголовка Content-Length указывается размер файла-источника, преобразованный с помощью функции XMLСтрока().

Ниже приведен пример, поясняющий все выше сказанное.

Код 1C v 8.х

 имяФайлаОтправки = "d:\data\request.txt"; // файл с отсылаемыми для обработки данными

 

// Определим размер файла-источника

// и установим HTTP заголовки

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "text/html;charset=utf-8");

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml");

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "addPost.php", имяВыходногоФайла, Заголовки);

Передача параметров методом POST.
Для передачи параметров, аналогично методу GET, можно сформировать строку параметров, записать их в текстовый файл и отправить этот файл на сервер для обработки. Ниже приведен пример аналогичный примеру отправки методом GET, но теперь те же данные отправляются методом POST.

Код 1C v 8.х

 // сформируем файл для отправки на сервер

 

имяФайлаОтправки = ПолучитьимяВременногоФайла("txt");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаОтправки);

ЗаписьТекста.Записать("owner=263544&amp;count=100");

ЗаписьТекста.Закрыть();

 

// отправим файл на сервер для обработки

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml"); // наш сервер возвращает ответы в виде XML

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "text/html;charset=utf-8");

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "addPost.php", имяВыходногоФайла, Заголовки);

 

// удалим файл отправки - он больше не нужен

Попытка

    УдалитьФайлы(имяФайлаОтправки);

Исключение

КонецПопытки;

 

// обработаем ответ сервера

 

ЧтениеXML = Новый ЧтениеXML;

ЧтениеXML.ОткрытьФайл(имяВыходногоФайла);

 

Пока ЧтениеXML.Прочитать() Цикл

    // чтение ответа в виде XML файла

    ...

КонецЦикла;

 

ЧтениеXML.Закрыть();

 

// удаляем файл после использования

Попытка

    УдалитьФайлы(имяВыходногоФайла); 

Исключение

КонецПопытки;

Передача файлов методом POST.
Зачастую данные для обработки задаются не виде строки параметров разделенных "&", как в рассматриваемых выше примерах, а виде файла определенного формата, например XML или JSON. Рассмотрим пример отправки данных на веб-сервер для обработки методом POST, которые задаются в формате XML. Например, сервер может добавить ваш комментарий к материалу. В описании процедуры добавлении сказано, что данные необходимо отправлять по адресу www.mysite.com/addComment.php. Сами данные должны быть переданы в следующем виде:

Код

<?xml version="1.0" encoding="UTF-8"?>
<request>
<user_id>ID_Пользователя</user_id>
<post_id>ID_Материала</post_id>
<message>Текст_Комментария</message>
</request>

где:
<ID_Пользователя> - id пользователя на сайте, от имени которого добавляется комментарий;
<ID_Материала> - id материала на сайте, к которому добавляется комментарий;
<Текст_Комментария> - текст комментария.

Предположим, что нам уже известны id пользователя и материала и они хранятся в переменных user_id и post_id. Ниже приведен пример, решающий нашу задачу.

Код 1C v 8.х

 // подготовим файл с данными для отправки

имяФайлаОтправки = ПолучитьимяВременногоФайла("xml");

 

ОбъектXML = Новый ЗаписьXML;

ОбъектXML.ОткрытьФайл(имяФайлаОтправки, "UTF-8");

ОбъектXML.ЗаписатьОбъявлениеXML();

ОбъектXML.ЗаписатьБезОбработки(

"<request>

|    <user_id>" + user_id + "</user_id>

|    <post_id>" + post_id + "</post_id>

|    <message>" + ТекстКомментария + "</message>

|</request>");

ОбъектXML.Закрыть();

 

// отправим файл на сервер для обработки

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml"); // наш сервер возвращает ответы в виде XML

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "text/html;charset=utf-8");

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "addComment.php", имяВыходногоФайла, Заголовки);

 

// удалим файл отправки - он больше не нужен

Попытка

    УдалитьФайлы(имяФайлаОтправки);

Исключение

КонецПопытки;

 

// обработаем ответ сервера

 

ЧтениеXML = Новый ЧтениеXML;

ЧтениеXML.ОткрытьФайл(имяВыходногоФайла);

 

Пока ЧтениеXML.Прочитать() Цикл

    // чтение ответа в виде XML файла

    ...

КонецЦикла;

 

ЧтениеXML.Закрыть();

 

// удаляем файл после использования

Попытка

    УдалитьФайлы(имяВыходногоФайла); 

Исключение

КонецПопытки;

Загрузка файлов (изображений, документов и т.п.) на веб-сервер методом POST.
Зачастую возникает необходимость загрузки файлов на веб-сервер. Это может быть, например, изображение к статье на сайте, или фотография для альбома, или архив для файлообменника. Ранее мы рассматривали передачу методом POST параметров или просто файлов. Таким же образом можно и передавать двоичные файлы. Но как быть, если файлы необходимо отправлять вместе с параметрами? Для возможности отправки файлов в этом случае используется HTTP заголовок ContentType:multipart/form-data. Следует заметить, что обычно таким способом передаются файлы через веб-браузеры. Т.е. когда на сайте вы выбираете файл и нажимаете кнопку "Загрузить", то файл передается способом описанным ниже. При таком способе сам файл также задается как переменная, т.е., например, файл передается через параметр file или image. Однако, мы не можем просто передать file=<Двоичные_Данные>. А вот как все таки передать файл мы и рассмотрим ниже.

Для возможности вместе с параметрами передавать и двоичные данные (файлы) необходимо сформировать HTTP заголовок Content-Type следующим образом:
Content-Type: multipart/form-data, boundary=<уникальные_данные>
где <уникальные_данные> - это любой набор цифр и/или символов, который будет служить для отделения значений друг от друга. Значение boundary должно быть уникальным в пределах пересылаемой информации, т.е. таких символов не должно встречаться в пересылаемых файлах и переменных.

Bounday можно сформировать, например, таким образом

Код 1C v 8.х

 boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

Все данные отделяются друг от друга разделителем boundary. Начинать разделитель нужно с "--":

Код

--<boundary>
Content-Disposition: form-data; name="<имя_переменной>"
<пустая_строка>
<значение_переменной>
Для отправки файла необходимо еще добавить тип и имя файла:

--<boundary>
Content-Disposition: form-data; name="<имя_переменной>"; filename="<имя_файла>"
Content-Type: <тип_файла> (например image/jpeg или text/plain)
<пустая_строка>
<данные_файла>

В конце данных нужно закрыть разделитель, добавили в конце разделителя "--", т.е. вид будет "--<boundary>--".

Итак, например, нам нужно передать на веб-сервер текстовый файл через параметр "text", его описание через параметр "desc" и id пользователя через параметр "uid", для которого будет загружен наш файл.

Предположим, что файл содержит следующий текст:
Мороз и солнце; день чудесный!
Еще ты дремлешь, друг прелестный -
Пора, красавица, проснись:
Открой сомкнуты негой взоры
Навстречу северной Авроры,
Звездою севера явись!
Описание должно содержать "Стих А.С. Пушкина", а id пользователя равно "0123456". Тогда файл должен быть сформирован следующим образом (для упрощения предположим, что bounday мы уже сформировали и он равен "ccf8111910")

Код

--ccf8111910
Content-Disposition: form-data; name="uid"

0123456
--ccf8111910
Content-Disposition: form-data; name="desc"

Стих А.С. Пушкина
--ccf8111910
Content-Disposition: form-data; name="text"; filename="stih.txt"
Content-Type: text/plain

Мороз и солнце; день чудесный!
Еще ты дремлешь, друг прелестный -
Пора, красавица, проснись:
Открой сомкнуты негой взоры
Навстречу северной Авроры,
Звездою севера явись!
--ccf8111910--

А теперь перейдем непосредственно к 1С. Пусть у нас будет форма с реквизитами "Пользователь", "Описание" и "ИмяФайла". Реализуем отправку данных, описанным выше способом

Код 1C v 8.х

 // подготовим файл с данными для отправки

имяФайлаОтправки = ПолучитьимяВременногоФайла("txt");

Boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаОтправки);

 

// параметр "uid"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""uid""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(Пользователь);

 

// параметр "desc"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""desc""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(Описание);

 

// параметр "text"

ФайлДляПередачи = Новый ТекстовыйДокумент;

ФайлДляПередачи.Прочитать(имяФайла);

 

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""text""; filename=""stih.txt""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: text/plain");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.Записать(ФайлДляПередачи.ПолучитьТекст());

ЗаписьТекста.ЗаписатьСтроку("");

 

// закроем разделитель

ЗаписьТекста.ЗаписатьСтроку("--"+boundary+"--");

 

ЗаписьТекста.Закрыть();

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

// передадим данные на сервер 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "multipart/form-data, boundary="+boundary);

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "postFile.php", имяВыходногоФайла, Заголовки);

Передача текстовых файлов таким способом проблем не вызывает. Сложнее дело обстоит с файлами, содержащими двоичные данные (изображения, архивы и т.п.). Все дело в том, что в 1С просто нет методов для чтение двоичных файлов в строку. Если мы делаем обмен со своим сайтом, которые сами и разрабатывали, то можно просто преобразовать файл в строку Base64 при помощи процедуры Base64Строка(), а на стороне сервера преобразовать строку Base64 обратно.

Код 1C v 8.х

 // подготовим файл с данными для отправки

имяФайлаДанных = "d:\photo\birthday.jpg";

 

имяФайлаОтправки = ПолучитьимяВременногоФайла("txt");

Boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаОтправки);

 

// параметр "file"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""file""; filename=""photo.jpg""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: image/jpeg");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.Записать(Base64Строка(Новый ДвоичныеДанные(имяФайлаДанных)));

ЗаписьТекста.ЗаписатьСтроку("");

 

// закроем разделитель

ЗаписьТекста.ЗаписатьСтроку("--"+boundary+"--");

 

ЗаписьТекста.Закрыть();

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

// передадим данные на сервер 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "multipart/form-data, boundary="+boundary);

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "uploadFile.php", имяВыходногоФайла, Заголовки);

А как же быть если мы загружаем файл на сторонний сервер, который принимает файл как есть без преобразование его в строку Base64(). В это случае можно пойти на хитрость. В 1С есть процедура ОбъединитьФайлы(), которая объединяет несколько файлов на диске в один результирующий файл

Код 1C v 8.х

 ОбъединитьФайлы(<ИменаЧастей>, <ИмяРезультирующегоФайла>)

<ИменаЧастей> (обязательный). Тип - Массив. Массив имен частей файлов, которые
требуется объединить. Объединение будет происходить в порядке, в котором заданы
имена файлов в массиве.
<ИмяРезультирующегоФайла> (обязательный). Тип - Строка. Имя файла, который будет
создан в результате объединения файлов.
Т.е. мы можем сформировать текстовый файл с запросом, объединить его с файлом(-ами), которые необходимо передать на веб-сервер и передать уже файл, получившийся в результате объединения исходных файлов. Ниже демонстрируется процесс передачи двух zip архивов на сервер с дополнительными параметрами user_id и post_id.

Код 1C v 8.х

 // подготовим файлы с данными для отправки

 

массивФайлов = Новый Массив;

 

Boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

 

имяФайлаСПараметрами = ПолучитьимяВременногоФайла("txt"); // первый файл, содержащий параметры

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаСПараметрами);

 

// параметр "user_id"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""user_id""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(user_id);

 

// параметр "post_id"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""post_id""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(post_id);

 

// начало параметра "file1"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""file1""; filename=""archive1.zip""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: application/x-zip-compressed");

ЗаписьТекста.ЗаписатьСтроку("");

 

ЗаписьТекста.Закрыть(); // заканчиваем работу с файлом 1

 

массивФайлов.Добавить(имяФайлаСПараметрами); // добавляем 1-ый файл для объединения

массивФайлов.Добавить(имяФайлаАрхива1); // добавляем 1-ый архив для объединения

 

// второй файл параметров, содержаший начало параметра "file2"

имяФайлаСПараметрами = ПолучитьимяВременногоФайла("txt");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаСПараметрами);

 

// начало параметра "file2"

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""file2""; filename=""archive2.zip""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: application/x-zip-compressed");

ЗаписьТекста.ЗаписатьСтроку("");

 

ЗаписьТекста.Закрыть(); // заканчиваем работу с файлом 2

 

массивФайлов.Добавить(имяФайлаСПараметрами); // добавляем 2-ой файл для объединения

массивФайлов.Добавить(имяФайлаАрхива2); // добавляем 2-ой архив для объединения

 

ЗаписьТекста.Записать(ФайлДляПередачи.ПолучитьТекст());

ЗаписьТекста.ЗаписатьСтроку("");

 

// третий файл, закрывающий параметры

имяФайлаСПараметрами = ПолучитьимяВременногоФайла("txt");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаСПараметрами);

 

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку("--"+boundary+"--");

 

ЗаписьТекста.Закрыть(); // заканчиваем работу с файлом 3

 

массивФайлов.Добавить(имяФайлаСПараметрами); // добавляем 3-ий файл, закрывающий параметры

 

// результирующий файл, который и будет отправлен

имяФайлаОтправки = ПолучитимяВременногоФайла("out");

 

// объединим все файлы

ОбъединитьФайлы(массивФайлов, имяФайлаОтправки);

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

// передадим данные на сервер 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "multipart/form-data, boundary="+boundary);

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "postFile.php", имяВыходногоФайла, Заголовки);

Ну вот, вроде бы, и все, что я хотел рассказать о способах передачи файлов и данных на веб-сервер из 1С. Если что-то не понятно, что-то хотите уточнить или нашли ошибки - пишите в комментариях.
Автор: Павел

Категория: Работа с Интернет, Почтой (Mail), FTP

Загрузка данных из текстовых файлов, выбирая SQL запросом данные из этих файлов

Код

Колонка1 20 символов – Номер заказа
Колонка2 5 символов – Код контрагента
Колонка3 10 символов – Дата заказа
Колонка4 10 символов – Дата доставки
Колонка5 10 символов – Дата сбора
Колонка6 4 символов – Количество строк в ТЧ

Структура строки в Rows_XXXXX.txt

Код

Колонка1 20 символов – Номер заказа
Колонка2 7 символов – Артикул номенклатуры
Колонка3 9 символов – Количество в базовых ед. изм.

В каждой паре файлов несколько Заказов. Необходимо загрузить эти заказы в БД 1С
Для этого воспользуемся Microsoft.Jet.OLEDB.4.0

Для того чтоб данный драйвер корректно понимал структуру файлов необходимо в каталоге расположения данных файлов, перед выполнением запросов, создать специальный текстовый файл schema.ini cо следующими строками:

Код

[ Head_XXXXX]
ColNameHeader=False
Format=FixedLength
Col1=NumberNote Text Width 20
Col2=StoreNum Text Width 5
Col3=DataNote DateTime Width 10
Col4=DataDev DateTime Width 10
Col5=DataDes DateTime Width 10
Col6=CountLine Long Width 4

[Rows_XXXXX]
ColNameHeader=False
Format=FixedLength
Col1=NumberNote Text Width 20
Col2=Articul Text Width 7
Col3=Counts Double Width 9

Как видим, здесь мы задаем структуру таблицы из файла.
Остается только выполнить запрос к полученной текстовой БД и обработать результат:

Ниже приведен пример кода для платформы 1С 8:

Код 1C v 8.х

 // Загружает данные из текстовых данных

//

// Параметры

// Стр_КаталогДанных - <Строка>

//

// Автор: Gmix 04.05.2006 12:22:09

//     

// Возвращаемое значение:

//   <Булево>

//

Функция ЗагрузитьДанныеИзtxt(Стр_КаталогДанных)

            // проверки заполнения

           

            ОБ_ФайлДанных=Новый Файл(Стр_КаталогДанных);

            Если НЕ ОБ_ФайлДанных.ЭтоКаталог() Тогда

                        Сообщить("Необходимо указать каталог данных!",СтатусСообщения.ОченьВажное);

                        Возврат Ложь;

            КонецЕсли;

          

            Если НЕ ОБ_ФайлДанных.Существует() Тогда

                Сообщить("Каталог """+Стр_КаталогДанных+""" не существует!",СтатусСообщения.ОченьВажное);

                        Возврат Ложь;

            КонецЕсли;

           

            ОБ_АДОКонект = Новый COMОбъект("ADODB.Connection");

            ОБ_АДОРекордсетШапка = Новый COMОбъект("ADODB.Recordset");

            ОБ_АДОРекордсетСтроки = Новый COMОбъект("ADODB.Recordset");

           

            //Определяем пару файлов

            Стр_ОкончаниеФайла="";

            ФайлыШапок = НайтиФайлы(Стр_КаталогДанных, "Head_*.txt");

            Для каждого ФайлШапки Из ФайлыШапок Цикл

                        Стр_ОкончаниеФайла=Сред(ФайлШапки.ИмяБезРасширения,6);

                        Стр_таблицаШапки=ФайлШапки.Имя;

                       

                        Стр_ТаблицаСтрок="Rows_"+Стр_ОкончаниеФайла+".txt";

                        Стр_ИмяФайлСтрок=ДобавлениеСлеша(Стр_КаталогДанных)+Стр_ТаблицаСтрок;

                        ФайлСтрок=Новый Файл(Стр_ИмяФайлСтрок);

                        Если НЕ ФайлСтрок.Существует() Тогда

                            Сообщить("Не найден файл строк для файла шапки """+Стр_таблицаШапки+"""! Пара файлов не обработана",СтатусСообщения.Важное);

                                   Продолжить;

                        КонецЕсли;

                       

                        //Создаем схему данных

                        ФайлСхемыДанных=Новый Файл(ДобавлениеСлеша(Стр_КаталогДанных)+"schema.ini");

                        Если ФайлСхемыДанных.Существует() Тогда

                                  Попытка

                                       УдалитьФайлы(ФайлСхемыДанных.Путь,ФайлСхемыДанных.Имя);

                                   Исключение

                                       Сообщить("Не возможно удалить файл """+ФайлСхемыДанных.ПолноеИмя+""" для создания новой схемы данных! Проверте атрибуты файла",СтатусСообщения.Важное);

                                               Возврат Ложь;

                                   КонецПопытки;

                        КонецЕсли;

                       

                        Стр_СхемаДанныхТхт="["+Стр_таблицаШапки+"]

                                                                                  |ColNameHeader=False

                                                                                  |Format=FixedLength

                                                                                  |Col1=NumberNote Text Width 20

                                                                                  |Col2=StoreNum Text Width 5

                                                                                  |Col3=DataNote DateTime Width 10

                                                                                  |Col4=DataDev DateTime Width 10

                                                                                  |Col5=DataDes DateTime Width 10

                                                                                  |Col6=CountLine Long Width 4

                                                                                 

                                                                                  |["+Стр_ТаблицаСтрок+"]

                                                                                  |ColNameHeader=False

                                                                                  |Format=FixedLength

                                                                                  |Col1=NumberNote Text Width 20

                                                                                  |Col2=Articul Text Width 7

                                                                                  |Col3=Counts Double Width 9";

                       

                        ТекстСхемы=Новый ЗаписьТекста(ФайлСхемыДанных.ПолноеИмя, КодировкаТекста.ANSI);

                        ТекстСхемы.Записать(Стр_СхемаДанныхТхт);

                        ТекстСхемы.Закрыть();

                       

                        // Создаем коннект

                        Попытка

                                   ОБ_АДОКонект.Open("Provider=Microsoft.Jet.OLEDB.4.0;Data Source="+Стр_КаталогДанных+";Extended Properties='text;FMT=Delimited;HDR=NO'");

                       Исключение

                                   Сообщить("Невозможно открыть соединение!"+ОписаниеОшибки(),СтатусСообщения.Важное);

                            Возврат Ложь;

                        КонецПопытки;

 

                       Стр_SQL = "S_elect * FROM "+Стр_таблицаШапки;

                      

                        Попытка

                                    ОБ_АДОРекордсетШапка=ОБ_АДОКонект.Execute(Стр_SQL);                

                        Исключение

                            Сообщить("Ошибка выполнения запроса """+Стр_SQL+"""!"+ОписаниеОшибки(),СтатусСообщения.Важное);

                                   Возврат Ложь;          

                        КонецПопытки;

 

                        Пока НЕ ОБ_АДОРекордсетШапка.EOF Цикл

                                  

                                   // Заказ

                                   Стр_НомерЗаказа     = ОБ_АДОРекордсетШапка.Fields("NumberNote").Value;

                                  Стр_КодКА= ОБ_АДОРекордсетШапка.Fields("StoreNum").Value;

                              

                                   Д_ДатаЗаказа= ОБ_АДОРекордсетШапка.Fields("DataNote").Value;

                                   Д_ДатаДоставки= ОБ_АДОРекордсетШапка.Fields("DataDev").Value;

                                   Д_ДатаСбора= ОБ_АДОРекордсетШапка.Fields("DataDes").Value;

                                   Ч_КоличествоСтрок            = ОБ_АДОРекордсетШапка.Fields("CountLine").Value;

                                 

                                   Сообщить("Заказ № "+Стр_НомерЗаказа+" от " +Д_ДатаЗаказа+ " Код контрагента: "+Стр_КодКА+" Дата доставки: "+Д_ДатаДоставки);

                                  

                                   // Обработка строк заказа

                                   Стр_SQL = "S_elect * FROM "+Стр_ТаблицаСтрок+" WHERE NumberNote='"+Стр_НомерЗаказа+"'";



                                   Попытка

                                               ОБ_АДОРекордсетСтроки=ОБ_АДОКонект.Execute(Стр_SQL);               

                                  Исключение

                                               Сообщить("Ошибка выполнения запроса """+Стр_SQL+"""!"+ОписаниеОшибки(),СтатусСообщения.Важное);

                                               Возврат Ложь;          

                                   КонецПопытки;



                                   Сч=0;

                                   Сообщить(" №           Артикул                     Количество");

                                   Пока НЕ ОБ_АДОРекордсетСтроки.EOF Цикл

                                              //Заполняем таб часть документа

                                               Сч=Сч+1;

                                               Стр_Артикул=СокрЛП(ОБ_АДОРекордсетСтроки.Fields("Articul").Value);

                                               Ч_Количество=ОБ_АДОРекордсетСтроки.Fields("Counts").Value;

                                               Сообщить(""+Сч+"    " +Стр_Артикул+ "               "+Ч_Количество);

                                               ОБ_АДОРекордсетСтроки.MoveNext();

                                   КонецЦикла;



                                   ОБ_АДОРекордсетШапка.MoveNext();

                        КонецЦикла;

           КонецЦикла;

    Возврат Истина;

КонецФункции // ЗагрузитьДанныеИзtxt() Gmix 04.05.2006 12:22:21

Автор: Журавлев Михаил Викторович

Категория: Конвертация данных, Обмен, Перенос

Ошибка 1С 8.2 "Сеанс отсутствует или удален".

BoricH пишет:
1C8.2 при работе в терминале на 64х сервере в клиент-серверном режиме при большом колличестве пользователей вылетает с ошибкой "Сеанс отсутствует или удален".

Сервер 1С 64х 8.2.10.82, 8.2.11.229 , SQL 2005.
Если на одной машине запустить около 60 сеансов 1С, то программа вылетает (на всех запущеных сеансах) с ошибкой "Сеанс отсутствует или удален".
Код ошибки 4587.
Тонкие клиенты не вылетают....
Делал эксперимент: запустил кучу тонких клиентов (порядка штук 70) и пару толстых клиентов.. буквально через минуту толстые клиенты "отвалились"..

Как оказалось, решение очень банальное: необходимо на сервере 1С:Предприятия добавить несколько рабочих процессов.

Категория: Системные Ошибки

Загрузка данных из текстовых файлов с выборкой через ADO.

Часто бывает потребность загружать данные из текстовых форматов, причем информация для загрузки бьется на 2 и более файлов.

Хорошо бы посредством SQL запроса выбирать данные из этих файлов и производить загрузку! Это вполне возможно и я считаю этот способ наиболее грамотный для решения таких задач!

Имеем 2 файла:
- Head_XXXXX.txt
- Rows_XXXXX.txt

Где XXXXX – порядковой номер пары файлов

Структура строки в Head_XXXXX.txt :

Колонка1 20 символов – Номер заказа
Колонка2 5 символов – Код контрагента
Колонка3 10 символов – Дата заказа
Колонка4 10 символов – Дата доставки
Колонка5 10 символов – Дата сбора
Колонка6 4 символов – Количество строк в ТЧ

Структура строки в Rows_XXXXX.txt :
Колонка1 20 символов – Номер заказа
Колонка2 7 символов – Артикул номенклатуры
Колонка3 9 символов – Количество в базовых ед. изм.

В каждой паре файлов несколько Заказов.
Необходимо загрузить эти заказы в БД 1С

Для этого воспользуемся Microsoft.Jet.OLEDB.4.0
Для того чтоб данный драйвер корректно понимал структуру файлов необходимо в каталоге расположения данных файлов, перед выполнением запросов, создать специальный текстовый файл schema.ini cо следующими строками:

Код

Код 1C v 8.х

 // Загружает данные из текстовых данных

// Параметры

// Стр_КаталогДанных - <Строка>

// Автор: Gmix 04.05.2006 12:22:09

// Возвращаемое значение:

//   <Булево>

Функция ЗагрузитьДанныеИзtxt(Стр_КаталогДанных)

            // проверки заполнения

           

            ОБ_ФайлДанных=Новый Файл(Стр_КаталогДанных);

            Если НЕ ОБ_ФайлДанных.ЭтоКаталог() Тогда

                        Сообщить("Необходимо указать каталог данных!",СтатусСообщения.ОченьВажное);

                        Возврат Ложь;

            КонецЕсли;

           

            Если НЕ ОБ_ФайлДанных.Существует() Тогда

                Сообщить("Каталог """+Стр_КаталогДанных+""" не существует!",СтатусСообщения.ОченьВажное);

                        Возврат Ложь;

            КонецЕсли;

           

            ОБ_АДОКонект = Новый COMОбъект("ADODB.Connection");

            ОБ_АДОРекордсетШапка = Новый COMОбъект("ADODB.Recordset");

            ОБ_АДОРекордсетСтроки = Новый COMОбъект("ADODB.Recordset");

           

            //Определяем пару файлов

            Стр_ОкончаниеФайла="";

            ФайлыШапок = НайтиФайлы(Стр_КаталогДанных, "Head_*.txt");

            Для каждого ФайлШапки Из ФайлыШапок Цикл

                        Стр_ОкончаниеФайла=Сред(ФайлШапки.ИмяБезРасширения,6);

                        Стр_таблицаШапки=ФайлШапки.Имя;

                       

                        Стр_ТаблицаСтрок="Rows_"+Стр_ОкончаниеФайла+".txt";

                        Стр_ИмяФайлСтрок=ДобавлениеСлеша(Стр_КаталогДанных)+Стр_ТаблицаСтрок;

                        ФайлСтрок=Новый Файл(Стр_ИмяФайлСтрок);

                        Если НЕ ФайлСтрок.Существует() Тогда

                            Сообщить("Не найден файл строк для файла шапки """+Стр_таблицаШапки+"""! Пара файлов не обработана",СтатусСообщения.Важное);

                                   Продолжить;

                        КонецЕсли;

                       

                        //Создаем схему данных

                        ФайлСхемыДанных=Новый Файл(ДобавлениеСлеша(Стр_КаталогДанных)+"schema.ini");

                        Если ФайлСхемыДанных.Существует() Тогда

                                   Попытка

                                       УдалитьФайлы(ФайлСхемыДанных.Путь,ФайлСхемыДанных.Имя);

                                   Исключение

                                       Сообщить("Не возможно удалить файл """+ФайлСхемыДанных.ПолноеИмя+""" для создания новой схемы данных! Проверте атрибуты файла",СтатусСообщения.Важное);

                                               Возврат Ложь;

                                   КонецПопытки;

                        КонецЕсли;

                       

                        Стр_СхемаДанныхТхт="["+Стр_таблицаШапки+"]

                                                                                  |ColNameHeader=False

                                                                                  |Format=FixedLength

                                                                                  |Col1=NumberNote Text Width 20

                                                                                  |Col2=StoreNum Text Width 5

                                                                                  |Col3=DataNote DateTime Width 10

                                                                                  |Col4=DataDev DateTime Width 10

                                                                                  |Col5=DataDes DateTime Width 10

                                                                                  |Col6=CountLine Long Width 4

                                                                                  |["+Стр_ТаблицаСтрок+"]

                                                                                  |ColNameHeader=False

                                                                                  |Format=FixedLength

                                                                                  |Col1=NumberNote Text Width 20

                                                                                  |Col2=Articul Text Width 7

                                                                                  |Col3=Counts Double Width 9";

                       

                        ТекстСхемы=Новый ЗаписьТекста(ФайлСхемыДанных.ПолноеИмя, КодировкаТекста.ANSI);

                        ТекстСхемы.Записать(Стр_СхемаДанныхТхт);

                        ТекстСхемы.Закрыть();

                       

                        // Создаем коннект

                        Попытка

                                   ОБ_АДОКонект.Open("Provider=Microsoft.Jet.OLEDB.4.0;Data Source="+Стр_КаталогДанных+";Extended Properties='text;FMT=Delimited;HDR=NO'");

                        Исключение

                                   Сообщить("Невозможно открыть соединение!"+ОписаниеОшибки(),СтатусСообщения.Важное);

                            Возврат Ложь;

                        КонецПопытки;

 

                        Стр_SQL = "S_elect * FROM "+Стр_таблицаШапки;

                       

                        Попытка

                                    ОБ_АДОРекордсетШапка=ОБ_АДОКонект.Execute(Стр_SQL);                

                        Исключение

                            Сообщить("Ошибка выполнения запроса """+Стр_SQL+"""!"+ОписаниеОшибки(),СтатусСообщения.Важное);

                                   Возврат Ложь;          

                        КонецПопытки;

 

                        Пока НЕ ОБ_АДОРекордсетШапка.EOF Цикл

                                  

                                   // Заказ

                                  

                                   Стр_НомерЗаказа     = ОБ_АДОРекордсетШапка.Fields("NumberNote").Value;

                                   Стр_КодКА= ОБ_АДОРекордсетШапка.Fields("StoreNum").Value;

                                  

                                   Д_ДатаЗаказа= ОБ_АДОРекордсетШапка.Fields("DataNote").Value;

                                   Д_ДатаДоставки= ОБ_АДОРекордсетШапка.Fields("DataDev").Value;

                                   Д_ДатаСбора= ОБ_АДОРекордсетШапка.Fields("DataDes").Value;

                                   Ч_КоличествоСтрок            = ОБ_АДОРекордсетШапка.Fields("CountLine").Value;

                               

                                   Сообщить("Заказ № "+Стр_НомерЗаказа+" от " +Д_ДатаЗаказа+ " Код контрагента: "+Стр_КодКА+" Дата доставки: "+Д_ДатаДоставки);



                                   // Обработка строк заказа

                                  Стр_SQL = "S_elect * FROM "+Стр_ТаблицаСтрок+" WHERE NumberNote='"+Стр_НомерЗаказа+"'";

                                   Попытка

                                               ОБ_АДОРекордсетСтроки=ОБ_АДОКонект.Execute(Стр_SQL);               

                                   Исключение

                                               Сообщить("Ошибка выполнения запроса """+Стр_SQL+"""!"+ОписаниеОшибки(),СтатусСообщения.Важное);

                                               Возврат Ложь;          

                                   КонецПопытки;

                                  

                                   Сч=0;

                                   Сообщить(" №           Артикул                     Количество");

                                   Пока НЕ ОБ_АДОРекордсетСтроки.EOF Цикл

                                               //Заполняем таб часть документа

                                               Сч=Сч+1;

                                              Стр_Артикул=СокрЛП(ОБ_АДОРекордсетСтроки.Fields("Articul").Value);

                                               Ч_Количество=ОБ_АДОРекордсетСтроки.Fields("Counts").Value;

                                               Сообщить(""+Сч+"    " +Стр_Артикул+ "               "+Ч_Количество);

                                               ОБ_АДОРекордсетСтроки.MoveNext();

                                   КонецЦикла;

                                   ОБ_АДОРекордсетШапка.MoveNext();

                        КонецЦикла;

            КонецЦикла;

    Возврат Истина;

КонецФункции

Автор Журавлев Михаил Викторович

Категория: JSON, XML, TXT, CSV, DBF

Как сохранить поле BLOB (image) как файл на диск?

Наиболее эффективно это можно сделать с помощью объектов OLE Automation , работа с которыми осуществляется при помощи:
sp_OACreate, sp_OAGetProperty, sp_OASetProperty, sp_OAMethod, sp_OAGetErrorInfo, sp_OADestroy (подробное описание есть в http://technet.microsoft.com/ru-ru/library/ms203721(sql.90).aspx).
Рабочий пример процедуры (была написана для сохранения zip-архивов, хранящихся в базе):

Код

CREATE PROCEDURE dbo.SaveRequestDataAsFile (
@FileName varchar(1024) --имя файла
,@FilePath varchar(1024) --путь файла
,@ReqID --некое условие на таблицу
)
AS
BEGIN

DECLARE
@Stream integer,
@Buffer varbinary(4096),
@Size integer,
@Pos integer,
@BufSize integer,
@FileNameLocal varchar(1024),
@HR integer

if RIGHT(@FilePath, 1)<>'&# 092;' begin set @FilePath=@FilePath+'&# 092;' end

set @FileNameLocal = @FilePath + @FileName

SET @BufSize = 4096

EXEC @HR = sp_OACreate 'ADODB.Stream',@Stream OUT
if @HR<>0
begin
--обработка ошибки создания объекта
EXEC [dbo].[sp_displayoaerrorinfo] @Stream ,@HR
end

EXEC @HR = sp_OASetProperty @Stream,'Type',1 -- binary
EXEC @HR = sp_OASetProperty @Stream,'Mode',3 -- write|read
EXEC @HR = sp_OAMethod @Stream,'Open'

S_elect
@Size = DATALENGTH(SrvRequests.RequestData)
FROM SrvRequests WHERE SrvRequests.RequestID = @ReqID

Set @Pos=0

WHILE @Pos < @Size BEGIN
SET @BufSize = CASE WHEN @Size - @Pos < 4096 THEN @Size - @Pos ELSE 4096 END

S_elect @Buffer = substring(SrvRequests.RequestData ,@Pos+1, @BufSize)
from SrvRequests where SrvRequests.RequestID = @ReqID

EXEC @HR = sp_OAMethod @Stream, 'Write', NULL, @Buffer

SET @Pos = @Pos + @BufSize
END

EXEC @HR = sp_OAMethod @Stream,'SaveToFile',null, @FileNameLocal,2
EXEC @HR = sp_OAMethod @Stream,'Close'
EXEC @HR = sp_OADestroy @Stream
END

Рекомендуется создать еще пару процедур для внятного описания ошибок в случае их возникновения

Код

CREATE PROCEDURE sp_hexadecimal
@binvalue varbinary(255),
@hexvalue varchar(255) OUTPUT
AS
DECLARE @charvalue varchar(255)
DECLARE @i int
DECLARE @length int
DECLARE @hexstring char(16)
S_elect @charvalue = '0x'
S_elect @i = 1
S_elect @length = DATALENGTH(@binvalue)
S_elect @hexstring = '0123456789abcdef'
WHILE (@i <= @length)
BEGIN
DECLARE @tempint int
DECLARE @firstint int
DECLARE @secondint int
S_elect @tempint = CONVERT(int, SUBSTRING(@binvalue,@i,1))
S_elect @firstint = FLOOR(@tempint/16)
S_elect @secondint = @tempint - (@firstint* 16)
S_elect @charvalue = @charvalue +
SUBSTRING(@hexstring, @firstint+1, 1) +
SUBSTRING(@hexstring, @secondint+1, 1)
S_elect @i = @i + 1
END
----------------------------------------------------------------------
CREATE PROCEDURE sp_displayoaerrorinfo
@object int,
@hresult int
AS
DECLARE @output varchar(255)
DECLARE @hrhex char(10)
DECLARE @hr int
DECLARE @source varchar(255)
DECLARE @description varchar(255)
PRINT 'OLE Automation Error Information'
EXEC sp_hexadecimal @hresult, @hrhex OUT
S_elect @output = ' HRESULT: ' + @hrhex
PRINT @output
EXEC @hr = sp_OAGetErrorInfo @object, @source OUT, @description OUT
IF @hr = 0
BEGIN
S_elect @output = ' Source: ' + @source
PRINT @output
S_elect @output = ' Description: ' + @description
PRINT @output
END
ELSE
BEGIN
PRINT ' sp_OAGetErrorInfo failed.'
RETURN
END

Категория: OLE, ActiveX