происходить » Поиск

Результаты по ключевому слову: происходить

Функция получение содержимого адреса url (веб-страницы) методом GET

Код 1C v 8.х

 // Возвращает содержимое ответа HTTP-сервера, полученного методом GET, в виде строки или двоичных данных

// ** Coded by Sergey (aka Porutchik) * 2014 http://forum.aeroion.ru/cat1.html //

// Параметры

//  СерверПриемник - <Строка> - доменное имя сервера или полный адрес (url) запрашиваемой ссылки.

//                        Может включать протокол (http://, https://) и порт.

//  АдресСтраницы - <Строка> - опционально. Адрес страницы на сервере без протокола (http://, https://),

//                        доменного имени сервера (хоста) и порта.

//                Если не указано, адрес страницы будет извлечён из параметра СерверПриемник

//  ПараметрыСоединения - <Структура> - опционально. Структура, содержащая дополнительные параметры для HTTPСоединение.

//                Назначение ключей:

//                Логин или Пользователь - Тип Строка - Имя пользователя на указанном сервере.

//                Пароль - Тип Строка - Пароль пользователя на указанном сервере.

//                Прокси - Тип ИнтернетПрокси - Прокси, используемый для соединения с сервером.

//                Таймаут - Тип Число - Таймаут осуществляемого соединения и операций, в секундах. 0 - не устанавливать таймаут..

//  ЗаголовкиHTTP  - <Соответствие> - опционально.

//                Заголовки, которые будут отправлены на сервер в виде соответствия: "Заголовок" - "Значение".

//                Если указано, функция возвратит в программу заголовки HTTP-ответа с кодом состояния в ключе StatusCode,

//                имя файла в ключе FileName, url-кодированное имя в ключе EncodeFileName

//  ПолучитьКакДвоичныеДанные - <Булево> - опционально. Определяет, в каком виде получить содержимое ответа сервера

//                            По умолчанию Ложь.

//  ЗащищенноеСоединение - <Булево> - опционально. По умолчанию Ложь.

//                            Если Истина, соединение будет происходить по протоколу https://

//

// Возвращаемое значение:

//   <Строка>, <ДвоичныеДанные> - содержимое ответа сервера, если ресурс найден по указанному адресу.

//

Функция ПолучитьСодержимоеВебАдреса(Знач СерверПриемник, Знач АдресСтраницы = "",

                Знач ПараметрыСоединения = Неопределено, ЗаголовкиHTTP = Неопределено,

                Знач ПолучитьКакДвоичныеДанные = Ложь, Знач ЗащищенноеСоединение = Ложь) Экспорт

    Перем ИмяФайлаОтветаКодированное, ИмяФайлаОтвета, Порт, Логин, Пользователь, Пароль, Прокси, Таймаут;



    Если Не ЗначениеЗаполнено(СерверПриемник) Тогда Возврат Неопределено; КонецЕсли;

    Если ТипЗнч(ЗаголовкиHTTP) <> Тип("Соответствие") Тогда ЗаголовкиHTTP = Новый Соответствие; КонецЕсли;

    Если Найти(Нрег(СерверПриемник), "https://") = 1 Тогда ЗащищенноеСоединение = Истина; КонецЕсли;



    Протокол = ?(Найти(Нрег(СерверПриемник), "https://") = 1 ИЛИ ЗащищенноеСоединение, "https://", "http://");

    Если Лев(НРег(СерверПриемник), СтрДлина(Протокол)) = Протокол Тогда

        СерверПриемник = Сред(СерверПриемник, СтрДлина(Протокол) + 1);

    КонецЕсли;



    Если НЕ ЗначениеЗаполнено(АдресСтраницы) Тогда

        Позиция = Найти(СерверПриемник, "/");

        Если Позиция > 0 Тогда

            АдресСтраницы = Сред(СерверПриемник, Позиция, СтрДлина(СерверПриемник));

            СерверПриемник = Лев(СерверПриемник, Позиция - 1);

        Иначе

            АдресСтраницы = "/";

        КонецЕсли;

    КонецЕсли;



    СерверПриемник = СтрЗаменить(СерверПриемник, "/", "");



    //Выделяем порт из доменного имени

    ПозицияДвоеточия = Найти(СерверПриемник, ":");

    Если ПозицияДвоеточия > 0 Тогда

        Порт = Число(Сред(СерверПриемник, ПозицияДвоеточия + 1));

        СерверПриемник = Лев(СерверПриемник, ПозицияДвоеточия - 1);

    КонецЕсли;



    Если ТипЗнч(ПараметрыСоединения) = Тип("Структура") Тогда

        Для каждого КлючЗначение из ПараметрыСоединения Цикл

            Значение = КлючЗначение.Значение; Выполнить(КлючЗначение.Ключ + " = Значение;");

        КонецЦикла;

        Пользователь = ?(ЗначениеЗаполнено(Пользователь), Пользователь, Логин);

    КонецЕсли;

    НТТР = Новый HTTPСоединение(СерверПриемник, Порт, Пользователь, Пароль, Прокси, Таймаут,

                        ?(ЗащищенноеСоединение, Новый ЗащищенноеСоединениеOpenSSL(), Неопределено));



    //Ответ от сервера получим в возвращаемом значении типа HTTPОтвет

    ОтветHTTP = НТТР.Получить(Новый HTTPЗапрос(АдресСтраницы, ЗаголовкиHTTP)); //

    ОшибкаЗапроса = (ОтветHTTP.КодСостояния >= 400);



    //После получения ответа сервера необходимо проверить статус или код состояния.

    //http://www.w3.org/Protocols/rfc2616/rfc2616-sec10....     //Если сервер вернул один из статусов переадресации

    //301 Moved Permanently («перемещено навсегда») или 302 Moved Temporarily («перемещено временно»),

    //то в этом случае можно попытаться перейти на ресурс, на который переадресовал сервер

    Если ОтветHTTP.КодСостояния = 301 или ОтветHTTP.КодСостояния = 302 Тогда



        Если ОтветHTTP.Заголовки.Количество() > 0 Тогда

            //Адрес страницы переадресации содержится в поле Location заголовка ответа

            АдресСтраницы = ОтветHTTP.Заголовки["Location"]; //

            Если ЗначениеЗаполнено(АдресСтраницы) Тогда

                Если Найти(НРег(АдресСтраницы), "http://") = 0 И Найти(НРег(АдресСтраницы), "https://") = 0 Тогда

                    АдресСтраницы = ?(Лев(АдресСтраницы, 1) = "/", Сред(АдресСтраницы, 2), АдресСтраницы);

                    Если Найти(АдресСтраницы, СерверПриемник + "/") = 0  Тогда

                        АдресСтраницы = Протокол + СерверПриемник + ?(ЗначениеЗаполнено(Порт), ":" + Порт, "") + "/" + АдресСтраницы;

                    КонецЕсли;

                КонецЕсли;



                //Если сервер вернул cookies (http://ru.wikipedia.org/wiki/HTTP_cookie, http://www.faqs.org/rfcs/rfc6265.html?#41;,                 //вставим их в заголовки для передачи на страницу перехода

                Куки = ОтветHTTP.Заголовки["Set-Cookie"];//

                Если ЗначениеЗаполнено(Куки) Тогда ЗаголовкиHTTP.Вставить("Cookie", Куки); КонецЕсли;



                //Рекурсивный вызов

                Возврат ПолучитьСодержимоеВебАдреса(АдресСтраницы, , , ЗаголовкиHTTP, ПолучитьКакДвоичныеДанные, ЗащищенноеСоединение);//



            КонецЕсли;

        КонецЕсли;



    ИначеЕсли ОтветHTTP.КодСостояния >= 100 И ОтветHTTP.КодСостояния <= 200 Тогда

        //Статус ответа в интервале между 100 и 200 Ok говорит о нормальном результате HTTP-запроса

        Если ОтветHTTP.Заголовки.Количество() > 0 Тогда

            ТипСодержимого = ОтветHTTP.Заголовки["Content-Type"];

            //http://ru.wikipedia.org/wiki/Список_MIME-типов             Если Найти(ТипСодержимого, "text/") = 1 ИЛИ Найти(ТипСодержимого, "/javascript")

                ИЛИ Найти(ТипСодержимого, "+xml") ИЛИ Найти(ТипСодержимого, "/xml") <> 0 ИЛИ Найти(ТипСодержимого, "/json") <> 0 Тогда

                ПолучитьКакДвоичныеДанные = Ложь;

            ИначеЕсли Найти(ТипСодержимого, "image/") = 1 ИЛИ Найти(ТипСодержимого, "video/") = 1 

                ИЛИ Найти(ТипСодержимого, "application/") = 1 ИЛИ Найти(ТипСодержимого, "audio/") = 1 Тогда

                //Если содержимое полученного ответа представляет собой изображение, видео, приложение,

                //возвращаем двоичные данные, так как возвращать в виде строки не имеет смысла.

                ПолучитьКакДвоичныеДанные = Истина;

            КонецЕсли;

            //Некоторые сервера возвращают в типе содержимого имя отданного файла, например image/png; name="Имя файла.png"

            //или отдают в заголовке Content-Disposition: attachment; filename=Имя файла.png (http://www.http11.ru/post.php?post=2)             Если ОтветHTTP.Заголовки["Content-Disposition"] <> Неопределено Тогда

                ТипСодержимого = ОтветHTTP.Заголовки["Content-Disposition"];

            КонецЕсли;

            ТипСодержимого = СтрЗаменить(СтрЗаменить(ТипСодержимого, """", ""), "'", "");



            //в ключе filename*=UTF-8'' содержится url-кодированное имя файла

            ПозицияИмениФайла = Найти(ТипСодержимого, "filename*=UTF-8");

            Если ПозицияИмениФайла <> 0 Тогда

                ИмяФайлаОтветаКодированное = Сред(ТипСодержимого, ПозицияИмениФайла + СтрДлина("filename*=UTF-8"));

                ПозицияДвоеточия = Найти(ИмяФайлаОтветаКодированное, ";");

                Если ПозицияДвоеточия <> 0 Тогда

                    ИмяФайлаОтветаКодированное = Лев(ИмяФайлаОтветаКодированное, ПозицияДвоеточия - 1);

                КонецЕсли;

            КонецЕсли;



            //в ключе filename= содержится обычное имя файла

            ПозицияИмениФайла = Найти(ТипСодержимого, "name=");

            Если ПозицияИмениФайла <> 0 Тогда

                ИмяФайлаОтвета = Сред(ТипСодержимого, ПозицияИмениФайла + СтрДлина("name="));

                ПозицияДвоеточия = Найти(ИмяФайлаОтвета, ";");

                Если ПозицияДвоеточия <> 0 Тогда

                    ИмяФайлаОтвета = Лев(ИмяФайлаОтвета, ПозицияДвоеточия - 1);

                КонецЕсли;

            КонецЕсли;

        КонецЕсли;

    КонецЕсли;



    ЗаголовкиHTTP = ОтветHTTP.Заголовки;

    //Добавляем в заголовки ответа код состояния (ответа) HTTP-сервера и имя файла содержимого, если есть.

    ЗаголовкиHTTP.Вставить("StatusCode", ОтветHTTP.КодСостояния);

    Если ЗначениеЗаполнено(ИмяФайлаОтвета) Тогда ЗаголовкиHTTP.Вставить("FileName", ИмяФайлаОтвета); КонецЕсли;

    Если ЗначениеЗаполнено(ИмяФайлаОтветаКодированное) Тогда

        ЗаголовкиHTTP.Вставить("EncodeFileName", ИмяФайлаОтветаКодированное);

    КонецЕсли;



    Если ОшибкаЗапроса ИЛИ НЕ ПолучитьКакДвоичныеДанные Тогда Возврат ОтветHTTP.ПолучитьТелоКакСтроку(); КонецЕсли;

    Возврат ОтветHTTP.ПолучитьТелоКакДвоичныеДанные();



КонецФункции // ПолучитьСодержимоеВебАдреса()







//Источник: http://forum.aeroion.ru/topic749.html

Примеры использования:

[c8]// Получение содержимого в виде строки//
СодержимоеАдреса = ПолучитьСодержимоеВебАдреса(" //
ЗаголовкиHTTP = Новый Соответствие;
ЗаголовкиHTTP.Вставить("Referer", "a href="http://some_site.com/" )"="">http://some_site.com/");
СодержимоеАдреса = ПолучитьСодержимоеВебАдреса("

Категория: Работа с Интернет, Почтой (Mail), FTP

Полнотекстовый поиск в 1С (что это и пример использования)

Полнотекстовый поиск - позволит найти текстовую информацию, размещенную практически в любом месте используемой конфигурации. При этом искать нужные данные можно либо по всей конфигурации в целом, либо сузив область поиска до нескольких объектов (например, определенных видов документов или справочников). Сами критерии поиска могут варьироваться в довольно широком диапазоне. То есть найти нужные данные можно, даже не помня точно, где они хранятся в конфигурации и как именно записаны.

Полнотекстовый поиск предоставляет следующие возможности:

Есть поддержка транслитерации (написание русских слов символами латиницы в соответствии с ГОСТ 7.79-2000). Пример: "русская фраза" = "russkaya fraza".
Есть поддержка замещения (написание части символов в русских словах одноклавишными латинскими символами). Пример: "руссrfz фраpf" (окончания каждого слова набраны латиницей, допустим, в результате ошибки оператора).
Есть возможность нечеткого поиска (буквы в найденных словах могут отличаться) с указанием порога нечеткости. Пример: указав в строке поиска слово "привет" и нечеткость 17 %, найдем все аналогичные слова с ошибками и без: "привет", "превет", "привед".
Есть возможность указать область выполнения поиска по выбранным объектам метаданных.
Полнотекстовое индексирование названий стандартных полей ("Код", "Наименование" и т. д.) производится на всех языках конфигурации.
Поиск выполняется с учетом синонимов русского, английского и украинского языков.
Морфологический словарь русского языка содержит ряд специфических слов, относящихся к областям деятельности, автоматизируемым с помощью системы программ "1С:Предприятие".
Стандартно в состав поставляемых словарей включены словарные базы и словари тезауруса и синонимов русского, украинского и английского языков, которые предоставлены компанией "Информатик".
Поиск можно осуществлять с использованием подстановочных символов ("*"), а также с указанием поисковых операторов ("И", "ИЛИ", "НЕ", "РЯДОМ") и спецсимволов.

Полнотекстовый поиск можно осуществлять в любой конфигурации на платформе 1С:Предприятие 8

Для того чтобы открыть окно управления полнотекстовым поиском необходимо выполнить следующее:

Обычное приложение - пункт меню Операции - Управление полнотекстовым поиском.

Управляемое приложение - пункт меню Главное меню - Все функции - Стандартные - Управление полнотекстовым поиском.

Обновить индекс – Создание индекса/Обновление индекса;
Очистить индекс – обнуление индекса(рекомендуется после обновления всех данных);
пункт Разрешить слияние индексов – отвечает за слияние основного и дополнительного индекса.

Полнотекстовый поиск осуществляется при помощи полнотекстового индекса. При отсутствии индекса полнотекстовый поиск как таковой не возможен. Для того чтобы поиск имел результат, все необходимые данные должны быть включены в полнотекстовый индекс. Если пользователем введены в базу новые данные, их следует включить в рассматриваемый индекс, иначе они не будут участвовать в поиске. Чтобы этого избежать, необходимо обновлять полнотекстовый индекс. При обновлении система анализирует только определенные типы данных: Строка, Данные ссылочного типа (ссылки на документы, справочники),Число, Дата, ХранилищеЗначения. Если пользователь не имеет прав доступа к определенной информации, то он не сможет увидеть ее в результатах поиска. Следует также помнить и о том, что в свойствах объектов, по которым будет происходить поиск должно быть установлено значение Полнотекстовый Поиск – Использовать, которое задано по умолчанию.

Как вы можете заметить свойство Использовать установлено для всего справочника Контрагенты, но сделать это можно и для каждого его реквизита соответствующего типа.

Рассмотрим более подробно полнотекстовый индекс, который состоит из двух частей (индексов): основного индекса и дополнительного. Высокая скорость поиска данных обеспечивается за счет основного индекса, но обновление его происходит относительно медленно, в зависимости от объема данных. Дополнительный индекс ему противоположен. Данные добавляются в него намного быстрее, но поиск осуществляется медленнее. Система осуществляет поиск одновременно в обоих индексах. Большая часть данных находится в основном индексе, а данные добавляемые в систему попадают в дополнительный индекс. Пока объем данных в дополнительном индексе небольшой, поиск по нему происходит относительно быстро. В тот момент, когда нагрузка на систему невелика, происходит операция слияния индексов, в результате чего дополнительный индекс очищается, а все данные помещаются в основной индекс. Слияние индексов предпочтительнее выполнять в тот момент времени, когда нагрузка на систему минимальна. С этой целью можно создавать регламентированные задания и задания по расписанию.

Специальные операторы, допустимые при задании поискового выражения

Механизм полнотекстового поиска допускает написание части символов русского слова одноклавишными латинскими символами. Результат поиска при этом не измениться.

Два оператора РЯДОМ

упрощенный. На расстоянии 8 слов друг от друга
РЯДОМ/[+/-]n – поиск данных в одном реквизите на расстоянии n-1 слов между ними.

Знак указывает в каком направлении от первого слова будет поиск второго. (+ - после, - до)

Групповой символ «*» может использоваться только в качестве замены конца слова

Оператор нечеткости «#». Если неизвестно точное написание названия, имени.

Программными средствами и средствами 1с: программирование.

Оператор синонимов «!». Позволяет найти слово и его синонимы

Как программно обновить индекс полнотекстового поиска?

Код 1C v 8.х

 Процедура ОбновлениеИндексы() Экспорт

ПолнотекстовыйПоиск.ОбновитьИндекс();

КонецПроцедуры

Пример полнотекстового поиска данных

Определение переменной СписокПоиска

Код 1C v 8.х

 Перем СписокПоиска;

Кроме этого в процедуре обработки события ПриОткрыии формы определим, что эта переменная будет содержать список полнотекстового поиска, с помощью которого мы и будем осуществлять поиск в данных

Код 1C v 8.х

 Процедура ПриОткрытии()

СписокПоиска = ПолнотекстовыйПоиск.СоздатьСписок();

КонецПроцедуры

Теперь для события нажатия на кнопку Найти напишем код, который позволит нам выполнять поиск в соответствии с тем выражением, которое задано в поле ПоисковоеВыражение

Код 1C v 8.х

 Процедура НайтиНажатие(Элемент)

СписокПоиска.СтрокаПоиска = ПоисковоеВыражение;

Попытка

СписокПоиска.ПерваяЧасть();

Исключение

Предупреждение(ОписаниеОшибки());

КонецПопытки;

Если СписокПоиска.ПолноеКоличество() = 0 Тогда

ЭлементыФормы.СообщениеОРезультате.Значение = "Не найдено";

ЭлементыФормы.РезультатПоиска.УстановитьТекст("");

Иначе

ВывестиРезультатПоиска();

КонецЕсли;

КонецПроцедуры

Сначала в этой процедуре мы устанавливаем поисковое выражение, введенное пользователем, в качестве строки поиска для полнотекстового поиска. Затем выполняем метод ПерваяЧасть(), который собственно запускает полнотекстовый поиск и возвращает первую порцию результатов. По умолчанию порция содержит 20 элементов. После этого мы анализируем количество элементов в списке поиска. Если он не содержит ни одного элемента, то мы выводим в форму соответствующее сообщение. В противном случае вызывается процедура ВывестиРезультатПоиска(), которая отображает полученные результаты пользователю.

Создадим в модуле формы процедуру с таким именем и напишем в ней код,

Код 1C v 8.х

 Процедура ВывестиРезультатПоиска()

ЭлементыФормы.СообщениеОРезультате.Значение = "Показаны " + Строка(СписокПоиска.НачальнаяПозиция() + 1) + " - " + Строка(СписокПоиска.НачальнаяПозиция() +СписокПоиска.Количество()) + " из " + СписокПоиска.ПолноеКоличество();

Результат = СписокПоиска.ПолучитьОтображение(ВидОтображенияПолнотекстовогоПоиска.HTMLТекст);

ЭлементыФормы.РезультатПоиска.УстановитьТекст(Результат);

ДоступностьКнопок();

КонецПроцедуры

Действия, выполняемые в этой процедуре, просты. Сначала мы формируем сообщение о том, какие элементы отображены и сколько всего элементов найдено. Затем получаем результат полнотекстового поиска в виде HTML-текста и выводим этот текст в поле HTML-документа, расположенное в форме.

В заключение передаем управление в процедуру ДоступностьКнопок() для того, чтобы сделать доступными или, наоборот, запретить доступ к кнопкам Предыдущая порция и Следующая порция (в зависимости от того, какая порция полученных результатов отображена). Текст этой процедуры представлен в Коде

Код 1C v 8.х

 Процедура ДоступностьКнопок()

ЭлементыФормы.СледующаяПорция.Доступность = (СписокПоиска.ПолноеКоличество() - СписокПоиска.НачальнаяПозиция()) > СписокПоиска.Количество();

ЭлементыФормы.ПредыдущаяПорция.Доступность = (СписокПоиска.НачальнаяПозиция() > 0);

КонецПроцедуры

Теперь необходимо создать обработчики событий нажатия на кнопки ПредыдущаяПорция() и СледующаяПорция().

Код 1C v 8.х

 Процедура ПредыдущаяПорцияНажатие(Элемент)

СписокПоиска.ПредыдущаяЧасть();

ВывестиРезультатПоиска();

КонецПроцедуры

Процедура СледующаяПорцияНажатие(Элемент)

СписокПоиска.СледующаяЧасть();

ВывестиРезультатПоиска();

КонецПроцедуры

Заключительным «штрихом» будет создание обработчика события onclick поля HTML-документа, расположенного в форме. Дело в том, что результат полнотекстового поиска, представленный в виде HTML-текста, содержит гиперссылки на номера элементов списка поиска. И нам хотелось бы, чтобы при переходе пользователя на эту ссылку система открывала бы форму того объекта, который содержится в этом элементе списка. Для этого мы будем перехватывать событие onclick HTML-документа, содержащегося в поле HTML-документа, получать номер элемента списка из гиперссылки и открывать форму соответствующего объекта. Текст обработчика события onclick поля HTML-документа представлен в коде

Код 1C v 8.х

 Процедура РезультатПоискаonclick(Элемент, pEvtObj)

htmlElement = pEvtObj.srcElement;

// Проверить идентификатор элемента

Если (htmlElement.id = "FullTextSearchListItem") Тогда

// Получить имя файла (номер строки списка поиска),

// содержащегося в гиперссылке

НомерВСписке = Число(htmlElement.nameProp);

// Получить строку списка поиска по номеру

ВыбраннаяСтрока = СписокПоиска[НомерВСписке];

// Открыть форму найденного объекта

ОткрытьЗначение(ВыбраннаяСтрока.Значение);

pEvtObj.returnValue = Ложь;

КонецЕсли;

КонецПроцедуры

Категория: Встроенные Функции

О формате EnterpriseData

Для облегчения интеграции с программными продуктами фирмы «1С» разработан формат обмена данными EnterpriseData. Формат основан на XML и является бизнес-ориентированным – описанные в нем структуры данных соответствуют бизнес-сущностям (документам и элементам справочников), представленным в программах «1С», например: акт выполненных работ, приходный кассовый ордер, контрагент, договор и т. п. Это делает формат интуитивно понятным и легким в использовании.

Формат EnterpriseData предназначен для обмена данными внутри компании (в том числе между разнородными и территориально удаленными информационными системами) и призван покрыть все сферы деятельности предприятия – финансы, производство, закупки и продажи, складские операции и т. п.

Описание формата

Версия 1.0.1 формата включает в себя описание 94 типов бизнес-сущностей из различных областей бизнеса (подробное описание формата можно найти здесь). Формат является расширяемым – фирма «1С» будет добавлять в него описание новых бизнес-сущностей и расширять существующие сущности новыми полями. Поддержка формата в продуктах фирмы «1С» обеспечивает совместимость снизу вверх – все программы сторонних производителей, обменивающихся данными в формате EnterpriseData с продуктами «1С», при выходе новых версий формата корректно продолжат работу.

Формат предназначен для обмена информацией между любыми информационными системами: он не зависит от особенностей собственного программного обеспечения или структур информационных баз, которые участвуют в обмене и не содержит в себе явных ограничений использования.

Обмен данными с программами «1С»

Предварительная настройка на стороне «1С»

Чтобы начать обмен данными в формате EnterpriseData между приложением «1С» и сторонним приложением, надо на стороне «1С» настроить синхронизацию данных. В ходе настройки указывается уникальный код приложения, с которым будет производиться обмен, а также по какому каналу будет происходить обмен данными. В настоящий момент доступны следующие опции:

веб-сервис,
файловый обмен через каталог,
файловый обмен через FTP.

Обмен через электронную почту

В случае обмена через веб-сервис стороннее приложение будет инициировать сеанс обмена данными путем вызова соответствующих веб-методов приложения «1С». В остальных случаях инициатором сеанса обмена будет приложение «1С».

Также на стороне «1С» настраивается, с какой периодичностью будет происходить синхронизация (для вариантов с файловым обменом через каталог и электронную почту):

по расписанию (с заданной периодичностью);

вручную; пользователь должен будет вручную запускать синхронизацию каждый раз, когда это ему потребуется.

Формат файлов обмена

В ходе синхронизации приложения «1С» и сторонние приложения обмениваются сообщениями – XML-файлами определенной структуры. Эти файлы состоят из двух секций – <Header> и <Body>. Секция <Header> содержит сообщение-квитанцию <Confirmation> (о ней ниже), а <Body> – информацию об измененных бизнес-сущностях в формате EnterpriseData.

Подробнее на сайте 1С

Категория: Конвертация данных, Обмен, Перенос

Как сделать Расшифровку в табличном документе

Вопрос: Подскажите пожалуйста, каким образом можно сделать следующее.

У меня есть выводимый в табличный документ результат запроса, к ячейке есть расшифровка.

Я хочу чтобы при двойном клике на ячейку выполнялась процедура которая к примеру запускает отчет по расшифровке ячейки.

Ответ: Расшифровки бывают стандартные и нестандартные.

I) Стандартные:

может использоваться как непосредственно в табличном документе, так и в объекте ПолеТабличногоДокумента (т.е.табличный документ, размещенный не в отдельном окне, а непосредственно на форме).

Чтобы Расшифровка сработала, должны выполняться 3 условия:

1) Для ячейки табличного документа, из которой мы хотим вызвать Расшифровку, должно быть установлено свойство ПараметрРасшифровки. Например, мы хотим, чтобы по двойному щелчку на ячейке с названием контрагента открывалась форма элемента справочника Контрагента, чтобы можно было уточнить какие-то данные, которые в отчет не выводятся. Задаем свойству ПараметрРасшифровки какое-нибудь значение, например, РасшифровкаКонтрагента.

2)В процессе вывода областей макета в результирующий табличный документ нужно ОБЯЗАТЕЛЬНО ПРИСВОИТЬ параметру расшифровки значение нужного типа, например:

Код 1C v 8.х

 ТабДок = Новый ТабличныйДокумент;

Выборка = Справочники.Контрагенты.Выбрать();

Пока Выборка.Следующий() Цикл

Область = Макет.ПолучитьОбласть("Строка");

Область.Параметры.Контрагент = Выборка.Наименование;

// .................................................

Область.Параметры.РасшифровкаКонтрагента = Выборка.Ссылка;

ТабДок.Вывести(Область);

КонецЦикла;

3)Должен быть обеспечен запрет редактирования ячейки с расшифровкой, т.е. нужно указать

ТабДок.ТолькоПросмотр = Истина;

иначе, несмотря на многообещающий вид курсура при наведении на ячейку можно щелкать по ней сколько угодно, но ничего происходить не будет.

II) Нестандартные:

по двойному щелчку на ячейке с расшифровкой можно вызвать свою процедуру. Для реализации этого следует выполнить несколько условий:

1)Вывод табличного документа должен осуществляться в объект ПолеТабличногоДокумента;

2)Должно быть присвоено значение свойству ячейки ПараметрРасшифровки, например, РасшифровкаКонтрагента.

3)Параметру расшифровки РасшифровкаКонтрагента присваивается заполненный при формировании табличного документа нужными значениями СписокЗначений или чаще Структура. В частности, может передаваться имя стандартного отчета конфигурации и параметров, которые нужно задать в форме отчета, например, период дат, номер счета и т.д. А потом этот отчет вызывается как процедура.

4)Для объекта ПолеТабличногоДокумента свойство ТолькоПросмотр нужно установить в значение Истина.

5)Код пользовательской процедуры помещается в процедуру

Код 1C v 8.х

 ПолеТабличногоДокумента1ОбработкаРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка)

// первой строкой в ней должна быть такая:

СтандартнаяОбработка = Ложь;

Приведу небольшой пример, открывающий для "щелкнутого" контрагента подчиненный справочник.

Код 1C v 8.х

 Процедура КнопкаСформироватьНажатие(Кнопка)

Контрагенты = Справочники.Контрагенты;

Выборка = Контрагенты.Выбрать();

Таб = ЭлементыФормы.ПолеТабличногоДокумента1;

Макет = ПолучитьМакет("Макет"); 

Пока Выборка.Следующий() Цикл

Если Выборка.ЭтоГруппа = Ложь Тогда

Область = Макет.ПолучитьОбласть("Строка");

Область.Параметры.Контрагент = Выборка.Наименование;

.................................................................................................

СтруктураРасшифровки = Новый Структура;

СтруктураРасшифровки.Вставить("Контрагент",Выборка.Ссылка);

СтруктураРасшифровки.Вставить(".......",.........);

.........................................................................

Область.Параметры.РасшифровкаКонтрагента = СтруктураРасшифровки;

ЭлементыФормы.ПолеТабличногоДокумента1.Вывести(Область);

Иначе

Продолжить;

КонецЕсли;

КонецЦикла;

ЭлементыФормы.ПолеТабличногоДокумента1.ТолькоПросмотр = Истина;

КонецПроцедуры



Процедура ПолеТабличногоДокумента1ОбработкаРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка)

СтандартнаяОбработка = Ложь;

Договоры = Справочники.Договоры.ПолучитьФормуСписка();

Договоры.ПараметрОтборПоВладельцу = Расшифровка.Контрагент;

Договоры.Открыть();

КонецПроцедуры

Категория: Табличный документ

Соединение с сервером баз данных разорвано администратором или Неопознанная ошибка HRESULT=80004005

Я думаю каждый хоть раз, но сталкивался с ошибкой 1С Соединение с сервером баз данных разорвано администратором Microsoft SQL Server Native Client 10.0: Неопознанная ошибка HRESULT=80004005

Вот некоторые способы, которые помогут решить данную проблему:
1. Проверить конфигурацию на наличие некорректной информации (мусора). Для этого следует выполнить команду “Проверка конфигурации” с установленным флажком “Проверка логической целостности конфигурации”. При выявлении проблем будет выдано сообщение. Некорректная информация при этом будет удалена автоматически, однако следует обеспечить доступность для изменения корневого объекта конфигурации (напимер, при работе с хранилищем его следует захватить).

2. Если Ваша конфигурация находится на поддержке, следует подобным образом проверить конфигурацию поставщика. Для этого в настройке поддержки следует сохранить конфигурацию поставщика в cf файл, загрузить его в новую базу и выполнить описанную в пункте 1 процедуру. В случае, если было получено сообщение об исправлении, значит конфигурация поставщика содержит некорректную информацию. В этом случае следует снять Вашу конфигурацию с поддержки и заново поставить путем объединения со свежим релизом конфигурации поставщика. В настоящее время все релизы выпускаемые 1С проходят проверку и выпускаются без данной проблемы.

3. Также с этой ситуацией пересекается следующая ситуация:
10007066 Запись данных, содержащих колонки типа ХранилищеЗначения
Проблема:
При использовании СУБД MS SQL SERVER при записи объекта базы данных, содержащего несколько колонок типа ХранилищеЗначения, данные для которых получены из файлов, может происходить ошибка
Ошибка СУБД:Microsoft OLE DB Provider for SQL Server: String data length mismatchHRESULT=80004005и аварийное завершение работы программы.

Включив технологический журнал на время загрузки, можно определить таблицу, в которой содержатся такие хранилища. Найдите средствами MS SQL Server Query Analizer в этой таблице колонки типа image. Для каждой колонки типа image выполните запрос вида:

S_elect top 10 DATALENGTH(_Fld4044)
from _InfoReg4038
order by DATALENGTH(_Fld4044) desc

Нюансы: обратите внимание, что ”Стандартные проверки” платформой (chdbfl, в конфигураторе) упорно говорят, что с базой все ОК.

Суть проблемы: важно, что под это сообщение об ошибке могут подпадать разные причины, но у них есть общая часть для 1С – это не достаточно оперативной памяти. А еще точнее неэффектиное использование ресурсов памяти. Отсюда косвенные способы победить проблему: путем рестарта сервера (на некотрое время становиться больше доступной памяти) или перейти на 64-разрядный сервер приложений.

1С:Предприятие 8.2. Лицензия на сервер (x86-64)

По опыту проблема связана с хранением данных в реквизите хранилище значений либо наличием в таблице config двоичных данных БОЛЬШЕ 120 mb.

Обобщенные рекомендации, если рекомендации от 1С не помогли (проделать следующие действия в указанном порядке):

1. Выключить все фоновый задачи у всех баз
В 8.1.11 появился переключатель “запрет на фоновые задания” в
момент создания базы.

Готов пояснить, фоновые задания сами по себе не зло, но регламентные процедуры
с полнотекстовым поиском – вещь в себе – и память она может через какое время
съедать ресурсы rphost.exe, что на другие операции не останеться, и просто
базу блокировать
т.е. другими словами, после первого шага уже можно проверять – возможно проблема “уйдет”.

2. Перезапустить сервер
Второй шаг является частным случаем для вашего случая и после него тоже
есть смысл проверять работоспособность. Однако поскольку существуют утечки памяти http://www.gilev.ru/1c/memleak, то через некоторое время после рестарта пролема может вернуться.

3) делаем бэкап средствами sql
Делать резервное копирование рекомендую при любых действиях, когда может потребоваться “возврат” к предыдущему состоянию данных

4) снимаем базу с поддержки, выгружаем cf
убиваем в менеджмент консоли базе данных в таблице config запись более 120Мб, делаем “загрузить конфигурацию” (не объединение) убиваем в менеджмент консоли базе данных в таблице config запись более 120Мб, делаем “загрузить конфигурацию” (не объединение)

вот пример работоспособности этого приема
http://partners.v8.1c.ru/forum/thread.jsp?id=543293

или

1. Открыть конфигратор;
2. Снял конфигурацию с поддержки, ПРИ ЭТОМ КОНФИГУРАЦИЮ НЕ СОХРАНЯЛ!
3. Далее Сохранить конфигурацию в файл (не сохраняя измененной конфигурации);
4. В SQL для требуемой базы выполнил следующую команду:
DELETE FROM dbo.Config WHERE DataSize > 125829120
5. Загрузить сохраненную конфигурацию обратно.

Взято с http://www.forum.mista.ru/topic.php?id=465608

можно попробовать и более радикальный шаг здесь:
удаляем (в менеджмент консоли) в базе данных таблицу “config”
D_rop TABLE [dbo].[Config]

5) делаем “загрузить конфигурацию” (не объединение) из cf
после этого проверяем, проблема уходит.

6) Ошибка :"Соединение с сервером баз данных разорвано администратором
Microsoft OLE DB Provider for SQL Server: Неопознанная ошибка
HRESULT=80004005"

Имеем : 1C 8.1.13.41 УПП 1.2.19.21 на MS SQL 2005 SP3 на Win2003 Server Enterprise на компе 4Gb физ. памяти (SQL настроен на Max Memory 2Gb)

Решение в моем случае:
Виндовс по-умолчанию 2Гб берет себе, а 2 отдает нам. SQL почти всю остальную память поедал (в настройках стоит 2Gb) и оставлял для всех остальных только 128Мб физ. памяти(как и положено SQL- он не должен забирать ВСЁ, должен 128 оставить). Ошибка 1С начала проявляться после перехода на релиз 1.2.21.1. Да, действительно, в релизе 1.2.19.1 в файле dbo.Config не было записей больше 120Мб. А вот после обновления на 1.2.21.1 такая запись (примерно 135мб )появляется. При снятии с поддержки запись исчезает сама, и ничего удалять не приходится. При постановке на поддержку -снова появляется... Я так понял, что это и есть конфигурация поставщика.
Если SQL оставляет всего 128, а надо целых 135, то вывод- надо дать рабочим процессам живую физическую память. Moжно урезать SQL. А можно винды. Установив в boot.ini ключ /3GB я тем самым отдал виндам 1Gb, а всему остальному 3Gb, а не 2/2 как по умолчанию. После перезагрузки - все ОК.

У Вас есть свое решение!? оставьте его в комментариях)

Категория: Администрирование

Передача файлов и данных на веб-сервер из 1С методами GET и POST

При интеграции 1С с веб-сайтами всегда встает вопрос о передачи некоторых данных на веб-сервер. Будь то это передача параметров запроса для получения данных от веб-сервера в 1С или же передача данных из 1С, которые должны быть сохранены или каким-то образом обработаны на веб-сервере. Передаваться могут как простые данные в виде строк, чисел, так и целые файлы (изображения, XML-файлы и прочее). Для передачи и получения файлов и данных на веб-сервер в 1С используется объект HTTPСоединение.

Создание и инициализация HTTP соединения в 1С
Для инициализации HTTP соединения в 1С необходимо создать объект HTTPСоединение и в конструкторе указать параметры HTTP соединения.

Код 1C v 8.х

 Новый HTTPСоединение(<Сервер>, <Порт>, <ИмяПользователя>, <Пароль>, <Прокси>, <ЗащищенноеСоединение>)

<Сервер> (обязательный) - адрес сервера, с которым необходимо установить соединение.
<Порт> (необязательный) - порт сервера, с которым устанавливается соединение.
Значение по умолчанию зависит от защищенности соединения (80 для незащищенного и 443 для SSL-соединения).
<ИмяПользователя> (необязательный) - имя пользователя на указанном сервере.
<Пароль> (необязательный) - пароль пользователя на указанном сервере.
<Прокси> (необязательный). Тип - ИнтернетПрокси. Прокси, используемый для соединения с сервером.
<ЗащищенноеСоединение> (необязательный). Тип - Булево. Определяет используемый протокол -
http или https. По умолчанию Ложь.
Ниже приведен примеры создания HTTPСоединения с сайтом http://www.mysite.ru/.

Код 1C v 8.х

 // соединение с параметрами по умолчанию

Соединение = Новый HTTPСоединение("www.mysite.ru");

 

// сервер использует порт 8080

Соединение = Новый HTTPСоединение("www.mysite.ru", 8080);

 

// сервер использует защищенное соединение (https),

// для подключения к серверу используется прокси

ПроксиСервер = Новый интернетПрокси;

ПроксиСервер.Пользователь = имяПользователя;

ПроксиСервер.Пароль       = парольПользователя;

 

Соединение = Новый HTTPСоединение("www.mysite.ru",,,, ПроксиСервер, Истина);

Передача данных на веб-сервер из 1С методом GET.
Для передачи данных на веб-сервер из 1С методом GET используется процедура Получить() объекта HTTPСоединение.

Код 1C v 8.х

 Получить(<Источник>, <ИмяВыходногоФайла>, <Заголовки>)

<Источник> (обязательный). Тип - Строка. Адрес ресурса на сервере.
<ИмяВыходногоФайла> (обязательный). Тип - Строка. Имя файла на диске, в который
помещаются данные, полученные от сервера (ответ сервера).
<Заголовки> (необязательный). Тип - Строка. Заголовки, добавляемые к запросу на сервер.
Текстовые пары вида <Заголовок>:<Значение>, разделенные комбинацией ВК + ПС.
(подробнее о заголовках будет сказано ниже).
Рассмотрим параметры процедуры Получить() более подробно:

В качестве источника указывается строка с адресом запроса, идущая после названия домена и символа "/". Так, если необходимо отправить данные на адрес https://www.mysite.com/getusers.php, то при создании HTTP соединения в конструкторе HTTPСоединение в поле "Сервер" указывается "www.mysite.com", признак защищенного соединения устанавливается в Истина, а в процедуре Получить() в параметре Источник указывается "getUsers.php".

В поле ИмяВыходногоФайла указывает имя файла на диске, в который будут сохранены данные, полученные от сервере в результате запроса. Так, например, если сервер возвращает список пользователей в формате XML, то на диск в указанный файл будет сохранен XML файл со списком пользователей.

О заголовках более подробно будет сказано ниже.

Так же, при запросе к веб-серверу зачастую передаются дополнительные данные (параметры) для этого запроса. Параметры от адреса источника отделяются символом "?". Каждый параметр задается в формате <Имя_Параметры>=<Значение_Параметры>. Параметры от адреса источника отделяются символом "?". Сами же параметры отделяются друг от друга символом "&". В результате строка адреса источника может выглядеть следующим образом: getUsers.php?owner_id=263544&count=100.

Ниже приведен пример, поясняющий все выше сказанное.

Код 1C v 8.х

 // необходимо выполнить запрос по адресу

// https://www.mysite.com/getUsers.php?owner_id=263544&amp;count=100

// ответ от сервера приходит в виде XML файла

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml");

 

Соединение = Новый HTTPСоединение("www.mysite.com",,,,, Истина);

Соединение.Получить("getUsers.php?owner_id=263544&amp;count=100", имяВыходногоФайла);

 

ЧтениеXML = Новый ЧтениеXML;

ЧтениеXML.ОткрытьФайл(имяВыходногоФайла);

 

Пока ЧтениеXML.Прочитать() Цикл

    // чтение ответа в виде XML файла

    ...

КонецЦикла;

 

ЧтениеXML.Закрыть();

 

// удаляем файл после использования

УдалитьФайлы(имяВыходногоФайла);

Заголовки HTTP
Ниже приведена общая информация о HTTP заголовках из википедии.
Заголовки HTTP (англ. HTTP Headers) — это строки в HTTP-сообщении, содержащие разделённую двоеточием пару имя-значение. Формат заголовков соответствует общему формату заголовков текстовых сетевых сообщений ARPA. Заголовки должны отделяться от тела сообщения хотя бы одной пустой строкой.

Все заголовки разделяются на четыре основных группы:

General Headers (рус. Основные заголовки) — должны включаться в любое сообщение клиента и сервера.
Request Headers (рус. Заголовки запроса) — используются только в запросах клиента.
Response Headers (рус. Заголовки ответа) — только для ответов от сервера.
Entity Headers (рус. Заголовки сущности) — сопровождают каждую сущность сообщения.
Именно в таком порядке рекомендуется посылать заголовки получателю.

Более подробно о заголовках HTTP можно прочитать здесь. Так же можно ознакомится со списком заголовков HTTP.

От себя лишь добавлю, что, если это явно не указано в требованиях к отправке данных веб-серверу заголовки HTTP для метода GET можно не указывать. Для метода POST обычно нужно указать заголовки Content-Type (тип передаваемых данных, например: "Content-Type: text/html;charset=utf-8") и Content-Length (размер передаваемых данных в байтах, например: "Content-Length: 1348").

Напомню, что HTTP заголовки в 1С указываются строкой в виде текстовых пар "<Заголовок>:<Значение>", разделенных комбинацией символов ВК+ПС.
Также заголовки можно задать типом Соответствие, где в качестве ключа указывается заголовок, а в качестве значения - значение заголовка.
Ниже приведены поясняющие примеры:

Код 1C v 8.х

 источник = "owner=263544&amp;count=100";

 

// Передача заголовков строкой

ЗаголовкиHTTP = "Content-Type:text/html;charset=utf-8" + Символ.ВК + Символ.ПС +

            "Content-Length: "+СтрДлина(источник);

Соединение.Получить("", имяВыходногоФайла, ЗаголовкиHTTP);

 

// Вставить символы ВК+ПС можно и таким способом

ЗаголовкиHTTP = "Content-Type:text/html;charset=utf-8

            |Content-Length: 1348";

Соединение.Получить("", имяВыходногоФайла, ЗаголовкиHTTP);

 

// Установка заголовков типом Соответствие

ЗаголовкиHTTP = Новый Соответствие;

ЗаголовкиHTTP.Вставить("Content-Type", "text/html;charset=utf-8");

ЗаголовкиHTTP.Вставить("Content-Length", СтрДлина(источник));

 

Соединение.Получить(источник, имяВыходногоФайла, ЗаголовкиHTTP);

Передача данных на веб-сервер из 1С методом POST.
Общие сведения.
Для передачи данных на веб-сервер из 1С методом POST используется процедура ОтправитьДляОбработки() объекта HTTPСоединение.

Код 1C v 8.х

 ОтправитьДляОбработки(<Источник>, <АдресРесурса>, <ИмяВыходногоФайла>, <Заголовки>)

<Источник> (обязательный) - Имя файла-источника, который будет отправлен
на сервер для обработки.
<АдресРесурса> (обязательный). Тип - строка. Адрес ресурса на сервере,
в который посылаются данные из источника.
<ИмяВыходногФайла> (обязательный) - Имя файла на диске, в который записываются
полученные с сервера данные.
<Заголовки> (необязательный). Тип - строка. Заголовки, добавляемые к запросу на сервер.
Текстовые пары вида <Заголовок>:<Значение>, разделенные комбинацией ВК + ПС.
(подробнее о заголовках будет сказано ниже).
Рассмотрим параметры процедуры ОтправитьДляОбработки() подробнее:

В качестве источника указывается файл, содержимое которого необходимо отправить на сервер для обработки. Подробнее о формировании содержимого файла-источника будет сказано ниже.

Поле АдресРесурса аналогично полю Источник процедуры Получить(), т.е. указывается строка с адресом запроса, идущая после имени домена и символа "/".

Поле ИмяВыходногоФайла также аналогично одноименному полю процедуры Получить(), т.е. содержит имя файла, в котором будут сохранены данные, полученные от сервера в результате обработки исходных данных.

О заголовках было упомянуто выше. Напомню лишь, что для метода POST обычно указываются заголовки Content-Type и Content-Length. В качестве параметра заголовка Content-Length указывается размер файла-источника, преобразованный с помощью функции XMLСтрока().

Ниже приведен пример, поясняющий все выше сказанное.

Код 1C v 8.х

 имяФайлаОтправки = "d:\data\request.txt"; // файл с отсылаемыми для обработки данными

 

// Определим размер файла-источника

// и установим HTTP заголовки

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "text/html;charset=utf-8");

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml");

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "addPost.php", имяВыходногоФайла, Заголовки);

Передача параметров методом POST.
Для передачи параметров, аналогично методу GET, можно сформировать строку параметров, записать их в текстовый файл и отправить этот файл на сервер для обработки. Ниже приведен пример аналогичный примеру отправки методом GET, но теперь те же данные отправляются методом POST.

Код 1C v 8.х

 // сформируем файл для отправки на сервер

 

имяФайлаОтправки = ПолучитьимяВременногоФайла("txt");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаОтправки);

ЗаписьТекста.Записать("owner=263544&amp;count=100");

ЗаписьТекста.Закрыть();

 

// отправим файл на сервер для обработки

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml"); // наш сервер возвращает ответы в виде XML

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "text/html;charset=utf-8");

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "addPost.php", имяВыходногоФайла, Заголовки);

 

// удалим файл отправки - он больше не нужен

Попытка

    УдалитьФайлы(имяФайлаОтправки);

Исключение

КонецПопытки;

 

// обработаем ответ сервера

 

ЧтениеXML = Новый ЧтениеXML;

ЧтениеXML.ОткрытьФайл(имяВыходногоФайла);

 

Пока ЧтениеXML.Прочитать() Цикл

    // чтение ответа в виде XML файла

    ...

КонецЦикла;

 

ЧтениеXML.Закрыть();

 

// удаляем файл после использования

Попытка

    УдалитьФайлы(имяВыходногоФайла); 

Исключение

КонецПопытки;

Передача файлов методом POST.
Зачастую данные для обработки задаются не виде строки параметров разделенных "&", как в рассматриваемых выше примерах, а виде файла определенного формата, например XML или JSON. Рассмотрим пример отправки данных на веб-сервер для обработки методом POST, которые задаются в формате XML. Например, сервер может добавить ваш комментарий к материалу. В описании процедуры добавлении сказано, что данные необходимо отправлять по адресу www.mysite.com/addComment.php. Сами данные должны быть переданы в следующем виде:

Код

<?xml version="1.0" encoding="UTF-8"?>
<request>
<user_id>ID_Пользователя</user_id>
<post_id>ID_Материала</post_id>
<message>Текст_Комментария</message>
</request>

где:
<ID_Пользователя> - id пользователя на сайте, от имени которого добавляется комментарий;
<ID_Материала> - id материала на сайте, к которому добавляется комментарий;
<Текст_Комментария> - текст комментария.

Предположим, что нам уже известны id пользователя и материала и они хранятся в переменных user_id и post_id. Ниже приведен пример, решающий нашу задачу.

Код 1C v 8.х

 // подготовим файл с данными для отправки

имяФайлаОтправки = ПолучитьимяВременногоФайла("xml");

 

ОбъектXML = Новый ЗаписьXML;

ОбъектXML.ОткрытьФайл(имяФайлаОтправки, "UTF-8");

ОбъектXML.ЗаписатьОбъявлениеXML();

ОбъектXML.ЗаписатьБезОбработки(

"<request>

|    <user_id>" + user_id + "</user_id>

|    <post_id>" + post_id + "</post_id>

|    <message>" + ТекстКомментария + "</message>

|</request>");

ОбъектXML.Закрыть();

 

// отправим файл на сервер для обработки

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml"); // наш сервер возвращает ответы в виде XML

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "text/html;charset=utf-8");

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "addComment.php", имяВыходногоФайла, Заголовки);

 

// удалим файл отправки - он больше не нужен

Попытка

    УдалитьФайлы(имяФайлаОтправки);

Исключение

КонецПопытки;

 

// обработаем ответ сервера

 

ЧтениеXML = Новый ЧтениеXML;

ЧтениеXML.ОткрытьФайл(имяВыходногоФайла);

 

Пока ЧтениеXML.Прочитать() Цикл

    // чтение ответа в виде XML файла

    ...

КонецЦикла;

 

ЧтениеXML.Закрыть();

 

// удаляем файл после использования

Попытка

    УдалитьФайлы(имяВыходногоФайла); 

Исключение

КонецПопытки;

Загрузка файлов (изображений, документов и т.п.) на веб-сервер методом POST.
Зачастую возникает необходимость загрузки файлов на веб-сервер. Это может быть, например, изображение к статье на сайте, или фотография для альбома, или архив для файлообменника. Ранее мы рассматривали передачу методом POST параметров или просто файлов. Таким же образом можно и передавать двоичные файлы. Но как быть, если файлы необходимо отправлять вместе с параметрами? Для возможности отправки файлов в этом случае используется HTTP заголовок ContentType:multipart/form-data. Следует заметить, что обычно таким способом передаются файлы через веб-браузеры. Т.е. когда на сайте вы выбираете файл и нажимаете кнопку "Загрузить", то файл передается способом описанным ниже. При таком способе сам файл также задается как переменная, т.е., например, файл передается через параметр file или image. Однако, мы не можем просто передать file=<Двоичные_Данные>. А вот как все таки передать файл мы и рассмотрим ниже.

Для возможности вместе с параметрами передавать и двоичные данные (файлы) необходимо сформировать HTTP заголовок Content-Type следующим образом:
Content-Type: multipart/form-data, boundary=<уникальные_данные>
где <уникальные_данные> - это любой набор цифр и/или символов, который будет служить для отделения значений друг от друга. Значение boundary должно быть уникальным в пределах пересылаемой информации, т.е. таких символов не должно встречаться в пересылаемых файлах и переменных.

Bounday можно сформировать, например, таким образом

Код 1C v 8.х

 boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

Все данные отделяются друг от друга разделителем boundary. Начинать разделитель нужно с "--":

Код

--<boundary>
Content-Disposition: form-data; name="<имя_переменной>"
<пустая_строка>
<значение_переменной>
Для отправки файла необходимо еще добавить тип и имя файла:

--<boundary>
Content-Disposition: form-data; name="<имя_переменной>"; filename="<имя_файла>"
Content-Type: <тип_файла> (например image/jpeg или text/plain)
<пустая_строка>
<данные_файла>

В конце данных нужно закрыть разделитель, добавили в конце разделителя "--", т.е. вид будет "--<boundary>--".

Итак, например, нам нужно передать на веб-сервер текстовый файл через параметр "text", его описание через параметр "desc" и id пользователя через параметр "uid", для которого будет загружен наш файл.

Предположим, что файл содержит следующий текст:
Мороз и солнце; день чудесный!
Еще ты дремлешь, друг прелестный -
Пора, красавица, проснись:
Открой сомкнуты негой взоры
Навстречу северной Авроры,
Звездою севера явись!
Описание должно содержать "Стих А.С. Пушкина", а id пользователя равно "0123456". Тогда файл должен быть сформирован следующим образом (для упрощения предположим, что bounday мы уже сформировали и он равен "ccf8111910")

Код

--ccf8111910
Content-Disposition: form-data; name="uid"

0123456
--ccf8111910
Content-Disposition: form-data; name="desc"

Стих А.С. Пушкина
--ccf8111910
Content-Disposition: form-data; name="text"; filename="stih.txt"
Content-Type: text/plain

Мороз и солнце; день чудесный!
Еще ты дремлешь, друг прелестный -
Пора, красавица, проснись:
Открой сомкнуты негой взоры
Навстречу северной Авроры,
Звездою севера явись!
--ccf8111910--

А теперь перейдем непосредственно к 1С. Пусть у нас будет форма с реквизитами "Пользователь", "Описание" и "ИмяФайла". Реализуем отправку данных, описанным выше способом

Код 1C v 8.х

 // подготовим файл с данными для отправки

имяФайлаОтправки = ПолучитьимяВременногоФайла("txt");

Boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаОтправки);

 

// параметр "uid"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""uid""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(Пользователь);

 

// параметр "desc"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""desc""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(Описание);

 

// параметр "text"

ФайлДляПередачи = Новый ТекстовыйДокумент;

ФайлДляПередачи.Прочитать(имяФайла);

 

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""text""; filename=""stih.txt""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: text/plain");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.Записать(ФайлДляПередачи.ПолучитьТекст());

ЗаписьТекста.ЗаписатьСтроку("");

 

// закроем разделитель

ЗаписьТекста.ЗаписатьСтроку("--"+boundary+"--");

 

ЗаписьТекста.Закрыть();

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

// передадим данные на сервер 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "multipart/form-data, boundary="+boundary);

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "postFile.php", имяВыходногоФайла, Заголовки);

Передача текстовых файлов таким способом проблем не вызывает. Сложнее дело обстоит с файлами, содержащими двоичные данные (изображения, архивы и т.п.). Все дело в том, что в 1С просто нет методов для чтение двоичных файлов в строку. Если мы делаем обмен со своим сайтом, которые сами и разрабатывали, то можно просто преобразовать файл в строку Base64 при помощи процедуры Base64Строка(), а на стороне сервера преобразовать строку Base64 обратно.

Код 1C v 8.х

 // подготовим файл с данными для отправки

имяФайлаДанных = "d:\photo\birthday.jpg";

 

имяФайлаОтправки = ПолучитьимяВременногоФайла("txt");

Boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаОтправки);

 

// параметр "file"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""file""; filename=""photo.jpg""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: image/jpeg");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.Записать(Base64Строка(Новый ДвоичныеДанные(имяФайлаДанных)));

ЗаписьТекста.ЗаписатьСтроку("");

 

// закроем разделитель

ЗаписьТекста.ЗаписатьСтроку("--"+boundary+"--");

 

ЗаписьТекста.Закрыть();

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

// передадим данные на сервер 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "multipart/form-data, boundary="+boundary);

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "uploadFile.php", имяВыходногоФайла, Заголовки);

А как же быть если мы загружаем файл на сторонний сервер, который принимает файл как есть без преобразование его в строку Base64(). В это случае можно пойти на хитрость. В 1С есть процедура ОбъединитьФайлы(), которая объединяет несколько файлов на диске в один результирующий файл

Код 1C v 8.х

 ОбъединитьФайлы(<ИменаЧастей>, <ИмяРезультирующегоФайла>)

<ИменаЧастей> (обязательный). Тип - Массив. Массив имен частей файлов, которые
требуется объединить. Объединение будет происходить в порядке, в котором заданы
имена файлов в массиве.
<ИмяРезультирующегоФайла> (обязательный). Тип - Строка. Имя файла, который будет
создан в результате объединения файлов.
Т.е. мы можем сформировать текстовый файл с запросом, объединить его с файлом(-ами), которые необходимо передать на веб-сервер и передать уже файл, получившийся в результате объединения исходных файлов. Ниже демонстрируется процесс передачи двух zip архивов на сервер с дополнительными параметрами user_id и post_id.

Код 1C v 8.х

 // подготовим файлы с данными для отправки

 

массивФайлов = Новый Массив;

 

Boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

 

имяФайлаСПараметрами = ПолучитьимяВременногоФайла("txt"); // первый файл, содержащий параметры

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаСПараметрами);

 

// параметр "user_id"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""user_id""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(user_id);

 

// параметр "post_id"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""post_id""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(post_id);

 

// начало параметра "file1"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""file1""; filename=""archive1.zip""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: application/x-zip-compressed");

ЗаписьТекста.ЗаписатьСтроку("");

 

ЗаписьТекста.Закрыть(); // заканчиваем работу с файлом 1

 

массивФайлов.Добавить(имяФайлаСПараметрами); // добавляем 1-ый файл для объединения

массивФайлов.Добавить(имяФайлаАрхива1); // добавляем 1-ый архив для объединения

 

// второй файл параметров, содержаший начало параметра "file2"

имяФайлаСПараметрами = ПолучитьимяВременногоФайла("txt");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаСПараметрами);

 

// начало параметра "file2"

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""file2""; filename=""archive2.zip""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: application/x-zip-compressed");

ЗаписьТекста.ЗаписатьСтроку("");

 

ЗаписьТекста.Закрыть(); // заканчиваем работу с файлом 2

 

массивФайлов.Добавить(имяФайлаСПараметрами); // добавляем 2-ой файл для объединения

массивФайлов.Добавить(имяФайлаАрхива2); // добавляем 2-ой архив для объединения

 

ЗаписьТекста.Записать(ФайлДляПередачи.ПолучитьТекст());

ЗаписьТекста.ЗаписатьСтроку("");

 

// третий файл, закрывающий параметры

имяФайлаСПараметрами = ПолучитьимяВременногоФайла("txt");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаСПараметрами);

 

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку("--"+boundary+"--");

 

ЗаписьТекста.Закрыть(); // заканчиваем работу с файлом 3

 

массивФайлов.Добавить(имяФайлаСПараметрами); // добавляем 3-ий файл, закрывающий параметры

 

// результирующий файл, который и будет отправлен

имяФайлаОтправки = ПолучитимяВременногоФайла("out");

 

// объединим все файлы

ОбъединитьФайлы(массивФайлов, имяФайлаОтправки);

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

// передадим данные на сервер 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "multipart/form-data, boundary="+boundary);

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "postFile.php", имяВыходногоФайла, Заголовки);

Ну вот, вроде бы, и все, что я хотел рассказать о способах передачи файлов и данных на веб-сервер из 1С. Если что-то не понятно, что-то хотите уточнить или нашли ошибки - пишите в комментариях.
Автор: Павел

Категория: Работа с Интернет, Почтой (Mail), FTP

Оптимизация запросов

Почему запрос может работать неоптимально:
1. в виртуальных таблицах не используются параметры
2. соединения с подзапросами, условия с подзапросами, вложенные подзапросы
3. соединения с виртуальными таблицами
4. наложение условий на неиндексированные поля
5. получение данных из составного типа через точку
6. использование вложенных подзапросов (с большой вложенностью)

Подробнее:
1. В виртуальных таблицах не используются параметры
Рекомендация
Надо использовать по-максимуму параметры виртуальных таблиц (Остатки, Обороты, ОстаткиИОбороты)
Объяснение
Сперва выбираются данные для виртуальных таблиц, а потом уже на них накладываются условия, соединения и т.д. Т.е. если сделать запрос:

Код 1C v 8.х

 ВЫБРАТЬ

 ТоварыНаСкладахОстатки.Номенклатура,

 ТоварыНаСкладахОстатки.КоличествоОстаток

ИЗ

 РегистрНакопления.ТоварыНаСкладах.Остатки КАК ТоварыНаСкладахОстатки

ГДЕ

 ТоварыНаСкладахОстатки.Склад = &Склад

То сперва выберется вся имеющаяся номенклатура со всеми остатками, а потом на неё наложится условие склада. Надо так:

Код 1C v 8.х

 ВЫБРАТЬ

 ТоварыНаСкладахОстатки.Номенклатура,

 ТоварыНаСкладахОстатки.КоличествоОстаток

ИЗ

 РегистрНакопления.ТоварыНаСкладах.Остатки(, Склад = &Склад) КАК ТоварыНаСкладахОстатки

2. Соединения с подзапросами, условия с подзапросами, вложенные подзапросы
Рекомендация
Надо вообще стараться не использовать подзапросы, а переписать их во временные таблицы. Соединять следует только объекты метаданных или временные таблицы.
Объяснение
Оптимизатор СУБД часто не может составить оптимальный план выполнения таких запросов. Проблема в определении алгоритма соединения, который зависит от количества записей в выборке. При использовании временных таблиц размер выбираемых таблиц известен заранее, поэтому СУБД легче составить оптимальный план выполнения. Но при этом появляются накладные расходы на создание временных таблиц.

3. Соединения с виртуальными таблицами
Рекомендация
Перед соединениями с виртуальными таблицами их следует предварительно выбрать во временные и соединять уже с ними.
Объяснение
Виртуальные таблицы часто содержатся в нескольких физических таблицах СУБД, в итоге для их выборки составляется подзапрос, а проблемы с ним расшифрованы в п.2.

4. Наложение условий на неидексированные поля
Рекомендация
Для условий запросов должны существовать подходящие индексы.
При соединении с виртуальными таблицами, их необходимо проиндексировать по полям, участвующим в соединении.
Объяснение
При отсутствии подходящего индекса СУБД будет сканировать всю таблицу для соединения по каждому полю.

5. Получение данных из составного типа через точку
Рекомендация
В запросах использовать ВЫРАЗИТЬ(... КАК ...), в описании типов полей указывать только необходимые типы.
Объяснение
При выполнении запроса для составного типа без ВЫРАЗИТЬ будет происходить соединение с таблицами всех объектов, входящих в составной тип.

Категория: Запросы

Создание событий и напоминаний пользователям используя Задачи

В процессе работы пользователей, зачастую возникает необходимость создать задачу другому пользователю ИБ и проконтролировать ее выполнение.

К примеру, существует следующая задача:
Автоматизируемая компания занимается торговлей оборудованием. Специфика отгрузки оборудования заключается в том, что в основном она сопровождается оказанием услуг по монтажу закупленного оборудования. Исходя из этого, при оформлении заказа покупателя необходимо кроме ответственного за данный заказ указывать ответственного сотрудника по монтажу (в случае если это услуга не предусмотрена, реквизит не виден).

Если услуга по монтажу оборудования предусмотрена, то автоматически должно сформироваться два напоминания (события):
- Для ответственного менеджера на дату и время напоминания
- Для сотрудника ответственного за монтаж за сутки до напоминания ответственному менеджеру.

Когда срабатывает напоминание у ответственного менеджера, он должен видеть отработано ли напоминание сотрудника по монтажу оборудования.

Сформировать отчет, показывающий состояние согласования (когда сотрудник, ответственный за монтаж отработал напоминание) по незакрытым заказам покупателей (в случае оказание услуги по монтажу).

Решим ее следующим способом:
Создаем три реквизита документа Заказ покупателя: М_Монтаж (булево), М_Монтажник (Справочник пользователи) и М_ДатаМонтажа. Размещаем их на форме. Для того что бы сами реквизиты и их надписи были не видимы добавим процедуру:

Код 1C v 8.х

 Процедура М_МонтажПриИзменении(Элемент)

ЭлементыФормы.М_Монтажник.Видимость = М_Монтаж;

ЭлементыФормы.М_ДатаМонтажа.Видимость = М_Монтаж;

ЭлементыФормы.НадписьМ_Монтажник.Видимость = М_Монтаж;

ЭлементыФормы.НадписьМ_ДатаМонтажа.Видимость = М_Монтаж;

КонецПроцедуры

При открытии формы документа тоже надо проверять можно ли отображать на форме новые реквизиты. Процедура УстановитьВидимость() вызывается из процедуры ПриОткрытии(). Именно здесь продублируем код процедуры М_МонтажПриИзменении(Элемент). Существуют, конечно, варианты. Например, можно управление видимостью организовать только в процедуре УстановитьВидимость() а в МонтажПриИзменении() обращаться к ней, или в процедуре УстановитьВидимость() вызывать МонтажПриИзменении(), однако, в первом варианте при каждом изменении значения реквизита «М_Монтаж» будет происходить установка видимости всех реквизитов в форме, что негативно скажется на производительности. Второй вариант не совсем корректен с точки зрения логики расположения программного кода, по этому сделаем наш код слегка избыточным, но зато логичным и не замедляющим работу программы.
При проведении документа следует создавать Задачу пользователя с взведенным флагом «Напоминание» и установленной датой напоминания. Лучше всего располагать создание задач после проверки на корректность заполнения всех полей документов (ведь документ может не провестись, а задачи создадутся)

Код 1C v 8.х

 // Движения по документу

Если Не Отказ Тогда

 ДвиженияПоРегистрам(РежимПроведения, СтруктураШапкиДокумента, ТаблицаПоТоварам, ТаблицаПоУслугам, ТаблицаПоТаре, Отказ, Заголовок);

 Если М_Монтаж тогда

  РаботаСДиалогами.ПроверитьЗадачиПоОбъекту(Ссылка);

 КонецЕсли;

КонецЕсли;

Создавать задачи лучше с помощью немного доработанной процедуры РаботаСДиалогами.ПроверитьЗадачиПоОбъекту(Ссылка);
Во-первых, она проверит, есть ли введенные на основании этого документа задачи, и если обнаружит их, выдаст диалоговое окно пользователю с предложением не создавать новые. Этим мы исключим вероятность создания большого числа напоминаний при перепроведении документа. В самой функции ПроверитьЗадачиПоОбъекту() напишем:

Код 1C v 8.х

 Процедура ПроверитьЗадачиПоОбъекту(ОбъектЗадачи) Экспорт



Запрос = Новый Запрос;

Запрос.Текст = "

|ВЫБРАТЬ РАЗРЕШЕННЫЕ ПЕРВЫЕ 1

| *

|ИЗ

| Задача.ЗадачиПользователя.ЗадачиПоИсполнителю(

| &ТекПользователь,

| Выполнена = ЛОЖЬ И Объект = &ОбъектЗадачи)

|";

Запрос.УстановитьПараметр("ТекПользователь", ПараметрыСеанса.ТекущийПользователь);

Запрос.УстановитьПараметр("ОбъектЗадачи" , ОбъектЗадачи);

РезультатЗапроса = Запрос.Выполнить();

Если НЕ РезультатЗапроса.Пустой() Тогда

Выполнение = Вопрос("Обнаружены незавершенные задачи по заданному объекту!" + Символы.ПС + " Желаете просмотреть список этих задач вместо создания новой?", РежимДиалогаВопрос.ДаНет, 0);

Если Выполнение = КодВозвратаДиалога.Да Тогда

 ОткрытьЗадачиТекущегоПользователя(ОбъектЗадачи);

 Возврат;

 КонецЕсли;

КонецЕсли;



// Сознание Задачи

НоваяЗадача = Задачи.ЗадачиПользователя.СоздатьЗадачу();

НоваяЗадача.Объект = ОбъектЗадачи;

НоваяЗадача.Оповещение = Истина;



Если ТипЗнч(ОбъектЗадачи) = Тип("ДокументСсылка.ЗаказПокупателя") тогда

 Если ОбъектЗадачи.М_Монтаж тогда

  НоваяЗадача.Наименование = "Напоминание менеджеру о сборке комплекта по: " + ОбъектЗадачи.Метаданные().Синоним;

  НоваяЗадача.Дата = ТекущаяДата();

  НоваяЗадача.СрокОповещения = ОбъектЗадачи.М_ДатаМонтажа;

  НоваяЗадача.Инициатор = ОбъектЗадачи.Ответственный;

  НоваяЗадача.Исполнитель = ОбъектЗадачи.Ответственный;

  НоваяЗадача.Записать();



  //   Напоминание мастеру

  НоваяЗадача = Задачи.ЗадачиПользователя.СоздатьЗадачу();

  НоваяЗадача.Дата = ТекущаяДата();

  НоваяЗадача.Объект = ОбъектЗадачи;

  НоваяЗадача.Инициатор = ОбъектЗадачи.Ответственный;

  НоваяЗадача.Оповещение = Истина;

  НоваяЗадача.Исполнитель = ОбъектЗадачи.М_Монтажник;

  НоваяЗадача.Наименование = "Напоминание мастеру о сборке комплекта по: " + ОбъектЗадачи.Метаданные().Синоним;

  НоваяЗадача.СрокОповещения = ОбъектЗадачи.М_ДатаМонтажа - 24 * 60 * 60;

  НоваяЗадача.Записать();

 КонецЕСли;

Иначе

 НоваяЗадача.Наименование = "Напоминание по объекту: " + ОбъектЗадачи.Метаданные().Синоним;

 ФормаНовой = НоваяЗадача.ПолучитьФорму();

 ФормаНовой.Открыть();

КонецЕсли;

КонецПроцедуры

Обратите внимание на реквизит «Инициатор» двух создаваемых нами задач. В форме списка задач существует возможность переключаться в режим просмотра заданий выданных текущим пользователем. Именно с помощью такого определения инициатора выполняется условие задачи: «В окошке напоминания менеджера должно быть видно, отработано ли событие монтажником»

Отчет в задании совсем не сложный, правда, могут возникнуть сомнения какой заказ считать закрытым. Как известно, заказ покупателя делает два движения. Одно по регистру «Заказы покупателя» где в разрезе номенклатуры, ведется учет по отгруженным товарам, второе по регистру «Расчеты с контрагентами» и здесь контролируется оплата по заказу. Думаю, что закрытым можно считать заказ, которого нет в остатках ни по одному, ни по второму регистру. Соединив их полным соединением, а так же присоединив таблицу Задач пользователя, получим отчет по незакрытым заказам пользователя.
Автор: Максим Нечистяк

Категория: Задачи

Пример разработки простого отчета - Схема Компоновки Данных

В статье описан пример создания отчета с использованием системы компоновки данных 1С:Предприятия 8.1. Схема компоновки данных - это описание отчета, при помощи которого платформа позволит вводить настройки и получать результат.

Рассмотрим пример создания отчета по взаиморасчетам с работниками (ЗУП 2.5):

1. Файл - Новый - Внешний отчет Для открытия и создания схемы компоновки нажмем кнопку "Открыть схему компоновки данных".
title

2. Система предложит создать новую схему компоновки данных. Схема компоновки данных является макетом, и будет записана в макеты. Укажите название схемы и нажмите "Готово"
title

3. Открывается окно конструктора схемы компановки данных:
title

Вкладка редактирования наборов данных. Здесь можно создавать или редактировать источники данных, в моем примере в качестве источника данных может выступать только текущая информационная база и он будет создаваться автоматически при добавлении первого набора данных.

В качестве набора данных может выступать:
Запрос - в этом случае получение данных описывается с помощью терминов языка запросов "1С: Предприятия 8.1" + инструкции специального расширения языка запросов для системы компоновки данных;
Объект - произвольный источник данных - например, таблица значений, сформированная и заполненная программно;
Объединение предназначено для описания наборов данных, входящих в объединение. Механизм объединения аналогичен объединению запросов средствами языка запросов;

4. Для нашего примера получим данные при помощи запроса, поэтому добавим набор данных - запрос. Для этого нажмем на кнопку "Добавить набор данных", которая расположена в командной панели на закладке "Наборы данных". В открывшемся меню выберем пункт "Добавить набор данных - запрос":
title

5. Будет создан набор данных. Теперь создадим запрос при помощи конструктора запросов, нажмем кнопку "Конструктор запроса"
title

6. Отчет, который мы создаем, будет получать данные из регистра накопления "ВзаиморасчетыСРаботникамиОрганизаций". Нас интересуют остатки, и текст запроса следующий:
title

Код 1C v 8.х

  ВЫБРАТЬ

       ВзаиморасчетыСРаботникамиОрганизацийОстатки.Организация,

       ВзаиморасчетыСРаботникамиОрганизацийОстатки.ПериодВзаиморасчетов,

       ВзаиморасчетыСРаботникамиОрганизацийОстатки.Физлицо,

       ВзаиморасчетыСРаботникамиОрганизацийОстатки.СуммаВзаиморасчетовОстаток

      ИЗ

       РегистрНакопления.ВзаиморасчетыСРаботникамиОрганизаций.Остатки КАК ВзаиморасчетыСРаботникамиОрганизацийОстатки

7. После закрытия конструктора запроса, конструктор схемы компановки Обратите внимание, что доступные поля для текущего набора данных будут сформированы системой автоматически только в том случае, если в конструкторе схемы компоновки данных стоит флаг Автозаполнение. Источником информации служит текст запроса. Система заполнила следующие поля:
title

Поле - имя поля набора данных, для которого делается описание. В нашем случае определяется именем поля в тексте запроса. Обратите внимание, по этому имени к полю нельзя будет обратиться в дальнейшем. Редактированию не подлежит
Путь - имя поля набора данных, под которым можно будет обратиться к полю в других разделах конструктора схемы компоновки данных. Может быть назначено разработчиком конфигурации самостоятельно
Заголовок - имя поля набора данных, под которым поле будет фигурировать в настройках в режиме 1С:Предприятие, а также в названии данного поля в шапке самого отчета. Может быть назначено разработчиком конфигурации самостоятельно. В качестве примера изменим Заголовок у поля Физлицо на Сотрудник
Роль - показывает, каким образом иоле будет использовано в дальнейшем в системе компоновки данных. Информация о том, что иоле является измерением, используется при расчете итогов по полям остатка.

8. Далее необходимо указать ресурсы. Ресурсы - это поля набора данных, по которым будет происходить агрегация значений.
Необходимо рассчитать суммы по полю "СуммаВзаиморасчетовОстаток". Найдем это поле в списке доступных полей и дважды щелкнем по нему. В правом табличном поле появится строка, содержащая формулу для расчета итога по полю "СуммаВзаиморасчетовОстаток". В нашем случае это "Сумма(СуммаВзаиморасчетовОстаток)". Эта формула означает, что для итоговых записей отчета значение поля "СуммаВзаиморасчетовОстаток" будет вычисляться как сумма поля "СуммаВзаиморасчетовОстаток" для всех строк участвующих в данной итоговой записи.
title

9. Этих введеных данных, нам хватит для вывода простого отчета. Перейдем на вкладку "Настройки" и откроем "Конструктор настроек"
title

10. Так как пока мы создаем простой отчет, выберем "Список", нажимая далее укажем выводимые поля:
title

11. После нажатия на "ОК" в конструкторе настроек, получаем следующее:
title

12. Закрываем схему компановки, сохраняем отчет в файл и запускаем в режиме 1С:Предприятия 8.1. Получаем:
title

Автор: Мигачев Евгений

Категория: Схема Компоновки Данных

Не удалось зафиксировать файл базы данных для открытия или изменения 1cv8.1CD

Фиксация файла базы данных – это разновидность внутренней блокировки, которая требуется, чтобы на некоторое непродолжительное время обеспечить целостность структуры файла при выполнении операций чтения данных или фиксации транзакции. При чтении требуется, чтобы эти структура файла была в целостном состоянии, а при фиксации транзакции структура может изменяться.
При нормальной работе такая ошибка возникать не должна. Суть сводится к следующему: для выполнения фиксация результатов транзакции может потребоваться выполнить перестройку внутренних структур данных файла *.1cd. А для выполнения чтения данных необходимо гарантировать, чтобы такая перестройка структур данных не выполнялась. Для обеспечения согласования этих операций имеется механизм внутренних блокировок, называемых фиксацией. Фиксация выполняется с ожиданием. В то же время предполагается, что фиксация выполняется на непродолжительное время, меньшее, чем время ожидания. Таким образом, если упомянутая ошибка возникла, то имеет место некоторое нарушение нормального хода событий. Мы наблюдали такую ситуацию и уже описывали ее в партнерской конференции. Вкратце все выглядит примерно так. В какой-то момент времени запрос на блокировку участка файла (функция LockFile() Win32 API) выдает ошибку Network error. В результате возникает ошибка движка файловой базы данных "Не удалось зафиксировать файл базы данных для открытия или изменения".
Природа ошибки нам пока непонятна. Известно только, что она возникает далеко не у всех. Не отмечено никакой связи возникновения этой ошибки с версией 1С:Предприятия 8.0 и используемой конфигурацией. По-видимому речь идет о каких-то особенностях некоторых сетей.

Вполне возможно, что проблема возникает из за нестабильности работы сети
Один из способов проверить - выполнить команду:
ping [Имя сервера] -t
на компьютере, с которого запускается 1с
после чего запустить 1с и посмотреть, что будет происходить...

Категория: Системные Ошибки

Коды ошибок 1Сv8 800*

Проблема:
Не найден интерфейс сервера (80070005)

Решение:
1. На клиенте включить DCOM утилитой dcomcnfg и добавить нужные протоколы в список.
2. На серваке добавить пользователей в группу "Distributed COM Users"
3. Перезапустить COM-приложение на сервере 1С:Предприятия

В настройках Windows на сервере должна быть включена роль "Сервер приложений" (Application Server)

Прочитать статью на ИТС.

Если клиент и сервер в разных подсетках (доменах), на сервере в локальную группу "Пользователи DCOM" пропишите пользователя клиента. Члены этой группы могут запускать, активизировать и использовать объекты DCOM на этом компьютере.

-----------
Проблема:
После выбора информационной базы (но до логина в 1с) возникает ощибка "Объект сервера 1С предприятия не обнаружен. 800706BF".

Решение:

1) Права пользователя.
Возможно, что пользователь, от имени которого запускается клиентское приложение не зарегистрирован и не доступен компьютеру сервера 1С:Предприятия.
2) Проверьте на клиентском компьютере настройки DCOM.
dcomcnfg/ Default protocols:
- Connection oriented TCP/IP
dcomcnfg/ Default properties:
- Enable distributed COM on this computer
- Default authentication level: Connect
- Default impersonation level: Identify
3) Попробуйте на серверном и клиентском компьютере понизить уровень
аутентификации:
Default authentication level: None
4) Проверьте, не установлено ли сетевых экранов. Откройте порт 135 и те, которые указаны на клиенте и сервере в диалоге:
dcomcnfg/ Default protocols/ Properties/ Post Ranges.
Если там диапазонов портов не указано - задайте их.

----------
Ошибка соединения с сервером 1С:Предприятия 8.0: Неправильный путь к файлу C:W

Решение:
Возможная причина ошибки в том, что для пользователя USER1CV8SERVER не заданы переменные окружения TEMP и TMP, поэтому при создании новой базы временные файлы пытаются быть созданными в корне диска C:
----------

Ошибка создания информационной базы: Компоненты OLE DB провайдера не найдены

Решение:
Такое сообщение может быть выдано, если сервер 1С:Предприятия не смог создать COM объект OLE DB Provider for Microsoft SQL Server.
Ознакомьтесь с разделом "Администрирование/ Установка и настройка/ Сервер 1С:Предприятия и SQL-сервер" на диске ИТС.
1) Найдите в Registry ветку
HKEY_CLASSES_ROOTCLSID{0C7FF16C-38E3-11d0-97AB-00C04FC2AD98}InprocServer32
Какой маршрут до файла SQLOLEDB.DLL является значением параметра default?
Убедитесь, что в этом каталоге этот файл есть.
2) Убедитесь, что каталог с файлом SQLOLEDB.DLL доступен пользователю USER1CV8SERVER. Для этого к списку пользователей, имеющих права на каталог можно добавить пользователя USER1CV8SERVER или группу everyone.
3) Запустите утилиту Microsoft SQL Server Client Network Utility. На закладке General установите протокол TCP/IP. На закладке Network Libraries посмотрите маршрут сетевой библиотеки для протокола TCP/IP. Убедитесь, что она присутствует в указанном каталоге и пользователь USER1CV8SERVER имеет доступ в этот каталог.
Попробуйте переустановить MDAC.
Убедитесь, что у пользователя, от имени которого стартует сервер 1С:Предприятия, есть права на каталог, содержащий компоненту OLE DB провайдера, и на файлы в этом каталоге.

----------

При попытке добавить базу с локальной станции, 1C предлагает только вариант выбора файлового варианта базы.

Решение:
На появление меню выбора вида создания базы (файловая или на сервере Предприятия) может влиять только ключ. Если ключа нет, то платформа может быть максимум базовой, а базовая не работает с сервером, поэтому этого меню нет. Если же оно есть, но недоступно, то возможно не установлены компоненты доступа к серверу на этой локальной станции.

----------
Проблема:
Выдается ошибка "Не удалось зафиксировать файл базы данных для открытия или изменения .../1cv8.1CD"

Решение:
Фиксация файла базы данных – это разновидность внутренней блокировки, которая требуется, чтобы на некоторое непродолжительное время обеспечить целостность структуры файла при выполнении операций чтения данных или фиксации транзакции. При чтении требуется, чтобы эти структура файла была в целостном состоянии, а при фиксации транзакции структура может изменяться.
При нормальной работе такая ошибка возникать не должна. Суть сводится к следующему: для выполнения фиксация результатов транзакции может потребоваться выполнить перестройку внутренних структур данных файла *.1cd. А для выполнения чтения данных необходимо гарантировать, чтобы такая перестройка структур данных не выполнялась. Для обеспечения согласования этих операций имеется механизм внутренних блокировок, называемых фиксацией. Фиксация выполняется с ожиданием. В то же время предполагается, что фиксация выполняется на непродолжительное время, меньшее, чем время ожидания. Таким образом, если упомянутая ошибка возникла, то имеет место некоторое нарушение нормального хода событий. Мы наблюдали такую ситуацию и уже описывали ее в партнерской конференции. Вкратце все выглядит примерно так. В какой-то момент времени запрос на блокировку участка файла (функция LockFile() Win32 API) выдает ошибку Network error. В результате возникает ошибка движка файловой базы данных "Не удалось зафиксировать файл базы данных для открытия или изменения".
Природа ошибки нам пока непонятна. Известно только, что она возникает далеко не у всех. Не отмечено никакой связи возникновения этой ошибки с версией 1С:Предприятия 8.0 и используемой конфигурацией. По-видимому речь идет о каких-то особенностях некоторых сетей.

Вполне возможно, что проблема возникает из за нестабильности работы сети
Один из способов проверить - выполнить команду:
ping [Имя сервера] -t
на компьютере, с которого запускается 1с
после чего запустить 1с и посмотреть, что будет происходить...
----------

80004027 - приложение 1CV8 или сомпонента v8.server.1 выключена,
если сервер на Windows Server 2003.
См. статью "Особенности настройки Windows Server 2003 при установке сервера 1С:Предприятия 8.0" на диске ИТС.

00000005
00000041
80070005
80080005
80000009
80030005
8001011B - клиент не имеет прав на доступ к серверу (access denied). Выполните
рекомендации статьи "Вопросы установки и настройки 1C:Предприятия 8.0
в варианте "клиент-сервер"" из раздела методической поддержки
1С:Предприятия 8.0 на диске ИТС.

800706BA
800706BE- на сервере произошло неожиданное исключение. Сервер упал.
Нужны записи из Event Log с сервера.

80010108 - внутренняя ошибка клиентского приложения. Нужны записи
Event Log клиентского компьютера и описание действий, выполнявшихся
в это время.

80070776 - Запустить DcomCnfg.exe и проверить протокол для DCOM
Должен быть TCP/IP с ориентацией на подключения

8000401A - В свойствах COM+ приложения 1CV8 на серверном компьютере
на закладке Identity установлен Interactive user, но никакой
пользователь интерактивно не вошел в серверный компьютер.

8001011C - На клиентском компьютере запрещено использование DCOM.
Помогает запустить на клиентском компьютере dcomcnfg.exe
и на закладке Default Properties установить флаг
Enable distributed COM on this computer.

80070721 - Ошибка возникает при рассогласовании протоколов
аутентификации между DCOM клиентом и сервером в том случае, если для связи
между ними используется Microsoft Internet Information Services (IIS).
Возможно, для DCOM используется протокол Tunneling TCP/IP. Установите
на компьютере - сервере 1С:Предприятия и на клиентских компьютерах для
DCOM протокол Connection-oriented TCP/IP.

Источник: mista.ru

Категория: Системные Ошибки