сохранением » Поиск

Результаты по ключевому слову: сохранением

ДеревоЗначений в ТекстовыйДокумент

Код 1C v 8.2 УП

 // Выводит данные ДереваЗначений в ТекстовыйДокумент, пригодный к рассмотрению в отладчике, окне сообщений и показу.

//

// Параметры:

//    рВетка - дерево значений, подлежащее выводу. Может иметь почти любую глубину иерархии, количество и тип колонок. Если хватит

//        объявленных позиционных строк-заполнителей, всё поместится. Если иерархия слишком глубока, строки просто надо нарастить;

//    рТекст - на входе должен быть равен Неопределено; на выходе по окончании работы содержит результатный текстовый документ;

//    рПараметры - структура дополнительных настроек, допустимые ключи:

//        Колонки - структура колонок, которые подлежат выводу. Если пуста или имеет тип, отличный от структуры, выводятся все колонки;

//           если в ключах структуры указаны имена колонок, будут выведены только они. В значениях структуры можно передать строковое

//           представление формата, согласно которому должны будут форматироваться выводимые значения. По умолчанию формата нет;

//        ПоказыватьУровни - булево, управляет выводом №№ уровней (метод Уровень()), по умолчанию выключено;

//        ШагОтступа - число, определяющее шаг в символах, используемый для показа псевдографики иерархии веток в дереве.

//

&НаСервереБезКонтекста

Процедура ВывестиДеревоЗначенийВТекст(Знач рВетка,рТекст,Знач рПараметры=Неопределено)

Попытка

    Если рТекст=Неопределено Тогда // первая итерация, шапочный вызов исходной части

        //---------------------------------------------------------------------------------------------------------------------------

        // Разбираем входные данные

        Если ТипЗнч(рВетка)<>Тип("ДеревоЗначений") Тогда Возврат КонецЕсли;

        Если ТипЗнч(рПараметры)<>Тип("Структура") Тогда рПараметры=Новый Структура КонецЕсли;

        стрКолонок=?(рПараметры.Свойство("Колонки"),рПараметры.Колонки,Неопределено);

        Если ТипЗнч(стрКолонок)<>Тип("Структура") Тогда стрКолонок=Новый Структура КонецЕсли;

        рПоказыватьУровни=?(рПараметры.Свойство("ПоказыватьУровни"),рПараметры.ПоказыватьУровни,Ложь); // затратное дело, кстати

        рШагОтступа=?(рПараметры.Свойство("ШагОтступа"),рПараметры.ШагОтступа,2); // для отображения отступа в колонке иерархии





        //---------------------------------------------------------------------------------------------------------------------------

        // Определяем максимальное количество уровней

        // Также можно получить максимальный уровень, "плоско" перебрав все строки (например, получив их через НайтиСтроки)

        // и в цикле для каждой вызывая Уровень() и определяя максимум.

        // Вариант через СКД и служебное поле "Уровень" ни на одной известной мне платформе не работоспособен (нехватка памяти).

        //

        //

        //рДеревоДляТеста=КакНибудьСкопироватьДерево(рВетка);

        //рДеревоДляТеста.Колонки.Вставить(0,"_Level",Новый ОписаниеТипов("Булево")); // самый экономный вариант, с сохранением иерархии

        //мНенужных=Новый Массив;

        //Для й=1 По рДеревоДляТеста.Колонки.Количество()-1 Цикл

        //  мНенужных.Добавить(рДеревоДляТеста.Колонки[й]);

        //КонецЦикла;

        //Для каждого кол Из мНенужных Цикл

        //  рДеревоДляТеста.Колонки.Удалить(кол);

        //КонецЦикла;

        //

        рДеревоДляТеста=рВетка; // пока сериализуем прямо всё дерево (неоптимально, но...)

        рЗапись=Новый ЗаписьXML;

        рЗапись.УстановитьСтроку();

        СериализаторXDTO.ЗаписатьXML(рЗапись,рДеревоДляТеста);

        стро=рЗапись.Закрыть();

        //

        стро=СтрЗаменить(стро,"xmlns=","xmlns:myns1C="); // иначе не будет работать XPath

        //

        рЧтение=Новый ЧтениеXML;

        рЧтение.УстановитьСтроку(стро);

        постр=Новый ПостроительDOM;

        рДокументДОМ=постр.Прочитать(рЧтение);





        рВыражение="/ValueTree/row"; максКолвоУровней=1;

        рРазыменователь=Новый РазыменовательПространствИменDOM(рДокументДОМ);

        Пока Истина Цикл

            #Если Клиент Тогда

                ОбработкаПрерыванияПользователя();

            #КонецЕсли

            рРезультат=рДокументДОМ.ВычислитьВыражениеXPath(рВыражение,рДокументДОМ,рРазыменователь,ТипРезультатаDOMXPath.Любой);

            Если рРезультат.ПолучитьСледующий()=Неопределено Тогда Прервать КонецЕсли;

            рВыражение=рВыражение+"/row";

            максКолвоУровней=максКолвоУровней+1;

        КонецЦикла;

        максКолвоУровней=максКолвоУровней-1; // можно и так: СтрЧислоВхождений(рВыражение,"/row")-1;





        //---------------------------------------------------------------------------------------------------------------------------

        // готовим исходный макет вывода

        строПробелы="                                                                                                                                                                                                                 ";

        строРазделители="===============================================================================================";

        строОтступы="___________________________________________________________________________________________"; // тут нужны чуть для другого

        //

        секШапка1="|[_HCS"+Лев(строПробелы,максКолвоУровней*рШагОтступа)+"]|"; // HierarchyColumnShow

        секГорРазделитель1="|"+Лев(строОтступы,максКолвоУровней*рШагОтступа+6)+"|"; // здесь именно Отступы!

        рШиринаКолонкиИерархии=СтрДлина(секШапка1)-2;

        строПолейШапки="#Поле _HCS

        |   #Выравнивание Центр";

        строПолейЗаписи="";

        //

        Если рПоказыватьУровни Тогда

            секШапка1=секШапка1+"[_Level]|";

            секГорРазделитель1=секГорРазделитель1+Лев(строРазделители,8)+"|";

            строПолейШапки=строПолейШапки+"

            |#Поле _Level

            |   #Выравнивание Центр";

            строПолейЗаписи="#Поле _Level

            |   #Выравнивание Центр

            |   #Забивать Истина";

        КонецЕсли;

        //

        мИменКолонок=Новый Массив;

        Для каждого кол Из рВетка.Колонки Цикл

            Если стрКолонок.Количество()<>0 и не стрКолонок.Свойство(кол.Имя) Тогда Продолжить КонецЕсли; // чётко указаны конкретные колонки

            рДлинаИмениКолонки=СтрДлина(кол.Имя);

            рНужнаяШирина=Макс(?(кол.Ширина<3,10,кол.Ширина),рДлинаИмениКолонки);

            // к сожалению, ключевое слово "#Поля" неприменимо - платформа падает - поэтому делаем всё сами

            секШапка1=секШапка1+"["+кол.Имя+Лев(строПробелы,рНужнаяШирина-рДлинаИмениКолонки)+"]|";

            секГорРазделитель1=секГорРазделитель1+Лев(строРазделители,рНужнаяШирина+1)+"=|";

            строПолейШапки=строПолейШапки+"

            |#Поле "+кол.Имя+"

            |   #Выравнивание Центр";

            рОписТипов=кол.ТипЗначения;

            Если рОписТипов.Типы().Количество()=1 и рОписТипов.СодержитТип(Тип("Булево")) Тогда

                рВыравнивание="Центр";

            ИначеЕсли рОписТипов.СодержитТип(Тип("Число")) Тогда

                рВыравнивание="Право";

            ИначеЕсли рОписТипов.СодержитТип(Тип("Строка")) и рОписТипов.КвалификаторыСтроки.Длина=0 Тогда

                рВыравнивание="ПоШирине";

            Иначе

                рВыравнивание="Лево";

            КонецЕсли;

            строПолейЗаписи=строПолейЗаписи+?(ПустаяСтрока(строПолейЗаписи),"",Символы.ПС)+"#Поле "+кол.Имя+"

            |   #Выравнивание "+рВыравнивание;

            Попытка

                Если ЗначениеЗаполнено(стрКолонок[кол.Имя]) Тогда // указан формат, уточняющий показ колонки

                    строПолейЗаписи=строПолейЗаписи+"

                    |   #Формат """+СокрЛП(стрКолонок[кол.Имя])+"""";

                КонецЕсли;

            Исключение

            КонецПопытки;

            мИменКолонок.Добавить(кол.Имя);

        КонецЦикла;

        секШапка2=СтрЗаменить(СтрЗаменить(секШапка1,"[","<"),"]",">");

        секЗапись1=секШапка1; секЗапись2=секШапка2; // пусть они по дизайну пока не отличаются

        секГорРазделитель2=СтрЗаменить(СтрЗаменить(секГорРазделитель1,"=","-"),"|","+");

        // обработаем нормальное обрамление шапки колонки иерархии

        секГорРазделитель1=СтрЗаменить(секГорРазделитель1,"_","=");

        секГорРазделитель2=СтрЗаменить(секГорРазделитель2,"_"," ");

        //

        тМакет=Новый ТекстовыйДокумент;

        тМакет.ДобавитьСтроку("#Область Шапка");

        тМакет.ДобавитьСтроку(строПолейШапки);

        тМакет.ДобавитьСтроку(секГорРазделитель1);

        тМакет.ДобавитьСтроку(секШапка1);

        тМакет.ДобавитьСтроку(секШапка2);

        тМакет.ДобавитьСтроку(секГорРазделитель1);

        тМакет.ДобавитьСтроку("#КонецОбласти");

        тМакет.ДобавитьСтроку("");

        тМакет.ДобавитьСтроку("#Область Запись");

        тМакет.ДобавитьСтроку(строПолейЗаписи);

        тМакет.ДобавитьСтроку(секЗапись1);

        тМакет.ДобавитьСтроку(секЗапись2);

        тМакет.ДобавитьСтроку(секГорРазделитель2);

        тМакет.ДобавитьСтроку("#КонецОбласти");

        рПараметры.Вставить("ИсходныйМакет",тМакет); // пусть будет





        //---------------------------------------------------------------------------------------------------------------------------

        // Запускаем вывод в итоговый документ

        рТекст=Новый ТекстовыйДокумент;

        сек=тМакет.ПолучитьОбласть("Шапка");

        сек.Параметры._HCS="Иерархия";

        Для каждого имякол Из мИменКолонок Цикл

            кол=рВетка.Колонки[имякол];

            сек.Параметры[кол.Имя]=?(ПустаяСтрока(кол.Заголовок),кол.Имя,кол.Заголовок);

        КонецЦикла;

        рТекст.Вывести(сек);

        //

        пар=Новый Структура;

        пар.Вставить("МассивИмёнКолонок",мИменКолонок);

        пар.Вставить("ТекущаяСекция",тМакет.ПолучитьОбласть("Запись"));

        пар.Вставить("ШиринаКолонкиИерархии",рШиринаКолонкиИерархии);

        пар.Вставить("ПоказыватьУровни",рПоказыватьУровни);

        пар.Вставить("Отступ",0);

        пар.Вставить("ШагОтступа",рШагОтступа);

        ВывестиДеревоЗначенийВТекст(рВетка,рТекст,пар);





    Иначе

        // очередная итерация, вывод в текстовый документ

        мИменКолонок=рПараметры.МассивИмёнКолонок;

        рСекция=рПараметры.ТекущаяСекция;

        рОтступ=рПараметры.Отступ;

        рШиринаКолонкиИерархии=рПараметры.ШиринаКолонкиИерархии;

        рПоказыватьУровни=рПараметры.ПоказыватьУровни;

        //

        строОтступы="_________________________________________________________________________________________________________";

        строПробелы="                                                                                                                                                                                                                 ";

        //

        пар=Новый Структура;

        пар.Вставить("МассивИмёнКолонок",мИменКолонок);

        пар.Вставить("ТекущаяСекция",рПараметры.ТекущаяСекция);

        пар.Вставить("ШиринаКолонкиИерархии",рШиринаКолонкиИерархии);

        пар.Вставить("ПоказыватьУровни",рПоказыватьУровни);

        пар.Вставить("ШагОтступа",рПараметры.ШагОтступа);

        пар.Вставить("Отступ",рОтступ+рПараметры.ШагОтступа);

        //

        Для каждого рПодветка Из рВетка.Строки Цикл

            рСекция.Параметры._HCS=Лев(строПробелы,рОтступ)+"\"+Лев(строОтступы,рШиринаКолонкиИерархии-рОтступ-1);

            Если рПоказыватьУровни Тогда

                рСекция.Параметры._Level=рПодветка.Уровень();

            КонецЕсли;

            Для каждого имякол Из мИменКолонок Цикл

                рСекция.Параметры[имякол]=рПодветка[имякол];

            КонецЦикла;

            рТекст.Вывести(рСекция);

            ВывестиДеревоЗначенийВТекст(рПодветка,рТекст,пар)

        КонецЦикла;

        //

    КонецЕсли;

Исключение

    Сообщить("ВывестиДеревоЗначенийВТекст, ошибка: "+ОписаниеОшибки(),СтатусСообщения.ОченьВажное);

КонецПопытки;

КонецПроцедуры

Источник

Категория: Работа с Деревом Значений

Как снять конфигурацию с поддержки?

Необходимость снять конфигурацию с поддержки может возникнуть по разным причинам. Чаще всего это нужно для внесения изменений в конфигурацию. Так же при обновлении конфигурации *.cf файлом нужно будет делать эту операцию.Снять конфигурацию с поддержки означает, что мы снимаем конфигурацию с поддержки поставщика (разработчика конфигурации) и конфигурацию теперь является не типовой.

Отмечу, что при обращении к разработчикам за помощью специалисты техподдержки всегда уточняют, снята ли конфигурация с поддержки. Если это так, то вам скорее всего откажут в помощи. При внесении изменений в конфигурацию в дальнейшем могут возникнуть проблемы с обновлением, потому не стоит прибегать к этому без надобности.

Тем не менее, иногда без снятия с поддержки не обойтись. Заходим в информационную базу в режиме "Конфигуратор". Если конфигурация не открыта, то нажимаем на кнопку "Открыть конфигурацию для редактирования".

Значок с замком означает, что конфигурация не редактируется. Объект поставщика не редактируется

Переходим пункт меню Конфигурация -> Поддержка -> Настройка поддержки.

В открывшемся окне нажимаем на кнопку "Включить возможность изменения"

Программа предупреждает о дальнейших проблемах с автоматическим обновлением, нажимаем "ОК"

Далее необходимо настроить правила поддержки. Правило "Объект поставщика редактируется с сохранением поддержки" означает, что объекты можно изменять, но при обновлении все изменения затрутся, если не убрать галочки в сравнении конфигураций. Правило "Объект поставщика снят с поддержки" означает, что все объекты открыты для изменений.

Нажимаем "ОК". После принятия изменений в окне "Настройка поддержки" пропадет кнопка "Включить возможность изменения" и появится надпись "Конфигурация находится на поддержке с возможностью изменения"

Значок замочка пропал, значит конфигурация доступна для изменений.

Сохраните изменения нажав F7 или

Категория: Администрирование

Загрузка картинок в базу 1С (сохранение в хранилище значений)

В теме форма: v8: Получение данных из ХралищаЗначений

Bell в управляемом интерфейсе пробует сохранить выбранные картинки в базу 1С, но возникли сложности с сохранением в хранилище значений. как пример Bell приложил CF файл с мини конфигурацией, за что ему большое спасибо, т.к. большая часть материалов этой статьи написана им, я лишь поправил небольшие участки кода связанные с передачей файлов и сохранение в хранилище значений.

Так как везде уже Такси, то CF я перевел в этот режим и в нем демонстрирую.

Имеется справочник Хранилище данных:

Основная Форма Элемента:

Ее код:

Код 1C v 8.3

 // ПРОЦЕДУРЫ ФОРМЫ

//======================================================================================================

&НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

	

	Если Объект.Ссылка.Пустая() Тогда

			Объект.Наименование = ".";

	КонецЕсли;

		

	Если НЕ Параметры.Ключ.Пустая() Тогда

	   ДанныеАдрес = ПолучитьНавигационнуюСсылку(Объект.Ссылка, "ДанныеХЗ");

	КонецЕсли;

	

КонецПроцедуры

&НаКлиенте

Процедура ПриОткрытии(Отказ)

	

	Если Объект.Ссылка.Пустая() Тогда

	КонецЕсли;





КонецПроцедуры

&НаСервере

Процедура ПередЗаписьюНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи)

	

	Если ЭтоАдресВременногоХранилища(ДанныеАдрес) Тогда

		

		РежимСжатия              = Новый СжатиеДанных(9);

		ДанныеСохранения         = ПолучитьИзВременногоХранилища(ДанныеАдрес);

		ТекущийОбъект.ДанныеХЗ   = Новый ХранилищеЗначения(ДанныеСохранения, РежимСжатия);

		

	КонецЕсли;

	

КонецПроцедуры

&НаСервере

Процедура ПриЗаписиНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи)

	

	Если ЭтоАдресВременногоХранилища(ДанныеАдрес) Тогда

		УдалитьИзВременногоХранилища(ДанныеАдрес);

		ДанныеАдрес =  ПолучитьНавигационнуюСсылку(ТекущийОбъект.Ссылка, "ДанныеХЗ");

	КонецЕсли;





КонецПроцедуры





// ПРОЦЕДУРЫ ЭЛЕМЕНТОВ ФОРМЫ

//======================================================================================================





&НаКлиенте

Процедура ВыбратьДанные(Команда)

	

	ДанныеВыбрать();





КонецПроцедуры





&НаКлиенте

Процедура СохранитьДанные(Команда)

  	

	Если НЕ ЗначениеЗаполнено(Объект.Ссылка) Тогда

		Предупреждение(НСтр("ru = 'Элемент не записан !!!'"));

		Возврат;

	КонецЕсли;

	

	ДанныеСохранения = ПолучитьНавигационнуюСсылку(Объект.Ссылка, "ДанныеХЗ");

	ИмяСохранения    = Объект.Наименование; 

	//ИмяСохранения    = Объект.Наименование + Объект.ДанныеРасширение; 

    ПолучитьФайл(ДанныеСохранения, ИмяСохранения, Истина);

	

КонецПроцедуры





// ПРОЦЕДУРЫ ПРОЧИЕ

//======================================================================================================





&НаКлиенте

Процедура ДанныеВыбрать()

	

	ПолученныеДанныеАдрес = "";

	Если ПоместитьФайл(ПолученныеДанныеАдрес, , Объект.ДанныеПуть, Истина, УникальныйИдентификатор)Тогда

		

		ДанныеАдрес = ПолученныеДанныеАдрес;

		

		ВыбранныйФайл = Новый Файл(Объект.ДанныеПуть);

		Объект.Наименование          =  ВыбранныйФайл.Имя;

		Объект.ДанныеТекущаяДата     =  ТекущаяДата();

		

		Модифицированность = Истина; 		

	КонецЕсли;

 	

КонецПроцедуры

так же имеется общая форма ФормаЗагрузкиФайлов

При помощи ее выбираются файлы изображений и загружаются в справочник - одновременно можно загружать несколько файлов

код формы:

Код 1C v 8.3

 // ПРОЦЕДУРЫ ЭЛЕМЕНТОВ ФОРМЫ

//======================================================================================================

&НаКлиенте

Процедура СписокФайловПередНачаломДобавления(Элемент, Отказ, Копирование, Родитель, Группа)

	

	Отказ = Истина;

	

	ДобавитьФайлы();





КонецПроцедуры



// ПРОЦЕДУРЫ ПРОЧИЕ

//======================================================================================================

&НаКлиенте

Процедура ДобавитьФайлы()

	

	ВыборФайла = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);

	ВыборФайла.МножественныйВыбор = Истина;

	ВыборФайла.Заголовок = НСтр("ru = 'Выбор файла'", "ru");

	ВыборФайла.Фильтр = НСтр("ru = 'Все файлы'", "ru") + " (*.*)|*.*";

	ВыборФайла.ПредварительныйПросмотр = Истина;

	Если ВыборФайла.Выбрать() Тогда

		

		Для каждого СтрокаФайл Из ВыборФайла.ВыбранныеФайлы Цикл

			

			ОписаниеФайла = Новый Файл(СтрокаФайл);

			

			НВС = СписокФайлов.Добавить();

			НВС.ПолноеИмяФайла   = СтрокаФайл; 

			НВС.РазмерФайла      = ОписаниеФайла.Размер();

			

		КонецЦикла;

		

	КонецЕсли;

		

КонецПроцедуры

&НаКлиенте

Процедура Загрузить()

	

	Если НЕ ПроверитьЗаполнение() Тогда

		Возврат;

	КонецЕсли;

	

	ОчиститьСообщения();

	Если СписокФайлов.Количество() = 0 Тогда

		Сообщить("Файлы не выбраны !!!'");

		Возврат;

	КонецЕсли;

	

	ПомещаемыеФайлы = Новый Массив;

	Для каждого СтрокаФайл Из СписокФайлов Цикл

		Описание = Новый ОписаниеПередаваемогоФайла(СтрокаФайл.ПолноеИмяФайла, "");

		ПомещаемыеФайлы.Добавить(Описание);

	КонецЦикла;

	

	// -------------------------------------------------------------------------------

	ПомещенныеФайлы         = Новый Массив;

	СписокЗагруженныхФайлов = Новый СписокЗначений;

	

	Если ПоместитьФайлы(ПомещаемыеФайлы, ПомещенныеФайлы, , Ложь, УникальныйИдентификатор) Тогда

		

		Закрыть(Истина);

		

	Иначе

		

		Сообщение = Новый СообщениеПользователю();

		Сообщение.Текст = НСтр("ru = 'Файлы не загружены'", "ru");

		Сообщение.Сообщить();

		

	КонецЕсли;





	ОповеститьОВыборе(ПомещенныеФайлы);





КонецПроцедуры

&НаСервере

Функция ПоместитьВыбранныеФайлыВХранилище(ПомещаемыеФайлы)

	

	АдресХЗ = ПоместитьВоВременноеХранилище(ПомещаемыеФайлы, УникальныйИдентификатор);

	Возврат АдресХЗ;

КонецФункции

в коде вызывается ОповеститьОВыборе(ПомещенныеФайлы) и срабатывает обработчик в ФормаСпискаДополнительно

Код 1C v 8.3

 &НаКлиенте

Процедура ОбработкаВыбора(ВыбранноеЗначение, ИсточникВыбора)

	

	Если ИсточникВыбора.ИмяФормы = "ОбщаяФорма.ФормаЗагрузкиФайлов" Тогда

		ОбработкаВыбораПодборНаСервере(ВыбранноеЗначение);

	КонецЕсли;

	

КонецПроцедуры

и следующим кодом идет создание элементов справочника и загрузка изображений из временного хранилища

Код 1C v 8.3

 &НаСервере

Процедура ОбработкаВыбораПодборНаСервере(ВыбранноеЗначение)

	

	Для Каждого СтрокаФайл Из ВыбранноеЗначение Цикл 		

		Файл = Новый Файл(СтрокаФайл.Имя);

		ХранимыйФайл = Справочники.ХранилищеДанныхСправочники.СоздатьЭлемент();

		ХранимыйФайл.Наименование                      = Файл.Имя;

		ХранимыйФайл.ДанныеПуть                        = Файл.Путь;

		ХранимыйФайл.ДанныеТекущаяДата                 = ТекущаяДата();

		ХранимыйФайл.ДанныеХЗ = Новый ХранилищеЗначения(ПолучитьИзВременногоХранилища(СтрокаФайл.Хранение), Новый СжатиеДанных());

 		ХранимыйФайл.Записать();

	КонецЦикла;

	

	Элементы.Список.Обновить();

	

КонецПроцедуры

Скачать DT - Платформа 8.3.4

Категория: Работа с Хранилищем Значений

ЗначениеВСтрокуВнутр / ЗначениеИзСтрокиВнутр

Эту статью я посвящаю двум процедурам ЗначениеВСтрокуВнутр и ЗначениеИзСтрокиВнутр. Они являются полным «антиподом действий» друг другу, а разработчики 1с предприятия отнесли их в раздел «Процедуры и функции сохранения значений».
Почему именно так они названы, для чего они полезны ну и конечно же почему эти функции ассоциируются с сохранением значений попробую разъяснить.
С этими функциями я познакомился еще, когда начинал свою деятельность 1с программиста в программных продуктах семейства 1с предприятия версии 7.7, обратил я на них внимание впервые, когда мне необходимо было сохранять сложные типы данных (например, заполненную таблицу значений, структуру и т.д.).
А т.к. средствами 1с можно представить различные типы значений в виде строки (с использованием процедуры ЗначениеВСтрокуВнутр), задачка моя упростилась. И вот собственно описание этих двух простых, но очень полезных функций.

ЗначениеВСтрокуВнутр
Функция ЗначениеВСтрокуВнутр преобразует или другими словами приводит в строковое представление данные, т.е. данные преобразуются в специальный строковый формат, который можно использовать только внутри одной информационной базы, это очень важно!
Например, у нас есть массив:

Код 1C v 8.х

 структураВидовТоваров = новый массив;

структураВидовТоваров.Добавить(«Тара»);

структураВидовТоваров.Добавить(«Контейнер»);

структураВидовТоваров.Добавить(«Паллет»);

А преобразование данного массива в строковое представление будет иметь вид:
{«#»,51e7a0d2-530b-11d4-b98a-008048da3034,{3, {«S»,»Тара»},{«S»,»Контейнер»},{«S»,»Паллет»}}}

ЗначениеИзСтрокиВнутр
Функция ЗначениеИзСтрокиВнутр производит обратное преобразование из строкового представления данных во внутреннее представление системы 1с предприятия. Т.е. если выполнить код вида:

Код 1C v 8.х

 МассивЗначений = ЗначениеИзСтрокиВнутр(“{«#»,51e7a0d2-530b-11d4-b98a-008048da3034,{3,{«S»,»Тара»},{«S»,»Контейнер»},{«S»,»Паллет»}}});

Мы в переменную «МассивЗначений» передаем уже не строку, а определенный тип данных «Массив» причем массив уже заполненный ранее.
Источник

Категория: Встроенные Функции

Чтение и Вывод данных в Excel

Замечание: В Excel разделителем дробной части считается символ ",". Поэтому перед сохранением таблицы 1С в формате Excel замените в ней другой разделитель (например ".") на ",". Иначе в Excel с этими числами не удастся произвести вычисления, или они вообще не будут отображаться как числа. Например, в таблице 1С "15.2" отобразится в Excel как "15.фев".

Для 8.х заменить СоздатьОбъект( на Новый COMОбъект(

Чтение (Получение) данных из Excel
Доступ из 1С к Excel производится посредством OLE. Например, код

Код 1C v 7.x

 Попытка

 Эксель = СоздатьОбъект("Excel.Application");

Исключение

 Сообщить(ОписаниеОшибки() + " Программа Exсel не установлена на данном компьютере!");

 Возврат;

КонецПопытки;

позволит получить доступ через переменную "Эксель" к запущенному приложению Excel. А далее уже можно получить доступ к книге (файлу), листу и ячейке с данными.Чтобы открыть книгу (файл)

Код 1C v 7.x

 Книга = Эксель.WorkBooks.Open(ПутьКФайлу);

//ПутьКФайлу - полный путь к файлу книги Excel.



//Выбор листа книги для работы с ним:

Лист = Книга.WorkSheets(НомерЛиста);

//или

Лист = Книга.WorkSheets(ИмяЛиста);

// где НомерЛиста - номер листа в книге, ИмяЛиста - имя листа в книге.



// Получение значения ячейки листа:

Значение = Лист.Cells(НомерСтроки, НомерКолонки).Value;

// где НомерСтроки, НомерКолонки - номер строки и номер колонки, на пересечении которых находится ячейка.

Важно: не забывайте поле выполнения нужных действий добавлять код

Код 1C v 7.x

 Эксель.Quit();

, иначе запущенный процесс останется незавершенным и будет занимать память и процессор компьютера.

Вывод данных в Excel
Для вывода (выгрузки) данных в Excel необходимо либо открыть существующую книгу, либо создать новую, и выбрать рабочий лист для вывода данных. Открытие существующей книги описано выше, а для создания новой книги нужно использовать следующий код:

Код 1C v 7.x

 Попытка

 Эксель = СоздатьОбъект("Excel.Application");

Исключение

 Сообщить(ОписаниеОшибки() + " Программа Exсel не установлена на данном компьютере!");

 Возврат;

КонецПопытки;



Книга = Эксель.WorkBooks.Add();

Так как при создании книги в Excel автоматически создаются листы (Сервис->Параметры->Общие->Листов в новой книге), то нужно лишь произвести выбор листа, с которым будет вестись работа:

Код 1C v 7.x

 Лист = Книга.WorkSheets(НомерЛиста);



// либо добавить в книгу новый лист, если необходимо:

Лист = Книга.Sheets.Add();

Следующим шагом будет установка значения ячейки:

Код 1C v 7.x

 Лист.Cells(НомерСтроки, НомерКолонки).Value = Значение;

// где НомерСтроки, НомерКолонки - номер строки и номер колонки, на пересечении которых находится ячейка.

И в конце нужно произвести запись созданной книги:

Код 1C v 7.x

 Попытка

 Книга.SaveAs(ПутьКФайлу);

Исключение

 Сообщить(ОписаниеОшибки()+" Файл не сохранен!");

 Возврат;

КонецПопытки;

// где ПутьКФайлу - полный путь к файлу книги Excel (включая имя).

Важно: не забывайте, что в имени файлов не должно содержаться символов \ / : * ? " > <

Категория: Работа с Microsoft Office и OpenOffice

Универсальное использование HTML Редактора

Гуляя по просторам интернета, случайно наткнулся на обработку HTML Редактор (Андрей Михайлов aka MAV):

title

Далее, пришла в голову интересная идея, сделать красивыми комментарии в документах ( у нас они очень большие и многострочные, в отдельной закладке), с поддержкой копирования информации из WORD и EXCEL, с сохранением всех цветов и стилей. Подредактировав данную обработку, стали доступны следующие функции:

1. Добавление текста

2. Добавление, просмотр и печать

3. Просмотр и печать

Теперь, более подробно:

Вот так выгляди поле комментариев в нашей базе:
title

1. Нажав на кнопку "Добавить комментарий" срабатывает Процедура ДобавитьКоммент(Элемент)

Код 1C v 8.х

 

Процедура ДобавитьКоммент(Элемент)

 форм=обработки.HTML.ПолучитьФорму("Форма");

 текст = форм.ОткрытьМодально();

 если не Пустаястрока(текст) тогда

  комментарий="Добавил: "+глтекущийпользователь+" , Добавлено: "+текущаядата()+текст+комментарий;

 ЭлементыФормы.ПолеHTMLДокумента.УстановитьТекст(комментарий);

 конецесли; 

КонецПроцедуры

2. Процедура вызова "Добавление, просмотр и печать"

Код 1C v 8.х

 

Процедура ВставитьПланГрафик(Кнопка)

 форм=обработки.HTML.ПолучитьФорму("ФормаПросмотра");

 форм.текст=ПланГрафик;

 текст=форм.ОткрытьМодально();

 ПланГрафик=текст+ПланГрафик;

КонецПроцедуры

Откроется форма, вида:
title

Нажав на "Добавить запись" и вставив Таблицу из Excel:
title

Нажимаем Добавить и получаем:
title

3. Просмотр и печать

Код 1C v 8.х

 

Процедура ИсторияИзмененийПросмотр(Кнопка)

 форм=обработки.HTML.ПолучитьФорму("Просмотр");

 форм.текст=ИсторияИзменений;

 форм.ОткрытьМодально();

КонецПроцедуры

Откроется форма просмотра реквизита ИсторияИзменений.

Обработка HTML редактор:
Для 8.0
Для 8.1

Категория: Полезные, Универсальные Функции

Как вывести иерархический справочник

Для вывода иерархического справочника в отчет с сохранением иерархии необходимо пользоваться запросом аналогичным следующему:

Код 1C v 8.х

 ВЫБРАТЬ

    Номенклатура.Код, 

    Номенклатура.Наименование КАК Наименование, 

    Номенклатура.ЗакупочнаяЦена 

ИЗ 

    Справочник.Номенклатура КАК Номенклатура 

УПОРЯДОЧИТЬ ПО 

    Наименование ИЕРАРХИЯ

Данный запрос выбирает все записи из справочника и производит упорядочивание по иерархии. Результат будет упорядочен по наименованию, с учетом иерархии.

Для того чтобы группы справочника размещались выше элементов необходимо в данном запросе заменить предложение УПОРЯДОЧИТЬ ПО на следующее:

Код 1C v 8.х

 УПОРЯДОЧИТЬ ПО 

    Номенклатура.ЭтоГруппа ИЕРАРХИЯ, 

    Наименование

Результат по-прежнему будет упорядочен по иерархии, однако группы будут располагаться выше элементов.

Возможна также замена предложения УПОРЯДОЧИТЬ ПО на предложение АВТОУПОРЯДОЧИВАНИЕ. В этом случае результат будет упорядочен в соответствии с настройками справочника, т.е. если в справочнике указано, что группы должны располагаться выше элементов, то они будут расположены выше.

Получить иерархическую структуру справочника также возможно и при помощи итогов.

Код 1C v 8.х

 ВЫБРАТЬ 

    Номенклатура.Код, 

    Номенклатура.Наименование КАК Наименование, 

    Номенклатура.ЗакупочнаяЦена 



ИЗ Справочник.Номенклатура КАК Номенклатура 



ГДЕ 

    (Номенклатура.ЭтоГруппа = ЛОЖЬ) 



УПОРЯДОЧИТЬ ПО Наименование 



ИТОГИ ПО Номенклатура.Ссылка ТОЛЬКО ИЕРАРХИЯ

Категория: Справочники

Копирование данных из одного созданного экселя в другой и открытие excel (с сохранением форматов)

Копирование данных из одного созданного экселя в другой и открытие excel (с сохранением шрифта, рамки положения текста) и с созданием закладки на которую как раз копируются данные:

Код 1C v 8.х

 // Данный код создает эксель, с одним листом и открывает в нем файл

	// далее тут же создается второй лист с нужным нам наименованием

	// и в созданный второй лист копируем данные из другого экселя, с сохранением всех атрибутов текста

	

Процедура КопируемЕксел()	

	ДокExcel = Новый COMОбъект("Excel.Application");

	

	// этот кусок отвечает за создание чистого листа

	//ДокExcel.Application.Workbooks.Application.Workbooks.Add(1);

	//ДокExcel.Application.Workbooks.Application.ActiveSheet.Application.Workbooks.Open("d:\temp\file.xls");

	

	// а здесь мы просто открываем любой указанный файл

	ДокExcel.Application.Workbooks.Application.Workbooks.Open("d:\temp\file.xls");

	ДокExcel.Application.Workbooks.Application.ActiveSheet.Name = "Отчет Общий";

	

	// создаем второй лист с наименованием "Отчет Региональный"

	ДокExcel.Application.Workbooks.Application.ActiveWorkbook.Worksheets.Add();

	ДокExcel.ActiveWorkbook.Sheets.Application.ActiveSheet.Name = "Отчет Региональный";

	

	

	xlLastCell = 11;

	Попытка

		Excel = Новый COMОбъект("Excel.Application");

		Excel.WorkBooks.Open("d:\temp\Региональный.xls");

		Состояние("Обработка файла Microsoft Excel...");

		ExcelЛист = Excel.Sheets(1);

	Исключение

		Сообщить("Ошибка. Возможно неверно указан номер листа книги Excel.");

	КонецПопытки;



	ActiveCell = Excel.ActiveCell.SpecialCells(xlLastCell);

	RowCount = ActiveCell.Row; // количество строк 

	ColumnCount = ActiveCell.Column; // колиество колонок

	

	Для Column = 1 По ColumnCount Цикл

		// Выставляем ширину колонок

		ДокExcel.Columns(Column).ColumnWidth = ExcelЛист.Columns(Column).ColumnWidth;

	КонецЦикла;



	Для Row = 1 По RowCount Цикл

		Для Column = 1 По ColumnCount Цикл

			

			// переносим значение ячейки

			ДокExcel.Cells(Row,Column).Value = ExcelЛист.Cells(Row,Column).Value;

			

			// Устанавливаем шрифт

			ДокExcel.Cells(Row,Column).Font.Size = ExcelЛист.Cells(Row,Column).Font.Size;

			ДокExcel.Cells(Row,Column).Font.Bold = ExcelЛист.Cells(Row,Column).Font.Bold; 

			

			// объединяем ячейки

			ДокExcel.Range(ExcelЛист.Cells(Row,Column).MergeArea.Address).Select(); 

			ДокExcel.Selection.Merge(); 

			

			// обводим ячейки рамкой

			ДокExcel.Range(ExcelЛист.Cells(Row,Column).MergeArea.Address).Borders.LineStyle = ExcelЛист.Cells(Row,Column).MergeArea.Borders.LineStyle; // рисуем рамку для одной ячейки или даипазона ячеек

			ДокExcel.Range(ДокExcel.Cells(Row,Column), ДокExcel.Cells(Row,Column)).Borders.LineStyle = ExcelЛист.Cells(Row,Column).MergeArea.Borders.LineStyle; // рисуем рамку для одной ячейки или даипазона ячеек

			ДокExcel.Range(ДокExcel.Cells(Row,Column), ДокExcel.Cells(Row,Column)).WrapText = Истина; // автоматический перенос больших строк  

			ДокExcel.Range(ДокExcel.Cells(Row,Column), ДокExcel.Cells(Row,Column)).VerticalAlignment = -4108; // Выравнивание по вертикали по центру  //ExcelЛист.Cells(Row,Column).VerticalAlignment;

			ДокExcel.Range(ДокExcel.Cells(Row,Column), ДокExcel.Cells(Row,Column)).HorizontalAlignment = - 4108; // Выравнивание по горизонтали по центру

			

		КонецЦикла;

	КонецЦикла;

	

	Excel.WorkBooks.Close();

	Excel = 0;

	ДокExcel.Visible=1; //Делаем Ексель видимым

	

	// Дополнительные параметры

	//Exel.WorkBooks(1).WorkSheets(1).Cells(1,1).Interior.ColorIndex=1;    //1= белый  фон

	//Exel.WorkBooks(1).WorkSheets(1).Cells(1,1).Font.ColorIndex=2;   //2= черный цвет шрифта

	//Exel.WorkBooks(1).WorkSheets(1).Cells(1,1).Font.Name= "Courier";   // указывает какой шрифт

	//Exel.WorkBooks(1).WorkSheets(1).Cells(1,1).Font.Size=12;     //размер шрифта

	//Exel.WorkBooks(1).WorkSheets(1).Cells(1,1).Font.Bold=1; либо (0); //т.е. истина либо лож - ?(обычный, жирный)

	//Exel.WorkBooks(1).WorkSheets(1).Cells(1,1).InsertIndent(2); //устанавливаем отступ (в данном случае на 2 символа)

	//Exel.WorkBooks(1).WorkSheets(1).Cells(1,1).ColumnWidth= 10;   // ширина колонки

	//Exel.WorkBooks(1).WorkSheets(1).Cells(1,1).Borders(5).LineStyle = -4142;   //очищаем все границы

	//Exel.WorkBooks(1).WorkSheets(1).Cells(1,1).Borders(7).LineStyle=1;   //добавили левую границу (7 - левая, 8 - верхняя, 9 - нижняя, 10 - правая )

	//Exel.WorkBooks(1).WorkSheets(1).Cells(1,1).VerticalAlignment = -4160; //выравнивание по левому краю

	//Exel.WorkBooks(1).WorkSheets(1).Cells(1,1).WrapText=1 (истина)   //устанавливаем перенос слов

	

	//Всего 56 цветов:

	//1- белый

	//2-черный

	//3-красный

	//5-синий

	//6-желтый

	//7-лиловый

	//10-зеленый

	//33-голубой

	//39-сиреневый

	//46-оранжевый

	

	//адрес ячейки:

	//.Address

	

	//Прямоугольная область ячеек:

	//Exel.WorkBooks(1).WorkSheets(2).Range("a1:b2");

	//Exel.WorkBooks(1).WorkSheets(2).Range("a1:b2").Copy();

	//Exel.WorkBooks(1).WorkSheets(2).Range("a11:b12").Select();

	//Exel.WorkBooks(1).WorkSheets(2).Paste();



	

	//Про Диаграммы:



	//Два варианта: 1-й если Диаграмма будет распологаться непосредственно на листе с данными, 2-й на отдельном листе.

	

	//Если Диаграмма распологается на листе с данными:

	//в скобках параметры определения левого верхнего угла и размеры.

	

	//Chart = Excel.WorkBooks(1).WorkSheets(2).ChartObjects.Add(,,,);

	

	//Если все же на отдельном листе, то добавим Sheets наш элемент: *(СОДЕРЖИТ ЛИСТЫ ВСЕХ ТИПОВ)*

		

	//Excel.WorkBooks(1).Sheets.Add(,,1,-4109);

	//где:Add(ПЕРВЫЙ,ВТОРОЙ,1,-4109);

	//ПЕРВЫЙ- номер листа, перед которым будет НАШ лист;

	//ВТОРОЙ-номер листа, после которого будет НАШ лист;

	//1- количество создоваемых листов;

	//-4109 - рабочий лист ( -4109 = с диаграммой, -4167 = лист с данными)



КонецПроцедуры

Категория: Работа с Microsoft Office и OpenOffice

Как конвертировать БД 1С SQL в БД 1с обычную dbf?

Последовательность действий такая:
1. Создать новую базу 1С. (Создать пустой каталог, скопировать в него папку ExtForms, в старотовом окне 1С нажать кнопку добавить, написать название базы и путь к только что созданному каталогу - ок)
2. В старой базе 1С sql сделать "Выгрузку данных" (не путать с "Сохранением данных").
3. В новой базе 1С сделать "Загрузку данных" (не путать с "Восстановлением данных").

Все... пользуемся.

Категория: Администрирование

Как конвертировать БД 1с обычную dbf в БД 1С SQL?

Последовательность действий такая (подразумевается что 1С версия для sql и сам ms sql server уже установлены):
1. Создать новую базу 1С, указать что это база SQL.
2. Создать новую базу данных SQL. При этом Вы прописываете, где будет Ваша база SQL хранится, например в Program Files\\Microsoft SQL Server\\MSSQL\\DATA.
3. В новой базе 1С прописать параметры подключения к новой базе SQL.
4. В старой dbf-базе 1С сделать "Выгрузку данных" (не путать с "Сохранением данных").
5. В новой базе 1С сделать "Загрузку данных" (не путать с "Восстановлением данных").

Все... пользуемся.

Категория: Администрирование