пользовательском » Поиск

Результаты по ключевому слову: пользовательском

Добавление дополнительных отчетов и обработок в тонком клиенте БП 3.0, ЗУП 3.0, УТ 11

Любой отчет и обработку можно подключить пользователям как дополнительные отчеты или обработки, вот например пункт в БП - Банк:

Добавление происходит через

далее Дополнительные отчеты и обработки, в списке нажмите Создать и Выберите Файл отчета/обработки:

Перед добавлением файл нужно подготовить, дописать в модуль объекта код подключения:

Для обработок код:

Код 1C v 8.3

 Функция СведенияОВнешнейОбработке() Экспорт

	

	ПараметрыРегистрации = Новый Структура;

	

	//Вид

	//Строка, вид обработки, один из возможных: 

	//"ДополнительнаяОбработка", "ДополнительныйОтчет", "ЗаполнениеОбъекта", "Отчет", "ПечатнаяФорма", "СозданиеСвязанныхОбъектов" 

	ПараметрыРегистрации.Вставить("Вид", "ДополнительнаяОбработка");

	

	//Массив строк имен объектов метаданных в формате: 

	//<ИмяКлассаОбъектаМетаданного>.[ * | <ИмяОбъектаМетаданных>]. 

	//Например, "Документ.СчетЗаказ" или "Справочник.*". 

	//Прим. параметр имеет смысл только для назначаемых обработок, для глобальных может не задаваться. 

	ПараметрыРегистрации.Вставить("Назначение", Новый СписокЗначений);

	

	//Наименование обработки, которым будет заполнено наименование элемента справочника по умолчанию - краткая строка для идентификации обработки администратором 

	ПараметрыРегистрации.Вставить("Наименование", "Сравнение документов БУХ и УТ");

	

	//Версия обработки в формате “<старший номер>.<младший номер>” используется при загрузке обработок в информационную базу. Например “. 

	ПараметрыРегистрации.Вставить("Версия", "1.0");

	

	//Принимает значение Истина или Ложь, в зависимости от того, требуется ли устанавливать или отключать безопасный режим исполнения обработок. Если истина, обработка будет запущена в безопасном режиме. Более подбробно о безопасном режиме в справке к платформе 1С:Предприятие. 

	ПараметрыРегистрации.Вставить("БезопасныйРежим", Истина);

	

	//Краткая информация по обработке, описание обработки. 

	ПараметрыРегистрации.Вставить("Информация", "");

	

	//Команды, поставляемые обработкой. Таблица значений с колонками: 

	ПараметрыРегистрации.Вставить("Команды", Новый СписокЗначений);

		

	ТаблицаКоманд = ПолучитьТаблицу_Команд();





  	ДобавитьКоманду(ТаблицаКоманд,

          "Сравнение документов БУХ и УТ", 	//Представление

          "Сравнение документов БУХ и УТ",	//Идентификатор

          "ОткрытиеФормы", 				//Использование

          Ложь,					 		//ПоказыватьОповещение

          "");			 				//Модификатор





  	ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);

	

	Возврат ПараметрыРегистрации;

	

КонецФункции





Функция ПолучитьТаблицу_Команд()





  Команды = Новый ТаблицаЗначений;

  

  //Представление – представление команды в пользовательском интерфейсе;

  Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));

  

  //Идентификатор – идентификатор команды; 

  //любая строка, уникальная в пределах данной обработки (отчета). 

  //В случае с обработками печатных форм на основе макета табличного документа передается список макетов, 

  //на основе которых нужно получить печатную форму 

  //(см. описание параметра ИменаМакетов процедуры УправлениеПечатьюКлиент.ВыполнитьКомандуПечати в разделе Печать). 

  Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));

  

  //"ОткрытиеФормы" – открыть форму обработки; 

  //"ВызовКлиентскогоМетода" – вызвать клиентскую экспортную процедуру из модуля формы обработки; 

  //"ВызовСерверногоМетода" – вызвать серверную экспортную процедуру из модуля объекта обработки.

  Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));

 	

  //ПоказыватьОповещение – если Истина, требуется показать оповещение при начале и при завершении работы обработки. 

  //Имеет смысл только при запуске обработки без открытия формы. 

  Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));

  

  //Модификатор – дополнительный модификатор команды. 

  //Используется для дополнительных обработок печатных форм на основе табличных макетов, 

  //для таких команд должен содержать строку ПечатьMXL (см. пример в демонстрационной конфигурации).

  Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));

  

  Возврат Команды;

           

КонецФункции





Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = "")





  НоваяКоманда = ТаблицаКоманд.Добавить();

  НоваяКоманда.Представление = Представление;

  НоваяКоманда.Идентификатор = Идентификатор;

  НоваяКоманда.Использование = Использование;

  НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;

  НоваяКоманда.Модификатор = Модификатор;



КонецПроцедуры

Для отчетов и печатных форм меняйте параметр Вид:

Код 1C v 8.3

 //"ДополнительнаяОбработка", "ДополнительныйОтчет", "ЗаполнениеОбъекта", "Отчет", "ПечатнаяФорма", "СозданиеСвязанныхОбъектов" 

	ПараметрыРегистрации.Вставить("Вид", "ДополнительнаяОбработка");

Возможные значения этого поля приведу в виде таблицы

Значение поля "Вид" Расположение команды

Расширение

файла

ПечатнаяФорма	В меню "Печать" на форме объекта или списка	epf
ЗаполнениеОбъекта	В меню "Заполнить" на форме объекта или списка	epf
СозданиеСвязанныхОбъектов	В меню "Создать на основании" - "Создание связанных объектов.." на форме объекта или списка	epf
Отчет	В меню "Отчеты" на форме объекта или списка	erf
ДополнительнаяОбработка	В списке соответствующих подсистем в меню "Сервис" - "Дополнительные обработки"	epf
ДополнительныйОтчет	В списке соответствующих подсистем в меню "Сервис" - "Дополнительные отчеты"	erf

Это поле может принимать одно из значений, возвращаемых функциями в типовых конфигурациях:

ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработки<Вид>(). Например, для вида "ПечатнаяФорма" есть функция ВидОбработкиПечатнаяФорма().

Категория: Внешние печатные формы, отчеты и обработк�…

Пример создания внешней печатной формы для управляемого приложения

Пример создания внешней печатной формы АКТа для Бухгалтерии 3.0

1. В конфигураторе 1C Предприятия 8 создаем внешнюю обработку (Файл->Новый->Внешняя обработка), задаем имя.

2. В модуле обработки пишем код. Постараюсь его максимально комментировать. Главное должно быть:

функция ПечатьВнешнейПечатнойФормы табличного документа - которая выведет данные в макет
функция Печать - вызывается из конфигурации! в нее передается массив печатаемых объектов
и функция СведенияОВнешнейОбработке(). Она необходима для регистрации печатной формы в справочнике ДополнительныеОтчетыИОбработки, в ней собирается структура с данными для подключения формы. Эта функция, а также ряд сопутствующих ей, практически одинаковы для всех печатных форм, поэтому их можно просто копировать в новую печатную форму ничего не меняя.

Код 1C v 8.3

 // Функция формирует табличный документ с Внешней печатной формой

//

// Возвращаемое значение:

//  Табличный документ - печатная форма акта

Функция ПечатьВнешнейПечатнойФормы(МассивОбъектов, ОбъектыПечати, Подписант) Экспорт

	ТабДок = новый ТабличныйДокумент;

	

	Макет = ПолучитьМакет("Макет");

	

	ОбластьШапки   = Макет.ПолучитьОбласть("Шапка");

	ОбластьДанные  = Макет.ПолучитьОбласть("Данные");

	ОбластьПодвал  = Макет.ПолучитьОбласть("Подвал");

	

	Запрос = новый запрос;

	Запрос.УстановитьПараметр("МассивОбъектов",МассивОбъектов);

	Запрос.Текст = "ВЫБРАТЬ

	|	РеализацияТоваровУслугТовары.Номенклатура,

	|	РеализацияТоваровУслугТовары.Сумма,

	|	РеализацияТоваровУслугТовары.Количество,

	|	РеализацияТоваровУслугТовары.Цена,

	|	РеализацияТоваровУслугТовары.Ссылка КАК Ссылка

	|ИЗ

	|	Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары

	|ГДЕ

	|	РеализацияТоваровУслугТовары.Ссылка В(&МассивОбъектов)

	|

	|ОБЪЕДИНИТЬ ВСЕ

	|

	|ВЫБРАТЬ

	|	РеализацияТоваровУслугУслуги.Номенклатура,

	|	РеализацияТоваровУслугУслуги.Сумма,

	|	РеализацияТоваровУслугУслуги.Количество,

	|	РеализацияТоваровУслугУслуги.Цена,

	|	РеализацияТоваровУслугУслуги.Ссылка

	|ИЗ

	|	Документ.РеализацияТоваровУслуг.Услуги КАК РеализацияТоваровУслугУслуги

	|ГДЕ

	|	РеализацияТоваровУслугУслуги.Ссылка В(&МассивОбъектов)  	

	|

	|УПОРЯДОЧИТЬ ПО

	|	Ссылка";

	

	ОбщаяВыборка = Запрос.Выполнить().Выгрузить();

	

	Для Каждого СсылкаНаОбъект из МассивОбъектов Цикл

		

		ОбластьШапки.Параметры.ТекстЗаголовка = "Акт №  "+СсылкаНаОбъект.Номер;

		ОбластьШапки.Параметры.Организация = СсылкаНаОбъект.Организация;

		

		ТабДок.Вывести(ОбластьШапки);

		

		Отбор = Новый Структура;

		Отбор.Вставить("Ссылка",СсылкаНаОбъект);

		

		Выборка = ОбщаяВыборка.НайтиСтроки(Отбор);

		

		ИтогоСумма      = 0;

		ИтогоКоличество = 0;

		

		Для Каждого Стр из Выборка Цикл

			ЗаполнитьЗначенияСвойств(ОбластьДанные.Параметры,Стр);

			

			ИтогоСумма = ИтогоСумма + Стр.Сумма;

			ИтогоКоличество = ИтогоКоличество + Стр.Количество;

			

			ТабДок.Вывести(ОбластьДанные);

		КонецЦикла;

		

		ОбластьПодвал.Параметры.ИтогоСумма      = ИтогоСумма;

		

		ОбластьПодвал.Параметры.Подписант      = Подписант;





		ТабДок.Вывести(ОбластьПодвал);

		

		ТабДок.ВывестиГоризонтальныйРазделительСтраниц();

	КонецЦикла;

	

	Возврат ТабДок;

КонецФункции



// Экспортная процедура печати, вызываемая из основной программы

//

// Параметры:

// ВХОДЯЩИЕ:

//  МассивОбъектовНазначения - Массив - список объектов ссылочного типа для печати документа

//                 Как правило, содержит один элемент с ссылкой на вызвавший форму объект (документ, справочник)

//

// ИСХОДЯЩИЕ:

//  КоллекцияПечатныхФорм - ТаблицаЗначений - таблица сформированных табличных документов.

//                 Как правило, содержит одну строку с именем текущей печатной формы

//  ОбъектыПечати - СписокЗначений - список объектов печати. 

//  ПараметрыВывода - Структура - Параметры сформированных табличных документов. Содержит поля:

//  						ДоступнаПечатьПоКомплектно - булево - по умолчанию Ложь

//							ПолучательЭлектронногоПисьма

//							ОтправительЭлектронногоПисьма

//

Процедура Печать(МассивОбъектовНазначения, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт

	

	Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "АКТПечатьВнешняя") Тогда 

		ТабличныйДокумент = ПечатьВнешнейПечатнойФормы(МассивОбъектовНазначения, ОбъектыПечати, "");

		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "АКТПечатьВнешняя", "АКТ (внешний)", ТабличныйДокумент);

		

	ИначеЕсли УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "АКТПечатьВнешняяИван") Тогда 

		ТабличныйДокумент = ПечатьВнешнейПечатнойФормы(МассивОбъектовНазначения, ОбъектыПечати, "Иванов А.Ю.");

		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "АКТПечатьВнешняяИван", "АКТ (внешний) Иванов", ТабличныйДокумент);  		

		

	ИначеЕсли УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "АКТПечатьВнешняяПетр") Тогда 

		ТабличныйДокумент = ПечатьВнешнейПечатнойФормы(МассивОбъектовНазначения, ОбъектыПечати, "Петров В.С.");

		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "АКТПечатьВнешняяПетр", "АКТ (внешний) Петров", ТабличныйДокумент);

	КонецЕсли;





КонецПроцедуры





#Область СведенияОВнешнейОбработке

// Сервисная экспортная функция. Вызывается в основной программе при регистрации обработки в информационной базе

// Возвращает структуру с параметрами регистрации

//

// Возвращаемое значение:

//		Структура с полями:

//			Вид - строка, вид обработки, один из возможных: "ДополнительнаяОбработка", "ДополнительныйОтчет", 

//					"ЗаполнениеОбъекта", "Отчет", "ПечатнаяФорма", "СозданиеСвязанныхОбъектов"

//			Назначение - Массив строк имен объектов метаданных в формате: 

//					<ИмяКлассаОбъектаМетаданного>.[ * | <ИмяОбъектаМетаданных>]. 

//					Например, "Документ.СчетЗаказ" или "Справочник.*". Параметр имеет смысл только для назначаемых обработок, для глобальных может не задаваться.

//			Наименование - строка - Наименование обработки, которым будет заполнено наименование элемента справочника по умолчанию.

//			Информация  - строка - Краткая информация или описание по обработке.

//			Версия - строка - Версия обработки в формате “<старший номер>.<младший номер>” используется при загрузке обработок в информационную базу.

//			БезопасныйРежим - булево - Принимает значение Истина или Ложь, в зависимости от того, требуется ли устанавливать или отключать безопасный режим 

//							исполнения обработок. Если истина, обработка будет запущена в безопасном режиме. 

//

Функция СведенияОВнешнейОбработке() Экспорт

	//Инициализируем структуру с параметрами регистрации    	

	ПараметрыРегистрации = Новый Структура;

	// Первый параметр, который мы должны указать - это какой вид обработки системе должна зарегистрировать.

	// Допустимые типы: ДополнительнаяОбработка, ДополнительныйОтчет, ЗаполнениеОбъекта, Отчет, ПечатнаяФорма, СозданиеСвязанныхОбъектов

	ПараметрыРегистрации.Вставить("Вид", "ПечатнаяФорма"); //может быть - ПечатнаяФорма, ЗаполнениеОбъекта, ДополнительныйОтчет, СозданиеСвязанныхОбъектов...

	

	МассивНазначений = Новый Массив;

	// Теперь нам необходимо передать в виде массива имен, к чему будет подключена наша ВПФ

	// Имейте ввиду, что можно задать имя в таком виде: Документ.* - в этом случае обработка будет подключена ко всем документам в системе,

	// которые поддерживают механизм ВПФ

	МассивНазначений.Добавить("Документ.РеализацияТоваровУслуг"); //Указываем документ к которому делаем внешнюю печ. форму   		

	ПараметрыРегистрации.Вставить("Назначение", МассивНазначений);

	

	ПараметрыРегистрации.Вставить("Наименование", "АКТ (Внешний)"); //имя под которым обработка будет зарегестрирована в справочнике внешних обработок

	ПараметрыРегистрации.Вставить("БезопасныйРежим", ЛОЖЬ);  // Зададим право обработке на использование безопасного режима. Более подробно можно узнать в справке к платформе (метод УстановитьБезопасныйРежим)

	ПараметрыРегистрации.Вставить("Версия", "1.0");   // эти два параметра играют больше информационную роль,

	ПараметрыРегистрации.Вставить("Информация", "Дополнительная печатная форма"); // т.е. это то, что будет видеть пользователь в информации к обработке

	

	// Создадим таблицу команд (подробнее смотрим ниже)

	ТаблицаКоманд = ПолучитьТаблицуКоманд();

	ДобавитьКоманду(ТаблицаКоманд, "Внешний: АКТ", "АКТПечатьВнешняя", "ВызовСерверногоМетода", Истина, "ПечатьMXL");

	ДобавитьКоманду(ТаблицаКоманд, "Внешний: АКТ (Иванов)", "АКТПечатьВнешняяИван", "ВызовСерверногоМетода", Истина, "ПечатьMXL");

	ДобавитьКоманду(ТаблицаКоманд, "Внешний: АКТ (Петров)", "АКТПечатьВнешняяПетр", "ВызовСерверногоМетода", Истина, "ПечатьMXL");

	

	ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);

	

	Возврат ПараметрыРегистрации; 	

КонецФункции

#КонецОбласти





#Область Вспомогательное

// ВСПОМОГАТЕЛЬНЫЕ ПРОЦЕДУРЫ И ФУНКЦИИ РЕГИСТРАЦИИ ОБРАБОТКИ





// Формирует структуру с параметрами регистрации регистрации обработки в информационной базе

//

// Параметры:

//	ОбъектыНазначенияФормы - Массив - Массив строк имен объектов метаданных в формате: 

//					<ИмяКлассаОбъектаМетаданного>.[ * | <ИмяОбъектаМетаданных>]. 

//					или строка с именем объекта метаданных 

//	НаименованиеОбработки - строка - Наименование обработки, которым будет заполнено наименование элемента справочника по умолчанию.

//							Необязательно, по умолчанию синоним или представление объекта

//	Информация  - строка - Краткая информация или описание обработки.

//							Необязательно, по умолчанию комментарий объекта

//	Версия - строка - Версия обработки в формате “<старший номер>.<младший номер>” используется при загрузке обработок в информационную базу.

//

//

// Возвращаемое значение:

//		Структура

//

Функция ПолучитьПараметрыРегистрации(ОбъектыНазначенияФормы = Неопределено, НаименованиеОбработки = "", Информация = "", Версия = "1.0")





	Если ТипЗнч(ОбъектыНазначенияФормы) = Тип("Строка") Тогда

		ОбъектНазначенияФормы = ОбъектыНазначенияФормы;

		ОбъектыНазначенияФормы = Новый Массив;

		ОбъектыНазначенияФормы.Добавить(ОбъектНазначенияФормы);

	КонецЕсли; 

	

	ПараметрыРегистрации = Новый Структура;

	ПараметрыРегистрации.Вставить("Вид", "ПечатнаяФорма");

	ПараметрыРегистрации.Вставить("БезопасныйРежим", Истина);

	ПараметрыРегистрации.Вставить("Назначение", ОбъектыНазначенияФормы);

	

	Если Не ЗначениеЗаполнено(НаименованиеОбработки) Тогда

		НаименованиеОбработки = ЭтотОбъект.Метаданные().Представление();

	КонецЕсли; 

	ПараметрыРегистрации.Вставить("Наименование", НаименованиеОбработки);

	

	Если Не ЗначениеЗаполнено(Информация) Тогда

		Информация = ЭтотОбъект.Метаданные().Комментарий;

	КонецЕсли; 

	ПараметрыРегистрации.Вставить("Информация", Информация);

	

	ПараметрыРегистрации.Вставить("Версия", Версия);





	Возврат ПараметрыРегистрации;





КонецФункции





// Формирует таблицу значений с командами печати

//	

// Возвращаемое значение:

//		ТаблицаЗначений

//

Функция ПолучитьТаблицуКоманд()





	Команды = Новый ТаблицаЗначений;

	

	//Представление команды в пользовательском интерфейсе

	Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));

	

	//Уникальный идентификатор команды или имя макета печати

	Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));

	

	//Способ вызова команды: "ОткрытиеФормы", "ВызовКлиентскогоМетода", "ВызовСерверногоМетода"

	// "ОткрытиеФормы" - применяется только для отчетов и дополнительных отчетов

	// "ВызовКлиентскогоМетода" - вызов процедуры Печать(), определённой в модуле формы обработки

	// "ВызовСерверногоМетода" - вызов процедуры Печать(), определённой в модуле объекта обработки

	Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));

	

	//Показывать оповещение.

	//Если Истина, требуется показать оповещение при начале и при завершении работы обработки. 

	//Имеет смысл только при запуске обработки без открытия формы

	Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));

	

	//Дополнительный модификатор команды. 

	//Используется для дополнительных обработок печатных форм на основе табличных макетов.

	//Для таких команд должен содержать строку ПечатьMXL

	Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));





	Возврат Команды; 

КонецФункции





// Вспомогательная процедура.

//

Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование = "ВызовСерверногоМетода", ПоказыватьОповещение = Ложь, Модификатор = "ПечатьMXL")

	НоваяКоманда = ТаблицаКоманд.Добавить();

	НоваяКоманда.Представление = Представление;

	НоваяКоманда.Идентификатор = Идентификатор;

	НоваяКоманда.Использование = Использование;

	НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;

	НоваяКоманда.Модификатор = Модификатор;      

КонецПроцедуры



#КонецОбласти

3. Добавляем макет вывода печатной формы:

4. Сохраняем и добавляем в конфигурацию:

Подключается через Администрирование - Печатные формы, отчеты и обработки:

Создаете новую обработку, записывайте и при открытии документа Реализация, нажав на Печать - появляются доступные печатные формы с разными подписывающими.

Скачать Шаблон внешней печатной формы для управляемого приложения

Категория: Внешние печатные формы, отчеты и обработк�…

Настройка многопользовательских сетевых ключей 1С

Речь ниже пойдет о usb-ключах, а программные лицензии > Если необходимо активировать многопользовательскую клиентскую лицензию 1С, так чтобы лицензии раздавал сервер приложений 1С, то это необходимо делать где угодно, только не на самом сервере приложений 1С. При этом в окне активации выбирать опцию «Дополнительно», поставить птичку на сервер 1С и указать параметры подключения к серверу.

о usb-ключах

Как показал опыт, чтобы клиенты 1С могли нормально получить лицензию с сервера, необходимо выполнить ряд условий:

1. Раздача лицензий сервером приложений 1С:- Тут все просто, ставим сервер приложений 1С, втыкаем ключ и в свойствах зарегистрированной в кластере 1С базы выставляем параметр «Разрешить выдачу лицензий сервером 1С:Предприятия» в позицию «Да». При такой конфигурации раздавать пользовательские лицензии будет сам сервер приложений 1С, но есть один неприятный момент, каждая открытая копия 1С на пользовательском компьютере будет съедать по одной лицензии, т. е. если открыть с одного компа 10 раз одну и ту же базу, то будет съедено 10 лицензий!

2. Раздача лицензий Hasp License Manager: - Ставим Hasp License Manager в качестве сервиса и запускаем. - Как правило при установке он сам добавляет разрешающие правила во встроенный в винду брандмауэр, если этого не произошло, то добавляем вручную правило разрешающее подключения по протоколам TCP и UDP на порт 475. - Если сеть побита на VLAN-ы и используются различные ACL, то необходимо прописать везде где это нужно правила доступа, как в пункте выше. - Настраиваем файл конфигурации Hasp License Manager, который называется nhsrv.ini и лежит по умолчанию в C:\Program Files (x86)\Aladdin\HASP LM . Вот примерный конфиг, указываю только интересующие пункты, остальное у меня закоментировано:NHS_USERLIST = 250 ; максимальное количество обслуживаемых клиентов, по умолчанию 250NHS_SERVERNAMES = ; имя сервера на котором установлен ключ с лицензиями и запущен Hasp LMNHS_USE_UDP = disabled ; включить или выключить использование протокола UDP, по умолчанию включенNHS_USE_TCP = enabled ; включить или выключить использование протокола TCPNHS_IP_portnum = 475 ; номер порта на котором принимает запросы Hasp LMNHS_IP_LIMIT = ; номера подсетей с которых разрешено подключение к Hasp LMNHS_USE_IPX = disabled ; включить или выключить использование IPXNHS_USE_NETBIOS = disabled ; включить или выключить использование NETBIOS - Настраиваем файл nethasp.ini на пользовательских компьютерах, по умолчанию лежит вC:\Program Files (x86)\1cv82\conf . Вот примерный конфиг, указываю только интересующие пункты, остальное у меня удалено:[NH_COMMON]NH_IPX = DisabledNH_NETBIOS = DisabledNH_TCPIP = Enabled

[NH_IPX]

[NH_NETBIOS]

[NH_TCPIP]

NH_SERVER_ADDR = 192.168.0.1, 192.168.0.2, 192.168.0.3 ; указываем где искать свободные лицензии, т. е. сервера на которых установлены многопользовательские клиентские ключи и настроенный Hasp LMNH_TCPIP_METHOD= TCPNH_SESSION = 5NH_SEND_RCV = 4NH_USE_BROADCAST = Disabled ; выключаем широковещание

- Стоит заметить, что когда раздача ключей настроена через Hasp LM, то пользователь занимает только одну лицензию, независимо от того сколько баз 1С он открыл, т. е. такой способ более выгоден экономически, но сложнее в реализации, особенно в больших организациях, где могут быть несколько сотен пользователей 1С.

- Если ключей много и доступ пользователей к ним делится по какому-то признаку (например по разным проектам), то хорошей практикой будет вести точный учет того, какие пользователи к каким ключам имеют доступ и настраивать их файлы nethasp.ini соотвественно. Это позволит администратору системы более полно владеть информацией и может очень помочь в решении проблем с нехваткой лицензий.

Источник

Категория: XML, DBF, TXT, CSV

Редактирование макетов печатных форм в УТ 11

В конфигурации 1C 8.2. УТ 11 все печатные формы по умолчанию доступны только на просмотр. В дополнение, Управление УТ 11 переписана на управляемых формах и метод редактирования печатных форм отличается от "Бухгалтерия 2.0" и других стандартных конфигураций 1C 8.2.

Проблему редактирования текста в документе перед печатью решается следующим образом:
Заходим в раздел "Администрирование" в пользовательском режиме
Печатные формы, отчеты и обработки. Выбираем пункт меню "Макеты печатных форм".
В открывшемся списке ищем нужную нам печатную форму. Все печатные формы сгруппированы по документам, к которым они относятся. Если не находим нужную форму у выбранного документа, смотрим внизу списка "Общие макеты".
Выбрав нужный макет позиционируемся на нем и нажимаем сверху на командной панели кнопку "Редактировать".
Откроется непосредственно макет печатной формы.
Выделяем полностью его (Ctrl+A, либо стандартными средствами как в Excel).
Жмем на поле правой кнопкой мыши, откроется контекстное меню. В нем выбираем пункт "Свойства".
В открывшемся окне свойств снимаем флаг "Защита". После этого закрываем макет формы.
Система предложит сохранить изменения, Нажимаем "ОК".
После выполненных действий в таблице макетов у выбранного макета появится галка "Есть пользовательский макет".

Категория: 1С Управление торговлей 10.3

Обработка Универсальный обмен данными в формате XML Категория: Обработки

Табличное поле ~ Как раскрасить строки табличной части по условию? Категория: Работа с Формой (Диалог) и её элементами

Распределенная информационная база. Пошаговая инструкция и подводные камни. Категория: Конвертация данных, Обмен, Перенос

Документ "Операция" - Как программно создать и заполнить?

В бухгалтерских подсистемах типовых конфигураций есть всем известный документ «Операция». Бухгалтерам не приходится долго объяснять, как им пользоваться. Все по-бухгалтерски просто и лаконично: счет дебета, счет кредита, субконто, количество, сумма и прочие атрибуты бухгалтерских проводок. Проводки вводятся вручную, поэтому результат абсолютно прозрачен и понятен.

Время от времени возникает необходимость массово ввести большое количество проводок. Ситуации могут быть самыми разными: загрузка остатков или наоборот - списание с учета, исправление ошибок в учете и т. д. И тут уже дело за программистом.

На первый взгляд задача может показаться простой: создать документ, заполнить таблицу проводок данными и провести. Но не тут-то было! Как только дело доходит до «Конфигуратора», начинаются сюрпризы. Оказывается, у документа «Операция» вообще нет таблицы проводок, которую мы видим в пользовательском режиме.

Как же так? А вот так! Документ «Операция" используется в качестве регистратора, а проводки пишутся непосредственно в регистр бухгалтерии.

Решается задача довольно просто. Рассмотрим в качестве примера фрагмент кода обработки загрузки остатков по счету 001 «Арендованные основные средства» из dbf-таблицы.

Код 1C v 8.х

 

ДокОперация = Документы.ОперацияБух.СоздатьДокумент();

ДокОперация.Дата = ДатаДокумента;

ДокОперация.Организация = Организация;

ДокОперация.Ответственный = Ответственный;

ДокОперация.Содержание = Содержание;

ДокОперация.Комментарий = Комментарий;

ДокОперация.Записать();

ДокОперацияСсылка = ДокОперация.Ссылка;

   

РегХозрасчетный = РегистрыБухгалтерии.Хозрасчетный.СоздатьНаборЗаписей();

РегХозрасчетный.Отбор.Регистратор.Значение = ДокОперацияСсылка;

ДБФ.Первая();

Пока Не ДБФ.ВКонце() Цикл

    КодКонтрагента = СокрП(ДБФ.CA);

    Контрагент = Справочники.Контрагенты.НайтиПоКоду(КодКонтрагента);

    Если Контрагент.Пустая() Тогда

        Сообщить("Не найден контрагент с кодом " + КодКонтрагента, СтатусСообщения.Внимание);

    КонецЕсли;

    КодОС = СокрП(ДБФ.OS);

    ОсновноеСредство = Справочники.ОсновныеСредства.НайтиПоКоду(КодОС);

    Если ОсновноеСредство.Пустая() Тогда

        Сообщить("Не найдено ОС с кодом " + КодОС, СтатусСообщения.Внимание);

    КонецЕсли;

    

    РегЗапись = РегХозрасчетный.Добавить();

    РегЗапись.Период = ДатаДокумента;

    РегЗапись.Регистратор = ДокОперацияСсылка;

    РегЗапись.Организация = Организация;

    РегЗапись.Содержание  = "Корректировка стоимости ОС с 0 стоимостью";

    РегЗапись.СчетДт = Сч001;

    БухгалтерскийУчет.УстановитьСубконто(РегЗапись.СчетДт, РегЗапись.СубконтоДт, "Контрагенты", Контрагент);

    БухгалтерскийУчет.УстановитьСубконто(РегЗапись.СчетДт, РегЗапись.СубконтоДт, "ОсновныеСредства", ОсновноеСредство);

    РегЗапись.Сумма = ДБФ.Sum;

    

    ДБФ.Следующая();

КонецЦикла;   

РегХозрасчетный.Записать();

Я полагаю, принцип работы кода понятен из примера. Сначала создаем и записываем документ «Операция». Сам документ не содержит никаких проводок. Затем создаем набор записей регистра бухгалтерии и записываем в него проводки, используя документ «Операция» в качестве регистратора.

Источник

Категория: Документы