разложитьстрокувмассивподстрок » Поиск

Результаты по ключевому слову: разложитьстрокувмассивподстрок

Как получить координаты выделенной области на Яндекс Карте?

На одном проекте потребовалось получать координаты выделенной области на яндекс карте, после долгих изучений получилось следующее:

Вид Формы: На карте выделяете объект, нажимаете кнопку Получить координаты выделенной области и заполняется таблица координат

Код инициализации карты и обработчик кнопки получения координат:

Код 1C v 8.х

 Процедура ИнициализироватьКарту()

	

	ПутьКФайлу = КаталогВременныхФайлов()+"yamaps.html";

	Ф = новый Файл(ПутьКФайлу);

	Если Ф.Существует() Тогда

		УдалитьФайлы(ПутьКФайлу);

	КонецЕсли; 

	

	Т = новый ТекстовыйДокумент;

	ТД = ЭтотОбъект.ПолучитьМакет("МакетЯндекс");

	Т.УстановитьТекст(ТД.ПолучитьТекст());

	Т.Записать(ПутьКФайлу);

		

	ЭлементыФормы.Эксплорер.Перейти(ПутьКФайлу);

КонецПроцедуры





Процедура ВыполнитьСкрипт(Команда) Экспорт 

	ЭлементыФормы.Эксплорер.document.getElementById("WebClientOperation").value = Команда;

	ЭлементыФормы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры





Процедура ПриОткрытии()

	ИнициализироватьКарту();

КонецПроцедуры





Процедура ПолучитьКоординатыНажатие(Элемент)

	ВыполнитьСкрипт("GetGEO();");

	ТекКоординаты=ЭлементыФормы.Эксплорер.document.getElementById("geometry").innerText;

	ТекКоординаты=СтрЗаменить(ТекКоординаты,"Координаты: [","");

	МассивСтроки = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(ТекКоординаты, "], [ ");

	Точки.Очистить();

	Для Каждого стр из МассивСтроки Цикл 

		Текстр=СтрЗаменить(стр,"[","");

		Текстр=СтрЗаменить(Текстр,"]","");

		Текстр=СокрЛП(Текстр);

		нСтрок=Точки.Добавить();

		симвЗапятой=Найти(Текстр,","); 

		нСтрок.Широта=Лев(Текстр,симвЗапятой-1);

		нСтрок.Долгота=Сред(Текстр,симвЗапятой+2,СтрДлина(Текстр));

	КонецЦикла;	

	//Сообщить(ТекКоординаты);

КонецПроцедуры

Макет

Код VBS

 <!DOCTYPE html">

<html xmlns="http://www.w3.org/1999/xhtml">

<head>

    <meta http-equiv="Content-Type" content="text/html; charset=utf-8"/>

    <meta http-equiv="X-UA-Compatible" content="IE=9"/>

    <style type="text/css">

	  html { height: 100% }

	  body { height: 100%; margin: 0px; padding: 0px }

	  #map { height: 100% }

	</style>

    <script src="https://api-maps.yandex.ru/2.1/?lang=ru_RU"  type="text/javascript"></script>

	<script src="http://yandex.st/jquery/1.6.4/jquery.min.js" type="text/javascript"></script>	

    <script type="text/javascript">

	var index = 1;

	var MyMap, route;

	var clusterer;

	var PointArray = [];

	var noclick = false;

	

	ymaps.ready(init);

	function init(){  

		myMap = new ymaps.Map ("map", {

			center: [55.75, 37.62],

			zoom: 10

		}),

        polygon = new ymaps.GeoObject({

        geometry: {

            type: "Polygon",

            coordinates: []

        }

  	  });

		myMap.behaviors.enable('scrollZoom');

		myMap.behaviors.disable('dblClickZoom');

			

		myMap.events.add('click', function (e) {

			if (!noclick) {

			//	addMarker(e.get('coords')); 				

			}else{

				noclick = false;

			}

		});

		

		myMap.events.add('drag end', function (e) {

			noclick = true;			

			document.getElementById('CoordX').value = "0";

			document.getElementById('CoordY').value = "0";

		});

		

		// создадим кластеризатор и запретим приближать карту при клике на кластеры

		//clusterer = new ymaps.Clusterer({clusterDisableClickZoom: true, synchAdd: true});

		//myMap.geoObjects.add(clusterer);

		

	myMap.geoObjects.add(polygon);

    polygon.editor.startDrawing();

	$('input').attr('disabled', false);

 

            // Обработка нажатия на любую кнопку.

            $('input').click(

                function () {

                    // Отключаем кнопки, чтобы на карту нельзя было

                    // добавить более одного редактируемого объекта (чтобы в них не запутаться).

                    $('input').attr('disabled', true);

					GetGEO();

                });

	}

	

	function addMarker(coordPosition){

		myPlacemark = new ymaps.Placemark(coordPosition, {

			// Свойства

			// Текст метки

			iconContent: 'Точка'+index

		}, {

			// Опции

			// Иконка метки будет растягиваться под ее контент

			preset: 'islands#blueStretchyIcon'

		});

		myMap.geoObjects.add(myPlacemark);

		

		document.getElementById('CoordX').value = coordPosition[0].toPrecision(15);

		document.getElementById('CoordY').value = coordPosition[1].toPrecision(15);

		index++;

	}

		

	function calcRoute(options){

		ymaps.route(options, {

	        // Опции маршрутизатора

	        mapStateAutoApply: true, // автоматически позиционировать карту

	        avoidTrafficJams: false   // Учитывать пробки

	    }).then(

		    function (router) {

		    route = router;

		        myMap.geoObjects.add(route);

		        

		        //заполняем и сохраняем инфо про маршрут

		        document.getElementById('RouteInfo').value = "Длина маршрута - " + route.getHumanLength() + ". Время - " + route.getHumanJamsTime();

		        

		        //генерация события для перехвата в 1С

		        var evt = document.createEventObject();

  				document.body.fireEvent('ondatasetcomplete', evt);

		    },

		    function (error) {

		        alert("Возникла ошибка: " + error.message);

	    });

	}

	

	function calcLine(options){

		var poly = new ymaps.Polyline(options, {

				hintContent: "Маршрут",

				balloonContent: "Маршрут экспедитора",

				balloonContentHeader: "",

				balloonContentBody: "",

				balloonContentFooter: ""

			}, {

				cursor: "pointer",

				draggable: false,

				hasBalloon: true,

				hasHint: true,

				interactiveZIndex: false,

				opacity: 1,

				openBalloonOnClick: true,

				openEmptyBalloon: false,

				openEmptyHint: false,

				openHintOnHover: true,

				strokeColor: '#E33926',

				strokeOpacity: 0.8,

				strokeStyle: '',

				strokeWidth: 5,

				syncOverlayInit: false,

				visible: true

			});

			myMap.geoObjects.add(poly);	

			myMap.setBounds(poly.geometry.getBounds());

	}

	

	function Reset(){

		// Удаляем все геообъекты на карте

		myMap.geoObjects.removeAll();   		   		

		PointArray = [];

		index = 1;

	}

	

	function ChangeCityMSK(){

		myMap.panTo([55.75, 37.62], {

            flying: 1

        });

	}

	function ChangeCitySPB(){

		myMap.panTo([59.938531, 30.313497], {

            flying: 1

        });

	}

	function ChangeCityKRAS(){

		myMap.panTo([45.04, 38.97], {

            flying: 1

        });

	}

	function ChangePlace(k,d){

		myMap.panTo([k, d], {

            flying: 1

        });

	}





	

	function FindAdres(Adres){

		Reset();

		var myGeocoder = ymaps.geocode(Adres);

		myGeocoder.then(

			function (res){

			var firstGeoObject = res.geoObjects.get(0);

			if(firstGeoObject != null){

				myMap.panTo(

					// Координаты нового центра карты

					firstGeoObject.geometry.getCoordinates(), {

						/* Опции перемещения:

						   разрешить уменьшать и затем увеличивать зум

						   карты при перемещении между точками 

						*/

						flying: true

					}

				);

				

				myPlacemark = new ymaps.Placemark(firstGeoObject.geometry.getCoordinates(), {

					// Свойства

					// Текст метки

					iconContent: Adres

				}, {

					// Опции

					// Иконка метки будет растягиваться под ее контент

					preset: 'islands#blueStretchyIcon'

				});

				myMap.geoObjects.add(myPlacemark);

			}else{

				alert("Ничего не найдено");}

			}

		);

	}

		

	function ReverseSearchAdres(CoordX, CoordY, Adres){

		Reset();

		

		var CoordPosition = [CoordX, CoordY];

		myMap.panTo(

		    // Координаты нового центра карты

		    CoordPosition, {

		        /* Опции перемещения:

		           разрешить уменьшать и затем увеличивать зум

		           карты при перемещении между точками 

		        */

		        flying: true

		    }

		);

		

		myPlacemark = new ymaps.Placemark(CoordPosition, {

			// Свойства

			// Текст метки

			iconContent: Adres

		}, {

			// Опции

			// Иконка метки будет растягиваться под ее контент

			preset: 'islands#blueStretchyIcon'

		});

		myMap.geoObjects.add(myPlacemark);

	}

	

	function addToPointArrayM(CoordX, CoordY, TextC, Text){

	var CoordPosition = [CoordX, CoordY];

	myPlacemark = new ymaps.Placemark(CoordPosition, {

			// Свойства

			// Текст метки

			iconContent: Text

		}, {

			// Опции

			// Иконка метки будет растягиваться под ее контент

			preset: TextC

		});

		myMap.geoObjects.add(myPlacemark);

	}

	

	function addToPointArrayPointOne(CoordX, CoordY, ID, Text){

		var point = new ymaps.GeoObject({

		    geometry: {type: "Point", coordinates: [CoordX, CoordY>,

		    properties: {

		        clusterCaption: ID,

		        iconContent: ID, 

		        hintContent: ID,  

		        balloonContent: Text, 

		        balloonContentBody: Text

		    }

			});

		myMap.geoObjects.add(point);

	}





	function addToPointArray(CoordX, CoordY, ID, Text){

		var point = new ymaps.GeoObject({

		    geometry: {type: "Point", coordinates: [CoordX, CoordY>,

		    properties: {

		        clusterCaption: ID,

		        iconContent: ID, 

		        hintContent: ID,  

		        balloonContent: Text, 

		        balloonContentBody: Text

		    }

			});

		PointArray.push(point);

	}

	

	function drawCluster(){

		clusterer.add(PointArray);

		myMap.geoObjects.add(clusterer);

	}	

	

	function createPolygon(ArrayPoint, Name, color) {

		// Создаем многоугольник

        myPolygon = new ymaps.Polygon([

            // Координаты вершин внешней границы многоугольника.

            ArrayPoint

        ], {

            //Свойства

            hintContent: Name

        }, {

            // Опции.

            // Цвет заливки (зеленый)

            fillColor: color,

            // Цвет границ (синий)

            strokeColor: '#0000FF',

            // Прозрачность (полупрозрачная заливка)

            opacity: 0.6,

            // Ширина линии

            strokeWidth: 5,

            // Стиль линии

            strokeStyle: 'shortdash'

        });

            

        myMap.geoObjects.add(myPolygon);

    }	

    

    function WebClientClick() {

    	//очистка перед кликом координат, иначе после клика в упр. формах идет считывание координат

    	document.getElementById('CoordX').value = "0";

		document.getElementById('CoordY').value = "0";

    	

    	var WebClientOperation = document.getElementById("WebClientOperation").value;

		//alert(WebClientOperation);

		switch (WebClientOperation) {

        	case "0":   // ничего не делаем

        	   var a = 1; 

        	default:   // запускаем функцию

        	    eval(WebClientOperation);

        }

        document.getElementById('WebClientOperation').value = "0";

	} 

	

function GetGEO(){

polygon.editor.stopEditing(); 

printGeometry(polygon.geometry.getCoordinates());

}

// Выводит массив координат геообъекта в <div id="geometry">

function printGeometry (coords) {

$('#geometry').html('Координаты: ' + stringify(coords));





function stringify (coords) {

	var res = '';

	if ($.isArray(coords)) {

		res = '[ ';

		for (var i = 0, l = coords.length; i < l; i++) {

			if (i > 0) {

				res += ', ';

			}

			res += stringify(coords[i]);

		}

		res += ' ]';

	} else if (typeof coords == 'number') {

		res = coords.toPrecision(6);

	} else if (coords.toString) {

		res = coords.toString();

	}





	return res;

}

}   		

    </script>

</head>





<body>

<div id="geometry"/></div>

<div id="map" style="width:100%; height:100%"></div>

    <input type="hidden" id="CoordX" name="CoordX" value="0"></input>

    <input type="hidden" id="CoordY" name="CoordY" value="0"></input>

    <input type="hidden" id="RouteInfo" name="RouteInfo" value=""></input>

    <input type="hidden" id="WebClientOperation" name="WebClientOperation" value="0"></input>

    <input type="hidden" id="WebClient" name="WebClient" onclick="WebClientClick();"></input>

    <!-- <input type="button" value="Завершить редактирование" id="stopEditPolyline"/> -->

</body>

</html>

Категория: Географическая схема

Функция разбора (разложения) строки в массив, аналог СтрРазделить

Код 1C v 8.х

 Функция РазложитьСтрокуВМассивПодстрок(Знач Строка, Знач Разделитель = ",",

    Знач ПропускатьПустыеСтроки = Неопределено)

 

    Результат = Новый Массив;

 

    // для обеспечения обратной совместимости

    Если ПропускатьПустыеСтроки = Неопределено Тогда

        ПропускатьПустыеСтроки = ?(Разделитель = " ", Истина, Ложь);

        Если ПустаяСтрока(Строка) Тогда 

            Если Разделитель = " " Тогда

                Результат.Добавить("");

            КонецЕсли;

            Возврат Результат;

        КонецЕсли;

    КонецЕсли;

    //

 

    Позиция = Найти(Строка, Разделитель);

    Пока Позиция > 0 Цикл

        Подстрока = Лев(Строка, Позиция - 1);

        Если Не ПропускатьПустыеСтроки Или Не ПустаяСтрока(Подстрока) Тогда

            Результат.Добавить(Подстрока);

        КонецЕсли;

        Строка = Сред(Строка, Позиция + СтрДлина(Разделитель));

        Позиция = Найти(Строка, Разделитель);

    КонецЦикла;

 

    Если Не ПропускатьПустыеСтроки Или Не ПустаяСтрока(Строка) Тогда

        Результат.Добавить(Строка);

    КонецЕсли;

 

    Возврат Результат;

 

КонецФункции

Источник

зы: админ, вот искал аналог СтрРазделить с игнорированием пустых строк - не нашел,зато нашел много дублей: https://helpf.pro/faq/view/504.html https://helpf.pro/faq/view/171.html https://helpf.pro/faq/view/351.html

, объедини пожалуйста.

зыы: кнопкой вставки ссылки невозможно пользоваться, ну что за извращенство с подменю, сделай одинарной как везде.

Категория: Работа с Текстом (Строкой)

Загрузка данных в 1С из PDF

В данной статье описан пример реализации загрузки данных накладных из PDF файлов для одного крупного Ритейла...

И так у Нас есть несколько файлов в формате pdf, которые нам необходимо загрузить в 1С.

Чтение PDF файлов из 1С

Первым дело я стал искать, как напрямую можно прочитать данные из 1С в PDF файлах - было найдено много информации и вариантов решений, но к сожалению большинство из них не правильно работали с кодировкой В результате банальный текст вида Красный стул превращался в страшную кракозябру.

Далее после долгих поисков был найден конвертер PDF в TXT - pdf2txt

Поддержка командной строки:

PDF2TXT <input PDF file> [output TXT file] [-logfile] [-open] [-space] [-html] [-format] [-silent] [-blankline] [-summary] [-zoom <num>] [-?] [-h]

<input PDF file> : Open an existing PDF file to convert.

[output TXT file] : Write to TEXT file, the default is same filename of input PDF file.

[-first <page number>]: Specify the first page number.

[-last <page number>]: Specify the last page number.

[-logfile] : Write log to "C:\pdf2txt.log" file.

[-open] : Auto open the text file after it be created.

[-space] : Auto insert spaces into text file.

[-html] : Output to a HTML file, not a text file.

[-format] : Keep the page layout in the generated TXT file.

[-silent] : Disable error and warning messages.

[-blankline] : Auto delete blank line in the generated TXT file.

[-summary] : Get PDF document summary.

[-zoom <num>] : Set zoom ratio, the range is from 50 to 200.

[-unicode] : Create UTF-8 encoding text file.

Примеры:

Код Batch File (DOS, CMD, BAT)

 C:\>PDF2TXT C:\input.pdf

C:\>PDF2TXT C:\input.pdf -unicode

C:\>PDF2TXT C:\input.pdf -first 10 -last 12

C:\>PDF2TXT C:\input.pdf C:\output.txt

C:\>PDF2TXT C:\input.pdf -open -silent -logfile -zoom 150

C:\>PDF2TXT C:\input.pdf C:\output.txt -open -silent

C:\>PDF2TXT C:\*.pdf

C:\>PDF2TXT C:\*.pdf C:\*.txt

C:\>PDF2TXT C:\test\*.pdf C:\test\*.txt

В архиве (Скачать Вы можете из статьи по ссылке) заготовка 1С обработки для частного случая, если она Вам подойдет - Хорошо

Если же нет, то Мы можем для Вас быстро доработать загрузку PDF в 1С!

Код на 1С для конфигурации УТ 10.3:

Код 1C v 8.х

 Функция РазложитьСтрокуВМассивПодстрок(Знач Стр, Разделитель = ",") Экспорт

	МассивСтрок = Новый Массив();

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			ТекЗнч = СокрЛП(Лев(Стр,Поз-1));

			Если ЗначениеЗаполнено(ТекЗнч) Тогда

				МассивСтрок.Добавить(ТекЗнч);

			КонецЕсли;

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;	

КонецФункции 









Процедура КнопкаВыполнитьНажатие(Кнопка)

	//Ищем Файлы

	тч.Очистить();

	НайденныеФайлы = НайтиФайлы(ПутьКPDF,"*.pdf",ложь);

	Для каждого стр Из НайденныеФайлы Цикл

		Нстр = ТЧ.Добавить();

		Нстр.ФайлPDF = стр.Имя;

	КонецЦикла;

	ЭтаФорма.Обновить();

	//Преобразуем PDF в TXT

	Для каждого стр Из ТЧ Цикл

		Попытка

			pdf = СокрЛП(ПутьКPDF+"\"+стр.ФайлPDF);

			txt = СтрЗаменить(pdf,"pdf","txt");

			Команд = ПутьКPDF2TXT+"\pdf2txt.exe "+pdf+" "+txt; 

			ЗапуститьПриложение(Команд,ПутьКPDF,Истина);	         

			стр.ФайлTXT = txt;

		Исключение

			стр.ФайлTXT = "!!!_ОШИБКА";

		КонецПопытки;

		ЭлементыФормы.ТЧ.ТекущаяСтрока = стр;

		ЭлементыФормы.ТЧ.ОбновитьСтроки(стр);

	КонецЦикла;	

	

	мТекущийПользователь = глЗначениеПеременной("глТекущийПользователь");

	мСкладПоУмолчанию = УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(мТекущийПользователь, "ОсновнойСклад");

	мОсновноеПодразделение = УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(мТекущийПользователь, "ОсновноеПодразделение");

	мОсновнаяВалютаВзаиморасчетов = УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(мТекущийПользователь, "ОсновнаяВалютаВзаиморасчетов");

	мОсновноеВедениеВзаиморасчетовПоДоговорам = УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(мТекущийПользователь, "ОсновноеВедениеВзаиморасчетовПоДоговорам");

	мВидНоменклатурыПоУмолчанию = УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(мТекущийПользователь, "ОсновнойВидНоменклатуры");

	

	мОтражатьВРеглУчете = УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(мТекущийПользователь, "ОтражатьДокументыВУправленческомУчете");

	мОтражатьВБухУчета = УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(мТекущийПользователь, "ОтражатьДокументыВБухгалтерскомУчете");

	мОтражатьВНалУчете = УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(мТекущийПользователь, "ОтражатьДокументыВНалоговомУчете");



	//Создаем Документ

	Для каждого стр Из ТЧ Цикл

		Состояние("Загружаю: "+стр.ФайлTXT);

		текдок=Новый ТекстовыйДокумент;

		текдок.Прочитать(стр.ФайлTXT,"UTF-8");

		ЗагрузкаТЧ=Ложь;

		

		ДокВозвратТоваровОтПокупателя = Документы.ВозвратТоваровОтПокупателя.СоздатьДокумент();	

		ДокВозвратТоваровОтПокупателя.Ответственный = мТекущийПользователь;   	

		ДокВозвратТоваровОтПокупателя.Дата  = ОбщегоНазначения.ПолучитьРабочуюДату();

		ДокВозвратТоваровОтПокупателя.УстановитьНовыйНомер();

		

		ДокВозвратТоваровОтПокупателя.ВидПоступления = Перечисления.ВидыПоступленияТоваров.НаСклад;

		ДокВозвратТоваровОтПокупателя.СкладОрдер = Склад;

		ДокВозвратТоваровОтПокупателя.Подразделение = мОсновноеПодразделение;

		ДокВозвратТоваровОтПокупателя.ВалютаДокумента  = Справочники.Валюты.НайтиПоКоду("643");

		ДокВозвратТоваровОтПокупателя.УчитыватьНДС     = ИСТИНА;

		ДокВозвратТоваровОтПокупателя.СуммаВключаетНДС = ИСТИНА;



		Для Ном=1 по текдок.КоличествоСтрок() цикл

			ТСтр = текдок.ПолучитьСтроку(Ном);

			ТекСтр = СокрЛП(ТСтр);

			

			Если Найти(ТекСтр, "Всего по накладной")>0 Тогда

				ЗагрузкаТЧ=Ложь;

				

				//делаем пересчеты сумм, количества мест и НДС по строкам

				Для Каждого СтрокаТабличнойЧасти Из ДокВозвратТоваровОтПокупателя.Товары Цикл

					ОбработкаТабличныхЧастей.РассчитатьКоличествоМестТабЧасти(СтрокаТабличнойЧасти, ДокВозвратТоваровОтПокупателя);

					ОбработкаТабличныхЧастей.РассчитатьСуммуТабЧасти(СтрокаТабличнойЧасти, ДокВозвратТоваровОтПокупателя);

					ОбработкаТабличныхЧастей.РассчитатьСуммуНДСТабЧасти(СтрокаТабличнойЧасти, ДокВозвратТоваровОтПокупателя);

				КонецЦикла;

				Попытка  

					ДокВозвратТоваровОтПокупателя.Записать(РежимЗаписиДокумента.Проведение); 

				Исключение

					ДокВозвратТоваровОтПокупателя.Записать(РежимЗаписиДокумента.Запись);  

				КонецПопытки;

				стр.Документ = ДокВозвратТоваровОтПокупателя.Ссылка;

				стр.Инфо = "Все ОК";

				ЭлементыФормы.ТЧ.ТекущаяСтрока = стр;

				ЭлементыФормы.ТЧ.ОбновитьСтроки(стр);

				

				//ВСЕ

				Прервать;

			КонецЕсли;	

				

			Если ЗагрузкаТЧ  Тогда

				ТекСтр = СтрЗаменить(ТекСтр, "подложке  ","подложке");

				ТекСтр = СтрЗаменить(ТекСтр, "   ","|");

				

				СтрМ=РазложитьСтрокуВМассивПодстрок(ТекСтр,"|");

				Если СтрМ.Количество()>2 Тогда

					//Сообщить(СтрМ);

					Попытка

						НоваяСтрока                            = ДокВозвратТоваровОтПокупателя.Товары.Добавить();

						НоваяСтрока.Номенклатура               = Справочники.Номенклатура.НайтиПоКоду(СтрМ[2]);

						//НоваяСтрока.ХарактеристикаНоменклатуры = СтрокаТаблицы.ХарактеристикаНоменклатуры;		

						//УстановитьСтавкуНДСВТабЧасти(НоваяСтрока, СтрокаТаблицы);

						//ПроверитьНаличиеСерииНоменклатуры(НоваяСтрока, СтрокаТаблицы);

						//УстановитьПризнакВеденияПоСериямНоменклатуры(НоваяСтрока); 		

						НоваяСтрока.ЕдиницаИзмерения           = НоваяСтрока.Номенклатура.БазоваяЕдиницаИзмерения;

						НоваяСтрока.Коэффициент                = 1;

						НоваяСтрока.Количество                 = Число(СтрМ[6]);

						НоваяСтрока.Цена                       = Число(СтрМ[7]);

						НоваяСтрока.Сумма         = Число(СтрМ[8]);

						НоваяСтрока.СуммаНДС     = Число(СтрМ[11]);

						НоваяСтрока.Качество = Справочники.Качество.Новый;

						Попытка

							НоваяСтрока.СтавкаНДС = Перечисления.СтавкиНДС["НДС"+Лев(СокрЛП(СтрМ[9]),2)];

						Исключение

							НоваяСтрока.СтавкаНДС = НоваяСтрока.Номенклатура.СтавкаНДС;

						КонецПопытки;

					Исключение

						Сообщить("Не загружено: "+ТекСтр);

					КонецПопытки;

				Иначе

					Продолжить;

				КонецЕсли;				

			Иначе

				// Возможно что-то будет			

			КонецЕсли;

			//Сообщить(ТекСтр);

			Если Найти(ТекСтр, "Товарная накладная")>0 Тогда

				ТекСтр = СтрЗаменить(ТекСтр, "   ","|");

				СтрМ=РазложитьСтрокуВМассивПодстрок(ТекСтр,"|");

				Если СтрМ.Количество()>1 Тогда

					//Сообщить(СтрМ);

					ДокВозвратТоваровОтПокупателя.НомерВходящегоДокументаЭлектронногоОбмена = СтрМ[1];

					ТекДата = СтрМ[2];

					ДокВозвратТоваровОтПокупателя.ДатаВходящегоДокументаЭлектронногоОбмена = Дата(Прав(ТекДата,4)+Сред(ТекДата,4,2)+Лев(ТекДата,2));

				КонецЕсли;			

			КонецЕсли;

			

			Если Найти(ТекСтр, "Грузополучатель:")>0 Тогда

				//Сообщить(ТекСтр);

				//Получим ИНН

				ГдеИНН = Найти(ТекСтр, "ИНН");

				Если ГдеИНН>0 Тогда

					ГдеИННвр= лев(ТекСтр,ГдеИНН+15);

					текИНН = Прав(гдеИННвр, СтрДлина(ГдеИННвр)-(ГдеИНН+3));

					текИНН = СокрЛП(СтрЗаменить(текИНН,".","")); текИНН = СокрЛП(СтрЗаменить(текИНН,",",""));  

					ТекОрганизация = Справочники.Организации.НайтиПоРеквизиту("ИНН",текИНН);

					Если ТекОрганизация=Справочники.Организации.ПустаяСсылка() Тогда

						ДокВозвратТоваровОтПокупателя.Организация = Организация;	

					Иначе

						ДокВозвратТоваровОтПокупателя.Организация = ТекОрганизация;			

					КонецЕсли;

					

				КонецЕсли;	

			КонецЕсли;

			

			Если Найти(ТекСтр, "Поставщик:")>0 Тогда

				//Сообщить(ТекСтр);

				//Получим ИНН

				ГдеИНН = Найти(ТекСтр, "ИНН");

				Если ГдеИНН>0 Тогда

					ГдеИННвр= лев(ТекСтр,ГдеИНН+15);

					текИНН = Прав(гдеИННвр, СтрДлина(ГдеИННвр)-(ГдеИНН+3));

					текИНН = СокрЛП(СтрЗаменить(текИНН,".","")); текИНН = СокрЛП(СтрЗаменить(текИНН,",",""));  

					ТекПоставщик = Справочники.Контрагенты.НайтиПоРеквизиту("ИНН",текИНН);

					ДокВозвратТоваровОтПокупателя.Контрагент = ТекПоставщик;

					ДокВозвратТоваровОтПокупателя.ДоговорКонтрагента = ТекПоставщик.ОсновнойДоговорКонтрагента;

				КонецЕсли;

			КонецЕсли;

			

			Если Найти(ТекСтр, "Плательщик:")>0 Тогда

				//Сообщить(ТекСтр);

				//Получим ИНН

				ГдеИНН = Найти(ТекСтр, "ИНН");

				Если ГдеИНН>0 Тогда

					ГдеИННвр= лев(ТекСтр,ГдеИНН+15);

					текИНН = Прав(гдеИННвр, СтрДлина(ГдеИННвр)-(ГдеИНН+3));

					текИНН = СокрЛП(СтрЗаменить(текИНН,".","")); текИНН = СокрЛП(СтрЗаменить(текИНН,",",""));  

					ТекПлательщик = Справочники.Контрагенты.НайтиПоРеквизиту("ИНН",текИНН);

				КонецЕсли;

			КонецЕсли;

			

			Если текстр="1                                   2                                       3            4        5      6       7            8             9      10               11                      12                  13               14                            15" Тогда

				ЗагрузкаТЧ=Истина;				

			КонецЕсли;

		КонецЦикла;	

		

	КонецЦикла;

	

КонецПроцедуры



Процедура ПутьКPDF2TXTОткрытие(Элемент, СтандартнаяОбработка)

	СтандартнаяОбработка = Ложь;

	Режим = РежимДиалогаВыбораФайла.ВыборКаталога; 

	ДиалогОткрытия = Новый ДиалогВыбораФайла(Режим); 

	ДиалогОткрытия.Каталог = ""; 

	ДиалогОткрытия.МножественныйВыбор = Ложь; 

	ДиалогОткрытия.Заголовок = "Выберите каталог с PDF2TXT"; 

	Если ДиалогОткрытия.Выбрать() Тогда 

		ПутьКPDF2TXT = ДиалогОткрытия.Каталог; 

		ПутьКPDF = ДиалогОткрытия.Каталог; 

	КонецЕсли; 

КонецПроцедуры



Процедура ПутьКPDFОткрытие(Элемент, СтандартнаяОбработка)

	СтандартнаяОбработка = Ложь;

	Режим = РежимДиалогаВыбораФайла.ВыборКаталога; 

	ДиалогОткрытия = Новый ДиалогВыбораФайла(Режим); 

	ДиалогОткрытия.Каталог = ""; 

	ДиалогОткрытия.МножественныйВыбор = Ложь; 

	ДиалогОткрытия.Заголовок = "Выберите каталог с PDF2TXT"; 

	Если ДиалогОткрытия.Выбрать() Тогда 

		ПутьКPDF = ДиалогОткрытия.Каталог; 

	КонецЕсли; 

КонецПроцедуры

Категория: Загрузка данных в 1С

Импорт в 1С из текстовых файлов (TXT, CSV)

Не редко возникает необходимость загрузить в справочники или документы 1С данные из текстового файла. Приведенный пример внешней обработки позволит преобразовать текстовый файл с известным разделителем данных в поле табличного документа для последующей обработки уже внутри 1С:Предприятия. Обработка содержит функцию разбора строки на массив данных, настраиваемый разделитель строки текста на "столбцы", процедуру чтения данных из текстового файла.

Разбор строки в массив с использованием функций из конфигурации 1С
Для разложения строки в массив в конфигурация 1С:Бухгалтерия, 1С:Торговля и 1С:УПП имеется замечательная функция - Функция РазложитьСтрокуВМассивПодстрок(Знач Стр, Разделитель = ",") Экспорт. Функция "расщепляет" строку на подстроки, используя заданный разделитель. Разделитель может иметь любую длину. Если в качестве разделителя задан пробел, рядом стоящие пробелы считаются одним разделителем, а ведущие и хвостовые пробелы параметра "Стр" игнорируются. Подробнее можно прочесть внутри конфигурации - "Общие модули" -> "Общего назначения". Функция возвращает массив значений, элементы которого - подстроки.

Чтение текстового файла (txt) в 1С
Операцию импорта - экспорта текстовых файлов (формат тхт или csv, а также htm, html) очень удобно реализовать при помощи конструкции следующего вида:

1. Функция ПолучитьПотокЧтенияСтрок(Файл) - Назначение: Проверить наличие файла (функция Файл()), Создать текстовый документ (Новый ТекстовыйДокумент()), вызвать метод "Прочитать" для открытия потока чтения файла. Возвращает поток, готовый для чтения.
2. Процедура ЧтениеТХТФайла(Элемент) - Назначение: В цикле произвести последовательное чтение строк файла текстового документа, разбирая на массив колонок данных и добавляя значения массива в табличное поле;

Исходный код 1С функции создания текстового потока чтения файла ТХТ:

Код 1C v 8.х

 Функция ПолучитьПотокЧтенияСтрок(Файл)

  Попытка

    // Используется для доступа к параметрам файлов или каталогов. 

    ТекстовыйФайл = Новый Файл(Файл);

    Если ТекстовыйФайл.Существует() = Ложь Тогда

      Сообщить("Файла "+Файл+" не существует!");

      Возврат Неопределено;

    КонецЕсли;



    // Текстовый документ предназначен для работы с текстами. 

    // Объект позволяет получать и сохранять текст в файле, 

    // работать со строками

    ПотокЧтенияСтрок = Новый ТекстовыйДокумент();

    ПотокЧтенияСтрок.Прочитать(ТекстовыйФайл);

  Исключение

    Сообщить("Файл не прочитан.", СтатусСообщения.Внимание);

    Сообщить(ОписаниеОшибки());

    Возврат Неопределено;

  КонецПопытки;



  // Возвращает текст, извлеченный из файла

  Возврат ПотокЧтенияСтрок;



КонецФункции // ПолучитьПотокЧтенияСтрок





// Исходный код функции загрузки строк в табличное поле:



Процедура ЧтениеТХТФайла(Элемент)



  // Проверка на наличие имени файла

  Если ПустаяСтрока(ИмяФайла) Тогда

    Предупреждение("Для запуска обработки необходимо предварительно выбрать файл данных.");

    Возврат;

  КонецЕсли;



  // Открыть файл, создать текстовый документ, прочитать

  ПотокСтрок = ПолучитьПотокЧтенияСтрок(ИмяФайла);



  // Очистить предыдущие значения

  ТаблицаДокумента.Очистить();

  ТаблицаДокумента.Колонки.Очистить();



  // Создать колонки табличного документа

  ТаблицаДокумента.Колонки.Добавить("Номер",,"Номер",5);

  ТаблицаДокумента.Колонки.Добавить("Артикул",,"Артикул",11);

  ТаблицаДокумента.Колонки.Добавить("Номенклатура",,"Номенклатура",25);

  ТаблицаДокумента.Колонки.Добавить("Цена",,"Цена",6);



  // Последовательное чтение строк текстового файла

  КоличествоСтрок = ПотокСтрок.КоличествоСтрок();

  Для Строка = 1 По КоличествоСтрок Цикл



    // Обработка нажатия Ctrl + Break

    ОбработкаПрерыванияПользователя();



    // Чтение строки из файла тхт / csv

    СтрокаИзФайла = ПотокСтрок.ПолучитьСтроку(Строка);



    // Разбор строки в массив, используя в качествен символа-разделителя "|"

    МассивСтрок = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(СтрокаИзФайла,"|");



    // Добавить данные в табличную часть экранной формы

    Стр=ТаблицаДокумента.Добавить();

    Стр.Номер	 = Строка;

    Стр.Артикул = МассивСтрок[0];

    Стр.Номенклатура = МассивСтрок[1];

    Стр.Цена = МассивСтрок[2];

    // Отобразить информацию о ходе выполнения обработки

    Состояние("Обработка строки файла : "

      + "строка " + Строка + " из " + КоличествоСтрок);



  КонецЦикла;



  // Отобразить результаты загрузки в форме элемента

  ЭлементыФормы.ТаблицаДокумента.Значение = ТаблицаДокумента;

  ЭлементыФормы.ТаблицаДокумента.СоздатьКолонки();



КонецПроцедуры // ЧтениеTXTФайла(Элемент)

В данном примере была произведена загрузка из текстового файла в следующем формате:

Код

7754|Процессор Atom 1.7|10,00
5054|Процессор AMD x64|8,99
7546|Мышь Microsoft|45,88

Категория: JSON, XML, TXT, CSV, DBF

Загрузить данные в 1с из текстового файла с разделителями

В этой статье я расскажу, как загружать данные в 1с 8 из простейших текстовых файлов с разделителями. Обычно они имеют расширение csv (Comma-Separated Values). Т. е. название подразумевает, что в каждой строке такого текстового файла значения разделены запятой. Но на самом деле, запятую, в качестве разделителя, использовать не надёжно. Поэтому применяют другие разделители, которые в обычном тексте встречаются редко. Это могут быть символы «^», «~»,«|» и другие. Итак, наша задача состоит в том, чтобы загрузить имеющуюся в csv файле информацию в базу данных 1с. Например, в файле будут содержаться товары интернет - магазина. В качестве образца, я взял выгрузку из магазина на скрипте virtuemart. Посмотрим, как выглядит файл.
Привожу две первых строки из него:

Код

~product_sku~^~category_path~^~product_name~^~product_desc~
~20~^~Книги/Электронные книги~^~Amazon Kindle 4 Touch~^~<p>Популярная электронная книга с ч/б экраном 6", электронной бумагой E-Ink Pearl, разрешением 600x800 пикс. с 16 - ю оттенками серого.</p>~

Посмотрим на файл.
Первая строка служебная. В ней описан формат нашего файла. Т. е. в какой ячейке, что находится. Однако, имейте в виду, что такой строки может и не быть.
Ячейки образуются при помощи разделителя «^», а данные в ячейках обрамляются символом «~».
В любой конфигурации 1с есть иерархический справочник товаров. В него и будем загружать информацию.
Создадим внешнюю обработку. Добавим строковый реквизит «путьКФайлуЗагрузки» для хранения имени файла. Добавим на форму поле ввода, связанное с данным реквизитом. Включим в свойствах поля ввода кнопку выбора и создадим обработчик события «НачалоВыбора» и напишем в нём такой код:

Код 1C v 8.х

 Процедура путьКФайлуЗагрузкиНачалоВыбора(Элемент, СтандартнаяОбработка)

	Режим = РежимДиалогаВыбораФайла.Открытие;

	ДиалогОткрытияФайла = Новый ДиалогВыбораФайла(Режим);

	ДиалогОткрытияФайла.ПолноеИмяФайла = "";

	Фильтр = "Comma separated file (*.csv)|*.csv";

	ДиалогОткрытияФайла.Фильтр = Фильтр;

	ДиалогОткрытияФайла.МножественныйВыбор = Ложь;

	ДиалогОткрытияФайла.Заголовок = "Выберите файл";

	

	Если ДиалогОткрытияФайла.Выбрать() Тогда

		путьКФайлуЗагрузки = ДиалогОткрытияФайла.ПолноеИмяФайла;

	КонецЕсли;

КонецПроцедуры

Т. о. мы организовали диалог для выбора файла в нашей обработке.
Хорошо. Теперь, для удобства и наглядности я предлагаю создать временную табличку, в которую мы загрузим текстовый файл, а уже после её заполнения - будем осуществлять загрузку в базу 1с. Для этого, на форму добавим табличное поле «табЗагрузки», с типом значения «ТаблицаЗначений» и командной панелью. В панели поместим кнопку «Заполнить» и создадим обработчик её нажатия «КоманднаяПанель1Заполнить». Также для элемента универсальности, добавим в обработку два строковых реквизита «символОграничения» и «разделительПолей». В них мы будем хранить «^», и «~». Можно в теле модуля формы осуществить их начальную инициализацию:
разделительПолей = "^";
символОграничения = "~";
Это позволит пользователю задать свои значения и при желании сохранить настройку, которая впоследствии не затрется нашей инициализацией.

Код 1C v 8.х

 Процедура КоманднаяПанель1Заполнить(Кнопка)

	Если табЗагрузки.Количество() > 0 И Вопрос("Таблица будет очищена. Вы уверены?",РежимДиалогаВопрос.ДаНет) 

		= КодВозвратаДиалога.Нет Тогда

		Возврат;	

	КонецЕсли;

	ЗаполнитьТаблицу();

КонецПроцедуры

Процедура ЗаполнитьТаблицу()

	текст = Новый ТекстовыйДокумент;

	Попытка

		//обязательно устанавливаем кодировку, в которой наш файл

		текст.Прочитать(путьКФайлуЗагрузки,КодировкаТекста.UTF8);

	Исключение

		Сообщить("Не удалось прочитать файл: " 

			+ ОписаниеОшибки(),СтатусСообщения.ОченьВажное);

		Возврат;

	КонецПопытки;	

	табЗагрузки.Очистить();//очищаем таблицу

	табЗагрузки.Колонки.Очистить();//удаляем колонки, так как их состав мог измениться

	квоСтрок = текст.КоличествоСтрок();

	Если Не квоСтрок > 0 Тогда

		Сообщить("Файл пустой",СтатусСообщения.Внимание);

		Возврат;	

	КонецЕсли;

	//получаем первую строку с форматом файла

	стрТекста = текст.ПолучитьСтроку(1);

	//преобразуем строку в массив при помощи функции общего модуля, которая есть в типовых

	//ниже я дам её код, на случай, если нет

	масЗначСтр = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(стрТекста,разделительПолей);

	//добавляем две служебные колонки

	//для возможности отказаться от загрузки определенной строки

	табЗагрузки.Колонки.Добавить("не_загружать",Новый ОписаниеТипов("Булево"),"Не загружать");

	//для удобства вывода комментариев с указанием номера строки по ходу загрузки

	табЗагрузки.Колонки.Добавить("номер_строки",Новый ОписаниеТипов("Число",

		Новый КвалификаторыЧисла(10,0,ДопустимыйЗнак.Неотрицательный)),"Номер строки");

	//формируем колонки нашей таблицы	

	Для каждого зн Из масЗначСтр Цикл

		//убираем лишний символОграничения

		значение = СтрЗаменить(зн,символОграничения,""); 

		кол = табЗагрузки.Колонки.Добавить(значение,Новый ОписаниеТипов("Строка"));

	КонецЦикла;

	

	//создаём колонки в табличном поле

	ЭлементыФормы.табЗагрузки.СоздатьКолонки();

	

	//начиная со второй строки читаем строки файла, раскладывая их в массив

	Для номСтр = 2 По квоСтрок Цикл

		стрТекста = текст.ПолучитьСтроку(номСтр);

		масЗначСтр = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(стрТекста,разделительПолей);

		//добавляем новую строку в таблицу

		новСтр = табЗагрузки.Добавить();

		новСтр.номер_строки = номСтр;

		//начиная с третьей колонки производим установку значений в колонки

		номЗнач = 2;

		Для каждого зн Из масЗначСтр Цикл

			новСтр[номЗнач] = СтрЗаменить(зн,символОграничения,"");

			номЗнач = номЗнач + 1;

		КонецЦикла;

    КонецЦикла;

КонецПроцедуры

Функцию разложения строки с разделителями в массив можно разместить как в одном из общих модулей, так и непосредственно в обработке.

Код 1C v 8.х

 Функция РазложитьСтрокуВМассивПодстрок(Знач Стр, Разделитель = ",") Экспорт

	МассивСтрок = Новый Массив();

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока Истина Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока Истина Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;

КонецФункции

Отлично. В итоге, после заполнения, получим примерно такую картинку:
title

Теперь приступим непосредственно к загрузке товаров. Рядом с кнопкой «заполнить» добавим кнопку «загрузить» и добавим обработчик её нажатия «КоманднаяПанель1Загрузить», а также добавим реквизит «ПапкаЗагрузкиВыгрузкиТоваров» с типом вашего справочника товаров для опциональной их загрузки в определенную папку. Текст обработчика будет такой:

Код 1C v 8.х

 Процедура КоманднаяПанель1Загрузить(Кнопка)

	Если Вопрос("Вы уверены, что хотите загрузить файл?", РежимДиалогаВопрос.ДаНет) 

		= КодВозвратаДиалога.Нет Тогда

	    Возврат;	

	КонецЕсли;

	ВсегоСтрок = табЗагрузки.Количество();

	номСтр = 1;

	Для каждого стрТЗ Из табЗагрузки Цикл

		Состояние("Обработано: " + Окр(номСтр * 100 / ВсегоСтрок) + "%");

		номСтр = номСтр + 1;

		ОбработкаПрерыванияПользователя();

		//если пользователь установил не_загружать = Истина, пропускаем 

		Если стрТЗ.не_загружать Тогда

			Продолжить;		

		КонецЕсли;

		объект1С = вернутьТовар(стрТЗ);

		Если объект1С = Неопределено Тогда

			Возврат;			

		КонецЕсли;

		Если Не ЗаписатьЭлементСпр(объект1С) Тогда

			Сообщить("Загрузка прервана!",СтатусСообщения.ОченьВажное);

			Возврат;				

		КонецЕсли;	

		//помечаем запись, как загруженную

		стрТЗ.не_загружать = Истина;

	КонецЦикла;

КонецПроцедуры

В приведенном коде две новые функции «вернутьТовар» и «ЗаписатьЭлементСпр». Вот их текст:

Код 1C v 8.х

 Функция вернутьТовар(стрТабФайла)

	Артикул = стрТабФайла.product_sku;

	Если Не ЗначениеЗаполнено(Артикул) Тогда

		Сообщить("В строке " + стрТабФайла.номер_строки + " не заполнен product_sku",

		СтатусСообщения.ОченьВажное);

		Возврат Неопределено;		

	КонецЕсли;

	Запрос = Новый Запрос("ВЫБРАТЬ

	|	Номенклатура.Ссылка

	|ИЗ

	|	Справочник.Номенклатура КАК Номенклатура

	|ГДЕ

	|	Номенклатура.Артикул = &Артикул");

	

	Запрос.УстановитьПараметр("Артикул",Артикул);

	

	Выборка = Запрос.Выполнить().Выбрать();

	Если Выборка.Следующий() Тогда

		Возврат Выборка.Ссылка.ПолучитьОбъект();			

	Иначе

		ЭтоНовый = Истина;

		объект1С = Справочники.Номенклатура.СоздатьЭлемент();

		объект1С.Артикул = Артикул;

		объект1С.Наименование = стрТабФайла.product_name;

		объект1С.Родитель = вернутьРодителяТовара(стрТабФайла.category_path);

		Возврат объект1С;

	КонецЕсли;

КонецФункции // вернутьТовар()

Функция ЗаписатьЭлементСпр(Спр)

	Попытка

		Спр.Записать();

	Исключение

		Сообщить("При записи элемента справочника " + Спр + " возникла ошибка: " + ОписаниеОшибки(),СтатусСообщения.ОченьВажное);

		Возврат Ложь;

	КонецПопытки;

	Возврат Истина;

КонецФункции // ЗаписатьЭлементСпр()

И осталась последняя новая функция для обработки родителя товара вернутьРодителяТовара. Текст её смотрите ниже. Комментарии по тексту.

Код 1C v 8.х

 Функция вернутьРодителяТовара(стрКатегории)

	//главный родитель - заполненная в обработке папка

	Родитель = ПапкаЗагрузкиВыгрузкиТоваров;

	//строку категории раскладываем в массив используя разделитель /

	масРодителей = РазложитьСтрокуВМассивПодстрок(стрКатегории,"/");

	Для каждого Род Из масРодителей Цикл

		//если папку не находим, создаём и назначаем в качестве родителя 

		//следующей и т. д. В случае проблем выдаём прекращаем загрузку

		РодСс = Справочники.Номенклатура.НайтиПоНаименованию(Род,Истина);

		Если РодСс.Пустая() Тогда

			НовРод = Справочники.Номенклатура.СоздатьГруппу();

			НовРод.Наименование = Род;

			НовРод.Родитель = Родитель;

			Если Не ЗаписатьЭлементСпр(НовРод) Тогда

				Возврат Неопределено; 			

			КонецЕсли;

			Родитель = НовРод.Ссылка;

		Иначе

			Родитель = РодСс;

		КонецЕсли;		

	КонецЦикла;

	Возврат Родитель;

КонецФункции //

Все. Конечно, в реальной жизни еще много чего нужно будет дописать, но не все сразу. Такой шаблон можно использовать как отправную точку. Скачивать файлы может только зарегистрированный пользователь!

Успехов в разработке!
Источник

Категория: Текстовый документ

Поле выбора ~ Как работать с многострочным полем?

Код 1C v 8.х

 Текст=Новый ТекстовыйДокумент;

	Текст.УстановитьТекст(ЭлементыФормы.ПолеВвода1.Значение);

	Для i=1 По Текст.КоличествоСтрок() Цикл

		Строка = Текст.ПолучитьСтроку(i);

		Массив = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(Строка, Символы.Таб);

		Попытка

			Сообщить(Массив[1]);

		Исключение

			

		КонецПопытки;

		

	КонецЦикла;

Категория: Работа с Формой (Диалог) и её элементами

Загрузка данных из CSV файла

Код 1C v 8.х

  // выберем CSV файл

ДиалогВыбора = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);

ДиалогВыбора.Заголовок = “Выберите файл”;



Если ДиалогВыбора.Выбрать() Тогда

ИмяФайла = ДиалогВыбора.ПолноеИмяФайла;

КонецЕсли;



//Обработка данных из CSV

// очищаем информацию в таблице и находим файл на диске, а потом считываем его:



//очищаем таблицу и удаляем колонки

Таблица.Очистить();

Таблица.Колонки.Очистить();

ЭлементыФормы.Таблица.Колонки.Очистить();



// чтение файла

ЗагружаемыйФайл = Новый ТекстовыйДокумент;

ЗагружаемыйФайл.Прочитать(ИмяФайла);



//После того как мы получили все данные из файла, мы считываем 1 строку файла

// и формируем колонки на форме с наименованиями из файла



//шапка по умолчанию 1 строка, из первой строки делаем колонки таблицы

Шапка = ЗагружаемыйФайл.ПолучитьСтроку(1);



//раскладываем строку в массив

МассивКолонок = РазложитьСтрокуВМассивПодстрок(Шапка,Разделитель); // процедура из типовой конфигурации, разбивает строку в массив по разделителям



//генерируем колонки

Для Каждого ИмяКолонки Из МассивКолонок Цикл



ИмяБезПробелов = СтрЗаменить(ИмяКолонки,” “,”"); // убираем из имени колонок пробелы

Таблица.Колонки.Добавить(ИмяБезПробелов,,ИмяКолонки);

НоваяКолонка = ЭлементыФормы.Таблица.Колонки.Добавить(ИмяБезПробелов, ИмяКолонки);

НоваяКолонка.Данные = ИмяБезПробелов;



КонецЦикла;



// После того, как шапка сформирована можно приступать к обработке самих данных

Для НомерСтроки=2 по ЗагружаемыйФайл.КоличествоСтрок() Цикл



Состояние(“Обрабатывается “+Строка(Формат(?(ЗагружаемыйФайл.КоличествоСтрок()=0,0,((100*НомерСтроки)/                                                                                                ЗагружаемыйФайл.КоличествоСтрок())),”ЧЦ=3; ЧДЦ=0&#8243;))+” %”);

ОбработкаПрерыванияПользователя(); //указав данный оператор, цикл можно прервать в любой момент нажатие ctrl+break



// получить строку файла с указанным номером и преобразуем её в массив

Строка = ЗагружаемыйФайл.ПолучитьСтроку(НомерСтроки);

МассивКолонок = РазложитьСтрокуВМассивПодстрок(Строка,Разделитель);// процедура из типовой конфигурации, разбивает строку в массив по разделителям

НоваяСтрока = Таблица.Добавить();



Если МассивКолонок.Количество() <> Таблица.Колонки.Количество() Тогда

Сообщить(“Ошибка со строкой ” + Строка);

Продолжить; // скорее всего в тексте содержит разделитель

КонецЕсли;



Для НомерКолонки = 1 по МассивКолонок.Количество() Цикл

//заполняем строку значениями

ТекущееЗначение = МассивКолонок[НомерКолонки-1];

ИмяКолонки = Таблица.Колонки[НомерКолонки-1].Имя;

НоваяСтрока[ИмяКолонки] = ТекущееЗначение;

КонецЦикла;



КонецЦикла;

Категория: JSON, XML, TXT, CSV, DBF

Как очистить кэш 1С?

Бывают случаи, когда на данном компьютере пользователя в рабочей базе была старая конфигурация, хотя на любом другом ПК и на сервере она обновилась. Так же может возникать ошибка потока данных. В этих и некоторых других случаях поможет очистка кеша.
В связи с тем, что 1С может быть установлена на различных операционных системах, папка, где хранится кэш, может быть различной.
Для Win XP:
%userprofile%\Local Settings\Application Data\1C\1Cv82
%userprofile%\Application Data\1C\1Cv82

Для Win 7:
%userprofile%\AppData\Roaming\1C\1Cv82
%userprofile%\AppData\Local\1C\1Cv82

Серверные оси Windows 2008
C:\Users\<username>\AppData\Local\1C
C:\Users\<username>\AppData\Roaming\1C

А самый простой способ найти папки – это использовать поиск по системе(win + F) по ключевым словам «1сv81» и/или «1cv82». Нужные нам папки находятся в каталоге пользователя.
Напимер:
C:\Documents and Settings\%userprofile%\Local Settings\Application Data\1C\1Cv81
C:\Documents and Settings\%userprofile% \Local Settings\Application Data\1C\1Cv82
C:\Documents and Settings\%userprofile% \Application Data\1C\1Cv81\
C:\Documents and Settings\%userprofile% \Application Data\1C\1Cv82\

Важно:
1) Кэш хранится в двух папках. Чаще всего эти папки называются «LocalSettings» и «ApplicationData». Обе папки находятся в каталоге пользователя.
2) Формат кэш-файлов выглядит вот так: «0df525c2-1c3e-44be-b852-c7059f17c5aa» или «0f2c4d8f-cc84-4033-8744-1acfa6204474». Удалять необходимо только те папки, у которых такой же формат в названии.
3.) Не удаляйте файл ibases.v8i — он содержит список баз

Можно ли изменить путь кэша метаданных?
Можно. С помощью групповых политик (gpedit.msc) можно переопределить путь профиля пользователя целиком (не только кэш метаданных).

ВАРИАНТЫ АВТОМАТИЗАЦИИ:
1. Доп. ключик командной строки /ClearCache — очистка кэша клиент-серверных вызовов (используется для тонкого и толстого клиентов в режиме 1С:Предприятия).
title

2. bat / cmd файл:

Код VBS

 @FOR /D %%i in ("C:\Users\*") do ( 

@FOR /D %%j in ("%%i\Local settings\Application data\1C\1Cv82\????????-????-????-????-????????????") do rd /s /q "%%j" 

@FOR /D %%j in ("%%i\AppData\Roaming\1C\1Cv82\????????-????-????-????-????????????") do rd /s /q "%%j" 

)

и текст батника с проверкой на ХР или 7:

Код VBS

 If Exist %USERPROFILE%\AppData\Roaming\1C\1Cv82 ( 

rem Удаляем все файлы в 7 

Del /F /Q %USERPROFILE%\AppData\Roaming\1C\1Cv82\*.* 

Del /F /Q %USERPROFILE%\AppData\Local\1C\1Cv82\*.* 



rem Удаляем все каталоги в 7 

for /d %%i in ("%USERPROFILE%\AppData\Roaming\1C\1Cv82\*") do rmdir /s /q "%%i" 

for /d %%i in ("%USERPROFILE%\AppData\Local\1C\1Cv82\*") do rmdir /s /q "%%i" 

) 



If Exist %USERPROFILE%\Local Settings\Application Data\1C\1Cv82 ( 

rem Удаляем все файлы в XP 

Del /F /Q %USERPROFILE%\Local Settings\Application Data\1C\1Cv82\*.* 

Del /F /Q %USERPROFILE%\Application Data\1C\1Cv82\*.* 



rem Удаляем все файлы в XP 

for /d %%i in ("%USERPROFILE%\Local Settings\Application Data\1C\1Cv82\*") do rmdir /s /q "%%i" 

for /d %%i in ("%USERPROFILE%\Application Data\1C\1Cv82\*") do rmdir /s /q "%%i" 

)

3. Процедуру ОчиститьКэшИПерезапуститьПрограмму() создаем в глобальном модуле и вызываем ее когда нужно почистить кэш 1С

Код 1C v 8.х

 // Процедура создает и запускает vbs файл, который производит очистку кэша.

// 1С и презапускает программу

//

Процедура ОчиститьКэшИПерезапуститьПрограмму() Экспорт



     СкриптФайл = Новый ТекстовыйДокумент;



     СтрокаСоединенияСБД = СтрокаСоединенияИнформационнойБазы();

     СтрокаЗапускаПрограммы = КаталогПрограммы();



     ПутьКФайлуСкрипта = КаталогВременныхФайлов() + "CacheCleaning.vbs";

     ПутьКФайлу1С = СтрокаЗапускаПрограммы + "1cv8.exe";



     ИмяСервера = "";

     ИмяБазы = "";

     Путь = "";

     КомандаЗапуска = "";

     Один = """";

     Два = """""";

     Три = """""""";  

    Если (Найти(СтрокаСоединенияСБД, "File=") <> 0) Тогда

          Путь = СтрЗаменить(СтрокаСоединенияСБД, "File=", "");

          Путь = Лев(Путь, СтрДлина(Путь)-1);

          КомандаЗапуска = "WshShell.Run " + Три + ПутьКФайлу1С + Два + " ENTERPRISE /F" + Путь + Один + ", 1, true";

     Иначе

          МассивПараметровСоединения = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(СтрокаСоединенияИнформационнойБазы(), ";");

          МассивПараметровСервера = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(МассивПараметровСоединения[0], """");

          ИмяСервера = СокрЛП(МассивПараметровСервера[1]);

          МассивПараметровБазы = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(МассивПараметровСоединения[1], """");

          ИмяБазы = СокрЛП(МассивПараметровБазы[1]);

          КомандаЗапуска = "WshShell.Run " + Три + ПутьКФайлу1С + Два + " ENTERPRISE /S" + ИмяСервера + "\" + ИмяБазы + Один + ", 1, true";

     КонецЕсли;

     // Если пользователь не хочет перезапускать сеанс 1С, то после выполнения скрипта ничего не делаем. 

     Если Не глЗначениеПеременной("глПерезапускатьСеансРаботыСПрограммой")  Тогда

          КомандаЗапуска = ""; 

     КонецЕсли; 



     СкриптФайл.УстановитьТекст("WScript.Sleep(5000)

     |

     |Dim FSO 

     |Set FSO = WScript.CreateObject(""Scripting.FileSystemObject"")

     |Set WshShell = WScript.CreateObject(""WScript.Shell"")

     |Set colEnvVars = WshShell.Environment(""Process"")

     |

     |strComputer = ""."" 

     |Set objWMIService = GetObject(""winmgmts:"" _ 

     |& ""{impersonationLevel=impersonate}!\\"" _ 

     |& strComputer & ""\root\cimv2"") 

     |

     |Set colProcesses = objWMIService.ExecQuery( _ 

     |""S_elect * From Win32_Process "" _ 

     |& ""Where Name = '1cv8.exe'"") 

     |

     |For Each objProcess In colProcesses 

     | objProcess.Terminate 

     |Next

     | 

     |WScript.Sleep(1000)

     | 

     |FolderName1 = ""\Local Settings\Application Data\1C\1Cv82""

     |FolderName2 = ""\Local Settings\Application Data\1C\1Cv81""

     |FolderName3 = ""\appdata\Local\1C\1Cv82""

     |FolderName4 = ""\appdata\Local\1C\1Cv81""

     | 

     |If FSO.FolderExists(colEnvVars(""userprofile"") & FolderName1) Then

     | GoSubFolders colEnvVars(""userprofile"") & FolderName1

     |End If

     |If FSO.FolderExists(colEnvVars(""userprofile"") & FolderName2) Then

     |GoSubFolders colEnvVars(""userprofile"") & FolderName2

     | End If

     |If FSO.FolderExists(colEnvVars(""userprofile"") & FolderName3) Then

     | GoSubFolders colEnvVars(""userprofile"") & FolderName3

     |End If

     |If FSO.FolderExists(colEnvVars(""userprofile"") & FolderName4) Then

     | GoSubFolders colEnvVars(""userprofile"") & FolderName4

     |End If

     |

     |" + КомандаЗапуска + "

     |Set WshShell = Nothing

     | 

     |Sub DelFile(sFILE)

     | On Error Resume Next

     | FSO.DeleteFile sFILE, True

     | If Err.Number <> 0 Then

     | Wscript.Echo ""Error deleting file: "" & sFILE

     | End If

     |End sub

     | 

     |Function GetFolder(sFOLDER)

     | On Error Resume Next

     | Set GetFolder = FSO.GetFolder(sFOLDER)

     | If Err.Number <> 0 Then

     | Wscript.Echo ""Error connecting to folder:"" & sFOLDER & VBlf & ""["" & Err.Number & ""]"" & Err.Description

     | Wscript.Quit Err.Number

     | End If

     |End Function

     | 

     |Sub GoSubFolders (objDIR)

     | ProcessFilesInFolder objDIR

     | Set sFolder = GetFolder(objDIR)

     | For Each eFolder in sFolder.SubFolders

     | GoSubFolders eFolder

     | Next

     | FSO.DeleteFolder sFolder, True

     |End Sub

     |

     |Sub ProcessFilesInFolder (objDIR)

     |Set sFolder = GetFolder(objDIR)

     |For Each objFile in sFolder.Files

     | DelFile objFile

     |Next

     |End Sub");



     Попытка

            СкриптФайл.Записать(ПутьКФайлуСкрипта, КодировкаТекста.Системная);

            ЗапуститьПриложение(ПутьКФайлуСкрипта);

     Исключение

     КонецПопытки;



КонецПроцедуры

Что хранится в C:\Documents and Settings\User\Application Data\1C\...

Категория: Администрирование

Функция разбора (разложения) строки в массив

Данные функции позволяют разложить строку в массив, используя заданный разделитель
Например есть строка: абв$dfd$232$-0oj$5
Выполнив код: НашМассив = РазложитьСтрокуВМассив(абв$dfd$232$-0oj$5, "$") ;
Получим: НашМассив = абв
dfd
232
-0oj
5

Код 1C v 8.х

 

// Функция "расщепляет" строку на подстроки, используя заданный 

//		разделитель. Разделитель может иметь любую длину. 

//		Если в качестве разделителя задан пробел, рядом стоящие пробелы 

//		считаются одним разделителем, а ведущие и хвостовые пробелы параметра Стр

//		игнорируются.

//		Например, 

//		РазложитьСтрокуВМассивПодстрок(",ку,,,му", ",") возвратит массив значений из пяти элементов, 

//		три из которых - пустые строки, а 

//		РазложитьСтрокуВМассивПодстрок(" ку   му", " ") возвратит массив значений из двух элементов

//

//	Параметры: 

//		Стр - строка, которую необходимо разложить на подстроки. 

//		Разделитель - 	строка-разделитель, по умолчанию - запятая.

//

//	Возвращаемое значение:

//		массив значений, элементы которого - подстроки

//

Функция РазложитьСтрокуВМассив(Знач Стр, Разделитель = ",") Экспорт

	

	МассивСтрок = Новый Массив();

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;

	

КонецФункции

Пример с использованием предустановленной библиотеки RegExp, т.е. она есть в любом windows.
Плюсы RegExp:
1. Хорошая скорость анализа, т.к. 1С анализ строк (разбор) обычно реализуется циклами и функциями: Лев, Прав, Сред, Найти, а встроенный язык медленный
2. Высокая читаемость и модифицированность (более предсказуем в случае несоответствия строки - разбору)
3. Дополнительный функционал (можно осуществлять анализ, замену и проверку строковых выражений)

Минусы RegExp:
1. Не все задачи можно решить (например рекурсивные разборы тип 1 + (2+3*(2-7)) в случае если нужно разобрать на выражения в скобках) приходится смешивать с кодом.
2. Возможность зависания при использовании сложных шаблонов(редкость, но бывает).
3. RegExp - это дополнительная библиотека и инициализация занимает значительное время.

Код 1C v 8.х

  // Пример с использованием предустановленной библиотеки RegExp, т.е. она есть в любом windows.

Функция РазложитьСтрокуВМассив(Строка, Разделитель = ",") Экспорт

	RegExp = Новый COMОбъект("VBScript.RegExp");    // создаем объект для работы с регулярными выражениями

	

	//Параметры:

	RegExp.MultiLine = Ложь;  // истина — текст многострочный, ложь — одна строка

	RegExp.Global = Истина;   // истина — поиск по всей строке, ложь — до первого совпадения

	RegExp.IgnoreCase = Ложь; // истина — игнорировать регистр строки при поиске

	

	//Разбор строки вида 1,СЛОВО,(1+2); Маска для разделителя ',' [^\,]*"

	RegExp.Pattern = "[^\" + Разделитель + "]+";

	Matches = RegExp.Execute (Строка);

	

	Массив = Новый Массив;

	

	Для Сч = 0 По Matches.Count - 1 Цикл

		Массив.Добавить(Matches.Item(Сч).Value);

	КонецЦикла;

	

	RegExp = Неопределено;

	

	Возврат Массив;

КонецФункции

Посмотрите Функцию разложить строку на подстроки (в список значений), используя заданный разделитель.

Категория: Работа с Текстом (Строкой)

Выгрузка результата запроса в текстовый файл с разделителями

Код 1C v 8.х

 Запрос = Новый Запрос();

Запрос.УстановитьПараметр("ДатаНач",НачалоДня(ДатаНач));

Запрос.УстановитьПараметр("ДатаКон",КонецДня(ДатаКон));

Запрос.УстановитьПараметр("Организация",Организация);

Запрос.Текст = "ВЫБРАТЬ

|	ПоступлениеТоваровУслугТовары.Номенклатура КАК Номенклатура,

|	ПоступлениеТоваровУслугТовары.Количество КАК Количество,

|	ПоступлениеТоваровУслугТовары.Цена КАК Цена,

|	ПоступлениеТоваровУслугТовары.Ссылка.Номер КАК Номер,

|	ПоступлениеТоваровУслугТовары.Ссылка.Дата КАК Дата,

|	ПоступлениеТоваровУслугТовары.Ссылка.Контрагент КАК Контрагент,

|	ПоступлениеТоваровУслугТовары.Номенклатура.Код КАК НоменклатураКод,

|	ПоступлениеТоваровУслугТовары.Номенклатура.Артикул КАК НоменклатураАртикул

|ИЗ

|	Документ.ПоступлениеТоваровУслуг.Товары КАК ПоступлениеТоваровУслугТовары

|ГДЕ

|	ПоступлениеТоваровУслугТовары.Ссылка.Дата МЕЖДУ &ДатаНач И &ДатаКон

|	И ПоступлениеТоваровУслугТовары.Ссылка.Организация = &Организация

|	

|УПОРЯДОЧИТЬ ПО	

|	Контрагент,

|	Номер,

|	Дата,

|	НоменклатураКод,

|	Номенклатура,

|	НоменклатураАртикул,

|	Количество,

|	Цена";	

Результат = Запрос.Выполнить().Выбрать();	

Текст = Новый ЗаписьТекста("c:\vigruz.txt", КодировкаТекста.ANSI);

РезультатДок = Запрос.Выполнить().Выбрать();	

Пока РезультатДок.Следующий() Цикл		

	ОбработкаПрерыванияПользователя();

	// В качестве разделителей необходимо использовать Символы. ВК (CR),ВТаб (VTab),НПП (NBSp),ПС (LF),ПФ (FF),Таб (Tab)

	

	//Если нам нужна строка вида " helpf.pro    07.08.2009   13 " в качестве разделителя используется табуляция

	//то пишем так:

	Текст.ЗаписатьСтроку(Строка(РезультатДок.Контрагент)+Символы.Таб+Строка(Формат((РезультатДок.Дата),"ДЛФ=D"))+Символы.Таб+Строка(РезультатДок.Номер));	

	// При загрузке строку можно будет разложить в массив для дальнейшей работы, РазложитьСтрокуВМассивПодстрок( ТекСтр, Символы.Таб). Ссылка на функцию ниже



	//Если нужен вид 

	// helpf.pro 

	// 07.08.2009

	// 13 

	// здесь в качестве разделителя используется перевод каретки (следующая строка), то пишем

	Текст.ЗаписатьСтроку(РезультатДок.Контрагент);

	Текст.ЗаписатьСтроку(Символы.ПС);	

	Текст.ЗаписатьСтроку(Формат((РезультатДок.Дата),"ДЛФ=D"));      

	Текст.ЗаписатьСтроку(Символы.ПС);	

	Текст.ЗаписатьСтроку(РезультатДок.Номер);          

	

КонецЦикла;		

Текст.Закрыть();

При загрузке для разбора строки используйте: Функция разбирает строку на подстроки, используя заданный разделитель и возвращает массив

Еще посмотрите пример: Загрузка данных из Текстового файла

Категория: Работа с Текстом (Строкой)

Пример загрузки данных из Текстового файла, документа

Файл для загрузки содержит данные вида(КодФизЛица, ФизЛицо, Сумма):
000000513~Петров Юрий Викторович~150
000000184~Иванов Александр Юрьевич~50

Код 1C v 8.х

 //Выбор файла

Режим = РежимДиалогаВыбораФайла.Открытие; 

ДиалогОткрытияФайла = Новый ДиалогВыбораФайла(Режим); 

ДиалогОткрытияФайла.ПолноеИмяФайла = ""; 

Фильтр = "Текст(*.txt)|*.txt"; 

ДиалогОткрытияФайла.Фильтр = Фильтр; 

ДиалогОткрытияФайла.МножественныйВыбор = Ложь; 

ДиалогОткрытияФайла.Заголовок = "Выберите файл для загрузки"; 

Если ДиалогОткрытияФайла.Выбрать() Тогда 

	ПутьКФайлу = ДиалогОткрытияФайла.ПолноеИмяФайла; 

КонецЕсли;	

//Выбор вида удержания пользователем

ВидУдерж=Неопределено;

МассивТипов = Новый Массив; 

МассивТипов.Добавить(Тип("ПланВидовРасчетаСсылка.УдержанияОрганизаций")); 

ОписаниеВозможныхТипов = Новый ОписаниеТипов(МассивТипов); 

Если ВвестиЗначение(ВидУдерж,"Выберите вид удержания", ОписаниеВозможныхТипов) Тогда

	Если Удержания.Количество()>0 тогда

		Предупреждение("Внимание! В таблице уже есть данные, новые данные Добавлены к существующим данным!");

	КонецЕсли;

	текдок=Новый ТекстовыйДокумент;

	текдок.Прочитать(ПутьКФайлу);

	Для Ном=1 по текдок.КоличествоСтрок() цикл

		Стр = текдок.ПолучитьСтроку(Ном);

		//Разложим строку в массив данных

		СтрМ=РазложитьСтрокуВМассивПодстрок(стр,"~");

		//Добавляем новую строку

		НовСтр=Удержания.Добавить();

		//Ищем Физика

		Физик = Справочники.ФизическиеЛица.НайтиПоКоду(СтрМ[0]);

		Если СокрЛП(Физик.Наименование) = СокрЛП(СтрМ[1]) тогда                                       

			НовСтр.Физлицо = Физик;

		Иначе 

			Сообщить("В справочнике Физ. Лиц не найден "+СтрМ[1],СтатусСообщения.ОченьВажное);

		КонецЕсли;

		НовСтр.ВидРасчета=ВидУдерж;

		НовСтр.ДатаНачала=РабочаяДата;

		НовСтр.ДатаОкончания=РабочаяДата;

		НовСтр.Показатель1=СтрМ[2];

		НовСтр.Результат=СтрМ[2];

	КонецЦикла;	

КонецЕсли;

Категория: Текстовый документ

Функция разбирает строку на подстроки, используя заданный разделитель и возвращает массив

Функция разбирает строку на подстроки, используя заданный разделитель. Разделитель может иметь любую длину.
Если в качестве разделителя задан пробел, рядом стоящие пробелы считаются одним разделителем, а ведущие и хвостовые пробелы параметра Стр игнорируются.

Например,
РазложитьСтрокуВМассивПодстрок(",ку,,,му", ",") возвратит массив значений из пяти элементов, три из которых - пустые строки, а РазложитьСтрокуВМассивПодстрок(" ку му", " ") возвратит массив значений из двух элементов
Параметры:
Стр - строка, которую необходимо разложить на подстроки.
Разделитель - строка-разделитель, по умолчанию - запятая.

Возвращаемое значение - массив значений, элементы которого - подстроки

Код 1C v 8.х

 Функция РазложитьСтрокуВМассивПодстрок(Знач Стр, Разделитель = ",") Экспорт

	МассивСтрок = Новый Массив();

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;	

КонецФункции

Категория: Работа с Текстом (Строкой)