петров » Поиск

Результаты по ключевому слову: петров

Пример создания внешней печатной формы для управляемого приложения

Пример создания внешней печатной формы АКТа для Бухгалтерии 3.0

1. В конфигураторе 1C Предприятия 8 создаем внешнюю обработку (Файл->Новый->Внешняя обработка), задаем имя.

2. В модуле обработки пишем код. Постараюсь его максимально комментировать. Главное должно быть:

функция ПечатьВнешнейПечатнойФормы табличного документа - которая выведет данные в макет
функция Печать - вызывается из конфигурации! в нее передается массив печатаемых объектов
и функция СведенияОВнешнейОбработке(). Она необходима для регистрации печатной формы в справочнике ДополнительныеОтчетыИОбработки, в ней собирается структура с данными для подключения формы. Эта функция, а также ряд сопутствующих ей, практически одинаковы для всех печатных форм, поэтому их можно просто копировать в новую печатную форму ничего не меняя.

Код 1C v 8.3

 // Функция формирует табличный документ с Внешней печатной формой

//

// Возвращаемое значение:

//  Табличный документ - печатная форма акта

Функция ПечатьВнешнейПечатнойФормы(МассивОбъектов, ОбъектыПечати, Подписант) Экспорт

	ТабДок = новый ТабличныйДокумент;

	

	Макет = ПолучитьМакет("Макет");

	

	ОбластьШапки   = Макет.ПолучитьОбласть("Шапка");

	ОбластьДанные  = Макет.ПолучитьОбласть("Данные");

	ОбластьПодвал  = Макет.ПолучитьОбласть("Подвал");

	

	Запрос = новый запрос;

	Запрос.УстановитьПараметр("МассивОбъектов",МассивОбъектов);

	Запрос.Текст = "ВЫБРАТЬ

	|	РеализацияТоваровУслугТовары.Номенклатура,

	|	РеализацияТоваровУслугТовары.Сумма,

	|	РеализацияТоваровУслугТовары.Количество,

	|	РеализацияТоваровУслугТовары.Цена,

	|	РеализацияТоваровУслугТовары.Ссылка КАК Ссылка

	|ИЗ

	|	Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары

	|ГДЕ

	|	РеализацияТоваровУслугТовары.Ссылка В(&МассивОбъектов)

	|

	|ОБЪЕДИНИТЬ ВСЕ

	|

	|ВЫБРАТЬ

	|	РеализацияТоваровУслугУслуги.Номенклатура,

	|	РеализацияТоваровУслугУслуги.Сумма,

	|	РеализацияТоваровУслугУслуги.Количество,

	|	РеализацияТоваровУслугУслуги.Цена,

	|	РеализацияТоваровУслугУслуги.Ссылка

	|ИЗ

	|	Документ.РеализацияТоваровУслуг.Услуги КАК РеализацияТоваровУслугУслуги

	|ГДЕ

	|	РеализацияТоваровУслугУслуги.Ссылка В(&МассивОбъектов)  	

	|

	|УПОРЯДОЧИТЬ ПО

	|	Ссылка";

	

	ОбщаяВыборка = Запрос.Выполнить().Выгрузить();

	

	Для Каждого СсылкаНаОбъект из МассивОбъектов Цикл

		

		ОбластьШапки.Параметры.ТекстЗаголовка = "Акт №  "+СсылкаНаОбъект.Номер;

		ОбластьШапки.Параметры.Организация = СсылкаНаОбъект.Организация;

		

		ТабДок.Вывести(ОбластьШапки);

		

		Отбор = Новый Структура;

		Отбор.Вставить("Ссылка",СсылкаНаОбъект);

		

		Выборка = ОбщаяВыборка.НайтиСтроки(Отбор);

		

		ИтогоСумма      = 0;

		ИтогоКоличество = 0;

		

		Для Каждого Стр из Выборка Цикл

			ЗаполнитьЗначенияСвойств(ОбластьДанные.Параметры,Стр);

			

			ИтогоСумма = ИтогоСумма + Стр.Сумма;

			ИтогоКоличество = ИтогоКоличество + Стр.Количество;

			

			ТабДок.Вывести(ОбластьДанные);

		КонецЦикла;

		

		ОбластьПодвал.Параметры.ИтогоСумма      = ИтогоСумма;

		

		ОбластьПодвал.Параметры.Подписант      = Подписант;





		ТабДок.Вывести(ОбластьПодвал);

		

		ТабДок.ВывестиГоризонтальныйРазделительСтраниц();

	КонецЦикла;

	

	Возврат ТабДок;

КонецФункции



// Экспортная процедура печати, вызываемая из основной программы

//

// Параметры:

// ВХОДЯЩИЕ:

//  МассивОбъектовНазначения - Массив - список объектов ссылочного типа для печати документа

//                 Как правило, содержит один элемент с ссылкой на вызвавший форму объект (документ, справочник)

//

// ИСХОДЯЩИЕ:

//  КоллекцияПечатныхФорм - ТаблицаЗначений - таблица сформированных табличных документов.

//                 Как правило, содержит одну строку с именем текущей печатной формы

//  ОбъектыПечати - СписокЗначений - список объектов печати. 

//  ПараметрыВывода - Структура - Параметры сформированных табличных документов. Содержит поля:

//  						ДоступнаПечатьПоКомплектно - булево - по умолчанию Ложь

//							ПолучательЭлектронногоПисьма

//							ОтправительЭлектронногоПисьма

//

Процедура Печать(МассивОбъектовНазначения, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт

	

	Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "АКТПечатьВнешняя") Тогда 

		ТабличныйДокумент = ПечатьВнешнейПечатнойФормы(МассивОбъектовНазначения, ОбъектыПечати, "");

		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "АКТПечатьВнешняя", "АКТ (внешний)", ТабличныйДокумент);

		

	ИначеЕсли УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "АКТПечатьВнешняяИван") Тогда 

		ТабличныйДокумент = ПечатьВнешнейПечатнойФормы(МассивОбъектовНазначения, ОбъектыПечати, "Иванов А.Ю.");

		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "АКТПечатьВнешняяИван", "АКТ (внешний) Иванов", ТабличныйДокумент);  		

		

	ИначеЕсли УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "АКТПечатьВнешняяПетр") Тогда 

		ТабличныйДокумент = ПечатьВнешнейПечатнойФормы(МассивОбъектовНазначения, ОбъектыПечати, "Петров В.С.");

		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "АКТПечатьВнешняяПетр", "АКТ (внешний) Петров", ТабличныйДокумент);

	КонецЕсли;





КонецПроцедуры





#Область СведенияОВнешнейОбработке

// Сервисная экспортная функция. Вызывается в основной программе при регистрации обработки в информационной базе

// Возвращает структуру с параметрами регистрации

//

// Возвращаемое значение:

//		Структура с полями:

//			Вид - строка, вид обработки, один из возможных: "ДополнительнаяОбработка", "ДополнительныйОтчет", 

//					"ЗаполнениеОбъекта", "Отчет", "ПечатнаяФорма", "СозданиеСвязанныхОбъектов"

//			Назначение - Массив строк имен объектов метаданных в формате: 

//					<ИмяКлассаОбъектаМетаданного>.[ * | <ИмяОбъектаМетаданных>]. 

//					Например, "Документ.СчетЗаказ" или "Справочник.*". Параметр имеет смысл только для назначаемых обработок, для глобальных может не задаваться.

//			Наименование - строка - Наименование обработки, которым будет заполнено наименование элемента справочника по умолчанию.

//			Информация  - строка - Краткая информация или описание по обработке.

//			Версия - строка - Версия обработки в формате “<старший номер>.<младший номер>” используется при загрузке обработок в информационную базу.

//			БезопасныйРежим - булево - Принимает значение Истина или Ложь, в зависимости от того, требуется ли устанавливать или отключать безопасный режим 

//							исполнения обработок. Если истина, обработка будет запущена в безопасном режиме. 

//

Функция СведенияОВнешнейОбработке() Экспорт

	//Инициализируем структуру с параметрами регистрации    	

	ПараметрыРегистрации = Новый Структура;

	// Первый параметр, который мы должны указать - это какой вид обработки системе должна зарегистрировать.

	// Допустимые типы: ДополнительнаяОбработка, ДополнительныйОтчет, ЗаполнениеОбъекта, Отчет, ПечатнаяФорма, СозданиеСвязанныхОбъектов

	ПараметрыРегистрации.Вставить("Вид", "ПечатнаяФорма"); //может быть - ПечатнаяФорма, ЗаполнениеОбъекта, ДополнительныйОтчет, СозданиеСвязанныхОбъектов...

	

	МассивНазначений = Новый Массив;

	// Теперь нам необходимо передать в виде массива имен, к чему будет подключена наша ВПФ

	// Имейте ввиду, что можно задать имя в таком виде: Документ.* - в этом случае обработка будет подключена ко всем документам в системе,

	// которые поддерживают механизм ВПФ

	МассивНазначений.Добавить("Документ.РеализацияТоваровУслуг"); //Указываем документ к которому делаем внешнюю печ. форму   		

	ПараметрыРегистрации.Вставить("Назначение", МассивНазначений);

	

	ПараметрыРегистрации.Вставить("Наименование", "АКТ (Внешний)"); //имя под которым обработка будет зарегестрирована в справочнике внешних обработок

	ПараметрыРегистрации.Вставить("БезопасныйРежим", ЛОЖЬ);  // Зададим право обработке на использование безопасного режима. Более подробно можно узнать в справке к платформе (метод УстановитьБезопасныйРежим)

	ПараметрыРегистрации.Вставить("Версия", "1.0");   // эти два параметра играют больше информационную роль,

	ПараметрыРегистрации.Вставить("Информация", "Дополнительная печатная форма"); // т.е. это то, что будет видеть пользователь в информации к обработке

	

	// Создадим таблицу команд (подробнее смотрим ниже)

	ТаблицаКоманд = ПолучитьТаблицуКоманд();

	ДобавитьКоманду(ТаблицаКоманд, "Внешний: АКТ", "АКТПечатьВнешняя", "ВызовСерверногоМетода", Истина, "ПечатьMXL");

	ДобавитьКоманду(ТаблицаКоманд, "Внешний: АКТ (Иванов)", "АКТПечатьВнешняяИван", "ВызовСерверногоМетода", Истина, "ПечатьMXL");

	ДобавитьКоманду(ТаблицаКоманд, "Внешний: АКТ (Петров)", "АКТПечатьВнешняяПетр", "ВызовСерверногоМетода", Истина, "ПечатьMXL");

	

	ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);

	

	Возврат ПараметрыРегистрации; 	

КонецФункции

#КонецОбласти





#Область Вспомогательное

// ВСПОМОГАТЕЛЬНЫЕ ПРОЦЕДУРЫ И ФУНКЦИИ РЕГИСТРАЦИИ ОБРАБОТКИ





// Формирует структуру с параметрами регистрации регистрации обработки в информационной базе

//

// Параметры:

//	ОбъектыНазначенияФормы - Массив - Массив строк имен объектов метаданных в формате: 

//					<ИмяКлассаОбъектаМетаданного>.[ * | <ИмяОбъектаМетаданных>]. 

//					или строка с именем объекта метаданных 

//	НаименованиеОбработки - строка - Наименование обработки, которым будет заполнено наименование элемента справочника по умолчанию.

//							Необязательно, по умолчанию синоним или представление объекта

//	Информация  - строка - Краткая информация или описание обработки.

//							Необязательно, по умолчанию комментарий объекта

//	Версия - строка - Версия обработки в формате “<старший номер>.<младший номер>” используется при загрузке обработок в информационную базу.

//

//

// Возвращаемое значение:

//		Структура

//

Функция ПолучитьПараметрыРегистрации(ОбъектыНазначенияФормы = Неопределено, НаименованиеОбработки = "", Информация = "", Версия = "1.0")





	Если ТипЗнч(ОбъектыНазначенияФормы) = Тип("Строка") Тогда

		ОбъектНазначенияФормы = ОбъектыНазначенияФормы;

		ОбъектыНазначенияФормы = Новый Массив;

		ОбъектыНазначенияФормы.Добавить(ОбъектНазначенияФормы);

	КонецЕсли; 

	

	ПараметрыРегистрации = Новый Структура;

	ПараметрыРегистрации.Вставить("Вид", "ПечатнаяФорма");

	ПараметрыРегистрации.Вставить("БезопасныйРежим", Истина);

	ПараметрыРегистрации.Вставить("Назначение", ОбъектыНазначенияФормы);

	

	Если Не ЗначениеЗаполнено(НаименованиеОбработки) Тогда

		НаименованиеОбработки = ЭтотОбъект.Метаданные().Представление();

	КонецЕсли; 

	ПараметрыРегистрации.Вставить("Наименование", НаименованиеОбработки);

	

	Если Не ЗначениеЗаполнено(Информация) Тогда

		Информация = ЭтотОбъект.Метаданные().Комментарий;

	КонецЕсли; 

	ПараметрыРегистрации.Вставить("Информация", Информация);

	

	ПараметрыРегистрации.Вставить("Версия", Версия);





	Возврат ПараметрыРегистрации;





КонецФункции





// Формирует таблицу значений с командами печати

//	

// Возвращаемое значение:

//		ТаблицаЗначений

//

Функция ПолучитьТаблицуКоманд()





	Команды = Новый ТаблицаЗначений;

	

	//Представление команды в пользовательском интерфейсе

	Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));

	

	//Уникальный идентификатор команды или имя макета печати

	Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));

	

	//Способ вызова команды: "ОткрытиеФормы", "ВызовКлиентскогоМетода", "ВызовСерверногоМетода"

	// "ОткрытиеФормы" - применяется только для отчетов и дополнительных отчетов

	// "ВызовКлиентскогоМетода" - вызов процедуры Печать(), определённой в модуле формы обработки

	// "ВызовСерверногоМетода" - вызов процедуры Печать(), определённой в модуле объекта обработки

	Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));

	

	//Показывать оповещение.

	//Если Истина, требуется показать оповещение при начале и при завершении работы обработки. 

	//Имеет смысл только при запуске обработки без открытия формы

	Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));

	

	//Дополнительный модификатор команды. 

	//Используется для дополнительных обработок печатных форм на основе табличных макетов.

	//Для таких команд должен содержать строку ПечатьMXL

	Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));





	Возврат Команды; 

КонецФункции





// Вспомогательная процедура.

//

Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование = "ВызовСерверногоМетода", ПоказыватьОповещение = Ложь, Модификатор = "ПечатьMXL")

	НоваяКоманда = ТаблицаКоманд.Добавить();

	НоваяКоманда.Представление = Представление;

	НоваяКоманда.Идентификатор = Идентификатор;

	НоваяКоманда.Использование = Использование;

	НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;

	НоваяКоманда.Модификатор = Модификатор;      

КонецПроцедуры



#КонецОбласти

3. Добавляем макет вывода печатной формы:

4. Сохраняем и добавляем в конфигурацию:

Подключается через Администрирование - Печатные формы, отчеты и обработки:

Создаете новую обработку, записывайте и при открытии документа Реализация, нажав на Печать - появляются доступные печатные формы с разными подписывающими.

Скачать Шаблон внешней печатной формы для управляемого приложения

Категория: Внешние печатные формы, отчеты и обработк�…

Удаление из строки всех лишних данных Категория: Регулярные выражения

Как получить Имя Пользователя? Категория: Пользователь, роль доступа, интерфейс

Получить запросом контактную информацию одной строкой по Физ. лицу

Для тех, кто мучается с получением сведений из регистра сведений КонтактнаяИнформация в стандартных конфигурациях.

Код 1C v 8.х

   //Нужно запросом получить контактные данные(ФИО, Адрес, Телефон) :

// ФизЛицо			Адрес								Телефон

// Иванов Петр Сергеевич	140943, Московская обл, Дзержинский г, Угрешская ул, дом № 3, кв.21

// Иванова Оксана Александровна	119672, Москва г, Краснобогатырская ул, дом № 2, корпус 4, кв.15		(499) 730-18-02

// Петрова Тамара Алексеевна	141257, Московская обл, Долгопрудный г, Молодежная ул, дом № 7, кв.3	

// Сидорова Юлия Васильевна	107126, Москва г, Академика Анохина ул, дом № 12, кв.54			(495) 963-08-01



Запрос=Новый Запрос;

Запрос.Текст="

|ВЫБРАТЬ

|	ВЗАдрес.Ссылка КАК ФизЛицо,

|	ВЗАдрес.Адрес,

|	ВЗТелефон.Телефон

|ИЗ

|	(ВЫБРАТЬ

|		ФизическиеЛица.Ссылка КАК Ссылка,

|		КонтактнаяИнформация.Представление КАК Адрес

|	ИЗ

|		Справочник.ФизическиеЛица КАК ФизическиеЛица

|			ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КонтактнаяИнформация КАК КонтактнаяИнформация

|			ПО ФизическиеЛица.Ссылка = КонтактнаяИнформация.Объект

|	ГДЕ

|		КонтактнаяИнформация.Вид = &АдрПоПрописке

|		И КонтактнаяИнформация.Тип = &Адрес) КАК ВЗАдрес

|		ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ

|			ФизическиеЛица.Ссылка КАК Ссылка,

|			КонтактнаяИнформация.Представление КАК Телефон

|		ИЗ

|			Справочник.ФизическиеЛица КАК ФизическиеЛица

|				ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КонтактнаяИнформация КАК КонтактнаяИнформация

|				ПО ФизическиеЛица.Ссылка = КонтактнаяИнформация.Объект

|		ГДЕ

|			КонтактнаяИнформация.Вид = &ВидТелеф

|			И КонтактнаяИнформация.Тип = &Телефон) КАК ВЗТелефон

|		ПО ВЗАдрес.Ссылка = ВЗТелефон.Ссылка

|

|УПОРЯДОЧИТЬ ПО

|	ФизЛицо

|АВТОУПОРЯДОЧИВАНИЕ

|";

Запрос.УстановитьПараметр("Адрес",Перечисления.ТипыКонтактнойИнформации.Адрес);

Запрос.УстановитьПараметр("АдрПоПрописке",Справочники.ВидыКонтактнойИнформации.ЮрАдресФизЛица);

Запрос.УстановитьПараметр("ВидТелеф",Справочники.ВидыКонтактнойИнформации.ТелефонФизЛица);

Запрос.УстановитьПараметр("Телефон",Перечисления.ТипыКонтактнойИнформации.Телефон);

Результат = Запрос.Выполнить();

Результат = Результат.Выбрать();

Пока Результат.Следующий() Цикл

	// обработка

КонецЦикла;

Категория: Запросы

Заполним диаграмму Ганта данными

Код 1C v 8.х

 ДГ = ЭлементыФормы.ДГ; 



// Установить заголовок диаграммы. 

ДГ.ОбластьЗаголовка.Текст = "График дежурств"; 



// Интервал будем определять самостоятельно. 

ДГ.АвтоОпределениеПолногоИнтервала = Ложь; 



// Установить интервал. 

ДГ.УстановитьПолныйИнтервал(НачалоМесяца(ТекущаяДата()), КонецМесяца(ТекущаяДата())); 



// В диаграмме будет две точки - сотрудники Петров и Сидоров... 

ТочкаП = ДГ.УстановитьТочку("Петров"); 

ТочкаС = ДГ.УстановитьТочку("Сидоров"); 



// и две серии - дежурство на вахте и дежурство в центральном офисе. 

СерияНаВахте = ДГ.УстановитьСерию("На вахте"); 

СерияВЦентре = ДГ.УстановитьСерию("В центральном офисе"); 



// Задать цвета серий, отличные от цвета по умолчанию. 

СерияНаВахте.Цвет = WebЦвета.Синий; 

СерияВЦентре.Цвет = WebЦвета.СветлоЖелтый; 

ПервыйДень = НачалоМесяца(ТекущаяДата()); 



// Получить значение диаграммы - дежурство Петрова на вахте. 

Значение = ДГ.ПолучитьЗначение(ТочкаП, СерияНаВахте); 



// В значении определить новый интервал. 

Интервал = Значение.Добавить(); 

Интервал.Текст = "Работает на вахте"; 



// Определить границы интервала. 

Интервал.Начало = ПервыйДень; 

Интервал.Конец = ПервыйДень + 10 * 24 * 60 * 60; 



// Получить значение диаграммы - дежурство Петрова в центральном офисе. 

Значение = ДГ.ПолучитьЗначение(ТочкаП, СерияВЦентре); 

Интервал = Значение.Добавить(); 

Интервал.Текст = "Работает в центральном офисе"; 

Интервал.Начало = ПервыйДень + 14 * 24 * 60 * 60; 

Интервал.Конец = ПервыйДень + 24 * 24 * 60 * 60; 



// Получить значение диаграммы - дежурство Сидорова на вахте. 

Значение = ДГ.ПолучитьЗначение(ТочкаС, СерияНаВахте); 

Интервал = Значение.Добавить(); 

Интервал.Текст = "Работает на вахте"; 

Интервал.Начало = ПервыйДень + 5 * 24 * 60 * 60; 

Интервал.Конец = ПервыйДень + 15 * 24 * 60 * 60; 



// Получить значение диаграммы - дежурство Сидорова в центральном офисе. 

Значение = ДГ.ПолучитьЗначение(ТочкаС, СерияВЦентре); 

Интервал = Значение.Добавить(); 

Интервал.Текст = "Работает в центральном офисе"; 

Интервал.Начало = ПервыйДень + 21 * 24 * 60 * 60; 

Интервал.Конец = ПервыйДень + 25 * 24 * 60 * 60;

Категория: Диаграмма

Пример загрузки данных из Текстового файла, документа

Файл для загрузки содержит данные вида(КодФизЛица, ФизЛицо, Сумма):
000000513~Петров Юрий Викторович~150
000000184~Иванов Александр Юрьевич~50

Код 1C v 8.х

 //Выбор файла

Режим = РежимДиалогаВыбораФайла.Открытие; 

ДиалогОткрытияФайла = Новый ДиалогВыбораФайла(Режим); 

ДиалогОткрытияФайла.ПолноеИмяФайла = ""; 

Фильтр = "Текст(*.txt)|*.txt"; 

ДиалогОткрытияФайла.Фильтр = Фильтр; 

ДиалогОткрытияФайла.МножественныйВыбор = Ложь; 

ДиалогОткрытияФайла.Заголовок = "Выберите файл для загрузки"; 

Если ДиалогОткрытияФайла.Выбрать() Тогда 

	ПутьКФайлу = ДиалогОткрытияФайла.ПолноеИмяФайла; 

КонецЕсли;	

//Выбор вида удержания пользователем

ВидУдерж=Неопределено;

МассивТипов = Новый Массив; 

МассивТипов.Добавить(Тип("ПланВидовРасчетаСсылка.УдержанияОрганизаций")); 

ОписаниеВозможныхТипов = Новый ОписаниеТипов(МассивТипов); 

Если ВвестиЗначение(ВидУдерж,"Выберите вид удержания", ОписаниеВозможныхТипов) Тогда

	Если Удержания.Количество()>0 тогда

		Предупреждение("Внимание! В таблице уже есть данные, новые данные Добавлены к существующим данным!");

	КонецЕсли;

	текдок=Новый ТекстовыйДокумент;

	текдок.Прочитать(ПутьКФайлу);

	Для Ном=1 по текдок.КоличествоСтрок() цикл

		Стр = текдок.ПолучитьСтроку(Ном);

		//Разложим строку в массив данных

		СтрМ=РазложитьСтрокуВМассивПодстрок(стр,"~");

		//Добавляем новую строку

		НовСтр=Удержания.Добавить();

		//Ищем Физика

		Физик = Справочники.ФизическиеЛица.НайтиПоКоду(СтрМ[0]);

		Если СокрЛП(Физик.Наименование) = СокрЛП(СтрМ[1]) тогда                                       

			НовСтр.Физлицо = Физик;

		Иначе 

			Сообщить("В справочнике Физ. Лиц не найден "+СтрМ[1],СтатусСообщения.ОченьВажное);

		КонецЕсли;

		НовСтр.ВидРасчета=ВидУдерж;

		НовСтр.ДатаНачала=РабочаяДата;

		НовСтр.ДатаОкончания=РабочаяДата;

		НовСтр.Показатель1=СтрМ[2];

		НовСтр.Результат=СтрМ[2];

	КонецЦикла;	

КонецЕсли;

Категория: Текстовый документ

Cклонения по падежам

Код 1C v 8.2 УП

 &НаКлиенте

Процедура Команда1(Команда)

  ФИО = "Иванов Иван Иванович";

  Падеж = 2;

  Пол = 1;

  Результат = СклонениеФИО(ФИО, Падеж, пол);

  Сообщить(Результат); 

КонецПроцедуры



&НаСервере

Функция СклонениеФИО(ФИО, Падеж, пол) 

  Результат = "";

  ПутьКФайлу="C:\NAMEDECL.DLL";

  NameDecl = "Склонение";

  Попытка

    Если ПодключитьВнешнююКомпоненту(ПутьКФайлу,NameDecl)ТОгда

      ФункцСкл = Новый ("AddIn.Склонение.NameDeclension"); 

      Результат = ФункцСкл.Просклонять(ФИО,Падеж, пол);

    КонецЕсли; 

  Исключение

    Сообщить("Не удалось загрузить внешнюю компаненту по причине: "+ОписаниеОшибки());

  КонецПопытки; 

  Возврат Результат; 

КонецФункции

Код для 8-й версии, но работает и в 7-й

Код 1C v 8.х

 // (c) Jurer Production Begin ( Start )

// http://superjur.narod.ru

// 

// Удаление этих строк незнаконно!

// Гарантия 91 года и 1 месяц!!!

// Послегарантийное обслуживание - бесплатно!!!

// Круглосуточная поддержка - все 48 часов в бою!

// Ссылка на источник обязательна!

// Эти программы защищены законом об авторских правах. Запрещается перепродажа данной программы.

// ПРОВЕРЕНО! ВИРУСОВ НЕТ!!! АНТИВИРУСОВ ТОЖЕ!!!

// Смотри Милячуша в творительном !!

// скупой слепой тупой - пропой!!

// !№№!

// !55! ПадежЫ - для оглы и кызы

// !54! 

// !53! Очередное сокращение кода

// !51! Прегромадное спасибо Олегу Дубровскому за оказанную моральную, информационную и материальную поддержку сего проекта.

//      Сергею Толкачёву за напоминание о том, что в русском языке всегда есть место исключениям!

// !50! П:Ответственный за электрохозяйство  Ф:Ацута Груша  

// !48! исправлена ошибка при склонении фамилий (спасибо, Mario).

// !47! исправлена ошибка при склонении профессий ( спасибо, Павел Ковалев).

// !46! оптимизация + четвертый параметр задает, что вернуть - фамилия, имя или отчество или всё сразу в нужном падеже

// !42! Осел + Соловей + Воробей + Немец + Кормилец + Силиец

// !41! отчества оканчивающиеся на "ы" считаются женскими ?

// Функция для склонения одного слова!!!

// z1 - само слово

// z2 - номер падежа

// z3 - пол

// z4 - 1-склонять как фамилию, 2-имя, 3-отчество

Функция ПадежС(z1,Знач z2=2,Знач z3="*",z4=0) Экспорт

  z5=Найти(z1,"-");

  z6=?(z5=0,"","-"+ПадежС(Сред(z1,z5+1,СтрДлина(z1)-z5+1),z2,z3,z4));

  z1=НРег(?(z5=0,z1,Лев(z1,z5-1)));

  z7=Прав(z1,3);z8=Прав(z7,2);z9=Прав(z8,1);

  z5=СтрДлина(z1);

  za=Найти("ая ия ел ок яц ий па да ца ша ба та га ка",z8);

  zb=Найти("аеёийоуэюяжнгхкчшщ",Лев(z7,1));

  zc=Макс(z2,-z2);

  zd=?(za=4,5,Найти("айяь",z9));

  zd=?((zc=1)или(z9=".")или((z4=2)и(Найти("оиеу"+?(z3="ч","","бвгджзклмнпрстфхцчшщъ"),z9)>0))или((z4=1)и(Найти("мия мяэ лия кия жая лея",z7)>0)),9,?((zd=4)и(z3="ч"),2,?(z4=1,?(Найти("оеиую",z9)+Найти("их ых аа еа ёа иа оа уа ыа эа юа яа",z8)>0,9,?(z3<>"ч",?(za=1,7,?(z9="а",?(za>18,1,6),9)),?(((Найти("ой ый",z8)>0)и(z5>4)и(Прав(z1,4)<>"опой"))или((zb>10)и(za=16)),8,zd))),zd)));

  ze=Найти("лец вей бей дец пец мец нец рец вец аец иец ыец бер",z7);

  zf=?((zd=8)и(zc<>5),?((zb>15)или(Найти("жий ний",z7)>0),"е","о"),?(z1="лев","ьв",?((Найти("аеёийоуэюя",Сред(z1,z5-3 ,1))=0)и((zb>11)или(zb=0))и(ze<>45),"",?(za=7,"л",?(za=10,"к",?(za=13,"йц",?(ze=0,"",?(ze<12,"ь"+?(ze=1,"ц",""),?(ze<37,"ц",?(ze<49,"йц","р"))))))))));

  zf=?((zd=9)или((z4=3)и(z3="ы")),z1,Лев(z1,z5-?((zd>6)или(zf<>""),2,?(zd>0,1,0)))+zf+СокрП(Сред("а у а "+Сред("оыые",Найти("внч",z9)+1,1)+"ме "+?(Найти("гжкхш",Лев(z8,1))>0,"и","ы")+" е у ойе я ю я ем"+?(za=16,"и","е")+" и е ю ейе и и ь ьюи и и ю ейи ойойу ойойойойуюойойгомуго"+?((zf="е")или(za=16)или((zb>12)и(zb<16)),"и","ы")+"мм",10*zd+2*zc-3,2)));

Возврат ?(""=z1,"",?(z4>0,ВРег(Лев(zf,1))+?((z2<0)и(z4>1),".",Сред(zf,2)),zf)+z6);

КонецФункции

//_____________________________________________________________________________

// z1 - фамилия имя отчество например Железняков Юрий Юрьевич

// z2 - Падеж ( по  умолчанию = 2 - родительный)

// 2 - родительный  ( нет кого?    ) Железнякова Юрия Юрьевича     

// 3 - дательный    ( кому?        ) Железнякову Юрию Юрьевичу 

// 4 - винительный  ( вижу кого?   ) Железнякова Юрия Юрьевича  

// 5 - творительный ( кем?         ) Железняковым Юрием Юрьевичем    

// 6 - предложный   ( о ком?       ) Железнякове Юрии Юрьевиче 

// Если задать Z2 меньше 0, то на выходе получим от -1=Железняков Ю. Ю. до -6=Железнякове Ю. Ю.

// z3 - параметр Пол может не указываться, но при наличии фамилий с 

// инициалами точное определение пола невозможно, поэтому предлагается задавать пол этим

// параметром  1 - мужской 2 - женский  

// ДЛЯ СКЛОНЕНИЯ ПРОФЕССИЙ ИСПОЛЬЗУЙТЕ ФУНКЦИЮ ПАДЕЖП И БУДЕТ ВАМ СЧАСТЬЕ!

// ---------------------------------------------------------------------------------------

// Бибик Галушка Цой Николайчик Наталия Петровна Герценберг Кривошей Капица-Метелица

// Если Падеж(Фио ,1 ,3),       то на выходе получим Фамилия Имя Отчество и т.д.

// Если Падеж(Фио ,1 ,3,"1" ),  то                   Фамилия 

// Если Падеж(Фио ,1 ,3,"2" ),  то                   Имя 

// Если Падеж(Фио ,1 ,3,"3" ),  то                   Отчество 

// Если Падеж(Фио, 1 ,3,"12" ), то                   Фамилия Имя 

// Если Падеж(Фио, 1 ,3,"23" ), то                   Имя Отчество 

// Если Падеж(Фио,-1 ,3,"231" ),то                   И. О. Фамилия 

// Если Падеж(Фио,-1 ,3,"23" ), то                   И. О.  

// 10-11-2003 3-20



Функция Падежик(z1,z2=2,z3=3,Знач z4="123",z5=1) Экспорт

  Возврат?(z5<4,Падежик(СокрЛП(СтрЗаменить(Сред(z1,Найти(z1+" "," ")+1),".",". ")),z2,z3,СтрЗаменить(z4,z5,ПадежС(Лев(z1,Найти(z1+" "," ")-1),z2,Сред("ча"+НРег(Прав(СокрП(z1),1)),z3,1),z5)+" "),z5+1),z4);

КонецФункции//Падежик



Функция Падеж(z1,z2=2,z3=3,Знач z4="123") Экспорт

	z1=СокрП(z1);

	z5=Прав(z1,4);

  z6=Найти("оглы кызы",z5);

	Возврат Падежик(?(z6>0,Лев(z1,СтрДлина(z1)-5),z1),z2,z3,z4)+?(z6>0,z5,"");

КонецФункции//Падеж



Функция ПадежП(Знач z1,Знач z2,z3=0) Экспорт

  z1=СокрЛП(z1);z4=Найти(z1+" "," ")+1;z5=Лев(z1,z4-2);z6=Прав(z5,2);

  z7=?((Найти("ая ий ый",z6)>0)и(Найти("ющий нный",Сред(z1,z4-5,4))=0)и(z3=0),"1","*");

Возврат НРег(?((z6="ая")или(Прав(z6,1)="а"),ПадежС(z5,z2,z7,1)+" "+ПадежС(Сред(z1,z4),z2),ПадежС(z5,z2,"ч",1)+?((z6="ий")и(Найти(z1," ")=0),""," "+?(z7="1",ПадежП(Сред(z1,z4),z2,Число(z7)),Сред(z1,z4)))));

КонецФункции//ПадежП

// (c) Jurer Production End ( Finish )

Пример использования в ЗиК 7.7:

Код 1C v 7.x

  ПодписантРодитПад=Падеж(Константа.Руководитель.Получить(ДатаДок),-2); 

ПодпСтрока="Заместителя Генерального Директора "+СокрЛП(ПодписантРодитПад)+", действующего на основании доверенности "+ сокрлп(Константа.Доверенность);

Категория: Полезные, Универсальные Функции