сортируем » Поиск

Результаты по ключевому слову: сортируем

Своя нумерация документов (сделали свою, т.к. штатную нумерацию испортили)

Обратился ко мне старый клиент и говорит - беда с нумерацией счетов!

Менеджеры, кто как хотел - так и изменял номера документов. с префиксом, без, писали даже б/н. Но тут пришел новый бухгалтер и сказал - нужно с 1 октября запустить авто нумерацию с номера 00010000, но старые счета не трогать!

Попросили - сделали:

т.к. Старые трогать нельзя - простое восстановление нумерации отпадает

Первое решение, которое пришло в голову, сделать выборку по моментувремени создания счета - обратная сортировка - получить первый - и к полученному номеру документа +1

Но оказалось, что бывает такое: менеджеры создают счета сегодня, но ставят дату вчера - и получается только что созданный документ уже не последний пришлось переделать алгоритм.

Нужно сортировать именно по дате создания документа! Реквизита такого нет, но решение было найдено в ГУИДе документа, вот статья на эту тему: Как по GUID определить время и дату создания ссылки?

Только алгоритм решили немного переделать - не получаем дату создания документа, а сортируем по части ГУИДа, которая является началом периода создания документа.

Код получился такой:

Код 1C v 8.2 УП

 //В модуле объекта документа

Процедура ПередЗаписью(Отказ, РежимЗаписи, РежимПроведения)

//... стандартный код

//All4CF - Установим новый номер

	Если ЭтоНовый() Тогда

	Запрос = Новый Запрос;

	Запрос.Текст =

	"ВЫБРАТЬ ПЕРВЫЕ 30

	|	СчетНаОплатуПокупателю.Номер,

	|	СчетНаОплатуПокупателю.Ссылка

	|ИЗ

	|	Документ.СчетНаОплатуПокупателю КАК СчетНаОплатуПокупателю

	|

	|УПОРЯДОЧИТЬ ПО

	|	СчетНаОплатуПокупателю.МоментВремени УБЫВ"; 	

	Результат = Запрос.Выполнить().Выбрать(); 

	спНомеров = Новый СписокЗначений;

	Пока Результат.Следующий() Цикл

		тевгуид = Результат.Ссылка.УникальныйИдентификатор(); спНомеров.Добавить(Результат.Ссылка, Сред(тевгуид,10,9)+Сред(тевгуид,0,8));

	КонецЦикла;	

	спНомеров.СортироватьПоПредставлению(НаправлениеСортировки.Убыв);

	послНомер = спНомеров[0].Значение.Номер;

	ДлиНом=СтрДлина(СокрЛП(послНомер));

    Номер = Формат(Число(послНомер)+1,"ЧЦ="+ДлиНом+"; ЧВН=; ЧГ=0");	

	КонецЕсли;	

КонецПроцедуры // ПередЗаписью

Встречалось ли у вас такая ситуация? Как решали?

Категория: Документы

Как запросом получить последний по дате документ?

Сортируем документы по убыванию даты и используем конструкцию «ВЫБРАТЬ ПЕРВЫЕ 1»:

Код 1C v 8.х

 Запрос = Новый Запрос;

Запрос.Текст = "

|ВЫБРАТЬ ПЕРВЫЕ 1

|	РеализацияТоваровУслуг.Ссылка

|ИЗ

|	Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг

|ГДЕ

|	РеализацияТоваровУслуг.Контрагент = &Контрагент

|УПОРЯДОЧИТЬ ПО

|	РеализацияТоваровУслуг.Дата УБЫВ";

Запрос.УстановитьПараметр("Контрагент",	Контрагент);

РезультатЗапроса = Запрос.Выполнить();

Выборка = РезультатЗапроса.Выбрать();

Пока Выборка.Следующий() Цикл 

	Возврат Выборка.Ссылка;

КонецЦикла;

В результате запрос вернёт одну строку, с данными последнего документа по одному контрагенту.

А как сделать запрос, который вернёт последние документы по всем контрагентам, а не по одному конкретному?

Используем функцию МАКСИМУМ в запросе для решения данной задачи.

Код 1C v 8.х

 Запрос = Новый Запрос;

Запрос.Текст = "

|ВЫБРАТЬ

|      ПоследниеДокументыКонтрагентов.Ссылка,

|      ПоследниеДокументыКонтрагентов.Контрагент

|ИЗ Документ.РеализацияТоваровУслуг КАК ПоследниеДокументыКонтрагентов

|ВНУТРЕННЕЕ СОЕДИНЕНИЕ

|      (ВЫБРАТЬ

|            Доки.Контрагент КАК Контрагент,

|            МАКСИМУМ(Доки.Дата) КАК ДатаПоследнегоДокумента

|      ИЗ Документ.РеализацияТоваровУслуг КАК Доки

|СГРУППИРОВАТЬ ПО Доки.Контрагент) 

|КАК ДатыПоследнихДокументовКонтрагентов

|ПО ПоследниеДокументыКонтрагентов.Контрагент = 

|ДатыПоследнихДокументовКонтрагентов.Контрагент       

|И ПоследниеДокументыКонтрагентов.Дата = 

|ДатыПоследнихДокументовКонтрагентов.ДатаПоследнегоДокумента";

РезультатЗапроса = Запрос.Выполнить();

Этот запрос выбирает последние документы по всем контрагентам.

Категория: Запросы

Форма ~ Отбор, Группировка, Порядок и Условное оформление через компоновку данных

Выполним отбор по подразделению, если основной интерфейс пользователя кассир.

Код 1C v 8.х

 Если ПользователиИнформационнойБазы.ТекущийПользователь().ОсновнойИнтерфейс.Имя = "ИнтерфейсКассира" Тогда

		//Установим отбор	

		ДокументСписок.Отбор.Сбросить();

		ДокументСписок.Отбор.Подразделение.ВидСравнения=ВидСравнения.Равно;

		ДокументСписок.Отбор.Подразделение.Значение=ПараметрыСеанса.ТекущийПользователь.Подразделение;

		ДокументСписок.Отбор.Подразделение.Установить();  	

		//Закроем отбор от изменений

		Элементыформы.Список.НастройкаОтбора.Подразделение.Доступность = Ложь; 		

	КонецЕсли;

Выполним отбор по дате в форме списка документа.

Код 1C v 8.2 УП

 ЭлементОтбора = Список.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));

      ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Дата");

      ЭлементОтбора.Использование = Истина;

      ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.БольшеИлиРавно;

      ЭлементОтбора.ПравоеЗначение = Дата1;

      ЭлементОтбора.РежимОтображения = РежимОтображенияЭлементаНастройкиКомпоновкиДанных.Обычный;

      Элементы.Список.Обновить();

Группировка. Сгруппируем список документов по полю Клиент.

Код 1C v 8.2 УП

 ЭлементГруппировки = Список.Группировка.Элементы.Добавить(Тип("ПолеГруппировкиКомпоновкиДанных"));

      ЭлементГруппировки.Использование = Истина;

      ЭлементГруппировки.Поле = Новый ПолеКомпоновкиДанных("Клиент");

      Элементы.Список.Обновить();

Порядок. Отсортируем список документов по полю ПлановаяДатаПоставки.

Код 1C v 8.2 УП

       Список.Порядок.Элементы.Очистить();

      НовыйПорядок = Список.Порядок.Элементы.Добавить(Тип("ЭлементПорядкаКомпоновкиДанных"));

      НовыйПорядок.Поле = Новый ПолеКомпоновкиДанных("Список.ПлановаяДатаПоставки");

      НовыйПорядок.Использование = Истина;

      НовыйПорядок.РежимОтображения = РежимОтображенияЭлементаНастройкиКомпоновкиДанных.Обычный;

      НовыйПорядок.ТипУпорядочивания = НаправлениеСортировкиКомпоновкиДанных.Возр;

      Элементы.Список.Обновить();

Условное оформление. Покрасим в красный цвет строки списка документов с незаполненной датой согласования счета.

Код 1C v 8.2 УП

      ЭлементОформления = Список.УсловноеОформление.Элементы.Добавить();

      

      ЭлементОтбора = ЭлементОформления.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));

      ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("ДатаСогласованияСчета");

      ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.НеЗаполнено;

      ЭлементОтбора.Использование = Истина;

      

      Элемент = ЭлементОформления.Оформление.Элементы[1];

      Элемент.Использование = Истина;

      Элемент.Значение = Новый Цвет(255,0,0);

Категория: Работа с Формой (Диалог) и её элементами

Выборка документа по номеру и вывод на Печать, в Табличный Документ

Код 1C v 7.x

 

Процедура Печать()

	Если (ПустоеЗначение(ДатаНач)=1) или (ПустоеЗначение(ДатаКон)=1) Тогда

		Предупреждение("Не задан период отчета");

		Возврат;

	КонецЕсли;

	Заг="За период с "+ДатаНач+" по "+ДатаКон;

	Таб=СоздатьОбъект("Таблица");

	Таб.ВывестиСекцию("Шапка");		

	Док=СоздатьОбъект("Документ");

	Док.ВыбратьДокументы(ДатаНач,ДатаКон);

	ИтогоПриход=0;

	ИтогоРасход=0;

	Чеков=0;   

	//1C-ovec.ru Нужно выводить документы по Номеру, хотя лучше для этих целей использовать Запрос

	ТЗврем = СоздатьОбъект("ТаблицаЗначений");

	ТЗврем.НоваяКолонка("Док");

	ТЗврем.НоваяКолонка("Дата");

	ТЗврем.НоваяКолонка("Номер");

	ТЗврем.НоваяКолонка("Приход");

	ТЗврем.НоваяКолонка("Расход"); 

	ТЗврем.НоваяКолонка("Чеков");

	//Выборка документов

	Пока Док.ПолучитьДокумент()=1 Цикл

		Если Док.Проведен()=0 Тогда

			Продолжить;

		ИначеЕсли (Док.Вид()="ПриходныйОрдерТБ") и (флПКО=1) Тогда

			Приход=Док.Сумма;

			Расход=0;

		ИначеЕсли (Док.Вид()="БезналичнаяОплата") и (флБН=1)  Тогда

			Приход=Док.Сумма;

			Расход=0;

		ИначеЕсли (Док.Вид()="РасходныйОрдерТБ") и (флРКО=1)  Тогда

			Приход=0;

			Расход=Док.Сумма;

		ИначеЕсли Док.Вид()="Чек" Тогда

			Если (Док.Тип=1) и (флЧекиП=1) Тогда

				Приход=Док.Сумма;

				Расход=0;

				Чеков=Чеков+1;

			ИначеЕсли (Док.Тип=2) и (флЧекиВ=1) Тогда

				Приход=0;

				Расход=Док.Сумма;

				Чеков=Чеков+1;

			Иначе

				Продолжить;

			КонецЕсли;

		Иначе

			Продолжить;

		КонецЕсли;  

		//Добавим в ТЗ строку

		НовСТР=ТЗврем.НоваяСтрока();

		ТЗврем.Док = Док;

		ТЗврем.Дата = Док.ДатаДок;

		ТЗврем.Номер = Док.НомерДок;

		ТЗврем.Приход = Приход;

		ТЗврем.Расход =Расход;

		ТЗврем.Чеков = Чеков;

		//Пока рано выводить

		//Таб.ВывестиСекцию("Строка");		 

		ИтогоПриход=ИтогоПриход+Приход;

		ИтогоРасход=ИтогоРасход+Расход;

	КонецЦикла;    

	//Теперь сортируем по номеру и выводим     

	ТЗврем.Сортировать("Номер");

	ТЗврем.ВыбратьСтроки();

	Пока ТЗврем.ПолучитьСтроку() = 1 Цикл  

		Док=ТЗврем.Док;

		Приход=ТЗврем.Приход;

		Расход=ТЗврем.Расход;

		Таб.ВывестиСекцию("Строка");

	КонецЦикла;

	

	Таб.ВывестиСекцию("Итого");		

	Таб.ТолькоПросмотр(1);

	Таб.Показать("Отчет по кассе");

КонецПроцедуры

Категория: Документы

Получение списка зарегистрированных на текущем компьютере баз 1С Предприятие 1Cv7

Код 1C v 7.x

 // Процедура получает из реестра список зарегистрированных ИБ 7.7

Процедура ПолучитьСписокИБ() 

	Попытка

		ScrptCtrl=Новый COMObject("MSScriptControl.ScriptControl");

		ScrptCtrl.Language="vbscript";

		ScrptCtrl.AddCode("

		|Function Get1CV77Titles()

		|	const HKEY_CURRENT_USER = &H80000001

		|	Set oReg=GetObject(""winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv"")

		|	strKeyPath = ""Software\1C\1Cv7\7.7\Titles""

		|	oReg.EnumValues HKEY_CURRENT_USER, strKeyPath, arrValues

		|	strInfo=vbNullString

		|   Get1CV77Titles = strInfo

		|	On Error Resume Next

		|	For i = LBound(arrValues) To UBound(arrValues)

		|		call oReg.GetStringValue(HKEY_CURRENT_USER,strKeyPath,arrValues(i),Value)

		|		strInfo=strInfo & arrValues(i) & vbTab & Value & vbCrLf

		|	Next		

		| 	Get1CV77Titles = strInfo

		|End Function

		|");

		Текст=СокрЛП(ScrptCtrl.Run("Get1CV77Titles"));

	Исключение

		Сообщить(ОписаниеОшибки());

		Возврат;

	КонецПопытки;

	

	ТаблицаПути.Очистить();

	

	Если НЕ ЗначениеЗаполнено(Текст) Тогда

		Возврат;

	КонецЕсли;

		

	Для Ном=1 По СтрЧислоСтрок(Текст) Цикл

		СтрБазы=СтрПолучитьСтроку(Текст,Ном);

		Разд=Найти(СтрБазы,Символы.Таб);

		Путь=Лев(СтрБазы,Разд-1);

		Название=Прав(СтрБазы,СтрДлина(СтрБазы)-Разд);

		

		НоваяСтрока = ТаблицаПути.Добавить();

		НоваяСтрока.Имя = Название;

		НоваяСтрока.Путь = Путь;

	КонецЦикла;

	

	ТаблицаПути.Сортировать("Имя");



КонецПроцедуры //ПолучитьСписокИБ

Функция возвращает список значений содержащий список баз установленных на данном компьютаре. В котором в качестве значения указывается путь до базы, а в представлении название базы, так как она отображается в окне выбора баз при запуске 1С. Если баз не обнаруженно то возвращает строку "Error"

Код 1C v 7.x

 

функция сзПолучитьСписокБаз()

    попытка

        // Создаем объект Microsoft Script Control.

        олеСкрипт = создатьобъект("MSScriptControl.ScriptControl");

        // Устанавливаем в качестве языка для выполнения сценариев Visual Basic

        олеСкрипт.Language = "VBScript";

        // Формируем код на VB.

        // В принципе он все делает. Создает объект

        // Windows Management Instrumentation и уже через него

        // получает значение ключи реестра преобразовывая данные

        // в строку.

        стрКод =

        "function strGetListBase()

        |  const RootKey = &H80000001

        |  set Reg = GetObject(""winmgmts:{impersonationLevel=impersonate}!\\."" &_

        |                      ""\root\default:StdRegProv"")

        |  PathKey = ""Software\1C\1Cv7\7.7\Titles""

        |  Reg.EnumValues RootKey, PathKey, Arr

        |  Answer = ""{""""СписокЗначений"""",{""

        |  for x = LBound(Arr) to UBound(Arr)

        |    call Reg.GetStringValue(RootKey, PathKey, Arr(x), Value)

        |    Answer = Answer & ""{{""""Строка"""","""""" &_

        |             Arr(x) & """"""},"""""" & replace(Value, """""""", """""""""""") &_

        |             """""",""""0""""}""

        |    if x <> UBound(Arr) then Answer = Answer & "",""

        |  next

        |  Answer = Answer & ""}}""

        |  strGetListBase = Answer

        |end function";

        // Добавляем наш код.

        олеСкрипт.AddCode(стрКод);

        // Вызываем его на выполнение, и пытаемся из полученного результата

        // сформировать список значений.

        Ответ = значениеизстроки(олеСкрипт.Run("strGetListBase"));

        // Отсортируем список по Представлению баз

        Ответ.СортироватьПоПредставлению();

    исключение

        // Если произошла ошибка. Значит вернем "Error".

        Ответ = "Error";

    конецпопытки;

    возврат Ответ;

конецфункции

Еще примеры! Получение списка баз 1С 7.7 из реестра

Категория: Полезные, Универсальные Функции