разбора » Поиск

Результаты по ключевому слову: разбора

Функция разбора (разложения) строки в массив, аналог СтрРазделить

Код 1C v 8.х

 Функция РазложитьСтрокуВМассивПодстрок(Знач Строка, Знач Разделитель = ",",

    Знач ПропускатьПустыеСтроки = Неопределено)

 

    Результат = Новый Массив;

 

    // для обеспечения обратной совместимости

    Если ПропускатьПустыеСтроки = Неопределено Тогда

        ПропускатьПустыеСтроки = ?(Разделитель = " ", Истина, Ложь);

        Если ПустаяСтрока(Строка) Тогда 

            Если Разделитель = " " Тогда

                Результат.Добавить("");

            КонецЕсли;

            Возврат Результат;

        КонецЕсли;

    КонецЕсли;

    //

 

    Позиция = Найти(Строка, Разделитель);

    Пока Позиция > 0 Цикл

        Подстрока = Лев(Строка, Позиция - 1);

        Если Не ПропускатьПустыеСтроки Или Не ПустаяСтрока(Подстрока) Тогда

            Результат.Добавить(Подстрока);

        КонецЕсли;

        Строка = Сред(Строка, Позиция + СтрДлина(Разделитель));

        Позиция = Найти(Строка, Разделитель);

    КонецЦикла;

 

    Если Не ПропускатьПустыеСтроки Или Не ПустаяСтрока(Строка) Тогда

        Результат.Добавить(Строка);

    КонецЕсли;

 

    Возврат Результат;

 

КонецФункции

Источник

зы: админ, вот искал аналог СтрРазделить с игнорированием пустых строк - не нашел,зато нашел много дублей: https://helpf.pro/faq/view/504.html https://helpf.pro/faq/view/171.html https://helpf.pro/faq/view/351.html

, объедини пожалуйста.

зыы: кнопкой вставки ссылки невозможно пользоваться, ну что за извращенство с подменю, сделай одинарной как везде.

Категория: Работа с Текстом (Строкой)

Универсальный парсер RSS для 1С

На одном проекте - клиент попросил отображать в программе данные, которые выдаю специализированные сайта в формате RSS - Что делать !?

Писать парсер rss для 1С

Первым делом, взглянув на ссылки, подумал что - обычный XML, сейчас его разложу и быстренько загружу в базу, но:

Выяснилось что сайты имеют разные форматы ввода RSS и главное они не валидные(

таким образом, написав небольшой код, который получает ссылку, далее XMLФайл.Прочитать() на одном сайте проходил на ура (этот пример я описывал в статье: Чтение данных с сайта в формате XML и загрузка в 1С), а вот второй сайт, и третий тоже, при попытке прочитать() выдавали:

{ОбщийМодуль.РегЗадания.Модуль(79)}: Ошибка при вызове метода контекста (Прочитать)

Пока XMLФайл.Прочитать() Цикл

по причине:

Ошибка разбора XML: - [1,1]

Фатальная ошибка:

Extra content at the end of the document

SystemId url rss

решил попробовать на rss других известных сайтов - 80% из проверяемых выдавали ошибку

Пришлось написать прямой построчный парсер RSS:

Структура конфигурации

ИсточникиRSS - URL на RSS, ДанныеRSS - сюда записываются загруженные данные новостей

Код получился таким(в принципе код универсальный, но возможно что-то придется подпилить):

Код 1C v 8.3

 

// RSS

Процедура ПрочитатьRSS(ИсточникRSS)

	url = ИсточникRSS.UrlRSS;

	

	// Получим Сервер

	Если Найти(url,".ru")>0 Тогда urlСервер = Лев(url,Найти(url,".ru")+2);	

	ИначеЕсли Найти(url,".com")>0 Тогда urlСервер = Лев(url,Найти(url,".com")+3);

	ИначеЕсли Найти(url,".org")>0 Тогда urlСервер = Лев(url,Найти(url,".org")+3);

	ИначеЕсли Найти(url,".info")>0 Тогда urlСервер = Лев(url,Найти(url,".info")+4);

	ИначеЕсли Найти(url,".pro")>0 Тогда urlСервер = Лев(url,Найти(url,".pro")+3);

	КонецЕсли;	 		

		

	//Определим тип соединения

	Если Лев(url,5)="https" Тогда

		//ssl = Новый ЗащищенноеСоединениеOpenSSL(Новый СертификатКлиентаWindows(), Новый СертификатыУдостоверяющихЦентровWindows());   

		ssl = Новый ЗащищенноеСоединениеOpenSSL( неопределено, неопределено );

		ТекАдрес = СтрЗаменить(url,urlСервер,""); Сервер = СтрЗаменить(urlСервер,"https://",""); 

		Соединение = Новый HTTPСоединение(Сервер,,,,,

		5, // таймаут в секундах

		ssl // защищенное HTTPS соединение

		);

	Иначе //Обычный HTTP 		

		ТекАдрес = СтрЗаменить(url,urlСервер,""); Сервер = СтрЗаменить(urlСервер,"http://","");

		Соединение = Новый HTTPСоединение(Сервер);

	КонецЕсли;





	Заголовки = Новый Соответствие;

	Заголовки.Вставить("host", Сервер);  

	Запрос = Новый HTTPЗапрос(ТекАдрес, Заголовки);

	Ответ =Соединение.Получить(Запрос);

	Если Ответ.КодСостояния = 200 Тогда // Данные получены, обрабатываем их

		Содержимое= Ответ.ПолучитьТелоКакСтроку();

		//Преобразуем содержимое

		Содержимое = СтрЗаменить(Содержимое,"<br/>","|"); 

		Содержимое = СтрЗаменить(Содержимое,"<![CDATA[",""); Содержимое = СтрЗаменить(Содержимое,"]]>","");  

		Содержимое = СтрЗаменить(Содержимое,Символы.ПС,""); Содержимое = СтрЗаменить(Содержимое,Символы.ВК,""); 

		Содержимое = СтрЗаменить(Содержимое,Символы.ВТаб,""); Содержимое = СтрЗаменить(Содержимое,Символы.Таб,""); 

		Содержимое = СтрЗаменить(Содержимое,"><",">"+Символы.ПС+"<"); 

		

		RegExp = Новый COMОбъект("VBScript.RegExp"); //Регулярка

		RegExp.IgnoreCase = Ложь; 

		RegExp.Global = Истина;    

		RegExp.MultiLine = Истина;   		

		RegExp.Pattern = "<[^>]*>"; //Ищем теги HTML   

		

		//Разберем полученный текст в таблицу

		ЭтоЗапись=Ложь;

		Для н=1 По СтрЧислоСтрок(Содержимое)Цикл

			обрТекст=СтрПолучитьСтроку(Содержимое,н);

			

			Если обрТекст = "<item>" Тогда //Началась запись 

				ЗаписьСтр = Новый Структура(); ЭтоЗапись=Истина; Продолжить;  

			ИначеЕсли обрТекст = "</item>" Тогда //Закончилась запись 

				

				/////////////// ЗАПИСЬ Закончилась //////////////

				/// теперь запишем ее в базу - Справочник ДанныеRSS

				// сначала ПОИСК ДУБЛЕЙ - вдруг уже загружен 				

				Запрос = Новый Запрос;

				Запрос.Текст = 

				"ВЫБРАТЬ

				|	ДанныеRSS.Ссылка

				|ИЗ

				|	Справочник.ДанныеRSS КАК ДанныеRSS

				|ГДЕ

				|	ДанныеRSS.ИсточникRSS =ИсточникRSS

				|	И ДанныеRSS.link ПОДОБНОlink";

				

				Запрос.УстановитьПараметр("link", "%"+ЗаписьСтр.link+"%");

				Запрос.УстановитьПараметр("ИсточникRSS", ИсточникRSS);				

				РезультатЗапроса = Запрос.Выполнить().Выбрать();

				Если РезультатЗапроса.Следующий() Тогда

					// Такая запись уже есть, пока ничего не делаем

				Иначе

					//СОЗДАЕМ Новый

					НовЭлем  = Справочники.ДанныеRSS.СоздатьЭлемент();

					ЗаполнитьЗначенияСвойств(НовЭлем,ЗаписьСтр);

					НовЭлем.ИсточникRSS = ИсточникRSS;

					НовЭлем.Записать(); 					

				КонецЕсли; 				

				/////////////////////// *** /////////////////////

				

				ЭтоЗапись=Ложь; Продолжить; 

			КонецЕсли; //Данные записи

			

			Если ЭтоЗапись Тогда	

				Если Найти(обрТекст,"title>")>0 и Найти(обрТекст,"/title>")>0 Тогда				

					обрТекст = СтрЗаменить(обрТекст,"title",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					ЗаписьСтр.Вставить("Наименование",СокрЛП(обрТекст));

				КонецЕсли;

				

				Если Найти(обрТекст,"link>")>0 и Найти(обрТекст,"/link>")>0 Тогда				

					обрТекст = СтрЗаменить(обрТекст,"link",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					ЗаписьСтр.Вставить("link",СокрЛП(обрТекст));

				КонецЕсли;

				

				Если Найти(обрТекст,"description>")>0 и Найти(обрТекст,"/description>")>0 Тогда			

					обрТекст = СтрЗаменить(обрТекст,"description",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					обрТекст=RegExp.Replace(обрТекст, ""); //Удалим все теги

					ЗаписьСтр.Вставить("desc",СокрЛП(обрТекст));

				КонецЕсли;

				

				Если Найти(обрТекст,"pubDate>")>0 и Найти(обрТекст,"/pubDate>")>0 Тогда			

					обрТекст = СтрЗаменить(обрТекст,"pubDate",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					ЗаписьСтр.Вставить("pubDate",ПреобразоватьRFC822КДате0(СокрЛП(обрТекст)));

				КонецЕсли;

				

				Если Найти(обрТекст,"enclosure")>0 Тогда					 

					обрТекст = СтрЗаменить(обрТекст,"""",""); обрТекст = СтрЗаменить(обрТекст,"<enclosure url=","");

					обрТекст = СтрЗаменить(обрТекст,"<enclosure url=",""); обрТекст = СтрЗаменить(обрТекст,"type=image/png length=/>","");

					ЗаписьСтр.Вставить("img",СокрЛП(обрТекст));

				КонецЕсли;

			КонецЕсли;	

							

		КонецЦикла;

		

	КонецЕсли;

	

КонецПроцедуры	









Процедура ПроверкаRSS() Экспорт

	Запрос = Новый Запрос;

	Запрос.Текст = 

	"ВЫБРАТЬ

	|	ИсточникиRSS.Ссылка КАК Ссылка

	|ИЗ

	|	Справочник.ИсточникиRSS КАК ИсточникиRSS

	|ГДЕ

	|	ИсточникиRSS.Использовать

	|	И ДОБАВИТЬКДАТЕ(ИсточникиRSS.ДатаПоследнегоОбновления, СЕКУНДА, ИсточникиRSS.ПериодОбновленияВСекундах) <ТекДата"; 	

	Запрос.УстановитьПараметр("ТекДата", ТекущаяДата());

	РезультатЗапроса = Запрос.Выполнить();

	ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

	Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

		ПрочитатьRSS(ВыборкаДетальныеЗаписи.Ссылка);

		// Запишем дату последнего обновления

		ТекОб = ВыборкаДетальныеЗаписи.Ссылка.ПолучитьОбъект();

		ТекОб.ДатаПоследнегоОбновления = ТекущаяДата();

		ТекОб.Записать();

	КонецЦикла;

КонецПроцедуры



Функция ПреобразоватьRFC822КДате0(ДатаВФорматеRFC822) Экспорт

    КопияСтроки = ДатаВФорматеRFC822;

    СтруктураДаты = Новый Структура("Год,Месяц,День,Час,Минута,Секунда",  "","","","","","");

    Месяцы = Новый Структура("Jan,Feb,Mar,Apr,May,Jun,Jul,Aug,Sep,Oct,Nov,Dec",  "01","02","03","04","05","06","07","08","09","10","11","12");

    Для каждого КлючИЗначение Из Месяцы Цикл

        Позиция = Найти(КопияСтроки,КлючИЗначение.Ключ);

        Если Позиция > 0  Тогда

             СтруктураДаты.Месяц = КлючИЗначение.Значение;

            Прервать;

        КонецЕсли;

    КонецЦикла; 

	Состояние = 0;

	КопияСтроки = СтрЗаменить(КопияСтроки,", 1 ",", 01 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 2 ",", 02 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 3 ",", 03 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 4 ",", 04 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 5 ",", 05 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 6 ",", 06 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 7 ",", 07 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 8 ",", 08 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 9 ",", 09 ");

	Для ш=0 По СтрДлина(КопияСтроки) Цикл

        ТекущийСимвол = Сред(КопияСтроки,ш,1); //ПолучитьСимвол(КопияСтроки, ш);

        ТекСимволЦифра= ЭтоЦифра(ТекущийСимвол);

        Если ТекСимволЦифра И Состояние = 0  Тогда

            СтруктураДаты.День = СтруктураДаты.День + ТекущийСимвол;

            Состояние = 1; //начало день

        ИначеЕсли ТекСимволЦифра И Состояние = 1  Тогда

            СтруктураДаты.День = СтруктураДаты.День + ТекущийСимвол;

            Состояние = 2; //ждем год

        ИначеЕсли ТекСимволЦифра И Состояние = 2  Тогда

            СтруктураДаты.Год = СтруктураДаты.Год + ТекущийСимвол;

            Состояние = 3; //продолжаем год

        ИначеЕсли ТекСимволЦифра И Состояние = 3  Тогда

            СтруктураДаты.Год = СтруктураДаты.Год + ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = " " И Состояние = 3 Тогда

               Состояние = 4; //дальше час    

        ИначеЕсли ТекСимволЦифра И Состояние = 4  Тогда

            СтруктураДаты.Час = СтруктураДаты.Час + ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = ":" И Состояние = 4  Тогда

            Состояние = 5; //дальше минута

        ИначеЕсли ТекСимволЦифра И Состояние = 5  Тогда

            СтруктураДаты.Минута = СтруктураДаты.Минута +  ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = ":" И Состояние = 5  Тогда

            Состояние = 6; //дальше секунда

        ИначеЕсли ТекСимволЦифра И Состояние = 6  Тогда

            СтруктураДаты.Секунда = СтруктураДаты.Секунда +  ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = " " И Состояние = 6 Тогда

            Прервать;

        КонецЕсли;

    КонецЦикла;

    Попытка

        Результат = Дата(СтруктураДаты.Год+СтруктураДаты.Месяц+СтруктураДаты.День

                        +СтруктураДаты.Час+СтруктураДаты.Минута+СтруктураДаты.Секунда);

    Исключение

        Результат = Неопределено;    

    КонецПопытки;

    Возврат Результат;

КонецФункции



Функция ЭтоЦифра(Символ) Экспорт

     Если (КодСимвола(Символ)>=48) И (КодСимвола(Символ)<=57) Тогда Возврат Истина; Иначе Возврат ложь; КонецЕсли;

КонецФункции



Функция ПолучитьСимвол(КопияСтроки, ш)

	Возврат Сред(КопияСтроки,ш,1);

КонецФункции

Результат загрузки новостей RSS HelpF.pro

Кстати, как позже выяснилось, здесь уже есть статья с примером через IE и DOM: Получения новостей с RSS-канала сайта buh.ru

Категория: Работа с Интернет, Почтой (Mail), FTP

Табличный документ: Колонтитулы и параметры страницы

Большинство обучающих материалов по программированию в системе 1С при описании формирования печатных форм на основе объекта «Табличный документ» ограничиваются выводом готовой формы на экран. Для пользователей же куда более важным является то, как документ будет выглядеть в распечатанном виде. Здесь, кроме хорошо сверстанного макета, играют роль и установки параметров печати.Почти все параметры, доступные в диалогах настройки печати (настройки принтера, свойства страницы), можно указать непосредственно при формировании табличного документа.Рассмотрим свойства и методы табличного документа, относящиеся к настройкам печати (в приведенных примерах «ТабДок» это объект типа «Табличный документ»).

Свойство «ИмяПринтера» позволяет задать для печати принтер, отличный от установленного по умолчанию. Имя должно совпадать с именем принтера, заданным в системе:

ТабДок.ИмяПринтера="HP LaserJet 3050 Series PCL 6";

При печати пакета документов можно сэкономить время, установив признак разбора по копиям:

ТабДок.РазборПоКопиям=истина;

Число копий можно указать так:

ТабДок.КоличествоЭкземпляров=5;

Разумеется, можно задать поля:

ТабДок.ПолеСлева=20;//Поле слева 20мм, остальные поля 10мм (по умолчанию)

Еще несколько свойств страницы:

ТабДок.ОриентацияСтраницы=ОриентацияСтраницы.Ландшафт; ТабДок.ЭкземпляровНаСтранице=2; //на листе будет размещено 2 страницы ТабДок.Автомасштаб=истина; //аналогично настройкам масштаба «по ширине страницы»

При необходимости можно указать конкретное значение масштабирования в процентах (свойство «МасштабПечати»).

Свойство «РазмерСтраницы» позволяет задать стандартные форматы страницы – “A3”, “A4”, “A5” (полный список вариантов доступен в справке 1С).

ТабДок.РазмерСтраницы="A3";// буква А должна быть английской

Для нестандартного размера бумаги (Custom) можно указать значения высоты и ширины страницы (в мм):

ТабДок.РазмерСтраницы="Custom";//нестандартный размер ТабДок.ВысотаСтраницы=350; ТабДок.ШиринаСтраницы=350;

Также в табличном документе доступно управление выводом колонтитулов и их содержимым. Для этого служат свойства «ВерхнийКолонтитул» и «НижнийКолонтитул». Например:

ТабДок.ВерхнийКолонтитул.Выводить=истина; //будет напечатан верхний колонтитул ТабДок.РазмерКолонтитулаСверху=7; //размер колонтитула 7мм (по умолчанию 10мм) ТабДок.ВерхнийКолонтитул.ВертикальноеПоложение=ВертикальноеПоложение.Верх; ТабДок.ВерхнийКолонтитул.НачальнаяСтраница=2;//колонтитул выводится со второй страницы ШрифтКолонтитула=Новый Шрифт("Courier New", 8,,Истина); ТабДок.ВерхнийКолонтитул.Шрифт=ШрифтКолонтитула; //наклонный шрифт ТабДок.ВерхнийКолонтитул.ТекстВЦентре="Верхний колонтитул"; ТабДок.ВерхнийКолонтитул.ТекстСправа="Стр.[&НомерСтраницы] из [&СтраницВсего]"; //нумерация страниц ТабДок.ВерхнийКолонтитул.ТекстСлева="[&Дата]";//текущая дата

Сформированный документ отправляется на печать с помощью метода «Напечатать()». Возможно два варианта вызова.

1) Непосредственно на принтер:ТабДок.Напечатать(РежимИспользованияДиалогаПечати.НеИспользовать); ТабДок.Напечатать(истина);

2) Перед печатью будет выведен диалог печати:ТабДок.Напечатать(РежимИспользованияДиалогаПечати.Использовать); ТабДок.Напечатать(ложь);

Кроме того можно управлять и разбиением документа на страницы. Оценить количество страниц в документе по настройкам текущего принтера можно так:

ТабДок.КоличествоСтраниц();

С помощью методов «ПроверитьВывод()» и «ПроверитьПрисоединение()» можно определить, умещается ли табличный документ или массив областей табличного документа на странице в высоту и в ширину при текущих настройках принтера.Надо иметь ввиду, что работа последних трех методов зависит от установленного принтера. Если методу не удается его найти, вызывается исключение.

Принудительно вставить разрывы страниц позволяют методы «ВывестиВертикальныйРазделительСтраниц()» и «ВывестиГоризонтальныйРазделительСтраниц()».Таким образом, можно управлять постраничным выводом на печать и контролировать заполнение страницы:

Если Не ТабДок.ПроверитьВывод(МассивВыводимыхОбластей) Тогда ТабДок.ВывестиГоризонтальныйРазделительСтраниц();КонецЕсли;

Категория: Табличный документ

Сравнение: Конкатенация, ТекстовыйДокумент, ЗаписьXML

Немного теории:
Конкатенация (соединение строк). Казалось бы - ну что может быть проще и однозначнее? Ан нет. Выражение T = "А"+"Б"; (если оно не вычислено на этапе компиляции/разбора) требует выделения памяти для "А", памяти для "Б", анализа длин "А" и "Б", выделение памяти для T, копирование первой строки, копирование второй строки. Это медленно, особенно если в цикле дописывается кусочек в конец строки.
В "нормальных" системах, например в .NET от этого можно уйти используя так называемые StringBuilder - это специальный объект, который более эффективно выделяет память (крупными блоками) и не копирует зря строки. По сути это поток (stream) который используется для записи в память, как в файл. А вот в 1С такого нет. Фиг вам товарищи, а не эффективная работа со строками

Но фиг только тем у кого хитрости мало, а для остальных есть варианты.
ТекстовыйДокумент
Оказывается, что метод ДобавитьСтроку() для типа ТекстовыйДокумент для больших строк работает гораздо эффективнее чем тупая конкатенация. Возможно, это связано с тем, что этот тип - обёртка к текстовому редактору, встроенному в 1С. Кстати, этот редактор для простых текстовых файлов файлов мне нравится гораздо больше, чем например, notepad или редактор Visual Studio - он позволяет бодрее работать с большими текстами, как в длину, так и в ширину.
Но! У этого способа есть недостаток - в 8.0 и 8.1 он не доступен на сервере, т.к. считается "интерфейсным". Обидно. Но это заставляет искать нас более эффективный способ:
ЗаписьXML
Опа! А при чём здесь XML? Правильно, XML нам не нужен. Но важно, что тип ЗаписьXML представляет собой как раз обёртку над последовательной записью в поток. А если учесть, что он позволяет формировать результат в память в виде строки, а не только в файл, то это уже готовый кандидат на замену StringBuilder. Осталось только упомянуть, что он позволяет дозаписывать в "XML" всё что угодно при помощи метода ЗаписатьБезОбработки().

Код 1C v 8.2 УП

 ДлинаДобавляемогоКуска = 200; //символов, последний - ПС

ОбщаяДлинаСтроки = 1000000;

КоличествоИтераций = 10;



//Создаём базовую строчку:

БазоваяСтрока = "";

Для Сч = 1 по ДлинаДобавляемогоКуска-1 Цикл

    БазоваяСтрока = БазоваяСтрока + "Ы";

КонецЦикла;

БазоваяСтрокаПС = БазоваяСтрока + Символы.ПС;



//Способ 1. Добавление строк к концу строки

Сообщить("Способ 1. Добавление строк к концу строки - Начало " + Строка(ТекущаяДата()));

ФиктивныйРезультат = 0;

Для СчИтераций = 1 по КоличествоИтераций Цикл

    Состояние("Способ 1. Добавление строк к концу строки - " + Строка(СчИтераций));

    СтрокаРезультат = "";

    Для СчДобавлений = 1 по (ОбщаяДлинаСтроки/ДлинаДобавляемогоКуска) Цикл

        СтрокаРезультат = СтрокаРезультат + БазоваяСтрокаПС;

    КонецЦикла;

    ФиктивныйРезультат = ФиктивныйРезультат + СтрДлина(СтрокаРезультат);

    ОбработкаПрерыванияПользователя();

КонецЦикла;

Сообщить("Фиктивный результат = " + Строка(ФиктивныйРезультат));

Сообщить("Способ 1. Добавление строк к концу строки - Окончание " + Строка(ТекущаяДата()));



//Способ 2. Добавление строк в текстовый документ

Сообщить("Способ 2. Добавление строк в текстовый документ - Начало " + Строка(ТекущаяДата()));

ФиктивныйРезультат = 0;

Для СчИтераций = 1 по КоличествоИтераций Цикл

    Состояние("Способ 2. Добавление строк в текстовый документ - " + Строка(СчИтераций));

    ТекстПостроитель = Новый ТекстовыйДокумент;

    Для СчДобавлений = 1 по (ОбщаяДлинаСтроки/ДлинаДобавляемогоКуска) Цикл

        ТекстПостроитель.ДобавитьСтроку(БазоваяСтрока); //ПС добавляется сам

    КонецЦикла;

    СтрокаРезультат = ТекстПостроитель.ПолучитьТекст();

    ФиктивныйРезультат = ФиктивныйРезультат + СтрДлина(СтрокаРезультат);

    ОбработкаПрерыванияПользователя();

КонецЦикла;

Сообщить("Фиктивный результат = " + Строка(ФиктивныйРезультат));

Сообщить("Способ 2. Добавление строк в текстовый документ - Окончание " + Строка(ТекущаяДата()));



//Способ 3. Создание через ЗаписьXML

Сообщить("Способ 3. Создание через ЗаписьXML - Начало " + Строка(ТекущаяДата()));

ФиктивныйРезультат = 0;

Для СчИтераций = 1 по КоличествоИтераций Цикл

    Состояние("Способ 3. Создание через ЗаписьXML - " + Строка(СчИтераций));

    ТекстПостроитель = Новый ЗаписьXML;

    ТекстПостроитель.УстановитьСтроку();

    Для СчДобавлений = 1 по (ОбщаяДлинаСтроки/ДлинаДобавляемогоКуска) Цикл

        ТекстПостроитель.ЗаписатьБезОбработки(БазоваяСтрокаПС);

    КонецЦикла;

    СтрокаРезультат = ТекстПостроитель.Закрыть();

    ФиктивныйРезультат = ФиктивныйРезультат + СтрДлина(СтрокаРезультат);

    ОбработкаПрерыванияПользователя();

КонецЦикла;

Сообщить("Фиктивный результат = " + Строка(ФиктивныйРезультат));

Сообщить("Способ 3. Создание через ЗаписьXML - Окончание " + Строка(ТекущаяДата()));

//ЗЫ: данный код проверен в 8.2

Результаты забегов
У меня на тестовой среде получилось примерно следующее время:
1. Конкатенация - 24 секунды
2. Текстовый документ 1,5 секунды
3. ЗаписьXML - около 0,4 секунды

Пишет Alexander Speshilov

Категория: Работа с Текстом (Строкой)

Обход метаданных (полезные функции)

При написании небольших автоматизированных тестов часто надо обойти всю конфигурацию и проверить, например, для всех форм какое-нибудь свойство. Это всё легко делается через свойство глобального контекста "Метаданные", но чтоб дорбаться до обхода реквизитов надо написать кучу вложенных циклов. При этом код становится слабочитаемым и слабомодифицируемым.

Ниже приведен небольшой модуль, который решает задачу легко и удобно. Создана специальная функция РазвернутьСтрокуОбходаМетаданных, которая может по строке типа "Метаданные.Справочники.*.Реквизиты.*" построить массив строк с перечислением всех реквизитов всех справочников. При помощи этой и нескольких других функций в экспортных функциях модуля реализованы вполне прикладные задачи - получение всех реквизитов, всех макетов, всех форм конфигурации и построение таблицы всех составных типов.

Код 1C v 8.х

  // Автор: Alexander Speshilov

// Рекрсивная функция, которая разворачивает строку вида "Метаданные.Справочники.*[Имя].Реквизиты.*.Тип" 

// в массив строк, заменяя "*" или другой символ, задаваемый параметрами обходом всех элементов 

// коллекции. Допускает выполнение функций встроенного языка (не стоит отдавать ввод параметров 

// пользователям). При этом выражение, используемое для получения по умолчанию может быть задано в 

// квадратных скобках или параметром функции.

//

// Параметры

//  СтрокаОбхода  - Строка - Разворачиваемая строка

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Массив строк

//

Функция РазвернутьСтрокуОбходаМетаданных(СтрокаОбхода, ЗаменяемоеЗначение = "*", ПредставлениеПоУмолчанию = "")

    

    Рез = Новый Массив;

    

    ЧастиСтрокиОбхода = РазобратьСтрокуОбхода(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

    Если ЧастиСтрокиОбхода = Неопределено тогда 

        Рез.Добавить(СтрокаОбхода); //фактически это ограничение рекурсии.

    Иначе

        ОбъектКоллекции = Вычислить(ЧастиСтрокиОбхода.СтрокаКоллекции);

        РазвернутаяКоллекция = РазвернутьКоллекциюВПредставления(ОбъектКоллекции, ЧастиСтрокиОбхода.СтрокаПредставление);

        Для каждого ЭлементРазвернутойКоллекции Из РазвернутаяКоллекция Цикл

            

            // рекурсивный вызов

            ТекущаяСтрокаОбхода = ЧастиСтрокиОбхода.СтрокаНачало + ЭлементРазвернутойКоллекции + ЧастиСтрокиОбхода.СтрокаКонец;

            МассивЭлемента = РазвернутьСтрокуОбходаМетаданных(ТекущаяСтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

            

            Для каждого ПримитивныйЭлементОбхода Из МассивЭлемента Цикл

                Рез.Добавить(ПримитивныйЭлементОбхода);

            КонецЦикла;

            

        КонецЦикла;

    КонецЕсли;

    

    Возврат Рез;

    

КонецФункции // РазвернутьСтрокуОбходаМетаданных()



// Разбирает строку обхода на удобные для работы поля

//

// Параметры

//  СтрокаОбхода  - Строка - Разворачиваемая строка

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Структура с полями ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец

// или Неопределено (если строка не содержит ЗаменяемоеЗначение)

//

Функция РазобратьСтрокуОбхода(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию)

    

    Если ПустаяСтрока(ЗаменяемоеЗначение) Тогда 

        ВызватьИсключение "Некорректное выражение заменяемого значения";

    КонецЕсли;

    

    ПозицияЗамены = Найти(СтрокаОбхода, ЗаменяемоеЗначение);

    

    // Если не найдена строка - возвращаем неопределено, как индикатор

    Если ПозицияЗамены = 0 Тогда 

        Возврат Неопределено; 

    КонецЕсли;

    

    СтрокаНачало = Лев(СтрокаОбхода,ПозицияЗамены - 1);

    

    //Получение строки для выражения-коллекции

    СтрокаКоллекции = СтрокаНачало;

    Если Прав(СтрокаКоллекции, 1) = "." Тогда 

        СтрокаКоллекции = Лев(СтрокаКоллекции,СтрДлина(СтрокаКоллекции) - 1);

    КонецЕсли;

    

    ПозицияОкончанияЗамены = ПозицияЗамены + СтрДлина(ЗаменяемоеЗначение);

    

    ОстатокВыражения = Сред(СтрокаОбхода, ПозицияОкончанияЗамены);

    

    //Обработка явного задания представления

    ОткрывающаяСкобка = "[";

    ЗакрывающаяСкобка = "]";

    Если Найти(ОстатокВыражения, ОткрывающаяСкобка) = 1 Тогда

        ОстатокВыражения = Сред(ОстатокВыражения, СтрДлина(ОткрывающаяСкобка) + 1);

        ПозицияЗакрывающейСкобки = Найти(ОстатокВыражения, ЗакрывающаяСкобка);

        Если ПозицияЗакрывающейСкобки = 0 Тогда 

            ВызватьИсключение "Синтаксическая ошибка разбора выражения";

        КонецЕсли;

        СтрокаПредставление = Лев(ОстатокВыражения, ПозицияЗакрывающейСкобки - 1);

        ОстатокВыражения = Сред(ОстатокВыражения, ПозицияЗакрывающейСкобки + СтрДлина(ЗакрывающаяСкобка));

    Иначе

        СтрокаПредставление = ПредставлениеПоУмолчанию;

    КонецЕсли;

    СтрокаКонец = ОстатокВыражения;

    

    Рез = Новый Структура("ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец",

    ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец);

    

    Возврат Рез;

    

КонецФункции // РазобратьСтрокуОбхода()



// Разворачивает объект коллекции в массив представления элементов

//

// Параметры

//  Коллекция  - Произвольный - Коллекция, которую можно обойти через "Для каждого"

//  ПредставлениеЭлемента  - Строка - необяз., свойство элементов коллекции, которое 

//               используется для получения представления.

//

// Возвращаемое значение:

//   Массив   - Массив представлений коллекции

//

Функция РазвернутьКоллекциюВПредставления(Коллекция, Знач ПредставлениеЭлемента = "")

    

    //Проверка и подгонка параметров

    Если не ПустаяСтрока(ПредставлениеЭлемента) Тогда 

        Если Найти(ПредставлениеЭлемента, ";")>0 Тогда 

            ВызватьИсключение "Некорректное выражение представления";

        КонецЕсли;

        ПредставлениеЭлемента = "." + ПредставлениеЭлемента;

    КонецЕсли;

    

    Рез = Новый Массив;

    Для каждого ЭлементКоллекции Из Коллекция Цикл

        ТекПредставление = Строка(Вычислить("ЭлементКоллекции" + ПредставлениеЭлемента));

        Рез.Добавить(ТекПредставление);

    КонецЦикла; 

    Возврат Рез;

    

КонецФункции // РазвернутьКоллекцию()



// Разворачивает массив строк через РазвернутьСтрокуОбходаМетаданных

//

// Параметры

//  МассивСтрокОбхода  - Массив - Массив разворачиваемых строк

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Массив строк

//

Функция РазвернутьМассивСтрокОбходаМетаданных(МассивСтрокОбхода, ЗаменяемоеЗначение = "*", ПредставлениеПоУмолчанию = "Имя")

    

    Рез = Новый Массив;

    

    Для каждого СтрокаОбхода Из МассивСтрокОбхода Цикл

        

        ДополнениеРезультата = РазвернутьСтрокуОбходаМетаданных(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

        Для каждого ТекСтрока Из ДополнениеРезультата Цикл

            Рез.Добавить(ТекСтрока);

        КонецЦикла; 

        

    КонецЦикла; 

    

    Возврат Рез;

    

КонецФункции // РазвернутьМассивСтрокОбходаМетаданных()



// Преобразует строку в массив одиночных строк по разделителю Символы.ПС

//

// Параметры

//  ПреобразуемаяСтрока - строка для преобразования

//    ИгнорироватьПустые - Булево - Пропускать пустые строки

//  СокращатьПробелы - Использовать СокрЛП

//

// Возвращаемое значение:

//   Массив строк

//

Функция ПолучитьМассивСтрокМногострочнойСтроки(ПреобразуемаяСтрока, ИгнорироватьПустые = Истина, СокращатьПробелы = Истина)

    

    Рез = Новый Массив;

    ЧислоСтрок = СтрЧислоСтрок(ПреобразуемаяСтрока);

    

    Для Сч = 1 По ЧислоСтрок Цикл

        

        ТекСтрока = СтрПолучитьСтроку(ПреобразуемаяСтрока, Сч);

        Если ИгнорироватьПустые и ПустаяСтрока(ТекСтрока) Тогда

            Продолжить;

        КонецЕсли; 

        Если СокращатьПробелы Тогда

            ТекСтрока = СокрЛП(ТекСтрока);

        КонецЕсли; 

        Рез.Добавить(ТекСтрока);

        

    КонецЦикла;

    

    Возврат Рез;

    

КонецФункции // ПолучитьМассивСтрокМногострочнойСтроки()



// Возвращает все реквизиты конфигурации, которые сохраняются в ИБ

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеХранимыеРеквизитыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.Константы.*

    |Метаданные.ПланыОбмена.*.Реквизиты.*

    |Метаданные.ПланыОбмена.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Справочники.*.Реквизиты.*

    |Метаданные.Справочники.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Документы.*.Реквизиты.*

    |Метаданные.Документы.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Последовательности.*.Измерения.*

    |Метаданные.ПланыВидовХарактеристик.*.Реквизиты.*

    |Метаданные.ПланыВидовХарактеристик.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.ПланыСчетов.*.Реквизиты.*

    |Метаданные.ПланыСчетов.*.ПризнакиУчета.*

    |Метаданные.ПланыСчетов.*.ПризнакиУчетаСубконто.*

    |Метаданные.ПланыСчетов.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.ПланыВидовРасчета.*.Реквизиты.*

    |Метаданные.ПланыВидовРасчета.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.РегистрыСведений.*.Измерения.*

    |Метаданные.РегистрыСведений.*.Ресурсы.*

    |Метаданные.РегистрыСведений.*.Реквизиты.*

    |Метаданные.РегистрыНакопления.*.Измерения.*

    |Метаданные.РегистрыНакопления.*.Ресурсы.*

    |Метаданные.РегистрыНакопления.*.Реквизиты.*

    |Метаданные.РегистрыБухгалтерии.*.Измерения.*

    |Метаданные.РегистрыБухгалтерии.*.Ресурсы.*

    |Метаданные.РегистрыБухгалтерии.*.Реквизиты.*

    |Метаданные.РегистрыРасчета.*.Измерения.*

    |Метаданные.РегистрыРасчета.*.Ресурсы.*

    |Метаданные.РегистрыРасчета.*.Реквизиты.*

    |Метаданные.БизнесПроцессы.*.Реквизиты.*

    |Метаданные.БизнесПроцессы.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Задачи.*.Реквизиты.*

    |Метаданные.Задачи.*.РеквизитыАдресации.*

    |Метаданные.Задачи.*.ТабличныеЧасти.*.Реквизиты.*

    |";

    ВсеХранимыеРеквизитыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеХранимыеРеквизитыКонфигурации;

    

КонецФункции // ПолучитьВсеХранимыеРеквизитыКонфигурации()



// Возвращает все реквизиты конфигурации составного типа, которые сохраняются в ИБ

//

// Параметры - Нет

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция ПолучитьВсеХранимыеРеквизитыКонфигурацииСоставногоТипа() Экспорт

    

    ВсеХранимыеРеквизитыКонфигурации = ПолучитьВсеХранимыеРеквизитыКонфигурации();

    Рез = Новый ТаблицаЗначений;

    Рез.Колонки.Добавить("Имя", Новый ОписаниеТипов("Строка"));

    Рез.Колонки.Добавить("Тип", Новый ОписаниеТипов("ОписаниеТипов"));

    Рез.Колонки.Добавить("КоличествоПростыхТипов", Новый ОписаниеТипов("Число"));

    

    Для каждого ТекРеквизит Из ВсеХранимыеРеквизитыКонфигурации Цикл

        

        Реквизит = Вычислить(ТекРеквизит);

        Тип = Реквизит.Тип;

        КоличествоПростыхТипов = Тип.Типы().Количество();

        Если КоличествоПростыхТипов<>1 Тогда 

    	    ТекСтрока = Рез.Добавить();

            ТекСтрока.Имя = ТекРеквизит;

            ТекСтрока.Тип = Тип;

            ТекСтрока.КоличествоПростыхТипов = КоличествоПростыхТипов;

        КонецЕсли;

    

    КонецЦикла; 

    

    Возврат Рез;

    

КонецФункции // ПолучитьВсеХранимыеРеквизитыКонфигурации()



// Возвращает все формы конфигурации

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеФормыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.ПланыОбмена.*.Формы.*

    |Метаданные.КритерииОтбора.*.Формы.*

    |Метаданные.ОбщиеФормы.*

    |Метаданные.Справочники.*.Формы.*

    |Метаданные.Документы.*.Формы.*

    |Метаданные.ЖурналыДокументов.*.Формы.*

    |Метаданные.Перечисления.*.Формы.*

    |Метаданные.Отчеты.*.Формы.*

    |Метаданные.Обработки.*.Формы.*

    |Метаданные.ПланыВидовХарактеристик.*.Формы.*

    |Метаданные.ПланыСчетов.*.Формы.*

    |Метаданные.ПланыВидовРасчета.*.Формы.*

    |Метаданные.РегистрыСведений.*.Формы.*

    |Метаданные.РегистрыНакопления.*.Формы.*

    |Метаданные.РегистрыБухгалтерии.*.Формы.*

    |Метаданные.РегистрыРасчета.*.Формы.*

    |Метаданные.БизнесПроцессы.*.Формы.*

    |Метаданные.Задачи.*.Формы.*

    |";

    ВсеФормыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеФормыКонфигурации;

    

КонецФункции // ПолучитьВсеФормыКонфигурации()



// Возвращает все макеты конфигурации

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеМакетыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.ПланыОбмена.*.Макеты.*

    |Метаданные.ОбщиеМакеты.*

    |Метаданные.Справочники.*.Макеты.*

    |Метаданные.Документы.*.Макеты.*

    |Метаданные.ЖурналыДокументов.*.Макеты.*

    |Метаданные.Перечисления.*.Макеты.*

    |Метаданные.Отчеты.*.Макеты.*

    |Метаданные.Обработки.*.Макеты.*

    |Метаданные.ПланыВидовХарактеристик.*.Макеты.*

    |Метаданные.ПланыСчетов.*.Макеты.*

    |Метаданные.ПланыВидовРасчета.*.Макеты.*

    |Метаданные.РегистрыСведений.*.Макеты.*

    |Метаданные.РегистрыНакопления.*.Макеты.*

    |Метаданные.РегистрыБухгалтерии.*.Макеты.*

    |Метаданные.РегистрыРасчета.*.Макеты.*

    |Метаданные.БизнесПроцессы.*.Макеты.*

    |Метаданные.Задачи.*.Макеты.*

    |";

    ВсеМакетыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеМакетыКонфигурации;

    

КонецФункции // ПолучитьВсеМакетыКонфигурации()

Категория: Метаданные

Импорт в 1С из текстовых файлов (TXT, CSV)

Не редко возникает необходимость загрузить в справочники или документы 1С данные из текстового файла. Приведенный пример внешней обработки позволит преобразовать текстовый файл с известным разделителем данных в поле табличного документа для последующей обработки уже внутри 1С:Предприятия. Обработка содержит функцию разбора строки на массив данных, настраиваемый разделитель строки текста на "столбцы", процедуру чтения данных из текстового файла.

Разбор строки в массив с использованием функций из конфигурации 1С
Для разложения строки в массив в конфигурация 1С:Бухгалтерия, 1С:Торговля и 1С:УПП имеется замечательная функция - Функция РазложитьСтрокуВМассивПодстрок(Знач Стр, Разделитель = ",") Экспорт. Функция "расщепляет" строку на подстроки, используя заданный разделитель. Разделитель может иметь любую длину. Если в качестве разделителя задан пробел, рядом стоящие пробелы считаются одним разделителем, а ведущие и хвостовые пробелы параметра "Стр" игнорируются. Подробнее можно прочесть внутри конфигурации - "Общие модули" -> "Общего назначения". Функция возвращает массив значений, элементы которого - подстроки.

Чтение текстового файла (txt) в 1С
Операцию импорта - экспорта текстовых файлов (формат тхт или csv, а также htm, html) очень удобно реализовать при помощи конструкции следующего вида:

1. Функция ПолучитьПотокЧтенияСтрок(Файл) - Назначение: Проверить наличие файла (функция Файл()), Создать текстовый документ (Новый ТекстовыйДокумент()), вызвать метод "Прочитать" для открытия потока чтения файла. Возвращает поток, готовый для чтения.
2. Процедура ЧтениеТХТФайла(Элемент) - Назначение: В цикле произвести последовательное чтение строк файла текстового документа, разбирая на массив колонок данных и добавляя значения массива в табличное поле;

Исходный код 1С функции создания текстового потока чтения файла ТХТ:

Код 1C v 8.х

 Функция ПолучитьПотокЧтенияСтрок(Файл)

  Попытка

    // Используется для доступа к параметрам файлов или каталогов. 

    ТекстовыйФайл = Новый Файл(Файл);

    Если ТекстовыйФайл.Существует() = Ложь Тогда

      Сообщить("Файла "+Файл+" не существует!");

      Возврат Неопределено;

    КонецЕсли;



    // Текстовый документ предназначен для работы с текстами. 

    // Объект позволяет получать и сохранять текст в файле, 

    // работать со строками

    ПотокЧтенияСтрок = Новый ТекстовыйДокумент();

    ПотокЧтенияСтрок.Прочитать(ТекстовыйФайл);

  Исключение

    Сообщить("Файл не прочитан.", СтатусСообщения.Внимание);

    Сообщить(ОписаниеОшибки());

    Возврат Неопределено;

  КонецПопытки;



  // Возвращает текст, извлеченный из файла

  Возврат ПотокЧтенияСтрок;



КонецФункции // ПолучитьПотокЧтенияСтрок





// Исходный код функции загрузки строк в табличное поле:



Процедура ЧтениеТХТФайла(Элемент)



  // Проверка на наличие имени файла

  Если ПустаяСтрока(ИмяФайла) Тогда

    Предупреждение("Для запуска обработки необходимо предварительно выбрать файл данных.");

    Возврат;

  КонецЕсли;



  // Открыть файл, создать текстовый документ, прочитать

  ПотокСтрок = ПолучитьПотокЧтенияСтрок(ИмяФайла);



  // Очистить предыдущие значения

  ТаблицаДокумента.Очистить();

  ТаблицаДокумента.Колонки.Очистить();



  // Создать колонки табличного документа

  ТаблицаДокумента.Колонки.Добавить("Номер",,"Номер",5);

  ТаблицаДокумента.Колонки.Добавить("Артикул",,"Артикул",11);

  ТаблицаДокумента.Колонки.Добавить("Номенклатура",,"Номенклатура",25);

  ТаблицаДокумента.Колонки.Добавить("Цена",,"Цена",6);



  // Последовательное чтение строк текстового файла

  КоличествоСтрок = ПотокСтрок.КоличествоСтрок();

  Для Строка = 1 По КоличествоСтрок Цикл



    // Обработка нажатия Ctrl + Break

    ОбработкаПрерыванияПользователя();



    // Чтение строки из файла тхт / csv

    СтрокаИзФайла = ПотокСтрок.ПолучитьСтроку(Строка);



    // Разбор строки в массив, используя в качествен символа-разделителя "|"

    МассивСтрок = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(СтрокаИзФайла,"|");



    // Добавить данные в табличную часть экранной формы

    Стр=ТаблицаДокумента.Добавить();

    Стр.Номер	 = Строка;

    Стр.Артикул = МассивСтрок[0];

    Стр.Номенклатура = МассивСтрок[1];

    Стр.Цена = МассивСтрок[2];

    // Отобразить информацию о ходе выполнения обработки

    Состояние("Обработка строки файла : "

      + "строка " + Строка + " из " + КоличествоСтрок);



  КонецЦикла;



  // Отобразить результаты загрузки в форме элемента

  ЭлементыФормы.ТаблицаДокумента.Значение = ТаблицаДокумента;

  ЭлементыФормы.ТаблицаДокумента.СоздатьКолонки();



КонецПроцедуры // ЧтениеTXTФайла(Элемент)

В данном примере была произведена загрузка из текстового файла в следующем формате:

Код

7754|Процессор Atom 1.7|10,00
5054|Процессор AMD x64|8,99
7546|Мышь Microsoft|45,88

Категория: JSON, XML, TXT, CSV, DBF

Выгрузка табличного документа в Google таблицу

Надумал когда-то задачу себе: выгрузить содержимое табличного документа в Google Document. Одним из вариантов использования данного функционала может быть выгрузка состояния заказов пользователей из базы в 1с в google spreadsheet. Если клиент знает адрес данного документа, то они могут ознакомиться с состоянием дел не звоня менеджеру. Может кто еще придумает варианты использования – пишите в комментарии, буду рад.
Последовательность выгрузки документа такова: сначала получаем список таблиц, которые есть у пользователя в системе Google Document. Затем после определения таблицы выгрузки пользователю предлагаем выбрать лист, в который будет выгружаться содержимое. Во время выбора всех этих параметров так же предоставляется возможность создания новых элементов (таблиц, листов). Уже после определения листа выгрузки обходим все ячейки документа и их содержимое переносим в таблицу на соответствующее место. Вопрос сохранения форматирования табличного документа в данной задаче не рассматривался.

Для написания функционала использовалась информация про google document API. Для того чтобы получить доступ к данным необходимо чтобы 1с сначала прошла аутентификацию. Про аутентификацию приложений можно почитать в соответствующем документе. Для того чтобы пройти аутентификацию мы должны сначала получить маркер, затем этот маркер прописывать каждый раз при обращении к серверу.

Функция получения маркера следующая:

Код 1C v 8.х

 Функция ПолучитьМаркер(ВидСервиса,Пользователь = Неопределено) Экспорт

    ПараметрыПользователя = ПолучитьПараметрыПользователя();



    Если ПараметрыПользователя = Неопределено Тогда

        Возврат Неопределено;

    КонецЕсли;



    АдресКлиентЛогин = "https://www.google.com/accounts/ClientLogin";

    Если ВидСервиса = "Таблица" Тогда

        Сервис = "wise";

    ИначеЕсли ВидСервиса = "Документ" Тогда

        Сервис = "writely";

    КонецЕсли;



    Попытка

        ХМЛХТТП = ПолучитьCOMОбъект("", "Microsoft.XMLHTTP");

        ХМЛХТТП.Open("POST", АдресКлиентЛогин, Ложь);

        ХМЛХТТП.SetRequestHeader("Content-Type", "application/x-www-form-urlencoded");

        ХМЛХТТП.Send("Email=" + ПараметрыПользователя.Логин + "&Passwd=" + ПараметрыПользователя.Пароль + "&service=" + Сервис + "&source=Gulp-CalGulp-1.05");

    Исключение

        Сообщить("Ошибка:" + ОписаниеОшибки());

        Возврат Неопределено;

    КонецПопытки;



    Если ХМЛХТТП.Status = 200 Тогда

        Маркер = ХМЛХТТП.ResponseText;

        Маркер = Прав(Маркер, СтрДлина(Маркер) - СтрДлина("Auth=") - Найти(Маркер, "Auth=") + 1);

        Возврат Маркер;

    Иначе

        Сообщить("Ошибка:" +  ХМЛХТТП.Status + "-" + ХМЛХТТП.ResponseText);

        Возврат Неопределено;

    КонецЕсли;

КонецФункции

Функция получения маркера в качестве входного параметра получает вид службы, для которой будет проходить аутентификация. Это очень важный момент. Например, полученный маркер для Календаря не даст возможности работать с документами.

Для получения списка таблиц отправляется GET запрос по адресу «https://spreadsheets.google.com/feeds/spreadsheets/private/full». В запросе параметр «Authorization» определяется значением полученного маркера аутентификации. В результате выполнения запроса в ResponseText мы получаем xml, который для удобство дальнейшего разбора перегоняется в ДеревоЗначений.Функция получения списка таблиц имеет следующий вид:

Код 1C v 8.х

 &НаСервере

Функция ПолучитьСписокТаблиц(Пользователь = Неопределено) Экспорт



    ПараметрыПользователя = ПолучитьПараметрыПользователя();

    Если ПараметрыПользователя = Неопределено Тогда

        Возврат Ложь;

    КонецЕсли;



    Маркер = ПолучитьМаркер("Таблица");

    Если Маркер = Неопределено Тогда

        Возврат Ложь;

    КонецЕсли;



    Адрес = "https://spreadsheets.google.com/feeds/spreadsheets/private/full";

    ХМЛХТТП = ПолучитьCOMОбъект("", "Microsoft.XMLHTTP");

    ХМЛХТТП.Open("GET", Адрес, Ложь);

    ХМЛХТТП.SetRequestHeader("Content-Type", "application/atom+xml");

    ХМЛХТТП.SetRequestHeader("Authorization", "GoogleLogin auth=" +Маркер);

    ХМЛХТТП.Send(Null);



    Если ХМЛХТТП.Status = 200 Тогда

        ОтветСервера = ХМЛХТТП.ResponseText;

        ДеревоXML = ПрочитатьResponseTextXML(ОтветСервера);

        СписокТаблиц = Новый СписокЗначений;

        ТаблицаСсылка = "";

        НазваниеТаблицы = "";



        Для Каждого Строка Из ДеревоXML.Строки[0].Строки Цикл

            Если Строка.ИмяXMLЭлементаДанных = "entry" Тогда

                Для Каждого ТекАтрибут Из Строка.Строки Цикл

                    Если ТекАтрибут.ИмяXMLЭлементаДанных = "link" Тогда

                        ТекРел = ТекАтрибут.СписокАтрибутов.НайтиПоЗначению("rel");

                        Если ТекРел.представление = "http://schemas.google.com/spreadsheets/2006#worksheetsfeed" Тогда

                            ТекСсылка = ТекАтрибут.СписокАтрибутов.НайтиПоЗначению("href");

                            ТаблицаСсылка = ТекСсылка.Представление;

                            ТаблицаСсылка = СтрЗаменить(ТаблицаСсылка,"https://","http://");

                        КонецЕсли;

                    КонецЕсли;



                    Если ТекАтрибут.ИмяXMLЭлементаДанных = "title" Тогда

                        НазваниеТаблицы = ТекАтрибут.ЗначениеXMLЭлементаДанных;

                    КонецЕсли;

                КонецЦикла;

                Если ЗначениеЗаполнено(ТаблицаСсылка) И ЗначениеЗаполнено(НазваниеТаблицы) Тогда

                    СписокТаблиц.Добавить(ТаблицаСсылка,НазваниеТаблицы);

                КонецЕсли;

            КонецЕсли;

        КонецЦикла;



        Возврат СписокТаблиц;

    Иначе

        Сообщить("Ошибка:" + ХМЛХТТП.Status + "-" + ХМЛХТТП.ResponseText);

        Возврат Неопределено;

    КонецЕсли;

КонецФункции

Теперь остановимся на самой выгрузке значения в ячейку google таблицы. Для определения значения в ячейке выполняется POST запрос по адресу листа таблицы, который пользователь определил до этого. Успешность выполнения обновления контролируется по значению Status, в случае удачного обновления он должен быть равен 201. Функция обновления значения ячейки на листе Google таблицы имеет следующий вид:

Код 1C v 8.х

 &НаСервере

Функция ОбновитьЯчейкуЛистаГугл(Маркер,ИДЛиста,Строка,Колонка,Значение)

    ТекстСоздания = "

    | " + ИДЛиста + "/R" + Строка(Строка) + "C" + Строка(Колонка)+"

    | + ИДЛиста + "/R"+ Строка(Строка) + "C" + Строка(Колонка)+"""/>

    |   + Строка(Строка) + """ col=""" + Строка(Колонка)+ """ inputValue=""" + Значение+"""/>

    | ";

    ХМЛХТТП = ПолучитьCOMОбъект("", "Microsoft.XMLHTTP");

    ХМЛХТТП.Open("POST", ИДЛиста, Ложь);

    ХМЛХТТП.SetRequestHeader("Content-Type", "application/atom+xml;type=feed");

    ХМЛХТТП.SetRequestHeader("X-If-No-Redirect", "true");

    ХМЛХТТП.SetRequestHeader("Authorization", "GoogleLogin auth=" + Маркер);

    ХМЛХТТП.Send(ТекстСоздания);

    Если ХМЛХТТП.Status = 201 Тогда

        Возврат Истина;

    Иначе

        Сообщить("Ошибка:" + ХМЛХТТП.Status + "-" + ХМЛХТТП.ResponseText);

        Возврат Ложь;

    КонецЕсли;

КонецФункции

Источник

Категория: Табличный документ

Выбор оптимального алгоритма для разбора строки в массив

Столкнулся с проблемой: ПолучитьСтрокуПоНомеру() медленно отрабатывает на входных данных >100 000 строк. Как сделать бытсрее?

Код 1C v 8.х

  // Пример Defender aka LINN

ВремяНачала = ТекущаяДата(); 

Сообщить("Обработка начата: " + ВремяНачала); 



ТЗ = Новый ТаблицаЗначений; 

Текст = ПолучитьМакет("Макет").ПолучитьТекст(); 



RE = New COMObject("VBScript.RegExp"); 

RE.Global        = Истина; 

RE.IgnoreCase    = Истина; 

RE.Multiline    = Истина; 



RE.Pattern = "^.*$"; 



Строки = RE.Execute(Текст); 



RE.Pattern = "([^\|]+?|\|)(?=\|)"; 



ДобавитьКолонки = Истина; 



Для Каждого СтрокаТекста из Строки Цикл 

   СтрокаДляРазбора = СтрокаТекста.Value; 

    

   Результат = RE.Execute(СтрокаДляРазбора); 

    

   Если ДобавитьКолонки Тогда 

       НомерКолонки = 0; 

       Для Каждого Совпадение Из Результат Цикл 

           НомерКолонки = НомерКолонки + 1; 

           ТЗ.Колонки.Добавить("Колонка" + НомерКолонки); 

       КонецЦикла; 

       ДобавитьКолонки = Ложь; 

   КонецЕсли; 

    

   НоваяСтрока = ТЗ.Добавить(); 

    

   НомерКолонки = 0; 

   Для Каждого Совпадение Из Результат Цикл 

        

       Значение = Совпадение.Value; 

        

       НоваяСтрока[НомерКолонки] = ?(Значение = "|", "", Значение); 

       НомерКолонки = НомерКолонки + 1; 

   КонецЦикла; 

КонецЦикла; 



ВремяОкончания = ТекущаяДата(); 



Сообщить("Обработка завершена: " + ВремяОкончания + ", время обработки: " + Формат('00010101' + (ВремяОкончания-ВремяНачала), "ДФ=мм:сс")); 

Сообщить("Количество строк: " + ТЗ.Количество());

Код 1C v 8.х

 // Пример  aleks-id

Функция InitRegExp(Разделитель = "|")

    RegExp = Новый COMОбъект("VBScript.RegExp");

    

    //Параметры: 

    RegExp.MultiLine = Истина;  // истина — текст многострочный, ложь — одна строка 

    RegExp.Global = Истина;   // истина — поиск по всей строке, ложь — до первого совпадения 

    RegExp.IgnoreCase = Ложь; // истина — игнорировать регистр строки при поиске 

    

    RegExp.Pattern = "[^\" + Разделитель + "]+";

    Возврат RegExp;

КонецФункции



Функция РазложитьСтрокуВМассив(RegExp, Строка)

    

    Matches = RegExp.Execute (Строка);

    

    Массив = Новый Массив;

    

    Для Сч = 0 По Matches.Count - 1 Цикл

        Массив.Добавить(Matches.Item(Сч).Value);

    КонецЦикла;

    

    

    Возврат Массив;

КонецФункции



Процедура КнопкаВыполнитьНажатие(Кнопка)

    Текст = Новый ЧтениеТекста("C:\aktivy.txt", КодировкаТекста.ANSI);

    RegExp = InitRegExp();

    Стр = Текст.ПрочитатьСтроку();

    Пока Стр <> Неопределено Цикл

        масс = РазложитьСтрокуВМассив(RegExp, Стр);

        Стр = Текст.ПрочитатьСтроку();

    КонецЦикла;

    RegExp = Неопределено;

КонецПроцедуры

Категория: Регулярные выражения

Использование регулярных выражений (RegExp) в 1С

Регулярные выражения (Regular Expressions) являются известным и мощным средством для поиска, тестирования и замены подстрок. Эта технология доступна и в 1С - через объект VBScript.RegExp. Нужный объект уже встроен в современные версии Windows (начиная с Windows 98), и устанавливать дополнительно ничего не нужно.
Приведенные ниже примеры были протестированы в 1С:Предприятие 7.7; для 1С:Предприятие 8.x изменяется способ создания объекта:

Код 1C v 8.х

 RegExp = Новый COMОбъект("VBScript.RegExp");

Кроме того, там уже есть логические константы Истина и Ложь - объявлять их не нужно.

Более подробное описание самой технологии RegExp (что означают те или иные значки или скобочки, или какие шаблоны поиска или замены можно использовать в типичных ситуациях) можно найти в специальной литературе (например Бен Форта "Освой самостоятельно регулярные выражения (regexp) за 10 минут") или на сайтах в сети Internet.

Код 1C v 7.x

 ///////////////////////////////////////////////////////////////////////

//Поиск вхождений подстроки

Процедура RegExp_Exec()

    

    //Для 1С 7.7:

    Истина=-1;

    Ложь=0;

    RegExp = CreateObject("VBScript.RegExp");

    

    RegExp.IgnoreCase = Ложь; //Игнорировать регистр

    RegExp.Global = Истина; //Поиск всех вхождений шаблона

    RegExp.MultiLine = Ложь; //Многострочный режим

    

    RegExp.Pattern = "<[^>]*>"; //Ищем теги HTML

    Matches=RegExp.Execute("Это <hr> строка <br> с тегами HTML");

    ЧислоВхождений=Matches.Count();

    Если ЧислоВхождений>0 Тогда 

        Для к = 0 По ЧислоВхождений-1 Цикл

            Match = Matches.Item(к);

            Сообщить("Найден тег:"+ Match.Value);

        КонецЦикла;

    Иначе

        Сообщить("Вхождений шаблона не найдено");

    КонецЕсли;

    //Выдаст в окно сообщений:    

    //Найден тег:<hr>

    //Найден тег:<br>    

КонецПроцедуры

Более продвинутый пример разбора HTML использует подвыражения (SubMatches) и позволяет находить как сами теги, так и текст между ними.

Код 1C v 7.x

 ///////////////////////////////////////////////////////////////////////

//Поиск вхождений подстроки с использованием подвыражений

Процедура RegExp_Exec1()

    

    //Для 1С 7.7:

    Истина=-1;

    Ложь=0;

    RegExp = CreateObject("VBScript.RegExp");

    

    RegExp.IgnoreCase = Ложь; //Игнорировать регистр

    RegExp.Global = Истина; //Поиск всех вхождений шаблона

    RegExp.MultiLine = Ложь; //Многострочный режим

    

    RegExp.Pattern = "([^<]*)(<[^>]*>)([^<]*)"; //Ищем теги HTML, а также текст до и после тега

    Matches=RegExp.Execute("  <tr><td id=aaa>Дятел <td> долбит <td> сосну </tr>");

    ЧислоВхождений=Matches.Count();

    Если ЧислоВхождений>0 Тогда 

        Для к = 0 По ЧислоВхождений-1 Цикл

            Match = Matches.Item(к);

            

            SubMatches = Match.SubMatches;

            ЧислоПодвыражений=SubMatches.Count();

            Для н = 0 По ЧислоПодвыражений-1 Цикл

                SubMatch=SubMatches.Item(н);

                Если SubMatch="" Тогда

                    Продолжить;

                КонецЕсли;    

                

                Сообщить("Подстрока: "+SubMatch);

            КонецЦикла;    

        КонецЦикла;

    Иначе

        Сообщить("Вхождений шаблона не найдено");

    КонецЕсли;

КонецПроцедуры



//Выводит в окно сообщений:

//Подстрока:   

//Подстрока: <tr>

//Подстрока: <td id=aaa>

//Подстрока: Дятел 

//Подстрока: <td>

//Подстрока:  долбит 

//Подстрока: <td>

//Подстрока:  сосну 

//Подстрока: </tr>

Часто регулярные выражения используются для тестирования строк, например пользовательского ввода.
Этот пример позволяет узнать, является ли строка целым числом.

Код 1C v 7.x

 ///////////////////////////////////////////////////////////////////////

//Проверка подстроки

Процедура RegExp_Test()

    RegExp = CreateObject("VBScript.RegExp");

    RegExp.Pattern =  "^\d+$"; //Шаблон, который соответствует целому числу

    стр="12345";//Строка, которую тестируем

    Если RegExp.Test(стр)=0 Тогда

        Сообщить("Это не целое число");

    Иначе

        Сообщить("Это целое число");

    КонецЕсли;

    //Выдаст в окно сообщений:    

    //"Это целое число"

КонецПроцедуры

Регулярные выражения поддерживают не только поиск, но и замену текста. При этом найденные подвыражения (в круглых скобках) могут быть представлены в строке замены как $1, $2 и т. д.
(знак доллара используется в VBScript.RegExp; в других средах программирования, например в JavaScript, используемый для этой цели символ может отличаться).

Код 1C v 7.x

 ///////////////////////////////////////////////////////////////////////

//Замена текста в подстроке

Процедура RegExp_Replace()

    

    //Строка, где мы будем производить замены

    стр="Дятел долбил сосну";

    

    Истина=-1;

    Ложь=0;

    RegExp = CreateObject("VBScript.RegExp");

    

    RegExp.IgnoreCase = Истина; //Игнорировать регистр

    RegExp.Global = Истина; //Поиск всех вхождений шаблона

    RegExp.MultiLine = Истина; //Многострочный режим

    

    

    RegExp.Pattern = "(долбил)"; 

    

    стр=RegExp.Replace(стр, "про$1"); 

    Сообщить(стр);

    //Выдаст в окно сообщений:    

    //"Дятел продолбил сосну"

КонецПроцедуры

Источник

Категория: Регулярные выражения

Функция разбора (разложения) строки в массив

Данные функции позволяют разложить строку в массив, используя заданный разделитель
Например есть строка: абв$dfd$232$-0oj$5
Выполнив код: НашМассив = РазложитьСтрокуВМассив(абв$dfd$232$-0oj$5, "$") ;
Получим: НашМассив = абв
dfd
232
-0oj
5

Код 1C v 8.х

 

// Функция "расщепляет" строку на подстроки, используя заданный 

//		разделитель. Разделитель может иметь любую длину. 

//		Если в качестве разделителя задан пробел, рядом стоящие пробелы 

//		считаются одним разделителем, а ведущие и хвостовые пробелы параметра Стр

//		игнорируются.

//		Например, 

//		РазложитьСтрокуВМассивПодстрок(",ку,,,му", ",") возвратит массив значений из пяти элементов, 

//		три из которых - пустые строки, а 

//		РазложитьСтрокуВМассивПодстрок(" ку   му", " ") возвратит массив значений из двух элементов

//

//	Параметры: 

//		Стр - строка, которую необходимо разложить на подстроки. 

//		Разделитель - 	строка-разделитель, по умолчанию - запятая.

//

//	Возвращаемое значение:

//		массив значений, элементы которого - подстроки

//

Функция РазложитьСтрокуВМассив(Знач Стр, Разделитель = ",") Экспорт

	

	МассивСтрок = Новый Массив();

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;

	

КонецФункции

Пример с использованием предустановленной библиотеки RegExp, т.е. она есть в любом windows.
Плюсы RegExp:
1. Хорошая скорость анализа, т.к. 1С анализ строк (разбор) обычно реализуется циклами и функциями: Лев, Прав, Сред, Найти, а встроенный язык медленный
2. Высокая читаемость и модифицированность (более предсказуем в случае несоответствия строки - разбору)
3. Дополнительный функционал (можно осуществлять анализ, замену и проверку строковых выражений)

Минусы RegExp:
1. Не все задачи можно решить (например рекурсивные разборы тип 1 + (2+3*(2-7)) в случае если нужно разобрать на выражения в скобках) приходится смешивать с кодом.
2. Возможность зависания при использовании сложных шаблонов(редкость, но бывает).
3. RegExp - это дополнительная библиотека и инициализация занимает значительное время.

Код 1C v 8.х

  // Пример с использованием предустановленной библиотеки RegExp, т.е. она есть в любом windows.

Функция РазложитьСтрокуВМассив(Строка, Разделитель = ",") Экспорт

	RegExp = Новый COMОбъект("VBScript.RegExp");    // создаем объект для работы с регулярными выражениями

	

	//Параметры:

	RegExp.MultiLine = Ложь;  // истина — текст многострочный, ложь — одна строка

	RegExp.Global = Истина;   // истина — поиск по всей строке, ложь — до первого совпадения

	RegExp.IgnoreCase = Ложь; // истина — игнорировать регистр строки при поиске

	

	//Разбор строки вида 1,СЛОВО,(1+2); Маска для разделителя ',' [^\,]*"

	RegExp.Pattern = "[^\" + Разделитель + "]+";

	Matches = RegExp.Execute (Строка);

	

	Массив = Новый Массив;

	

	Для Сч = 0 По Matches.Count - 1 Цикл

		Массив.Добавить(Matches.Item(Сч).Value);

	КонецЦикла;

	

	RegExp = Неопределено;

	

	Возврат Массив;

КонецФункции

Посмотрите Функцию разложить строку на подстроки (в список значений), используя заданный разделитель.

Категория: Работа с Текстом (Строкой)

Выгрузка результата запроса в текстовый файл с разделителями

Код 1C v 8.х

 Запрос = Новый Запрос();

Запрос.УстановитьПараметр("ДатаНач",НачалоДня(ДатаНач));

Запрос.УстановитьПараметр("ДатаКон",КонецДня(ДатаКон));

Запрос.УстановитьПараметр("Организация",Организация);

Запрос.Текст = "ВЫБРАТЬ

|	ПоступлениеТоваровУслугТовары.Номенклатура КАК Номенклатура,

|	ПоступлениеТоваровУслугТовары.Количество КАК Количество,

|	ПоступлениеТоваровУслугТовары.Цена КАК Цена,

|	ПоступлениеТоваровУслугТовары.Ссылка.Номер КАК Номер,

|	ПоступлениеТоваровУслугТовары.Ссылка.Дата КАК Дата,

|	ПоступлениеТоваровУслугТовары.Ссылка.Контрагент КАК Контрагент,

|	ПоступлениеТоваровУслугТовары.Номенклатура.Код КАК НоменклатураКод,

|	ПоступлениеТоваровУслугТовары.Номенклатура.Артикул КАК НоменклатураАртикул

|ИЗ

|	Документ.ПоступлениеТоваровУслуг.Товары КАК ПоступлениеТоваровУслугТовары

|ГДЕ

|	ПоступлениеТоваровУслугТовары.Ссылка.Дата МЕЖДУ &ДатаНач И &ДатаКон

|	И ПоступлениеТоваровУслугТовары.Ссылка.Организация = &Организация

|	

|УПОРЯДОЧИТЬ ПО	

|	Контрагент,

|	Номер,

|	Дата,

|	НоменклатураКод,

|	Номенклатура,

|	НоменклатураАртикул,

|	Количество,

|	Цена";	

Результат = Запрос.Выполнить().Выбрать();	

Текст = Новый ЗаписьТекста("c:\vigruz.txt", КодировкаТекста.ANSI);

РезультатДок = Запрос.Выполнить().Выбрать();	

Пока РезультатДок.Следующий() Цикл		

	ОбработкаПрерыванияПользователя();

	// В качестве разделителей необходимо использовать Символы. ВК (CR),ВТаб (VTab),НПП (NBSp),ПС (LF),ПФ (FF),Таб (Tab)

	

	//Если нам нужна строка вида " helpf.pro    07.08.2009   13 " в качестве разделителя используется табуляция

	//то пишем так:

	Текст.ЗаписатьСтроку(Строка(РезультатДок.Контрагент)+Символы.Таб+Строка(Формат((РезультатДок.Дата),"ДЛФ=D"))+Символы.Таб+Строка(РезультатДок.Номер));	

	// При загрузке строку можно будет разложить в массив для дальнейшей работы, РазложитьСтрокуВМассивПодстрок( ТекСтр, Символы.Таб). Ссылка на функцию ниже



	//Если нужен вид 

	// helpf.pro 

	// 07.08.2009

	// 13 

	// здесь в качестве разделителя используется перевод каретки (следующая строка), то пишем

	Текст.ЗаписатьСтроку(РезультатДок.Контрагент);

	Текст.ЗаписатьСтроку(Символы.ПС);	

	Текст.ЗаписатьСтроку(Формат((РезультатДок.Дата),"ДЛФ=D"));      

	Текст.ЗаписатьСтроку(Символы.ПС);	

	Текст.ЗаписатьСтроку(РезультатДок.Номер);          

	

КонецЦикла;		

Текст.Закрыть();

При загрузке для разбора строки используйте: Функция разбирает строку на подстроки, используя заданный разделитель и возвращает массив

Еще посмотрите пример: Загрузка данных из Текстового файла

Категория: Работа с Текстом (Строкой)

Получения курса валют из Интернет

Код 1C v 8.х

 Соединение = Новый HTTPСоединение("export.rbc.ru"); //готовим соединение

ИмяФайла = ПолучитьИмяВременногоФайла(".txt");

//строка-образец

//http://export.rbc.ru/free/cb.0/free.fcgi?period=DAILY&tickers=USD&d1=18&m1=01&y1=2009&d2=17&m2=02&y2=2009&lastdays=30&separator=TAB&data_format=BROWSER&header=1

//http://export.rbc.ru/free/cb.5/free.fcgi?period=DAILY&tickers=USDEUR_BASKET&d1=08&m1=07&y1=2009&d2=22&m2=07&y2=2009&lastdays=14&separator=TAB&data_format=BROWSER&header=1

СтрокаСоединения="/free/"+Источник+"/free.fcgi?period=DAILY&tickers="+Валюта1+"&d1="+День1+"&m1="+Месяц1+"&y1="+Год1+"&d2="+День2+"&m2="+Месяц2+"&y2="+Год2+"&separator=%7C&data_format=BROWSER";

СтрокаСоединения=СтрЗаменить(СтрокаСоединения," ","");



Попытка //соединяемся

Соединение.Получить(СтрокаСоединения,ИмяФайла);

Исключение

Сообщить("Невозможно получить курс по адресу http://export.rbc.ru"+СтрокаСоединения);

КонецПопытки;



КурсыТекст=Новый ТекстовыйДокумент; //читаем результат запроса

КурсыТекст.Прочитать(ИмяФайла);

Код 1C v 8.х

  // еще пример

 Функция ПолучитьКакСтроку(Адресс) 

	соминет = Новый COMОбъект("MSXML2.XMLHTTP");

	соминет.open ("GET", Адресс, Ложь);

	соминет.send();

	Возврат соминет.responseText;

КонецФункции	



Функция ПреобразоватьДату(дат)

	// Медот преобразования даты времен 1Сv7

	//Т=Строка(Дат);

	//Возврат Сред(Т,7,4)+"/"+Сред(Т,4,2)+"/"+Лев(Т,2);

	Возврат Формат(Дат,"ДФ=""гггг/ММ/дд""");

КонецФункции



Процедура КнопкаЗагрузитьКурсы(Элемент)

	//Список - список валют	

	Для А = 1 по Список.Количество() цикл

		Если Список[а-1].Пометка тогда

			Сообщить("Загружаем курсы для "+Строка(Список[а-1].Значение));

			Код = Строка(Список[а-1].Значение.Код);

			Дат = ПериодС;

			Пока Дат <= ПериодПо цикл

				Стр = ПолучитьКакСтроку("http://cbrates.rbc.ru/tsv/"+Код+"/"+ПреобразоватьДату(Дат)+".tsv");

				Поз = Найти(Стр,Символы.Таб);

				Если Поз = 0 Тогда

					Дат = Дат + 86400;

					Продолжить;

				КонецЕсли;					

				Кратность = Число(СокрЛП(Лев(стр,Поз-1)));

				курс = Число(СокрЛП(Сред(Стр,Поз+1,СтрДлина(Стр)-Поз)));

				Сообщить("Дата="+Строка(Дат)+" Курс="+Строка(курс)+" Кратность="+Строка(Кратность));

				Запись = РегистрыСведений.КурсыВалют.СоздатьМенеджерЗаписи();

				Запись.Период = Дат;

				Запись.Валюта = Список[а-1].Значение.Ссылка;

				Запись.Курс = Курс;

				Запись.Кратность = Кратность;

				Запись.Записать(Истина);

				Дат = Дат + 86400;                   

			КонецЦикла;				

		КонецЕсли;			

	КонецЦикла;		

КонецПроцедуры

Код 1C v 7.x

 // Взято с http://www.1c-club.kz     IUnknown

//Небольшая обработка для получения курса валют размещенной на странице Национального Банка РК.

//Внимание: работоспособность данной обработки может быть нарушена, если дизайнеры сайта НБ РК изменят формат страницы с //официальным курсом валюта. Но не большой анализ нового формата и работоспособность обработки будет восстановлена.

// шаблон для отображаемой на форме таблице значения

перем тзПустышка;



//*******************************************

// ПриНачалеВыбораЗначения(стрНазвание, чисФлаг)

//

// Параметры:

//  стрНазвание - Строка. Наименование реквизита формы инициюрующей

//                вызов процедуры.

//  чисФлаг     - Число. Флаг станадартной обработки иницации нажатия

//                кнопки выбора значения.

//

// Возвращаемое значение:

//  Нет.

//

// Описание:

//  Переопределенная процедура инициирующая при нажатии кнопки

//  выбора значения реквизита формы.

//

процедура ПриНачалеВыбораЗначения(стрНазвание, чисФлаг)

    // Если инициировали из реквизита "стрУРЛа"

    если стрНазвание = "стрУРЛа" тогда

        // откроем страницу с введенным URL

        запуститьприложение(стрУРЛа);

    конецесли;

конецпроцедуры



//*******************************************

// кнПолучить()

//

// Параметры:

//  Нет

//

// Возвращаемое значение:

//  Нет.

//

// Описание:

//  Процедура получающая курсы валют с URL находящегося в

//  строковом реквизите формы "стрУРЛа". Пытается по указаноому URL

//  получить страницу и распарсить ее.

//

//  ПРЕДУПРЕЖДЕНИЕ:

//  В случае измения формата данных представленных на странице, возможно

//  будет работать не правильно.

//

процедура кнПолучить()

    // сгенирим имя файла для временного хранения содержимого

    // страницы курса валют Национального банка

    стрИмяФайла = каталогпользователя() + "$$$$.###";

    // создадим объект XMLHttpRequest

    олеХМЛ = создатьобъект("Microsoft.XMLHTTP");

    // иницируем его типом запроса и нужным нам URL

    олеХМЛ.Open("GET", стрУРЛа, 0);

    // отправим запрос для обработки серверу

    олеХМЛ.Send();

    // создадим "поток" через ADODDB для работы с данными

    олеАДО = создатьобъект("ADODB.Stream");

    // зададим тип и режим потока

    олеАДО.Mode = 3;

    олеАДО.Type = 1;

    // откроем его

    олеАДО.Open();

    // создадим объект для управления скриптами

    олеШелл = создатьобъект("MSScriptControl.ScriptControl");

    // установим язык сценариев

    олеШелл.Language = "vbscript";

    // добавим созданные объекты

    олеШелл.AddObject("oleADO", олеАДО);

    олеШелл.AddObject("oleXML", олеХМЛ);

    // с помощью скрипта запишем в поток ADO данные из

    // объекта XMLHttpRequest

    // то есть содержимое страницы

    олеШелл.Eval("oleADO.Write(oleXML.ResponseBody)");

    // запишем данные во временный файл

    олеАДО.SaveToFile(стрИмяФайла, 2);

    // закроем данный поток

    олеАДО.Close();

    // для ускорения парсера занесем весь файл в строковую

    // переменую с разделителем строк

    // для этого инициализуруем поток установкой

    // соотвествующим режимом и типом

    олеАДО.Mode= 3;

    олеАДО.Type = 2;

    // так как страница курса валют НБК имеет формат

    // символов UTF-8, то установим соотвествующий набор

    олеАДО.CharSet="UTF-8";

    // откроем поток

    олеАДО.Open();

    // загрузим содержимое нашего файла в поток

    олеАДО.LoadFromFile(стрИмяФайла);

    // обнулим временную строковую переменную

    стрТемп = "";

    // в цикле получим из потока все строки

    пока олеАДО.EOS() = 0 цикл

        // и запишем их во временную переменую, добавив разделитель строк

        стрТемп = стрТемп + олеАДО.ReadText(-2) + разделительстрок;

    конеццикла;

    // закроем поток

    олеАДО.Close();

    // удалим временный файл

    фс.УдалитьФайл(стрИмяФайла);

    // найдем в строке позицию начала блока с данными о курсе

    чисПозиция = найти(стрТемп, "Официальные курсы валют на");

    если чисПозиция = 0 тогда

        // если позиции нет ... то мы имем другую страницу

        // или другой формат страницы...

        предупреждение("Не получилось получить курсы валют");

    иначе

        // создаим временную таблицу значений

        // для более шустрого заполения из-за отстуствия вызова

        // функции перерисовки таблицы при изменении данных

        тзТемп = создатьобъект("ТаблицаЗначений");

        // установим для нее нужный формат

        тзПустышка.Выгрузить(тзТемп);

        // отрежем все лишнее

        стрТемп = сред(стрТемп, чисПозиция);

        // получим дату курса

        дтКурса = дата(стрзаменить(стрполучитьстроку(стрТемп, 2), "/", "."));

        // первая строка с курсом валюты находится на 18 строке от начала

        // после удаления мусора

        чисПозиция = 18;

        // узнаем сколько всего строк в многострочке

        чисКоличествоСтрок = стрколичествострок(стрТемп);

        // получим строку

        стрТекущая = стрполучитьстроку(стрТемп, чисПозиция);

        // если в строке есть подстрока ... то значит это наверное очередная валюта

        пока найти(стрТекущая, "input type=""checkbox"" name=""idval""") > 0 цикл

            // добавляем новую строку

            тзТемп.НоваяСтрока();

            // получаем строку со смещением 1 от позиции

            стрТекущая = стрполучитьстроку(стрТемп, чисПозиция + 1);

            // используя фичу 1С по преобразованию, получим число

            // за сколько единиц валюты имеем курс в тенге

            тзТемп.Количество = число(стрТекущая);

            // путем убирания "мусора" получаем наименование валюты

            тзТемп.Наименование = сокрлп(стрзаменить(стрзаменить(стрТекущая, тзТемп.Количество, ""), "</td>", ""));

            // получаем строку со смещением 2 от позиции

            стрТекущая = стрполучитьстроку(стрТемп, чисПозиция + 2);

            // убираем html мусор

            стрТекущая = сокрлп(стрзаменить(стрзаменить(стрТекущая, "<td class=""gen7"" align=""center"">", ""), "</td>", ""));

            // получаем код валюты

            тзТемп.Код1 = лев(стрТекущая, 3);

            // получаем код валюты "Тенге"

            тзТемп.Код2 = прав(стрТекущая, 3);

            // получаем строку со смещением 5 от позиции

            стрТекущая = стрполучитьстроку(стрТемп, чисПозиция + 5);

            // очищаем от мусора и преобразуем в число... получаем курс

            тзТемп.Курс = число(стрзаменить(стрзаменить(стрТекущая, "<td class=""gen7"" align=""center"">", ""), "</td>", ""));

            // увеличиваем позицию на 17 ...

            чисПозиция = чисПозиция + 17;

            если чисПозиция > чисКоличествоСтрок тогда

                // если позици дальше имеющихся строк

                // то все курсов больше нет

                стрТекущая = "";

            иначе

                // получаем очередную строку для разбора

                стрТекущая = стрполучитьстроку(стрТемп, чисПозиция);

            конецесли;

        конеццикла;

        // сформированую таблицу копируем в таблицу на форме

        тзТемп.Выгрузить(тзКурсов);

    конецесли;

конецпроцедуры



//*******************************************

// установим значение реквизита текущим URL по которому можно получить курс валют

стрУРЛа = "http://www.nationalbank.kz/?docid=460&uid=DD54B73C-802C-E8F0-E27EDF82ECF77C1D";

// формируем формат таблицы

тзПустышка = создатьобъект("ТаблицаЗначений");

тзПустышка.НоваяКолонка("Количество", "число", 3, 0, "", 5);

тзПустышка.НоваяКолонка("Наименование", "строка", , , "Наименование", 70);

тзПустышка.НоваяКолонка("Код1", "строка", 3, , "код", 10);

тзПустышка.НоваяКолонка("Код2", "строка", 3, , "код", 10);

тзПустышка.НоваяКолонка("Курс", "число", 7, 2, "Курс", 10);

// копируем получившийся формат в таблицу на форме

тзПустышка.Выгрузить(тзКурсов);

Категория: COM-объекты, WMI, WSH