&НаСервере

Процедура ЗаписатьСервер()

 

 пСеанс = ВнешниеИсточникиДанных.ВнешнийSQL.ПолучитьОбщиеПараметрыСоединения();

 

 Если НЕ пСеанс.СУБД = "MSSQLServer" Тогда

  Возврат;

 КонецЕсли;

 

 ЗапросSQL = ?(Объект.Ссылка.Пустая(), ПолучитьЗапросДобавления(), ПолучитьЗапросОбновления());

 

 Connection  = Новый COMОбъект("ADODB.Connection");

 Command  = Новый COMОбъект("ADODB.Command");

 RecordSet  = Новый COMОбъект("ADODB.RecordSet");

 

 //учетка и пароль уже в строке подключения

 //иначе их необходимо добавить в строку

 Попытка

  Connection.Open(СокрЛП(пСеанс.СтрокаСоединения));

  Command.ActiveConnection   = Connection;

  Command.CommandText = ЗапросSQL;

  RecordSet = Command.Execute();

 Исключение

  Сообщить(ОписаниеОшибки());

 КонецПопытки;  





КонецПроцедуры // ЗаписатьСервер()





&НаСервере

Функция ПолучитьЗапросОбновления()

 

 мДанные = Объект.Ссылка.Метаданные();

 СтрокаПоля = "";

 СтрокаДанные = "";

 

 ДанныеОбъект = Объект.Ссылка.ПолучитьОбъект();

 

 Для Каждого мПоле Из мДанные.Поля Цикл

  Если Объект[мПоле.Имя] = ДанныеОбъект[мПоле.Имя] Тогда

   Продолжить;

  КонецЕсли;

  СтрокаДанные = СтрокаДанные + ?(ПустаяСтрока(СтрокаДанные), " SET ", ", ") + мПоле.Имя + "= '" + Объект[мПоле.Имя] + "'";

 КонецЦикла;

 

 //делаем UDPDATE по id, поскольку оно у нас ключевое

 ЗапросSQL = "UPDATE " + мДанные.ИмяВИсточникеДанных + СтрокаДанные + "WHERE (id = '" + ДанныеОбъект.id + "')";

 

 Возврат ЗапросSQL; 

 

КонецФункции





&НаСервере

Функция ПолучитьЗапросДобавления()

 

 мДанные = Объект.Ссылка.Метаданные();

 СтрокаПоля = "";

 СтрокаДанные = "";

 

 Для Каждого мПоле Из мДанные.Поля Цикл

  СтрокаПоля = СтрокаПоля + ?(ПустаяСтрока(СтрокаПоля), " (", ", ") + мПоле.Имя;

  СтрокаДанные = СтрокаДанные + ?(ПустаяСтрока(СтрокаДанные), " VALUES (", ", ") + "'" + Объект[мПоле.Имя] + "'";

 КонецЦикла;

 

 СтрокаПоля = СтрокаПоля + ")";

 СтрокаДанные = СтрокаДанные + ")";

 ЗапросSQL = "INSERT INTO " + мДанные.ИмяВИсточникеДанных + СтрокаПоля + СтрокаДанные;

 

 Возврат ЗапросSQL; 

 

КонецФункции





&НаКлиенте

Процедура ЗаписатьДанные(Команда)

 

 ЗаписатьСервер();

 //делаем оповещение для списка, поскольку он автоматически не обновляется

 Оповестить("ОбновитьВнешнийИсточникДанных");

 

КонецПроцедуры   

 &НаКлиенте

Процедура Добавить(Команда)





 ОткрытьФорму("ВнешнийИсточникДанных.ВнешнийSQL.Таблица.dbo_assortment.ФормаОбъекта");

 

КонецПроцедуры





&НаКлиенте

Процедура ОбработкаОповещения(ИмяСобытия, Параметр, Источник)

 

 Если ИмяСобытия = "ОбновитьВнешнийИсточникДанных" Тогда

  Элементы.Список.Обновить();

 КонецЕсли;

 

КонецПроцедуры   

В этой статье я расскажу, как загружать данные в 1с 8 из простейших текстовых файлов с разделителями. Обычно они имеют расширение csv (Comma-Separated Values). Т. е. название подразумевает, что в каждой строке такого текстового файла значения разделены запятой. Но на самом деле, запятую, в качестве разделителя, использовать не надёжно. Поэтому применяют другие разделители, которые в обычном тексте встречаются редко. Это могут быть символы «^», «~»,«|» и другие. Итак, наша задача состоит в том, чтобы загрузить имеющуюся в csv файле информацию в базу данных 1с. Например, в файле будут содержаться товары интернет - магазина. В качестве образца, я взял выгрузку из магазина на скрипте virtuemart. Посмотрим, как выглядит файл.
Привожу две первых строки из него:

Код

~product_sku~^~category_path~^~product_name~^~product_desc~
~20~^~Книги/Электронные книги~^~Amazon Kindle 4 Touch~^~<p>Популярная электронная книга с ч/б экраном 6", электронной бумагой E-Ink Pearl, разрешением 600x800 пикс. с 16 - ю оттенками серого.</p>~

Посмотрим на файл.
Первая строка служебная. В ней описан формат нашего файла. Т. е. в какой ячейке, что находится. Однако, имейте в виду, что такой строки может и не быть.
Ячейки образуются при помощи разделителя «^», а данные в ячейках обрамляются символом «~».
В любой конфигурации 1с есть иерархический справочник товаров. В него и будем загружать информацию.
Создадим внешнюю обработку. Добавим строковый реквизит «путьКФайлуЗагрузки» для хранения имени файла. Добавим на форму поле ввода, связанное с данным реквизитом. Включим в свойствах поля ввода кнопку выбора и создадим обработчик события «НачалоВыбора» и напишем в нём такой код:

Код 1C v 8.х

 Процедура путьКФайлуЗагрузкиНачалоВыбора(Элемент, СтандартнаяОбработка)

	Режим = РежимДиалогаВыбораФайла.Открытие;

	ДиалогОткрытияФайла = Новый ДиалогВыбораФайла(Режим);

	ДиалогОткрытияФайла.ПолноеИмяФайла = "";

	Фильтр = "Comma separated file (*.csv)|*.csv";

	ДиалогОткрытияФайла.Фильтр = Фильтр;

	ДиалогОткрытияФайла.МножественныйВыбор = Ложь;

	ДиалогОткрытияФайла.Заголовок = "Выберите файл";

	

	Если ДиалогОткрытияФайла.Выбрать() Тогда

		путьКФайлуЗагрузки = ДиалогОткрытияФайла.ПолноеИмяФайла;

	КонецЕсли;

КонецПроцедуры   

Т. о. мы организовали диалог для выбора файла в нашей обработке.
Хорошо. Теперь, для удобства и наглядности я предлагаю создать временную табличку, в которую мы загрузим текстовый файл, а уже после её заполнения - будем осуществлять загрузку в базу 1с. Для этого, на форму добавим табличное поле «табЗагрузки», с типом значения «ТаблицаЗначений» и командной панелью. В панели поместим кнопку «Заполнить» и создадим обработчик её нажатия «КоманднаяПанель1Заполнить». Также для элемента универсальности, добавим в обработку два строковых реквизита «символОграничения» и «разделительПолей». В них мы будем хранить «^», и «~». Можно в теле модуля формы осуществить их начальную инициализацию:
разделительПолей = "^";
символОграничения = "~";
Это позволит пользователю задать свои значения и при желании сохранить настройку, которая впоследствии не затрется нашей инициализацией.

Код 1C v 8.х

 Процедура КоманднаяПанель1Заполнить(Кнопка)

	Если табЗагрузки.Количество() > 0 И Вопрос("Таблица будет очищена. Вы уверены?",РежимДиалогаВопрос.ДаНет) 

		= КодВозвратаДиалога.Нет Тогда

		Возврат;	

	КонецЕсли;

	ЗаполнитьТаблицу();

КонецПроцедуры

Процедура ЗаполнитьТаблицу()

	текст = Новый ТекстовыйДокумент;

	Попытка

		//обязательно устанавливаем кодировку, в которой наш файл

		текст.Прочитать(путьКФайлуЗагрузки,КодировкаТекста.UTF8);

	Исключение

		Сообщить("Не удалось прочитать файл: " 

			+ ОписаниеОшибки(),СтатусСообщения.ОченьВажное);

		Возврат;

	КонецПопытки;	

	табЗагрузки.Очистить();//очищаем таблицу

	табЗагрузки.Колонки.Очистить();//удаляем колонки, так как их состав мог измениться

	квоСтрок = текст.КоличествоСтрок();

	Если Не квоСтрок > 0 Тогда

		Сообщить("Файл пустой",СтатусСообщения.Внимание);

		Возврат;	

	КонецЕсли;

	//получаем первую строку с форматом файла

	стрТекста = текст.ПолучитьСтроку(1);

	//преобразуем строку в массив при помощи функции общего модуля, которая есть в типовых

	//ниже я дам её код, на случай, если нет

	масЗначСтр = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(стрТекста,разделительПолей);

	//добавляем две служебные колонки

	//для возможности отказаться от загрузки определенной строки

	табЗагрузки.Колонки.Добавить("не_загружать",Новый ОписаниеТипов("Булево"),"Не загружать");

	//для удобства вывода комментариев с указанием номера строки по ходу загрузки

	табЗагрузки.Колонки.Добавить("номер_строки",Новый ОписаниеТипов("Число",

		Новый КвалификаторыЧисла(10,0,ДопустимыйЗнак.Неотрицательный)),"Номер строки");

	//формируем колонки нашей таблицы	

	Для каждого зн Из масЗначСтр Цикл

		//убираем лишний символОграничения

		значение = СтрЗаменить(зн,символОграничения,""); 

		кол = табЗагрузки.Колонки.Добавить(значение,Новый ОписаниеТипов("Строка"));

	КонецЦикла;

	

	//создаём колонки в табличном поле

	ЭлементыФормы.табЗагрузки.СоздатьКолонки();

	

	//начиная со второй строки читаем строки файла, раскладывая их в массив

	Для номСтр = 2 По квоСтрок Цикл

		стрТекста = текст.ПолучитьСтроку(номСтр);

		масЗначСтр = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(стрТекста,разделительПолей);

		//добавляем новую строку в таблицу

		новСтр = табЗагрузки.Добавить();

		новСтр.номер_строки = номСтр;

		//начиная с третьей колонки производим установку значений в колонки

		номЗнач = 2;

		Для каждого зн Из масЗначСтр Цикл

			новСтр[номЗнач] = СтрЗаменить(зн,символОграничения,"");

			номЗнач = номЗнач + 1;

		КонецЦикла;

    КонецЦикла;

КонецПроцедуры   

Функцию разложения строки с разделителями в массив можно разместить как в одном из общих модулей, так и непосредственно в обработке.

Код 1C v 8.х

 Функция РазложитьСтрокуВМассивПодстрок(Знач Стр, Разделитель = ",") Экспорт

	МассивСтрок = Новый Массив();

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока Истина Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока Истина Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;

КонецФункции   

Отлично. В итоге, после заполнения, получим примерно такую картинку:


Теперь приступим непосредственно к загрузке товаров. Рядом с кнопкой «заполнить» добавим кнопку «загрузить» и добавим обработчик её нажатия «КоманднаяПанель1Загрузить», а также добавим реквизит «ПапкаЗагрузкиВыгрузкиТоваров» с типом вашего справочника товаров для опциональной их загрузки в определенную папку. Текст обработчика будет такой:

Код 1C v 8.х

 Процедура КоманднаяПанель1Загрузить(Кнопка)

	Если Вопрос("Вы уверены, что хотите загрузить файл?", РежимДиалогаВопрос.ДаНет) 

		= КодВозвратаДиалога.Нет Тогда

	    Возврат;	

	КонецЕсли;

	ВсегоСтрок = табЗагрузки.Количество();

	номСтр = 1;

	Для каждого стрТЗ Из табЗагрузки Цикл

		Состояние("Обработано: " + Окр(номСтр * 100 / ВсегоСтрок) + "%");

		номСтр = номСтр + 1;

		ОбработкаПрерыванияПользователя();

		//если пользователь установил не_загружать = Истина, пропускаем 

		Если стрТЗ.не_загружать Тогда

			Продолжить;		

		КонецЕсли;

		объект1С = вернутьТовар(стрТЗ);

		Если объект1С = Неопределено Тогда

			Возврат;			

		КонецЕсли;

		Если Не ЗаписатьЭлементСпр(объект1С) Тогда

			Сообщить("Загрузка прервана!",СтатусСообщения.ОченьВажное);

			Возврат;				

		КонецЕсли;	

		//помечаем запись, как загруженную

		стрТЗ.не_загружать = Истина;

	КонецЦикла;

КонецПроцедуры   

В приведенном коде две новые функции «вернутьТовар» и «ЗаписатьЭлементСпр». Вот их текст:

Код 1C v 8.х

 Функция вернутьТовар(стрТабФайла)

	Артикул = стрТабФайла.product_sku;

	Если Не ЗначениеЗаполнено(Артикул) Тогда

		Сообщить("В строке " + стрТабФайла.номер_строки + " не заполнен product_sku",

		СтатусСообщения.ОченьВажное);

		Возврат Неопределено;		

	КонецЕсли;

	Запрос = Новый Запрос("ВЫБРАТЬ

	|	Номенклатура.Ссылка

	|ИЗ

	|	Справочник.Номенклатура КАК Номенклатура

	|ГДЕ

	|	Номенклатура.Артикул = &Артикул");

	

	Запрос.УстановитьПараметр("Артикул",Артикул);

	

	Выборка = Запрос.Выполнить().Выбрать();

	Если Выборка.Следующий() Тогда

		Возврат Выборка.Ссылка.ПолучитьОбъект();			

	Иначе

		ЭтоНовый = Истина;

		объект1С = Справочники.Номенклатура.СоздатьЭлемент();

		объект1С.Артикул = Артикул;

		объект1С.Наименование = стрТабФайла.product_name;

		объект1С.Родитель = вернутьРодителяТовара(стрТабФайла.category_path);

		Возврат объект1С;

	КонецЕсли;

КонецФункции // вернутьТовар()

Функция ЗаписатьЭлементСпр(Спр)

	Попытка

		Спр.Записать();

	Исключение

		Сообщить("При записи элемента справочника " + Спр + " возникла ошибка: " + ОписаниеОшибки(),СтатусСообщения.ОченьВажное);

		Возврат Ложь;

	КонецПопытки;

	Возврат Истина;

КонецФункции // ЗаписатьЭлементСпр()   

И осталась последняя новая функция для обработки родителя товара вернутьРодителяТовара. Текст её смотрите ниже. Комментарии по тексту.

Код 1C v 8.х

 Функция вернутьРодителяТовара(стрКатегории)

	//главный родитель - заполненная в обработке папка

	Родитель = ПапкаЗагрузкиВыгрузкиТоваров;

	//строку категории раскладываем в массив используя разделитель /

	масРодителей = РазложитьСтрокуВМассивПодстрок(стрКатегории,"/");

	Для каждого Род Из масРодителей Цикл

		//если папку не находим, создаём и назначаем в качестве родителя 

		//следующей и т. д. В случае проблем выдаём прекращаем загрузку

		РодСс = Справочники.Номенклатура.НайтиПоНаименованию(Род,Истина);

		Если РодСс.Пустая() Тогда

			НовРод = Справочники.Номенклатура.СоздатьГруппу();

			НовРод.Наименование = Род;

			НовРод.Родитель = Родитель;

			Если Не ЗаписатьЭлементСпр(НовРод) Тогда

				Возврат Неопределено; 			

			КонецЕсли;

			Родитель = НовРод.Ссылка;

		Иначе

			Родитель = РодСс;

		КонецЕсли;		

	КонецЦикла;

	Возврат Родитель;

КонецФункции //   

Все. Конечно, в реальной жизни еще много чего нужно будет дописать, но не все сразу. Такой шаблон можно использовать как отправную точку. Скачивать файлы может только зарегистрированный пользователь!
Успехов в разработке!
Источник

Все достаточно просто.
Необходимо в запрос добавить поле:

Код 1C v 8.2 УП

 ПОДСТРОКА(&СтрокаПроценты, 1, ВЫРАЗИТЬ(ВложенныйЗапрос.Процент * &КоэффициентПроценты КАК ЧИСЛО(3, 0))) КАК ПроцентМикрографик   

Вывести его в динамический список.

И добавить в процедуре ПриСозданииНаСервере, какой шаблон мы хотим использовать для микрографика:

Код 1C v 8.2 УП

 &НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

    

    // Задать для каждого случая конкретно

    // В этой строке содержится шаблон для 100%

    // В реальной задаче можете изменить длинну, или заполнить другими символами

    СтрокаПроценты = "|||||||||||||||||||||||||||";	

    //СтрокаПроценты = "*************************";

    //СтрокаПроценты = "·························";

    //СтрокаПроценты = "•••••••••••••••••••••••••";

        

    // Считается автоматически

    ДлинаСтрокаПроценты = СтрДлина(СтрокаПроценты);

    КоэффициентПроценты	= ДлинаСтрокаПроценты / 100;

    ДинСписок.Параметры.УстановитьЗначениеПараметра("СтрокаПроценты", СтрокаПроценты);

    ДинСписок.Параметры.УстановитьЗначениеПараметра("КоэффициентПроценты", КоэффициентПроценты);

...   

Получим следующее:





Вот обработка, демонстрирующее все вышесказанное:

Скачивать файлы может только зарегистрированный пользователь!

www.softonit.ru

При организации выборок в реальных задачах в подавляющем большинстве случаев организуется отбор данных в соответствии с некоторыми критериями.

В случае, когда выборка делается из реальной таблицы, никаких сложностей не возникает. Данные обрабатываются абсолютно тривиально:

В том случае, когда источником в запросе выступает виртуальная таблица, ситуация становится несколько сложнее.

Язык запросов позволяет наложить условие на выборку из виртуальных таблиц двумя способами: в предложении ГДЕ и с помощью параметров виртуальных таблиц. Оба способа приведут к одному результату (за исключением некоторых специфических случаев), но, тем не менее, они далеко не эквиваленты.

Мы уже знаем, что виртуальные таблицы потому и называются виртуальными, что в базе их на самом деле нет. Формируются они только в тот момент, когда к ним обращается запрос. Несмотря на это, нам (то есть, тем, кто составляет запрос) удобно рассматривать виртуальные таблицы именно как реально существующие. Что же произойдёт в системе 1С Предприятие 8, когда составленный нами запрос всё-таки обратится к виртуальной таблице?

На первом шаге, система построит виртуальную таблицу. На втором шаге из полученной таблицы будут выбраны записи, удовлетворяющие условию, заданному в предложении ГДЕ:

Хорошо видно, что в итоговую выборку попадут не все записи из виртуальной таблицы (а, следовательно, и из базы данных), а только те, которые удовлетворяют заданному условию. А остальные записи просто будут исключены из результата.

Таким образом, система проделает не просто бесполезную, а двойную бесполезную работу! Сначала будут затрачены ресурсы на построение виртуальной таблицы на основе лишних данных (на рисунке они помечены как «области данных А и Б»), а потом ещё будет проделана работа по фильтрации этих данных из окончательного результата.

Нельзя ли сразу, на этапе построения виртуальной таблицы, отказаться от использования ненужных данных? Оказывается, можно. Именно для этого и предназначены параметры виртуальных таблиц:

Параметризируя виртуальную таблицу, мы сразу ограничиваем объём данных, который будет обрабатываться запросом.

---

В чем заключается различие значений параметра виртуальной таблицы "МетодДополнения"?
Когда МетодДополнения установлен в "движения", то будут выданы только те периоды в которых были движения. Когда установлен "ДвиженияИГраницыПериода", тогда к вышеуказанным движениям добавятся 2 записи: движения на начало и конец заданного в параметрах ВТ периода. Поле "Регистратор" при этом для этих 2-х записей будет пустым.

---

Данные, которые определяют логику функционирования системы на базе 1С:Предприятия, относятся к информационной базе. Хранение информационной базы осуществляется в базе данных с виде набора таблиц, для чего 1С:Предприятие 8.1 может использовать одну из четырех систем управления базами данных (СУБД):
* Встроенную в 1С:Предприятие 8.1 (файловый вариант информационной базы). В этом случае все данные информационной базы хранятся в файле с именем 1Cv8.1CD. Этот файл имеет двоичный формат и по сути является базой данных для встроенной в 1С:Предприятие 8.1 СУБД.
* Microsoft SQL Server (клиент-серверный вариант информационной базы). Все данные информационной базы хранятся в базе данных Microsoft SQL Server.
* PostgreSQL (клиент-серверный вариант информационной базы). Все данные информационной базы хранятся в базе данных PostgreSQL.
* IBM DB2 (клиент-серверный вариант информационной базы). Все данные информационной базы хранятся в базе данных IBM DB2.

На уровне объектов базы данных (таблиц, полей, индексов и т. п.) как файловый так и клиент-серверный вариант информационной базы имеют сходный формат (отличающийся несущественными деталями). Некоторая информация об этом формате содержится ниже.

Вся информационная база представляется в базе данных в виде набора таблиц. Среди них есть несколько таблиц, которые обязательно присутствуют в представлении любой информационной базы:

* Config - основная конфигурация информационной базы. Эта конфигурация соответствует реальной структуре данных и используется 1С:Предприятием 8.0 в режиме Предприятия.
* ConfigSave - конфигурация, редактируемая Конфигуратором. Конфигурация из ConfigSave переписывается в Config при выполнении "Обновления конфигурации базы данных" в Конфигураторе, а наоборот - при выполнении в Конфигураторе операции "Конфигурация - Конфигурация базы данных - Вернуться к конфигурации БД".
* Files содержит служебную информацию, например, о работе с хранилищем конфигурации.
* Params содержит параметры информационной базы. Среди них:
=> Список пользователей информационной базы.
=> Национальные настройки информационной базы.
=> Таблица соответствия объектов метаданных и объектов базы данных (таблиц, полей, индексов).
=> Некоторая другая информация.
* _YearOffset - смещение дат в базе данных. Эта таблица создается только при использовании Microsoft SQL Server.
* DBSchema содержит информацию о структуре базы данных 1С:Предприятия и определяет другие объекты базы данных, используемые данной информационной базой.

При старте 1С:Предприятие проверяет наличие в информационной базе перечисленных таблиц и в случае отсутствия какой-нибудь из них выдается сообщение "информационная база разрушена". Отсутствие всех перечисленных таблиц означает, что информационная база пустая. В последнем случае эти таблицы будут созданы.

Перечень и структура других таблиц базы данных определяется конкретной конфигурацией, а именно, определенными в ней объектами метаданных. Имя каждой таблицы состоит из буквенного префикса и следующего за ним номера. Префикс определяет назначение таблицы, а номер позволяет различать таблицы одинакового назначения, относящиеся к разным объектам метаданных. Если в качестве СУБД используется IBM DB2, то описанную структуру имеют не имена таблиц, а их псевдонимы.

Если в конфигурации определен хотя бы один план обмена с установленным флагом "Распределенная информационная база", то будут созданы следующие таблицы:

* _ConfigChangeRec - таблица регистрации изменений объектов конфигурации.
* _ConfigChangeRec_ExtProps - таблица имен файлов измененных внешних свойств объектов конфигурации.

Ниже перечислены различные объекты метаданных, которым могут соответствовать те или иные таблицы.

* Константы
=> _Consts содержит текущие значения всех констант, определенных в конфигурации.
=> _ConstsChangeRec - таблица регистрации изменений констант. Создается, если хотя бы одна константа участвует хотя бы в одном плане обмена.
* Планы обмена
=> _Node<n> - таблица плана обмена.
=> _Node<n>_VT<k> - табличная часть плана обмена, создается для каждой табличной части.
* Справочники
=> _Reference<n> - таблица справочника.
=> _Reference<n>_VT<k> - табличная часть справочника - для каждой табличной части.
=> _ReferenceChangeRec<n> - таблица регистрации изменений справочника. Создается, если справочник участвует хотя бы в одном плане обмена.
* Документы
=> _Document<n> - таблица документов для каждого объекта метаданных "документ".
=> _Document<n>_VT<k> - табличная часть документа - для каждой табличной части каждого документа.
=> _DocumentChangeRec<n> - таблица регистрации изменений объекта метаданных типа "документ". Создается для каждого объекта метаданных типа "документ", если он участвует хотя бы в одном плане обмена.
* Последовательности документов
=> _Sequence<n> - таблица регистрации документов - для каждой последовательности.
=> _SequenceBoundary<n> - таблица границ последовательности - для каждой последовательности.
=> _SequenceChangeRec<n> - таблица регистрации изменений последовательности. Создается для каждой последовательности, которая участвует хотя бы в одном плане обмена.
* Журналы документов.
=> _DocumentJournal<n> - таблица журнала документов, создается для каждого журнала документов.
* Перечисления
=> _Enum<n> - таблица перечисления - по одной для каждого перечисления.
* Планы видов характеристик
=> _Chrc<n> - основная таблица плана видов характеристик.
=> _Chrc<n>_VT<k> - табличная часть плана видов характеристик - для каждой табличной части.
=> _ChrcChangeRec<n> - таблица регистрации изменений плана видов характеристик. Создается, если план видов характеристик участвует хотя бы в одном плане обмена.
* Планы счетов
=> _Acc<n> - основная таблица плана счетов.
=> _Acc<n>_ExtDim<k> - таблица видов субконто плана счетов, создается для плана счетов в том случае, если максимальное количество субконто больше нуля.
=> _Acc<n>_VT<k> - табличная часть плана счетов, создается для каждой табличной части плана счетов.
=> _AccChangeRec<n> - таблица регистрации изменений плана счетов. Создается, если план счетов участвует хотя бы в одном плане обмена.
* Планы видов расчета
=> _CalcKind<n> - основная таблица плана видов расчета.
=> _CalcKind<n>_BaseCK - таблица базовых видов расчета, создается для плана видов расчета в случае, если его свойство "Зависимость от базы" имеет значение, отличное от "Не зависит".
=> _CalcKind<n>_DisplacedCK - таблица вытесняемых видов расчета, создается для плана видов расчета в случае, если у него установлен флаг "Использует период действия".
=> _CalcKind<n>_LeadingCK - таблица ведущих видов расчета - для каждого плана видов расчета.
=> _CalcKindDN<n> - вспомогательная таблица для порядка вытеснения, создается, если у плана видов расчета установлен флаг "Использует период действия".
=> _CalcKind<n>_VT<k> - табличная часть плана видов расчета, создается для каждой табличной части.
=> _CalcKindChangeRec<n> - таблица регистрации изменений плана видов расчета. Создается, если план видов расчета участвует хотя бы в одном плане обмена.
* Регистры сведений
=> _InfoReg<n> - таблица движений регистра сведений.
=> _InfoRegChangeRec<n> - таблица регистрации изменений регистра сведений. Создается, если регистр сведений участвует хотя бы в одном плане обмена.
* Регистры накопления
=> _AccumReg<n> - таблица движений регистра накопления.
=> _AccumRegTotals<n> - таблица итогов регистра накопления, если регистр поддерживает остатки.
=> _AccumRegTurnovers<n> - таблица оборотов регистра накопления, если регистр поддерживает обороты.
=> _AccumRegChangeRec<n> - таблица регистрации изменений регистра накопления. Создается, если регистр накопления участвует хотя бы в одном плане обмена.
=> _AccumRegOptions - таблица настроек хранения итогов регистров накопления одна на все регистры накопления.
* Регистры бухгалтерии
=> _AccntReg<n> - таблица движений регистра бухгалтерии.
=> _AccntRegED<n> - таблица значений субконто регистра бухгалтерии, создается в том случае, если он ссылается на план счетов, у которого максимальное количество субконто больше нуля.
=> _AccTtl0<n> - таблица итогов по счету.
=> _AccTtl<i><n> - где i от 1 до максимального количества субконто. Таблица итогов по счету с количеством видов субконто равным i.
=> _AccTtlC<n> - таблица итогов оборотов между счетами, только для регистра бухгалтерии поддерживающего корреспонденцию.
=> _AccntRegChangeRec<n> - таблица регистрации изменений регистра бухгалтерии. Создается, если регистр бухгалтерии участвует хотя бы в одном плане обмена.
=> _AccntRegOptions - таблица настроек хранения итогов одна на все регистры бухгалтерии.
* Регистры расчета
=> _CalcReg<n> - таблица движений регистра расчета.
=> _CalcRegActPer<n> - таблица фактических периодов действия для регистра расчета, создается, если у регистра расчета установлен флаг "Период действия".
=> _CalcRegChangeRec<n> - таблица регистрации изменений регистра расчета. Создается для каждого регистра расчета, участвующего хотя бы в одном плане обмена.
=> _CalcRegRecalc<n> - таблица перерасчета регистра расчета, создается для каждого перерасчета.
=> _CalcRegRecalcChangeRec<n> - таблица регистрации изменений перерасчета. Создается, если перерасчет участвует хотя бы в одном плане обмена.
* Бизнес-процессы
=> _BPRoutePoint<n> - таблица точек маршрута бизнес-процесса для каждого бизнес-процесса.
=> _BusinessProcess<n> - основная таблица бизнес-процесса.
=> _BusinessProcess<n>_VT<k> - табличная часть бизнес-процесса для каждой табличной части.
=> _BusinessProcessChangeRec<n> - таблица регистрации изменений бизнес-процесса. Создается для каждого бизнес-процесса, участвующего хотя бы в одном плане обмена.
* Задачи
=> _Task<n> - основная таблица задачи.
=> _Task<n>_VT<k> - табличная часть задачи для каждой табличной части.
=> _TaskChangeRec<n> - таблица регистрации изменений в задачах. Создается для каждого объекта метаданных типа "задача", который участвует хотя бы в одном плане обмена.

При использовании IBM DB2 префиксы псевдонимов таблиц начинаются не с символа подчеркивания, а сразу с буквенной части.

Количество этих таблиц зависит от функциональности конфигурации и может быть достаточно большим. В штатном режиме 1С:Предприятие не выполняет проверку их наличия, а также целостности и непротиворечивости содержащихся в них данных. Поэтому важно, чтобы база данных, в которой размещена информационная база 1С:Предприятия 8.1, была защищена от несанкционированного доступа и ее модификация выполнялась только средствами 1С:Предприятия. Для проверки необходимо использовать функцию "Администрирование - Тестирование и исправление", встроенную в конфигуратор.

Важно также, чтобы резервное копирование и восстановление базы данных, хранящей информационную базу, выполнялось только целиком. С этой целью рекомендуется использование средств резервного копирования баз данных, встроенных в в используемую СУБД. Резервное сохранение файлового варианта информационной базы может быть выполнено копированием файла 1Cv8.1CD.

В конфигураторе есть специальная функция: Администрирование - Выгрузить информационную базу. С ее помощью можно выгрузить в указанный файл (файл выгрузки) все данные, относящиеся к информационной базе, и больше никакие. Обратная ей функция "Загрузить информационную базу" позволяет в текущую информационную базу вместо существующих загрузить все данные из файла выгрузки. Эти функции также можно использовать для резервного копирования данных информационной базы как в файловом так и в клиент-серверном варианте.

---

Как просмотреть структуру таблиц информационной базы?