сайтов » Поиск

Результаты по ключевому слову: сайтов

Cодержимое указанного ниже веб-сайта в этом приложении блокируется... Aboutsecurity_1cv8c.exe

Проблема: После обновления на 1С:Бухгалтерию предприятия 3-й версии, при нажатии на закладку командного интерфейса 1С:предприятие, выскакивает ошибка:

Aboutsecurity_1cv8c.exe или Aboutsecurity_1cv8.exe

«Содержимое указанного ниже веб-узла в этом приложении блокировано конфигурацией усиленной безопасности Internet Explorer».

Ошибка исчезает после многократного нажатия на «Закрыть», что несколько мешает работать, мягко говоря. Похожая ошибка бывает и в конфигураторе, при обновлении конфигурации или сравнении/объединении конфигураций. Чаще всего, мне попадалась эта проблема в серверных ОС, в частности Windows 2008 r2.

Решение: нужно добавить исключение в настройках безопасности Internet Explorer (далее & IE).

Это делается просто, если у вас один или несколько компьютеров & просто открываете IE/Свойства обозревателя/Безопасность/Надёжные узлы/Сайты, добавляете Aboutsecurity_1cv8c.exe и Aboutsecurity_1cv8.exe, нажимаете Ок, и наслаждаетесь результатом.

Но вот если у вас терминал-сервер и 40/60 пользователей, или еще хуже & пользователей 150 и они ходят в SQL версию 1С с локальных рабочих станций, то бегать по всем корпусам и добавлять эту настройку весьма накладно по времени, да и отвлекать пользователей лишний раз от работы не порядочно.

В этом случае, нужно пользоваться групповыми политиками домена (который у вас должен быть настроен, если вы не офисный спортсмен-бегун).

Вариант №1. Неудавшийся.

Первое решение & прописать настройки через Group Polices (Административные шаблоны/Компоненты Windows/Internet explorer/Вкладка «Безопасность»/Список назначений зоны для веб-сайтов) & не увенчалось успехом. Настройки пользователей, как и обещалось в статьях по данному методу, перестали работать, а вот зоны, описанные в этих настройках, работать не начали. При этом, я пробовал добавлять настройки и в локальные политики, и в доменные и в политики контроллера домена. Скорее всего из-за этих экспериментов с разными зонами действия групповых политик и появилась проблема.

И так, после этих манипуляций, в настройках безопасности IE появилась надпись «Некоторыми параметрами управляет системный администратор» и добавлять/удалять сайты узлов безопасности стало невозможно. От этой надписи, почему-то, оказалось не так просто избавиться. Удаление проделанных настроек GPO не разблокировали вкладку «Безопасность», а манипуляции с реестром привели к появлению ошибок «В параметрах зоны есть ошибка. Не удалось добавить сайт.» (IE 10) или «При установке параметров безопасности зоны произошла ошибка. Добавить узел не удается.» (IE 9) & все дальнейшие действия сходили на нет.

Исправить косяк удалось следующим путём:

Обновил Internet Explorer до версии 10 (был 9-й).

Предварительно экспортировав разделы реестра в файл, на случай восстановления, удалил из следующие ключи:

[HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\CurrentVersion\InternetSettings

[HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings

[HKEY_CURRENT_USER\Software\Policies\Microsoft\Windows\CurrentVersion\Internet Settings]

Восстановил настройки Internet Explorer (Свойства обозревателя/Дополнительно/Сброс).

Проверить, что проблема не вернётся можно введя команду gpupdate /force в командной строке. После обновления политики запустите IE и проверьте, что настройки остались на месте. Если настройки опять слетели и добавление сайтов в узлы безопасности стало опять невозможно, то, скорее всего вы забыли отключить параметр «Список назначений зоны для веб-сайтов» в какой-то из зон групповой политики.

Чтобы определить в какой из зон групповых политик засела настройка (в локальных, доменных или контроллера домена), удобно пользоваться мастером отчётов «Результаты групповой политики», который находится в консоли «Диспетчер сервера», в разделе «Компоненты/Управление групповой политикой» (в Windows 2008 r2, по крайне мере он там).

Так что, здесь стоит быть осторожным, чтобы не создать себе дополнительной работы.

Вариант №2. Через GPO и реестр.

Этот метод делается через те же групповые политики, но через прямые записи в реестр, а не манипулирование стандартными настройками.

Что делать:

Удаляем узлы Aboutsecurity_1cv8 из настроек IE, если вы их туда уже добавили вручную & это нужно для чистоты эксперимента. Проверьте, что в 1С ошибка сохранилась.

Создаём файл 1csec.reg, с содержимым:

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\EscDomains\security_1cv8c.exe]

«about»=dword:00000002

Небольшая ремарка: подраздел EscDomains используется в режиме расширенной настройки безопасности, если же этот режим отключен по какой-то причине, то нужно использовать раздел Domains вместо EscDomains (подробнее о записях реестра IE см. в базе знаний Microsoft).

И пробуем добавить его в реестр & если срабатывает, и в тонком клиенте 1С ошибка Aboutsecurity_1cv8c.exe исчезает, делаем дальше.

Снова открываем Default Domain Policy в диспетчере управления сервером, далее Конфигурация пользователя/Настройка/Конфигурация Windows/Реестр.

Добавляем туда две записи, где поле «Путь раздела»:

в первой записи это «Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\EscDomains\security_1cv8c.exe» (для тонкого клиента 1С),

во второй записи «Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\EscDomains\security_1cv8.exe» (для толстого клиента).

В остальном запись содержит те же данные, что и на картинке.

После этого, как положено, перелогиниваемся и проверяем результат. В толстом и тонком клиенте 1С:предприятие, ошибка должна исчезнуть.

В моём случае, для надёжности избавления от проделанных в Варианте №2 настроек, были добавлены ещё три записи в реестр:

Обновить: HKCU\Software\Policies\Microsoft\Windows\CurrentVersion\Internet Settings; параметр: ListBox_Support_ZoneMapKey; значение 0 (тип DWORD десятичный)

Удалить: HKCU\Software\Policies\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap

Удалить: HKCU\Software\Policies\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMapKey

Вариант №3. Интерфейсный.

Есть ещё вариант, который переключит работу программы в режим интерфейса «Такси» : Администрирование/Настройки программы/Интерфейс & здесь включаем «Интерфейс «Такси»" & в этом режиме данная ошибка не появляется, но пользователям может не понравиться работать с этим вариантом интерфейса, т. к. он предназначен для мобильных устройств и планшетов (например, для работы через Web).

Источник

Категория: Администрирование

Веб браузер в 1С используя поле HTML документа Категория: Работа с Интернет, Почтой (Mail), FTP

Универсальный парсер RSS для 1С

На одном проекте - клиент попросил отображать в программе данные, которые выдаю специализированные сайта в формате RSS - Что делать !?

Писать парсер rss для 1С

Первым делом, взглянув на ссылки, подумал что - обычный XML, сейчас его разложу и быстренько загружу в базу, но:

Выяснилось что сайты имеют разные форматы ввода RSS и главное они не валидные(

таким образом, написав небольшой код, который получает ссылку, далее XMLФайл.Прочитать() на одном сайте проходил на ура (этот пример я описывал в статье: Чтение данных с сайта в формате XML и загрузка в 1С), а вот второй сайт, и третий тоже, при попытке прочитать() выдавали:

{ОбщийМодуль.РегЗадания.Модуль(79)}: Ошибка при вызове метода контекста (Прочитать)

Пока XMLФайл.Прочитать() Цикл

по причине:

Ошибка разбора XML: - [1,1]

Фатальная ошибка:

Extra content at the end of the document

SystemId url rss

решил попробовать на rss других известных сайтов - 80% из проверяемых выдавали ошибку

Пришлось написать прямой построчный парсер RSS:

Структура конфигурации

ИсточникиRSS - URL на RSS, ДанныеRSS - сюда записываются загруженные данные новостей

Код получился таким(в принципе код универсальный, но возможно что-то придется подпилить):

Код 1C v 8.3

 

// RSS

Процедура ПрочитатьRSS(ИсточникRSS)

	url = ИсточникRSS.UrlRSS;

	

	// Получим Сервер

	Если Найти(url,".ru")>0 Тогда urlСервер = Лев(url,Найти(url,".ru")+2);	

	ИначеЕсли Найти(url,".com")>0 Тогда urlСервер = Лев(url,Найти(url,".com")+3);

	ИначеЕсли Найти(url,".org")>0 Тогда urlСервер = Лев(url,Найти(url,".org")+3);

	ИначеЕсли Найти(url,".info")>0 Тогда urlСервер = Лев(url,Найти(url,".info")+4);

	ИначеЕсли Найти(url,".pro")>0 Тогда urlСервер = Лев(url,Найти(url,".pro")+3);

	КонецЕсли;	 		

		

	//Определим тип соединения

	Если Лев(url,5)="https" Тогда

		//ssl = Новый ЗащищенноеСоединениеOpenSSL(Новый СертификатКлиентаWindows(), Новый СертификатыУдостоверяющихЦентровWindows());   

		ssl = Новый ЗащищенноеСоединениеOpenSSL( неопределено, неопределено );

		ТекАдрес = СтрЗаменить(url,urlСервер,""); Сервер = СтрЗаменить(urlСервер,"https://",""); 

		Соединение = Новый HTTPСоединение(Сервер,,,,,

		5, // таймаут в секундах

		ssl // защищенное HTTPS соединение

		);

	Иначе //Обычный HTTP 		

		ТекАдрес = СтрЗаменить(url,urlСервер,""); Сервер = СтрЗаменить(urlСервер,"http://","");

		Соединение = Новый HTTPСоединение(Сервер);

	КонецЕсли;





	Заголовки = Новый Соответствие;

	Заголовки.Вставить("host", Сервер);  

	Запрос = Новый HTTPЗапрос(ТекАдрес, Заголовки);

	Ответ =Соединение.Получить(Запрос);

	Если Ответ.КодСостояния = 200 Тогда // Данные получены, обрабатываем их

		Содержимое= Ответ.ПолучитьТелоКакСтроку();

		//Преобразуем содержимое

		Содержимое = СтрЗаменить(Содержимое,"<br/>","|"); 

		Содержимое = СтрЗаменить(Содержимое,"<![CDATA[",""); Содержимое = СтрЗаменить(Содержимое,"]]>","");  

		Содержимое = СтрЗаменить(Содержимое,Символы.ПС,""); Содержимое = СтрЗаменить(Содержимое,Символы.ВК,""); 

		Содержимое = СтрЗаменить(Содержимое,Символы.ВТаб,""); Содержимое = СтрЗаменить(Содержимое,Символы.Таб,""); 

		Содержимое = СтрЗаменить(Содержимое,"><",">"+Символы.ПС+"<"); 

		

		RegExp = Новый COMОбъект("VBScript.RegExp"); //Регулярка

		RegExp.IgnoreCase = Ложь; 

		RegExp.Global = Истина;    

		RegExp.MultiLine = Истина;   		

		RegExp.Pattern = "<[^>]*>"; //Ищем теги HTML   

		

		//Разберем полученный текст в таблицу

		ЭтоЗапись=Ложь;

		Для н=1 По СтрЧислоСтрок(Содержимое)Цикл

			обрТекст=СтрПолучитьСтроку(Содержимое,н);

			

			Если обрТекст = "<item>" Тогда //Началась запись 

				ЗаписьСтр = Новый Структура(); ЭтоЗапись=Истина; Продолжить;  

			ИначеЕсли обрТекст = "</item>" Тогда //Закончилась запись 

				

				/////////////// ЗАПИСЬ Закончилась //////////////

				/// теперь запишем ее в базу - Справочник ДанныеRSS

				// сначала ПОИСК ДУБЛЕЙ - вдруг уже загружен 				

				Запрос = Новый Запрос;

				Запрос.Текст = 

				"ВЫБРАТЬ

				|	ДанныеRSS.Ссылка

				|ИЗ

				|	Справочник.ДанныеRSS КАК ДанныеRSS

				|ГДЕ

				|	ДанныеRSS.ИсточникRSS =ИсточникRSS

				|	И ДанныеRSS.link ПОДОБНОlink";

				

				Запрос.УстановитьПараметр("link", "%"+ЗаписьСтр.link+"%");

				Запрос.УстановитьПараметр("ИсточникRSS", ИсточникRSS);				

				РезультатЗапроса = Запрос.Выполнить().Выбрать();

				Если РезультатЗапроса.Следующий() Тогда

					// Такая запись уже есть, пока ничего не делаем

				Иначе

					//СОЗДАЕМ Новый

					НовЭлем  = Справочники.ДанныеRSS.СоздатьЭлемент();

					ЗаполнитьЗначенияСвойств(НовЭлем,ЗаписьСтр);

					НовЭлем.ИсточникRSS = ИсточникRSS;

					НовЭлем.Записать(); 					

				КонецЕсли; 				

				/////////////////////// *** /////////////////////

				

				ЭтоЗапись=Ложь; Продолжить; 

			КонецЕсли; //Данные записи

			

			Если ЭтоЗапись Тогда	

				Если Найти(обрТекст,"title>")>0 и Найти(обрТекст,"/title>")>0 Тогда				

					обрТекст = СтрЗаменить(обрТекст,"title",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					ЗаписьСтр.Вставить("Наименование",СокрЛП(обрТекст));

				КонецЕсли;

				

				Если Найти(обрТекст,"link>")>0 и Найти(обрТекст,"/link>")>0 Тогда				

					обрТекст = СтрЗаменить(обрТекст,"link",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					ЗаписьСтр.Вставить("link",СокрЛП(обрТекст));

				КонецЕсли;

				

				Если Найти(обрТекст,"description>")>0 и Найти(обрТекст,"/description>")>0 Тогда			

					обрТекст = СтрЗаменить(обрТекст,"description",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					обрТекст=RegExp.Replace(обрТекст, ""); //Удалим все теги

					ЗаписьСтр.Вставить("desc",СокрЛП(обрТекст));

				КонецЕсли;

				

				Если Найти(обрТекст,"pubDate>")>0 и Найти(обрТекст,"/pubDate>")>0 Тогда			

					обрТекст = СтрЗаменить(обрТекст,"pubDate",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					ЗаписьСтр.Вставить("pubDate",ПреобразоватьRFC822КДате0(СокрЛП(обрТекст)));

				КонецЕсли;

				

				Если Найти(обрТекст,"enclosure")>0 Тогда					 

					обрТекст = СтрЗаменить(обрТекст,"""",""); обрТекст = СтрЗаменить(обрТекст,"<enclosure url=","");

					обрТекст = СтрЗаменить(обрТекст,"<enclosure url=",""); обрТекст = СтрЗаменить(обрТекст,"type=image/png length=/>","");

					ЗаписьСтр.Вставить("img",СокрЛП(обрТекст));

				КонецЕсли;

			КонецЕсли;	

							

		КонецЦикла;

		

	КонецЕсли;

	

КонецПроцедуры	









Процедура ПроверкаRSS() Экспорт

	Запрос = Новый Запрос;

	Запрос.Текст = 

	"ВЫБРАТЬ

	|	ИсточникиRSS.Ссылка КАК Ссылка

	|ИЗ

	|	Справочник.ИсточникиRSS КАК ИсточникиRSS

	|ГДЕ

	|	ИсточникиRSS.Использовать

	|	И ДОБАВИТЬКДАТЕ(ИсточникиRSS.ДатаПоследнегоОбновления, СЕКУНДА, ИсточникиRSS.ПериодОбновленияВСекундах) <ТекДата"; 	

	Запрос.УстановитьПараметр("ТекДата", ТекущаяДата());

	РезультатЗапроса = Запрос.Выполнить();

	ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

	Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

		ПрочитатьRSS(ВыборкаДетальныеЗаписи.Ссылка);

		// Запишем дату последнего обновления

		ТекОб = ВыборкаДетальныеЗаписи.Ссылка.ПолучитьОбъект();

		ТекОб.ДатаПоследнегоОбновления = ТекущаяДата();

		ТекОб.Записать();

	КонецЦикла;

КонецПроцедуры



Функция ПреобразоватьRFC822КДате0(ДатаВФорматеRFC822) Экспорт

    КопияСтроки = ДатаВФорматеRFC822;

    СтруктураДаты = Новый Структура("Год,Месяц,День,Час,Минута,Секунда",  "","","","","","");

    Месяцы = Новый Структура("Jan,Feb,Mar,Apr,May,Jun,Jul,Aug,Sep,Oct,Nov,Dec",  "01","02","03","04","05","06","07","08","09","10","11","12");

    Для каждого КлючИЗначение Из Месяцы Цикл

        Позиция = Найти(КопияСтроки,КлючИЗначение.Ключ);

        Если Позиция > 0  Тогда

             СтруктураДаты.Месяц = КлючИЗначение.Значение;

            Прервать;

        КонецЕсли;

    КонецЦикла; 

	Состояние = 0;

	КопияСтроки = СтрЗаменить(КопияСтроки,", 1 ",", 01 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 2 ",", 02 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 3 ",", 03 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 4 ",", 04 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 5 ",", 05 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 6 ",", 06 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 7 ",", 07 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 8 ",", 08 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 9 ",", 09 ");

	Для ш=0 По СтрДлина(КопияСтроки) Цикл

        ТекущийСимвол = Сред(КопияСтроки,ш,1); //ПолучитьСимвол(КопияСтроки, ш);

        ТекСимволЦифра= ЭтоЦифра(ТекущийСимвол);

        Если ТекСимволЦифра И Состояние = 0  Тогда

            СтруктураДаты.День = СтруктураДаты.День + ТекущийСимвол;

            Состояние = 1; //начало день

        ИначеЕсли ТекСимволЦифра И Состояние = 1  Тогда

            СтруктураДаты.День = СтруктураДаты.День + ТекущийСимвол;

            Состояние = 2; //ждем год

        ИначеЕсли ТекСимволЦифра И Состояние = 2  Тогда

            СтруктураДаты.Год = СтруктураДаты.Год + ТекущийСимвол;

            Состояние = 3; //продолжаем год

        ИначеЕсли ТекСимволЦифра И Состояние = 3  Тогда

            СтруктураДаты.Год = СтруктураДаты.Год + ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = " " И Состояние = 3 Тогда

               Состояние = 4; //дальше час    

        ИначеЕсли ТекСимволЦифра И Состояние = 4  Тогда

            СтруктураДаты.Час = СтруктураДаты.Час + ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = ":" И Состояние = 4  Тогда

            Состояние = 5; //дальше минута

        ИначеЕсли ТекСимволЦифра И Состояние = 5  Тогда

            СтруктураДаты.Минута = СтруктураДаты.Минута +  ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = ":" И Состояние = 5  Тогда

            Состояние = 6; //дальше секунда

        ИначеЕсли ТекСимволЦифра И Состояние = 6  Тогда

            СтруктураДаты.Секунда = СтруктураДаты.Секунда +  ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = " " И Состояние = 6 Тогда

            Прервать;

        КонецЕсли;

    КонецЦикла;

    Попытка

        Результат = Дата(СтруктураДаты.Год+СтруктураДаты.Месяц+СтруктураДаты.День

                        +СтруктураДаты.Час+СтруктураДаты.Минута+СтруктураДаты.Секунда);

    Исключение

        Результат = Неопределено;    

    КонецПопытки;

    Возврат Результат;

КонецФункции



Функция ЭтоЦифра(Символ) Экспорт

     Если (КодСимвола(Символ)>=48) И (КодСимвола(Символ)<=57) Тогда Возврат Истина; Иначе Возврат ложь; КонецЕсли;

КонецФункции



Функция ПолучитьСимвол(КопияСтроки, ш)

	Возврат Сред(КопияСтроки,ш,1);

КонецФункции

Результат загрузки новостей RSS HelpF.pro

Кстати, как позже выяснилось, здесь уже есть статья с примером через IE и DOM: Получения новостей с RSS-канала сайта buh.ru

Категория: Работа с Интернет, Почтой (Mail), FTP

Как мы писали парсер сайта с ценами для 1С

Недавно, мой постоянный клиент решил проводить маркетинговые исследования по изменению цен на товары у конкурентов... и эти данные захотел использовать в 1С в связке с его прайс-листом + куча отчетов с графиками и процентным отклонением от цен основного конкурента

В результате этого, была написана обработка собирающая данные со страниц разных сайтов. Из целей конфиденциальности - сайты раскрывать не буду...

Вид обработки загрузки данных с сайта в 1С

Ниже код загрузки данных со страницы сайта, смысл такой :

в функция передается адрес страницы сайта
полученный текст страницы обрабатывается, удаляются теги
из полученного текста формируется ТЗ с данными
По названию ищется поставщик из вспомогательного справочника Справочники.Pr_Поставщики.НайтиПоНаименованию(, если нет - создается
на выходе ТЗ с данными

Код 1C v 8.х

 Функция ПолучитьТаблицуДанных(Строка)

	

	тзДанных = Новый ТаблицаЗначений;

	Сервер = "site.ru";

	

	Соединение = Новый HTTPСоединение(Сервер);			

	Заголовки = Новый Соответствие;

	Заголовки.Вставить("host", Сервер);

	ТекАдрес = СтрЗаменить(Строка.Наименование.УРЛСтраницы,"http://","");

	ТекАдрес = СтрЗаменить(ТекАдрес,Сервер,"");

	Запрос = Новый HTTPЗапрос(ТекАдрес, Заголовки);

	Ответ =Соединение.Получить(Запрос);

	Если Ответ.КодСостояния = 200 Тогда // Данные получены, обрабатываем их

		Содержимое= Ответ.ПолучитьТелоКакСтроку();

		//Выведем тест полученной страницы

		НачалоБлока = "<table id=" + """" + "table-price" + """" + " cellspacing=" + """" + "0" + """" + " border=" + """" + "1" + """" + " bordercolor=" + """" + "#dedede" + """" + " class=" + """" + "tablesorter" + """" + " >";

		//НачалоБлока = "<div class=" + """" + "w100fl" + """" + " id=" + """" + "kurs" + """" + ">";

		КонецБлока = "</table>";

		ТекстБлока = Сред(Содержимое, Найти(Содержимое, НачалоБлока) + СтрДлина(НачалоБлока), Найти(Содержимое, КонецБлока) - Найти(Содержимое, НачалоБлока) - СтрДлина(НачалоБлока));

		    				

		//Обработаем тест  				

		обрТекст = СтрЗаменить(ТекстБлока,"<tr>","");

		обрТекст = СтрЗаменить(обрТекст,"</tr>",Символы.ПС);

		обрТекст = СтрЗаменить(обрТекст," >", ">");

		обрТекст = СтрЗаменить(обрТекст,"</th> <th>", " | ");

		обрТекст = СтрЗаменить(обрТекст,"</td> <td>", " | ");

	   	обрТекст = СтрЗаменить(обрТекст,"</th> <th class=" + """" + "sortable_header" + """" + ">", " | ");

		обрТекст = СтрЗаменить(обрТекст,"</th> <th >", " | ");

		обрТекст = СтрЗаменить(обрТекст,"</th><th>", " | ");

		обрТекст = СтрЗаменить(обрТекст,"</td><td>", " | ");

		обрТекст = СтрЗаменить(обрТекст," >", ">");

		RegExp = Новый COMОбъект("VBScript.RegExp");

		RegExp.IgnoreCase = Ложь; 

		RegExp.Global = Истина;    

		RegExp.MultiLine = Истина;    

		

		RegExp.Pattern = "<[^>]*>"; //Ищем теги HTML   

		обрТекст=RegExp.Replace(обрТекст, "");

		//Сообщить(обрТекст);

		

		Если СокрЛП(обрТекст) = "Ни одной позиции не найдено." Тогда

			Сообщить(Строка(Строка.Наименование)+ " = Ни одной позиции не найдено! Строка " + Строка.Наименование);

			Возврат тзДанных;

		КонецЕсли;





		Если Найти(обрТекст, "Страница не найдена") > 0 Тогда

			Сообщить(Строка(ТекАдрес)+" = Страница не найдена, строка " + Строка.Наименование);

			Возврат тзДанных;  

		КонецЕсли;

		

		//Преобразуем полученный текст в таблицу

		Для н=1 По СтрЧислоСтрок(обрТекст)Цикл

			СтрТекста=СтрПолучитьСтроку(обрТекст,н);

			Если Найти(СтрТекста, "Длина Цена") > 0 Тогда

				СтрТекста = СтрЗаменить(СтрТекста, "Длина Цена", "Длина | Цена");

			КонецЕсли;

			Если Найти(СтрТекста, "Марка стали Цена") > 0 Тогда

				СтрТекста = СтрЗаменить(СтрТекста, "Марка стали Цена", "Марка стали | Цена");

			КонецЕсли;

			Если Найти(СтрТекста, ",  Поставщик") > 0 Тогда

				СтрТекста = СтрЗаменить(СтрТекста, ",  Поставщик", " | Поставщик");

			КонецЕсли;

			//Выводим текст страницы построчно

			мсДанных = ПолучитьМассивИзСтрокиСРазделителем(СтрТекста, "|", Истина);

			Если н=1 Тогда

				Для Каждого ткЗнач из мсДанных Цикл

					СтрЗапрещСимволов = " .,<>""\/-";

					ИмяКолонки = ткЗнач;

					Для сч33 = 1 по СтрДлина(СтрЗапрещСимволов) Цикл

						ЗапрещСимв = Сред(СтрЗапрещСимволов, сч33, 1);

						ИмяКолонки = СтрЗаменить(ИмяКолонки, ЗапрещСимв, "_");

					КонецЦикла;

					

					// добавим нужное количество колонок- если перед колонкой Поставщик не хватает

					// бывает, что в шапке определяется меньше колонок, чем реально в таблице

					Если НРег(ИмяКолонки) = "поставщик" Тогда

						Для Сч_дк = (Строка.Наименование.Родитель.Поставшик - 2) по тзДанных.Колонки.Количество() Цикл

							тзДанных.Колонки.Добавить("Колонка_" + (тзДанных.Колонки.Количество() + 1));

						КонецЦикла;

					КонецЕсли;

					

					тзДанных.Колонки.Добавить(ИмяКолонки);

				КонецЦикла;

				тзДанных.Колонки.Добавить("ном", , , 7);

			Иначе 

				НовСтр = тзДанных.Добавить(); нмас=0;

				Для Каждого ткЗнач из мсДанных Цикл

					НовСтр[нмас] = ткЗнач;

					нмас=нмас+1;

				КонецЦикла;

				НовСтр.ном = н;

			КонецЕсли;

			//Сообщить(стр);

		КонецЦикла;

		тзДанных.Колонки.Добавить("ЕстьСоответствие", Новый ОписаниеТипов("Булево"));

		тзДанных.Колонки.Добавить("СпрPr_Поставщики", Новый ОписаниеТипов("СправочникСсылка.Pr_Поставщики"));

		

		Для каждого стр из тзДанных Цикл

			текПоставщик = Справочники.Pr_Поставщики.НайтиПоНаименованию(стр[Строка.Наименование.родитель.Поставшик-1]);

			Если текПоставщик = Справочники.Pr_Поставщики.ПустаяСсылка() Тогда

				НовЭлем = Справочники.Pr_Поставщики.СоздатьЭлемент();

				НовЭлем.Наименование = СокрЛП(стр[Строка.Наименование.родитель.Поставшик-1]);

				НовЭлем.Записать();

				текПоставщик = НовЭлем.Ссылка;

			КонецЕсли;

			стр.СпрPr_Поставщики = текПоставщик;

		КонецЦикла;

	Иначе

		тзДанных.Колонки.Добавить("ЕстьСоответствие", Новый ОписаниеТипов("Булево"));

		тзДанных.Колонки.Добавить("СпрPr_Поставщики", Новый ОписаниеТипов("СправочникСсылка.Pr_Поставщики"));

		

		Сообщить("Ошибка получения данных для строки " + Строка.Наименование);

	КонецЕсли;

	

	Возврат тзДанных;

	

КонецФункции

В коде используется вспомогательная функция ПолучитьМассивИзСтрокиСРазделителем

Код 1C v 8.2 УП

 // Функция разбивает строку разделителем.

// 

// Параметры:

//  пСтрока      - Строка - которую разбиваем;

//  *пРазделитель - Строка, "." - символ-разделитель;

//  *ОбрезатьНепечатныеСимволы - Булево, *Ложь.

//

// Возвращаемое значение:

//  Массив - фрагментов.

//

Функция ПолучитьМассивИзСтрокиСРазделителем(Знач Стр, Разделитель = ".", ОбрезатьНепечатныеСимволы = Ложь) Экспорт

	

	МассивСтрок = Новый Массив;

	

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				Фрагмент = Стр;

				Если ОбрезатьНепечатныеСимволы Тогда

					Фрагмент = СокрЛП(Фрагмент);

				КонецЕсли;

				МассивСтрок.Добавить(Фрагмент);

				Возврат МассивСтрок;

			КонецЕсли;

			Фрагмент = Лев(Стр,Поз-1);

			Если ОбрезатьНепечатныеСимволы Тогда

				Фрагмент = СокрЛП(Фрагмент);

			КонецЕсли;

			МассивСтрок.Добавить(Фрагмент);

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;





	Возврат МассивСтрок;

		

КонецФункции // ПолучитьМассивИзСтрокиСРазделителем()

Конечно, перед тем как мы начали это делать - прошерстили интернет и нашли несколько решений , вот они:

Код 1C v 8.х

 Соединение = ПолучитьCOMОбъект("","Microsoft.XMLHTTP");

ИмяВременногоФайла=ПолучитьИмяВременногоФайла("htm");



Соединение.open("GET", "http://mamba.ru/my", 0);

Соединение.send();



//status: //404 - Not Found //200 - Ok

ТаймАут = 200;

Начало=ТекущаяДата();

Пока Соединение.readyState <> 4 И (ТаймАут=0 ИЛИ ТекущаяДата()-Начало<ТаймАут) Цикл

бфДиалоги.ксОбработкаПрерыванияПользователя();

КонецЦикла;



//Сохраняем во временный файл

обСохранитьДвоичныйБуферВФайл(Соединение.responseBody, ИмяВременногоФайла);



Соединение.open("POST", "http://mamba.ru/my");

Соединение.send("login=xxx&password=&&&");





Функция обСохранитьДвоичныйБуферВФайл(Буфер, ИмяФайла) Экспорт

    Поток = Новый COMОбъект("ADODB.Stream");

    Поток.Type = 1;  //Бинарный

       Поток.Mode = 3; 

    Поток.Open();

    Поток.Write(Буфер);

    Поток.SaveToFile(ИмяФайла);

    Поток.Close();

КонецФункции

Код 1C v 8.х

     НТТР = ПолучитьCOMОбъект("","Microsoft.XMLHTTP");

    ИмяФайлаОтвета = КаталогВременныхФайлов() + "filename.tmp";           

    НТТР.open("GET", "www.google.com",0,,); 

    НТТР.send();

    StreamTypeEnum = Новый Структура("adTypeBinary, adTypeText", 1, 2);

    ConnectModeEnum = Новый Структура(

            "adModeRead, adModeReadWrite, adModeRecursive, adModeShareDenyNone,

            |adModeShareDenyRead, adModeShareDenyWrite, adModeShareExclusive, 

            |adModeUnknown, adModeWrite", 1, 3, 4194304, 16, 4, 8, 12, 0, 2);

    SaveOptionsEnum = Новый Структура("adSaveCreateNotExist, adSaveCreateOverWrite", 1, 2);

    StreamOut = Новый COMОбъект("ADODB.Stream");

    StreamOut.Type = StreamTypeEnum.adTypeBinary;

    StreamOut.Mode = ConnectModeEnum.adModeReadWrite; //Нужны и чтение и запись   

    StreamOut.Open(); //Открыли на чтение и запись

    StreamOut.Write(НТТР.responseBody); 

    StreamOut.SaveToFile(ИмяФайлаОтвета, SaveOptionsEnum.adSaveCreateOverWrite); //"2" - перезапись файла

    StreamOut.Close();

И даже не этом сайте есть статья : Парсер сайта связного на 1С

Нужен парсер сайта в 1С!? - Обращайтесь, контакты в профиле

Категория: Работа с Интернет, Почтой (Mail), FTP

Как обработать файлы с разделителями, изменив их структуру и сохранив в кодировке UTF8 без BOM

Частенько при разработке сайтов приходится обрабатывать тысячи однотипных файлов... чтобы оптимизировать эту рутинную работу я набросал небольшую обработку, которая перебирает в указанном каталоге все файлы с расширением w1c и полностью меняет структуру данного файла, сохраняя его в кодировке UTF8 без BOM сигнатуры

Код обработки файлов:

Код 1C v 8.3

 &НаКлиенте

Процедура КомандаОбрW1C(Команда)

	Режим = РежимДиалогаВыбораФайла.ВыборКаталога; 

	ДиалогОткрытия = Новый ДиалогВыбораФайла(Режим); 

	ДиалогОткрытия.Каталог = ""; 

	ДиалогОткрытия.МножественныйВыбор = Ложь; 

	ДиалогОткрытия.Заголовок = "Выберите каталог с Файлами"; 

	Если ДиалогОткрытия.Выбрать() Тогда 

		ПутьККаталогу = ДиалогОткрытия.Каталог; 	

		

		ВыбранКаталог = НайтиФайлы(ПутьККаталогу, "*.*");

		Для каждого НайденныйФайл Из ВыбранКаталог Цикл

			Если НайденныйФайл.ЭтоКаталог() Тогда //Каталог

				//каталоги пока не трогаем

			ИначеЕсли НайденныйФайл.Расширение=".w1c" Тогда // Файл для обработки				

				Сообщить(НайденныйФайл.ПолноеИмя);

				ОбработатьФайл(НайденныйФайл.ПолноеИмя);

			КонецЕсли; 

		КонецЦикла;

	КонецЕсли; 	    

	

КонецПроцедуры  





&НаКлиенте

Процедура ОбработатьФайл(ТекФайл)

	//Прочитаем текст файла

	ОбрФайл = Новый ТекстовыйДокумент;

	ОбрФайл.Прочитать(ТекФайл,"UTF-8");

	врТекст = ОбрФайл.ПолучитьТекст();

	врМассив = РазложитьСтрокуВМассив(врТекст,"<&w1c&>");

	/// Переформируем структуру файла

	новТекст = СокрЛП(врМассив[0])+"<&w1c&>"; 

	новТекст = новТекст + СокрЛП(врМассив[1])+"<&w1c&>"+"1<&w1c&>"; 

	//Получим атрибуты файла

	АтрибутыФайла = Новый Файл(ТекФайл);

	новТекст = новТекст + Формат(АтрибутыФайла.ПолучитьВремяИзменения(),"ДФ=dd/MM/yyyy")+"<&w1c&>";

	новТекст = новТекст + СокрЛП(врМассив[2])+"<&w1c&>"; 

	новТекст = новТекст + СокрЛП(врМассив[3])+"<&w1c&>"; 

	новТекст = новТекст + СокрЛП(врМассив[4])+"<&w1c&>"; 

	новТекст = новТекст + СокрЛП(врМассив[5])+"<&w1c&>"; 

	новТекст = новТекст + "no-mods<&w1c&>"; 

	новТекст = новТекст + СокрЛП(врМассив[6])+"<&w1c&>";

	новТекст = новТекст + СокрЛП(врМассив[7]);

	// Запишем в тот же файл

	ОбрФайл.Очистить();

	ОбрФайл.УстановитьТекст(новТекст);

	ОбрФайл.Записать(ТекФайл,"UTF-8");

	

	//Но нужно получить файл UTF8 без сигнатуры BOM

	 Данные = Новый ДвоичныеДанные(ТекФайл);

    Строка64=Base64Строка(Данные);

    Строка64=Прав(Строка64,СтрДлина(Строка64)-4);

    ДанныеНаЗапись=Base64Значение(Строка64);

    ДанныеНаЗапись.Записать(ТекФайл); // записываем

КонецПроцедуры



//// Вспомогательное

&НаКлиенте

Функция РазложитьСтрокуВМассив(Знач Стр, Разделитель = ",") Экспорт 	

	МассивСтрок = Новый Массив();

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;   	

КонецФункции

Внешний вид обработки получился таким:

Обработка написана для Web-Студии W1C : Первый Веб-Консультант

Категория: Текстовый документ

Парсер сайта на 1С Категория: Работа с Интернет, Почтой (Mail), FTP

Настройка веб-браузеров для работы в веб-клиенте 8.2 Категория: Администрирование