списоквыбора » Поиск

Результаты по ключевому слову: списоквыбора

Вывод в поле Наименование справочника Штатное список значений из справочника Подразделения? Категория: Справочники

Динамический отчет на СКД с разными вариантами

На днях делал несколько однотипных отчетов на СКД.

Общий принцип: формируются все варианты отчета, указанные в настройках схемы и каждый вариант выводится на отдельной вкладке.

Потом возникла мысль попробовать объединить все схемы в один отчет, чтобы не плодить лишних объектов в конфигурации. При этом количество вариантов в этих схемах заранее неизвестно. Ok, challenge accepted.

В тестовой конфигурации создаю для отчета две схемы компоновки, "Склад" и "Заявки".

Запросы наборов данных приводить не буду, для каждой схемы в настройках добавляю несколько вариантов отчетов.

Теперь переходим к созданию формы. Практически все реквизиты формы будут создаваться при выборе необходимого макета отчета.

Код 1C v 8.2 УП

 &НаСервере
Процедура СоздатьПереченьОтчетов()


 Для Каждого Макет Из РеквизитФормыВЗначение("Отчет").Метаданные().Макеты Цикл
  Элементы.МакетОтчета.СписокВыбора.Добавить(Макет.Имя, Макет.Синоним);
 КонецЦикла;


КонецПроцедуры // СоздатьПереченьОтчетов()


&НаСервере
Процедура ОбработатьВыборМакета()


 Макет = РеквизитФормыВЗначение("Отчет").ПолучитьМакет(МакетОтчета);
 
 мУдалить = ?(ПустаяСтрока(РеквизитыКУдалению), Новый Массив, ПолучитьИзВременногоХранилища(РеквизитыКУдалению));
 мДобавить = Новый Массив;
 кУдалению = Новый Массив;
 
 Для Каждого Вариант Из Макет.ВариантыНастроек Цикл
  ИмяРеквизита = "ТабДок_" + Вариант.Имя;
  тРеквизит = Новый РеквизитФормы(ИмяРеквизита, Новый ОписаниеТипов("ТабличныйДокумент"));
  мДобавить.Добавить(тРеквизит);
  кУдалению.Добавить(ИмяРеквизита);
 КонецЦикла;
 
 ИзменитьРеквизиты(мДобавить, мУдалить);
 
 Пока Элементы.СтраницыОтчета.ПодчиненныеЭлементы.Количество() Цикл
  Элементы.Удалить(Элементы.СтраницыОтчета.ПодчиненныеЭлементы[0]);
 КонецЦикла;
 
 Для Каждого Вариант Из Макет.ВариантыНастроек Цикл
  
  Страница = Элементы.Добавить("Страница_" + Вариант.Имя, Тип("ГруппаФормы"), Элементы.СтраницыОтчета);
  Страница.Вид = ВидГруппыФормы.Страница;
  Страница.Заголовок = Вариант.Представление;
  
  ИмяРеквизита = "ТабДок_" + Вариант.Имя;
  ТабДок = Элементы.Добавить(ИмяРеквизита, Тип("ПолеФормы"), Страница);
  ТабДок.Вид = ВидПоляФормы.ПолеТабличногоДокумента;
  ТабДок.ПутьКДанным = ИмяРеквизита;
  ТабДок.ПоложениеЗаголовка = ПоложениеЗаголовкаЭлементаФормы.Нет;
  
  ЭтаФорма[ИмяРеквизита].Очистить();


 КонецЦикла;
 
 РеквизитыКУдалению = ПоместитьВоВременноеХранилище(кУдалению, УникальныйИдентификатор);


КонецПроцедуры // ОбработатьВыборМакета()


&НаСервере
Процедура СформироватьОтчеты()


 Схема = РеквизитФормыВЗначение("Отчет").ПолучитьМакет(МакетОтчета);
 
 Для Каждого Вариант Из Схема.ВариантыНастроек Цикл
  
  Отчет.КомпоновщикНастроек.ЗагрузитьНастройки(Вариант.Настройки);
     
     КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
     Макет = КомпоновщикМакета.Выполнить(Схема, Отчет.КомпоновщикНастроек.ПолучитьНастройки());
     
     ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
     ПроцессорКомпоновки.Инициализировать(Макет);
     
     ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
     ПроцессорВывода.УстановитьДокумент(ЭтаФорма["ТабДок_" + Вариант.Имя]);
     ПроцессорВывода.Вывести(ПроцессорКомпоновки); 
  
 КонецЦикла;


КонецПроцедуры // СформироватьОтчеты()


&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
 
 СоздатьПереченьОтчетов();
 
КонецПроцедуры


&НаКлиенте
Процедура МакетОтчетаПриИзменении(Элемент)
 
 ОбработатьВыборМакета();
 
КонецПроцедуры


&НаКлиенте
Процедура Сформировать(Команда)
 
 СформироватьОтчеты();
 
КонецПроцедуры

Смотрим, что получилось.

Выгрузка базы 1Cv8skd.rar

Источник

Категория: Схема Компоновки Данных

Добавление в список выбора листов excel-файла с возможностью последующего к ним обращения Категория: Работа с Microsoft Office и OpenOffice

Поле выбора ~ Как заполнить список выбора элемента формы?

Код 1C v 8.х

 
Запрос = Новый Запрос(
	"ВЫБРАТЬ РАЗРЕШЕННЫЕ
	|	Организации.Ссылка,
	|	Организации.Наименование КАК Наименование
	|ИЗ
	|	Справочник.Организации КАК Организации
	|ГДЕ
	|	Организации.ГоловнаяОрганизация = &ПустаяОрганизация
	|
	|ОБЪЕДИНИТЬ
	|
	|ВЫБРАТЬ РАЗЛИЧНЫЕ
	|	Организации.ГоловнаяОрганизация,
	|	Организации.ГоловнаяОрганизация.Наименование
	|ИЗ
	|	Справочник.Организации КАК Организации
	|ГДЕ
	|	Организации.ГоловнаяОрганизация <> &ПустаяОрганизация
	|
	|УПОРЯДОЧИТЬ ПО
	|	Наименование");
	Запрос.УстановитьПараметр("ПустаяОрганизация", Справочники.Организации.ПустаяСсылка());						  
	СписокОрганизаций = Новый СписокЗначений;
	Выборка = Запрос.Выполнить().Выбрать(); 
	Пока Выборка.Следующий() Цикл
		СписокОрганизаций.Добавить(Выборка.Ссылка, Выборка.Наименование);
	КонецЦикла; 
	СписокОрганизаций.Вставить(0, Справочники.Организации.ПустаяСсылка(), "По всем сотрудникам");
	ЭлементыФормы.ОтборПоОрганизации.СписокВыбора = СписокОрганизаций;
	// Установим текущим первое значение
	ЭлементыФормы.ОтборПоОрганизации.Значение = ЭлементыФормы.ОтборПоОрганизации.СписокВыбора.Получить(0).Значение;

Посмотрите также пример: Загрузка значений в элемент список значений на форме

Категория: Работа с Формой (Диалог) и её элементами

Битая ссылка, <Объект не найден>, Уникальный Идентификатор, GUID Категория: 1С Общие вопросы - Обычные формы

Поле выбора ~ Заполнение списка значений в элементе поле выбора на форме

Код 1C v 8.х

  //Заполнение списка перебором данных
// Элемент формы МетаданныеВыбор имеет тип - Произвольный, Использование - Режим выбора из Списка, кнопка списка
Для Каждого Метаданное из Метаданные.РегламентныеЗадания Цикл
   ЭлементыФормы.МетаданныеВыбор.СписокВыбора.Добавить(Метаданное.Имя, Метаданное. Представление());
КонецЦикла;

Код 1C v 8.х

  // Загрузка из списка значений
// Элемент формы ПараметрЦены имеет тип - Строка, Использование -  кнопка списка
СписВыб = Новый СписокЗначений;
СписВыб.Добавить("Закупочная","Закупочная");
СписВыб.Добавить("Розничная","Розничная");
ЭлементыФормы.ПараметрЦены.СписокВыбора = СписВыб;

Код 1C v 8.х

  //Прямое добавление в список выбора
// Элемент формы Операционка имеет тип - Строка, Использование -  кнопка списка
ЭлементыФормы.Операционка.СписокВыбора.Добавить("Windows 98");
ЭлементыФормы.Операционка.СписокВыбора.Добавить("Windows 2000");
ЭлементыФормы.Операционка.СписокВыбора.Добавить("Windows XP");

Код 1C v 8.х

  //Заполнение данными из результата запроса
Запрос = Новый Запрос;
Запрос.УстановитьПараметр("Физлицо",	Физлицо);
Запрос.Текст =
	"ВЫБРАТЬ
	|	ФизическиеЛицаСоставСемьи.Имя
	|ИЗ
	|	Справочник.ФизическиеЛица.СоставСемьи КАК ФизическиеЛицаСоставСемьи
	|ГДЕ
	|	ФизическиеЛицаСоставСемьи.Ссылка = &Физлицо
	|
	|УПОРЯДОЧИТЬ ПО
	|	ФизическиеЛицаСоставСемьи.НомерСтроки";

ЭлементыФормы.Родственник.СписокВыбора.ЗагрузитьЗначения(Запрос.Выполнить().Выгрузить().ВыгрузитьКолонку("Имя"));

Категория: Работа с Формой (Диалог) и её элементами

Получить список Документов конфигурации

Код 1C v 8.х

  //ЭлементыФормы.ОбъектПоиска - Поле Выбора на форме
	СписокВыбора = ЭлементыФормы.ОбъектПоиска.СписокВыбора;
	Для Каждого Документ Из Метаданные.Документы Цикл
		//Проверим, есть ли права на просмотр? Да- добавляем, Нет - пропускаем
		Если ПравоДоступа("Просмотр", Документ) Тогда
			ИмяДокумента = Документ.Синоним;
			Если ИмяДокумента = "" Тогда
				ИмяДокумента = Документ.Имя;
			КонецЕсли;
			Структура = Новый Структура;
			Структура.Вставить("Тип", "Документ");
			Структура.Вставить("Объект", Документ);
			СписокВыбора.Добавить(Структура, ИмяДокумента, ,ЭлементыФормы.КартинкаДокумента.Картинка);
		КонецЕсли;
	КонецЦикла;

Код 1C v 7.x

 //Выведем список всех документов в окно сообщений
	Для Индекс=1 По Метаданные.Документ() Цикл
		Значение = Метаданные.Документ(Индекс).Идентификатор;
		Представление = Метаданные.Документ(Индекс).Представление();
		Комментарий = Метаданные.Документ(Индекс).Комментарий;
		Сообщить(значение+"  "+Представление+"  "+Комментарий);
	КонецЦикла;
    // Выведем Список документов, ФормРегистр - Поле со списком на форме
	ФормРегистр.УдалитьВсе();
	Для ъ=1 По Метаданные.Регистр() Цикл
		ФормРегистр.ДобавитьЗначение(Метаданные.Регистр(ъ).Идентификатор, Метаданные.Регистр(ъ).Представление());
	КонецЦикла;
	Если ФормРегистр.РазмерСписка()>0 Тогда
		ФормРегистр.ТекущаяСтрока(1);
	КонецЕсли;
	
	//функция создаёт список реквизитов документа
Процедура гСписокРеквизитовДокумента(Список,Документ,ФлагПредставление=0) Экспорт
     //шапка
     Для i=1 По Метаданные.Документ(Документ).РеквизитШапки() Цикл
          Ж=Метаданные.Документ(Документ).РеквизитШапки(i);
          Если ФлагПредставление=0 Тогда
               Представление=Ж.Идентификатор;
          Иначе
               Представление=Ж.Представление();
          КонецЕсли;
          Список.ДобавитьЗначение(Ж.Идентификатор,"Ш: "+Представление);
     КонецЦикла;
     //многострочка
     Для i=1 По Метаданные.Документ(Документ).РеквизитТабличнойЧасти() Цикл
          Ж=Метаданные.Документ(Документ).РеквизитТабличнойЧасти(i);
          Если ФлагПредставление=0 Тогда
               Представление=Ж.Идентификатор;
          Иначе
               Представление=Ж.Представление();
          КонецЕсли;
          Список.ДобавитьЗначение(Ж.Идентификатор,"Т: "+Представление);
     КонецЦикла;
     //общий
     Для i=1 По Метаданные.ОбщийРеквизитДокумента() Цикл
          Ж=Метаданные.ОбщийРеквизитДокумента(i);
          Если ФлагПредставление=0 Тогда
               Представление=Ж.Идентификатор;
          Иначе
               Представление=Ж.Представление();
          КонецЕсли;
          Список.ДобавитьЗначение(Ж.Идентификатор,"О: "+Представление);
     КонецЦикла;
КонецПроцедуры

Категория: Метаданные

Получить список Справочников конфигурации

Код 1C v 8.2 УП

 &НаКлиенте
Процедура ПоКнопкеЧтениеИзМетаданных(Команда)
        // Вставить содержимое обработчика.
        Перем СписокСправочников; 

        СписокСправочников = Новый СписокЗначений;
        СписокСправочников = СправочникиИзМетаданных();
        Для Сч = 0 По СписокСправочников.Количество() - 1 Цикл 
               Сообщить(СписокСправочников.Получить(Сч))
       КонецЦикла;

КонецПроцедуры

&НаСервере
Функция СправочникиИзМетаданных()

        Перем СписокСправочников, СправочникИзМетаданных;
        СписокСправочников = Новый СписокЗначений;
        Для Каждого СправочникИзМетаданных Из Метаданные.Справочники Цикл
                СписокСправочников.Добавить(СправочникИзМетаданных.Имя);
        КонецЦикла;

        Возврат СписокСправочников;

КонецФункции

Код 1C v 8.х

 //ЭлементыФормы.ОбъектПоиска - Поле Выбора на форме
	СписокВыбора = ЭлементыФормы.ОбъектПоиска.СписокВыбора;
	Для Каждого Справочник Из Метаданные.Справочники Цикл
		//Проверим, есть ли права на просмотр? Да- добавляем, Нет - пропускаем
		Если ПравоДоступа("Просмотр", Справочник) Тогда
			ИмяСправочника = Справочник.Синоним;
			Если ИмяСправочника = "" Тогда
				ИмяСправочника = Справочник.Имя;
			КонецЕсли;
			Структура = Новый Структура;
			Структура.Вставить("Тип", "Справочник");
			Структура.Вставить("Объект", Справочник);
			СписокВыбора.Добавить(Структура, ИмяСправочника, ,ЭлементыФормы.КартинкаСправочника.Картинка);
		КонецЕсли;
	КонецЦикла;

Код 1C v 7.x

 	//Выведем список всех справочников в окно сообщений
	Для Индекс=1 По Метаданные.Справочник() Цикл
		Значение = Метаданные.Справочник(Индекс).Идентификатор;
		Представление = Метаданные.Справочник(Индекс).Представление();
		Комментарий = Метаданные.Справочник(Индекс).Комментарий;
		Сообщить(Значение+"  "+Представление+"  "+Комментарий);
	КонецЦикла;

Категория: Метаданные