регистрбухгалтериинаборзаписей » Поиск

Результаты по ключевому слову: регистрбухгалтериинаборзаписей

РеквизитФормыВЗначение() и ДанныеФормыВзначение() - Описание и примеры использования

gvk2009 подробно и доходчиво описал разницу методов, за что ему огромное спасибо:

В Синтаксис-Помощнике очень скупо написано о процедуре ДанныеФормыВЗначение(), чуть побольше - о РеквизитФормыВЗначение(). И совсем нет примеров использования. Попробуем с этим разобраться.

РеквизитФормыВЗначение()

Является методом управляемой формы, компилируется только &НаСервере, контекст формы является для него необходимым, поэтому компиляция &НаСервереБезКонтекста недоступна. На клиенте не работает, поскольку в результате получаем прикладной объект.

Где и когда его нужно использовать?

Метод РеквизитФормыВЗначение() необходим, если требуется из модуля формы вызвать стандартный метод объекта или метод (процедуру, функцию) из модуля объекта, из общего модуля.

Этот метод будет отрабатывать с данными, взятыми из формы, т.е. еще не записанными в базу.

Для того, чтобы измененные данные вернуть на форму, используется метод ЗначениеВРеквизитФормы().

Вторым параметром метода РеквизитФормыВЗначение является тип значения. Это необязательный параметр. Если обрабатываемый реквизит не является составным типом, то тип будет автоматически получен из реквизита формы. Иначе генерируется исключение времени выполнения.

Примеры:

Код 1C v 8.2 УП

 // 1)

&НаСервере

Процедура ЗаполнитьТЧПоДаннымПоследнегоДокумента(Контрагент)

            ДокОбъект = РеквизитФормыВЗначение("Объект");

            ДокОбъект.ЗаполнитьТЧПоДаннымПоследнегоДокумента(Контрагент);

            ЗначениеВРеквизитФормы(ДокОбъект, "Объект");

КонецПроцедуры





// 2)

&НаСервере

Процедура ОчиститьСтрокиСПустойЦенойНаСервере()

	ДокОбъект = РеквизитФормыВЗначение("Объект");

	ДокОбъект.ОчиститьСтрокиСПустойЦеной();

	ЗначениеВРеквизитФормы(ДокОбъект, "Объект");

КонецПроцедуры



//3)

&НаСервере

Функция ОбъектЗаполнен()

	Возврат РеквизитФормыВЗначение("Объект").ПроверитьЗаполнение();

КонецФункции

В указанных выше случаях метод РеквизитФормыВЗначение() похож на метод ПолучитьОбъект(). Разница в том, что первый получает объект, заполненный данными формы, а второй - объект с данными из базы.

ДанныеФормыВзначение()

В отличие от метода управляемой формы РеквизитФормыВЗначение(), процедура глобального контекста ДанныеФормыВЗначение() может работать без контекста формы, но именно поэтому, в частности, ей необходимо указывать тип конвертируемых данных.

Обратной процедурой является ЗначениеВДанныеФормы().

Примеры:

Код 1C v 8.2 УП

 // 1)

    &НаСервере

       // Инициализация набора констант

       НаборКонстантОбъект = ДанныеФормыВЗначение(НаборКонстант, Тип("КонстантыНабор"));

       НаборКонстантОбъект.Прочитать();

       ЗначениеВДанныеФормы(НаборКонстантОбъект, НаборКонстант);



// 2)

   &НаСервере  

       НаборФорма = Объект.Движения.РегистрУправленческий;

       Набор = ДанныеФормыВЗначение(НаборФорма, Тип("РегистрБухгалтерииНаборЗаписей.РегистрУправленческий"));

       Если Набор.Количество()=0 Тогда

              Возврат;

       КонецЕсли; 

       Набор.УстановитьАктивность(НЕ Набор[0].Активность);

       ЗначениеВДанныеФормы(Набор, НаборФорма);

В этом примере на форме отображен набор записей регистра бухгалтерии. При отработке процедуры, активность набора меняется только на форме, в базе при этом ничего не происходит. Активность у набора записей регистра в базе поменяется только после выполнения операции Записать.

Код 1C v 8.2 УП

 // 3)

&НаКлиенте

Процедура Заполнить(Команда)

       ОснРеквизит = Объект;

       ВыполнитьНаСервереБезКонтекста(ОснРеквизит);

       КопироватьДанныеФормы(ОснРеквизит,Объект)

КонецПроцедуры



&НаСервереБезКонтекста

Процедура ВыполнитьНаСервереБезКонтекста(ОснРеквизит)

       ОбъектЗначение = ДанныеФормыВЗначение(ОснРеквизит, Тип("ДокументОбъект.АктСверкиВзаиморасчетов"));

       //...Выполнение операций с Объектом "ОбъектЗначение"

       ЗначениеВДанныеФормы(ОбъектЗначение, ОснРеквизит);

КонецПроцедуры

В этом примере на клиент возвращается ОснРеквизит, содержащий измененные данные. Но его еще нужно "запихать" в отображаемую форму. Для этого используем процедуру глобального контекста КопироватьДанныеФормы().

В большинстве случаев процедуры ДанныеФормыВзначение() и РеквизитФормыВЗначение() взаимозаменяемы. При этом РеквизитФормыВЗначение проще в использовании. Но если требуется использование &НаСервереБезКонтекста - тогда только ДанныеФормыВЗначение.

В качестве иллюстрации взаимозаменяемости Пример 2 еще в двух вариантах:

Код 1C v 8.2 УП

 // ВАРИАНТ 1

&НаКлиенте

Процедура Активность(Команда)



       ОснРеквизитДвижения = Объект.Движения.РегистрУправленческий;

       АктивностьНаСервереБезКонтекста(ОснРеквизитДвижения);

       КопироватьДанныеФормы(ОснРеквизитДвижения,Объект.Движения.РегистрУправленческий);



КонецПроцедуры // Активность()



&НаСервереБезКонтекста

Процедура АктивностьНаСервереБезКонтекста(ОснРеквизитДвижения)



       Набор = ДанныеФормыВЗначение(ОснРеквизитДвижения, Тип("РегистрБухгалтерииНаборЗаписей.РегистрУправленческий"));

       Если Набор.Количество()=0 Тогда

              Возврат;

       КонецЕсли; 

       Набор.УстановитьАктивность(НЕ Набор[0].Активность);

       ЗначениеВДанныеФормы(Набор, ОснРеквизитДвижения);



КонецПроцедуры // АктивностьНаСервереБезКонтекста()



// ВАРИАНТ 2

&НаСервере

Процедура АктивностьНаСервере()



       НаборФорма = РеквизитФормыВЗначение("Объект");

       Набор = НаборФорма.Движения.РегистрУправленческий;



       Если Набор.Количество()=0 Тогда

              Возврат;

       КонецЕсли; 



       Набор.УстановитьАктивность(НЕ Набор[0].Активность);

       ЗначениеВРеквизитФормы(НаборФорма, "Объект");



КонецПроцедуры // АктивностьНаСервере()

Категория: Управляемое приложение, Тонкий клиент

Планы обмена и их использование Категория: Конвертация данных, Обмен, Перенос