примером » Поиск

Результаты по ключевому слову: примером

Универсальный парсер RSS для 1С

На одном проекте - клиент попросил отображать в программе данные, которые выдаю специализированные сайта в формате RSS - Что делать !?

Писать парсер rss для 1С

Первым делом, взглянув на ссылки, подумал что - обычный XML, сейчас его разложу и быстренько загружу в базу, но:

Выяснилось что сайты имеют разные форматы ввода RSS и главное они не валидные(

таким образом, написав небольшой код, который получает ссылку, далее XMLФайл.Прочитать() на одном сайте проходил на ура (этот пример я описывал в статье: Чтение данных с сайта в формате XML и загрузка в 1С), а вот второй сайт, и третий тоже, при попытке прочитать() выдавали:

{ОбщийМодуль.РегЗадания.Модуль(79)}: Ошибка при вызове метода контекста (Прочитать)

Пока XMLФайл.Прочитать() Цикл

по причине:

Ошибка разбора XML: - [1,1]

Фатальная ошибка:

Extra content at the end of the document

SystemId url rss

решил попробовать на rss других известных сайтов - 80% из проверяемых выдавали ошибку

Пришлось написать прямой построчный парсер RSS:

Структура конфигурации

ИсточникиRSS - URL на RSS, ДанныеRSS - сюда записываются загруженные данные новостей

Код получился таким(в принципе код универсальный, но возможно что-то придется подпилить):

Код 1C v 8.3

 

// RSS

Процедура ПрочитатьRSS(ИсточникRSS)

	url = ИсточникRSS.UrlRSS;

	

	// Получим Сервер

	Если Найти(url,".ru")>0 Тогда urlСервер = Лев(url,Найти(url,".ru")+2);	

	ИначеЕсли Найти(url,".com")>0 Тогда urlСервер = Лев(url,Найти(url,".com")+3);

	ИначеЕсли Найти(url,".org")>0 Тогда urlСервер = Лев(url,Найти(url,".org")+3);

	ИначеЕсли Найти(url,".info")>0 Тогда urlСервер = Лев(url,Найти(url,".info")+4);

	ИначеЕсли Найти(url,".pro")>0 Тогда urlСервер = Лев(url,Найти(url,".pro")+3);

	КонецЕсли;	 		

		

	//Определим тип соединения

	Если Лев(url,5)="https" Тогда

		//ssl = Новый ЗащищенноеСоединениеOpenSSL(Новый СертификатКлиентаWindows(), Новый СертификатыУдостоверяющихЦентровWindows());   

		ssl = Новый ЗащищенноеСоединениеOpenSSL( неопределено, неопределено );

		ТекАдрес = СтрЗаменить(url,urlСервер,""); Сервер = СтрЗаменить(urlСервер,"https://",""); 

		Соединение = Новый HTTPСоединение(Сервер,,,,,

		5, // таймаут в секундах

		ssl // защищенное HTTPS соединение

		);

	Иначе //Обычный HTTP 		

		ТекАдрес = СтрЗаменить(url,urlСервер,""); Сервер = СтрЗаменить(urlСервер,"http://","");

		Соединение = Новый HTTPСоединение(Сервер);

	КонецЕсли;





	Заголовки = Новый Соответствие;

	Заголовки.Вставить("host", Сервер);  

	Запрос = Новый HTTPЗапрос(ТекАдрес, Заголовки);

	Ответ =Соединение.Получить(Запрос);

	Если Ответ.КодСостояния = 200 Тогда // Данные получены, обрабатываем их

		Содержимое= Ответ.ПолучитьТелоКакСтроку();

		//Преобразуем содержимое

		Содержимое = СтрЗаменить(Содержимое,"<br/>","|"); 

		Содержимое = СтрЗаменить(Содержимое,"<![CDATA[",""); Содержимое = СтрЗаменить(Содержимое,"]]>","");  

		Содержимое = СтрЗаменить(Содержимое,Символы.ПС,""); Содержимое = СтрЗаменить(Содержимое,Символы.ВК,""); 

		Содержимое = СтрЗаменить(Содержимое,Символы.ВТаб,""); Содержимое = СтрЗаменить(Содержимое,Символы.Таб,""); 

		Содержимое = СтрЗаменить(Содержимое,"><",">"+Символы.ПС+"<"); 

		

		RegExp = Новый COMОбъект("VBScript.RegExp"); //Регулярка

		RegExp.IgnoreCase = Ложь; 

		RegExp.Global = Истина;    

		RegExp.MultiLine = Истина;   		

		RegExp.Pattern = "<[^>]*>"; //Ищем теги HTML   

		

		//Разберем полученный текст в таблицу

		ЭтоЗапись=Ложь;

		Для н=1 По СтрЧислоСтрок(Содержимое)Цикл

			обрТекст=СтрПолучитьСтроку(Содержимое,н);

			

			Если обрТекст = "<item>" Тогда //Началась запись 

				ЗаписьСтр = Новый Структура(); ЭтоЗапись=Истина; Продолжить;  

			ИначеЕсли обрТекст = "</item>" Тогда //Закончилась запись 

				

				/////////////// ЗАПИСЬ Закончилась //////////////

				/// теперь запишем ее в базу - Справочник ДанныеRSS

				// сначала ПОИСК ДУБЛЕЙ - вдруг уже загружен 				

				Запрос = Новый Запрос;

				Запрос.Текст = 

				"ВЫБРАТЬ

				|	ДанныеRSS.Ссылка

				|ИЗ

				|	Справочник.ДанныеRSS КАК ДанныеRSS

				|ГДЕ

				|	ДанныеRSS.ИсточникRSS =ИсточникRSS

				|	И ДанныеRSS.link ПОДОБНОlink";

				

				Запрос.УстановитьПараметр("link", "%"+ЗаписьСтр.link+"%");

				Запрос.УстановитьПараметр("ИсточникRSS", ИсточникRSS);				

				РезультатЗапроса = Запрос.Выполнить().Выбрать();

				Если РезультатЗапроса.Следующий() Тогда

					// Такая запись уже есть, пока ничего не делаем

				Иначе

					//СОЗДАЕМ Новый

					НовЭлем  = Справочники.ДанныеRSS.СоздатьЭлемент();

					ЗаполнитьЗначенияСвойств(НовЭлем,ЗаписьСтр);

					НовЭлем.ИсточникRSS = ИсточникRSS;

					НовЭлем.Записать(); 					

				КонецЕсли; 				

				/////////////////////// *** /////////////////////

				

				ЭтоЗапись=Ложь; Продолжить; 

			КонецЕсли; //Данные записи

			

			Если ЭтоЗапись Тогда	

				Если Найти(обрТекст,"title>")>0 и Найти(обрТекст,"/title>")>0 Тогда				

					обрТекст = СтрЗаменить(обрТекст,"title",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					ЗаписьСтр.Вставить("Наименование",СокрЛП(обрТекст));

				КонецЕсли;

				

				Если Найти(обрТекст,"link>")>0 и Найти(обрТекст,"/link>")>0 Тогда				

					обрТекст = СтрЗаменить(обрТекст,"link",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					ЗаписьСтр.Вставить("link",СокрЛП(обрТекст));

				КонецЕсли;

				

				Если Найти(обрТекст,"description>")>0 и Найти(обрТекст,"/description>")>0 Тогда			

					обрТекст = СтрЗаменить(обрТекст,"description",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					обрТекст=RegExp.Replace(обрТекст, ""); //Удалим все теги

					ЗаписьСтр.Вставить("desc",СокрЛП(обрТекст));

				КонецЕсли;

				

				Если Найти(обрТекст,"pubDate>")>0 и Найти(обрТекст,"/pubDate>")>0 Тогда			

					обрТекст = СтрЗаменить(обрТекст,"pubDate",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					ЗаписьСтр.Вставить("pubDate",ПреобразоватьRFC822КДате0(СокрЛП(обрТекст)));

				КонецЕсли;

				

				Если Найти(обрТекст,"enclosure")>0 Тогда					 

					обрТекст = СтрЗаменить(обрТекст,"""",""); обрТекст = СтрЗаменить(обрТекст,"<enclosure url=","");

					обрТекст = СтрЗаменить(обрТекст,"<enclosure url=",""); обрТекст = СтрЗаменить(обрТекст,"type=image/png length=/>","");

					ЗаписьСтр.Вставить("img",СокрЛП(обрТекст));

				КонецЕсли;

			КонецЕсли;	

							

		КонецЦикла;

		

	КонецЕсли;

	

КонецПроцедуры	









Процедура ПроверкаRSS() Экспорт

	Запрос = Новый Запрос;

	Запрос.Текст = 

	"ВЫБРАТЬ

	|	ИсточникиRSS.Ссылка КАК Ссылка

	|ИЗ

	|	Справочник.ИсточникиRSS КАК ИсточникиRSS

	|ГДЕ

	|	ИсточникиRSS.Использовать

	|	И ДОБАВИТЬКДАТЕ(ИсточникиRSS.ДатаПоследнегоОбновления, СЕКУНДА, ИсточникиRSS.ПериодОбновленияВСекундах) <ТекДата"; 	

	Запрос.УстановитьПараметр("ТекДата", ТекущаяДата());

	РезультатЗапроса = Запрос.Выполнить();

	ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

	Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

		ПрочитатьRSS(ВыборкаДетальныеЗаписи.Ссылка);

		// Запишем дату последнего обновления

		ТекОб = ВыборкаДетальныеЗаписи.Ссылка.ПолучитьОбъект();

		ТекОб.ДатаПоследнегоОбновления = ТекущаяДата();

		ТекОб.Записать();

	КонецЦикла;

КонецПроцедуры



Функция ПреобразоватьRFC822КДате0(ДатаВФорматеRFC822) Экспорт

    КопияСтроки = ДатаВФорматеRFC822;

    СтруктураДаты = Новый Структура("Год,Месяц,День,Час,Минута,Секунда",  "","","","","","");

    Месяцы = Новый Структура("Jan,Feb,Mar,Apr,May,Jun,Jul,Aug,Sep,Oct,Nov,Dec",  "01","02","03","04","05","06","07","08","09","10","11","12");

    Для каждого КлючИЗначение Из Месяцы Цикл

        Позиция = Найти(КопияСтроки,КлючИЗначение.Ключ);

        Если Позиция > 0  Тогда

             СтруктураДаты.Месяц = КлючИЗначение.Значение;

            Прервать;

        КонецЕсли;

    КонецЦикла; 

	Состояние = 0;

	КопияСтроки = СтрЗаменить(КопияСтроки,", 1 ",", 01 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 2 ",", 02 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 3 ",", 03 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 4 ",", 04 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 5 ",", 05 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 6 ",", 06 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 7 ",", 07 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 8 ",", 08 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 9 ",", 09 ");

	Для ш=0 По СтрДлина(КопияСтроки) Цикл

        ТекущийСимвол = Сред(КопияСтроки,ш,1); //ПолучитьСимвол(КопияСтроки, ш);

        ТекСимволЦифра= ЭтоЦифра(ТекущийСимвол);

        Если ТекСимволЦифра И Состояние = 0  Тогда

            СтруктураДаты.День = СтруктураДаты.День + ТекущийСимвол;

            Состояние = 1; //начало день

        ИначеЕсли ТекСимволЦифра И Состояние = 1  Тогда

            СтруктураДаты.День = СтруктураДаты.День + ТекущийСимвол;

            Состояние = 2; //ждем год

        ИначеЕсли ТекСимволЦифра И Состояние = 2  Тогда

            СтруктураДаты.Год = СтруктураДаты.Год + ТекущийСимвол;

            Состояние = 3; //продолжаем год

        ИначеЕсли ТекСимволЦифра И Состояние = 3  Тогда

            СтруктураДаты.Год = СтруктураДаты.Год + ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = " " И Состояние = 3 Тогда

               Состояние = 4; //дальше час    

        ИначеЕсли ТекСимволЦифра И Состояние = 4  Тогда

            СтруктураДаты.Час = СтруктураДаты.Час + ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = ":" И Состояние = 4  Тогда

            Состояние = 5; //дальше минута

        ИначеЕсли ТекСимволЦифра И Состояние = 5  Тогда

            СтруктураДаты.Минута = СтруктураДаты.Минута +  ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = ":" И Состояние = 5  Тогда

            Состояние = 6; //дальше секунда

        ИначеЕсли ТекСимволЦифра И Состояние = 6  Тогда

            СтруктураДаты.Секунда = СтруктураДаты.Секунда +  ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = " " И Состояние = 6 Тогда

            Прервать;

        КонецЕсли;

    КонецЦикла;

    Попытка

        Результат = Дата(СтруктураДаты.Год+СтруктураДаты.Месяц+СтруктураДаты.День

                        +СтруктураДаты.Час+СтруктураДаты.Минута+СтруктураДаты.Секунда);

    Исключение

        Результат = Неопределено;    

    КонецПопытки;

    Возврат Результат;

КонецФункции



Функция ЭтоЦифра(Символ) Экспорт

     Если (КодСимвола(Символ)>=48) И (КодСимвола(Символ)<=57) Тогда Возврат Истина; Иначе Возврат ложь; КонецЕсли;

КонецФункции



Функция ПолучитьСимвол(КопияСтроки, ш)

	Возврат Сред(КопияСтроки,ш,1);

КонецФункции

Результат загрузки новостей RSS HelpF.pro

Кстати, как позже выяснилось, здесь уже есть статья с примером через IE и DOM: Получения новостей с RSS-канала сайта buh.ru

Категория: Работа с Интернет, Почтой (Mail), FTP

Пример хранения изображений в базе (отдельный справочник), в интерфейсе Такси и без модальности

Часто разрабатывая некую конфигурацию, пользователи хотят прикреплять к элементу справочника фото и чтобы они хранились в базе данных.

В этой статье я расскажу как к справочнику объекты строительства подключить хранилище фотографий в виде справочника Хранилище файлов.

Основные элементы конфигурации с которыми нам работать:

1. Справочник Объекты строительства - основной справочник в котором хранится инфо и к каждому элементу нужно подгружать фото

2. Справочник Хранилище Фалов, он подчинен справочнику Объекты строительства и в нем есть реквизит ДанныеХЗ - хранилище значений в котором мы будем хранить фото

Форма элемента Объекты строительства, добавим кнопку загрузить фото для списка Файлы (динамический список, в котором запросом отбирается по владельцу приложенные файлы)

Код команды Добавить Файлы (Код для отключенного режима модальности):

Код 1C v 8.3

 &НаКлиенте

Процедура ДобавитьФайлы()

//ПРОВЕРИМ - текущий элемент записан или нет

	Если ЗначениеЗаполнено(Объект.Ссылка) Тогда // Записан

		Оповещение  =  Новый ОписаниеОповещения("ОбработатьВыборФайла",   ЭтотОбъект);

		НачатьПомещениеФайла(Оповещение,   ,   ,   Истина,   УникальныйИдентификатор);

	Иначе // НЕ записан, нужно спросить пользователя

		Оповещение = Новый ОписаниеОповещения("ОтветНаВопросЗаписать", ЭтотОбъект);

		ТекстВопроса = "Элемент не записан, Записать?";

		ПоказатьВопрос(Оповещение, ТекстВопроса, РежимДиалогаВопрос.ДаНет);		

	КонецЕсли;	  

КонецПроцедуры



//вопрос пользователю

&НаКлиенте 

Процедура ОтветНаВопросЗаписать(Результат, ДополнительныеПараметры) Экспорт 

// Вопрос пользователю, если ДА, то записываем объект и снова вызываем добавить файлы

	Если Результат = КодВозвратаДиалога.Да Тогда

		 ЭтотОбъект.Записать();

		 ДобавитьФайлы();

	КонецЕсли;

КонецПроцедуры 



// После диалога выбора файла срабатывает это оповещение, в котором мы сохраняем файл с справочник Хранилище файлов

&НаКлиенте

Процедура ОбработатьВыборФайла(Результат, Адрес, ВыбранноеИмяФайла, ДополнительныеПараметры) Экспорт

Если Не Результат Тогда

 Возврат; 

КонецЕсли;

//Получим данные файла

ОписаниеФайла = Новый Файл(ВыбранноеИмяФайла);

//Сохраним в справочник ХранилищеФайлов

СохранитьФайлВХранилище(Адрес,Объект.Ссылка,ОписаниеФайла.ИмяБезРасширения);

//обновим список файлы, т.к. там добавися новый файл

Элементы.Файлы.Обновить();

ЭтаФорма.ОбновитьОтображениеДанных();

КонецПроцедуры



// Сохранение файла в справочник

&НаСервереБезКонтекста

Процедура СохранитьФайлВХранилище(Адрес,Владелец,Имя)

	НовФайл = Справочники.ХранилищеФайлов.СоздатьЭлемент();

	НовФайл.Владелец = Владелец;

	НовФайл.Наименование = Имя;

	НовФайл.ДанныеТекущаяДата = ТекущаяДата();

	НовФайл.ДанныеХЗ = Новый ХранилищеЗначения(ПолучитьИзВременногоХранилища(Адрес));

	НовФайл.Записать();

КонецПроцедуры

файлы записаны, далее если файлов много, то пользователь может перемещаться по списку файлов и ему должны показываться файлы

Добавим для списка файлы Событие ФайлыПриАктивизацииСтроки

Код 1C v 8.3

 &НаКлиенте

Процедура ФайлыПриАктивизацииСтроки(Элемент)

	Попытка

		ТекКартинка = ФайлыПриАктивизацииСтрокиНаСервере(Элемент.ТекущиеДанные.Ссылка); 

	Исключение

		//видимо нет еще фото

	КонецПопытки;	

КонецПроцедуры





&НаСервереБезКонтекста

Функция ФайлыПриАктивизацииСтрокиНаСервере(ЭлементС)

	Возврат ПолучитьНавигационнуюСсылку(ЭлементС, "ДанныеХЗ");

КонецФункции

+ чуть не забыл, т.к. файлы это динамический список с установленным запросом и параметром - необходимо при открытии задать параметр:

Установим параметр при открытии:

Код 1C v 8.3

 &НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

	Файлы.Параметры.УстановитьЗначениеПараметра("Владелец",Объект.Ссылка);

КонецПроцедуры

Результат:

Скачать DT с примером : Foto_V_BD.7z

Если у Вас есть вопросы или комментарии - пишите ниже, обсудим

Категория: 1С Общие вопросы - Управляемые формы и Такс…

Запись во внешний источник данных из 1С 8.3 (без com подключения)

В 8.3.4 в свойствах объекта "Внешний источник данных" появилась вкладка "Функции". Для внешних таблиц MSSQL данный функционал позволяет подключить к 1С хранимые процедуры и функции на стороне SQL. В том числе и процедуры, содержащие запросы SQL на добавление и обновление данных внешней таблицы.

По сравнению с прошлым примером количество кода 1С уменьшится, поскольку подключение через COM-объект и формирование запросов SQL на стороне 1С нам больше не потребуется.

Для начала создадим тестовую таблицу с помощью скрипта в панели управления сервером SQL:

Код SQL

 USE [test]

GO



SET ANSI_NULLS ON

GO



SET QUOTED_IDENTIFIER ON

GO



CREATE TABLE [dbo].[tovar](

 [id] [int] IDENTITY(1,1) NOT NULL,

 [name] [nvarchar](max) NOT NULL,

 [price] [numeric](18, 2) NULL,

 CONSTRAINT [PK_tovar] PRIMARY KEY CLUSTERED

(

 [id] ASC

)WITH (PAD_INDEX  = OFF, STATISTICS_NORECOMPUTE  = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS  = ON, ALLOW_PAGE_LOCKS  = ON) ON [PRIMARY]

) ON [PRIMARY]



GO

Скрипт создания процедуры insert_tovar:

Код SQL

 SET ANSI_NULLS ON

GO

SET QUOTED_IDENTIFIER ON

GO



CREATE PROCEDURE insert_tovar



 @name nvarchar(max),

 @price numeric(18, 2)



AS

BEGIN



 SET NOCOUNT ON;



 INSERT INTO test.dbo.tovar

    ([name] ,[price])

    VALUES (@name, @price)



END

GO

Скрипт создания процедуры update_tovar:

Код SQL

 SET ANSI_NULLS ON

GO

SET QUOTED_IDENTIFIER ON

GO



CREATE PROCEDURE update_tovar



 @id int,

 @name nvarchar(max),

 @price numeric(18, 2)



AS

BEGIN



 SET NOCOUNT ON;



 UPDATE test.dbo.tovar

    SET [name] = @name

    ,[price] = @price

 WHERE id = @id 

 

END

GO

Теперь переходим в 1С и добавляем внешний источник данных. Подключаем таблицу SQL:

Подключаем процедуры:

Далее, для таблицы dbo_tovar создаем формы списка и объекта. На форму списка вешаем команду "ДобавитьТовар" и обработку оповещения:

Код 1C v 8.3

 &НаКлиенте

Процедура ДобавитьТовар(Команда)

 

 ОткрытьФорму("ВнешнийИсточникДанных.test.Таблица.dbo_tovar.ФормаОбъекта", , ЭтаФорма);

 

КонецПроцедуры





&НаКлиенте

Процедура ОбработкаОповещения(ИмяСобытия, Параметр, Источник)

 

 Если ИмяСобытия = "ОбновитьВнешнийИсточникДанных_dbo_tovar" Тогда

  Элементы.Список.Обновить();

 КонецЕсли; 

 

КонецПроцедуры

На форме объекта на командной панели размещаем команду "ЗаписатьТовар", для кнопки выставляем свойство "Кнопка по умолчанию":

Код 1C v 8.3

 &НаКлиенте

Процедура ЗаписатьТовар(Команда)

 

 ЗаписатьТоварНаСервере();

 Оповестить("ОбновитьВнешнийИсточникДанных_dbo_tovar");

 

КонецПроцедуры





&НаСервере

Процедура ЗаписатьТоварНаСервере()

 

 Если Объект.Ссылка.Пустая() Тогда

  ВнешниеИсточникиДанных.test.dbo_insert_tovar(Объект.name, Объект.price);

 Иначе

  ВнешниеИсточникиДанных.test.dbo_update_tovar(Объект.id, Объект.name, Объект.price);

 КонецЕсли;

 

КонецПроцедуры

Для свойства реквизита "Объект" снимаем свойство "Сохраняемые данные", для поля "id" устанавливаем свойство "Только просмотр".

Готово, запускаем, тестируем. Для тестов использовался сервер MSSQL Server 2008 R2.

Источник

Категория: Внешние источники данных

Установка Сервера 1С и PostgreSQL на Ubuntu Linux

Установка сервера 1С на Ubuntu Linux

Видео с примером установки PostgreSQL для сервера 1С на Ubuntu Linux и предварительной настройкой СУБД

Юрий Пермитин

Категория: Администрирование

Парсер сайта на 1С

В этой статье я постараюсь описать процесс парсинга сайтов средствами 1С с примером.
Это статья не является инструкцией к применению, а лишь демонстрирует возможности 1С.

Что мы имеем?
1. Сайт в интернете, на котором располагается список товаров. В моем случае – это интернет магазин салона «Связной»
2. Понимание основ сайтостроения… хотя бы знание HTML тегов
3. Умение кодить в 1С 8

Для начала парсинга стоит определиться с тем что мы хотим спарсить и какая у нас будет иерархия. В моем случае это категория сотовых телефонов. Верхний уровень иерархии будет производители. Почему именно так? Потомы что я так захотел. Вы же вправе использовать любую иерархию.

Далее нам будут интересны такие поля как: Наименование, Цена, Картинка и Описание... ну и пожалую захватим операционную систему, чтобы пример получился более наглядным.

1. Создаем внешнюю обработку. Те, кто не знают как это сделать - дальше могут не читать
2. Создаем форму обработки с командной панелью снизу и сверху (они могут быть полезными)
3. Размещаем на ней Панель и обзываем первую страницу "СамСайт"
4. Кладем на страницу "СамСайт" ПолеHTMLДокумента и обзываем его к примеру "Сайт"
5. Переименовываем кнопку "Выполнить", которая находится на нижней панели в "Загрузить сайт"
6. Описываем процедуру нажатия на эту кнопку так:

Код 1C v 8.х

   ЭлементыФормы.Сайт.Перейти("http://www.svyaznoy.ru/catalog/phone/224"); //Категория с мобильными телефонами

7. Проверяем работу нашей обработки. У меня появился сайт связного. А у Вас?

Дальше сложнее. Все еще хочешь парсить сайты? Тогда читай:

Сам парсинг сайта заключается в обходе всех элементов загруженной страницы, выдергивания необходимой информации и запихивания их в табличную часть. Для этого:
1. Создадим табличную часть "Производители" с реквизитами "Отметка" (Булево), "Наименование" (Строка 100) и "Ссылка" (Строка 300).
2. Добавляем еще одну страницу на панели и обзываем ее "Производители"
3. Размещаем на этой странице одноименную табличную часть
4. Добавляем на нижней панели кнопку "Заполнить производителей" с кодом:

Код 1C v 8.х

        Для Каждого Стр из ЭлементыФормы.Сайт.Документ.body.all Цикл

              Если Стр.tagName = "H1" и Стр.innerText = "Производители" Тогда

                  Для Каждого опСтр из Стр.nextSibling.children Цикл

                      новСтр = Производители.Добавить();

                      новСтр.Наименование = опСтр.innerText;

                      новСтр.Ссылка = опСтр.firstChild.href;

                  КонецЦикла;

                  Возврат;

              КонецЕсли;

          КонецЦикла;

Здесь напрашиваются небольшие пояснения:
tagName - имя HTML тега в HTML документе
nextSubling - следующий элемент HTML документа от текущего
children - список дочерних элементов
firstChild - первый дочерний элемент от текущего
5. Проверям. При проверке важно, находиться на странице "СамСайт", чтобы заполнять производителей

Производители заполнены. Теперь к самим телефонам

1. Создаем табличную часть "Товары" с реквизитами "Производитель" (Строка 100), "Наименование" (Строка 100), "Цена" (Число 10,2), "Картинка" (Строка 300), "Описание" (Строка Неограниченная), "ОС" (строка 100), "Ссылка" (Строка,300)
2. Добавляем еще одну страницу на панели и обзываем ее "Товары"
3. Размещаем на этой странице одноименную табличную часть
4. Добавляем на нижней панели кнопку "Заполнить товары" с кодом:

Код 1C v 8.х

       Для Каждого Стр из Производители Цикл

          //Если отметку сняли - то не трогаем этого производителя

          Если Не Стр.Отметка Тогда

              Продолжить;

          КонецЕсли;

          Форма = ПолучитьФорму("ФормаТоваров");

          Форма.ЭлементыФормы.Сайт.Перейти(Стр.Ссылка);

          Форма.ТекущийПроизводитель = Стр;

          Форма.ОткрытьМодально();

      КонецЦикла;

5. Создаем форму обработки "ФормаТоваров"
6. Кладем на "ФормаТоваров" ПолеHTMLДокумента и называем его "Сайт"
7. На событие ДкументСформирован у ПоляHTMLДокумента пишем код:

Код 1C v 8.х

  Если ЭлементыФормы.Сайт.Документ.body.all.length>1 Тогда

          ГрузимТовары();

      КонецЕсли;

8. Создаем переменную в модуле формы
перем ТекущийПроизводитель Экспорт;
9. Создаем процедуру ГрузимТовары():

Код 1C v 8.х

       Процедура ГрузимТовары()

          Для Каждого Стр из ЭлементыФормы.Сайт.Документ.body.all Цикл

              Если Стр.className = "ct_desc cleared" Тогда

                  новСтр = Товары.Добавить();

                  Для Каждого опСтр из Стр.children Цикл

                      Если опСтр.className = "pic_and_comp" Тогда

                          новСтр.Картинка = СтрЗаменить(Сред(опСтр.firstChild.style.backgroundImage,5),")","")

                      КонецЕсли;

                      Если опСтр.className = "name" Тогда

                          новСтр.Наименование = опСтр.innerText;

                          новСтр.Ссылка = опСтр.firstChild.href;

                      КонецЕсли;

                      Если опСтр.className = "price" Тогда

                          новСтр.Цена = Число(СтрЗаменить(СтрЗаменить(опСтр.innerText,"-","")," ",""));

                      КонецЕсли;

                      Если опСтр.className = "desc" Тогда

                          новСтр.Описание = опСтр.innerText;//опСтр.innerHTML - если нужно вместе с тегами 



                      КонецЕсли;

                  КонецЦикла;



              КонецЕсли;



          КонецЦикла;

          Закрыть();

      КонецПроцедуры

10. Проверям. Все работает.

Дело осталось за "операционной системой" и еще надо загрузить картинки. Давайте по порядку. Чтобы получить "ОС" нам надо открыть этот товар и считать "ОС" оттуда. Для этого делаем следующее:

1. Добавляем на нижней панели кнопку "Доп Инфо" с кодом:

Код 1C v 8.х

 Для Каждого Стр из Товары Цикл

          Форма = ПолучитьФорму("ФормаДопИнфо");

          Форма.ЭлементыФормы.Сайт.Перейти(Стр.Ссылка);

          Форма.ТекущийТовар = Стр;

          Форма.ОткрытьМодально();

      КонецЦикла;

2. Создаем форму обработки "ФормаДопИнфо"
3. Кладем на "ФормаДопИнфо" ПолеHTMLДокумента и называем его "Сайт"
4. На событие ДкументСформирован у ПоляHTMLДокумента пишем код:

Код 1C v 8.х

   Если ЭлементыФормы.Сайт.Документ.body.all.length>1 Тогда

          ГрузимДопИнфо();

      КонецЕсли;

5. Создаем переменную в модуле формы
перем ТекущийТовар Экспорт;
6. Создаем процедуру ГрузимДопИнфо():

Код 1C v 8.х

       Процедура ГрузимДопИнфо();

          Для Каждого Стр из ЭлементыФормы.Сайт.Документ.body.all Цикл

              Если Стр.className = "card_spec" Тогда

                  Для Каждого опСтр из Стр.children Цикл

                      Если Найти(опСтр.innerText,"Операционная система:") Тогда

                          ТекущийТовар.ОС = СокрЛП(СтрЗаменить(опСтр.innerText,"Операционная система:",""));

                      КонецЕсли;

                  КонецЦикла;

              КонецЕсли;

          КонецЦикла;

          Закрыть();

      КонецПроцедуры

7. Проверяем и переходим к последнему пункту

Заметили как похожи две последние инструкции? То-то же. Стремился к универсальности. Ну и наконец последний этап - Сохраним все изображения к примеру на диск "С" в папку "связной". Поехали

1. Добавляем на нижней панели кнопку "Сохранить Картинки" с кодом:

Код 1C v 8.х

       Для Каждого Стр из Товары Цикл

              путьСамФайл = Лев(Стр.Картинка,Найти(Стр.Картинка,".jpg/") + 3);

              самФайл = СтрЗаменить(СтрЗаменить(ПутьСамФайл,"http://static.svyaznoy.ru/upload/iblock/",""),"/","");

              Стр.Картинка = СохранитьКартинкуСайта("C:\Svyaznoy",ПутьСамФайл,СамФайл);

          КонецЦикла;

2. Добавляем функцию СохранитьКартинкуСайта:

Код 1C v 8.х

       Функция СохранитьКартинкуСайта(КаталогСохранения,КартинкаНаСайте,КартинкаУНас)

              ИмяФайлаКартинки = КаталогСохранения + "\" + КартинкаУНас;

              ГетЗапрос = Новый COMОбъект("WinHttp.WinHttpRequest.5.1");

              ГетЗапрос.SetTimeouts(10000, 10000, 10000, 10000);

              БазовыйУРЛ = КартинкаНаСайте;

              Хидер1 = "Content-Type";

              Хидер2 = "image/jpg"; // Тип рисунка.

              ГетЗапрос.Open("GET", БазовыйУРЛ, False); // Синхронный режим.

              ГетЗапрос.setRequestHeader(Хидер1, Хидер2);

              ГетЗапрос.Send();

              СтатусОтправки = ГетЗапрос.status;

              Если СтатусОтправки <> 200 Тогда

                  Сообщить("Ошибка отправки запроса на: "

                      + КартинкаНаСайте);

                  Возврат "";

              КонецЕсли;        



              Стрим = Новый COMОбъект("ADODB.Stream");

              Стрим.Mode = 3;

              Стрим.Type = 1;

              Стрим.Open();

              Стрим.Write(ГетЗапрос.responseBody);



              Стрим.SaveToFile(ИмяФайлаКартинки, 2);

              Стрим.Close();

              Возврат ИмяФайлаКартинки;

      КонецФункции

На этом наша эпопея с парсингом закончена. Это всего лишь пример того, как это можно сделать. Приложив сюда немного своего кода - можно сделать парсер для любого сайта. Скачивать файлы может только зарегистрированный пользователь!

Имея парсер 1С - я могу спарсить все, кроме этого парсера. Имя два парсера 1С - я могу спарсить все
Автор: opx

Категория: Работа с Интернет, Почтой (Mail), FTP

Своя функция в вычисляемых полях СКД

В вычисляемых полях СКД можно использовать свои функции расчетов!

для этого необходимо добавить экспорнутю функцию в общий модуль:

Код 1C v 8.х

 Функция МояФункцияДляСКД(ТекЗнач) Экспорт



//... какая-либо обработка ТекЗнач

Возврат ТекЗнач;

КонецФункции

В скд на закладке вычисляемые поля добавляете поле:
указываете Путь к данными и пишете по аналогии с примером:
title

Категория: Схема Компоновки Данных

Произвольный макет в СКД

Делал недавно отчет с неопределенным количеством колонок. Возиться с кодом было неохота, решил сделать на СКД. С этим проблема не возникла, необходимо было натянуть результат на произвольный макет (свой заголовок + период). Покажу на примере по шагам, с чем столкнулся и как решил.

Первоначальную настройку схемы СКД описывать не буду, начнем с того, что мне надо было сделать произвольный заголовок. В нашем случае, формируем представление периода отчета.
Добавляем новый параметр "ПредставлениеПериода", тип Строка.
title

Теперь добавляем новое поле группировки, поля группировок не выбираем (Детальные записи), удаляем поле "Авто", переносим наш параметр.
title

Переходим на вкладку "Макет", рисуем шапку. Добавляем Заголовок группировки. Мы можем использовать Имя группировки, если заранее задали его в схеме компоновки, или выбрать из доступных полей. После этого определяем область в табличном документе. Далее, прописываем наш параметр на макете, потом необходимо будет установить в свойствах этой ячейки свойство "Заполнение" - "Параметр". И в окне параметров макета связать наш параметр с параметром СКД.
title

Теперь немного кода. Создаем форму отчета. Отключаем видимость у Основной Командной Панели и Компоновщика Настроек. Создаем нашу команду "Сформировать", реквизит формы "Дата", перетаскиваем все это на форму. Пишем код в модуле формы:

Код 1C v 8.2 УП

 &НаСервере

Процедура УстановитьПараметрыКомпоновки()



 пОтчета = Отчет.КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы.Найти("Период");

 Если НЕ пОтчета = Неопределено Тогда

  пОтчета.Значение = КонецДня(Дата);

 КонецЕсли;

 ПредставлениеПериода = Отчет.КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы.Найти("ПредставлениеПериода");

 Если НЕ ПредставлениеПериода = Неопределено Тогда

  ПредставлениеПериода.Значение = "Остатки по складам на " + Формат(Дата, "ДЛФ=Д");

 КонецЕсли;

 

КонецПроцедуры



&НаСервере

Процедура СформироватьНаСервере()



 УстановитьПараметрыКомпоновки();

 

 Результат.Очистить();



 СхемаКомпоновкиДанных = РеквизитФормыВЗначение("Отчет").СхемаКомпоновкиДанных;

 КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

 МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Отчет.КомпоновщикНастроек.Настройки, ДанныеРасшифровки);



 ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;

 ПроцессорКомпоновки.Инициализировать(МакетКомпоновки);



 ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

 ПроцессорВывода.УстановитьДокумент(Результат);

 ПроцессорВывода.ОтображатьПроцентВывода = Истина;



 ПроцессорВывода.Вывести(ПроцессорКомпоновки); 



КонецПроцедуры



&НаКлиенте

Процедура Сформировать(Команда)

 

 СформироватьНаСервере();

 

КонецПроцедуры



&НаКлиенте

Процедура ПриОткрытии(Отказ)

 

 Дата = ТекущаяДата();

 

КонецПроцедуры

После этого, если все правильно сделали, результат отчета должен выглядеть вот так:
title

Теперь попробуем сделать полностью свой произвольный макет на СКД .
Здесь самое главное понять структуру областей макета в СКД. Разберем пример с неопределенным количеством колонок.

Заготовка для отчета выглядит так:
title

Пример результата:
title

Теперь создаем свой макет:

1. Добавляем шапку по аналогии с прошлым примером. Устанавливаем макет оформления "Без оформления". Итоги по номенклатуре выводить не будем, поэтому ставим у таблицы настройку "Расположение общих итогов по горизонтали" - "Нет".
title

2. Теперь создаем макет, прописываем параметры, настраиваем дополнительные свойства ячеек. Например, для номенклатуры можно выставить в свойстве "Размещение текста" значение "Переносить" вместо "Авто", а так же указать параметры расшифровки.
title

3. Теперь самое интересное, назначаем области. Структура областей будет выглядеть таким образом:
title

Начинаем создавать области, параметры при этом будут автоматически сопоставляться по именам. В итоге должно получиться следующее:
title

Проверяем отчет, должно получиться следующее:
title

4. Пишем код по аналогии с прошлым примером:

Код 1C v 8.2 УП

 &НаСервере

Процедура УстановитьПараметрыКомпоновки()



 пОтчета = Отчет.КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы.Найти("Период");

 Если НЕ пОтчета = Неопределено Тогда

  пОтчета.Значение = Период;

 КонецЕсли;

 ПредставлениеПериода = Отчет.КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы.Найти("ПредставлениеПериода");

 Если НЕ ПредставлениеПериода = Неопределено Тогда

  ПредставлениеПериода.Значение = "Заказы контрагентов за " + Формат(Период.ДатаНачала, "ДЛФ=Д") + " - " + Формат(Период.ДатаОкончания, "ДЛФ=Д");

 КонецЕсли;

 

КонецПроцедуры



&НаСервере

Процедура СформироватьНаСервере()



 УстановитьПараметрыКомпоновки();

 

 Результат.Очистить();



 СхемаКомпоновкиДанных = РеквизитФормыВЗначение("Отчет").СхемаКомпоновкиДанных;

 КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

 МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Отчет.КомпоновщикНастроек.Настройки, ДанныеРасшифровки);



 ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;

 ПроцессорКомпоновки.Инициализировать(МакетКомпоновки);



 ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

 ПроцессорВывода.УстановитьДокумент(Результат);

 ПроцессорВывода.ОтображатьПроцентВывода = Истина;



 ПроцессорВывода.Вывести(ПроцессорКомпоновки); 

 

 //решил добавить колонтитулы 

 Результат.НижнийКолонтитул.Выводить = Истина; 

 Результат.НижнийКолонтитул.НачальнаяСтраница = 1;

 ШрифтКолонтитула=Новый Шрифт("Arial", 6);

    Результат.НижнийКолонтитул.Шрифт=ШрифтКолонтитула;

 Результат.НижнийКолонтитул.ТекстСлева  = "Тест СКД";



КонецПроцедуры



&НаКлиенте

Процедура Сформировать(Команда)

 

 СформироватьНаСервере();

 

КонецПроцедуры





&НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

 

 Период.ДатаНачала = НачалоМесяца(ТекущаяДата());

 Период.ДатаОкончания = ТекущаяДата();

 

КонецПроцедуры

В итоге у нас получается следующее:
title

Кстати, при последующем открытии отчета, вы увидите, что компоновка перестроила макет по-своему.
title

Это вполне нормально, не стоит беспокоиться.

Источник: http://start1c.blogspot.ru

Категория: Схема Компоновки Данных

Как в запросе отобрать значения по Типу?

Для того, чтобы определить отобрать по типу значения в запросе нужно использовать логический оператор "ССЫЛКА". Примером может служить вот такой фрагмент запроса из типовой конфигурации 1С:

Код 1C v 8.х

     Запрос = Новый Запрос;

    Запрос.Текст =     "ВЫБРАТЬ

                       |    ХозрасчетныйОстатки.Субконто1 КАК Покупатель

                       |ИЗ

                       |    РегистрБухгалтерии.Хозрасчетный.Остатки(

                       |            &Период,

                       |            Счет = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.НДСНачисленныйПоОтгрузке),

                       |            ,

                       |            Организация = &Организация

                       |                И Субконто2 ССЫЛКА Документ.РеализацияТоваровУслуг

                       |                И Субконто1 В (&СписокПокупателей)

                       |                И ВЫРАЗИТЬ(Субконто2 КАК Документ.РеализацияТоваровУслуг).ВидОперации = 

                       |                       &ОперацияОтгрузка) КАК ХозрасчетныйОстатки";

В данном примере используется проверка, что субконто 2 содержит тип значения ссылки на документ Реализации товаров и услуг, чтобы потом уверенно использовать реквизит вид операции.

Категория: Запросы

Ограничение доступа на уровне записей RLS

Когда требуется более тонкая настройка доступа, на помощь приходит механизм RLS - Record Level Security.

Конфигурации системы «1С:Предприятие» 8 изначально позиционировалась как программа для многофирменного учета, и один из первых возникающих вопросов – как бы сделать так, что бы пользователь видел только те данные, которые ему положено видеть, и никакие другие? Конечно, есть роли, с помощью которых можно разрешить или запретить то или иное действие над объектом конфигурации, есть интерфейсы, позволяющие минимизировать пункты меню. Но как быть в случае, когда к одному и тому же объекту конфигурации нужно организовать «интеллектуальный» доступ, скрывающий только определенный записи? Ярким примером служит справочник «Организации»: учет в базе ведется по нескольким фирмам, справочник физически один, документы по фирмам ведутся одни и те же. Понятно, что в этом случае в назначенных ролях пользователя нельзя просто убрать права на чтение и просмотр, нужна более детальная настройка - RLS.

Ограничения RLS можно задавать для следующих действий над объектами базы данных:
- Чтение – получение записей из таблицы базы данных;
- Добавление – добавление новых записей без изменения существующих;
- Изменение – изменение существующих записей;
- Удаление – удаление некоторых записей без внесения изменений в другие.

Ограничение доступа задаётся подмножеству, определяемому условием выборки, заданному с помощью языка запросов. Если результат выполнения запроса ИСТИНА, то доступ на определенное действие будет предоставлен, в противном случае доступ будет запрещен.
Пример запроса:

Код 1C v 8.х

 ##Если &ИспользоватьОграничениеПоОрганизации ИЛИ &ИспользоватьОграничениеПоФизическиеЛица ##Тогда

ТекущаяТаблица ИЗ #ТекущаяТаблица КАК ТекущаяТаблица

    ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ РАЗЛИЧНЫЕ

        СоставГруппы.Ссылка КАК ГруппаПользователей

    ИЗ

        Справочник.ГруппыПользователей.ПользователиГруппы КАК СоставГруппы

    ГДЕ

        СоставГруппы.Пользователь = &ТекущийПользователь) КАК ГруппыПользователей

    ПО (ИСТИНА)

                ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Организации КАК ОбособленныеПодразделения

                ПО ОбособленныеПодразделения.ГоловнаяОрганизация = ТекущаяТаблица.#Параметр(1)

                И НЕ ОбособленныеПодразделения.ГоловнаяОрганизация = ЗНАЧЕНИЕ(Справочник.Организации.ПустаяСсылка)

                ИЛИ ОбособленныеПодразделения.Ссылка = ТекущаяТаблица.#Параметр(1)

ГДЕ (НЕ 1 В

                    (ВЫБРАТЬ ПЕРВЫЕ 1

                        1 КАК ПолеОтбора

                    ИЗ

                        РегистрСведений.НазначениеВидовОбъектовДоступа КАК НазначениеВидовОбъектовДоступа

                    ГДЕ

                        НазначениеВидовОбъектовДоступа.ГруппаПользователей = ГруппыПользователей.ГруппаПользователей

                        И ВЫБОР

                               ##Если &ИспользоватьОграничениеПоОрганизации ##Тогда

                            КОГДА НазначениеВидовОбъектовДоступа.ВидОбъектаДоступа = ЗНАЧЕНИЕ(Перечисление.ВидыОбъектовДоступа.Организации)

                                ТОГДА ВЫБОР

                                        КОГДА 1 В

                                                (ВЫБРАТЬ ПЕРВЫЕ 1

                                                    1

                                                ИЗ

                                                    (ВЫБРАТЬ

                                                        1 КАК ПолеОтбора

                                                    ) КАК Оптмизация ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.НастройкиПравДоступаПользователей КАК НастройкиПравДоступаПользователей

                                                        ПО

                                                            НастройкиПравДоступаПользователей.ОбъектДоступа = ОбособленныеПодразделения.Ссылка

                                                                И НастройкиПравДоступаПользователей.ВидОбъектаДоступа = ЗНАЧЕНИЕ(Перечисление.ВидыОбъектовДоступа.Организации)

                                                                И (НастройкиПравДоступаПользователей.Пользователь = НазначениеВидовОбъектовДоступа.ГруппаПользователей

                                                                    ИЛИ НастройкиПравДоступаПользователей.Пользователь = ЗНАЧЕНИЕ(Справочник.ГруппыПользователей.ВсеПользователи)))

                                            ТОГДА ИСТИНА

                                        ИНАЧЕ ЛОЖЬ

                                    КОНЕЦ

                               ##КонецЕсли

                               

                               ##Если &ИспользоватьОграничениеПоФизическиеЛица ##Тогда

                            КОГДА НазначениеВидовОбъектовДоступа.ВидОбъектаДоступа = ЗНАЧЕНИЕ(Перечисление.ВидыОбъектовДоступа.ФизическиеЛица)

                                ТОГДА ВЫБОР

                                        КОГДА 1 В

                                                (ВЫБРАТЬ ПЕРВЫЕ 1

                                                    1

                                                ИЗ

                                                    Справочник.ФизическиеЛица КАК ФизическиеЛица ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.НастройкиПравДоступаПользователей КАК НастройкиПравДоступаПользователей

                                                        ПО

                                                            НастройкиПравДоступаПользователей.ОбъектДоступа = ФизическиеЛица.ГруппаДоступаФизическогоЛица

                                                                И НастройкиПравДоступаПользователей.ВидОбъектаДоступа = ЗНАЧЕНИЕ(Перечисление.ВидыОбъектовДоступа.ФизическиеЛица)

                                                                                                                                                                                                                                                           И НастройкиПравДоступаПользователей.ОбластьДанных = ЗНАЧЕНИЕ(Перечисление.ОбластиДанныхОбъектовДоступа.ФизическиеЛицаДанные)

                                                                И (НастройкиПравДоступаПользователей.Пользователь = НазначениеВидовОбъектовДоступа.ГруппаПользователей

                                                                    ИЛИ НастройкиПравДоступаПользователей.Пользователь = ЗНАЧЕНИЕ(Справочник.ГруппыПользователей.ВсеПользователи))

                                                ГДЕ

                                                    ФизическиеЛица.Ссылка = ТекущаяТаблица.#Параметр(2))

                                            ТОГДА ИСТИНА

                                        ИНАЧЕ ЛОЖЬ

                                    КОНЕЦ

                               ##КонецЕсли

                               

                            ИНАЧЕ ИСТИНА

                        КОНЕЦ = ЛОЖЬ))

                        И НЕ ГруппыПользователей.ГруппаПользователей ЕСТЬ NULL

##КонецЕсли

В качестве переменных в запросах RLS используются специальные объекты конфигурации – параметры сеанса. Кроме привычных типов объектов, тип параметра может быть такжеNULL, УникальныйИдентификатор, ФиксированныйМассив, ВидДвиженияНакопления и др. Особо хочется отметить тип ХранилищеЗначений, позволяющий хранить разнородные данные в одном параметре (например, ОбщиеЗначения). Значения параметров сеанса обычно задается в процедуре ПриНачалеРаботыСистемы.

Так, при выводе списка номенклатуры можно отображать только некоторые группы справочника, при выборе контрагента в документ можно показывать не всех контрагентов, а только тех, к которым позволено работать пользователю, при формировании отчета скрывать данные по определенному подразделению. Вариантов применения RLS масса, нужды бизнеса иногда диктуют порой умопомрачительные требования, например разграничения доступа к проектам и спецификациям.

Заданные ограниченияRLS добавляются системой к каждому запросу, каждому действию с базой данных. Поэтому необходимо помнить, что злоупотребление механизмом RLS чревато снижением быстродействия системы.

В типовых конфигурациях возможность настройки прав доступа на уровне записей организована только для групп пользователей. Т.е. каждый пользователь системы включается в одну или несколько групп, для которых настраивается правило доступа к объекту или множеству элементов. Чем в большее количество групп входит пользователь, тем ниже будет производительность системы.

Платформа 1С в явном виде не предоставляет возможность отладки работы механизма RLS, но тем ни менее сделать это вполне реально. Для этого можно воспользоваться универсальной консолью отчетов (версия не ниже 2.6.9.2), на закладке «Данные» у которой есть функция «Выполнить от имени». Обработка создаст COM-соединение с помощью указанного имени пользователя и пароля, и выдаст результат выполнения запроса в консоль.

Используя имеющиеся в конфигурациях шаблоны ограничений, или создавая свой собственный запрос с помощью конструктора ограничений доступа к данным, можно настроить работу базы данных до мельчайших деталей, расписав кому что видно, доступно и дозволено. Единственным минусом является снижение производительности базы данных, но, как говорится, всё хорошее должно быть в меру.

Категория: Пользователь, роль доступа, интерфейс

Пример построения отчета Налогооблагаемая база

Многие, кто еще не касался СКД или касался поверхностно, высказывают - СКД сырая приблуда, на которой можно рисовать простенькие отчеты, типа вывода на печать справочника номенклатуры!
Так вот, на самом деле СКД очень мощный и гибкий инструмент, позволяющий на несколько минут создать хороший и многофункциональный отчет!
Этим примером я хочу Вам это показать!

Цель:
Необходимо для проверки сдаваемой отчетности создать в ЗУПе отчет, выводящий по Организации Налогооблагаемые базы: ОБЩАЯ, БАЗА ПФР, БАЗА ФОМС, БАЗА ФСС, БАЗА ФСС от НС, БАЗА не облагаемая и Скидка.
В отчете Нужна разбивка по месяцам, Видам Дохода, Видам расчета входящих в выше указанный Вид дохода,
Сумму представленную по Виду расчета, необходимо развернуть по ФизЛицу с указанием документа начисления!

Создание:
И так начнем:
1. Создаем отчет и Открываем Схему Компоновки Данных
title

2. В Наборах Данных -> Добавляем Набор данных - Запрос
title

Создаем не сложный запрос, собирающий доходы с регистра накопления СтраховыеВзносыСведенияОДоходах и по условиям распределяющий суммы в разные базы:

Код 1C v 8.х

 

ВЫБРАТЬ

	СтраховыеВзносыСведенияОДоходах.Организация КАК Организация,

	НАЧАЛОПЕРИОДА(СтраховыеВзносыСведенияОДоходах.Период, МЕСЯЦ) КАК Месяц,

	СтраховыеВзносыСведенияОДоходах.ВидДохода КАК ВидДохода,

	СтраховыеВзносыСведенияОДоходах.ВидРасчета КАК ВидРасчета,

	СтраховыеВзносыСведенияОДоходах.Результат КАК ОБЩАЯ,

	ВЫБОР

		КОГДА СтраховыеВзносыСведенияОДоходах.ВидДохода.ВходитВБазуФСС

			ТОГДА СтраховыеВзносыСведенияОДоходах.Результат

		ИНАЧЕ 0

	КОНЕЦ КАК БАЗА_ФСС,

	ВЫБОР

		КОГДА СтраховыеВзносыСведенияОДоходах.ВидДохода.ВходитВБазуФОМС

			ТОГДА СтраховыеВзносыСведенияОДоходах.Результат

		ИНАЧЕ 0

	КОНЕЦ КАК БАЗА_ФОМС,

	ВЫБОР

		КОГДА СтраховыеВзносыСведенияОДоходах.ВидДохода.ВходитВБазуПФР

			ТОГДА СтраховыеВзносыСведенияОДоходах.Результат

		ИНАЧЕ 0

	КОНЕЦ КАК БАЗА_ПФР,

	ВЫБОР

		КОГДА СтраховыеВзносыСведенияОДоходах.ВидРасчета.КодДоходаФСС_НС <> &НеОблагается

				ИЛИ СтраховыеВзносыСведенияОДоходах.ВидРасчета.КодДоходаФСС_НС ЕСТЬ NULL 

			ТОГДА СтраховыеВзносыСведенияОДоходах.Результат

		ИНАЧЕ 0

	КОНЕЦ КАК БАЗА_ФСС_от_НС,

	ВЫБОР

		КОГДА СтраховыеВзносыСведенияОДоходах.ВидРасчета.КодДоходаФСС_НС = &НеОблагается		

			ТОГДА СтраховыеВзносыСведенияОДоходах.Результат

		ИНАЧЕ 0

	КОНЕЦ КАК БАЗА_Не_Облагаемая,

	СтраховыеВзносыСведенияОДоходах.Скидка КАК Скидка,

	СтраховыеВзносыСведенияОДоходах.Регистратор,

	СтраховыеВзносыСведенияОДоходах.ФизЛицо,

	СтраховыеВзносыСведенияОДоходах.ВидРасчета.КодДоходаФСС_НС

ИЗ

	РегистрНакопления.СтраховыеВзносыСведенияОДоходах КАК СтраховыеВзносыСведенияОДоходах

Закладка - Набор данных:
title

3. Так как у нас только один набор данных, закладку Связи Наборов Данных пропускаем.
Вычисляемые поля, тоже нам не нужны - пропускаем.
4. Для расчета итогов по группировкам на закладке Ресурсы добавляем:
title

5. В запросе я использовал Параметры, теперь на Закладке Параметры их нужно указать:
title

6. Закладки Макет и Вложенные Запросы пропускаем, переходим на Закладку Настройки
В верхней части формы необходимо указать выводимые данные отчета - воспользуемся Конструктором Настроек..
Далее комментировать не буду, смотрите по картинкам:
title

После нажатия на ОК получаем:
title

7. При формировании отчет будет выводить группировку месяц как дату 01.01.2010, сделаем же ее вида Январь 2010
Для этого в нижней части перейдем на Закладку Условное оформление и добавим строку:
title

В колонке область выберем Месяц, а в колонке Оформление зададим формат вывода:
title

Все, сохраняем, запускаем, формируем, получаем:
title

Вот так, за 5 минут был создан удобный отчет (Скачать его можете здесь)!
Автор: Мигачев Евгений

Категория: Схема Компоновки Данных