сохраняются » Поиск

Результаты по ключевому слову: сохраняются

Импорт/экспорт CSV в ТЗ

Код 1C v 8.х

 //ПреобразоватьТекстCSVвТЗ () импортирует данные в ТЗ из текста формата CSV

//Параметры:

//ТекстCSV 		- Строка, содержащая текст в формате csv

//Разделитель 	- Для формата CSV разделителем является ',', но т.к. 

//				  Excel берет разделитель из региональных стандартов, то

//				  используется ';', поддерживает многострочные поля

//

&НаСервереБезКонтекста

Функция ПреобразоватьТекстCSVвТЗ(ТекстCSV="", Разделитель=";") Экспорт

	ТЗ = Новый ТаблицаЗначений;

	ОсобаяСтрока = "$#%^&*!xyxb$#%&*!^";	// для замены ""

	

	НомерСтроки = 1;

	Стр = СтрПолучитьСтроку(ТекстCSV,НомерСтроки);

	Пока НомерСтроки <= СтрЧислоСтрок(ТекстCSV) Цикл

		СтрокаТЗ = ТЗ.Добавить();

		НомерПоля = 0;

		Пока Стр <> "" Цикл

			Токен = "";

			ПозицияРазделителя = Найти(стр, Разделитель);

			ПозицияОткрКавычек = Найти(стр, """");

			Если (ПозицияРазделителя > ПозицияОткрКавычек ИЛИ ПозицияРазделителя = 0) И ПозицияОткрКавычек > 0 Тогда

				// начинающееся с кавычек читаем до тех пор

				Токен = Сред(Стр, 1, ПозицияОткрКавычек);

				Стр = СтрЗаменить(Сред(Стр, ПозицияОткрКавычек+1), """""", ОсобаяСтрока);

				

				ПозицияЗакрКавычек = Найти(Стр, """");

				Пока ПозицияЗакрКавычек = 0 Цикл

					Токен = Токен + Стр + Символы.ПС;

					НомерСтроки = НомерСтроки + 1;

					Стр = СтрПолучитьСтроку(ТекстCSV, НомерСтроки);

					Стр = СтрЗаменить(Стр, """""", ОсобаяСтрока);

					// пока не встретим закрывающие

					ПозицияЗакрКавычек = Найти(Стр, """");

				КонецЦикла;

				ПозицияРазделителя=Найти(Сред(Стр,ПозицияЗакрКавычек), Разделитель);

				ПозицияРазделителя = ?(ПозицияРазделителя>0, ПозицияЗакрКавычек + ПозицияРазделителя-1, 0);

			КонецЕсли;



			Токен = Токен + ?(ПозицияРазделителя>0, Сред(Стр, 1, ПозицияРазделителя-1), Стр);

			Стр = ?(ПозицияРазделителя>0, Сред(Стр, ПозицияРазделителя+1), "");

			

			Если Лев(Токен, 1) = """" Тогда

				Токен = Сред(Токен, 2);

				Токен = ?(Прав(Токен, 1) = """", Сред(Токен, 1, СтрДлина(Токен)-1), Токен);

			КонецЕсли;

			Токен = СтрЗаменить(Токен, ОсобаяСтрока, """");

			

			НомерПоля = НомерПоля + 1;

			Если ТЗ.Колонки.Количество()<НомерПоля Тогда

				ТЗ.Колонки.Добавить("Колонка"+НомерПоля, Новый ОписаниеТипов("Строка"));

			КонецЕсли;

			СтрокаТЗ[НомерПоля-1] = Токен;



		КонецЦикла;

		НомерСтроки = НомерСтроки + 1;

		Стр = СтрПолучитьСтроку(ТекстCSV, НомерСтроки);

	КонецЦикла;

	Возврат ТЗ;

КонецФункции



//ПреобразоватьТЗвТекстCSV () экспортирует данные ТЗ в текст в формате CSV

//Параметры:

//ТЗ 			- Таблица значений данные которые сохраняются в файл

//флЭкспортироватьИменаКолонок - Первой строкой выводить имена колонок

//Разделитель 	- Для формата CSV разделителем является ',', но т.к. 

//				  Excel берет разделитель из региональных стандартов, то

//				  используется ';'

//

&НаСервереБезКонтекста

Функция ПреобразоватьТЗвТекстCSV(ТЗ, Разделитель = ";", флЭкспортироватьИменаКолонок = Ложь) Экспорт

		

	ТекстCSV = "";

	

	Если флЭкспортироватьИменаКолонок Тогда

		//Если нужно выгружать наименование колонок Выгружаем

		ПодготовленнаяСтрока = "";

		Для Каждого Колонка Из ТЗ.Колонки Цикл

			ПодготовленнаяСтрока = ПодготовленнаяСтрока + Колонка.Имя + Разделитель;

		КонецЦикла;

		ПодготовленнаяСтрока = Лев (ПодготовленнаяСтрока,СтрДлина(ПодготовленнаяСтрока)-1);

		

		ТекстCSV = ТекстCSV + ПодготовленнаяСтрока + Символы.ПС;

	КонецЕсли;

	

	Для Каждого Строка Из ТЗ Цикл

		ПодготовленнаяСтрока = "";

		Для Каждого Колонка Из ТЗ.Колонки Цикл

			ПреобразованноеПоле = Строка[Колонка.Имя];

			//по правилам CSV если поле содержит двойные ковычки они должны повторятся дважды

			Если Найти(ПреобразованноеПоле,"""") Тогда

				ПреобразованноеПоле = СтрЗаменить(ПреобразованноеПоле,"""","""""");

			КонецЕсли;

			//по правилам CSV если поле содержит перенос строки или запятую оно должно заключатся в двойные кавычки

			Если Найти(ПреобразованноеПоле,Разделитель) ИЛИ Найти(ПреобразованноеПоле,Символы.ПС) ИЛИ Найти(ПреобразованноеПоле,"""") Тогда

				ПреобразованноеПоле = """" + ПреобразованноеПоле + """";

			КонецЕсли;



			ПодготовленнаяСтрока = ПодготовленнаяСтрока + ПреобразованноеПоле + Разделитель;

		КонецЦикла;

		ПодготовленнаяСтрока = Лев (ПодготовленнаяСтрока,СтрДлина(ПодготовленнаяСтрока)-1);

		

		ТекстCSV = ТекстCSV + ПодготовленнаяСтрока + Символы.ПС;

	КонецЦикла;



	Возврат ТекстCSV;

КонецФункции

Источник

Категория: Работа с Таблицей Значений

Обход метаданных (полезные функции)

При написании небольших автоматизированных тестов часто надо обойти всю конфигурацию и проверить, например, для всех форм какое-нибудь свойство. Это всё легко делается через свойство глобального контекста "Метаданные", но чтоб дорбаться до обхода реквизитов надо написать кучу вложенных циклов. При этом код становится слабочитаемым и слабомодифицируемым.

Ниже приведен небольшой модуль, который решает задачу легко и удобно. Создана специальная функция РазвернутьСтрокуОбходаМетаданных, которая может по строке типа "Метаданные.Справочники.*.Реквизиты.*" построить массив строк с перечислением всех реквизитов всех справочников. При помощи этой и нескольких других функций в экспортных функциях модуля реализованы вполне прикладные задачи - получение всех реквизитов, всех макетов, всех форм конфигурации и построение таблицы всех составных типов.

Код 1C v 8.х

  // Автор: Alexander Speshilov

// Рекрсивная функция, которая разворачивает строку вида "Метаданные.Справочники.*[Имя].Реквизиты.*.Тип" 

// в массив строк, заменяя "*" или другой символ, задаваемый параметрами обходом всех элементов 

// коллекции. Допускает выполнение функций встроенного языка (не стоит отдавать ввод параметров 

// пользователям). При этом выражение, используемое для получения по умолчанию может быть задано в 

// квадратных скобках или параметром функции.

//

// Параметры

//  СтрокаОбхода  - Строка - Разворачиваемая строка

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Массив строк

//

Функция РазвернутьСтрокуОбходаМетаданных(СтрокаОбхода, ЗаменяемоеЗначение = "*", ПредставлениеПоУмолчанию = "")

    

    Рез = Новый Массив;

    

    ЧастиСтрокиОбхода = РазобратьСтрокуОбхода(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

    Если ЧастиСтрокиОбхода = Неопределено тогда 

        Рез.Добавить(СтрокаОбхода); //фактически это ограничение рекурсии.

    Иначе

        ОбъектКоллекции = Вычислить(ЧастиСтрокиОбхода.СтрокаКоллекции);

        РазвернутаяКоллекция = РазвернутьКоллекциюВПредставления(ОбъектКоллекции, ЧастиСтрокиОбхода.СтрокаПредставление);

        Для каждого ЭлементРазвернутойКоллекции Из РазвернутаяКоллекция Цикл

            

            // рекурсивный вызов

            ТекущаяСтрокаОбхода = ЧастиСтрокиОбхода.СтрокаНачало + ЭлементРазвернутойКоллекции + ЧастиСтрокиОбхода.СтрокаКонец;

            МассивЭлемента = РазвернутьСтрокуОбходаМетаданных(ТекущаяСтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

            

            Для каждого ПримитивныйЭлементОбхода Из МассивЭлемента Цикл

                Рез.Добавить(ПримитивныйЭлементОбхода);

            КонецЦикла;

            

        КонецЦикла;

    КонецЕсли;

    

    Возврат Рез;

    

КонецФункции // РазвернутьСтрокуОбходаМетаданных()



// Разбирает строку обхода на удобные для работы поля

//

// Параметры

//  СтрокаОбхода  - Строка - Разворачиваемая строка

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Структура с полями ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец

// или Неопределено (если строка не содержит ЗаменяемоеЗначение)

//

Функция РазобратьСтрокуОбхода(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию)

    

    Если ПустаяСтрока(ЗаменяемоеЗначение) Тогда 

        ВызватьИсключение "Некорректное выражение заменяемого значения";

    КонецЕсли;

    

    ПозицияЗамены = Найти(СтрокаОбхода, ЗаменяемоеЗначение);

    

    // Если не найдена строка - возвращаем неопределено, как индикатор

    Если ПозицияЗамены = 0 Тогда 

        Возврат Неопределено; 

    КонецЕсли;

    

    СтрокаНачало = Лев(СтрокаОбхода,ПозицияЗамены - 1);

    

    //Получение строки для выражения-коллекции

    СтрокаКоллекции = СтрокаНачало;

    Если Прав(СтрокаКоллекции, 1) = "." Тогда 

        СтрокаКоллекции = Лев(СтрокаКоллекции,СтрДлина(СтрокаКоллекции) - 1);

    КонецЕсли;

    

    ПозицияОкончанияЗамены = ПозицияЗамены + СтрДлина(ЗаменяемоеЗначение);

    

    ОстатокВыражения = Сред(СтрокаОбхода, ПозицияОкончанияЗамены);

    

    //Обработка явного задания представления

    ОткрывающаяСкобка = "[";

    ЗакрывающаяСкобка = "]";

    Если Найти(ОстатокВыражения, ОткрывающаяСкобка) = 1 Тогда

        ОстатокВыражения = Сред(ОстатокВыражения, СтрДлина(ОткрывающаяСкобка) + 1);

        ПозицияЗакрывающейСкобки = Найти(ОстатокВыражения, ЗакрывающаяСкобка);

        Если ПозицияЗакрывающейСкобки = 0 Тогда 

            ВызватьИсключение "Синтаксическая ошибка разбора выражения";

        КонецЕсли;

        СтрокаПредставление = Лев(ОстатокВыражения, ПозицияЗакрывающейСкобки - 1);

        ОстатокВыражения = Сред(ОстатокВыражения, ПозицияЗакрывающейСкобки + СтрДлина(ЗакрывающаяСкобка));

    Иначе

        СтрокаПредставление = ПредставлениеПоУмолчанию;

    КонецЕсли;

    СтрокаКонец = ОстатокВыражения;

    

    Рез = Новый Структура("ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец",

    ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец);

    

    Возврат Рез;

    

КонецФункции // РазобратьСтрокуОбхода()



// Разворачивает объект коллекции в массив представления элементов

//

// Параметры

//  Коллекция  - Произвольный - Коллекция, которую можно обойти через "Для каждого"

//  ПредставлениеЭлемента  - Строка - необяз., свойство элементов коллекции, которое 

//               используется для получения представления.

//

// Возвращаемое значение:

//   Массив   - Массив представлений коллекции

//

Функция РазвернутьКоллекциюВПредставления(Коллекция, Знач ПредставлениеЭлемента = "")

    

    //Проверка и подгонка параметров

    Если не ПустаяСтрока(ПредставлениеЭлемента) Тогда 

        Если Найти(ПредставлениеЭлемента, ";")>0 Тогда 

            ВызватьИсключение "Некорректное выражение представления";

        КонецЕсли;

        ПредставлениеЭлемента = "." + ПредставлениеЭлемента;

    КонецЕсли;

    

    Рез = Новый Массив;

    Для каждого ЭлементКоллекции Из Коллекция Цикл

        ТекПредставление = Строка(Вычислить("ЭлементКоллекции" + ПредставлениеЭлемента));

        Рез.Добавить(ТекПредставление);

    КонецЦикла; 

    Возврат Рез;

    

КонецФункции // РазвернутьКоллекцию()



// Разворачивает массив строк через РазвернутьСтрокуОбходаМетаданных

//

// Параметры

//  МассивСтрокОбхода  - Массив - Массив разворачиваемых строк

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Массив строк

//

Функция РазвернутьМассивСтрокОбходаМетаданных(МассивСтрокОбхода, ЗаменяемоеЗначение = "*", ПредставлениеПоУмолчанию = "Имя")

    

    Рез = Новый Массив;

    

    Для каждого СтрокаОбхода Из МассивСтрокОбхода Цикл

        

        ДополнениеРезультата = РазвернутьСтрокуОбходаМетаданных(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

        Для каждого ТекСтрока Из ДополнениеРезультата Цикл

            Рез.Добавить(ТекСтрока);

        КонецЦикла; 

        

    КонецЦикла; 

    

    Возврат Рез;

    

КонецФункции // РазвернутьМассивСтрокОбходаМетаданных()



// Преобразует строку в массив одиночных строк по разделителю Символы.ПС

//

// Параметры

//  ПреобразуемаяСтрока - строка для преобразования

//    ИгнорироватьПустые - Булево - Пропускать пустые строки

//  СокращатьПробелы - Использовать СокрЛП

//

// Возвращаемое значение:

//   Массив строк

//

Функция ПолучитьМассивСтрокМногострочнойСтроки(ПреобразуемаяСтрока, ИгнорироватьПустые = Истина, СокращатьПробелы = Истина)

    

    Рез = Новый Массив;

    ЧислоСтрок = СтрЧислоСтрок(ПреобразуемаяСтрока);

    

    Для Сч = 1 По ЧислоСтрок Цикл

        

        ТекСтрока = СтрПолучитьСтроку(ПреобразуемаяСтрока, Сч);

        Если ИгнорироватьПустые и ПустаяСтрока(ТекСтрока) Тогда

            Продолжить;

        КонецЕсли; 

        Если СокращатьПробелы Тогда

            ТекСтрока = СокрЛП(ТекСтрока);

        КонецЕсли; 

        Рез.Добавить(ТекСтрока);

        

    КонецЦикла;

    

    Возврат Рез;

    

КонецФункции // ПолучитьМассивСтрокМногострочнойСтроки()



// Возвращает все реквизиты конфигурации, которые сохраняются в ИБ

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеХранимыеРеквизитыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.Константы.*

    |Метаданные.ПланыОбмена.*.Реквизиты.*

    |Метаданные.ПланыОбмена.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Справочники.*.Реквизиты.*

    |Метаданные.Справочники.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Документы.*.Реквизиты.*

    |Метаданные.Документы.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Последовательности.*.Измерения.*

    |Метаданные.ПланыВидовХарактеристик.*.Реквизиты.*

    |Метаданные.ПланыВидовХарактеристик.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.ПланыСчетов.*.Реквизиты.*

    |Метаданные.ПланыСчетов.*.ПризнакиУчета.*

    |Метаданные.ПланыСчетов.*.ПризнакиУчетаСубконто.*

    |Метаданные.ПланыСчетов.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.ПланыВидовРасчета.*.Реквизиты.*

    |Метаданные.ПланыВидовРасчета.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.РегистрыСведений.*.Измерения.*

    |Метаданные.РегистрыСведений.*.Ресурсы.*

    |Метаданные.РегистрыСведений.*.Реквизиты.*

    |Метаданные.РегистрыНакопления.*.Измерения.*

    |Метаданные.РегистрыНакопления.*.Ресурсы.*

    |Метаданные.РегистрыНакопления.*.Реквизиты.*

    |Метаданные.РегистрыБухгалтерии.*.Измерения.*

    |Метаданные.РегистрыБухгалтерии.*.Ресурсы.*

    |Метаданные.РегистрыБухгалтерии.*.Реквизиты.*

    |Метаданные.РегистрыРасчета.*.Измерения.*

    |Метаданные.РегистрыРасчета.*.Ресурсы.*

    |Метаданные.РегистрыРасчета.*.Реквизиты.*

    |Метаданные.БизнесПроцессы.*.Реквизиты.*

    |Метаданные.БизнесПроцессы.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Задачи.*.Реквизиты.*

    |Метаданные.Задачи.*.РеквизитыАдресации.*

    |Метаданные.Задачи.*.ТабличныеЧасти.*.Реквизиты.*

    |";

    ВсеХранимыеРеквизитыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеХранимыеРеквизитыКонфигурации;

    

КонецФункции // ПолучитьВсеХранимыеРеквизитыКонфигурации()



// Возвращает все реквизиты конфигурации составного типа, которые сохраняются в ИБ

//

// Параметры - Нет

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция ПолучитьВсеХранимыеРеквизитыКонфигурацииСоставногоТипа() Экспорт

    

    ВсеХранимыеРеквизитыКонфигурации = ПолучитьВсеХранимыеРеквизитыКонфигурации();

    Рез = Новый ТаблицаЗначений;

    Рез.Колонки.Добавить("Имя", Новый ОписаниеТипов("Строка"));

    Рез.Колонки.Добавить("Тип", Новый ОписаниеТипов("ОписаниеТипов"));

    Рез.Колонки.Добавить("КоличествоПростыхТипов", Новый ОписаниеТипов("Число"));

    

    Для каждого ТекРеквизит Из ВсеХранимыеРеквизитыКонфигурации Цикл

        

        Реквизит = Вычислить(ТекРеквизит);

        Тип = Реквизит.Тип;

        КоличествоПростыхТипов = Тип.Типы().Количество();

        Если КоличествоПростыхТипов<>1 Тогда 

    	    ТекСтрока = Рез.Добавить();

            ТекСтрока.Имя = ТекРеквизит;

            ТекСтрока.Тип = Тип;

            ТекСтрока.КоличествоПростыхТипов = КоличествоПростыхТипов;

        КонецЕсли;

    

    КонецЦикла; 

    

    Возврат Рез;

    

КонецФункции // ПолучитьВсеХранимыеРеквизитыКонфигурации()



// Возвращает все формы конфигурации

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеФормыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.ПланыОбмена.*.Формы.*

    |Метаданные.КритерииОтбора.*.Формы.*

    |Метаданные.ОбщиеФормы.*

    |Метаданные.Справочники.*.Формы.*

    |Метаданные.Документы.*.Формы.*

    |Метаданные.ЖурналыДокументов.*.Формы.*

    |Метаданные.Перечисления.*.Формы.*

    |Метаданные.Отчеты.*.Формы.*

    |Метаданные.Обработки.*.Формы.*

    |Метаданные.ПланыВидовХарактеристик.*.Формы.*

    |Метаданные.ПланыСчетов.*.Формы.*

    |Метаданные.ПланыВидовРасчета.*.Формы.*

    |Метаданные.РегистрыСведений.*.Формы.*

    |Метаданные.РегистрыНакопления.*.Формы.*

    |Метаданные.РегистрыБухгалтерии.*.Формы.*

    |Метаданные.РегистрыРасчета.*.Формы.*

    |Метаданные.БизнесПроцессы.*.Формы.*

    |Метаданные.Задачи.*.Формы.*

    |";

    ВсеФормыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеФормыКонфигурации;

    

КонецФункции // ПолучитьВсеФормыКонфигурации()



// Возвращает все макеты конфигурации

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеМакетыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.ПланыОбмена.*.Макеты.*

    |Метаданные.ОбщиеМакеты.*

    |Метаданные.Справочники.*.Макеты.*

    |Метаданные.Документы.*.Макеты.*

    |Метаданные.ЖурналыДокументов.*.Макеты.*

    |Метаданные.Перечисления.*.Макеты.*

    |Метаданные.Отчеты.*.Макеты.*

    |Метаданные.Обработки.*.Макеты.*

    |Метаданные.ПланыВидовХарактеристик.*.Макеты.*

    |Метаданные.ПланыСчетов.*.Макеты.*

    |Метаданные.ПланыВидовРасчета.*.Макеты.*

    |Метаданные.РегистрыСведений.*.Макеты.*

    |Метаданные.РегистрыНакопления.*.Макеты.*

    |Метаданные.РегистрыБухгалтерии.*.Макеты.*

    |Метаданные.РегистрыРасчета.*.Макеты.*

    |Метаданные.БизнесПроцессы.*.Макеты.*

    |Метаданные.Задачи.*.Макеты.*

    |";

    ВсеМакетыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеМакетыКонфигурации;

    

КонецФункции // ПолучитьВсеМакетыКонфигурации()

Категория: Метаданные

Особенности работы с хранилищем конфигурации

Хранилище конфигурации предназначено для коллективной разработки конфигурации. В хранилище сохраняется история разрабатываемой конфигурации, а также информация о том, когда и кто вносил изменения в конфигурацию. Разработка конфигурации с использованием хранилища может вестись неограниченным числом пользователей.

Принцип работы

Хранилище конфигурации представляет собой базу данных, в которой сохраняются все изменения конфигурации, сделанные в процессе её разработки. После подключения информационной базы к хранилищу из него в информационную базу загружается последняя версия конфигурации, и все объекты метаданных конфигурации становятся недоступными для редактирования.

Гранулой редактирования - объектами разработки - являются все основные объекты метаданных (такие как справочники, документы, регистры сведений), а также формы и макеты. Объекты разработки могут редактироваться независимо друг от друга разными пользователями. Реквизиты, табличные часть и т.д. не являются отдельными объектами с логической точки зрения, поэтому они не были включены в состав объектов разработки. Данные объекты метаданных редактируются в составе своих родительских объектов, являющихся объектами разработки.

Для получения возможности редактирования объекта необходимо произвести его захват в хранилище. При выполнении захвата из хранилища будет получена (в случае наличия) новая версия объекта разработки. После внесения изменений объект необходимо поместить в хранилище, после этого обновленная версия объекта становится доступной для других пользователей, участвующих в процессе разработки конфигурации. Если же изменения не должны быть помещены в хранилище, то предусмотрена процедура отмены захвата, при которой из хранилища получается старая версия объекта разработки. Таким образом, можно выделить четыре простейшие операции работы с хранилищем:
захват объекта в хранилище;
помещение объекта в хранилище;
получение объекта из хранилища;
отмена захвата в хранилище.
Для параллельной разработки конфигурации в хранилище используется стратегия пессимистической блокировки: в то время, пока объект разработки редактируется одним пользователем, другие пользователи не имеют возможности его редактировать.

Стоит обратить внимание на тот факт, что при подключении информационной базы к хранилищу конфигурации происходит полная замена текущей редактируемой конфигурации конфигурацией хранилища . Это необходимо для обеспечения полного соответствия идентификаторов объектов метаданных. Если все же имеется информационная база, часть объектов метаданных конфигурации которой необходимо перенести в конфигурацию хранилища, то необходимо:
выгрузить конфигурацию из информационной базы в файл,
подключить информационную базу к хранилищу конфигурации,
выполнить захват объектов, которые необходимо заместить,
произвести объединение с требуемой конфигурацией.
Важно понимать, что предметом разработки является конфигурация, а не отдельные объекты. Хранилище ведет историю развития конфигурации. При помещении объектов разработки в хранилище создается новая версия конфигурации, для которой записываются: дата создания версии, пользователь, создавший версию, а также списки объектов разработки, которые были добавлены, изменены, удалены в процессе получения данной версии конфигурации. История объектов разработки не ведется. Несмотря на то, что имеется возможность просмотра истории объекта разработки, отдельно загрузить из хранилища объект разработки какой-либо версии конфигурации невозможно, возможна лишь загрузка из хранилища версии конфигурации целиком. Однако все же имеется возможность получения объекта определенной версии конфигурации: необходимо захватить объект и выполнить объединение с версией конфигурации, в которой данный объект имеет требуемое состояние.

При создании новой версии конфигурации хранилища имеется возможность записать комментарий к этой версии. Рекомендуется комментировать версии конфигурации, для того чтобы впоследствии можно было понять, что именно было изменено в данной версии конфигурации. Для наиболее значимых версий (например: выпуск релиза) рекомендуется также устанавливать метку - строку, кратко описывающую версию конфигурации хранилища.

В процессе разработки конфигурации с использованием хранилища рекомендуется периодически получать актуальное состояние объектов разработки. Это позволяет избежать возможных трудностей при помещении объектов в хранилище (например при удалении объектов метаданных из конфигурации).

Средства работы с хранилищем конфигурации позволяют просматривать историю версий конфигурации хранилища, сохранять конфигурацию определенной версии в файл, сравнивать с другими версиями конфигурации данного хранилища или же сравнивать с другой конфигурацией из файла.

Если по каким-либо причинам хранилище конфигурации недоступно, то имеется возможность продолжать работу с объектами разработки, захваченными ранее в хранилище. Таким образом, можно вести разработку, не имея постоянной непосредственной связи с хранилищем конфигурации.

Режимы использования

Для работы с хранилищем конфигурации предусмотрено несколько способов:
с подключением информационной базы к хранилищу;
без подключения информационной базы к хранилищу.
Данные режимы отличаются друг от друга как набором функциональности, предоставляемой платформой 1С:Предприятия, так и своим предназначением.

Работа с подключением информационной базы к хранилищу

Этот режим является основным режимом работы с хранилищем. Он используется для групповой разработки конфигурации несколькими пользователями.

Работа в данном режиме начинается с процедуры подключения информационной базы к хранилищу. К одному хранилищу может быть одновременно подключена одна информационная база от имени одного пользователя. Если пользователь, у которого уже имеется информационная база, подключенная к данному хранилищу, произведет попытку подключения другой информационной базы, то ему будет выдано соответствующее предупреждение. Если же подключение все же будет осуществлено, то прежняя информационная база уже не сможет работать с данным хранилищем конфигурации без предварительного отключения от него. Аутентификация в хранилище от имени пользователя, не подключавшего данную информационную базу к хранилищу, невозможна.

При подключении информационной базы к хранилищу в нем регистрируется строка соединения с информационной базой. Если при последующих соединениях с хранилищем данная строка будет изменена (по каким-либо причинам информационная база была перемещена на другой ресурс), то платформой будет выдано соответствующе предупреждение, и, в случае подтверждения соединения, строка соединения будет обновлена. Если соединение происходило копией информационной базы, то работа оригинала с данным хранилищем будет невозможна без предварительного отключения от него.

Работа без подключения информационной базы к хранилищу

Режим обеспечивает возможность просмотра и администрирования хранилища без подключения к нему, т.е. без замены редактируемой конфигурации конфигурацией хранилища. В данном режиме пользователь может получить конфигурацию определенной версии хранилища, посмотреть историю конфигурации или отдельных объектов разработки, произвести действия по редактированию прав пользователей или изменению их состава.

Работа в данном режиме начинается с открытия хранилища конфигурации, данная процедура заключается в аутентификации пользователя в хранилище, которая будет автоматически предложена при выполнении любого первого действия с хранилищем в данной сессии работы Конфигуратора. Для открытия другого хранилища в данной сессии Конфигуратора необходимо закрыть текущее хранилище конфигурации, выполнив соответствующий пункт меню.

Предполагается, что данный режим будет использоваться для подготовки дистрибутивов конфигураций на основе файлов выгрузки информационных баз. Данная процедура может выглядеть следующим образом:

Создать новую информационную базу.
Открыть хранилище конфигурации.
Из хранилища конфигурации загрузить конфигурацию нужной версии.
Произвести заполнение информационной базы необходимыми данными.
Произвести подготовку дистрибутива конфигурации.
В процессе модернизации конфигурации хранилища для выпуска новых дистрибутивов необходимо повторить процедуру, начиная с пункта 2, и, если новых данных вводить не требуется, сразу выполнить подготовку дистрибутива.

Контроль ссылочной целостности

Стандартные механизмы контроля ссылочной целостности конфигурации обеспечивают контроль на уровне объектов метаданных: нельзя, например, удалить из конфигурации справочник, если на него ссылается реквизит документа и т.д. На уровне интерфейсов, форм и макетов такой контроль не ведется.

Пример: удаление справочника Склады из демонстрационной конфигурации ":
происходит проверка имеющихся на этот объект ссылок в других объектах:
"Справочник.Склады" использован в:
Документ.ПриходнаяНакладная.Реквизит.Склад.Тип
Документ.РасходнаяНакладная.Реквизит.Склад.Тип
РегистрНакопления.УчетНоменклатуры.Измерение.Склад.Тип

после удаления обнаруженных ссылок справочник Склады успешно удаляется из конфигурации, хотя ссылка не него по-прежнему имеется в интерфейсе Основной (кнопка Склады из подменю Справочники содержит действие "Склады: Открыть справочник") и формах документов ПриходнаяНакладная, РасходнаяНакладная (поля ввода, предназначенные для редактирования реквизитов Склад по-прежнему имеют тип СправочникСсылка.Склады).
При разработке конфигурации без использования хранилища этого вполне хватает. Однако для параллельной разработки конфигурации такой контроль ссылочной целостности недостаточен.

Хранилище конфигурации обеспечивает более строгий контроль ссылочной целостности конфигурации. Производится полный контроль ссылок между объектами метаданных как на уровне самих объектов, так и на уровне содержимого их форм и макетов, а также содержимого интерфейсов.

Следствием этого факта является необходимость получения из хранилища (помещения в хранилище) объектов, так или иначе связанных с объектом, над которым непосредственно производится действие. Однако хранилище конфигурации производит анализ ссылок объекта и требует получения (помещения) дополнительных объектов только в случае необходимости.

Анализ ссылок производится рекурсивно: сначала производится анализ объекта, с которым производится действие в хранилище; затем при обнаружении необходимости выполнения операции над дополнительными объектами аналогичный анализ производится для них, и так до тех пор, пока ссылки всех требуемых объектов не будут проанализированы.

Особенности конфигурирования

Разработка конфигурации в информационной базе, подключенной к хранилищу конфигурации, имеет некоторые особенности.

Как уже говорилось ранее, для получения возможности редактирования объекта необходимо произвести его захват в хранилище конфигурации. Если необходимо внести изменения в объект метаданных, не являющийся объектом разработки (реквизиты, табличные части), то необходимо произвести захват того объекта разработки, который содержит данные объекты метаданных.

Для добавления нового объекта метаданных или же для изменения порядка следования существующих объектов необходимо произвести захват родительского объекта разработки.

Удаление объектов конфигурации

Особое внимание стоит уделить процедуре удаления объектов метаданных из конфигурации. Для удаления объекта метаданных из конфигурации необходимо захватить в хранилище сам удаляемый объект, его родительский объект, а также все подчиненные объекты удаляемого. После чего появится возможность удалить объект из конфигурации.

Однако при помещении в хранилище, если на удаленный объект имеются ссылки в других объектах, средства работы с хранилищем потребуют помещение этих объектов в хранилище с очищенными ссылками на удаленный объект.

Рекомендуется перед удалением объекта из конфигурации производить поиск ссылок на данный объект. Произвести захват в хранилище всех обнаруженных объектов и вычистить из них все ссылки на удаляемый объект. После этого необходимо удалить все ссылки на удаляемый объект из форм, интерфейсов и макетов. После чего удалить объект из конфигурации и произвести попытку помещения изменений в хранилище. Если помещение в хранилище завершится неудачей из-за обнаружения ссылок на удаленный объект, то необходимо захватить указанные объекты и произвести повторную попытку помещения изменений в хранилище.

Пример: удаление справочника Склады из демонстрационной конфигурации:
Производим поиск ссылок на удаляемый объект:
"Справочник.Склады" использован в:
Документ.ПриходнаяНакладная.Реквизит.Склад.Тип
Документ.РасходнаяНакладная.Реквизит.Склад.Тип
РегистрНакопления.УчетНоменклатуры.Измерение.Склад.Тип
Захватываем данные объекты и удаляем из них реквизиты, ссылающиеся на справочник Склады.
Захватываем интерфейс "Основной" и удаляем из него кнопку Склады из подменю Справочники с действием "Склады: Открыть справочник".
Захватываем корневой объект конфигурации и справочник Склады.
Удаляем справочник Склады из конфигурации.
Производим попытку помещения корневого объекта конфигурации в хранилище

Параметры командной строки для работы с хранилищем конфигурации
Параметры командной строки режима работы с хранилищем конфигурации
/ConfigurationRepositoryF <каталог хранилища> — указание имени каталога хранилища.

/ConfigurationRepositoryN <имя> — указание имени пользователя хранилища.

/ConfigurationRepositoryP <пароль> — указание пароля пользователя хранилища.

/ConfigurationRepositoryDumpCfg <имя cf файла> [-v <номер версии хранилища>] — сохранить конфигурацию из хранилища в файл (пакетный режим запуска).

-v <номер версии хранилища> v — номер версии, если номер версии не указан, или равен -1, будет сохранена последняя версия.

/ConfigurationRepositoryUpdateCfg [-v <номер версии хранилища>] [-revised] — обновить конфигурацию хранилища из хранилища (пакетный режим запуска).

-v<номер версии хранилища> — номер версии, если номер версии не указан, или равен -1, будет сохранена последняя версия, если конфигурация не подключена к хранилищу, то параметр игнорируется;
-revised — получать захваченные объекты, если потребуется. Если конфигурация не подключена к хранилищу, то параметр игнорируется;
-force — если при пакетном обновлении конфигурации из хранилища должны быть получены новые объекты конфигурации или удалиться существующие, указание этого параметра свидетельствует о подтверждении пользователем описанных выше операций. Если параметр не указан — действмия выполнены не будут.

/ConfigurationRepositoryUnbindCfg [-force] — отключение конфигурации от хранилища конфигурации (у пользователя должны быть административные права в данной информационной базе). Если пользователь аутентифицируется в хранилище (интерактивно или через параметры командной строки), то отключение конфигурации от хранилища также отражается в самом хранилище конфигурации (информация о подключении удаляется), если же пользователь не аутентифицировался в хранилище, то производится только локальное отключение конфигурации от хранилища.

В случае, если в конфигурации имеются захваченные объекты, которые были изменены относительно хранилища, то будет выдано соответствующее сообщение и отключения не выполнится.

–force — ключ для форсирования отключения от хранилища (пропуск диалога аутентификации, если не указаны параметры пользователя хранилища, игнорирование наличия захваченных и измененных объектов).

/ConfigurationRepositoryReport <имя файла> [-NBegin <номер версии>] [-NEnd <номер версии>] [-GroupByObject] [-GroupByComment] — построение отчета по истории хранилища. Если параметры группировки не указаны и режим совместимости указан "Не используется", то отчет формируется с группировкой по версиям. В режимах совместимости "Версия 8.1" и "Версия 8.2.13" отчет формируется с группировкой по объектам. Если конфигурация базы данных отличается от редактируемой по свойству совместимости, при обработке командной строки учитывается значение режима совместимости конфигурации базы данных.

<имя файла> — имя файла, в который выводится отчет;
NBegin — номер сохраненной версии, от которой начинается строиться отчет;
NEnd — номер сохраненной версии, по которую строится отчет;
GroupByObject — признак формирования отчета по версиям с группировкой по объектам;
GroupByComment — признак формирования отчета по версиям с группировкой по комментарию.

Примеры:
для конфигурации, не присоединенной к текущему хранилищу:

Код DOS Batch File

 DESIGNER /F"D:\V8\Cfgs82\ИБ82" /ConfigurationRepositoryF "D:\V8\Cfgs82" /ConfigurationRepositoryN "Администратор" /ConfigurationRepositoryReport "D:\ByObject.mxl" -NBegin 1 -NEnd 2 –GroupByObject

для присоединенной к хранилищу конфигурации, информация для отчетов берется из текущего хранилища:

Код DOS Batch File

 DESIGNER /F"D:\V8\Cfgs82\ИБ82" /ConfigurationRepositoryReport "D:\ByComment.mxl" -NBegin 1 -NEnd 2 -GroupByComment

Категория: Администрирование

Сохранение реквизитов и табличных частей объектов в XML

Сохранение производится процедурой СохранитьРеквизитыИТабличныеЧасти. В качестве параметров она принимает сохраняемый объект и имя файла. Ссылочные реквизиты сохраняются в виде GUID.

Код 1C v 8.х

 Процедура СохранитьРеквизитыИТабличныеЧасти (Объект, ИмяФайлаXML=Неопределено) Экспорт

    ФайлXML = Новый ЗаписьXML;

    ФайлXML.ОткрытьФайл(ИмяФайлаXML);

    ФайлXML.ЗаписатьОбъявлениеXML();

    ФайлXML.ЗаписатьНачалоЭлемента("Root");

    ФайлXML.ЗаписатьАтрибут("Объект",Объект.Метаданные().Имя);

//Сохраняем реквизиты

    Для Каждого Реквизит Из Объект.Метаданные().Реквизиты Цикл

        ФайлXML.ЗаписатьНачалоЭлемента("Реквизит");

        ФайлXML.ЗаписатьАтрибут("Имя", Реквизит.Имя);

        ТипЗначения = ТипЗнч(Объект[Реквизит.Имя]);

        Если Не ТипЗначения = Тип("Неопределено") Тогда

            ФайлXML.ЗаписатьАтрибут("ИмяТипа", XMLТип(ТипЗначения).ИмяТипа);

            ФайлXML.ЗаписатьАтрибут("URI", XMLТип(ТипЗначения).URIПространстваИмен);

        КонецЕсли;

        ФайлXML.ЗаписатьТекст(XMLСтрока(Объект[Реквизит.Имя]));

        ФайлXML.ЗаписатьКонецЭлемента();

    КонецЦикла;

//Сохраняем табличные части

    Для Каждого ТЧ из Объект.Метаданные().ТабличныеЧасти Цикл

        ФайлXML.ЗаписатьНачалоЭлемента("ТабличнаяЧасть");

        ФайлXML.ЗаписатьАтрибут("Имя", ТЧ.Имя);

        Для Каждого СтрокаТЧ из Объект[ТЧ.Имя] Цикл

            ФайлXML.ЗаписатьНачалоЭлемента("ЭлементКоллекции");

            Для Каждого РеквизитТЧ Из ТЧ.Реквизиты Цикл

                ФайлXML.ЗаписатьНачалоЭлемента("Реквизит");

                ФайлXML.ЗаписатьАтрибут("Имя", РеквизитТЧ.Имя);

                ТипЗначения = ТипЗнч(СтрокаТЧ[РеквизитТЧ.Имя]);

                Если Не ТипЗначения = Тип("Неопределено") Тогда

                    ФайлXML.ЗаписатьАтрибут("ИмяТипа", XMLТип(ТипЗначения).ИмяТипа);

                    ФайлXML.ЗаписатьАтрибут("URI", XMLТип(ТипЗначения).URIПространстваИмен);

                КонецЕсли;

                ФайлXML.ЗаписатьТекст(XMLСтрока(СтрокаТЧ[РеквизитТЧ.Имя]));

                ФайлXML.ЗаписатьКонецЭлемента();

            КонецЦикла;

            ФайлXML.ЗаписатьКонецЭлемента();

        КонецЦикла;

        ФайлXML.ЗаписатьКонецЭлемента();

    КонецЦикла;

    Если Не ФайлXML=Null Тогда

        ФайлXML.ЗаписатьКонецЭлемента();

        ФайлXML.Закрыть();

    КонецЕсли;

КонецПроцедуры

За чтение объекта отвечают процедуры ЗагрузитьРеквизитыИТабличныеЧасти и ЗагрузитьОбъектРекурсивно. Чтобы прочитать объект вызывается первая, ей передаются объект, который необходимо заполнить, и имя файла. Вторая является вспомогательной.

Код 1C v 8.х

 Процедура ЗагрузитьРеквизитыИТабличныеЧасти(Объект, ИмяФайлаXML=Неопределено) Экспорт

    Если Не ИмяФайлаXML = Неопределено Тогда

        ФайлXML = Новый ЧтениеXML;

        ФайлXML.ОткрытьФайл(ИмяФайлаXML);

        Пока ФайлXML.Прочитать() Цикл

            Если ФайлXML.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда

                ЗагрузитьОбъектРекурсивно(ФайлXML, Объект, ФайлXML.Имя);

            КонецЕсли

        КонецЦикла;

    КонецЕсли;

КонецПроцедуры

Процедура ЗагрузитьОбъектРекурсивно(ФайлXML, Объект, знач ИмяУзла)

    ИмяТипа = "";

    ПространствоИмен = "";

    Пока ФайлXML.ПрочитатьАтрибут() Цикл

        Если ФайлXML.Имя = "ИмяТипа" Тогда

            ИмяТипа = ФайлXML.Значение;

        ИначеЕсли ФайлXML.Имя = "URI" Тогда

            ПространствоИмен = ФайлXML.Значение;

        КонецЕсли;

    КонецЦикла;

    Пока ФайлXML.Прочитать() Цикл

        Если ФайлXML.ТипУзла = ТипУзлаXML.КонецЭлемента И ФайлXML.Имя = ИмяУзла Тогда

            Возврат;

        ИначеЕсли ФайлXML.ТипУзла = ТипУзлаXML.Текст Тогда

            ТипОбъекта = ИзXMLТипа(ИмяТипа, ПространствоИмен);

            Если НЕ ТипОбъекта = Неопределено тогда

                Объект = XMLЗначение(ТипОбъекта, ФайлXML.Значение);

            КонецЕсли;

        ИначеЕсли ФайлXML.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда

            ИмяТекУзла = ФайлXML.Имя;

            Если ФайлXML.Имя = "ЭлементКоллекции" Тогда

                ЗагрузитьОбъектРекурсивно(ФайлXML, Объект.Добавить(), ИмяТекУзла);

            Иначе

                Если ФайлXML.ПрочитатьАтрибут() Тогда

                    ЗагрузитьОбъектРекурсивно(ФайлXML, Объект[ФайлXML.Значение], ИмяТекУзла);

                КонецЕсли;

            КонецЕсли;

        КонецЕсли;

    КонецЦикла;

КонецПроцедуры

В приложенном файле - Скачивать файлы может только зарегистрированный пользователь!

- демонстрационная обработка, позволяющая сохранить ссылочный объект БД в файл и заполнить объект из файла. Заполняемый объект должен быть того же типа, что и сохраненный, а также он должен быть предварительно создан, сохранен в ИБ и выбран в поле "Ссылка".

Категория: Документы

Как восстановить, скопировать удаленный документ и архивной копии базы?

Восстановление документов 1С из архива в рабочую базу
Не редко требуется восстановить данные испорченного документа 1С из архива базы после не умышленных, а зачастую ошибочных, действий удачливого пользователя.
Самым простым способом является выгрузка данных из базы архива 1с в XML, а затем загрузка этого XML файла в рабочую базу. Данное решение целиком и полностью опирается на внутренние XML алгоритмы работы конфигурации 1С. При помощи предлагаемой обработки в рабочую базу загружаются все реквизиты документа и его табличные части в том виде, в котором они существовали в архиве.
Исключение составляют движения документа. Данные о движениях не сохраняются при XML сериализации. Хотя документ и восстанавливается проведенным, но все регистры учета и накопления не трогаются. По этому, после восстановления документа следует его провести, либо воспользоваться обработкой, которая позволяет восстановить утерянный или испорченный документ со всеми его движениями.

Как пользоваться:
Начало работы с обработкой по выгрузке данных документа 1С в XML начинается с выбора имени XML файла и документа, данные которого необходимо сохранить. Первый этап следует выполнять на архивной копии базы, из которой требуется получить достоверные данные. После указания требуемых данных следует нажать кнопку "Выгрузить". Экспорт данных выбранного документа будет осуществлен в указанный пользователем XML файл.
title

Загрузка данных из XML файла следует осуществлять уже в рабочей базе в режиме "1С Предприятие". Для этого откройте обработку, выберите файл данных и нажмите кнопку восстановить. Документ выбирать не обязательно, так как все его данные уже известны и содержаться в XML файле. Важное замечание - движения документа не изменяются, по этому если нужно их тоже восстановить документ следует провести.
Скачать обработку: Скачивать файлы может только зарегистрированный пользователь!

Категория: 1С Общие вопросы - Обычные формы

Импорт - экспорт данных через XML. Обработка обмена документами

Восстановление документов 1С из архива в рабочую базу (XML обмен)
Не редко требуется восстановить данные испорченного документа 1С из архива базы после не умышленных, а зачастую ошибочных, действий удачливого пользователя. Самым простым способом является выгрузка данных из базы архива 1с в XML, а затем загрузка этого XML файла в рабочую базу. Данное решение целиком и полностью опирается на внутренние XML алгоритмы работы конфигурации 1С. При помощи предлагаемой обработки в рабочую базу загружаются все реквизиты документа и его табличные части в том виде, в котором они существовали в архиве.
Исключение составляют движения документа. Данные о движениях не сохраняются при XML сериализации. Хотя документ и восстанавливается проведенным, но все регистры учета и накопления не трогаются. По этому, после восстановления документа следует его провести, либо воспользоваться обработкой, которая позволяет восстановить утерянный или испорченный документ со всеми его движениями.

Импорт - экспорт данных через XML. Обработка обмена данными.
Начало работы с обработкой по экспорту данных документа 1С в XML начинается с выбора имени XML файла и документа, данные которого необходимо сохранить. Первый этап следует выполнять на архивной копии базы, из которой требуется получить достоверные данные. После указания требуемых данных следует нажать кнопку "Выгрузить". Экспорт данных выбранного документа будет осуществлен в указанный пользователем XML файл.
title

Импорт данных из XML файла следует осуществлять уже в рабочей базе в режиме "1С Предприятие". Для этого откройте обработку, выберите файл данных и нажмите кнопку восстановить. Документ выбирать не обязательно, так как все его данные уже известны и содержаться в XML файле. Важное замечание - движения документа не изменяются, по этому если нужно их тоже восстановить документ следует провести.
Скачать обработку: Скачивать файлы может только зарегистрированный пользователь!

Импорт данных из 1С в XML
Обеспечение возможности импорта данных из 1С в XML осуществляет процедура XML_Импорт. Процедура импорта проверяет пользовательский ввод - имя файла и ссылку на документ, данные которого нужно сохранить в XML файл. Далее создается новый текстовый файл, в который средствами 1С осуществляется выгрузка значений всех реквизитов документа и табличных частей.
Исходный код процедуры:

Код 1C v 8.х

 /////////////////////////////////////////////

// Процедура осуществляет выгрузку данных

// выбранного документа из 1С в XML используя

// запись сообщения обмена (XML Writer)

Процедура XML_Импорт(Кнопка)



/////////////////////////////////////////

// Проверить выбор пользователя.

// Поле Документ ДОЛЖНО быть заполнено

Если НЕ ЗначениеЗаполнено(ДокументОбъект) Тогда

Предупреждение("Нужно выбрать документ.");

Возврат;

КонецЕсли;



/////////////////////////////////////////

// Проверить выбор пользователя.

// Поле Имя файла ДОЛЖНО быть заполнено

Если ПустаяСтрока(ИмяФайла) Тогда

Предупреждение("Укажите файл данных XML для выгрузки.");

Возврат;

КонецЕсли;



// Проверить возможность перезаписи текста

Файл = Новый Файл(ИмяФайла);

Если Файл.Существует() Тогда

Ответ = Вопрос("Файл " + ИмяФайла + " существует. Заменить?",РежимДиалогаВопрос.ДаНет);

Если Ответ = КодВозвратаДиалога.Нет Тогда

Сообщить("Сохранение отменено.");

Возврат;

КонецЕсли;

КонецЕсли;



/////////////////////////////////////////

// Записать данные документа в XML используя

// последовательный доступ к тексту и XML сериализацию

ТекстФайл = Новый ЗаписьТекста(ИмяФайла, КодировкаТекста.UTF8);



// Преобразовать данные документа в формат XML

// страндарными средствами платформы 1С

ЗаписьXML = Новый ЗаписьXML;

ЗаписьXML.УстановитьСтроку();

ЗаписатьXML(ЗаписьXML, ДокументОбъект.ПолучитьОбъект());



// Сохранить полученные XML Данные в текстовый документ

ТекстФайл.Записать(ЗаписьXML.Закрыть());

ТекстФайл.Закрыть();

КонецПроцедуры

Экспорт данных из XML в 1С
Обратная операция - экспорт данных из XML в 1С реализована в процедуре XML_Экспорт. Данные, сохраненные на предыдущем этапе, читаются из XML файл при помощи механизма XML Reader. Для восстановления данных документа достаточно указать только имя XML файла, так все необходимые данные о том, какой именно документ нужно восстанавливать уже имеются в файле. После успешного чтения данных 1С средствами платформы изменит требуем документ и откроет его в новом окне для проверки. Для восстановления движений документа его необходимо провести.
Исходный код процедуры:

Код 1C v 8.х

 Процедура XML_Экспорт(Кнопка)

/////////////////////////////////////////

// Проверить выбор пользователя.

// Поле Имя файла ДОЛЖНО быть заполнено

Если ПустаяСтрока(ИмяФайла) Тогда

Предупреждение("Укажите файл данных XML для загрузки!");

Возврат;

КонецЕсли;



/////////////////////////////////////////

// Проверка возможности чтения XML файла

Файл = Новый Файл(ИмяФайла);

Если НЕ Файл.Существует() Тогда

Предупреждение("Указанный Вами файл " + ИмяФайла + " не найден!");

Возврат;

КонецЕсли;



/////////////////////////////////////////

// Прочитать XML файл используя стандартные

// средства платформы 1С XML Reader

попытка

ЧтениеXML = Новый ЧтениеXML;

ЧтениеXML.ОткрытьФайл(ИмяФайла);

НовыйОбъект = ПрочитатьXML(ЧтениеXML);

ДокументОбъект = НовыйОбъект.Ссылка;

Документ = НовыйОбъект.ПолучитьФорму();

Документ.Открыть();

исключение

Сообщить(ОписаниеОшибки());

конецпопытки;

КонецПроцедуры

источник

Категория: Конвертация данных, Обмен, Перенос

Как быстро сохранить огромный отчет в EXCEL?

Иногда бывает так, что отчет очень большой (> 65535 строк), а работать с этим всем нужно через EXCEL - 1С такой отчет в xls не сохранит. Да и отчеты с меньшим количеством строк сохраняются в xls-файл очень долго.

Приведенная здесь небольшая хитрость поможет Вам сохранять для EXCEL таблицы с бОльшим количество строк и делать это быстрее.

Выведите отчет, идем в меню Файл-Сохранить копию и выбираем тип "Документ HTML4". Файл сохранится быстрее, чем в xls, и его корректно откроет EXCEL.
Потом можно в EXCEL пересохранить в xls или xlsx.

Категория: Работа с Microsoft Office и OpenOffice

Работа с Почтой в 1С: Предприятие v 8

У разработчиков на платформе 1С иногда возникает задача по взаимодействию системы 1С: Предприятие с различными почтовыми программами и протоколами. 1С Предприятие 8.0 имеет довольно удобные средства для отправки сообщений, импорта писем из почтового клиента в справочник или другой объект конфигурации, работы с MAPI, SMTP или POP3.

При работе с почтой разделяют два способа доступа к почтовому ящику, почтовому клиенту:

объект "Почта" и объект "Интернет почта", каждый из объектов имеет свои достоинства.

Почта - предоставляет доступ к почте через встроенный почтовый клиент, работает по технологии MAPI.

Интернет почта - объект открывает возможности по доступу непосредственно к почтовым ящикам и учетным записям находящимися на почтовом сервере, использование и работа данного объекта не зависит от установленных в системе почтовых клиентов, даже если почтовый клиент установлен в системе "ИнтернетПочта" будет работать параллельно с ним, объект использует интернет-протоколы SMTP, POP3.

1.Получение сообщений объектом "Почта".

Для работы с объектом Почта необходимо наличие установленного на компьютере почтового клиента с описанными учетными записями.

Для подключения к почтовому клиенту у объекта есть метод "Подключиться".

Код 1C v 8.х

 

Почта = Новый Почта;

Почта.Подключиться(,);

Первый параметр - имя профиля, к примеру, если в системе установлен MS Outlook, то как правило его профиль называется Outlook. Следовательно при подключении строка выглядела бы так:

Код 1C v 8.х

 

Почта.Подключиться("Outlook");

Второй параметр отвечает за пароль к учетной записи.

Далее необходимо произвести выбор необходимых нам писем, для этой цели объект Почта имеет метод "Выбрать". У метода два параметра, первый отвечает за выбор непрочитанных писем - Истина (при Ложь будут выбраны все письма, находящиеся в папке "Входящие" почтового клиента), второй отвечает за выборку вложений, при Ложь, вложения выбираются.

//Выбираем все письма, со всеми вложениями.

Код 1C v 8.х

 Сообщения = Почта.Выбрать(Ложь,Ложь);

(иногда при взаимодействии с Outlook 2003 возникает проблема, при которой 1С 8 просто аварийно завершает работу с ошибкой, именно на данной строке кода, это лечится установкой пакета обновления SP2 для MS Office 2003).

Далее после выборки сообщений необходимо перебрать их в цикле и сохранить, на форме необходимо добавить ТабличноеПоле1 куда будут сохраняться входящие письма.

Код 1C v 8.х

 Для каждого Сообщение Из Сообщения Цикл

//Добавляем строку в табличную часть

СтрокаТП = ТабличноеПоле1.Добавить();



// Перебираем коллекцию получателей сообщения

Для каждого Получатель Из Письмо.Получатели Цикл

Получатели = Получатели + Получатель.Пользователь + " <" + Получатель.Адрес + "> ";

КонецЦикла; 



СтрокаТП.Кому = Получатели;

Попытка

СтрокаТП.ОтКого= Сообщение.Отправитель.Адрес;

Исключение

СтрокаТП.ОтКого= Сообщение.Отправитель;

КонецПопытки;



СтрокаТП.Тема = Сообщение.Тема;

СтрокаТП.Текст = Сообщение.Текст;

СтрокаТП.Дата = Сообщение.ДатаПолучения;



// Перебираем вложения письма

Для каждого Вложение Из Сообщение.Вложения Цикл

Вложение.Данные.Записать(Вложение.Наименование); 

//Запоминаем имена вложение прикрепленных к данному письму, и сохраним в ТабличноеПоле1

Влож=Влож+Вложение.Наименование+",";

КонецЦикла;



СтрокаТП.ПутьВложения=Влож;

КонецЦикла; 



//отключение 

Почта.Отключиться();

Все реквизиты входящих писем сохраняются в соответствующие поля табличного поля, вложения сохраняются в каталог временных файлов, а имена вложений в реквизит табличного поля. Для более удобного хранения вложений писем, 1С 8 имеет тип "Хранилище значения", который позволяет хранить двоичные данные, далее при получении сообщений объектом ИнтернетПочта рассмотрим возможность хранения в "Хранилище значения".

2.Отправка сообщений объектом "Почта"

При отправке сообщения, подключение к почтовому клиенту производится точно так же, как и при получении, перед отправкой необходимо подготовить письмо.

Код 1C v 8.х

 Сообщение = Новый ПочтовоеСообщение;

Сообщение.Текст = "текст сообщения";

Сообщение.Отправитель = "petya@pupkin.com";

Сообщение.Тема ="Тема сообщения";

Сообщение.Получатели.Добавить("vasya@pupkin.com");

Сообщение.Вложения.Добавить(Новый ДвоичныеДанные("C:\file.jpg"),"file.jpg");



Почта = Новый Почта;



//подключаемся без параметров, к клиенту установленному по умолчанию в системе

Почта.Подключиться(,);



Попытка

//Пытаемся послать письмо

Почта.Послать(Сообщение,Истина);

Исключение

Сообщить(ОписаниеОшибки()); 

Возврат;

КонецПопытки; 



//отключение

Почта.Отключиться();

В методе Почта.Послать(Сообщение,Истина) два параметра, первый принимает ссылку на почтовое сообщение, второй параметр определяет, требуется ли запрос на подтверждение о получении письма адресатом (Истина - запрос включен). После этих операций письмо попадает в папку "Исходящие" почтового клиента, и в зависимости от настроек клиента отправляется сразу или по команде пользователя.

В MS Outlook встроена защита от несанкционированного доступа к адресной книге и базе почтовых сообщений, и защита от несанкционированной отправки электронных писем через службы Outlook. В Outlook 2003 система безопасности срабатывает не только при попытке получить адрес отправителя письма, но даже при попытке получить его текст. В действительности защита выражается в показываемом пользователю окне системы безопасности при обращении к некоторым объектам и свойствам объектов Outlook и предлагает открыть доступ на определенное время, следует разрешить доступ.

3.Получение сообщений объектом "ИнтернетПочта".

Перед подключением к почтовому серверу, для объекта ИнтернетПочта необходимо заполнить данные Профиля учетной записи, и затем передать эти данные в метод "Подключиться".

Код 1C v 8.х

 Функция ПолучитьПрофиль()



Профиль = Новый ИнтернетПочтовыйПрофиль;



// SMTP сервер

Профиль.АдресСервераSMTP = "smtp.pupkin.com";



// Порт SMTP сервера

Профиль.ПортSMTP = 25;



// POP3 сервер

Профиль.АдресСервераPOP3 = "pop.pupkin.com";



// Порт POP3 сервера

Профиль.ПортPOP3 = 110;



// Пароль к почтовому ящику

Профиль.Пароль = "pass";



// Пароль пользователя для SMTP сервера

Профиль.ПарольSMTP = "pass";



// Логин пользователя

Профиль.Пользователь = "vasya";



// Логин пользователя для SMTP сервера

Профиль.ПользовательSMTP = "vasya";



// Время ожидания выполнения операции в секундах



Профиль.ВремяОжидания = 50; 

Возврат Профиль;



КонецФункции





Почта = Новый ИнтернетПочта;



Попытка

Почта.Подключиться(ПолучитьПрофиль());

Исключение

Сообщить(ОписаниеОшибки()); 

Возврат;

КонецПопытки;



Заголовки=Почта.ПолучитьЗаголовки()

Если Заголовки.Количество()=0 Тогда

Предупреждение("В почтовом ящике нет входящих сообщений!", ,"Нет сообщений");

КонецЕсли;



// Загрузка сообщений в массив

Сообщения = Почта.Выбрать(Истина,Заголовки);



Для каждого Сообщение Из Сообщения Цикл

СтрокаТП = ТабличноеПолеИнтернетПочта.Добавить();

СтрокаТП.Дата = Сообщение.ДатаОтправления;

СтрокаТП.ОтКого = Сообщение.Отправитель.Пользователь + " <" + Сообщение.Отправитель.Адрес + "> ";

СтрокаТП.Тема = Сообщение.Тема;



// Перебираем получателей сообщения

Для каждого Получатель Из Сообщение.Получатели Цикл

КомуВходящие = КомуВходящие + Получатель.Пользователь + " <" + Получатель.Адрес + "> ";

КонецЦикла; 

СтрокаТП.Кому = КомуВходящие;



// Перебираем тексты сообщения

Для каждого ТекстСообщения Из Сообщение.Тексты Цикл

ТекстВходящие = ТекстВходящие + ТекстСообщения.Текст;

КонецЦикла; 

СтрокаТП.Текст = ТекстВходящие;



// Перебираем вложения письма

Для каждого Вложение Из Сообщение.Вложения Цикл

Вложение.Данные.Записать(Вложение.Name);

СправочникВложения.РеквизитВложение = новый ХранилищеЗначения(Новый ДвоичныеДанные(Вложение.Name));

СправочникВложения.ИмяВложения=Вложение.Name;

КонецЦикла;

КонецЦикла; 



// отключение

Почта.Отключиться();

Метод Почта.Выбрать(Истина,Заголовки); имеет два параметра, первый отвечает за удаление писем с сервера (при Истина-удалять), второй параметр отвечает за массив сообщений для выборки (т.е. закачки на компьютер клиента с сервера), если параметр пуст, то выбираются все сообщения находящиеся на сервере.

При переборе вложений, данные полученные из письма сохраняются в реквизит типа ХранилищеЗначения, заранее созданного справочника "СправочникВложения" в конфигураторе, т.к. данные первоначально сохраняются на диск, а затем загружаются в справочник, то, после загрузки в соответствующий реквизит справочника данные можно удалить. Не рекомендуется хранить данные типа ХранилищеЗначения в Табличных частях справочников, т.к. при больших объемах данных это затормаживает работу конфигурации.

4.Отправка сообщений объектом "ИнтернетПочта".

При отправке сообщения используется Функция ПолучитьПрофиль().

Код 1C v 8.х

 

Почта = Новый ИнтернетПочта;

Попытка

Почта.Подключиться(ПолучитьПрофиль());

Исключение

Сообщить(ОписаниеОшибки()); 

Возврат;

КонецПопытки;

Сообщение = Новый ИнтернетПочтовоеСообщение;



Сообщение.Вложения.Добавить(Новый ДвоичныеДанные("C:\file.jpg"),"file.jpg");



Сообщение.Отправитель = "vasya@pupkin.com";

Сообщение.ИмяОтправителя = "Вася";

ПочтовыеАдреса = Сообщение.Получатели;

ПочтовыйАдрес = ПочтовыеАдреса.Добавить();

ПочтовыйАдрес.Адрес = "petya@pupkin.com";

Сообщение.Тема ="Тема сообщения"; 



ИнтернетТекстПочтовогоСообщения = Сообщение.Тексты.Добавить();

ИнтернетТекстПочтовогоСообщения.Текст = "Текст сообщения";

ИнтернетТекстПочтовогоСообщения.ТипТекста = ТипТекстаПочтовогоСообщения.ПростойТекст;



Попытка

// Пытаемся послать письмо

Почта.Послать(Сообщение);

Исключение

Сообщить(ОписаниеОшибки()); 

Возврат;

КонецПопытки;

// отключение

Почта.Отключиться();

Удобно подключить автополучение/автоотправку почты командой "ПодключитьОбработчикОжидания(,)". Первый параметр в команде отвечает за наименование вызываемой процедуры, и второй, период ожидания процедуры в секундах, обычно обработчик ожидания вставляется в глобальный модуль системы (например, в процедуру ПриНачалеРаботыСистемы()) и указывает на процедуру с пометкой Экспорт.

Например, можно создать процедуру ПроверитьПочту, в которую вставить загрузку писем из почтового ящика и вставить ее в следующую строку:

ПодключитьОбработчикОжидания("ПроверитьПочту",60)

Также для обработки и просмотра сообщений в формате HTML удобно пользоваться компонентом "Поле HTML документа", для загрузки HTML текста в компонент используется метод ПолеHTMLдокумента.УстановитьТекст(Html), где Html-это документа полученный из текста сообщения. Есть вариант загрузки HTML с диска (если это вложение), ПолеHTMLдокумента.Перейти("file:\\C:\File.html").

После использования нескольких или сразу всех способов работы с электронной почтой, образуется полноценный почтовый клиент с возможностью хранения и обработки писем с вложениями на базе 1С предприятие 8.0.

Автор: Alimov Roman

Как организовать работу с почтой без установленного почтового клиента на компьютере пользователя?

Категория: Работа с Интернет, Почтой (Mail), FTP

Технологический журнал 1С v8.1

Технологический Журнал (далее ТЖ) позволяет протоколировать все события 1С:Предприятия (или часть, используя фильтр).
ТЖ настраивается с помощью файла logcfg.xml в папку программы C:\Program Files\1cv81\bin\conf, пример структуры файла (включить запись событий DBMSSQL):

Код

< config xmlns="http://v8.1c.ru/v8/tech-log">
< log history="168" location="C:\Program Files\1Cv81\bin\logs">
< event>
< eq property="name" value="dbmssql"/>
< /event>
< property name="all"/>
< /log>
< dump create="1" location=location="C:\Program Files\1Cv81\bin\dumps" type="2" />
< /config>

1. Для успешного создания логов, нужно создать каталоги для логов (например C:\Program Files\1cv81\bin\logs) и дапмов (например C:\Program Files\1cv81\bin\dumps),
где в случае аварийного завершения ТЖ создаст дамп памяти и копию экрана для передачи разработчикам.
Важно иметь в виду, что в каталог ТЖ при некоторых его настройках могут выводится данные очень большого объема. Поэтому, либо на диске С: должно быть достаточно места, либо каталог ТЖ необходимо изменить.
Для работы ТЖ необходимо, чтобы пользователи, от имени которых запускаются приложения 1С:Предприятия (как клиентские, так и серверные), имели полные права на каталог ТЖ (C:\Program FiIes\1cv81\bin\logs), и право на чтение выше лежащего каталога (C:\Program Files\lcv81).
Примечание. Если все равно не пишется ТЖ, то дать права всем на эту папку (временно, чтобы убедиться что дела в правах).

В каталоге технологического журнала не должно быть посторонних файлов. Каталог, в котором имеются посторонние файлы не позволит создавать журнал (логи).
Место хранения dumps и logs не хранить вместе, потому что через указанный интервал (по умолчанию 1 час) содержимое польностью перетирается и вы потеряете дампы

2. ТЖ лучше настраивать (с помощью фильтров - тэгов logcfg.xml) только на исследуемые события, остальное не собирать, иначе словите "отсутствие места на диске" и тормоза в быстродействии сервера.
Легче выполнять настройку фильтров с помощью обработки с ИТС НастройкаТехнологическогоЖурнала.epf, но при этом помнить, что новые фичи последних релизов в обратке могут отстутствавать (каждая новая версия добавляет новые возможности, в обработки они не отражены). В этом случаи корректировать файл logcfg.xml руками.

Структура конфигурационного файла

Корневым элементом конфигурационного файла является элемент < config>, который определяет настройки ТЖ. он может содержать несколько элементов < log> и один < dump>

< log> определяет каталог ТЖ:
history = количество часов, через которое инфа будет удалятся из ТЖ.
location = Каталог в котором сохраняются логи

Код

< log history="168" location="C:\Program Files\1Cv81\bin\logs">
...
< /log>

Элемент < dump> определяет каталог в который будут записываться дампы аварийного завершения

Код

< dump create="1" location=location="C:\Program Files\1Cv81\bin\dumps" type="2" />

< event> - этим элементом определяется условие, при выполнении которого событие будет записано в ТЖ. Условия записываются элементами:
eq = равно
ne = не равно
gt = больше
ge = больше или равно
lt = меньше
le = меньше или равно
like = соответсвие маске

property - атрибут задает название события
value - атрибут задает значение события, ниже пример в котором в ТЖ будут регистрироваться события относящиеся к группе с именем "dbmssql"

Код

< event>
< eq property="name" value="dbmssql"/>
< /event>

Доступны следующие имена групп, с выходом новых версий платформы возможны добавления новых групп:
PROC - события, относящиеся к процессу целиком и влияющие на дальнейшую работоспособность процесса(старт, завершение, аварийное завершение и т.д.);
SCOM - события создания или удаления серверного контекста, обычно связанного с информационной базой;
ЕХСР - исключительные ситуации приложений системы Предприятие 8.1, которые штатно не обрабатываются и могут послужить причиной аварийного завершения серверного процесса или подсоединенного к нему клиентского процесса;
EXCPCNTX - события, которые начались, но не закончились в момент возникновения нештатной ситуации;
SDBL - события, связанные с исполнением запросов к модели базы данных системы 1С:Предприятие 8.1;
QERR - события, связанные с обнаружением ошибок компиляции запроса или ограничения на уровне записей и полей базы данных.
PERR - события, связанные с обнаружением ошибок работы с настройками пользователя;
CONN - установка или разрыв клиентского соединения с сервером;
ADMIN - управляющие воздействия администратора кластера серверов;
DBV8DBErg - исполнение операторов SQL файловой СУБД;
DBMSSQL - исполнение операторов SQL СУБД Microsoft SQL Server;
DBPOSTGRS - исполнение операторов SQL СУБД PostgreSQL;
DB2 - исполнение операторов SQL СУБД DB2,
CALL - удаленный вызов.
TLOCK - управление транзакционными блокировками в управляемом режиме.

Следует заметить, что на клиентском компьютере могут возникать только те события, которые отсносятся к группам PROC, ЕХСР, SDBL Также на клиентском компьютере могут возникать события из группы DBVBDBEng, если используется файловый вариант работы системы 1С:Предприятие 8.1.
Также следует заметить, что события из групп PROC, SCOW, ЕХСP, CONN и ADMIN возникают относительно и содержат малое количестово информации, в то время как регистрация событий из групп SDBL, DBVPCBE v и DBMSSQL может привозить к значительному росту ТЖ.

3. Чтобы логи перестали собираться достаточно переименовать файл, перезапускать сервер не надо, настройки пересчитываются каждую минуту "на лету"

4. Настроить logcfg.xml для фильтрации событий по определённой ИБ нужно использовать "p:processName="
5. Дополнительные примеры настроек взятые с форумов
6. Дополнительные примеры настроек на сайте 1С

7. Понятно, что собрать логи мало, их еще нужно обработать для решения конкретной задачи.
Файлы ТЖ могут быть просмотрены с помощью любого текстового редактора, но через блокнот ТЖ сложно читаем, так как:
- Требует хорошего понимания архитектуры работы системы
- Тексты запросов регистрируются на внутреннем языке 1С:Предприятия и на языке DBMS
Файлы технологического журнала хранятся в подкаталогах. Имя каждого подкаталога технологического журнала одного процесса будет иметь вид: < ИмяПроцесса>_< ИдентификаторПроцесса>, например: rphost_4076. Имя файла журнала задается шаблоном ГГММДДЧЧ.log. Например, в журнале 07051819.log имя файла образовано от 2007 мая 18, 19 часов)
Журнал для анализа можно выгрузить в эксель, используя разделителем запятую например
1С:ЦУП использует для своих аналитических показалей логи технологического журнала. При использовании ЦУП другие данные собираться не должны, удалите logcfg.xml вручную, ЦУП сам создаст файл с нужными настройками.

Других парсеров логов от 1С нет, есть ObrabotkaTehnologiceskogoGurnala.epf

8. Возможные ошибки и доп. информация:
- ищем логи в каталоге на сервере хотя для 64 разрядного сервера другой каталог программы
- отследить не завершившийся запрос; событие технологического журнала DBMSSQL выводится только в момент окончания выполнения запроса. Если запрос долго не может выполниться, то его выполнение можно прервать, после чего будут выведены в технологический журнал связанные с ним события.

В статье использованы материалы с http://www.gilev.ru/1c/81/techlog/index.htm

Категория: Администрирование

Как занести лицевые счета работников для выплаты з/п, счета у сотрудников в разных банках?

1.Войдите в пункт меню «Расчет зарплаты по организации» - «Касса и банк» - «Заявка на открытие счета».
2.Поставьте галочку напротив реквизита «Ввод начальных сведений».
3.Укажите в поле «Банк», банк в котором у сотрудника открыт счет. Предварительно для выбора заполните справочник «Контрагенты» списком банков.
4.В табличной части формы добавьте сотрудника, номер его счета. Нажмите на кнопку «Записать».
5.На панели инструмента открытой формы документа «Заявка на открытие счета» нажмите кнопку «Создать новый копированием», в котором сведения для предыдущего сотрудника замените на сведения для нового. Нажмите на «Ок».
6.Повторите п. 5 для остальных сотрудников.
Записанные номера лицевых счетов работников сохраняются в регистре сведений «Лицевые счета работников организации» («Расчет зарплаты по организации» - «Касса и банк» - «Лицевые счета работников организации»)

Категория: 1С Зарплата и Управление Персоналом 2.5