Как известно делать проводки по счетам-группам нельзя. Однако жизнь течет и после введения бухгалтером очередного нового счета какой либо старый, который ранее не являлся счетом-группы, теперь становится групповым. И соответственно все проводки на этот счет становятся ошибочными. Для предупреждения подобной ситуации целесообразно перед записью данных по счетам имеет смысл всегда проверять счета на предмет группы. Один из возможных вариантов такой проверки привожу ниже:

 



Процедура ПриЗаписи(Отказ, РежимЗаписи)

      

    Запрос = Новый Запрос;

    Запрос.Текст = 

        "ВЫБРАТЬ

        |	Хозрасчетный.Код КАК Код,

        |   Хозрасчетный.Родитель.Код КАК РодительКод

        |ИЗ

        |ПланСчетов.Хозрасчетный КАК Хозрасчетный

        |ГДЕ

	    |Хозрасчетный.Родитель В (&СчетДт,СчетКт)";

    

    СчетДт = ЭтотОбъект[0].СчетДт;

    СчетКт = ЭтотОбъект[0].СчетКт;

    

    Запрос.УстановитьПараметр("СчетДт", СчетДт);

    Запрос.УстановитьПараметр("СчетКт", СчетКт);

    

    РезультатЗапроса = Запрос.Выполнить();

    

    Если НЕ РезультатЗапроса.Пустой() Тогда

        

        ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

        

        Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

            Если СтрНайти(ВыборкаДетальныеЗаписи.Код, ".") Тогда

                Отказ = Истина; 

                Сообщить("Некорретный номер счета - " + ВыборкаДетальныеЗаписи.РодительКод);   	

            КонецЕсли;		

        КонецЦикла;

    КонецЕсли;

КонецПроцедуры





   

Любой отчет и обработку можно подключить пользователям как дополнительные отчеты или обработки, вот например пункт в БП - Банк:

Добавление происходит через

далее Дополнительные отчеты и обработки, в списке нажмите Создать и Выберите Файл отчета/обработки:

Перед добавлением файл нужно подготовить, дописать в модуль объекта код подключения:

Для обработок код:

 Функция СведенияОВнешнейОбработке() Экспорт

	

	ПараметрыРегистрации = Новый Структура;

	

	//Вид

	//Строка, вид обработки, один из возможных: 

	//"ДополнительнаяОбработка", "ДополнительныйОтчет", "ЗаполнениеОбъекта", "Отчет", "ПечатнаяФорма", "СозданиеСвязанныхОбъектов" 

	ПараметрыРегистрации.Вставить("Вид", "ДополнительнаяОбработка");

	

	//Массив строк имен объектов метаданных в формате: 

	//<ИмяКлассаОбъектаМетаданного>.[ * | <ИмяОбъектаМетаданных>]. 

	//Например, "Документ.СчетЗаказ" или "Справочник.*". 

	//Прим. параметр имеет смысл только для назначаемых обработок, для глобальных может не задаваться. 

	ПараметрыРегистрации.Вставить("Назначение", Новый СписокЗначений);

	

	//Наименование обработки, которым будет заполнено наименование элемента справочника по умолчанию - краткая строка для идентификации обработки администратором 

	ПараметрыРегистрации.Вставить("Наименование", "Сравнение документов БУХ и УТ");

	

	//Версия обработки в формате “<старший номер>.<младший номер>” используется при загрузке обработок в информационную базу. Например “. 

	ПараметрыРегистрации.Вставить("Версия", "1.0");

	

	//Принимает значение Истина или Ложь, в зависимости от того, требуется ли устанавливать или отключать безопасный режим исполнения обработок. Если истина, обработка будет запущена в безопасном режиме. Более подбробно о безопасном режиме в справке к платформе 1С:Предприятие. 

	ПараметрыРегистрации.Вставить("БезопасныйРежим", Истина);

	

	//Краткая информация по обработке, описание обработки. 

	ПараметрыРегистрации.Вставить("Информация", "");

	

	//Команды, поставляемые обработкой. Таблица значений с колонками: 

	ПараметрыРегистрации.Вставить("Команды", Новый СписокЗначений);

		

	ТаблицаКоманд = ПолучитьТаблицу_Команд();





  	ДобавитьКоманду(ТаблицаКоманд,

          "Сравнение документов БУХ и УТ", 	//Представление

          "Сравнение документов БУХ и УТ",	//Идентификатор

          "ОткрытиеФормы", 				//Использование

          Ложь,					 		//ПоказыватьОповещение

          "");			 				//Модификатор





  	ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);

	

	Возврат ПараметрыРегистрации;

	

КонецФункции





Функция ПолучитьТаблицу_Команд()





  Команды = Новый ТаблицаЗначений;

  

  //Представление – представление команды в пользовательском интерфейсе;

  Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));

  

  //Идентификатор – идентификатор команды; 

  //любая строка, уникальная в пределах данной обработки (отчета). 

  //В случае с обработками печатных форм на основе макета табличного документа передается список макетов, 

  //на основе которых нужно получить печатную форму 

  //(см. описание параметра ИменаМакетов процедуры УправлениеПечатьюКлиент.ВыполнитьКомандуПечати в разделе Печать). 

  Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));

  

  //"ОткрытиеФормы" – открыть форму обработки; 

  //"ВызовКлиентскогоМетода" – вызвать клиентскую экспортную процедуру из модуля формы обработки; 

  //"ВызовСерверногоМетода" – вызвать серверную экспортную процедуру из модуля объекта обработки.

  Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));

 	

  //ПоказыватьОповещение – если Истина, требуется показать оповещение при начале и при завершении работы обработки. 

  //Имеет смысл только при запуске обработки без открытия формы. 

  Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));

  

  //Модификатор – дополнительный модификатор команды. 

  //Используется для дополнительных обработок печатных форм на основе табличных макетов, 

  //для таких команд должен содержать строку ПечатьMXL (см. пример в демонстрационной конфигурации).

  Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));

  

  Возврат Команды;

           

КонецФункции





Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = "")





  НоваяКоманда = ТаблицаКоманд.Добавить();

  НоваяКоманда.Представление = Представление;

  НоваяКоманда.Идентификатор = Идентификатор;

  НоваяКоманда.Использование = Использование;

  НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;

  НоваяКоманда.Модификатор = Модификатор;



КонецПроцедуры   

Для отчетов и печатных форм меняйте параметр Вид:

 //"ДополнительнаяОбработка", "ДополнительныйОтчет", "ЗаполнениеОбъекта", "Отчет", "ПечатнаяФорма", "СозданиеСвязанныхОбъектов" 

	ПараметрыРегистрации.Вставить("Вид", "ДополнительнаяОбработка");

   

Возможные значения этого поля приведу в виде таблицы

Расширение

файла

Это поле может принимать одно из значений, возвращаемых функциями в типовых конфигурациях:

 ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработки<Вид>(). Например, для вида "ПечатнаяФорма" есть функция ВидОбработкиПечатнаяФорма(). 

Заказали виртуальный сервер на FastVPS, купили мини сервер 1С и пришло время установки.

В сети нашлась хорошая статья, где все по порядку:

Итак, устанавливаем минимальный CentOS, настраиваем имена хостов, DNSы и сетевые подключения и приступаем собственно к установке серверных компонентов.

1. Установка Postgre SQL server

Обновление от 03-ноя-2016: в последних версиях CentOS (у меня сегодня был 7.2.1511) отсутствует поддержка libtermcap (и как-то "иначе" реализована libreadline), из-за чего сборки с сайта 1С не устанавливаются - решил поставить сборку от Postgres Professionals https://postgrespro.ru/products/1c_build - вроде работает, но о стабильности и производительности пока судить рано. Так что у кого проблемы с libtermcap.so.2() и/ли libreadline.so.5() при установке PostgreSQL с патчами 1С, можете попробовать этот альтернативный вариант.

Для установки использовался рекомендованный (адаптированный) 1С дистрибутив, для чего потребуется скачать его из раздела поддержки пользователей сайта 1С. В моём случае это был "Дистрибутив СУБД PostgreSQL для Linux x86 (64-bit) одним архивом (RPM)", который я сохранил в /root/temp. Распаковываем архив:

[root@vm-sql01 temp]# tar -vxf postgresql-9.2.1-1.1C_x86_64_rpm.tar.gz

postgresql92-9.2.1-1.1C.x86_64.rpm

postgresql92-libs-9.2.1-1.1C.x86_64.rpm

postgresql92-server-9.2.1-1.1C.x86_64.rpm

postgresql92-contrib-9.2.1-1.1C.x86_64.rpm

[root@vm-sql01 temp]#

Устанавливаем в следующей последовательности:

yum install postgresql92-libs-9.2.1-1.1C.x86_64.rpm

yum install postgresql92-9.2.1-1.1C.x86_64.rpm

yum install postgresql92-server-9.2.1-1.1C.x86_64.rpm

yum install postgresql92-contrib-9.2.1-1.1C.x86_64.rpm

Все недостающие зависимости (пакеты) будут установлены в процессе установки этих rpm, хотя на сайте 1С рекомендуют предварительно установить пакеты readline, libtermcap, krb5-libs и openssl, но в моём случае они либо уже были установлены, либо не были обнаружены в репозиториях.

2. Первый запуск Postgre SQL server

В отличии от сценариев установки большинства знакомых мне sql-серверов, postgres требует предварительной инициализации перед запуском, для чего существует два пути - первый, правильный:

[root@vm-sql01 pgsql]# su postgres -c '/usr/pgsql-9.2/bin/initdb -D /var/lib/pgsql/9.2/data --locale=ru_RU.UTF-8'

Файлы, относящиеся к этой СУБД, будут принадлежать пользователю "postgres".

От его имени также будет запускаться процесс сервера.

Кластер баз данных будет инициализирован с локалью "ru_RU.UTF-8".

Кодировка БД по умолчанию, выбранная в соответствии с настройками: "UTF8".

Выбрана конфигурация текстового поиска по умолчанию "russian".

исправление прав для существующего каталога /var/lib/pgsql/9.2/data... ок

создание подкаталогов... ок

выбирается значение max_connections... 100

выбирается значение shared_buffers... 32MB

создание конфигурационных файлов... ок

создание базы template1 в /var/lib/pgsql/9.2/data/base/1... ок

инициализация pg_authid... ок

инициализация зависимостей... ок

создание системных представлений... ок

загрузка описаний системных объектов... ок

создание правил сортировки... ок

создание преобразований... ок

создание словарей... ок

установка прав для встроенных объектов... ок

создание информационной схемы... ок

загрузка серверного языка PL/pgSQL... ок

очистка базы данных template1... ок

копирование template1 в template0... ок

копирование template1 в postgres... ок

ВНИМАНИЕ: используется проверка подлинности "trust" для локальных подключений.

Другой метод можно выбрать, отредактировав pg_hba.conf или используя ключи -A,

--auth-local или --auth-host при следующем выполнении initdb.

Готово. Теперь вы можете запустить сервер баз данных:

/usr/pgsql-9.2/bin/postgres -D /var/lib/pgsql/9.2/data

или

/usr/pgsql-9.2/bin/pg_ctl -D /var/lib/pgsql/9.2/data -l logfile start

-bash-4.1$

Или тот же вывод на английском языке:

[root@vm-sql01 ~]# su postgres -c '/usr/pgsql-9.2/bin/initdb -D /var/lib/pgsql/9.2/data --locale=ru_RU.UTF-8'

could not change directory to "/root"

The files belonging to this database system will be owned by user "postgres".

This user must also own the server process.

The database cluster will be initialized with locale "ru_RU.UTF-8".

The default database encoding has accordingly been set to "UTF8".

The default text search configuration will be set to "russian".

fixing permissions on existing directory /var/lib/pgsql/9.2/data ... ok

creating subdirectories ... ok

selecting default max_connections ... 100

selecting default shared_buffers ... 32MB

creating configuration files ... ok

creating template1 database in /var/lib/pgsql/9.2/data/base/1 ... ok

initializing pg_authid ... ok

initializing dependencies ... ok

creating system views ... ok

loading system objects' descriptions ... ok

creating collations ... ok

creating conversions ... ok

creating dictionaries ... ok

setting privileges on built-in objects ... ok

creating information schema ... ok

loading PL/pgSQL server-side language ... ok

vacuuming database template1 ... ok

copying template1 to template0 ... ok

copying template1 to postgres ... ok

WARNING: enabling "trust" authentication for local connections

You can change this by editing pg_hba.conf or using the option -A, or

--auth-local and --auth-host, the next time you run initdb.

Success. You can now start the database server using:

/usr/pgsql-9.2/bin/postgres -D /var/lib/pgsql/9.2/data

or

/usr/pgsql-9.2/bin/pg_ctl -D /var/lib/pgsql/9.2/data -l logfile start

[root@vm-sql01 ~]#

Или второй, более простой, но не всегда дающий необходимый результат (зависит от региональных настроек сервера, но у меня иногда приводивший к установке базы данных без поддержки необходимого collation ru_RU.UTF-8):

[root@vm-sql01 pgsql]# service postgresql-9.2 initdb

Инициализируется база данных: [ OK ]

[root@vm-sql01 pgsql]#

В результате была создана структура базы данных (с настройками) в /var/lib/pgsql/9.2/data. Хочу обратить особое внимание на конструкцию --locale=ru_RU.UTF-8, которую необходимо указать при инициализации, иначе сервер может быть инициализирован с неверным набором языковых параметров, что в конечном итоге приведёт к сообщениям

Ошибка установки или изменения национальных настроек информационной базы

Порядок сортировки не поддерживается базой данных

по причине:

Порядок сортировки не поддерживается базой данных

при установке информационной базы. Теперь можно настраивать автоматический запуск sql-сервера и, собственно, запускать его:

[root@vm-sql01 temp]# chkconfig postgresql-9.2 on

[root@vm-sql01 temp]# service postgresql-9.2 start

Запускается служба postgresql-9.2: [ OK ]

[root@vm-sql01 temp]#

Всё. Для локальных подключений сервер настроен. В моём случае сервер 1С и сервер SQL находятся на разных машинах, поэтому потребуется настроить и удалённые подключения с авторизацией.

В случае каких-то проблем, читаем содержимое файлов:

/var/lib/pgsql/9.2/pgstartup.log

/var/lib/pgsql/9.2/data/postgresql-*.log

Для повышения быстродействия документация PostgreSQL рекомендует как минимум унести журнал /var/lib/pgsql/9.2/data/pg_xlog на отдельный физический том и создать симлинк на него в исходном месте; из личных наблюдений - надо ещё и значительно увеличить размер используемой памяти... но необъятное не охватить, поэтому за статьями по оптимизации работы PostgreSQL для 1С предлагаю обращаться в поисковые системы, а оттуда - на профильные форумы.

3. Настройка пользователей (ролей) Postgre SQL server

Для управления PostgreSQL на начальном этапе потребуется сменить текущего пользователя на postgres и создать нового пользователя из командной строки:

[root@vm-sql01 temp]# su - postgres

-bash-4.1$ cd /usr/pgsql-9.2/bin

-bash-4.1$ createuser --interactive -P

Введите имя новой роли:server1c

Введите пароль для новой роли:

Повторите его:

Должна ли новая роль иметь полномочия суперпользователя? (y - да/n - нет) n

Новая роль должна иметь право создавать базы данных? (y - да/n - нет) y

Новая роль должна иметь право создавать другие роли? (y - да/n - нет) n

-bash-4.1$ exit

logout

[root@vm-sql01 temp]#

В принципе, для обслуживания полезно иметь пользователя с правами суперпользователя - создавать его можно тем же путём.

Теперь осталось разрешить удалённое подключение с авторизацией - для этого в файле /var/lib/pgsql/9.2/data/pg_hba.conf потребуется заменить значение ident на md5 в строке "host all all 0.0.0.0/0 md5" и перезапустить сервис.

Не следует забывать и про настройки iptables - для работы Postgre SQL необходимо открыть как минимум порт tcp 5432, хотя привычнее (да и проще) объявить сетевой интерфейс "внутренним" (разрешить все подключения на интерфейсе).

Для управления сервером потребуется pgAdmin, который можно установить из репозиториев используемого для административных целей линукса, либо скачать с сайта проекта.

4. Установка компонентов сервера 1С

Внимание!!! Для избежания проблем с зависимостями, желательно, чтобы разрядность сервера 1С совпадала с разрядностью используемого дистрибутива Linux! Иначе (если ставим 32-битный 1С на 64-битный Linux), при входе в базу, можно получить сообщение типа "Ошибка загрузки библиотеки libWand.so по причине:Библиотека не обнаружена. Часть функций будет недоступна." и клиенты не будут запускаться (хотя конфигуратор - будет). В принципе, я с этой проблемой справился на CentOS 7 (которой не выпускают больше в 32-битном исполнении) - просто поставил не только 'ImageMagick', но и 'ImageMagick.i686' (yum install ImageMagick.i686) - всё заработало (хоть и притянуло за собой гору зависимостей).

Первый шаг установки сервера 1С мало отличается от аналогичного этапа с SQL-сервером - распаковать скачанный дистрибутив сервера командой tar -vxf rpm64.tar.gz. В итоге получим файлы:

1C_Enterprise83-common-8.3.3-715.x86_64.rpm - основные файлы 1С (включая русский и английский интерфейсы)

1C_Enterprise83-common-nls-8.3.3-715.x86_64.rpm - дополнительные языковые модули

1C_Enterprise83-server-8.3.3-715.x86_64.rpm - сервер 1С

1C_Enterprise83-server-nls-8.3.3-715.x86_64.rpm - дополнительные языковые модули

1C_Enterprise83-ws-8.3.3-715.x86_64.rpm - компоненты вэб-сервера 1С

1C_Enterprise83-ws-nls-8.3.3-715.x86_64.rpm - дополнительные языковые модули

1C_Enterprise83-crs-8.3.3-715.i386.rpm - хранилище конфигураций (только в 32-битном комплекте)

Устанавливаем нужные пакеты командами:

yum install 1C_Enterprise83-common-8.3.3-715.x86_64.rpm

yum install 1C_Enterprise83-server-8.3.3-715.x86_64.rpm

Настраиваем автоматический запуск демона и стартуем его:

[root@vh-1c83 temp]# chkconfig srv1cv83 on

[root@vh-1c83 temp]# service srv1cv83 start

Starting 1C:Enterprise 8.3 server: Error: service failed to start!

FAILED

[root@vh-1c83 temp]# service srv1cv83 start

Starting 1C:Enterprise 8.3 server: OK

[root@vh-1c83 temp]#

Хочу обратить внимание - если сразу после установки сервис (как в приведённом примере) не стартовал, а при второй попытке старта он запустился, скорее всего не настроен DNS - об этом чуть ниже. Если верить информации с многочисленных форумов, то наш сервер уже готов обслуживать до 12 клиентов. Для работы большего числа пользователей, необходимо установить лицензию сервера - либо в виде USB HASP и драйвера, либо в виде электронной лицензии. Про установку аппаратных ключей я уже писал, а установка программных лицензий достаточно проста: запускаем конфигуратор (с клиентской машины; кластер уже должен быть настроен и должна быть информационная база), вызываем "Сервис" - "Получение лицензии", вводим номер комплекта (с коробки или "Регистрационный номер" с карточки из конверта "Пинкоды программной лицензии") и пин-код (с той самой карточки из конверта), ставим галочку "Установка на сервер", вводим имя сервера в соответствующем поле, нажимаем "Далее", говорим, что это - "Первый запуск", заполняем форму "Владелец лицензии" (к стати, я не понял что писать в полях "Фамилия", "Имя", "Отчество" - то ли ответственного за эксплуатацию, то ли генерального директора - оставил поля пустыми, и оно получило лицензию, не ругнувшись), "Далее", "Автоматически" - профит! в /var/1C/licenses на сервере появился файлик XXXXXXXXXXXXXX.lic и серверу "стало хорошо" (если это была многопользовательская лицензия, то клиентам тоже "станет хорошо", т.к. они будут получать лицензии на сервере).

Для работы с графическими объектами и экспорта в xls, могут потребоваться дополнительные пакеты: ImageMagick, freetype (входит в зависимости ImageMagick), libgsf (входит в зависимости ImageMagick), corefonts (отсутствует в репозитариях CentOS - см. раздел 6); для "ТАКСИ" и "Управляемого приложения" они необходимы, для классического толстого клиента вроде бы не особо нужны, но 1С всё равно ругается на их отсутствие, хоть и работает.

По умолчанию сервер 1С слушает порт tcp 1541(1540) и для соединений использует диапазон портов 1560-1691.

5. Настройка экземпляра (кластера) сервера 1С

Информации о наличии оснастки управления сервером 1С для Linux мне не попадалось, так что для управления сервером будем использовать традиционную оснастку mmc для Windows "Администрирование серверов 1С:Предприятия", которую следует поставить из дистрибутива технологической платформы для Windows.

В этом месте на тестовом сервере возникли трудности - кластер по умолчанию отсутствовал, а при попытке создания нового кластера, ragent аварийно завершал работу с сообщением Sep 3 21:29:04 vh-1c83 kernel: ragent[1879]: segfault at 8 ip 00007f56473c9fd4 sp 00007f563b7b14a0 error 4 in rserver.so[7f56472db000+70e000]... странно, но если верить форумам, на CentOS у многих сервер 1С 8.3 ставится некорректно - не создаётся начальная конфигурация, включающая "Кластер по умолчанию". Краткий анализ ситуации выявил, что настройки кластера по умолчанию не были сгенерированы полностью и не попали в /home/usr1cv8/.1cv8/1C/1cv8/.

При попытке подложить файлы с рабочего сервера на неудачный, сервис 1С не запускается абсолютно без каких-либо диагностических сообщений - подобное поведение я видел при проблемах (неверных контекстах) SELinux, но в данном случае никаких отказов в audit.log не обнаружилось.

В результате детального изучения проблемы с применением strace удалось выяснить, что агент сервера при запуске ищет настройки по пути ~/.1cv8/1C/1cv8/ (в домашнем каталоге запустившего пользователя) и если не находит, пытается создать настройки кластера по умолчанию, для чего ему нужно имя хоста (выяснено экспериментально), и если верить "Руководству администратора", нужен корректно работающий DNS; экспериментально же был установлен факт, что сначала ragent читает файл /etc/hosts, затем обращается к DNS-серверу, а затем вызывает uname и снова лезет в hosts и к DNS и если не находит сопоставления, аварийно завершается. Итак, для нормального запуска потребуется полноценная и правильно настроенная сетевая инфраструктура, ну а в отсутствии работающего DNS достаточно дописать строчку в /etc/hosts и привести его примерно к такому виду:

127.0.0.1 localhost

192.168.122.227 vh-1c83.test.lan vh-1c83

::1 localhost localhost.localdomain localhost6 localhost6.localdomain6

За дальнейшими инструкциями пока отсылаю к своей статье про 8.2 - принципиальных отличий пока нет. Единственное замечание - при создании новой информационной базы, если указывать пользователя подключения к базе данных не с правами суперпользователя (а с набором прав из пункта 3), информационная база не создавалась, а в /var/lib/pgsql/9.2/data/pg_log/postgresql-Xxx.log наблюдались сообщения:

ОШИБКА: нет прав для изменения параметра "lc_messages"

ОПЕРАТОР: SET lc_messages to 'en_US.UTF-8';

ОШИБКА: нет доступа к языку c

ОПЕРАТОР: CREATE OR REPLACE FUNCTION plpgsql_call_handler() RETURNS language_handler AS '$libdir/plpgsql' LANGUAGE C

ОШИБКА: нет прав для изменения параметра "lc_messages"

ОПЕРАТОР: SET lc_messages to 'en_US.UTF-8';

ОШИБКА: ошибка синтаксиса (примерное положение: "application") в символе 24

ОПЕРАТОР: lock table pg_class in application share mode

ПРЕДУПРЕЖДЕНИЕ: нет незавершённой транзакции

ОШИБКА: тип "mvarchar" не существует в символе 31

ОПЕРАТОР: create table Config (FileName mvarchar(128) not null, Creation timestamp not null, Modified timestamp not null, Attributes int not null, DataSize int8 not null, BinaryData bytea not null, PartNo int not null, PRIMARY KEY (FileName, PartNo))

ОШИБКА: нет прав для изменения параметра "lc_messages"

ОПЕРАТОР: SET lc_messages to 'en_US.UTF-8';

ОШИБКА: нет доступа к языку c

ОПЕРАТОР: CREATE OR REPLACE FUNCTION plpgsql_call_handler() RETURNS language_handler AS '$libdir/plpgsql' LANGUAGE C

После подключения с учётными данными суперпользователя БД, сообщения изменились на англоязычные и проблемы исчезли. Судя по всему, если на сервере установлен язык по умолчанию en_US, данного казуса не случится, но это - не проверенная информация, а лишь предположение, сделанное по прочтении чужой статьи про 8.1 и праздных раздумий =)

Ещё одна странность - если создать пустую SQL базу не из шаблона1 (см. официальную документацию по 1С), и попытаться ей указать на этапе создания ИБ, то всё равно получим сообщение "ОШИБКА: тип "mvarchar" не существует (символ 31)"/"ERROR: type "mvarchar" does not exist at character 31", но мне так и не удалось создать из требуемого шаблона БД - валились разные ошибки, но если пользователя sql, от которого создаётся ИБ временно повысить до суперпользователя с правом создания БД, и указать создание базы данных в случае её отсутствия, то всё получается в лучшем виде, так что на этапе первичной настройки, видимо, придётся повышать пользователя до супер...

Что порадовало - теперь в 1С можно работать непосредственно из Linux, что актуально для компаний, использующих его как основную ОС в корпоративной сети (я сейчас работаю как раз в такой компании); из неожиданностей - что при установке клиента 1С, он заявляет о зависимости от сервера и требует его установки, но потом ставится, прописывает значки запуска в "Офис" - "Финансы" и работает довольно сносно (по ощущениям - чуть менее комфортно, чем 8.2 под Windows, но заметно приятнее, чем тот же 8.2 через WINE от Ethersoft).

6. Установка недостающих зависимостей

При запуске клиента к настроенному по данной инструкции серверу, появится сообщение "На сервере отсутствуют шрифты из состава Microsoft Core Fonts. Внешний вид приложения может отличаться от ожидаемого. Процедура установки описана в справочной системе..." - данное сообщение появляется достаточно редко (периодичность не выявил, но появляется точно не единожды, но и не при каждом запуске), и на работе особо не сказывается, но "для красоты" я решил пройтись по всей цепочке и поставить рекомендуемые пакеты. Всё, кроме "corefonts" поставилось из репозиториев (хотя в той самой "справочной системе" безбожно перепутаны регистры в названиях пакетов, из-за чего их идентификация оказалась весьма развлекательна), ну а шрифты я решил пересобрать (в соответствии с рекомендациями из "справочной системы") и результат прикрепляю к статье - msttcorefonts-2.5-1.noarch.rpm, заодно и сами шрифты (уже переименованные в нижний регистр, как происходит при сборке rpm рекомендованным скриптом) - msttcorefonts.tar.gz - содержимое этого архива рекомендуют распаковать в /home/usr1cv8/.fonts (не забыв сменить владельца как на папку, так и на файлы!), если нет возможности установить предложенный .rpm

Кроме "ImageMagick" и шрифтов, для возможности сохранения в табличные файлы (кроме xls - его я пока не заставил формироваться, хотя xlsx формируется), на клиенте должны быть установлены пакеты "libMagickWand5", "libgomp1", "liblcms2-2" и "libbz2-1" - на ряде машин они отсутствовали. При чём той же разрядности, что и сервер 1С (см. п. 4).

7. Настройка аппаратного hasp для виртуализированного сервера 1С (работающего на виртуальной машине KVM)

Не планировал описывать эту процедуру, но раз уж столкнулся с такой ситуацией, опишу... Итак, на этот раз я использовал драйвер от "Alladin Knowledge Systems USB HASP", предоставляемый компанией Sentinel - мне попались две версии:

2878061 сен 11 2012 aksusbd-2.0-1.i386.rpm - с сайта aladdin-rd.ru

3009880 авг 6 16:35 aksusbd-2.2-1.i386.rpm - с сайта safenet-inc.com

Можно воспользоваться драйвером эзерсофт - окончательный выбор следует делать из опыта практической эксплуатации.

Наиболее правильная (на мой взгляд) последовательность действий:

а) убедиться, что на хост-машине драйвер HASP не установлен;

б) установить выбранный драйвер USB HASP4 на виртуальном сервере;

в) выяснить список подключенных USB-устройств к хост-машине

[root@vh01 files]# ls -R /dev/bus/usb

/dev/bus/usb:

001

002

003

004

/dev/bus/usb/001:

001

002

/dev/bus/usb/002:

001

/dev/bus/usb/003:

001

/dev/bus/usb/004:

001

[root@vh01 files]#

г) подключить USB-HASP к хост-машине и выяснить адрес ключа:

[root@vh01 files]# ls -R /dev/bus/usb

/dev/bus/usb:

001

002

003

004

/dev/bus/usb/001:

001

002

/dev/bus/usb/002:

001

/dev/bus/usb/003:

001

/dev/bus/usb/004:

001

002 <==== это наш ключ - раньше его не было

[root@vh01 files]#

д) используя любой из способов (я использовал Virtual Manager на удалённой машине) добавить "USB Host Device" с найденным адресом (в моём примере - 004:002) к виртуальной машине 1С - может потребоваться выключение и включение машины (я добавлял устройство на выключенную машину).

Собственно, всё - на CentOS 6.4 x64/i686 всё работает (были багрепорты про CentOS 6.0/6.1, но вроде всё починили). Если при запуске виртуалки выдаётся сообщение о занятости устройства, скорее всего подцепился драйвер на хост-машине (так писали на паре форумов, хотя мне эту ситуацию воспроизвести не получилось - даже с установленным драйвером на сервере устройство мапилось корректно). Естественно, если переставить ключ в другой порт USB, придётся перенацеливать и виртуальную машину!

И напоследок, коротко о том "что где лежит":

/etc/sysconfig/srv1cv83 - файл конфигурации сервера 1С

/home/usr1cv8/.1cv8/1C/1cv8/1cv8wsrv.lst - файл, в котором хранятся основные свойства сервера - например, учётные данные администратора сервера, зарегистрированые кластеры и т.п.

/home/usr1cv8/.1cv8/1C/1cv8/reg_1541/1CV8Clst.lst - файл, в котором хранятся свойства кластера по умолчанию

/opt/1C/v8.3/x86_64/ - (вместо "x86_64" может быть "i386" - в зависимости от архитектуры системы) исполняемые файлы и сопутствующие ресурсы сервера (и клиента) 1С

/var/1C/licenses - здесь лежат файлы электронных ключей лицензий

8. Настройка локального репозитория 1С для удобства обновления платформы 

В процессе эксплуатации 1С нередко приходится обновлять платформу. Если всё установлено по приведённой выше инструкции, это вызывает определённые неудобства - надо останавливать сервис, удалять старые пакеты, ставить новые... не знаю - мне это ещё в винде надоело смертельно. Linux предлагает очень удобный механизм пакетного обновления из локального репозитория - всё, что нужно - это выбрать место, где будут лежать обновки: для одиночного сервера, к которому все ходят только через web-интерфейс, это может быть /root/repo (всё равно обновление под рутом идёт), ну а в общем случае - хоть /var/www/1c-repo - главное, чтобы все, кому он нужен, его видели. Далее надо установить пакет 'createrepo' (yum install createrepo) - за собой он притащит немало зависимостей, но не смертельно. Теперь командой 'createrepo /root/repo' (где "/root/repo" - выбранный путь хранения репозитория) создаём его "описание" и можно пользоваться.

Затем создаём файл описания нашего репозитория и помещаем его в каталог описаний репозиториев (для CentOS это /etc/yum.repos.d). Пример конфига локального файлового репозитария:

[root@1c yum.repos.d]# cat local-1c.repo

[local-1c]

name=1C Enterprise

#baseurl=http://inhost.firm.lan/repo

baseurl=file:///root/repo

gpgcheck=0

enabled=1

По-моему, разъяснять что за что отвечает, особого смысла нет. Единственное, что важно - сразу yum его может не увидеть - в этой ситуации поможет очистка его кэшей (yum clean all).

Всё. Теперь если надо обновиться, то помещаем новые файлы дистрибутива 1С рядом со старыми, повторяем 'createrepo /root/repo' вызываем 'yum update' - и всё - платформа пошла обновляться! Естественно, за сохранностью и защищённостью своего репозитория надо следить, так как GPG у нас выключен, и это всё же дыра в безопасности, хоть и не особо толстая...

 // Возвращает содержимое ответа HTTP-сервера, полученного методом GET, в виде строки или двоичных данных

// ** Coded by Sergey (aka Porutchik) * 2014 http://forum.aeroion.ru/cat1.html //

// Параметры

//  СерверПриемник - <Строка> - доменное имя сервера или полный адрес (url) запрашиваемой ссылки.

//                        Может включать протокол (http://, https://) и порт.

//  АдресСтраницы - <Строка> - опционально. Адрес страницы на сервере без протокола (http://, https://),

//                        доменного имени сервера (хоста) и порта.

//                Если не указано, адрес страницы будет извлечён из параметра СерверПриемник

//  ПараметрыСоединения - <Структура> - опционально. Структура, содержащая дополнительные параметры для HTTPСоединение.

//                Назначение ключей:

//                Логин или Пользователь - Тип Строка - Имя пользователя на указанном сервере.

//                Пароль - Тип Строка - Пароль пользователя на указанном сервере.

//                Прокси - Тип ИнтернетПрокси - Прокси, используемый для соединения с сервером.

//                Таймаут - Тип Число - Таймаут осуществляемого соединения и операций, в секундах. 0 - не устанавливать таймаут..

//  ЗаголовкиHTTP  - <Соответствие> - опционально.

//                Заголовки, которые будут отправлены на сервер в виде соответствия: "Заголовок" - "Значение".

//                Если указано, функция возвратит в программу заголовки HTTP-ответа с кодом состояния в ключе StatusCode,

//                имя файла в ключе FileName, url-кодированное имя в ключе EncodeFileName

//  ПолучитьКакДвоичныеДанные - <Булево> - опционально. Определяет, в каком виде получить содержимое ответа сервера

//                            По умолчанию Ложь.

//  ЗащищенноеСоединение - <Булево> - опционально. По умолчанию Ложь.

//                            Если Истина, соединение будет происходить по протоколу https://

//

// Возвращаемое значение:

//   <Строка>, <ДвоичныеДанные> - содержимое ответа сервера, если ресурс найден по указанному адресу.

//

Функция ПолучитьСодержимоеВебАдреса(Знач СерверПриемник, Знач АдресСтраницы = "",

                Знач ПараметрыСоединения = Неопределено, ЗаголовкиHTTP = Неопределено,

                Знач ПолучитьКакДвоичныеДанные = Ложь, Знач ЗащищенноеСоединение = Ложь) Экспорт

    Перем ИмяФайлаОтветаКодированное, ИмяФайлаОтвета, Порт, Логин, Пользователь, Пароль, Прокси, Таймаут;



    Если Не ЗначениеЗаполнено(СерверПриемник) Тогда Возврат Неопределено; КонецЕсли;

    Если ТипЗнч(ЗаголовкиHTTP) <> Тип("Соответствие") Тогда ЗаголовкиHTTP = Новый Соответствие; КонецЕсли;

    Если Найти(Нрег(СерверПриемник), "https://") = 1 Тогда ЗащищенноеСоединение = Истина; КонецЕсли;



    Протокол = ?(Найти(Нрег(СерверПриемник), "https://") = 1 ИЛИ ЗащищенноеСоединение, "https://", "http://");

    Если Лев(НРег(СерверПриемник), СтрДлина(Протокол)) = Протокол Тогда

        СерверПриемник = Сред(СерверПриемник, СтрДлина(Протокол) + 1);

    КонецЕсли;



    Если НЕ ЗначениеЗаполнено(АдресСтраницы) Тогда

        Позиция = Найти(СерверПриемник, "/");

        Если Позиция > 0 Тогда

            АдресСтраницы = Сред(СерверПриемник, Позиция, СтрДлина(СерверПриемник));

            СерверПриемник = Лев(СерверПриемник, Позиция - 1);

        Иначе

            АдресСтраницы = "/";

        КонецЕсли;

    КонецЕсли;



    СерверПриемник = СтрЗаменить(СерверПриемник, "/", "");



    //Выделяем порт из доменного имени

    ПозицияДвоеточия = Найти(СерверПриемник, ":");

    Если ПозицияДвоеточия > 0 Тогда

        Порт = Число(Сред(СерверПриемник, ПозицияДвоеточия + 1));

        СерверПриемник = Лев(СерверПриемник, ПозицияДвоеточия - 1);

    КонецЕсли;



    Если ТипЗнч(ПараметрыСоединения) = Тип("Структура") Тогда

        Для каждого КлючЗначение из ПараметрыСоединения Цикл

            Значение = КлючЗначение.Значение; Выполнить(КлючЗначение.Ключ + " = Значение;");

        КонецЦикла;

        Пользователь = ?(ЗначениеЗаполнено(Пользователь), Пользователь, Логин);

    КонецЕсли;

    НТТР = Новый HTTPСоединение(СерверПриемник, Порт, Пользователь, Пароль, Прокси, Таймаут,

                        ?(ЗащищенноеСоединение, Новый ЗащищенноеСоединениеOpenSSL(), Неопределено));



    //Ответ от сервера получим в возвращаемом значении типа HTTPОтвет

    ОтветHTTP = НТТР.Получить(Новый HTTPЗапрос(АдресСтраницы, ЗаголовкиHTTP)); //

    ОшибкаЗапроса = (ОтветHTTP.КодСостояния >= 400);



    //После получения ответа сервера необходимо проверить статус или код состояния.

    //http://www.w3.org/Protocols/rfc2616/rfc2616-sec10....     //Если сервер вернул один из статусов переадресации

    //301 Moved Permanently («перемещено навсегда») или 302 Moved Temporarily («перемещено временно»),

    //то в этом случае можно попытаться перейти на ресурс, на который переадресовал сервер

    Если ОтветHTTP.КодСостояния = 301 или ОтветHTTP.КодСостояния = 302 Тогда



        Если ОтветHTTP.Заголовки.Количество() > 0 Тогда

            //Адрес страницы переадресации содержится в поле Location заголовка ответа

            АдресСтраницы = ОтветHTTP.Заголовки["Location"]; //

            Если ЗначениеЗаполнено(АдресСтраницы) Тогда

                Если Найти(НРег(АдресСтраницы), "http://") = 0 И Найти(НРег(АдресСтраницы), "https://") = 0 Тогда

                    АдресСтраницы = ?(Лев(АдресСтраницы, 1) = "/", Сред(АдресСтраницы, 2), АдресСтраницы);

                    Если Найти(АдресСтраницы, СерверПриемник + "/") = 0  Тогда

                        АдресСтраницы = Протокол + СерверПриемник + ?(ЗначениеЗаполнено(Порт), ":" + Порт, "") + "/" + АдресСтраницы;

                    КонецЕсли;

                КонецЕсли;



                //Если сервер вернул cookies (http://ru.wikipedia.org/wiki/HTTP_cookie, http://www.faqs.org/rfcs/rfc6265.html?#41;,                 //вставим их в заголовки для передачи на страницу перехода

                Куки = ОтветHTTP.Заголовки["Set-Cookie"];//

                Если ЗначениеЗаполнено(Куки) Тогда ЗаголовкиHTTP.Вставить("Cookie", Куки); КонецЕсли;



                //Рекурсивный вызов

                Возврат ПолучитьСодержимоеВебАдреса(АдресСтраницы, , , ЗаголовкиHTTP, ПолучитьКакДвоичныеДанные, ЗащищенноеСоединение);//



            КонецЕсли;

        КонецЕсли;



    ИначеЕсли ОтветHTTP.КодСостояния >= 100 И ОтветHTTP.КодСостояния <= 200 Тогда

        //Статус ответа в интервале между 100 и 200 Ok говорит о нормальном результате HTTP-запроса

        Если ОтветHTTP.Заголовки.Количество() > 0 Тогда

            ТипСодержимого = ОтветHTTP.Заголовки["Content-Type"];

            //http://ru.wikipedia.org/wiki/Список_MIME-типов             Если Найти(ТипСодержимого, "text/") = 1 ИЛИ Найти(ТипСодержимого, "/javascript")

                ИЛИ Найти(ТипСодержимого, "+xml") ИЛИ Найти(ТипСодержимого, "/xml") <> 0 ИЛИ Найти(ТипСодержимого, "/json") <> 0 Тогда

                ПолучитьКакДвоичныеДанные = Ложь;

            ИначеЕсли Найти(ТипСодержимого, "image/") = 1 ИЛИ Найти(ТипСодержимого, "video/") = 1 

                ИЛИ Найти(ТипСодержимого, "application/") = 1 ИЛИ Найти(ТипСодержимого, "audio/") = 1 Тогда

                //Если содержимое полученного ответа представляет собой изображение, видео, приложение,

                //возвращаем двоичные данные, так как возвращать в виде строки не имеет смысла.

                ПолучитьКакДвоичныеДанные = Истина;

            КонецЕсли;

            //Некоторые сервера возвращают в типе содержимого имя отданного файла, например image/png; name="Имя файла.png"

            //или отдают в заголовке Content-Disposition: attachment; filename=Имя файла.png (http://www.http11.ru/post.php?post=2)             Если ОтветHTTP.Заголовки["Content-Disposition"] <> Неопределено Тогда

                ТипСодержимого = ОтветHTTP.Заголовки["Content-Disposition"];

            КонецЕсли;

            ТипСодержимого = СтрЗаменить(СтрЗаменить(ТипСодержимого, """", ""), "'", "");



            //в ключе filename*=UTF-8'' содержится url-кодированное имя файла

            ПозицияИмениФайла = Найти(ТипСодержимого, "filename*=UTF-8");

            Если ПозицияИмениФайла <> 0 Тогда

                ИмяФайлаОтветаКодированное = Сред(ТипСодержимого, ПозицияИмениФайла + СтрДлина("filename*=UTF-8"));

                ПозицияДвоеточия = Найти(ИмяФайлаОтветаКодированное, ";");

                Если ПозицияДвоеточия <> 0 Тогда

                    ИмяФайлаОтветаКодированное = Лев(ИмяФайлаОтветаКодированное, ПозицияДвоеточия - 1);

                КонецЕсли;

            КонецЕсли;



            //в ключе filename= содержится обычное имя файла

            ПозицияИмениФайла = Найти(ТипСодержимого, "name=");

            Если ПозицияИмениФайла <> 0 Тогда

                ИмяФайлаОтвета = Сред(ТипСодержимого, ПозицияИмениФайла + СтрДлина("name="));

                ПозицияДвоеточия = Найти(ИмяФайлаОтвета, ";");

                Если ПозицияДвоеточия <> 0 Тогда

                    ИмяФайлаОтвета = Лев(ИмяФайлаОтвета, ПозицияДвоеточия - 1);

                КонецЕсли;

            КонецЕсли;

        КонецЕсли;

    КонецЕсли;



    ЗаголовкиHTTP = ОтветHTTP.Заголовки;

    //Добавляем в заголовки ответа код состояния (ответа) HTTP-сервера и имя файла содержимого, если есть.

    ЗаголовкиHTTP.Вставить("StatusCode", ОтветHTTP.КодСостояния);

    Если ЗначениеЗаполнено(ИмяФайлаОтвета) Тогда ЗаголовкиHTTP.Вставить("FileName", ИмяФайлаОтвета); КонецЕсли;

    Если ЗначениеЗаполнено(ИмяФайлаОтветаКодированное) Тогда

        ЗаголовкиHTTP.Вставить("EncodeFileName", ИмяФайлаОтветаКодированное);

    КонецЕсли;



    Если ОшибкаЗапроса ИЛИ НЕ ПолучитьКакДвоичныеДанные Тогда Возврат ОтветHTTP.ПолучитьТелоКакСтроку(); КонецЕсли;

    Возврат ОтветHTTP.ПолучитьТелоКакДвоичныеДанные();



КонецФункции // ПолучитьСодержимоеВебАдреса()







//Источник: http://forum.aeroion.ru/topic749.html   

Примеры использования:

У клиента огромная база клиентов и соответственно огромный штат менеджеров. Дошло до того, что менеджеры в поисках новых клиентов( знакомство, интернет, реклама и т.д.) очень часто звонят одним и тем же клиентам по несколько раз. Стали вести базу звонков... Но в базе одного и того же клиента могли назвать по разному - как-только вздумается... 

Понадобился поиск по нечеткому названию и для этого решено было использовать полнотекстовый поиск 1С:

Механизм полнотекстового поиска в 1С позволяет быстро находить необходимую для пользователя информацию. Данный вид поиска особенно эффективен, если информационная база располагает большим объемом информации, а также точно не известно, где находятся интересующие пользователя данные или как часто бывает, их точное название не известно.

Смысл обработки в том, что менеджер копирует названия клиентов в список слева, нажимает Выполнить поиск и справа видит найденных в базе контрагентов (подходящих по нечеткости). Порог нечеткости менеджеры могут устанавливать сами.

Приведу краткий пример реализации данного поиска, код:

 



Процедура КнопкаВыполнитьНажатие(Кнопка)

	Если ПолнотекстовыйПоиск.ПолучитьРежимПолнотекстовогоПоиска() <> РежимПолнотекстовогоПоиска.Разрешить Тогда

		Отказ = Истина;

		Сообщение = Новый СообщениеПользователю();

		Сообщение.Текст = НСтр("ru = 'Использование полнотекстового поиска не разрешено. Вы можете включить его в диалоге ""Управление полнотекстовым поиском""'", "ru");

		Сообщение.Сообщить();

		Возврат;

	КонецЕсли;

	

	тчРезультата.Очистить();

	текдок = Новый ТекстовыйДокумент;

	текдок.УстановитьТекст(ТестПоиска);

	Для Ном=1 по текдок.КоличествоСтрок() цикл

		Стр = СокрЛП(текдок.ПолучитьСтроку(Ном));

		СписокПоиска = ПолнотекстовыйПоиск.СоздатьСписок(Стр);		

		СписокПоиска.ПолучатьОписание = Истина;

		СписокПоиска.РазмерПорции = 5;

		

		СписокПоиска.ПорогНечеткости = ПорогНечеткости;

		

		МассивОтбор = Новый Массив();

		МассивОтбор.Добавить(Метаданные.Справочники.Контрагенты);

		//МассивОтбор.Добавить(Метаданные.Документы.КассовыйЧек);

		СписокПоиска.ОбластьПоиска = МассивОтбор;

		СписокПоиска.ПерваяЧасть(); // Выдает по 5 результатов - РазмерПорции

		// Если нужно листать

		//	СписокПоиска.ПредыдущаяЧасть(ТекущаяПозиция);      

		//	СписокПоиска.СледующаяЧасть(ТекущаяПозиция);      

				

		Для каждого Результат Из СписокПоиска Цикл

			нСтр=тчРезультата.Добавить();

			нСтр.ТекстПоиска=Стр;

			нСтр.Контрагент=Результат.Значение;

		КонецЦикла; 			





	КонецЦикла;

	

КонецПроцедуры





Процедура ПриОткрытии()

	ПорогНечеткости=15;

КонецПроцедуры   

Результат обработки:

Пример создания внешней печатной формы АКТа для Бухгалтерии 3.0

1. В конфигураторе 1C Предприятия 8 создаем внешнюю обработку (Файл->Новый->Внешняя обработка), задаем имя.

2. В модуле обработки пишем код. Постараюсь его максимально комментировать. Главное должно быть:

• функция ПечатьВнешнейПечатнойФормы табличного документа - которая выведет данные в макет
• функция Печать - вызывается из конфигурации! в нее передается массив печатаемых объектов
• и функция СведенияОВнешнейОбработке(). Она необходима для регистрации печатной формы в справочнике ДополнительныеОтчетыИОбработки, в ней собирается структура с данными для подключения формы. Эта функция, а также ряд сопутствующих ей, практически одинаковы для всех печатных форм, поэтому их можно просто копировать в новую печатную форму ничего не меняя.

 // Функция формирует табличный документ с Внешней печатной формой

//

// Возвращаемое значение:

//  Табличный документ - печатная форма акта

Функция ПечатьВнешнейПечатнойФормы(МассивОбъектов, ОбъектыПечати, Подписант) Экспорт

	ТабДок = новый ТабличныйДокумент;

	

	Макет = ПолучитьМакет("Макет");

	

	ОбластьШапки   = Макет.ПолучитьОбласть("Шапка");

	ОбластьДанные  = Макет.ПолучитьОбласть("Данные");

	ОбластьПодвал  = Макет.ПолучитьОбласть("Подвал");

	

	Запрос = новый запрос;

	Запрос.УстановитьПараметр("МассивОбъектов",МассивОбъектов);

	Запрос.Текст = "ВЫБРАТЬ

	|	РеализацияТоваровУслугТовары.Номенклатура,

	|	РеализацияТоваровУслугТовары.Сумма,

	|	РеализацияТоваровУслугТовары.Количество,

	|	РеализацияТоваровУслугТовары.Цена,

	|	РеализацияТоваровУслугТовары.Ссылка КАК Ссылка

	|ИЗ

	|	Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары

	|ГДЕ

	|	РеализацияТоваровУслугТовары.Ссылка В(&МассивОбъектов)

	|

	|ОБЪЕДИНИТЬ ВСЕ

	|

	|ВЫБРАТЬ

	|	РеализацияТоваровУслугУслуги.Номенклатура,

	|	РеализацияТоваровУслугУслуги.Сумма,

	|	РеализацияТоваровУслугУслуги.Количество,

	|	РеализацияТоваровУслугУслуги.Цена,

	|	РеализацияТоваровУслугУслуги.Ссылка

	|ИЗ

	|	Документ.РеализацияТоваровУслуг.Услуги КАК РеализацияТоваровУслугУслуги

	|ГДЕ

	|	РеализацияТоваровУслугУслуги.Ссылка В(&МассивОбъектов)  	

	|

	|УПОРЯДОЧИТЬ ПО

	|	Ссылка";

	

	ОбщаяВыборка = Запрос.Выполнить().Выгрузить();

	

	Для Каждого СсылкаНаОбъект из МассивОбъектов Цикл

		

		ОбластьШапки.Параметры.ТекстЗаголовка = "Акт №  "+СсылкаНаОбъект.Номер;

		ОбластьШапки.Параметры.Организация = СсылкаНаОбъект.Организация;

		

		ТабДок.Вывести(ОбластьШапки);

		

		Отбор = Новый Структура;

		Отбор.Вставить("Ссылка",СсылкаНаОбъект);

		

		Выборка = ОбщаяВыборка.НайтиСтроки(Отбор);

		

		ИтогоСумма      = 0;

		ИтогоКоличество = 0;

		

		Для Каждого Стр из Выборка Цикл

			ЗаполнитьЗначенияСвойств(ОбластьДанные.Параметры,Стр);

			

			ИтогоСумма = ИтогоСумма + Стр.Сумма;

			ИтогоКоличество = ИтогоКоличество + Стр.Количество;

			

			ТабДок.Вывести(ОбластьДанные);

		КонецЦикла;

		

		ОбластьПодвал.Параметры.ИтогоСумма      = ИтогоСумма;

		

		ОбластьПодвал.Параметры.Подписант      = Подписант;





		ТабДок.Вывести(ОбластьПодвал);

		

		ТабДок.ВывестиГоризонтальныйРазделительСтраниц();

	КонецЦикла;

	

	Возврат ТабДок;

КонецФункции



// Экспортная процедура печати, вызываемая из основной программы

//

// Параметры:

// ВХОДЯЩИЕ:

//  МассивОбъектовНазначения - Массив - список объектов ссылочного типа для печати документа

//                 Как правило, содержит один элемент с ссылкой на вызвавший форму объект (документ, справочник)

//

// ИСХОДЯЩИЕ:

//  КоллекцияПечатныхФорм - ТаблицаЗначений - таблица сформированных табличных документов.

//                 Как правило, содержит одну строку с именем текущей печатной формы

//  ОбъектыПечати - СписокЗначений - список объектов печати. 

//  ПараметрыВывода - Структура - Параметры сформированных табличных документов. Содержит поля:

//  						ДоступнаПечатьПоКомплектно - булево - по умолчанию Ложь

//							ПолучательЭлектронногоПисьма

//							ОтправительЭлектронногоПисьма

//

Процедура Печать(МассивОбъектовНазначения, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт

	

	Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "АКТПечатьВнешняя") Тогда 

		ТабличныйДокумент = ПечатьВнешнейПечатнойФормы(МассивОбъектовНазначения, ОбъектыПечати, "");

		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "АКТПечатьВнешняя", "АКТ (внешний)", ТабличныйДокумент);

		

	ИначеЕсли УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "АКТПечатьВнешняяИван") Тогда 

		ТабличныйДокумент = ПечатьВнешнейПечатнойФормы(МассивОбъектовНазначения, ОбъектыПечати, "Иванов А.Ю.");

		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "АКТПечатьВнешняяИван", "АКТ (внешний) Иванов", ТабличныйДокумент);  		

		

	ИначеЕсли УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "АКТПечатьВнешняяПетр") Тогда 

		ТабличныйДокумент = ПечатьВнешнейПечатнойФормы(МассивОбъектовНазначения, ОбъектыПечати, "Петров В.С.");

		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "АКТПечатьВнешняяПетр", "АКТ (внешний) Петров", ТабличныйДокумент);

	КонецЕсли;





КонецПроцедуры





#Область СведенияОВнешнейОбработке

// Сервисная экспортная функция. Вызывается в основной программе при регистрации обработки в информационной базе

// Возвращает структуру с параметрами регистрации

//

// Возвращаемое значение:

//		Структура с полями:

//			Вид - строка, вид обработки, один из возможных: "ДополнительнаяОбработка", "ДополнительныйОтчет", 

//					"ЗаполнениеОбъекта", "Отчет", "ПечатнаяФорма", "СозданиеСвязанныхОбъектов"

//			Назначение - Массив строк имен объектов метаданных в формате: 

//					<ИмяКлассаОбъектаМетаданного>.[ * | <ИмяОбъектаМетаданных>]. 

//					Например, "Документ.СчетЗаказ" или "Справочник.*". Параметр имеет смысл только для назначаемых обработок, для глобальных может не задаваться.

//			Наименование - строка - Наименование обработки, которым будет заполнено наименование элемента справочника по умолчанию.

//			Информация  - строка - Краткая информация или описание по обработке.

//			Версия - строка - Версия обработки в формате “<старший номер>.<младший номер>” используется при загрузке обработок в информационную базу.

//			БезопасныйРежим - булево - Принимает значение Истина или Ложь, в зависимости от того, требуется ли устанавливать или отключать безопасный режим 

//							исполнения обработок. Если истина, обработка будет запущена в безопасном режиме. 

//

Функция СведенияОВнешнейОбработке() Экспорт

	//Инициализируем структуру с параметрами регистрации    	

	ПараметрыРегистрации = Новый Структура;

	// Первый параметр, который мы должны указать - это какой вид обработки системе должна зарегистрировать.

	// Допустимые типы: ДополнительнаяОбработка, ДополнительныйОтчет, ЗаполнениеОбъекта, Отчет, ПечатнаяФорма, СозданиеСвязанныхОбъектов

	ПараметрыРегистрации.Вставить("Вид", "ПечатнаяФорма"); //может быть - ПечатнаяФорма, ЗаполнениеОбъекта, ДополнительныйОтчет, СозданиеСвязанныхОбъектов...

	

	МассивНазначений = Новый Массив;

	// Теперь нам необходимо передать в виде массива имен, к чему будет подключена наша ВПФ

	// Имейте ввиду, что можно задать имя в таком виде: Документ.* - в этом случае обработка будет подключена ко всем документам в системе,

	// которые поддерживают механизм ВПФ

	МассивНазначений.Добавить("Документ.РеализацияТоваровУслуг"); //Указываем документ к которому делаем внешнюю печ. форму   		

	ПараметрыРегистрации.Вставить("Назначение", МассивНазначений);

	

	ПараметрыРегистрации.Вставить("Наименование", "АКТ (Внешний)"); //имя под которым обработка будет зарегестрирована в справочнике внешних обработок

	ПараметрыРегистрации.Вставить("БезопасныйРежим", ЛОЖЬ);  // Зададим право обработке на использование безопасного режима. Более подробно можно узнать в справке к платформе (метод УстановитьБезопасныйРежим)

	ПараметрыРегистрации.Вставить("Версия", "1.0");   // эти два параметра играют больше информационную роль,

	ПараметрыРегистрации.Вставить("Информация", "Дополнительная печатная форма"); // т.е. это то, что будет видеть пользователь в информации к обработке

	

	// Создадим таблицу команд (подробнее смотрим ниже)

	ТаблицаКоманд = ПолучитьТаблицуКоманд();

	ДобавитьКоманду(ТаблицаКоманд, "Внешний: АКТ", "АКТПечатьВнешняя", "ВызовСерверногоМетода", Истина, "ПечатьMXL");

	ДобавитьКоманду(ТаблицаКоманд, "Внешний: АКТ (Иванов)", "АКТПечатьВнешняяИван", "ВызовСерверногоМетода", Истина, "ПечатьMXL");

	ДобавитьКоманду(ТаблицаКоманд, "Внешний: АКТ (Петров)", "АКТПечатьВнешняяПетр", "ВызовСерверногоМетода", Истина, "ПечатьMXL");

	

	ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);

	

	Возврат ПараметрыРегистрации; 	

КонецФункции

#КонецОбласти





#Область Вспомогательное

// ВСПОМОГАТЕЛЬНЫЕ ПРОЦЕДУРЫ И ФУНКЦИИ РЕГИСТРАЦИИ ОБРАБОТКИ





// Формирует структуру с параметрами регистрации регистрации обработки в информационной базе

//

// Параметры:

//	ОбъектыНазначенияФормы - Массив - Массив строк имен объектов метаданных в формате: 

//					<ИмяКлассаОбъектаМетаданного>.[ * | <ИмяОбъектаМетаданных>]. 

//					или строка с именем объекта метаданных 

//	НаименованиеОбработки - строка - Наименование обработки, которым будет заполнено наименование элемента справочника по умолчанию.

//							Необязательно, по умолчанию синоним или представление объекта

//	Информация  - строка - Краткая информация или описание обработки.

//							Необязательно, по умолчанию комментарий объекта

//	Версия - строка - Версия обработки в формате “<старший номер>.<младший номер>” используется при загрузке обработок в информационную базу.

//

//

// Возвращаемое значение:

//		Структура

//

Функция ПолучитьПараметрыРегистрации(ОбъектыНазначенияФормы = Неопределено, НаименованиеОбработки = "", Информация = "", Версия = "1.0")





	Если ТипЗнч(ОбъектыНазначенияФормы) = Тип("Строка") Тогда

		ОбъектНазначенияФормы = ОбъектыНазначенияФормы;

		ОбъектыНазначенияФормы = Новый Массив;

		ОбъектыНазначенияФормы.Добавить(ОбъектНазначенияФормы);

	КонецЕсли; 

	

	ПараметрыРегистрации = Новый Структура;

	ПараметрыРегистрации.Вставить("Вид", "ПечатнаяФорма");

	ПараметрыРегистрации.Вставить("БезопасныйРежим", Истина);

	ПараметрыРегистрации.Вставить("Назначение", ОбъектыНазначенияФормы);

	

	Если Не ЗначениеЗаполнено(НаименованиеОбработки) Тогда

		НаименованиеОбработки = ЭтотОбъект.Метаданные().Представление();

	КонецЕсли; 

	ПараметрыРегистрации.Вставить("Наименование", НаименованиеОбработки);

	

	Если Не ЗначениеЗаполнено(Информация) Тогда

		Информация = ЭтотОбъект.Метаданные().Комментарий;

	КонецЕсли; 

	ПараметрыРегистрации.Вставить("Информация", Информация);

	

	ПараметрыРегистрации.Вставить("Версия", Версия);





	Возврат ПараметрыРегистрации;





КонецФункции





// Формирует таблицу значений с командами печати

//	

// Возвращаемое значение:

//		ТаблицаЗначений

//

Функция ПолучитьТаблицуКоманд()





	Команды = Новый ТаблицаЗначений;

	

	//Представление команды в пользовательском интерфейсе

	Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));

	

	//Уникальный идентификатор команды или имя макета печати

	Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));

	

	//Способ вызова команды: "ОткрытиеФормы", "ВызовКлиентскогоМетода", "ВызовСерверногоМетода"

	// "ОткрытиеФормы" - применяется только для отчетов и дополнительных отчетов

	// "ВызовКлиентскогоМетода" - вызов процедуры Печать(), определённой в модуле формы обработки

	// "ВызовСерверногоМетода" - вызов процедуры Печать(), определённой в модуле объекта обработки

	Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));

	

	//Показывать оповещение.

	//Если Истина, требуется показать оповещение при начале и при завершении работы обработки. 

	//Имеет смысл только при запуске обработки без открытия формы

	Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));

	

	//Дополнительный модификатор команды. 

	//Используется для дополнительных обработок печатных форм на основе табличных макетов.

	//Для таких команд должен содержать строку ПечатьMXL

	Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));





	Возврат Команды; 

КонецФункции





// Вспомогательная процедура.

//

Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование = "ВызовСерверногоМетода", ПоказыватьОповещение = Ложь, Модификатор = "ПечатьMXL")

	НоваяКоманда = ТаблицаКоманд.Добавить();

	НоваяКоманда.Представление = Представление;

	НоваяКоманда.Идентификатор = Идентификатор;

	НоваяКоманда.Использование = Использование;

	НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;

	НоваяКоманда.Модификатор = Модификатор;      

КонецПроцедуры



#КонецОбласти   

3. Добавляем макет вывода печатной формы:

4. Сохраняем и добавляем в конфигурацию:

Подключается через Администрирование - Печатные формы, отчеты и обработки:

Создаете новую обработку, записывайте и при открытии документа Реализация, нажав на Печать - появляются доступные печатные формы с разными подписывающими.

Скачать Шаблон внешней печатной формы для управляемого приложения

В 1С есть такая замечательная вещь, как МенеджерВременныхТаблиц. Этот объект позволяет передавать временные таблицы из одного запроса в другой. То есть, мы можем создать временную таблицу в запросе, прерваться, выполнить какой-нибудь код, и продолжить работу с этой временной таблицей дальше. 

  Запрос = Новый Запрос;

    МВТ = Новый МенеджерВременныхТаблиц;

    Запрос.МенеджерВременныхТаблиц = МВТ;

    

    Запрос.Текст = "ВЫБРАТЬ

                   |    ТЧ.Номенклатура

                   |ПОМЕСТИТЬ ВременнаяТЗ

                   |ИЗ

                   |    &ТЧ КАК ТЧ

                   |ГДЕ

                   |    ТЧ.Номенклатура В ИЕРАРХИИ(&Номенклатура)

                   |    И ТЧ.Цена < 5";

    Запрос.УстановитьПараметр("Номенклатура", Номенклатура);

    Запрос.УстановитьПараметр("ТЧ", ТЧ);

    РезультатЗапроса = Запрос.Выполнить();

                   

    Запрос2 = Новый Запрос;

    Запрос2.Текст = "ВЫБРАТЬ

                    | ВременнаяТЗ.Номенклатура

                    |ИЗ

                    | ВременнаяТЗ КАК ВременнаяТЗ"; 

    Запрос2.МенеджерВременныхТаблиц    = МВТ;   

    РезультатЗапроса = Запрос2.Выполнить().Выгрузить();   

Например, в отчете в зависимости от выбранных настроек первичные данные обрабатываются тем или иным способом. Тогда имеет смысл в одной процедуре сформировать эти данные и поместить их во временную таблицу, которую уже передаем через менеджер временных таблиц в другую процедуру, отвечающую за выбранный способ обработки. Это позволит сократить код, сделать запросы более читаемыми. А так же в случае, если возникнут изменения в методике подготовки первичных данных для обработки, то потребуется внести изменения только в один запрос, а не в каждый.

В качестве примера работы с менеджером временных таблиц приведу следующую обработку.

Я создаю менеджер временных таблиц, и передаю его последовательно в каждую процедуру, для создания и объединения временных таблиц. Результат выводится в сводную таблицу.

 &НаКлиенте

Процедура ЗаполнитьСводную(Команда)

 ЗаполнитьСводнуюНаСервере();

КонецПроцедуры



&НаСервере

Процедура ЗаполнитьСводнуюНаСервере()

 

 МенВТ = Новый МенеджерВременныхТаблиц;

 ПолучитьДанныеА(МенВТ);

 ПолучитьДанныеБ(МенВТ);

 ЗагрузитьСводные(МенВТ);

 МенВТ.Закрыть();

 

КонецПроцедуры





&НаСервере

Процедура ПолучитьДанныеА(МенВремТаб)



 Запрос = Новый Запрос;

 Запрос.МенеджерВременныхТаблиц = МенВремТаб;

 Запрос.Текст = "ВЫБРАТЬ

                | ТаблицаА.Контрагент КАК Контрагент,

                | ТаблицаА.Сумма

                |ПОМЕСТИТЬ ТабА

                |ИЗ

                |ТаблицаА КАК ТаблицаА

                |

                |ИНДЕКСИРОВАТЬ ПО

                | Контрагент";

 Запрос.УстановитьПараметр("ТаблицаА", ТаблицаА.Выгрузить());

 Запрос.Выполнить();

 

КонецПроцедуры // ПолучитьДанныеА()





&НаСервере

Процедура ПолучитьДанныеБ(МенВремТаб)





 Запрос = Новый Запрос;

 Запрос.МенеджерВременныхТаблиц = МенВремТаб;

 Запрос.Текст = "ВЫБРАТЬ

                | ТаблицаБ.Контрагент КАК Контрагент,

                | ТаблицаБ.Комментарий

                |ПОМЕСТИТЬ ТабБ

                |ИЗ

                |ТаблицаБ КАК ТаблицаБ

                |

                |ИНДЕКСИРОВАТЬ ПО

                | Контрагент";

 Запрос.УстановитьПараметр("ТаблицаБ", ТаблицаБ.Выгрузить());

 Запрос.Выполнить();

 

КонецПроцедуры // ПолучитьДанныеА()



&НаСервере

Процедура ЗагрузитьСводные(МенВремТаб)



 Запрос = Новый Запрос;

 Запрос.МенеджерВременныхТаблиц = МенВремТаб;

 Запрос.Текст = "ВЫБРАТЬ

                | ЕСТЬNULL(ТабА.Контрагент, ТабБ.Контрагент) КАК Контрагент,

                | ЕСТЬNULL(ТабА.Сумма, 0) КАК Сумма,

                | ЕСТЬNULL(ТабБ.Комментарий, """") КАК Комментарий

                |ИЗ

                | ТабА КАК ТабА

                |  ПОЛНОЕ СОЕДИНЕНИЕ ТабБ КАК ТабБ

                |  ПО ТабА.Контрагент = ТабБ.Контрагент

                |

                |УПОРЯДОЧИТЬ ПО

                | Контрагент

                |АВТОУПОРЯДОЧИВАНИЕ";

       

 ТаблицаСводная.Загрузить(Запрос.Выполнить().Выгрузить());



КонецПроцедуры // ЗагрузитьСводные()   

Частенько пользователи просят упростить ввод данных в программу используя копирование таблиц из Excel. Ниже я приведу пример как загрузить данные скопированные из Excel:

Создаем форму для загрузки данных:

внутри пишем код:

 // Функция ПолучитьТЗИзМакета(ТабДок, КолонкаИндекса = 1)     

    ТаблицаДанных = Новый ТаблицаЗначений;

    НомерКолонки = 0;

    Пока Истина Цикл

        НомерКолонки = НомерКолонки + 1;

        ИмяКолонки = ТабДок.Область(1, НомерКолонки).Текст;

        Если ПустаяСтрока(ИмяКолонки) Тогда

            Прервать;

        КонецЕсли;        

        ТаблицаДанных.Колонки.Добавить("К"+Строка(НомерКолонки));

    КонецЦикла;

    

    СчетчикКолонок = НомерКолонки - 1;

    

    НомерСтроки = 1; ФлагПрерывания = Ложь;

    Пока Истина Цикл

        НомерСтроки = НомерСтроки + 1;

        Стр = ТаблицаДанных.Добавить();

        

        Для А = 1 ПО СчетчикКолонок Цикл

            ТекстКолонки = ТабДок.Область(НомерСтроки, А).Текст;

            Если ПустаяСтрока(ТекстКолонки) Тогда

                Если А = КолонкаИндекса Тогда

                    Флагпрерывания = Истина;

                    ТаблицаДанных.Удалить(Стр);

                КонецЕсли;

            Иначе

                Стр[А - 1] = ТекстКолонки

            КонецЕсли;

            

            Если Флагпрерывания Тогда

                Прервать

            КонецЕсли;

        КонецЦикла;

        

        Если Флагпрерывания Тогда

            Прервать

        КонецЕсли;

    КонецЦикла;

    

    Возврат ТаблицаДанных

КонецФункции



Процедура ОсновныеДействияФормыЗагрузить(Кнопка)

	тзДанных=ПолучитьТЗИзМакета(ЭлементыФормы.ПолеТД);

	Закрыть(тзДанных);

КонецПроцедуры   

В документ добавлена кнопка  - Загрузка из Excel ее код:

  //Функция преобразует строку вида 31.01.2015 в дату

Функция РазобратьДату(ИзмДата);

	Возврат Дата(Сред(ИзмДата,7,4)+Сред(ИзмДата,4,2)+Сред(ИзмДата,0,2));	       	

КонецФункции



Процедура ЗагрузитьИзЕкселНажатие(Элемент)

тзДанных = ПолучитьФорму("ФормаЗагрузкиИзExcel").ОткрытьМодально();	

//ТЗ получили, загружаем:

ГрафикПлатежейКлиент.Очистить();

Для Каждого стр из тзДанных Цикл 

	 нСтр = ГрафикПлатежейКлиент.Добавить();

	 нСтр.Дата = РазобратьДату(стр.К1);

	 нСтр.Сумма = стр.К2;

	 нСтр.СуммаАкта = стр.К3;

КонецЦикла;



КонецПроцедуры   

Смысл в том что из Excel копируют таблицу:

Жмут на кнопку загрузить и в документе Табличная часть заполняется автоматически:

Если у вас возникаем ошибка вида:

Не найдено ни одного сервера с размещенным сервисом serviceName = DebugService

или

Не найдено ни одного сервера с размещенным сервисом serviceName = JobService

то для исправления этой ошибки - серверу необходимо назначить функциональность:

1. Откройте Панель Администрирования серверов и перейдите в раздел Требования назначения функциональности

2. Добавите общую функциональность с типом требования Назначить

3. Примените требования

4. Все должно работать

Я указал общие требования, т.к. баз на сервере мало, нагрузки практически нет, Но требования назначения функциональности имеют более глубокий смысл:

Требование назначение функциональности определяет:

Для какого объекта требования создается требование. В качестве объекта требования могут выступать некоторые сервисы 1 кластера, клиентские соединения и произвольный объект требования. В качестве объекта требования могут выступать следующие сервисы кластера:

• Блокировок объектов.
• Времени.
• Журналов регистрации.
• Заданий.
• Нумерации.
• Полнотекстового поиска.
• Пользовательских настроек.
• Сеансовых данных.
• Транзакционных блокировок.
• Работы с внешними источниками данных через ODBC.
• Работы с внешними источниками данных через XMLA.
• Сервис лицензирования.
• Сервис фонового обновления конфигурации базы1 данных.
• Сервис тестирования.
• Сервис внешнего управления сеансами.

Определяет тип требования. Тип требования определяет, каким образом будет выполняться использование рабочего сервера:

Не назначать - означает, что рабочий сервер, для которого создано данное требование, не будет назначен для обслуживания объекта требования, подходящего под условия, заданные в требовании.

Назначать - означает, что рабочий сервер, для которого создано данное требование, будет являться одним из кандидатов на обслуживание данного объекта требования (если рабочих серверов будет несколько).

Авто - означает, что рабочий сервер может быть использован для обслуживания объекта требования в том случае, если нет рабочего сервера с явным указанием необходимости использования.

Тип требования Авто - имеет смысл использовать тогда, когда в списке требований рабочего сервера есть требование с более широким набором условий, и необходимо иметь требование для более узкого набора условий. Например, данный сервер не может обслуживать соединения клиентских приложений для всех информационных баз, кроме одной информационной базы, для которой такое обслуживание разрешено.

Дополнительные параметры, необходимые кластеру серверов для принятия решения в ряде случаев:

Имя информационной базы. Используется для уточнения требования для формирования требований для клиентских соединений и всех сервисов кластера, которые могут выступать в качестве объекта требования, кроме сервиса лицензирования.

Дополнительные параметры. Используются для уточнения требований при размещении клиентского соединения или сервиса сеансовых данных. Дополнительный параметр проверяется на совпадение с началом соответствующего параметра объекта требования. Дополнительный параметр может принимать одно из следующих значений:

Для указания конкретного фонового задания:

• BackgroundJob.CommonModule.<Имя модуля>.<Имя метода?.
• Для указания всех фоновых заданий: BackgroundJob. CommonModule .
• Для указания конкретного отчета: BackgroundJob.Report.<Имя отчета;.
• Для указания всех отчетов: BackgroundJob.Report.
• Для указания фоновой реструктуризации: SystemBackgroundJot.
• Для клиентского приложения:
• 1CV - толстый клиент.
• 1CV8CDirect- тонкий клиент в случае прямого подключения к серверу «1С:Предприятия».
• Designer - конфигуратор.
• COMConnectior - COM-соединение.
• WebServerExtensior- соединение с информационной базой через веб-сервер: веб-клиент, тонкий клиент в случае подключения через веб-сервер, Web-сервис.

Рассмотрим, как работает кластер серверов при обработке требований.

В случае необходимости выполнить размещение объекта требования, кластер выполняет следующие действия:

1. На всех серверах, входящих в состав кластера, выполняется обработка заданных для этих серверов требований назначения функциональности. Обход серверов и требований выполняется в порядке следования этих объектов в консоли кластера.2. 

2. В каждом списке требований определяется первое требование, которое удовлетворяет размещаемому объекту: по собственно объекту, информационной базе и дополнительному параметру.

3. Затем полученный список рабочих серверов сортируется по признаку типа требования так, что первыми оказываются рабочие сервера с явным указанием использования. Рабочие сервера, для которых подходящее требование содержит явный запрет на использование - исключаются из списка доступных рабочих серверов. При этом назначение выполняется следующим образом:

• Есть рабочие сервера с явным указанием использования: в этом случае объект требования будет обслужен одним из этих рабочих серверов.
• Нет рабочих серверов с явным указанием использования: происходит попытка использовать рабочие сервера с автоматическим указанием использования или те рабочие серверы, для которых не указано требований.
• При размещении клиентского соединения, из списка доступных серверов будет выбран тот, в состав которого входит рабочий процесс с наивысшей доступной производительностью.
• Клиентское приложение, инициировавшее размещение объекта требования, будет завершено аварийно в одном из следующих случаях:
• Если для объекта требования список рабочих серверов оказывается пустым - нет ни одного рабочего сервера, который может обслужить объект. При этом объект требования не будет размещен и будет вызвано исключение.
• Если невозможно выполнить размещение на выбранном рабочем сервер, например, если выбранный сервер вышел из строя, и нет альтернативных рабочих серверов.

Недавно, мой постоянный клиент решил проводить маркетинговые исследования по изменению цен на товары у конкурентов... и эти данные захотел использовать в 1С в связке с его прайс-листом + куча отчетов с графиками и процентным отклонением от цен основного конкурента

В результате этого, была написана обработка собирающая данные со страниц разных сайтов. Из целей конфиденциальности - сайты раскрывать не буду...

Вид обработки загрузки данных с сайта в 1С

Ниже код загрузки данных со страницы сайта, смысл такой :

• в функция передается адрес страницы сайта
• полученный текст страницы обрабатывается, удаляются теги
• из полученного текста формируется ТЗ с данными
• По названию ищется поставщик из вспомогательного справочника Справочники.Pr_Поставщики.НайтиПоНаименованию(, если нет - создается
• на выходе ТЗ с данными

 Функция ПолучитьТаблицуДанных(Строка)

	

	тзДанных = Новый ТаблицаЗначений;

	Сервер = "site.ru";

	

	Соединение = Новый HTTPСоединение(Сервер);			

	Заголовки = Новый Соответствие;

	Заголовки.Вставить("host", Сервер);

	ТекАдрес = СтрЗаменить(Строка.Наименование.УРЛСтраницы,"http://","");

	ТекАдрес = СтрЗаменить(ТекАдрес,Сервер,"");

	Запрос = Новый HTTPЗапрос(ТекАдрес, Заголовки);

	Ответ =Соединение.Получить(Запрос);

	Если Ответ.КодСостояния = 200 Тогда // Данные получены, обрабатываем их

		Содержимое= Ответ.ПолучитьТелоКакСтроку();

		//Выведем тест полученной страницы

		НачалоБлока = "<table id=" + """" + "table-price" + """" + " cellspacing=" + """" + "0" + """" + " border=" + """" + "1" + """" + " bordercolor=" + """" + "#dedede" + """" + " class=" + """" + "tablesorter" + """" + " >";

		//НачалоБлока = "<div class=" + """" + "w100fl" + """" + " id=" + """" + "kurs" + """" + ">";

		КонецБлока = "</table>";

		ТекстБлока = Сред(Содержимое, Найти(Содержимое, НачалоБлока) + СтрДлина(НачалоБлока), Найти(Содержимое, КонецБлока) - Найти(Содержимое, НачалоБлока) - СтрДлина(НачалоБлока));

		    				

		//Обработаем тест  				

		обрТекст = СтрЗаменить(ТекстБлока,"<tr>","");

		обрТекст = СтрЗаменить(обрТекст,"</tr>",Символы.ПС);

		обрТекст = СтрЗаменить(обрТекст," >", ">");

		обрТекст = СтрЗаменить(обрТекст,"</th> <th>", " | ");

		обрТекст = СтрЗаменить(обрТекст,"</td> <td>", " | ");

	   	обрТекст = СтрЗаменить(обрТекст,"</th> <th class=" + """" + "sortable_header" + """" + ">", " | ");

		обрТекст = СтрЗаменить(обрТекст,"</th> <th >", " | ");

		обрТекст = СтрЗаменить(обрТекст,"</th><th>", " | ");

		обрТекст = СтрЗаменить(обрТекст,"</td><td>", " | ");

		обрТекст = СтрЗаменить(обрТекст," >", ">");

		RegExp = Новый COMОбъект("VBScript.RegExp");

		RegExp.IgnoreCase = Ложь; 

		RegExp.Global = Истина;    

		RegExp.MultiLine = Истина;    

		

		RegExp.Pattern = "<[^>]*>"; //Ищем теги HTML   

		обрТекст=RegExp.Replace(обрТекст, "");

		//Сообщить(обрТекст);

		

		Если СокрЛП(обрТекст) = "Ни одной позиции не найдено." Тогда

			Сообщить(Строка(Строка.Наименование)+ " = Ни одной позиции не найдено! Строка " + Строка.Наименование);

			Возврат тзДанных;

		КонецЕсли;





		Если Найти(обрТекст, "Страница не найдена") > 0 Тогда

			Сообщить(Строка(ТекАдрес)+" = Страница не найдена, строка " + Строка.Наименование);

			Возврат тзДанных;  

		КонецЕсли;

		

		//Преобразуем полученный текст в таблицу

		Для н=1 По СтрЧислоСтрок(обрТекст)Цикл

			СтрТекста=СтрПолучитьСтроку(обрТекст,н);

			Если Найти(СтрТекста, "Длина Цена") > 0 Тогда

				СтрТекста = СтрЗаменить(СтрТекста, "Длина Цена", "Длина | Цена");

			КонецЕсли;

			Если Найти(СтрТекста, "Марка стали Цена") > 0 Тогда

				СтрТекста = СтрЗаменить(СтрТекста, "Марка стали Цена", "Марка стали | Цена");

			КонецЕсли;

			Если Найти(СтрТекста, ",  Поставщик") > 0 Тогда

				СтрТекста = СтрЗаменить(СтрТекста, ",  Поставщик", " | Поставщик");

			КонецЕсли;

			//Выводим текст страницы построчно

			мсДанных = ПолучитьМассивИзСтрокиСРазделителем(СтрТекста, "|", Истина);

			Если н=1 Тогда

				Для Каждого ткЗнач из мсДанных Цикл

					СтрЗапрещСимволов = " .,<>""\/-";

					ИмяКолонки = ткЗнач;

					Для сч33 = 1 по СтрДлина(СтрЗапрещСимволов) Цикл

						ЗапрещСимв = Сред(СтрЗапрещСимволов, сч33, 1);

						ИмяКолонки = СтрЗаменить(ИмяКолонки, ЗапрещСимв, "_");

					КонецЦикла;

					

					// добавим нужное количество колонок- если перед колонкой Поставщик не хватает

					// бывает, что в шапке определяется меньше колонок, чем реально в таблице

					Если НРег(ИмяКолонки) = "поставщик" Тогда

						Для Сч_дк = (Строка.Наименование.Родитель.Поставшик - 2) по тзДанных.Колонки.Количество() Цикл

							тзДанных.Колонки.Добавить("Колонка_" + (тзДанных.Колонки.Количество() + 1));

						КонецЦикла;

					КонецЕсли;

					

					тзДанных.Колонки.Добавить(ИмяКолонки);

				КонецЦикла;

				тзДанных.Колонки.Добавить("ном", , , 7);

			Иначе 

				НовСтр = тзДанных.Добавить(); нмас=0;

				Для Каждого ткЗнач из мсДанных Цикл

					НовСтр[нмас] = ткЗнач;

					нмас=нмас+1;

				КонецЦикла;

				НовСтр.ном = н;

			КонецЕсли;

			//Сообщить(стр);

		КонецЦикла;

		тзДанных.Колонки.Добавить("ЕстьСоответствие", Новый ОписаниеТипов("Булево"));

		тзДанных.Колонки.Добавить("СпрPr_Поставщики", Новый ОписаниеТипов("СправочникСсылка.Pr_Поставщики"));

		

		Для каждого стр из тзДанных Цикл

			текПоставщик = Справочники.Pr_Поставщики.НайтиПоНаименованию(стр[Строка.Наименование.родитель.Поставшик-1]);

			Если текПоставщик = Справочники.Pr_Поставщики.ПустаяСсылка() Тогда

				НовЭлем = Справочники.Pr_Поставщики.СоздатьЭлемент();

				НовЭлем.Наименование = СокрЛП(стр[Строка.Наименование.родитель.Поставшик-1]);

				НовЭлем.Записать();

				текПоставщик = НовЭлем.Ссылка;

			КонецЕсли;

			стр.СпрPr_Поставщики = текПоставщик;

		КонецЦикла;

	Иначе

		тзДанных.Колонки.Добавить("ЕстьСоответствие", Новый ОписаниеТипов("Булево"));

		тзДанных.Колонки.Добавить("СпрPr_Поставщики", Новый ОписаниеТипов("СправочникСсылка.Pr_Поставщики"));

		

		Сообщить("Ошибка получения данных для строки " + Строка.Наименование);

	КонецЕсли;

	

	Возврат тзДанных;

	

КонецФункции   

В коде используется вспомогательная функция ПолучитьМассивИзСтрокиСРазделителем 

 // Функция разбивает строку разделителем.

// 

// Параметры:

//  пСтрока      - Строка - которую разбиваем;

//  *пРазделитель - Строка, "." - символ-разделитель;

//  *ОбрезатьНепечатныеСимволы - Булево, *Ложь.

//

// Возвращаемое значение:

//  Массив - фрагментов.

//

Функция ПолучитьМассивИзСтрокиСРазделителем(Знач Стр, Разделитель = ".", ОбрезатьНепечатныеСимволы = Ложь) Экспорт

	

	МассивСтрок = Новый Массив;

	

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				Фрагмент = Стр;

				Если ОбрезатьНепечатныеСимволы Тогда

					Фрагмент = СокрЛП(Фрагмент);

				КонецЕсли;

				МассивСтрок.Добавить(Фрагмент);

				Возврат МассивСтрок;

			КонецЕсли;

			Фрагмент = Лев(Стр,Поз-1);

			Если ОбрезатьНепечатныеСимволы Тогда

				Фрагмент = СокрЛП(Фрагмент);

			КонецЕсли;

			МассивСтрок.Добавить(Фрагмент);

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;





	Возврат МассивСтрок;

		

КонецФункции // ПолучитьМассивИзСтрокиСРазделителем()   

Конечно, перед тем как мы начали это делать - прошерстили интернет и нашли несколько решений , вот они:

 Соединение = ПолучитьCOMОбъект("","Microsoft.XMLHTTP");

ИмяВременногоФайла=ПолучитьИмяВременногоФайла("htm");



Соединение.open("GET", "http://mamba.ru/my", 0);

Соединение.send();



//status: //404 - Not Found //200 - Ok

ТаймАут = 200;

Начало=ТекущаяДата();

Пока Соединение.readyState <> 4 И (ТаймАут=0 ИЛИ ТекущаяДата()-Начало<ТаймАут) Цикл

бфДиалоги.ксОбработкаПрерыванияПользователя();

КонецЦикла;



//Сохраняем во временный файл

обСохранитьДвоичныйБуферВФайл(Соединение.responseBody, ИмяВременногоФайла);



Соединение.open("POST", "http://mamba.ru/my");

Соединение.send("login=xxx&password=&&&");





Функция обСохранитьДвоичныйБуферВФайл(Буфер, ИмяФайла) Экспорт

    Поток = Новый COMОбъект("ADODB.Stream");

    Поток.Type = 1;  //Бинарный

       Поток.Mode = 3; 

    Поток.Open();

    Поток.Write(Буфер);

    Поток.SaveToFile(ИмяФайла);

    Поток.Close();

КонецФункции   

     НТТР = ПолучитьCOMОбъект("","Microsoft.XMLHTTP");

    ИмяФайлаОтвета = КаталогВременныхФайлов() + "filename.tmp";           

    НТТР.open("GET", "www.google.com",0,,); 

    НТТР.send();

    StreamTypeEnum = Новый Структура("adTypeBinary, adTypeText", 1, 2);

    ConnectModeEnum = Новый Структура(

            "adModeRead, adModeReadWrite, adModeRecursive, adModeShareDenyNone,

            |adModeShareDenyRead, adModeShareDenyWrite, adModeShareExclusive, 

            |adModeUnknown, adModeWrite", 1, 3, 4194304, 16, 4, 8, 12, 0, 2);

    SaveOptionsEnum = Новый Структура("adSaveCreateNotExist, adSaveCreateOverWrite", 1, 2);

    StreamOut = Новый COMОбъект("ADODB.Stream");

    StreamOut.Type = StreamTypeEnum.adTypeBinary;

    StreamOut.Mode = ConnectModeEnum.adModeReadWrite; //Нужны и чтение и запись   

    StreamOut.Open(); //Открыли на чтение и запись

    StreamOut.Write(НТТР.responseBody); 

    StreamOut.SaveToFile(ИмяФайлаОтвета, SaveOptionsEnum.adSaveCreateOverWrite); //"2" - перезапись файла

    StreamOut.Close();   

И даже не этом сайте есть статья : Парсер сайта связного на 1С

В данной статье я расскажу вам как быстро найти в справочнике элементы у которых в наименовании присутствует вхождение искомой нами строки:

Текст запроса будет выглядеть так:

 Запрос = Новый Запрос;

	Запрос.Текст = 

		"ВЫБРАТЬ

		|	Номенклатура.Ссылка,

		|	Номенклатура.Наименование

		|ИЗ

		|	Справочник.Товары КАК Номенклатура

		|ГДЕ

		|	Номенклатура.Наименование ПОДОБНОПараметрСтрокаПоиска";

	

	Запрос.УстановитьПараметр("ПараметрСтрокаПоиска", ПараметрСтрокаПоиска);

	

	РезультатЗапроса = Запрос.Выполнить();

	

	ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

	

	Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

		// Вставить обработку выборки ВыборкаДетальныеЗаписи

	КонецЦикла;   

где оператор запроса ПОДРОБНО как раз и будет искать вхождения ПараметрСтрокаПоиска по всем элементам справочника Номенклатура.

Установить значение параметра ПараметрСтрокаПоиска можно командой:

 РезультатПоиска.Параметры.УстановитьЗначениеПараметра("ПараметрСтрокаПоиска", "%" + СтрокаПоиска + "%");   

Подобным образом можно организовать поиск по точному вхождению строки. Такой способ подходит для поиска элемента справочника например по коду. Строка запроса изменится и будет выглядеть так:

|Номенклатура.Наименование ПОДОБНОПараметрСтрокаПоиска

Оператор ПОДОБНО позволяет сравнить значение выражения, указанного слева от него, со строкой шаблона, указанной справа. Значение выражения должно иметь тип строка. Если значение выражения удовлетворяет шаблону – результатом оператора будет ИСТИНА, иначе – ЛОЖЬ.

Следующие символы в строке шаблона являются служебными и имеют смысл, отличный от символа строки:

• % (процент): последовательность, содержащая любое количество произвольных символов
• _ (подчеркивание): один произвольный символ
• […] (в квадратных скобках один или несколько символов): любой одиночный символ из перечисленных внутри квадратных скобок. В перечислении могут встречаться диапазоны, например a-z, означающие произвольный символ, входящий в диапазон, включая концы диапазона.
• [^…] (в квадратных скобках значок отрицания, за которым следует один или несколько символов): любой одиночный символ, кроме тех, которые перечислены следом за значком отрицания

Связка сервера 1С:Предприятие и PostgreSQL вторая по популярности среди установок 1С и самое используемое решение на платформе Linux. В отличии внедрений на базе Windows и MSSQL, где трудно сделать так, чтобы не заработало, внедрения на базе Linux таят множество подводных камней для неопытного администратора. Часто бывает так, что вроде бы все сделано правильно, но ошибка следует за ошибкой. Сегодня мы рассмотрим самые типовые из них.

Общая информация

Перед тем, как начинать искать ошибки установки и, вообще, приступать к внедрению серверной версии 1С:Предприятия было бы неплохо освежить представление как это работает:

Сервер 1С Предприятия. Часть 1 - Общие вопросы.

В небольших внедрениях сервер 1С и сервер СУБД обычно совмещают на одном физическом сервере, что немного сужает круг возможных ошибок. В нашем случае будет рассматриваться ситуация, когда сервера разнесены по разным машинам. В нашей тестовой лаборатории мы развернули следующую схему:

В нашем распоряжении имеются два сервера под управлением Ubuntu 12.04 x64, на одном из них установлен сервер 1С:Предприятие версии 8.3, на другом PostgreSQL 9.04 от Ethersoft, а также клиент под управлением Windows. Напоминаем, что клиент работает только с сервером 1С, который, в свою очередь, формирует необходимые запросы к серверу СУДБ. Никаких запросов от клиента к серверу управления базами данных не происходит.

Сервер баз данных не обнаруженВАЖНО: пользователь "postgres" не прошёл проверку подлинности (Ident)

Данная ошибка возникает при разнесении серверов по разным ПК из-за неправильно настроеной проверки подлинности в локальной сети. Для устранения откройте /var/lib/pgsql/data/pg_hba.conf, найдите строку:

host    all    all      192.168.31.0/24 ident[/pre]
и приведите ее к виду:
host    all    all      192.168.31.0/24   md5[/pre]
где 192.168.31.0/24 - диапазон вашей локальной сети. Если такой строки нет, ее следует создать в секции IPv4 local connections.
Сервер баз данных не обнаруженcould not translate host name "NAME" to address: Temporary failure in name resolution
На первый взгляд ошибка понятна: клиент не может разрешить имя сервера СУБД, типичная ошибка для небольших сетей, где отсутствует локальный DNS-сервер. В качестве решения добавляют запись в файлhosts на клиенте, что не дает никакого результата...
А теперь вспоминаем, о чем было сказано несколько раньше. Клиентом сервера СУБД является сервер 1С, но никак не клиентский ПК, следовательно запись нужно добавлять на сервере 1С:Предприятие в файл/etc/hosts на платформе Linux или в C:\Windows\System32\drivers\etc\hosts на платформе Windows.
Аналогичная ошибка будет возникать, если вы забыли добавить запись типа A для сервера СУБД на локальном DNS-сервере.
Ошибка при выполнении операции с информационной базойserver_addr=NAME descr=11001(0x00002AF9): Этот хост неизвестен.
Как и прошлая, эта ошибка связана с неправильным разрешением клиентом имени сервера. На этот раз именно клиентским ПК. В качестве решения добавляем в файл /etc/hosts на платформе Linux или в C:\Windows\System32\drivers\etc\hosts на платформе Windows запись вида: 
192.168.31.83SRV-1C-1204[/pre]
где указываете адрес и имя вашего сервера 1С:Предприятия. В случае использования локального DNS следует добавить A-запись для сервера 1С.
Ошибка СУБД: DATABASE не пригоден для использования
Гораздо более серьезная ошибка, которая говорит о том, что вы установили несовместимую с 1С:Предприятие версию PostgreSQL или допустили грубые ошибки при установке, например не установили все необходимые зависимости, в частности библиотеку libICU. 
Если вы имеете достаточный опыт администрирования Linux систем, то можете попробовать доустановить необходимые библиотеки и заново инициализировать кластер СУБД. В противном случае PostgreSQL лучше переустановить, не забыв удалить содержимое папки /var/lib/pgsql.
Также данная ошибка может возникать при использовании сборок 9.1.x и 9.2.x Postgre@Etersoft, подробности смотрите ниже.
Ошибка СУБД: ERROR: could not load library "/usr/lib/x86_64-linux-gnu/postgresql/fasttrun.so"
Довольно специфичная ошибка, характерная для сборок 9.1.x и 9.2.x Postgre@Etersoft, также может приводить предыдущей ошибке. Причина кроется в неисправленной ошибке в библиотеке fasttrun.so. Решение - откатиться на сборку 9.0.x Postgre@Etersoft.
Ошибка СУБДERROR: type "mvarchar" does not exist at character 31
Возникает если база данных была создана без помощи системы 1С:Предприятия. Помните, для работы с 1С базы данных следует создавать только с использованием инструментов платформы 1С: через консоль Администрирование серверов 1С Предприятия
или через средство запуска 1С.
Сервер баз данных не обнаруженВАЖНО: пользователь "postgres" не прошёл проверку подлинности (по паролю)
Очень простая ошибка. Неправильно указан пароль суперпользователя СУБД postgres. Вариантов решения два: вспомнить пароль или изменить его. Во втором случае вам нужно будет изменить пароль в свойствах всех существующих информационных баз через оснастку Администрирование серверов 1С Предприятия.
Сервер баз данных не обнаруженFATAL: database "NAME" does not exist
Еще одна очень простая ошибка. Смысл ее сводится к тому, что указанная БД не существует. Чаще всего возникает из-за ошибки в указании имени базы. Следует помнить, что информационная база 1С в кластере и база данных СУБД - две разные сущности и могут иметь различные имена. Также следует помнить, что Linux системы чувствительны к регистру и для них unf83 и UNF83 два разных имени.
Источник: interface31

Для настройки счетов учета расчетов с контрагентами необходимо зайти в меню:

Справочники/Бухгалтерский и налоговый учет/Счета учета расчетов с контрагентами

Счета учета расчетов с контрагентами настраиваются при первом запуске программы, вместе с настройками учетных политик и констант.

Настройки определяют, те счета бухгалтерского учета расчетов и авансов, которые будут подставляться в документах: расходных, приходных накладных, возвратах, таможенных декларациях, поступлениях дополнительных расходов, авансовых отчетах, платежках, кассовых ордерах и.т.д.

Нажмите кнопку «Изменить» на записи с видом расчета «Расчеты в валюте регламентированного учета (с резидентами)».

Организация определяет настройку счетов учета в разрезе каждой из организаций, введенных в нашу базу, для того чтобы настройки счетов учета распространялись на все организации, это поле можно не заполнять.

Настройка Контрагент и договор – также выполняет детализацию счетов расчетов по каждому из введенных контрагентов и договоров, если поля пустые, настройки распространяются на всех контрагентов, введенных в справочник контрагентов.

Вид расчетов – определяет, выполняется ли настройка для резидентов или для не резидентов

Детализация настроек по контрагентам и договорам имеет смысл в том случае, если с определенными контрагентами ожидаются специфические настройки счетов взаиморасчетов, например по счетам 6851, 3771.

Но даже в таком случае имеет смысл собрать всех таких контрагентов в одну папку и настроить счета учета в целом на папку.

На закладке Счета учета НДС настраиваются счета бухгалтерского учета по НДС кредиту и обязательствам, а также ставки НДС.

Чем более крупненно настроены настройки взаиморасчетов, тем лучше: на всю папку, на всех покупателей, на всю организацию и.т.д

FaceЧем более крупненно настроены настройки взаиморасчетов, тем лучше: на всю папку, на всех покупателей, на всю организацию и.т.д

Если вы не используете счета авансов НЕ ОСТАВЛЯЙТЕ поля: авансов выданных, авансов полученных пустыми, заполняйте их ТЕМИ ЖЕ СЧЕТАМИ как и для взаиморасчетов.

Это позволит избежать случаев не сворачивания вторых событий по документу аванса.

Резюмируя:

Настройки счетов учета желательно выполнить сразу же после установки программы.

Максимально укрупнить их по папкам или в целом по организации.

Обязательно обратить внимание на счета авансов они должны быть такими же, как и счета учета взаиморасчетов, если мы не используем счета авансов у себя в организации.

Счета учета взаиморасчетов, так же как и ставки НДС могут быть изменены в самих первичных документах при отражении хозяйственных операций.