прерывание » Поиск

Результаты по ключевому слову: прерывание

Несовместимая версия файла базы данных 1Cv8.1CD

В основном, проблема в параметрах подключения - неверно указана версия платформы 1С.

Например, ваша конфигурация разработана для платформы 1С 8.3, а в настройках подключения прописано 1С 8.2 или наоборот.

Жизненный опыт решения проблемы "несовместимая версия файла базы данных 1cv8.1cd".

В первую очередь, единый совет для всех. Перед выполнением Всех манипуляций с файлом БД, всегда делайте архивную копию базы. Следуйте данному несложному правилу, и Вы избавитесь от почти всех малоприятных неожиданностей.

И так, при открытии базы, появляется сообщение следующего вида: "Ошибка при выполнении операции с базой данных

Несовместимая версия файла базы данных 'D:\путь к файлу/1Cv8.1CD' по причине:

Несовместимая версия файла базы данных 'D:\путь к файлу/1Cv8.1CD'"

Скажу сходу, что утилита chdbfl.exe здесь не может помочь, Вы станете получать ошибку "Произошло неожиданное прерывание выполнения проверки или исправления файла БД. Несовместимая версия файла базы данных 'D:\путь к файлу/1Cv8.1CD'"

Покопавшись чуть-чуть в гугле, я обнаружил причину данной проблемы (кстати, причина обычная) & не был схожим файл базы и версия платформы. Т.е. я открывал файл базы, сделанный в 8.2, платформой 8.3.

Для решения данной проблемы выполните следующие манипуляции: откройте базу конфигуратором; дальше, конфигуратор обязан конвертировать Вашу базу под ту версию платформы, на которой Вы на этот момент работаете.

А если, по каким-то причинам это не поможет - Вам понадобиться поставить ту версию платформы, в какой был вначале создан файл БД.

Категория: Администрирование

Вертикальная автофиксация для СКД

В СКД очень не хватает возможности автофиксации строк. Обусловлено это невозможностью однозначно определить их количество в общем случае. Однако в большинстве случаев это можно сделать
Обращаю ваше внимание, что приведенная процедура работает не всегда корректно. Но в большинстве случаев она сделает свое дело.

Код 1C v 8.х

 // Выводит результат СКД с установкой вертикальной автофиксации.

// Параметры:

// Таб - ТабличныеДокумент, ПолеТабличногоДокумента - куда выводим отчет;

// ПроцессорКомпоновкиДанных - ПроцессорКомпоновкиДанных;

// ЭлементыРасшировки - ЭлементыРасшифровкиКомпоновкиДанных;

// МассивИгнорируемыхПолей - Массив, *Неопределено - массив имен игнорируемых полей;

// РазрешитьПрерывание - Булево, *Истина.

//

Процедура ЛксВывестиРезультатКомпоновкиСАвтофиксациейСтрок(Таб, ПроцессорКомпоновкиДанных, ЭлементыРасшировки,

 Знач МассивИгнорируемыхПолей = Неопределено, РазрешитьПрерывание = Истина) Экспорт 

 

 ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

 ПроцессорВывода.УстановитьДокумент(Таб);

 ПроцессорВывода.НачатьВывод();

 ФиксацияВыполнена = Ложь;

 Если МассивИгнорируемыхПолей = Неопределено Тогда

 	МассивИгнорируемыхПолей = Новый Массив;

 КонецЕсли; 

 Пока Истина Цикл

 	ЭлементРезультатаКомпоновкиДанных = ПроцессорКомпоновкиДанных.Следующий();

 	Если ЭлементРезультатаКомпоновкиДанных = Неопределено Тогда

 	 Прервать;

 	КонецЕсли;

  

 	// Автофиксация

 	Если Не ФиксацияВыполнена Тогда

 	 Для Каждого ЗначениеПараметра Из ЭлементРезультатаКомпоновкиДанных.ЗначенияПараметров Цикл

 	 Если ТипЗнч(ЗначениеПараметра.Значение) = Тип("ИдентификаторРасшифровкиКомпоновкиДанных") Тогда

 	 ЗначенияПолейРасшифровки = ЭлементыРасшировки[ЗначениеПараметра.Значение].ПолучитьПоля();

 	 Для Каждого ЗначениеПоляРасшифровки Из ЗначенияПолейРасшифровки Цикл

 	 Если МассивИгнорируемыхПолей.Найти(ЗначениеПоляРасшифровки.Поле) = Неопределено Тогда

 	 Таб.ФиксацияСверху = Таб.ВысотаТаблицы;

 	 ФиксацияВыполнена = Истина;

 	 Прервать;

 	 КонецЕсли;

 	 КонецЦикла;

 	 Если ФиксацияВыполнена Тогда

 	 Прервать;

 	 КонецЕсли;

 	 КонецЕсли;

 	 КонецЦикла;

 	КонецЕсли;

  

 	ПроцессорВывода.ВывестиЭлемент(ЭлементРезультатаКомпоновкиДанных);

 	Если РазрешитьПрерывание Тогда

 	 ОбработкаПрерыванияПользователя();

 	КонецЕсли; 

 КонецЦикла;

 ПроцессорВывода.ЗакончитьВывод();

 

КонецПроцедуры // ЛксВывестиРезультатКомпоновкиСАвтофиксациейСтрок

tormozit

Категория: Схема Компоновки Данных

Преобразование XLS в MXL

Конвертация таблиц из Excel в MXL - скачать Converter Excel v MXL:
Для 8.х - Скачивать файлы может только зарегистрированный пользователь!

Для 7.7 - Скачивать файлы может только зарегистрированный пользователь!

Код 1C v 8.х

 // Выбор файла Microsoft Excel

Procedure FileNameStartChoice(Element, StdProcessing)

	

	StdProcessing = False;

	DialogFile = New FileDialog(FileDialogMode.Open);

	DialogFile.Filter = "Файлы Microsoft Excel (*.xls)|*.xls";

	DialogFile.DefaultExt = "xls";

	If DialogFile.Choose() Then

		FileName = DialogFile.FullFileName;

	EndIf;

	

EndProcedure // FileNameStartChoice()

// Получить список листов текущей книги

Function GetSheets(ExcelApplication)

		

	ListS_electSheet = New ValueList;

	

	ListS_electSheet.Add(0, "Все листы");

	

	NumberSheet = 0;

	For FirstSheet = 1 To ExcelApplication.Worksheets.Count Do 

		

		NumberSheet = NumberSheet + 1;

		ListS_electSheet.Add(

							 NumberSheet, ExcelApplication.WorkSheets(NumberSheet).Name

							);

		

	EndDo;	

	

	Return ListS_electSheet; 

	

EndFunction // GetSheets()



// Преобразование XLS в MXL

Procedure ButtonExecuteClick()

	

	If IsBlankString(FileName) Then

		DoMessageBox("Не указано имя файла");

		Return;

	EndIf;	

	

		Try

		ExcelApplication = GetCOMObject(FileName); // Excel.Application

	Except

		DoMessageBox("Ошибка чтения файла: " + FileName + " возможно защищен паролем.");

		Return;

	EndTry;	

	

	S_electSheet = 0;

	S_electSheet = GetSheets(ExcelApplication).ChooseItem("Выберите лист", S_electSheet); 

	

	If S_electSheet = Undefined Then

		Return;

	EndIf;

	

	S_electNumberSheet1 = S_electSheet.Value; 

	S_electNumberSheet2 = S_electNumberSheet1;

	If S_electNumberSheet1 = 0 Then

		S_electNumberSheet1 = 1;

		S_electNumberSheet2 = ExcelApplication.Worksheets.Count	

	EndIf;

	

	frmProgressBar = GetForm("FormProgressBar");

	frmProgressBar.Caption = "Обрабатывается файл: " + FileName;

	frmProgressBar.Controls.ProgressBarAll.MaxValue = S_electNumberSheet2;

	frmProgressBar.Controls.ProgressBarAll.Value = 0; 

	

	For NumberSheet = S_electNumberSheet1 To S_electNumberSheet2 Do

		

		frmProgressBar.Open();

		

		SprDoc = New SpreadsheetDocument;

	

		Try

			WorkSheet = ExcelApplication.Sheets(NumberSheet).UsedRange;

		Except

			DoMessageBox(ErrorDescription());

			Return;

		EndTry;

		

		AllStrings 	= WorkSheet.Rows.Count; 	// Всего строк

		AllColumns 	= WorkSheet.Columns.Count; 	// Всего колонок

		AllCells	= AllStrings * AllColumns; 	// Все ячейки

		

		frmProgressBar.Controls.InfoProgressBarAll.Value = "Обрабатывается лист № " +

		                                                    NumberSheet + " из " +

															S_electNumberSheet2;

															   

		frmProgressBar.Controls.ProgressBarAll.Value = frmProgressBar.Controls.ProgressBarAll.Value + 1; 

		

		If AllCells < 2 Then

			Continue; // Пустой лист

		EndIf;

		

		frmProgressBar.Controls.ProgressBarCur.MaxValue = AllStrings;

		frmProgressBar.Controls.ProgressBarCur.Value = 0; 

		

		For CurrentString = 1 To AllStrings Do

			

			For CurrentColumn = 1  To AllColumns Do

				

				frmProgressBar.Controls.InfoProgressBarCur.Value = "Обрабатывается строка №: " +

				                                                   TrimAll(CurrentString) +

																   " из " + AllStrings +

																   ", колонка №: " +

																   TrimAll(CurrentColumn) +

																   " из " + AllColumns;

				

				Try

					CurrentCell = WorkSheet.Cells(

					                               CurrentString,

												   CurrentColumn

												  );

					SlcCell 	= SprDoc.Area(

					                           CurrentString,

					                           CurrentColumn,

											   CurrentString,

											   CurrentColumn

											  );

					

					SlcCell.RowHeight 	= CurrentCell.RowHeight; 

					SlcCell.ColumnWidth = CurrentCell.ColumnWidth; 

					

					// Горизонтальное положение

					SlcCell.HorizontalAlign = mListHorizontalAlign.Get(

					                                                    Format(CurrentCell.HorizontalAlignment, "NG=0")

																	   );

																	   

					// Вертикальное положение																	   

					SlcCell.VerticalAlign 	= mListVerticalAlign.Get(

					                                                  Format(CurrentCell.VerticalAlignment, "NG=0")

																	 );

																	 

					// Размещение текста																	 

					SlcCell.TextPlacement = ?(

					                           CurrentCell.WrapText = 0,

											   SpreadsheetDocumentTextPlacementType.Auto,

											   SpreadsheetDocumentTextPlacementType.Wrap

											  );

					

					FontCell = CurrentCell.Font;

					

					// Цвет фона

					SlcCell.BackColor 	= mColorRGB(

													 CurrentCell.Interior.Color

													);

					

					// Цвет текста

					SlcCell.TextColor 	= mColorRGB(

													 FontCell.Color

													);

					

					

					SlcCell.Font = New Font(

					                         FontCell.Name, 

					                         Number(FontCell.Size),

					                         ?(Number(FontCell.Bold) = 0,

											 False, True),

											 ?(Number(FontCell.Italic) = 0,

											 False, True),

											 ?(Format(Number(FontCell.Underline),"NG=0") = "-4142",

											 False, True),

											 ?(FontCell.Strikethrough, // Зачеркнутый шрифт

											 True, False)

											);

					

					SlcCell.Text = CurrentCell.Value;

					

					// Рамка

					Try

						SlcCell.LeftBorder 		= mStyleBorder(CurrentCell, 7);

						SlcCell.TopBorder 		= mStyleBorder(CurrentCell, 8);

						SlcCell.RightBorder 	= mStyleBorder(CurrentCell, 10);

						SlcCell.BottomBorder 	= mStyleBorder(CurrentCell, 9);

					Except

					EndTry;

					

					SlcCell.Details = CurrentCell.Formula;

					

					// Объединение ячеек

					If (CurrentCell.MergeCells <> 0) and

					   (Find(CurrentCell.MergeArea.Rows.Address(,, 2),

					    CurrentCell.Address(,, 2)) = 1) Then

						

						SlcCell = SprDoc.Area(

						                       CurrentString,

						                       CurrentColumn,

											   (CurrentString + CurrentCell.MergeArea.Rows.Count - 1),

											   (CurrentColumn + CurrentCell.MergeArea.Columns.Count - 1)

											  );

						SlcCell.Merge();

						

					EndIf;

						

				Except

					

					Message(ErrorDescription());

					

				EndTry;	

								

			EndDo;

			

			frmProgressBar.Controls.ProgressBarCur.Value = frmProgressBar.Controls.ProgressBarCur.Value + 1; 

			UserInterruptProcessing(); // Прерывание пользователя Ctrl+Break



		EndDo;

		

		SprDoc.Show("" + TrimAll(FileName) + ", лист " + NumberSheet,"");

		

	EndDo;	

	

	frmProgressBar.Close();

		

	ExcelApplication = "";

	

EndProcedure // ButtonExecuteClick()

Категория: Работа с Microsoft Office и OpenOffice

Как закрепить шапку таблицы отчета?

Код 1C v 8.х

 // Пример от  sergeante   Фиксирует шапку при любых отборах.

Процедура скдФиксироватьШапкуОтчета(ТабДок, Фиксировать, Строка = "Номенклатура", Поправка = 0) Экспорт

    Если Фиксировать Тогда

        Область = ТабДок.НайтиТекст(Строка,,,,Истина);

        ТабДок.ФиксацияСверху = ?(ЗначениеЗаполнено(Область), Область.Верх + Поправка, 0);    

    Иначе

        ТабДок.ФиксацияСверху = 0;

    КонецЕсли; 

КонецПроцедуры

Код 1C v 8.х

  // Пример от i-rek

   ПроцессорВывода.НачатьВывод(); 



    ТаблицаЗафиксирована = Ложь;

    Пока Истина Цикл

        ЭлементРезультата = ПроцессорКомпоновкиДанных.Следующий();

         Если ЭлементРезультата= Неопределено Тогда

            Прервать;     

         Иначе     

            ПроцессорВывода.ВывестиЭлемент(ЭлементРезультата);

            Если Не ТаблицаЗафиксирована И ЭлементРезультата.ЗначенияПараметров.Количество() >  0 Тогда

                ТаблицаЗафиксирована = Истина;

                Таб.ФиксацияСверху = Таб.ВысотаТаблицы;

              КонецЕсли;

         КонецЕсли;

    КонецЦикла;

    ПроцессорВывода.ЗакончитьВывод();

Код 1C v 8.х

 // Пример от Kashemir

Процедура глВывестиРезультатКомпоновкиСАвтофиксациейСтрок( Таб, 

                                                            ПроцессорКомпоновкиДанных, 

                                                            ЭлементыРасшировки,

                                                             Знач МассивИгнорируемыхПолей = Неопределено, 

                                                            РазрешитьПрерывание = Истина) Экспорт 

 

 ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

 ПроцессорВывода.УстановитьДокумент(Таб);

 ПроцессорВывода.НачатьВывод();

 ФиксацияВыполнена = Ложь;

 Если МассивИгнорируемыхПолей = Неопределено Тогда

     МассивИгнорируемыхПолей = Новый Массив;

 КонецЕсли; 

 Пока Истина Цикл

     ЭлементРезультатаКомпоновкиДанных = ПроцессорКомпоновкиДанных.Следующий();

     Если ЭлементРезультатаКомпоновкиДанных = Неопределено Тогда

         Прервать;

     КонецЕсли;

     

     // Автофиксация 

     Если Не ФиксацияВыполнена Тогда

         Для Каждого ЗначениеПараметра Из ЭлементРезультатаКомпоновкиДанных.ЗначенияПараметров Цикл

             Если ТипЗнч(ЗначениеПараметра.Значение) = Тип("ИдентификаторРасшифровкиКомпоновкиДанных") Тогда

                 ЗначенияПолейРасшифровки = ЭлементыРасшировки[ЗначениеПараметра.Значение].ПолучитьПоля();

                 Для Каждого ЗначениеПоляРасшифровки Из ЗначенияПолейРасшифровки Цикл

                     Если МассивИгнорируемыхПолей.Найти(ЗначениеПоляРасшифровки.Поле) = Неопределено Тогда

                         Таб.ФиксацияСверху = Таб.ВысотаТаблицы;

                         ФиксацияВыполнена = Истина;

                         Прервать;

                     КонецЕсли;

                 КонецЦикла;

                 Если ФиксацияВыполнена Тогда

                     Прервать;

                 КонецЕсли;

             КонецЕсли;

         КонецЦикла;

     КонецЕсли;

     

     ПроцессорВывода.ВывестиЭлемент(ЭлементРезультатаКомпоновкиДанных);

     Если РазрешитьПрерывание Тогда

         #Если Клиент тогда 

         ОбработкаПрерыванияПользователя();

         #КонецЕсли 

     КонецЕсли; 

 КонецЦикла;

 ПроцессорВывода.ЗакончитьВывод();

 

КонецПроцедуры

Категория: Схема Компоновки Данных

Создать элемент в нужной группе

Код 1C v 8.х

 КодГруппы = "123100"; 

ПоискПоПолномуКоду = Ложь; // значение по умолчанию 

Группа = Справочники.Номенклатура.НайтиПоКоду(КодГруппы, ПоискПоПолномуКоду); 

Если Группа.Пустая() Тогда 

	Группа = Справочники.Номенклатура.СоздатьГруппу(); 

	Группа.Код = КодГруппы; 

	Группа.Наименование = "Загруженные"; 

	Группа.Записать(); 

ИначеЕсли Не Группа.ЭтоГруппа Тогда 

	Сообщить("Найден элемент справочника с указанным кодом!"); 

	// Предусмотреть прерывание алгоритма.

КонецЕсли; 



Спр = Справочники.Номенклатура.СоздатьЭлемент(); 

Спр.Наименование = "Программно созданный"; 



// Реквизиты заполняются в соответствии с задачей.  



Спр.Родитель = Группа.Ссылка; 

Спр.Записать(); 



Группа = Справочники.Номенклатура.Загруженные; 



КодЭлемента = "46245"; 

ПоискПоПолномуКоду = Ложь; //Значение по умолчанию 

Родитель = Справочники.Номенклатура.НайтиПоКоду(КодЭлемента, ПоискПоПолномуКоду); 



Если Родитель.Пустая() Тогда 

	Родитель = Справочники.Номенклатура.СоздатьЭлемент(); 

	Родитель.Код = КодЭлемента; 

	Родитель.Наименование = "Загруженные"; 

	Родитель.Записать(); 

КонецЕсли; 



Спр = Справочники.Номенклатура.СоздатьЭлемент(); 

Спр.Наименование = "Программно созданный"; 

// Реквизиты заполняются в соотвествии с задачей. 

Спр.Родитель = Родитель.Ссылка; 

Спр.Записать();

Категория: Справочники