получитьатрибут » Поиск

Результаты по ключевому слову: получитьатрибут

Скрипт автообновления типовых конфигураций

Батник на "языке 1С" для клиент серверных баз, скачивает с сайта ИТС нужное обновление, бекапит базу и обновляет. Подойдет как рабочая заготовка для собственных "обновляторов". В текущем виде все работает. Надо только занести свои переменные.

Код 1C v 8.3

 //     Путь к обновлениям
Перем мРасположениеОбновлений;


//Параметры для подключения к серверу обновления 1С
Перем мИтсЛогин;
Перем мИтсПароль;


//****
Перем home;
Перем DumpIB;


Перем ФайлСписокОбновленийZIP;
Перем ФайлСписокОбновленийXML;


Перем КодВозврата;


// Проверка существования файла или каталога.
//
// Параметр:
//  ПутьКФайлу   - Строка - путь к файлу или каталогу, существование которого
//                 нужно проверить.
//
// Возвращаемое значение:
//  Булево - признак существования файла или каталога.
//
Функция ФайлСуществует(Знач ПутьКФайлу) Экспорт
    
    Файл = Новый Файл(ПутьКФайлу);
    Возврат Файл.Существует();
    
КонецФункции 


Процедура УстановитьКонстанты()
    каталог_tmplts = "D:\tmplts";
     мИтсЛогин = "---";
    мИтсПароль = "---";
    
    //**Ниже можно не менять.
    мРасположениеОбновлений = каталог_tmplts + "\1c";
    home = каталог_tmplts + "\1Cupdate";
    DumpIB = home + "\DumpIB\";
    ФайлСписокОбновленийXML = home + "\v8cscdsc.xml";
    ФайлСписокОбновленийZIP = home + "\v8upd11.zip";
    
    Если НЕ ФайлСуществует(home) Тогда
        СоздатьКаталог(home); 
    КонецЕсли;
    
    Если НЕ ФайлСуществует(DumpIB) Тогда
        СоздатьКаталог(DumpIB); 
    КонецЕсли;
    
    Если НЕ ФайлСуществует(мРасположениеОбновлений) Тогда
        СоздатьКаталог(мРасположениеОбновлений); 
    КонецЕсли;


КонецПроцедуры


Функция ВернутьРелизИПлатформу(мИмяСервера,мИмяБазы,мВерсияПлатформы,мБазаЛогин,мБазаПароль)


   ПараметрыБазы = Неопределено;
 
   Попытка
        //Создаем COM-объект с идентификатором V82.COMConnector
        COMОбъект = Новый COMОбъект("V"+мВерсияПлатформы+".COMConnector");   //выйдет V82.COMConnector
   Исключение
        Сообщить("Не удалось создать COM-объект!");    
        Возврат ПараметрыБазы;
   КонецПопытки; 


    ПутьКБазе = "srvr="""+ СокрЛП(мИмяСервера) +""";" + "ref=""" + СокрЛП(мИмяБазы)  +""";";    


    СтрокаСоединения = ПутьКБазе + "Usr="""+ СокрЛП(мБазаЛогин) +""";" + "Pwd="""+ СокрЛП(мБазаПароль) + """;";    
 
     Попытка
        //Устанавливаем внешнее соединение с информационной базой через COM-соединение
        V82 = COMОбъект.Connect(СтрокаСоединения);
    Исключение
        Сообщить(СтрокаСоединения);
        Сообщить("Внешнее соединение не установлено!");    
        Возврат ПараметрыБазы;
    КонецПопытки;


     ПараметрыБазы = Новый Структура;
     ПараметрыБазы.Вставить("ТекущаяВерсия", v82.Метаданные.Версия);
     ПараметрыБазы.Вставить("ПутьКПлатформе",v82.КаталогПрограммы() + "1cv8.exe");


     Возврат ПараметрыБазы;
КонецФункции


Процедура УстановитьCOMСоединение(мИмяСервера,мИмяБазы,мВерсияПлатформы,мБазаЛогин,мБазаПароль) 
   Попытка
        //Создаем COM-объект с идентификатором V82.COMConnector
        COMОбъект = Новый COMОбъект("V"+мВерсияПлатформы+".COMConnector");   //выйдет V82.COMConnector
   Исключение
        Сообщить("Не удалось создать COM-объект!");    
        Возврат;
   КонецПопытки; 


    //Инициализируем строку подключения к информационной базе:    
 //   Если ФайловаяИБ Тогда
        //Файловый вариант 
   //     ПутьКБазе = "File="""+ СокрЛП(КаталогИБ) +""";";
//    Иначе
        //Серверных вариант    
        ПутьКБазе = "srvr="""+ СокрЛП(мИмяСервера) +""";"+
               "ref=""" + СокрЛП(мИмяБазы)  +""";";    
//    КонецЕсли;
                
    СтрокаСоединения = ПутьКБазе +
            "Usr="""+ СокрЛП(мБазаЛогин) +""";"+
            "Pwd="""+ СокрЛП(мБазаПароль) +""";";    
        Сообщить(СтрокаСоединения);         
    Попытка
        //Устанавливаем внешнее соединение с информационной базой через COM-соединение
        V82 = COMОбъект.Connect(СтрокаСоединения);
    Исключение
        Сообщить(СтрокаСоединения);
        Сообщить("Внешнее соединение не установлено!");    
        Возврат;
    КонецПопытки;
             
КонецПроцедуры


        
        
        
// Загрузка списка обновлений из файла XML
// Достаем из XML файла, наибольший номер возможного обновления
Функция ВыполнитьЗагрузкуСпискаОбновлений(ИмяФайлаЗагрузки,ТекущаяВерсияКонфигурации)
    
    СообщениеОбОшибке = "Ошибка при чтении файла списка обновлений.";
    
    Если НЕ ФайлСуществует(ИмяФайлаЗагрузки) Тогда
        Сообщить("Нету XML файла (списка обновлений)");
        Возврат Неопределено;
    КонецЕсли;
    
    ВерсияДляОбновления = Неопределено;
    Попытка
//        ТаблицаЗначений = Новый ТаблицаЗначений;        
//        ТаблицаЗначений.Колонки.Добавить("Конфигурация",          Тип("Строка"));
//        ТаблицаЗначений.Колонки.Добавить("Поставщик",             Тип("Строка"));
//        ТаблицаЗначений.Колонки.Добавить("Версия",                Тип("Строка"));
//        ТаблицаЗначений.Колонки.Добавить("ВерсияДляОбновления",   Тип("Строка"));
//        ТаблицаЗначений.Колонки.Добавить("ПутьКФайлуОбновления",  Тип("Строка"));
//        ТаблицаЗначений.Колонки.Добавить("РазмерФайлаОбновления", Тип("Число"));
        
        ЧтениеXML = Новый ЧтениеXML;
        ЧтениеXML.ОткрытьФайл(ИмяФайлаЗагрузки);
        ЧтениеXML.Прочитать(); // <?xml version="1.0" encoding="UTF-8" ?> 
        
        // Дата формирования файла.
        ЧтениеXML.Прочитать();
        ЧтениеXML.Прочитать();
        ДатаФормирования = ЧтениеXML.Значение;
        ЧтениеXML.Прочитать();
        // Читаем начало элемента Update или конец элемента UpdateList.
        Пока ЧтениеXML.Прочитать() Цикл
            
            Если ЧтениеXML.Имя = "v8u:updateList" Тогда
                Прервать;                    
            Иначе        
                
                Конфигурация = ЧтениеXML.ПолучитьАтрибут("configuration");
                
                Пока ЧтениеXML.Прочитать() Цикл
                    
                    Если ЧтениеXML.Имя = "v8u:update" Тогда
                        Прервать;                    
                    Иначе        
                        
                        Если ЧтениеXML.Имя = "v8u:vendor" Тогда
                            ЧтениеXML.Прочитать();
                            Поставщик = ЧтениеXML.Значение;                            
                        ИначеЕсли ЧтениеXML.Имя = "v8u:version" Тогда
                            ЧтениеXML.Прочитать();
                            Версия = ЧтениеXML.Значение;
                        ИначеЕсли ЧтениеXML.Имя = "v8u:file" Тогда
                            ЧтениеXML.Прочитать();
                            ПутьКФайлуОбновления = ЧтениеXML.Значение;
                        ИначеЕсли ЧтениеXML.Имя = "v8u:size" Тогда
                            ЧтениеXML.Прочитать();
                            РазмерФайлаОбновления = ЧтениеXML.Значение;
                        ИначеЕсли ЧтениеXML.Имя = "v8u:target" Тогда
                            ЧтениеXML.Прочитать();
                        //    НоваяСтрока = ТаблицаЗначений.Добавить();
                        //    НоваяСтрока.Конфигурация          = Конфигурация;
                        //    НоваяСтрока.Поставщик             = Поставщик;
                        //    НоваяСтрока.Версия                = Версия;
                        //    НоваяСтрока.ВерсияДляОбновления      = ЧтениеXML.Значение;
                        //    НоваяСтрока.ПутьКФайлуОбновления  = ПутьКФайлуОбновления;
                        //    НоваяСтрока.РазмерФайлаОбновления = РазмерФайлаОбновления;
                            Если ЧтениеXML.Значение = ТекущаяВерсияКонфигурации Тогда   //279 Новые в конце. на последнюю полученную и будем обновяться
                                ВерсияДляОбновления = Версия;
                            КонецЕсли;
                        КонецЕсли;
                        
                        ЧтениеXML.Прочитать();
                        
                    КонецЕсли;
                    
                КонецЦикла;
                
            КонецЕсли;
            
        КонецЦикла;
        
    Исключение
        Сообщить(СообщениеОбОшибке);
        ЧтениеXML.Закрыть();
        Возврат Неопределено;
        
    КонецПопытки;
    //Возврат ТаблицаЗначений;    
    ЧтениеXML.Закрыть();
    Возврат ВерсияДляОбновления;
    
КонецФункции // ВыполнитьЗагрузкуСпискаОбновлений()




//Входящие Сервер - База - ТипКонфигурации - ВерсияРелиза - ВерсияПлатформы-ИТС логин и пароль необязательно
Процедура ПроверитьОбновлениеКонфигурации(мИмяСервера,мИмяБазы,мТипКонфигурации,мВерсияРелиза,мВерсияПлатформы,мБазаЛогин,мБазаПароль)    
    Сообщить("----------------------------------------------------------------------");
    //удалить старые файлы
    УдалитьФайлы(ФайлСписокОбновленийXML);
    УдалитьФайлы(ФайлСписокОбновленийZIP);    


    // Качаем v8cscdsc.xml в виде v8upd11.zip    
    // Создание HTTP-соединения с сервером обновлений
    СерверОбновлений = Новый HTTPСоединение("downloads.1c.ru",,мИтсЛогин,мИтсПароль,);
    ЗапросКСерверуОбновлений = Новый HTTPЗапрос("/ipp/ITSREPV/V8Update/Configs/"+мТипКонфигурации+"/"+мВерсияРелиза+"/"+мВерсияПлатформы+"/v8upd11.zip");
    СерверОбновлений.Получить(ЗапросКСерверуОбновлений,ФайлСписокОбновленийZIP);


    // Распаковываем v8cscdsc.xml
    ФайлZip = Новый ЧтениеZipФайла(ФайлСписокОбновленийZIP); 
    ФайлZip.ИзвлечьВсе(home);
    ФайлZip.Закрыть();
    УдалитьФайлы(ФайлСписокОбновленийZIP);
    
    //+++++ Запрос версии конфигурации базы...
        ПараметрыComБазы = ВернутьРелизИПлатформу(мИмяСервера,мИмяБазы,мВерсияПлатформы,мБазаЛогин,мБазаПароль);
        
        Если ПараметрыComБазы = Неопределено Тогда 
            Возврат; 
        КонецЕсли;
        ВерсияДляОбновления = ВыполнитьЗагрузкуСпискаОбновлений(ФайлСписокОбновленийXML,ПараметрыComБазы.ТекущаяВерсия);
        ТребуетсяОбновление = Ложь;
        Если ВерсияДляОбновления = Неопределено Тогда 
            Сообщить(мИмяБазы + " ver: " +ПараметрыComБазы.ТекущаяВерсия+ " ОБНОВЛЕНИЕ НЕ ТРЕБУЕТСЯ");
            Возврат;
        КонецЕсли;
        Сообщить(мИмяБазы + " ver: " +ПараметрыComБазы.ТекущаяВерсия+ " update: " + ВерсияДляОбновления);
    //----- Запрос версии конфигурации базы...
    
    КомандаПакетногоАрхивирования = """" + ПараметрыComБазы.ПутьКПлатформе +""""+" CONFIG /S"+мИмяСервера+"\"+мИмяБазы+" /N"""+мБазаЛогин+""" /P"""+мБазаПароль+""" /DumpIB "+DumpIB + мИмяБазы + ".dt /OUT """+home+"\"+мИмяБазы+".log"" -NoTruncate";
    //NoTruncate - не очищать логи 
    //Сообщить(КомандаПакетногоАрхивирования);
    ЗапуститьПриложение(КомандаПакетногоАрхивирования,,Истина,КодВозврата);
    Если КодВозврата = 0  Тогда
        Сообщить("Резервная копия успешно создана.");
    Иначе
        Сообщить("Ошибка при создании резервной копии");
        Возврат;
    КонецЕсли;
    
    Версия_Для_Обновления = СтрЗаменить(ВерсияДляОбновления, ".", "_"); //в каталоге шаблонов через подчеркивание храняться


    //качаем новую версию, если уже не скачено
    Если НЕ ФайлСуществует(мРасположениеОбновлений +"\"+мТипКонфигурации+"\"+Версия_Для_Обновления+"\") Тогда
        //качаем новую
        // Создание HTTP-соединения с сервером обновлений
        Заголовки = Новый Соответствие();
        Заголовки.Вставить("User-Agent", "1C+Enterprise/8.2");     //без заголовка сайт не даст скачать.
        СерверОбновлений = Новый HTTPСоединение("downloads.v8.1c.ru",,мИтсЛогин,мИтсПароль,);
        СтрокаЗапросHTTP = "/tmplts/1c/"+мТипКонфигурации+"/"+ Версия_Для_Обновления +"/1cv8.zip";
        Сообщить(СтрокаЗапросHTTP);
        ЗапросКСерверуОбновлений = Новый HTTPЗапрос(СтрокаЗапросHTTP,Заголовки);
        СерверОбновлений.Получить(ЗапросКСерверуОбновлений, мРасположениеОбновлений+"\1cv8.zip");
        
        ФайлZip = Новый ЧтениеZipФайла(мРасположениеОбновлений+"\1cv8.zip"); 
        ФайлZip.ИзвлечьВсе(мРасположениеОбновлений+"\"+мТипКонфигурации+"\"+Версия_Для_Обновления);
        ФайлZip.Закрыть();
        
        УдалитьФайлы(мРасположениеОбновлений+"\1cv8.zip");
    КонецЕсли;
    //запускаем обновление                                                                                                                                                              
    КомандаПакетногоОбновления = """" + ПараметрыComБазы.ПутьКПлатформе +""""+" CONFIG /S"+мИмяСервера+"\"+мИмяБазы+" /N"""+мБазаЛогин+""" /P"""+мБазаПароль+""" /UpdateCfg "+мРасположениеОбновлений+"\"+мТипКонфигурации+"\"+Версия_Для_Обновления + "\1cv8.cfu /UpdateDBCfg /OUT """+home+"\"+мИмяБазы+".log"" -NoTruncate";
    //Сообщить(КомандаПакетногоОбновления);
    ЗапуститьПриложение(КомандаПакетногоОбновления,,Истина,КодВозврата);
    Если КодВозврата = 0 Тогда
        Сообщить("База Успешно обновлена");
    Иначе
        Сообщить("ОШИБКА ПРИ ОБНОВЛЕНИИ");
        Возврат;
    КонецЕсли;
    
    //Еще разок запрос версии
    //+++++ Запрос версии конфигурации базы...
        ПараметрыComБазы = ВернутьРелизИПлатформу(мИмяСервера,мИмяБазы,мВерсияПлатформы,мБазаЛогин,мБазаПароль);
        
        Если ПараметрыComБазы = Неопределено Тогда 
            Возврат; 
        КонецЕсли;
        ВерсияДляОбновления = ВыполнитьЗагрузкуСпискаОбновлений(ФайлСписокОбновленийXML,ПараметрыComБазы.ТекущаяВерсия);
        ТребуетсяОбновление = Ложь;
        Если ВерсияДляОбновления = Неопределено Тогда 
            Сообщить(мИмяБазы + " ver: " +ПараметрыComБазы.ТекущаяВерсия+ " ОБНОВЛЕНИЕ НЕ ТРЕБУЕТСЯ");
            Возврат;
        КонецЕсли;
        Сообщить(мИмяБазы + " ver: " +ПараметрыComБазы.ТекущаяВерсия+ " update: " + ВерсияДляОбновления);
    //----- Запрос версии конфигурации базы...


КонецПроцедуры
        
УстановитьКонстанты();
//ОСНОВНЫЕ


//ЗУП 2.5
ПроверитьОбновлениеКонфигурации("ka1sql1:1641","up_el","HRM","25","82","Администратор","Администратор");
ПроверитьОбновлениеКонфигурации("ka1sql1:1641","up_spb","HRM","25","82","Администратор","Администратор");

//БП 3.0
ПроверитьОбновлениеКонфигурации("ka1sql1:1741","bp_domx","Accounting","30","83","Администратор","Администратор");
ПроверитьОбновлениеКонфигурации("ka1sql1:1741","bp_el","Accounting","30","83","Администратор","Администратор");


//СВЕТЛАНЫ
//БП 3.0
ПроверитьОбновлениеКонфигурации("ka1sql1:1741","bp_ip","Accounting","30","83","Администратор","Администратор");
ПроверитьОбновлениеКонфигурации("ka1sql1:1741","bp_guild","Accounting","30","83","Администратор","Администратор");
ПроверитьОбновлениеКонфигурации("ka1sql1:1741","bp_lebedeva","Accounting","30","83","Администратор","Администратор");
//ПроверитьОбновлениеКонфигурации("ka1sql1:1741","bp_service","AccountingBase","30","83","Администратор","Администратор");
ПроверитьОбновлениеКонфигурации("ka1sql1:1741","bp_porsche","Accounting","30","83","Администратор","Администратор");


//ЗУП 2.5
ПроверитьОбновлениеКонфигурации("ka1sql1:1641","up_service","HRM","25","82","Администратор","Администратор");

Источник

Категория: Администрирование

Присваивание значений реквизитам по их идентификатору

Казалось бы, что может быть проще - пишем через точку идентификатор реквизита и присваиваем.
Что-то вроде вот этого:

Код 1C v 8.х

 СправочникОбъект.Наименование = "Новое наименование";

Но бывают случаи, когда идентификатор реквизита формируется динамически и какой именно реквизит сейчас надо обработать неизвестно. Что тогда делать?

В 1С 7.7 существовали такие методы объектов, как Справочник.УстановитьАтрибут() и Справочник.ПолучитьАтрибут(), которые позволяли установить значение атрибута объекта по его идентификатору.

А в 1С 8.1 таких методов нет! Что же делать?!
Можно, конечно, написать кучу условий, что-то типа:

Код 1C v 8.х

 Если ИмяРеквизита="Наименование" тогда
СправочникОбъект.Наименование = ЗначениеРеквизита;
ИначеЕсли ИмяРеквизита="Код" тогда
СправочникОбъект.Код = ЗначениеРеквизита;
ИначеЕсли
.....
КонецЕсли;

Выглядит совершенно прямолинейно, но работать будет. Вот только если реквизитов будет с полсотни - замучаетесь условия писать.
А на самом деле все просто. Можно использовать вот такую конструкцию:

Код 1C v 8.х

 СправочникОбъект[ИмяРеквизита] = ЗначениеРеквизита;

где : ИмяРеквизита - строка идентификатора реквизита справочника (например, "Наименование")
И вся наша куча условий сводится всего к одной строке кода....
Автор: Николай Николаев

Категория: Встроенные Функции

Перебор групп расчета

Код 1C v 7.x

 
Для Ном=1 По Метаданные.ГруппаРасчета() Цикл
 кфгГруппаРасч = Метаданные.ГруппаРасчета(Ном);
 //недоработка фирмы 1С. По имени группы расчета нельзя получить саму группу расчета как объект.
 //если помечтать, то можно было бы сделать вот так:
 // ГруппаРасч = ГруппаРасчета.ПолучитьАтрибут(кфгГруппаРасч.Идентификатор);
КонецЦикла;

Категория: Группы расчетов

Перебор всех видов расчета и видов расчета, входящих в группу

Код 1C v 7.x

 //   Перебор всех видов расчета
Для Ном=1 По Метаданные.ВидРасчета() Цикл
 кфгВР = Метаданные.ВидРасчета(Ном);
 ВР = ВидРасчета.ПолучитьАтрибут(кфгВР.Идентификатор);
КонецЦикла;

//   Перебор видов расчета, входящих в группу
Для Ном=1 По ГруппаРасчетов.ВсеНачисления.Количество() Цикл
 ВР = ГруппаРасчетов.ВсеНачисления.ПолучитьРасчет(Ном);
 Сообщить(ВР.Код);
КонецЦикла;

Категория: Виды расчетов

Как указать ссылку на вид расчета

Код 1C v 7.x

 ВР = ВидРасчета.НаРуки;
ВР = ВидРасчета.Премия;

ВР = ВидРасчета.ПолучитьАтрибут("НаРуки");

Категория: Виды расчетов

Выгрузка / Загрузка данных посредством XML файлов?

В основе работы с XML-файлами лежит технология доступа SAX, которая осуществляет считывание по одному тегу. Для этого существует два типа данных – ЗаписьXML и ЧтениеXML.
Запись данных справочника в XML-файл:

Код 1C v 8.х

 Запись = Новый ЗаписьXML;
Запись.ОткрытьФайл(ПутьКФайлу);
Запись.ЗаписатьОбъявлениеXML();
// формируем корневой элемент
Запись.ЗаписатьНачалоЭлемента("Клиенты");
Выборка = Справочники.Клиенты.Выбрать();
Пока Выборка.Следующий() Цикл
	// для каждого клиента формируем свой элемент
	Запись.ЗаписатьНачалоЭлемента("Клиент");
	// запишем код клиента в атрибут тега
	Запись.ЗаписатьАтрибут("Код", Строка(Выборка.Код));
	// Наименование клиента запишем в текст элемента
	Запись.ЗаписатьТекст(Выборка.Наименование);
	// закрываем элемент клиента
	Запись.ЗаписатьКонецЭлемента();	
КонецЦикла;
// закрываем корневой элемент xml-документа
Запись.ЗаписатьКонецЭлемента();	
// закрыть файл
Запись.Закрыть();

Чтение данных из XML-файла в справочник:

Код 1C v 8.х

 Чтение = Новый ЧтениеXML;
Чтение.ОткрытьФайл(ПутьКФайлу);
Спр="";
// чтение осуществляется по одному тегу
Пока Чтение.Прочитать() Цикл
	// анализируем тип элемента и его имя
	Если Чтение.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
		Если Чтение.Имя="Клиент" Тогда
			// создаем новый элемент справочника
			Спр = Справочники.Клиенты.СоздатьЭлемент();
// читаем атрибуты
			Пока Чтение.ПрочитатьАтрибут() Цикл
				Если Чтение.Имя="Код" Тогда
					Спр.Код = Число(Чтение.Значение);
				КонецЕсли;
КонецЦикла;
		КонецЕсли;
	ИначеЕсли Чтение.ТипУзла = ТипУзлаXML.Текст Тогда
		// заполняем наименование созданного ранее элемента
		Спр.Наименование = Чтение.Значение;
	ИначеЕсли Чтение.ТипУзла = ТипУзлаXML.КонецЭлемента Тогда
		// требуется записать информацию про клиента
		Спр.Записать();
	КонецЕсли;
КонецЦикла;

Создадим обработку в типовой конфигурации для экспорта плана счетов. Структура xml-файла должна быть такой. Корневой элемент xml-документа соответствует плану счетов в целом. В нем располагаются подчиненные элементы с именем Счет, содержащие информацию о счетах. В качестве содержимого элементов указывается наименование счета. Остальные данные записываются в качестве атрибутов (код, признаки валютного, количественного учета и пр.). В качестве подчиненных элементов для элемента Счет задаются элементы, обозначающие его субсчета с теми же атрибутами. Приведем код процедуры экспорта плана счетов.

Код 1C v 7.x

 Процедура Выполнить()
  Если ЗагрузитьВнешнююКомпоненту(КаталогПрограммы()+"v7plus.dll")<>1 Тогда
    Предупреждение("Компонента не обнаружена");
    Возврат;
  КонецЕсли;
  Анализатор=СоздатьОбъект("AddIn.XMLParser");
  Корень=Анализатор.СоздатьДокумент();
  План=Корень.СоздатьПодчиненныйЭлемент("ПланСчетов");
  Счет=СоздатьОбъект("Счет.Основной");
  Родитель=СоздатьОбъект("Счет.Основной");
  Счет.ВыбратьСчета();
  Пока Счет.ПолучитьСчет()=1 Цикл
    // если это счет, а не субсчет
    Если Счет.Уровень()=1 Тогда
      Родитель.НайтиПоКоду(Счет.Код);
      СчетXML=План.СоздатьПодчиненныйЭлемент("Счет");
      СчетXML.УстановитьАтрибут("Код", Счет.Код);
      СчетXML.УстановитьАтрибут("Валютный", Счет.Валютный);
      СчетXML.УстановитьАтрибут("Количественный", Счет.Количественный);
      СчетXML.УстановитьАтрибут("Забалансовый", Счет.Забалансовый);
      Если Счет.Активный=1 Тогда
        СчетXML.УстановитьАтрибут("вид","активный");
      ИначеЕсли Счет.Активный=2 Тогда
        СчетXML.УстановитьАтрибут("вид","пассивный");
      Иначе
        СчетXML.УстановитьАтрибут("вид","активно-пассивный");
      КонецЕсли;
      СчетXML.Значение=Счет.Наименование;
    Иначе
      Если Счет.ПринадлежитГруппе(Родитель)=1 Тогда
        СубсчетXML=СчетXML.СоздатьПодчиненныйЭлемент("Субсчет");
        СубсчетXML.УстановитьАтрибут("Код", Счет.Код);
        // аналогично устанавливаем все атрибуты на элемент СубсчетXML
        СубсчетXML.Значение=Счет.Наименование;
      КонецЕсли;
    КонецЕсли;
  КонецЦикла;
  Корень.Записать(КаталогПрограммы()+"plan.xml");
КонецПроцедуры

В результате будет получен файл, вот его фрагмент:

Код

<?xml version="1.0" encoding="windows-12Sl" ?> - <ПланСчетов>
<Счет Код="00" Валютный="0" Количественный="0" Забалансовый="0" вид="активно-пассивный">Вспомогательный</Счет>
- <Счет Код="01" Валютный="0" Количественный="0" Забалансовый="0" вид="активный">
Основные средства
<Субсчет Код="01.1" Валютный="0" Количественный="0" Забалансовый="0"
вид="активный">ОС в организации</Субсчет> <Субсчет Код="01.2" Валютный="0" Количественный="0" Забалансовый="0"
вид="активный">Выбытие ОС</Субсчет> </Счет>
- <Счет Код="02" Валютный="0" Количественный="0" Забалансовый="0" вид="пассивный">
Амортизация ОС

А теперь приведем код для импорта плана счетов из xml-файла в новую конфигурацию. Код модуля соответствующей обработки должен содержать процедуру Выполнить(), которая имеет такой вид.

Код 1C v 7.x

 Процедура Выполнить()
  Если ЗагрузитьВнешнююКомпоненту(КаталогПрограммы()+"v7plus.dll")<>1 Тогда
    Предупреждение("Внешняя компонента не найдена");
    Возврат;
  КонецЕсли;
  Анализатор=СоздатьОбъект("AddIn.XMLParser");
  Файл=Анализатор.СоздатьДокумент();
  Файл.Загрузить(КаталогПрограммы()+"plan.xml");
  План=Файл.ВыбратьУзел("ПланСчетов");
  кол=План.КоличествоПодчиненных();
  Счет=СоздатьОбъект("Счет.Основной");
  Для инд=1 по кол Цикл
    СчетXML=План.ПолучитьПодчиненныйПоНомеру(инд);
    КолСубсчетов=СчетXML.КоличествоПодчиненных();
    // подчиненным элементом является и содержимое элемента
    Если КолСубсчетов>1 Тогда
      Счет.Новый(1);
    Иначе
      Счет.Новый(0);
    КонецЕсли;
    Счет.Код=СчетXML.ПолучитьАтрибут("Код");
    Счет.Наименование=СчетXML.Значение;
    Счет.Валютный=СчетXML.ПолучитьАтрибут("Валютный");
    Счет.Количественный=СчетXML.ПолучитьАтрибут("Количественный");
    Счет.Забалансовый=СчетXML.ПолучитьАтрибут("Забалансовый");
    Если СчетXML.ПолучитьАтрибут("вид")="активный" Тогда
      Счет.Активный=1;
    ИначеЕсли СчетXML.ПолучитьАтрибут("вид")="пассивный" Тогда
      Счет.Активный=2;
    Иначе
      Счет.Активный=3;
    КонецЕсли;
    Счет.Записать();
    Если КолСубсчетов>1 Тогда
      Счет1=СоздатьОбъект("Счет.Основной");
      Для инд1=2 По кол_субсчетов Цикл
        Субсчет=СчетXML.ПолучитьПодчиненныйПоНомеру(инд1);
        Счет1.Новый(0);
        Счет1.Код=Субсчет.ПолучитьАтрибут("Код");
        // аналогично устанавливаются все атрибуты создаваемого субсчета
        Счет1.Записать();
      КонецЦикла;
    КонецЕсли;
  КонецЦикла;

Категория: JSON, XML, TXT, CSV, DBF

Функция выгружает справочник в таблицу значений

Пример выгрузки(помещения) справочника в Таблицу Значений (ТЗ):

Код 1C v 7.x

  // Параметры:
//		ВидСправочника				-	Строка, указывающая вид справочника, как он задан в конфигураторе
//		ДобавлятьЭлементыСправочника		-	1-	добавить колонку с наименованием "Элемент", содержащую элементы справочников, 0 - не добавлять колонку
//		ИмяРеквизита 				-	Имя реквизита, как он задан в конфигураторе. Используется при заполнении таблицы из выборки по значению реквизита.
//		ЗначениеРеквизита			-	Значение реквизита, по которому надо построить выборку. Используется при заполнении таблицы из выборки по значению реквизита.
//		ЭлементВладелец 				-	Владелец, указывается для подчиненных справочников
//		ЭлементРодитель 				-	Родитель, используется в случае, если надо ограничить выборку условием принадлежности элементов одной группе
//		ВключатьПодчиненные 			-	Установить флаг выборки всех подчиненных элементов.
//		Иерархия				-   Флаг указывающий на то как выбирать элементы (1 - выбирать элементы с учетом иерархии, 0 - выбирать элементы без учета иерархии)
//		ВОбратномПорядке			-	Число: 1 - выбирать элементы справочника в обратном порядке; 0 - выбирать элементы справочника в прямом порядке
//		ВключатьГруппы				-	1 - выбирать среди групп справочника, 0 - выбирать только среди элементов
//
// Возвращает: Таблица значений, колонками которой, являются реквизиты справочника

Функция СправочникВТЗ(ВидСправочника, ДобавлятьЭлементыСправочника = 0,ИмяРеквизита = 0, ЗначениеРеквизита = 0, ЭлементВладелец = 0, ЭлементРодитель = 0, ВключатьПодчиненные = 1, Иерархия = 1, ВОбратномПорядке = 0, ВключатьГруппы = 0) Экспорт
	
	ТаблицаСпр			=	СоздатьОбъект("ТаблицаЗначений");
	мдСпр				=	Метаданные.Справочник(ВидСправочника);
	ВсегоРеквизитовСпр	=	мдСпр.Реквизит();
	Для индРекв			= 	1 по ВсегоРеквизитовСпр Цикл
		Вид = мдСпр.Реквизит(индРекв).Вид;
		ТаблицаСпр.НоваяКолонка(мдСпр.Реквизит(индРекв).Идентификатор, мдСпр.Реквизит(индРекв).Тип + ?(ПустоеЗначение(Вид) = 0, "." + Вид, ""), мдСпр.Реквизит(индРекв).Длина, мдСпр.Реквизит(индРекв).Точность);
	КонецЦикла;
	ТаблицаСпр.НоваяКолонка("Код", ?(мдСпр.ТипКода = "Текстовый", "Строка", "Число"), мдСпр.ДлинаКода);
	ТаблицаСпр.НоваяКолонка("Наименование", "Строка", мдСпр.ДлинаНаименования);
	Если ДобавлятьЭлементыСправочника = 1 тогда
		ТаблицаСпр.НоваяКолонка("Элемент", "Справочник." + ВидСправочника);
	КонецЕсли;
	Спр = СоздатьОбъект("Справочник." + ВидСправочника);
	Если ЭлементВладелец <> 0 тогда
		Спр.ИспользоватьВладельца(ЭлементВладелец);
	КонецЕсли;
	Если ЭлементРодитель <> 0 тогда
		Спр.ИспользоватьРодителя(ЭлементРодитель);
	КонецЕсли;
	Спр.ОбратныйПорядок(ВОбратномПорядке);
	Спр.ВключатьПодчиненные(ВключатьПодчиненные);
	Если ИмяРеквизита = 0 тогда
		Спр.ВыбратьЭлементы(Иерархия);
	Иначе
		Спр.ВыбратьЭлементыПоРеквизиту(ИмяРеквизита, ЗначениеРеквизита, Иерархия, ВключатьГруппы);
	КонецЕсли;
	
	Пока Спр.ПолучитьЭлемент() = 1 Цикл
		      
		ТаблицаСпр.НоваяСтрока();
		ТекущаяСтрока	=	ТаблицаСпр.НомерСтроки;
		Для НомерКолонки= 	1 по ВсегоРеквизитовСпр Цикл
			ТаблицаСпр.УстановитьЗначение(ТекущаяСтрока, НомерКолонки, Спр.ПолучитьАтрибут(мдСпр.Реквизит(НомерКолонки)));
		КонецЦикла;
		ТаблицаСпр.Код			=	Спр.Код;
		ТаблицаСпр.Наименование	=	Спр.Наименование;
		Если ДобавлятьЭлементыСправочника = 1 тогда
			ТаблицаСпр.УстановитьЗначение(ТекущаяСтрока, "Элемент", Спр.ТекущийЭлемент());
		КонецЕсли;
		
	КонецЦикла;
	
	Возврат ТаблицаСпр;	
КонецФункции

Новинки игровых автоматов с возможностью играть на бездепозитный бонус за регистрацию в онлайн казино на деньги.

Категория: Справочники

Функция устанавливает новое значение реквизита документа или справочника.

Код 1C v 7.x

  //функция устанавливает новое значение реквизита документа или справочника и задаёт вопрос, если новое значение не соответствует предыдущему
Функция гЗначение(Ко,Атрибут,Значение) Экспорт
     Знач1=Ко.ПолучитьАтрибут(Атрибут);
     Знач2=Значение;
     //проверка
     Если Не(ТипЗначенияСтр(Знач1)=ТипЗначенияСтр(Знач2)) Тогда
          //несоответствие типов
          Возврат(0);
     ИначеЕсли Не(ТипЗначенияСтр(Знач2)="Число") И (ПустоеЗначение(Знач2)=1) Тогда
          //пустое новое значение
          Возврат(0);
     КонецЕсли;
     //реквизит
     Если Метаданные.Документ(Ко.Вид()).Выбран()=1 Тогда
          //документ
          Если Метаданные.Документ(Ко.Вид()).РеквизитШапки(Атрибут).Выбран()=1 Тогда
               Ж=Метаданные.Документ(Ко.Вид()).РеквизитШапки(Атрибут);
               Имя=Ж.Представление();
          ИначеЕсли Метаданные.Документ(Ко.Вид()).РеквизитТабличнойЧасти(Атрибут).Выбран()=1 Тогда
               Ж=Метаданные.Документ(Ко.Вид()).РеквизитТабличнойЧасти(Атрибут);
               Имя=Ж.Представление()+" (строка "+Ко.НомерСтроки+")";
          Иначе
               Ж=Метаданные.ОбщийРеквизитДокумента(Атрибут);
               Имя=Ж.Представление();
          КонецЕсли;
     ИначеЕсли Метаданные.Справочник(Ко.Вид()).Выбран()=1 Тогда
          //справочник
          Ж=Метаданные.Справочник(Ко.Вид()).Реквизит(Атрибут);
          Имя=Ж.Представление();
          Если ПустаяСтрока(Имя)=1 Тогда
               Имя=Атрибут;
          КонецЕсли;
     КонецЕсли;
     //форматирование
     Если ТипЗначенияСтр(Знач2)="Строка" Тогда
          Знач1=СокрЛП(Знач1);
          Знач2=СокрЛП(Знач2);
     ИначеЕсли ТипЗначенияСтр(Знач2)="Число" Тогда
          Знач2=Окр(Знач2,Ж.Точность);
     КонецЕсли;
     //проверка
     Если Знач1=Знач2 Тогда
          Возврат(0);
     КонецЕсли;
     //установка значения
     Если ПустоеЗначение(Знач1)=0 Тогда
          Текст=
          "Атрибут: "+Имя+"
          |
          |Старое значение: "+СимволТабуляции+Знач1+"
          |Новое значение: "+СимволТабуляции+Знач2+"
          |
          |Установить новое значение?";
          Если Вопрос(Текст,"Да+Нет")="Нет" Тогда
               Возврат(0)
          КонецЕсли;
     КонецЕсли;
     //значение
     Ко.УстановитьАтрибут(Атрибут,Знач2);
     Возврат(1);
КонецФункции

Категория: Метаданные

Реквизит ~ Перебор реквизитов Формы

Код 1C v 8.х

 //Перебор Основных Реквизитов формы
	Для Каждого Рек из ЭтаФорма.Метаданные().Реквизиты Цикл
		Сообщить(рек.Имя+" - "+рек.Синоним+" - "+Строка(рек.Тип));
	КонецЦикла;
	// или так
	Для Каждого Рек из Метаданные().Реквизиты Цикл
		Сообщить(рек.Имя+" - "+рек.Синоним+" - "+Строка(рек.Тип));
	КонецЦикла;
	
	//Реквизиты формы - Надписи, Поля Ввода и т.д
	//можно и через ЭтаФорма.ЭлементыФормы
	Для Каждого Рек из ЭлементыФормы Цикл
		Сообщить(Строка(рек)+" - "+рек.имя);
    КонецЦикла;

Перебор реквизитов определенного слоя формы:

Код 1C v 7.x

 Процедура ПриВыбореЗакладки(НомерЗакладки, ЗначениеЗакладки)
    ТекущаяСтраница = ЗначениеЗакладки;
    Форма.ИспользоватьСлой("Кнопки,"+СокрЛП(ТекущаяСтраница), 2);
    
    Если ТекущаяСтраница="зклдПодписание" Тогда
    Для Инд = 1 По Метаданные.Справочник("ДоговораНов").Реквизит() Цикл

         Реквизит = Метаданные.Справочник("ДоговораНов").Реквизит(Инд);
         Если Форма.ПолучитьАтрибут(Реквизит).Видимость() = 1 Тогда
               Форма.ПолучитьАтрибут(Реквизит).Доступность(0);
         КонецЕсли;

    КонецЦикла;
    КонецЕсли;

КонецПроцедуры

Категория: Работа с Формой (Диалог) и её элементами

Как при проведении прописать движения регистра, имея переменную с его именем?

Код 1C v 7.x

  Процедура ОбработкаПроведения() 
    //Здесь следует написать алгоритм проведения документа 
   Рег = Регистр.ПолучитьАтрибут("Новый1"); 
   Рег.Новый1 = Новый1; 
   Рег.Количество = 1; 
   Рег.ДвижениеПриходВыполнить(); 
КонецПроцедуры

Категория: Регистры

Вывести список элементов справочника в Word используя шаблон spisok.dot

Код 1C v 7.x

  Процедура ВывестиСписокЭлементовСправочникаВWord()
	
	спр1=создатьобъект("справочник.сотрудники");
	спр1.ИспользоватьДату(ТекущаяДата());
	Сообщить( спр1.НайтиПоНаименованию("Администрация",0,1));
	Сообщить(спр1.ПолучитьАтрибут("Наименование"));  
	сотр=создатьобъект("справочник.сотрудники"); 
	сотр.ИспользоватьДату(ТекущаяДата());
	сотр.ИспользоватьРодителя(спр1);
	отчет=создатьобъект("word.application");
	отчет.visible = 1; 
	отчет.documents.add("d:\spisok.dot");
	отчет.documents(1).tables(1).cell(1,2).range.text= спр1.ПолучитьАтрибут("Наименование");
	сотр.ВыбратьЭлементы();       
	ном=2;
	Пока сотр.ПолучитьЭлемент(1)=1 цикл
		Сообщить(сотр.ПолучитьАтрибут("Наименование"));                                       
		отчет.documents(1).tables(2).cell(ном,1).range.text = сотр.ПолучитьАтрибут("Код");
		отчет.documents(1).tables(2).cell(ном,2).range.text = сотр.ПолучитьАтрибут("Наименование");
		отчет.documents(1).tables(2).cell(ном,3).range.text = сотр.ПолучитьАтрибут("Должность");
		отчет.documents(1).tables(2).cell(ном,4).range.text = сотр.ПолучитьАтрибут("Оклад");
		отчет.documents(1).tables(2).rows.add();
		ном=ном+1;
	КонецЦикла;
КонецПроцедуры

Категория: Работа с Microsoft Office и OpenOffice

Копирование подчиненных элементов справочника из группы Источник в группу Цель

Код 1C v 7.x

 
Справ=СоздатьОбъект("Справочник.Задания");
Справ2=СоздатьОбъект("Справочник.Задания");
Справ.ИспользоватьВладельца(Цель);
Справ2.ИспользоватьВладельца(Источник);
Справ.ИспользоватьДату(НаДату);
Справ2.ИспользоватьДату(НаДату);

Справ2.ВыбратьЭлементы();
Пока Справ2.ПолучитьЭлемент()>0 Цикл
     Справ.Новый();
     Справ.Записать();
     МетаСправочник=Метаданные.Справочник(Справ.Вид());
     Для Счетчик=1 По МетаСправочник.Реквизит() Цикл
          МетаРеквизит=МетаСправочник.Реквизит(Счетчик);
          Идентификатор=Строка(МетаРеквизит.Идентификатор);
          Значенице=Справ2.ПолучитьАтрибут(Идентификатор);
          Справ.УстановитьАтрибут(Идентификатор,Значенице);
     КонецЦикла;
Справ.Записать();
КонецЦикла;

Категория: Справочники