стороне » Поиск

Результаты по ключевому слову: стороне

Ограничение доступа на уровне записей - RLS (Отбор по организации)

Часто возникает необходимость в частичном ограничении доступа к данным. Например, когда пользователь должен видеть документы только своей организации. В таких случаях в 1С используется механизм ограничения доступа на уровне записей (так называемый, RLS – Record Level Securiy).

Для примера предположим, что перед нами стоит следующая задача. На предприятии ведется многофирменный учет и каждый контрагент и пользователь базы данных относится к определенной организации. Необходимо обеспечить доступ к справочнику “Контрагенты” таким образом, чтобы каждый пользователь мог просматривать, редактировать и добавлять контрагентов только своей организации.

Для решения задачи будем использовать платформу “1С:Предприятие 8.2″. Создадим новую конфигурацию в свойствах которой в качестве основного режима запуска будет выбран вариант “Управляемое приложение”.

Далее создадим справочник “Организации” и ещё два справочника – “Контрагенты” и “Пользователи” с реквизитом “Организация”. Кроме справочников нам понадобятся два параметра сеанса – “Организация” и “Пользователь” (соответствующих типов). Значения этих параметров устанавливаются при запуске сеанса работы с конфигурацией и хранятся до его завершения. Именно значения этих параметров мы и будем использовать при добавлении условий ограничения доступа на уровне записей.

Установка параметров сеанса выполняется в специальном модуле – “Модуль сеанса”

В этом модуле опишем предопределенную процедуру “УстановкаПараметровСеанса” в которой вызовем функцию заранее подготовленного общего модуля “ПолныеПрава”. Это необходимо в силу особенностей работы базы данных в режиме управляемого приложения, когда часть программного кода может выполняться только на стороне сервера (подробно на объяснении этих принципов в данной статье я останавливаться не буду).

Код 1C v 8.х

 Процедура УстановкаПараметровСеанса(ТребуемыеПараметры)

    ПолныеПрава.УстановитьПараметрыСеанса();

КонецПроцедуры<br>

В свойствах модуля “ПолныеПрава” необходимо отметить флажки “Сервер”, “Вызов сервера” и “Привилегированный” (последнее означает, что процедуры и функций данного модуля будут выполнятся без контроля прав доступа). Текст модуля будет выглядеть так:

Код 1C v 8.х

 Функция ОпределитьТекущегоПользователя()

    ТекПользователь = Справочники.Пользователи.НайтиПоНаименованию(ИмяПользователя(),Истина);

    Возврат ТекПользователь;

КонецФункции





Процедура УстановитьПараметрыСеанса() Экспорт

    ТекущийПользователь = ОпределитьТекущегоПользователя();

    ТекущаяОрганизация = Справочники.Организации.ПустаяСсылка();

    Если ЗначениеЗаполнено(ТекущийПользователь) Тогда

        ТекущаяОрганизация = ТекущийПользователь.Организация;

    КонецЕсли;

    ПараметрыСеанса.Пользователь = ТекущийПользователь;

    ПараметрыСеанса.Организация = ТекущаяОрганизация;

КонецПроцедуры





Функция ПараметрСеансаУстановлен(ИмяПараметра) Экспорт

    Возврат ЗначениеЗаполнено(ПараметрыСеанса[ИмяПараметра]);

КонецФункции





Функция РольДоступнаПользователю(ИмяРоли) Экспорт

    Возврат РольДоступна(ИмяРоли);

КонецФункции<br>

В модуле управляемого приложения будем проверять наличие пользователя конфигурации в справочнике “Пользователи” (для простоты будем искать его по наименованию) и завершать работу системы если он не найден. Это необходимо для того, чтобы обеспечить заполнение параметров сеанса.

Код 1C v 8.х

 Процедура ПередНачаломРаботыСистемы(Отказ)

    // всех кроме администратора будем проверять на наличие в справочнике "Пользователи"

    Если Не ПолныеПрава.РольДоступнаПользователю("ПолныеПрава") Тогда

        Если НЕ ПолныеПрава.ПараметрСеансаУстановлен("Пользователь") Тогда

            Предупреждение("Пользователь """ + ИмяПользователя() + """ не найден в справочнике!");

            Отказ = Истина;

            Возврат;

        КонецЕсли;

    КонецЕсли;

КонецПроцедуры<br>

Теперь можем перейти непосредственно к описанию ограничений доступа. Для этого создадим роль “Пользователь” и перейдем на закладку “Шаблоны ограничений”, где добавим новый шаблон “КонтрагентыЧтениеИзменение” со следующим текстом шаблона: ГДЕ Организация =Организация #Параметр(1)

Текст шаблона ограничений является расширением языка запросов. В отличии от обычного запроса, текст ограничения должен в обязательном порядке содержать условие “ГДЕ”. В качестве значений параметров запроса (в нашем случае это “&Организация”) используются значения одноименных параметров сеанса. Конструкция вида #Параметр(1) означает, что на это место система подставит текст, переданный в качестве первого параметра в месте использования шаблона. С помощь приведенного шаблона будет выполняться проверка каждой записи таблицы (в нашем случае это будет справочник “Контрагены”). Для записей, значение реквизита “Организация” которых совпадает с заданным в соответствующем параметре сеанса, условие описанное в шаблоне будет выполняться. Таким образом эти записи будут доступны для чтения, изменения или добавления (в зависимости от того для какого из этих прав применяется шаблон). Продемонстрирую вышеизложенное на нашем примере.

Перейдем на закладку “Права” роли “Пользователь” и откроем список прав справочника “Контрагенты”. Будем использовать шаблон ограничений “КонтрагентыЧтениеИзменеие” для прав “Чтение”, “Изменение” и “Доблавление”.

Для права “Чтение” будем использовать шаблон с параметром “ИЛИ ЭтоГруппа”. При этом пользователям данной роли будет разрешено чтение не только элементов справочника “Контрагенты” своей организации, но и всех групп этого справочника.

#КонтрагентыЧтениеИзменение("ИЛИ ЭтоГруппа")

Поскольку при добавлении новых элементов справочника системой выполняется неявное чтение предопределенных реквизитов (это нужно, например, для нумерации), то необходимо обеспечить беспрепятственное чтение этих полей. Для этого добавим дополнительную строку с пустым текстом ограничения в таблицу ограничения доступа к данным и перечислим поля для которых действует данное правило – Ссылка, Версия данных, Родитель, Код.

Таким образом, поставленная задача ограничения доступа на уровне записей решена. Пользователи с действующими ограничениями получат доступ на просмотр и редактирование данных только своей организации.

Источник

Категория: Пользователь, роль доступа, интерфейс

О формате EnterpriseData

Для облегчения интеграции с программными продуктами фирмы «1С» разработан формат обмена данными EnterpriseData. Формат основан на XML и является бизнес-ориентированным – описанные в нем структуры данных соответствуют бизнес-сущностям (документам и элементам справочников), представленным в программах «1С», например: акт выполненных работ, приходный кассовый ордер, контрагент, договор и т. п. Это делает формат интуитивно понятным и легким в использовании.

Формат EnterpriseData предназначен для обмена данными внутри компании (в том числе между разнородными и территориально удаленными информационными системами) и призван покрыть все сферы деятельности предприятия – финансы, производство, закупки и продажи, складские операции и т. п.

Описание формата

Версия 1.0.1 формата включает в себя описание 94 типов бизнес-сущностей из различных областей бизнеса (подробное описание формата можно найти здесь). Формат является расширяемым – фирма «1С» будет добавлять в него описание новых бизнес-сущностей и расширять существующие сущности новыми полями. Поддержка формата в продуктах фирмы «1С» обеспечивает совместимость снизу вверх – все программы сторонних производителей, обменивающихся данными в формате EnterpriseData с продуктами «1С», при выходе новых версий формата корректно продолжат работу.

Формат предназначен для обмена информацией между любыми информационными системами: он не зависит от особенностей собственного программного обеспечения или структур информационных баз, которые участвуют в обмене и не содержит в себе явных ограничений использования.

Обмен данными с программами «1С»

Предварительная настройка на стороне «1С»

Чтобы начать обмен данными в формате EnterpriseData между приложением «1С» и сторонним приложением, надо на стороне «1С» настроить синхронизацию данных. В ходе настройки указывается уникальный код приложения, с которым будет производиться обмен, а также по какому каналу будет происходить обмен данными. В настоящий момент доступны следующие опции:

веб-сервис,
файловый обмен через каталог,
файловый обмен через FTP.

Обмен через электронную почту

В случае обмена через веб-сервис стороннее приложение будет инициировать сеанс обмена данными путем вызова соответствующих веб-методов приложения «1С». В остальных случаях инициатором сеанса обмена будет приложение «1С».

Также на стороне «1С» настраивается, с какой периодичностью будет происходить синхронизация (для вариантов с файловым обменом через каталог и электронную почту):

по расписанию (с заданной периодичностью);

вручную; пользователь должен будет вручную запускать синхронизацию каждый раз, когда это ему потребуется.

Формат файлов обмена

В ходе синхронизации приложения «1С» и сторонние приложения обмениваются сообщениями – XML-файлами определенной структуры. Эти файлы состоят из двух секций – <Header> и <Body>. Секция <Header> содержит сообщение-квитанцию <Confirmation> (о ней ниже), а <Body> – информацию об измененных бизнес-сущностях в формате EnterpriseData.

Подробнее на сайте 1С

Категория: Конвертация данных, Обмен, Перенос

Отдаем PDF файл через Web-сервис

В инфраструктурах, активно использующих возможности web-сервисов 1С, нередко возникает потребность получения не только массивов данных из базы, но и различных файлов. Сам файл через веб-сервис так просто не передашь, но на его основе можно создать объект ДвоичныеДанные, который, в свою очередь, уже сериализуется в base64Binary. После такой операции наш веб-сервис без проблем передает данные и получателю остается только выполнить на своей стороне обратное преобразование и сохранить файл.

В качестве примера такого механизма я буду создавать в 1С счет на оплату на основании переданных через сервис ИНН контрагента и суммы, и возвращать PDF печатной формы. На этот раз, кроме примеров кода, дополнительно был записан скринкаст разработки.

Для начала создадим в пустой конфигурации справочник "Контрагенты" с реквизитом "ИНН" и документ "Счет" с реквизитами "Контрагент" и "СуммаДокумента".

Теперь добавим пакет XDTO "test_ws"с пространством имен "http://www.test-ws.org", в котором опишем тип объекта "File". Он будет содержать свойства:

binaryData - (base64Binary (http://www.w3.org/2001/XMLSchema));

ext - string (http://www.w3.org/2001/XMLSchema);

message - string (http://www.w3.org/2001/XMLSchema).

Создаем web-сервис "DocWork", пространство имен "http://www.test-ws.org", выбираем пакет "http://www.test-ws.org". Добавляем в сервис операцию "CreateBill", возвращаемый тип File (http://www.test-ws.org), входные параметры:

INN - string (http://www.w3.org/2001/XMLSchema);

Summ - decimal (http://www.w3.org/2001/XMLSchema).

Код web-сервиса:

Код 1C v 8.3

 Функция CreateBill(INN, Summ)

 

 typeFile = ФабрикаXDTO.Тип("<a href="http://www.test-ws.org" ,"="">http://www.test-ws.org",</a> "File");

 

 текФайл = ФабрикаXDTO.Создать(typeFile);

 текФайл.binaryData = ФабрикаXDTO.Создать(ФабрикаXDTO.Тип("<a href="http://www.w3.org/2001/XMLSchema" ,"="">http://www.w3.org/2001/XMLSchema",</a> "base64Binary"));

 текФайл.ext = ФабрикаXDTO.Создать(ФабрикаXDTO.Тип("<a href="http://www.w3.org/2001/XMLSchema" ,"="">http://www.w3.org/2001/XMLSchema",</a> "string"));

 

 Если ПустаяСтрока(INN) ИЛИ Summ = 0 Тогда

  текФайл.message = "empty data";

  Возврат текФайл;

 КонецЕсли;

 

 Запрос = Новый Запрос;

 Запрос.Текст = 

  "ВЫБРАТЬ ПЕРВЫЕ 1

  | Контрагенты.Ссылка

  |ИЗ

  | Справочник.Контрагенты КАК Контрагенты

  |ГДЕ

  | Контрагенты.ИНН = &ИНН";





 Запрос.УстановитьПараметр("ИНН", INN);





 Результат = Запрос.Выполнить().Выгрузить();

 Если Результат.Количество() = 0 Тогда

  текФайл.message = "client not found";

  Возврат текФайл;

 КонецЕсли;

 

 СчетДок = Документы.Счет.СоздатьДокумент();

 СчетДок.Дата = ТекущаяДата();

 СчетДок.Контрагент = Результат[0].Ссылка;

 СчетДок.СуммаДокумента = Summ;

 СчетДок.Записать();

 

 ТабДок = Новый ТабличныйДокумент;

 Документы.Счет.Печать(ТабДок, СчетДок.Ссылка);

 

 ИмяФайла = ПолучитьИмяВременногоФайла("pdf");

 ТабДок.Записать(ИмяФайла, ТипФайлаТабличногоДокумента.PDF);

 ДанныеФайла = Новый ДвоичныеДанные(ИмяФайла);

 

 текФайл.binaryData = ДанныеФайла;

 текФайл.message = "ok";

 текФайл.ext = "pdf";

 

 Возврат текФайл;

КонецФункции<br>

Тестовая обработка

Код 1C v 8.3

 &НаСервере

Функция ПолучитьПДФ()





 ОпределениеВС = Новый WSОпределения("<a href="http://localhost/testWS/ws/ws1.1cws?wsdl" )"="">http://localhost/testWS/ws/ws1.1cws?wsdl")</a>;

 СсылкаВС = Новый WSПрокси(ОпределениеВС, "<a href="http://www.test-ws.org" ,"="">http://www.test-ws.org",</a> "DocWork", "DocWorkSoap");

 

 ФайлСервис = СсылкаВС.CreateBill(ИНН, Сумма);

 

 Возврат ФайлСервис.binaryData;





КонецФункции// ПолучитьПДФ()









&НаКлиенте

Процедура СоздатьСчет(Команда)

 

 мДанные = ПолучитьПДФ();

 Если мДанные = Неопределено Тогда

  Возврат;

 КонецЕсли;

 мДанные.Записать("c:\temp_bil.pdf");

 

КонецПроцедуры<br>

А так же обещанное видео, как есть, без купюр

Источник

Категория: WEB-сервисы, WS-ссылки, XDTO-пакеты

Запись во внешний источник данных из 1С 8.3 (без com подключения)

В 8.3.4 в свойствах объекта "Внешний источник данных" появилась вкладка "Функции". Для внешних таблиц MSSQL данный функционал позволяет подключить к 1С хранимые процедуры и функции на стороне SQL. В том числе и процедуры, содержащие запросы SQL на добавление и обновление данных внешней таблицы.

По сравнению с прошлым примером количество кода 1С уменьшится, поскольку подключение через COM-объект и формирование запросов SQL на стороне 1С нам больше не потребуется.

Для начала создадим тестовую таблицу с помощью скрипта в панели управления сервером SQL:

Код SQL

 USE [test]

GO



SET ANSI_NULLS ON

GO



SET QUOTED_IDENTIFIER ON

GO



CREATE TABLE [dbo].[tovar](

 [id] [int] IDENTITY(1,1) NOT NULL,

 [name] [nvarchar](max) NOT NULL,

 [price] [numeric](18, 2) NULL,

 CONSTRAINT [PK_tovar] PRIMARY KEY CLUSTERED

(

 [id] ASC

)WITH (PAD_INDEX  = OFF, STATISTICS_NORECOMPUTE  = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS  = ON, ALLOW_PAGE_LOCKS  = ON) ON [PRIMARY]

) ON [PRIMARY]



GO

Скрипт создания процедуры insert_tovar:

Код SQL

 SET ANSI_NULLS ON

GO

SET QUOTED_IDENTIFIER ON

GO



CREATE PROCEDURE insert_tovar



 @name nvarchar(max),

 @price numeric(18, 2)



AS

BEGIN



 SET NOCOUNT ON;



 INSERT INTO test.dbo.tovar

    ([name] ,[price])

    VALUES (@name, @price)



END

GO

Скрипт создания процедуры update_tovar:

Код SQL

 SET ANSI_NULLS ON

GO

SET QUOTED_IDENTIFIER ON

GO



CREATE PROCEDURE update_tovar



 @id int,

 @name nvarchar(max),

 @price numeric(18, 2)



AS

BEGIN



 SET NOCOUNT ON;



 UPDATE test.dbo.tovar

    SET [name] = @name

    ,[price] = @price

 WHERE id = @id 

 

END

GO

Теперь переходим в 1С и добавляем внешний источник данных. Подключаем таблицу SQL:

Подключаем процедуры:

Далее, для таблицы dbo_tovar создаем формы списка и объекта. На форму списка вешаем команду "ДобавитьТовар" и обработку оповещения:

Код 1C v 8.3

 &НаКлиенте

Процедура ДобавитьТовар(Команда)

 

 ОткрытьФорму("ВнешнийИсточникДанных.test.Таблица.dbo_tovar.ФормаОбъекта", , ЭтаФорма);

 

КонецПроцедуры





&НаКлиенте

Процедура ОбработкаОповещения(ИмяСобытия, Параметр, Источник)

 

 Если ИмяСобытия = "ОбновитьВнешнийИсточникДанных_dbo_tovar" Тогда

  Элементы.Список.Обновить();

 КонецЕсли; 

 

КонецПроцедуры

На форме объекта на командной панели размещаем команду "ЗаписатьТовар", для кнопки выставляем свойство "Кнопка по умолчанию":

Код 1C v 8.3

 &НаКлиенте

Процедура ЗаписатьТовар(Команда)

 

 ЗаписатьТоварНаСервере();

 Оповестить("ОбновитьВнешнийИсточникДанных_dbo_tovar");

 

КонецПроцедуры





&НаСервере

Процедура ЗаписатьТоварНаСервере()

 

 Если Объект.Ссылка.Пустая() Тогда

  ВнешниеИсточникиДанных.test.dbo_insert_tovar(Объект.name, Объект.price);

 Иначе

  ВнешниеИсточникиДанных.test.dbo_update_tovar(Объект.id, Объект.name, Объект.price);

 КонецЕсли;

 

КонецПроцедуры

Для свойства реквизита "Объект" снимаем свойство "Сохраняемые данные", для поля "id" устанавливаем свойство "Только просмотр".

Готово, запускаем, тестируем. Для тестов использовался сервер MSSQL Server 2008 R2.

Источник

Категория: Внешние источники данных

COM-подключение к базе 7.7 из 8.2 1С

Если код выполняется на стороне клиента, то необходимо наличие базы 7.7 на локальной машине.

Пример (На форме объекта присутствует реквизит Таблица(ТаблицаЗначений)):

Код 1C v 8.2 УП

 &НаКлиенте

   Процедура Загрузки()

    ПутьКБазе="D:\ВашаБаза\1с77\";

    Пользователь="stvbliz";//пользователь базы 7.7

    Пароль="вашпароль";

    МонопольныйРежимOLE = ""; // " /m";

    ЗапускБезЗаставки = 1;

    База = Новый COMОбъект("V1CEnterprise.Application");

    СтрокаПодключения = "/D"""+СокрЛП(ПутьКБазе)+""" /N"""+СокрЛП(Пользователь)+""" /P"""+СокрЛП(Пароль)+"""";

    РезультатПодключения=База.Initialize(База.RMTrade,СтрокаПодключения,?(ЗапускБезЗаставки = 1,"NO_SPLASH_SHOW",""));



    Если НЕ РезультатПодключения Тогда

        Сообщить("Не удалось произвести подключение к информационной базе");

    КонецЕсли;

    Таблица.Очистить();

    Док = База.CreateObject("Документ.ЗаявкаПокупателя");

    Док.ВыбратьДокументы(НачалоНедели(Дата),КонецНедели(Дата));                  

    Пока Док.ПолучитьДокумент() = 1 Цикл

        ОбработкаПрерыванияПользователя();

        Если Док.НомерДок = НомерЗаявки Тогда

            Док.ВыбратьСтроки();

            Пока Док.ПолучитьСтроку()=1 Цикл

                нов=Таблица.Добавить();

                нов.Номенклатура = Док.Номенклатура.Наименование;

                нов.Количество = Док.Количество;

                нов.Единица = Док.Единица.Наименование;

                нов.Цена = Док.Цена;

                Нов.Сумма = Док.Сумма;

                нов.Коэффициент = Док.Коэффициент;

                нов.Производитель = Док.производитель;

                Нов.Валюта = Док.Валюта.Наименование;



            КонецЦикла;

        КонецЕсли;



    КонецЦикла;  



    Док=NULL;

КонецПроцедуры

Код 1C v 8.2 УП

 //Примеры получения значений



//Периодический реквизит нужно получать на дату

ДатаОст= ТекущаяДата();

Спр77Оле.ВидГрейда.Получить(ДатаОст).код;



// Перечисление

Если База77ОЛЕ.ВидКонтрагента.Идентификатор() = "ЧастноеЛицо"

// или

Если Сотрудник.ХарактерРаботы.Получить(Необходимая_Дата).Идентификатор() = БазаОЛЕ.EvalExpr("Перечисление.ХарактерРаботы.ТрудовыеОтношения.Идентификатор()") Тогда 

// Принадлежит ...

КонецЕсли;



//В запросе

   // в v7 ссылка OLE

   Запрос = v7.CreateObject("Запрос");

   ТипТовара = v7.evalexpr("Перечисление.ТипыТоваров.Собственный.ПорядковыйНомер()");

   

   ТекстЗапроса = 

   "//{{ЗАПРОС(Сформировать) 

   |ТекущийЭлемент = Справочник.Номенклатура.ТекущийЭлемент;

   |Наименование = Справочник.Номенклатура.Наименование;

   |ТипТовара = Справочник.Номенклатура.ТипТовара;

   |ЕдиницаИзмерения = Справочник.Номенклатура.ЕдиницаИзмерения;

   |Функция Счётчик = Счётчик();

   |Группировка ТекущийЭлемент;

   |Условие(ТипТовара.ПорядковыйНомер() = "+ТипТовара+");

   |"//}}ЗАПРОС 

   ;

Категория: COM-объекты, WMI, WSH

Передача файлов и данных на веб-сервер из 1С методами GET и POST

При интеграции 1С с веб-сайтами всегда встает вопрос о передачи некоторых данных на веб-сервер. Будь то это передача параметров запроса для получения данных от веб-сервера в 1С или же передача данных из 1С, которые должны быть сохранены или каким-то образом обработаны на веб-сервере. Передаваться могут как простые данные в виде строк, чисел, так и целые файлы (изображения, XML-файлы и прочее). Для передачи и получения файлов и данных на веб-сервер в 1С используется объект HTTPСоединение.

Создание и инициализация HTTP соединения в 1С
Для инициализации HTTP соединения в 1С необходимо создать объект HTTPСоединение и в конструкторе указать параметры HTTP соединения.

Код 1C v 8.х

 Новый HTTPСоединение(<Сервер>, <Порт>, <ИмяПользователя>, <Пароль>, <Прокси>, <ЗащищенноеСоединение>)

<Сервер> (обязательный) - адрес сервера, с которым необходимо установить соединение.
<Порт> (необязательный) - порт сервера, с которым устанавливается соединение.
Значение по умолчанию зависит от защищенности соединения (80 для незащищенного и 443 для SSL-соединения).
<ИмяПользователя> (необязательный) - имя пользователя на указанном сервере.
<Пароль> (необязательный) - пароль пользователя на указанном сервере.
<Прокси> (необязательный). Тип - ИнтернетПрокси. Прокси, используемый для соединения с сервером.
<ЗащищенноеСоединение> (необязательный). Тип - Булево. Определяет используемый протокол -
http или https. По умолчанию Ложь.
Ниже приведен примеры создания HTTPСоединения с сайтом http://www.mysite.ru/.

Код 1C v 8.х

 // соединение с параметрами по умолчанию

Соединение = Новый HTTPСоединение("www.mysite.ru");

 

// сервер использует порт 8080

Соединение = Новый HTTPСоединение("www.mysite.ru", 8080);

 

// сервер использует защищенное соединение (https),

// для подключения к серверу используется прокси

ПроксиСервер = Новый интернетПрокси;

ПроксиСервер.Пользователь = имяПользователя;

ПроксиСервер.Пароль       = парольПользователя;

 

Соединение = Новый HTTPСоединение("www.mysite.ru",,,, ПроксиСервер, Истина);

Передача данных на веб-сервер из 1С методом GET.
Для передачи данных на веб-сервер из 1С методом GET используется процедура Получить() объекта HTTPСоединение.

Код 1C v 8.х

 Получить(<Источник>, <ИмяВыходногоФайла>, <Заголовки>)

<Источник> (обязательный). Тип - Строка. Адрес ресурса на сервере.
<ИмяВыходногоФайла> (обязательный). Тип - Строка. Имя файла на диске, в который
помещаются данные, полученные от сервера (ответ сервера).
<Заголовки> (необязательный). Тип - Строка. Заголовки, добавляемые к запросу на сервер.
Текстовые пары вида <Заголовок>:<Значение>, разделенные комбинацией ВК + ПС.
(подробнее о заголовках будет сказано ниже).
Рассмотрим параметры процедуры Получить() более подробно:

В качестве источника указывается строка с адресом запроса, идущая после названия домена и символа "/". Так, если необходимо отправить данные на адрес https://www.mysite.com/getusers.php, то при создании HTTP соединения в конструкторе HTTPСоединение в поле "Сервер" указывается "www.mysite.com", признак защищенного соединения устанавливается в Истина, а в процедуре Получить() в параметре Источник указывается "getUsers.php".

В поле ИмяВыходногоФайла указывает имя файла на диске, в который будут сохранены данные, полученные от сервере в результате запроса. Так, например, если сервер возвращает список пользователей в формате XML, то на диск в указанный файл будет сохранен XML файл со списком пользователей.

О заголовках более подробно будет сказано ниже.

Так же, при запросе к веб-серверу зачастую передаются дополнительные данные (параметры) для этого запроса. Параметры от адреса источника отделяются символом "?". Каждый параметр задается в формате <Имя_Параметры>=<Значение_Параметры>. Параметры от адреса источника отделяются символом "?". Сами же параметры отделяются друг от друга символом "&". В результате строка адреса источника может выглядеть следующим образом: getUsers.php?owner_id=263544&count=100.

Ниже приведен пример, поясняющий все выше сказанное.

Код 1C v 8.х

 // необходимо выполнить запрос по адресу

// https://www.mysite.com/getUsers.php?owner_id=263544&amp;count=100

// ответ от сервера приходит в виде XML файла

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml");

 

Соединение = Новый HTTPСоединение("www.mysite.com",,,,, Истина);

Соединение.Получить("getUsers.php?owner_id=263544&amp;count=100", имяВыходногоФайла);

 

ЧтениеXML = Новый ЧтениеXML;

ЧтениеXML.ОткрытьФайл(имяВыходногоФайла);

 

Пока ЧтениеXML.Прочитать() Цикл

    // чтение ответа в виде XML файла

    ...

КонецЦикла;

 

ЧтениеXML.Закрыть();

 

// удаляем файл после использования

УдалитьФайлы(имяВыходногоФайла);

Заголовки HTTP
Ниже приведена общая информация о HTTP заголовках из википедии.
Заголовки HTTP (англ. HTTP Headers) — это строки в HTTP-сообщении, содержащие разделённую двоеточием пару имя-значение. Формат заголовков соответствует общему формату заголовков текстовых сетевых сообщений ARPA. Заголовки должны отделяться от тела сообщения хотя бы одной пустой строкой.

Все заголовки разделяются на четыре основных группы:

General Headers (рус. Основные заголовки) — должны включаться в любое сообщение клиента и сервера.
Request Headers (рус. Заголовки запроса) — используются только в запросах клиента.
Response Headers (рус. Заголовки ответа) — только для ответов от сервера.
Entity Headers (рус. Заголовки сущности) — сопровождают каждую сущность сообщения.
Именно в таком порядке рекомендуется посылать заголовки получателю.

Более подробно о заголовках HTTP можно прочитать здесь. Так же можно ознакомится со списком заголовков HTTP.

От себя лишь добавлю, что, если это явно не указано в требованиях к отправке данных веб-серверу заголовки HTTP для метода GET можно не указывать. Для метода POST обычно нужно указать заголовки Content-Type (тип передаваемых данных, например: "Content-Type: text/html;charset=utf-8") и Content-Length (размер передаваемых данных в байтах, например: "Content-Length: 1348").

Напомню, что HTTP заголовки в 1С указываются строкой в виде текстовых пар "<Заголовок>:<Значение>", разделенных комбинацией символов ВК+ПС.
Также заголовки можно задать типом Соответствие, где в качестве ключа указывается заголовок, а в качестве значения - значение заголовка.
Ниже приведены поясняющие примеры:

Код 1C v 8.х

 источник = "owner=263544&amp;count=100";

 

// Передача заголовков строкой

ЗаголовкиHTTP = "Content-Type:text/html;charset=utf-8" + Символ.ВК + Символ.ПС +

            "Content-Length: "+СтрДлина(источник);

Соединение.Получить("", имяВыходногоФайла, ЗаголовкиHTTP);

 

// Вставить символы ВК+ПС можно и таким способом

ЗаголовкиHTTP = "Content-Type:text/html;charset=utf-8

            |Content-Length: 1348";

Соединение.Получить("", имяВыходногоФайла, ЗаголовкиHTTP);

 

// Установка заголовков типом Соответствие

ЗаголовкиHTTP = Новый Соответствие;

ЗаголовкиHTTP.Вставить("Content-Type", "text/html;charset=utf-8");

ЗаголовкиHTTP.Вставить("Content-Length", СтрДлина(источник));

 

Соединение.Получить(источник, имяВыходногоФайла, ЗаголовкиHTTP);

Передача данных на веб-сервер из 1С методом POST.
Общие сведения.
Для передачи данных на веб-сервер из 1С методом POST используется процедура ОтправитьДляОбработки() объекта HTTPСоединение.

Код 1C v 8.х

 ОтправитьДляОбработки(<Источник>, <АдресРесурса>, <ИмяВыходногоФайла>, <Заголовки>)

<Источник> (обязательный) - Имя файла-источника, который будет отправлен
на сервер для обработки.
<АдресРесурса> (обязательный). Тип - строка. Адрес ресурса на сервере,
в который посылаются данные из источника.
<ИмяВыходногФайла> (обязательный) - Имя файла на диске, в который записываются
полученные с сервера данные.
<Заголовки> (необязательный). Тип - строка. Заголовки, добавляемые к запросу на сервер.
Текстовые пары вида <Заголовок>:<Значение>, разделенные комбинацией ВК + ПС.
(подробнее о заголовках будет сказано ниже).
Рассмотрим параметры процедуры ОтправитьДляОбработки() подробнее:

В качестве источника указывается файл, содержимое которого необходимо отправить на сервер для обработки. Подробнее о формировании содержимого файла-источника будет сказано ниже.

Поле АдресРесурса аналогично полю Источник процедуры Получить(), т.е. указывается строка с адресом запроса, идущая после имени домена и символа "/".

Поле ИмяВыходногоФайла также аналогично одноименному полю процедуры Получить(), т.е. содержит имя файла, в котором будут сохранены данные, полученные от сервера в результате обработки исходных данных.

О заголовках было упомянуто выше. Напомню лишь, что для метода POST обычно указываются заголовки Content-Type и Content-Length. В качестве параметра заголовка Content-Length указывается размер файла-источника, преобразованный с помощью функции XMLСтрока().

Ниже приведен пример, поясняющий все выше сказанное.

Код 1C v 8.х

 имяФайлаОтправки = "d:\data\request.txt"; // файл с отсылаемыми для обработки данными

 

// Определим размер файла-источника

// и установим HTTP заголовки

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "text/html;charset=utf-8");

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml");

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "addPost.php", имяВыходногоФайла, Заголовки);

Передача параметров методом POST.
Для передачи параметров, аналогично методу GET, можно сформировать строку параметров, записать их в текстовый файл и отправить этот файл на сервер для обработки. Ниже приведен пример аналогичный примеру отправки методом GET, но теперь те же данные отправляются методом POST.

Код 1C v 8.х

 // сформируем файл для отправки на сервер

 

имяФайлаОтправки = ПолучитьимяВременногоФайла("txt");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаОтправки);

ЗаписьТекста.Записать("owner=263544&amp;count=100");

ЗаписьТекста.Закрыть();

 

// отправим файл на сервер для обработки

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml"); // наш сервер возвращает ответы в виде XML

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "text/html;charset=utf-8");

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "addPost.php", имяВыходногоФайла, Заголовки);

 

// удалим файл отправки - он больше не нужен

Попытка

    УдалитьФайлы(имяФайлаОтправки);

Исключение

КонецПопытки;

 

// обработаем ответ сервера

 

ЧтениеXML = Новый ЧтениеXML;

ЧтениеXML.ОткрытьФайл(имяВыходногоФайла);

 

Пока ЧтениеXML.Прочитать() Цикл

    // чтение ответа в виде XML файла

    ...

КонецЦикла;

 

ЧтениеXML.Закрыть();

 

// удаляем файл после использования

Попытка

    УдалитьФайлы(имяВыходногоФайла); 

Исключение

КонецПопытки;

Передача файлов методом POST.
Зачастую данные для обработки задаются не виде строки параметров разделенных "&", как в рассматриваемых выше примерах, а виде файла определенного формата, например XML или JSON. Рассмотрим пример отправки данных на веб-сервер для обработки методом POST, которые задаются в формате XML. Например, сервер может добавить ваш комментарий к материалу. В описании процедуры добавлении сказано, что данные необходимо отправлять по адресу www.mysite.com/addComment.php. Сами данные должны быть переданы в следующем виде:

Код

<?xml version="1.0" encoding="UTF-8"?>
<request>
<user_id>ID_Пользователя</user_id>
<post_id>ID_Материала</post_id>
<message>Текст_Комментария</message>
</request>

где:
<ID_Пользователя> - id пользователя на сайте, от имени которого добавляется комментарий;
<ID_Материала> - id материала на сайте, к которому добавляется комментарий;
<Текст_Комментария> - текст комментария.

Предположим, что нам уже известны id пользователя и материала и они хранятся в переменных user_id и post_id. Ниже приведен пример, решающий нашу задачу.

Код 1C v 8.х

 // подготовим файл с данными для отправки

имяФайлаОтправки = ПолучитьимяВременногоФайла("xml");

 

ОбъектXML = Новый ЗаписьXML;

ОбъектXML.ОткрытьФайл(имяФайлаОтправки, "UTF-8");

ОбъектXML.ЗаписатьОбъявлениеXML();

ОбъектXML.ЗаписатьБезОбработки(

"<request>

|    <user_id>" + user_id + "</user_id>

|    <post_id>" + post_id + "</post_id>

|    <message>" + ТекстКомментария + "</message>

|</request>");

ОбъектXML.Закрыть();

 

// отправим файл на сервер для обработки

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml"); // наш сервер возвращает ответы в виде XML

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "text/html;charset=utf-8");

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "addComment.php", имяВыходногоФайла, Заголовки);

 

// удалим файл отправки - он больше не нужен

Попытка

    УдалитьФайлы(имяФайлаОтправки);

Исключение

КонецПопытки;

 

// обработаем ответ сервера

 

ЧтениеXML = Новый ЧтениеXML;

ЧтениеXML.ОткрытьФайл(имяВыходногоФайла);

 

Пока ЧтениеXML.Прочитать() Цикл

    // чтение ответа в виде XML файла

    ...

КонецЦикла;

 

ЧтениеXML.Закрыть();

 

// удаляем файл после использования

Попытка

    УдалитьФайлы(имяВыходногоФайла); 

Исключение

КонецПопытки;

Загрузка файлов (изображений, документов и т.п.) на веб-сервер методом POST.
Зачастую возникает необходимость загрузки файлов на веб-сервер. Это может быть, например, изображение к статье на сайте, или фотография для альбома, или архив для файлообменника. Ранее мы рассматривали передачу методом POST параметров или просто файлов. Таким же образом можно и передавать двоичные файлы. Но как быть, если файлы необходимо отправлять вместе с параметрами? Для возможности отправки файлов в этом случае используется HTTP заголовок ContentType:multipart/form-data. Следует заметить, что обычно таким способом передаются файлы через веб-браузеры. Т.е. когда на сайте вы выбираете файл и нажимаете кнопку "Загрузить", то файл передается способом описанным ниже. При таком способе сам файл также задается как переменная, т.е., например, файл передается через параметр file или image. Однако, мы не можем просто передать file=<Двоичные_Данные>. А вот как все таки передать файл мы и рассмотрим ниже.

Для возможности вместе с параметрами передавать и двоичные данные (файлы) необходимо сформировать HTTP заголовок Content-Type следующим образом:
Content-Type: multipart/form-data, boundary=<уникальные_данные>
где <уникальные_данные> - это любой набор цифр и/или символов, который будет служить для отделения значений друг от друга. Значение boundary должно быть уникальным в пределах пересылаемой информации, т.е. таких символов не должно встречаться в пересылаемых файлах и переменных.

Bounday можно сформировать, например, таким образом

Код 1C v 8.х

 boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

Все данные отделяются друг от друга разделителем boundary. Начинать разделитель нужно с "--":

Код

--<boundary>
Content-Disposition: form-data; name="<имя_переменной>"
<пустая_строка>
<значение_переменной>
Для отправки файла необходимо еще добавить тип и имя файла:

--<boundary>
Content-Disposition: form-data; name="<имя_переменной>"; filename="<имя_файла>"
Content-Type: <тип_файла> (например image/jpeg или text/plain)
<пустая_строка>
<данные_файла>

В конце данных нужно закрыть разделитель, добавили в конце разделителя "--", т.е. вид будет "--<boundary>--".

Итак, например, нам нужно передать на веб-сервер текстовый файл через параметр "text", его описание через параметр "desc" и id пользователя через параметр "uid", для которого будет загружен наш файл.

Предположим, что файл содержит следующий текст:
Мороз и солнце; день чудесный!
Еще ты дремлешь, друг прелестный -
Пора, красавица, проснись:
Открой сомкнуты негой взоры
Навстречу северной Авроры,
Звездою севера явись!
Описание должно содержать "Стих А.С. Пушкина", а id пользователя равно "0123456". Тогда файл должен быть сформирован следующим образом (для упрощения предположим, что bounday мы уже сформировали и он равен "ccf8111910")

Код

--ccf8111910
Content-Disposition: form-data; name="uid"

0123456
--ccf8111910
Content-Disposition: form-data; name="desc"

Стих А.С. Пушкина
--ccf8111910
Content-Disposition: form-data; name="text"; filename="stih.txt"
Content-Type: text/plain

Мороз и солнце; день чудесный!
Еще ты дремлешь, друг прелестный -
Пора, красавица, проснись:
Открой сомкнуты негой взоры
Навстречу северной Авроры,
Звездою севера явись!
--ccf8111910--

А теперь перейдем непосредственно к 1С. Пусть у нас будет форма с реквизитами "Пользователь", "Описание" и "ИмяФайла". Реализуем отправку данных, описанным выше способом

Код 1C v 8.х

 // подготовим файл с данными для отправки

имяФайлаОтправки = ПолучитьимяВременногоФайла("txt");

Boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаОтправки);

 

// параметр "uid"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""uid""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(Пользователь);

 

// параметр "desc"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""desc""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(Описание);

 

// параметр "text"

ФайлДляПередачи = Новый ТекстовыйДокумент;

ФайлДляПередачи.Прочитать(имяФайла);

 

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""text""; filename=""stih.txt""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: text/plain");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.Записать(ФайлДляПередачи.ПолучитьТекст());

ЗаписьТекста.ЗаписатьСтроку("");

 

// закроем разделитель

ЗаписьТекста.ЗаписатьСтроку("--"+boundary+"--");

 

ЗаписьТекста.Закрыть();

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

// передадим данные на сервер 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "multipart/form-data, boundary="+boundary);

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "postFile.php", имяВыходногоФайла, Заголовки);

Передача текстовых файлов таким способом проблем не вызывает. Сложнее дело обстоит с файлами, содержащими двоичные данные (изображения, архивы и т.п.). Все дело в том, что в 1С просто нет методов для чтение двоичных файлов в строку. Если мы делаем обмен со своим сайтом, которые сами и разрабатывали, то можно просто преобразовать файл в строку Base64 при помощи процедуры Base64Строка(), а на стороне сервера преобразовать строку Base64 обратно.

Код 1C v 8.х

 // подготовим файл с данными для отправки

имяФайлаДанных = "d:\photo\birthday.jpg";

 

имяФайлаОтправки = ПолучитьимяВременногоФайла("txt");

Boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаОтправки);

 

// параметр "file"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""file""; filename=""photo.jpg""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: image/jpeg");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.Записать(Base64Строка(Новый ДвоичныеДанные(имяФайлаДанных)));

ЗаписьТекста.ЗаписатьСтроку("");

 

// закроем разделитель

ЗаписьТекста.ЗаписатьСтроку("--"+boundary+"--");

 

ЗаписьТекста.Закрыть();

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

// передадим данные на сервер 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "multipart/form-data, boundary="+boundary);

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "uploadFile.php", имяВыходногоФайла, Заголовки);

А как же быть если мы загружаем файл на сторонний сервер, который принимает файл как есть без преобразование его в строку Base64(). В это случае можно пойти на хитрость. В 1С есть процедура ОбъединитьФайлы(), которая объединяет несколько файлов на диске в один результирующий файл

Код 1C v 8.х

 ОбъединитьФайлы(<ИменаЧастей>, <ИмяРезультирующегоФайла>)

<ИменаЧастей> (обязательный). Тип - Массив. Массив имен частей файлов, которые
требуется объединить. Объединение будет происходить в порядке, в котором заданы
имена файлов в массиве.
<ИмяРезультирующегоФайла> (обязательный). Тип - Строка. Имя файла, который будет
создан в результате объединения файлов.
Т.е. мы можем сформировать текстовый файл с запросом, объединить его с файлом(-ами), которые необходимо передать на веб-сервер и передать уже файл, получившийся в результате объединения исходных файлов. Ниже демонстрируется процесс передачи двух zip архивов на сервер с дополнительными параметрами user_id и post_id.

Код 1C v 8.х

 // подготовим файлы с данными для отправки

 

массивФайлов = Новый Массив;

 

Boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

 

имяФайлаСПараметрами = ПолучитьимяВременногоФайла("txt"); // первый файл, содержащий параметры

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаСПараметрами);

 

// параметр "user_id"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""user_id""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(user_id);

 

// параметр "post_id"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""post_id""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(post_id);

 

// начало параметра "file1"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""file1""; filename=""archive1.zip""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: application/x-zip-compressed");

ЗаписьТекста.ЗаписатьСтроку("");

 

ЗаписьТекста.Закрыть(); // заканчиваем работу с файлом 1

 

массивФайлов.Добавить(имяФайлаСПараметрами); // добавляем 1-ый файл для объединения

массивФайлов.Добавить(имяФайлаАрхива1); // добавляем 1-ый архив для объединения

 

// второй файл параметров, содержаший начало параметра "file2"

имяФайлаСПараметрами = ПолучитьимяВременногоФайла("txt");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаСПараметрами);

 

// начало параметра "file2"

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""file2""; filename=""archive2.zip""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: application/x-zip-compressed");

ЗаписьТекста.ЗаписатьСтроку("");

 

ЗаписьТекста.Закрыть(); // заканчиваем работу с файлом 2

 

массивФайлов.Добавить(имяФайлаСПараметрами); // добавляем 2-ой файл для объединения

массивФайлов.Добавить(имяФайлаАрхива2); // добавляем 2-ой архив для объединения

 

ЗаписьТекста.Записать(ФайлДляПередачи.ПолучитьТекст());

ЗаписьТекста.ЗаписатьСтроку("");

 

// третий файл, закрывающий параметры

имяФайлаСПараметрами = ПолучитьимяВременногоФайла("txt");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаСПараметрами);

 

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку("--"+boundary+"--");

 

ЗаписьТекста.Закрыть(); // заканчиваем работу с файлом 3

 

массивФайлов.Добавить(имяФайлаСПараметрами); // добавляем 3-ий файл, закрывающий параметры

 

// результирующий файл, который и будет отправлен

имяФайлаОтправки = ПолучитимяВременногоФайла("out");

 

// объединим все файлы

ОбъединитьФайлы(массивФайлов, имяФайлаОтправки);

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

// передадим данные на сервер 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "multipart/form-data, boundary="+boundary);

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "postFile.php", имяВыходногоФайла, Заголовки);

Ну вот, вроде бы, и все, что я хотел рассказать о способах передачи файлов и данных на веб-сервер из 1С. Если что-то не понятно, что-то хотите уточнить или нашли ошибки - пишите в комментариях.
Автор: Павел

Категория: Работа с Интернет, Почтой (Mail), FTP

Форма ~ Программное создание таблицы значений с условным оформлением

Как создать на форме таблицу и сделать для неё подсветку содержимого колонки в строке по условию?

Итак для начала нам надо добавить реквизиты в форму. Для этого у нас есть метод: ИзменитьРеквизиты(). Перед тем как его использовать мы сформируем массив добавляемых реквизитов, который будет называться МассивДобавляемыхРеквизитов.

Код 1C v 8.2 УП

 МассивДобавляемыхРеквизитов = Новый Массив; 

МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("План", Новый ОписаниеТипов("ТаблицаЗначений")));

Обратите внимание, что элементы массива у нас типа РеквизитФормы. Дальше помимо таблицы значений, нам надо добавить колонки таблицы, например будем добавлять три колонки:

Код 1C v 8.2 УП

 МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("Номенклатура", Новый ОписаниеТипов("СправочникСсылка.Номенклатура"),"План" ,"Номенклатура")); 

МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("Регион", Новый ОписаниеТипов("Число",Новый КвалификаторыЧисла(10,2)),"План" , "Регион")); 

МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("Разница", Новый ОписаниеТипов("Число",Новый КвалификаторыЧисла(10,2)),"План" , "Осталось распределить"));

Во время добавления колонок в МассивДобавляемыхРеквизитов обязательно надо указать путь к создаваемому реквизиту, в нашем случае это «План», который был добавлен в массив ранее. Обратите внимание, что путь к создаваемому реквизиту не включает в себя сам реквизит. После того, как массив сформирован, можно вызывать изменение реквизитов:

Код 1C v 8.2 УП

 ИзменитьРеквизиты(МассивДобавляемыхРеквизитов);

После изменения реквизитов у нас уже есть нужный нам реквизит формы «План» типа ТаблицаЗначений с тремя колонками. Если вам надо будет обратиться к значению реквизита, то вы можете это сделать используя ЭтаФорма["План"]. Можно приступать к созданию элементов формы, для отображения данных. Сначала создадим элемент формы типа ТаблицаФормы.

Код 1C v 8.2 УП

 ТаблицаФормы = Элементы.Добавить("План", Тип("ТаблицаФормы"));

ТаблицаФормы.ПутьКДанным = "План"; 

ТаблицаФормы.ПоложениеКоманднойПанели = ПоложениеКоманднойПанелиЭлементаФормы.Нет; 

ТаблицаФормы.ФиксацияСлева = 3; 

ТаблицаФормы.УстановитьДействие("ПередУдалением", "ПланПередУдалением"); 

ТаблицаФормы.УстановитьДействие("ПередНачаломДобавления", "ПланПередНачаломДобавления");

Как вы видите из приведенного когда, во время создания элемента мы тут же определяем действия на события. После создания элемента План типа ТаблицаФормы создадим подчиненные ему элементы типа ПолеФормы, которые будут отвечать у нас за вывод данных в колонки таблицы. Для этого в цикле перебора колонок таблицы необходимо выполнить следующий код (на примере одной из итераций цикла):

Код 1C v 8.2 УП

 НоваяКолонка = Элементы.Добавить("ПланНоменклатура", Тип("ПолеФормы"), Элементы.План); 

НоваяКолонка.Заголовок = "Номенклатура"; 

НоваяКолонка.ПутьКДанным = "План.Номенклатура";

НоваяКолонка.Вид = ВидПоляФормы.ПолеВвода; 

НоваяКолонка.РежимРедактирования = РежимРедактированияКолонки.ВходПриВводе;

Обратите внимание, что во время добавления элемента мы указываем родителя Элементы.План. Так же путь к данным у нас состоит из наименования реквизита типа ТаблицаЗначений и имени колонки, разделенные точкой. После того, как вы в цикле создадите все элементы для колонок форма будет готова к выводу и вводу данных в таблицу.

Теперь можно перейти ко второй части задачи про подсветку цветом колонки Номенклатура. Например условие у нас будет накладываться на колонку Разница и когда она будет равно 100 строку надо будет подсвечивать колонку Номенклатуры серым цветом.

Для реализации этой части задачи мы будем использовать объект УсловноеОформление, который доступен на стороне сервера. Сначала в элементы условного оформления необходимо добавить новый элемент. Затем мы добавляем оформляемые поля. Если надо подсвечивать всю строку, то можно обойти в цикле колонки и добавить все их поля ввода в оформляемые. Так же необходимо потом добавить отбор. В левом значении отбора указываем поле, по которому будет идти сравнение. Поле указывает с точкой, как путь к данным во время добавления колонки.

Код 1C v 8.2 УП

 ЭлементУсловногоОформления = УсловноеОформление.Элементы.Добавить();

ОформляемоеПоле = ЭлементУсловногоОформления.Поля.Элементы.Добавить();

ОформляемоеПоле.Поле = Новый ПолеКомпоновкиДанных("ПланНоменклатура");

ЭлементОтбора = ЭлементУсловногоОформления.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));

ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("План.Разница");

ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;

ЭлементОтбора.ПравоеЗначение = 100; 

ЭлементУсловногоОформления.Оформление.УстановитьЗначениеПараметра("ЦветФона", WebЦвета.СеребристоСерый);

Внешняя обработка, демонстрирующая создание таблицы значений программно - Скачивать файлы может только зарегистрированный пользователь!

Андрей Данилюк

Категория: Работа с Формой (Диалог) и её элементами

Импорт документа Excel через web-клиент

Во время реализации задачи по регистрации продаж дистрибьюторов на основании Excel документов столкнулся с интересной задачей. Необходимо реализовать загрузку файла и на стороне сервера обработать его, заполнив табличную часть документа.

Решение состоит из двух функций: клиентской и серверной.

Клиентская часть инициирует выбор файла, передачу выбранного файла на сервер и передача управления серверной процедуре.

Код 1C v 8.2 УП

 #НаКлиенте

Процедура ИмпортИзВнешнегоФайла(Команда)

     //Выбор и загрузка файла.

     Если НЕ  ПодключитьРасширениеРаботыСФайлами() Тогда

          УстановитьРасширениеРаботыСФайлами();

     КонецЕсли;

 

     Если  ПодключитьРасширениеРаботыСФайлами() Тогда

          Режим =  РежимДиалогаВыбораФайла.Открытие;

          ДиалогОткрытияФайла = Новый  ДиалогВыбораФайла(Режим);

          ДиалогОткрытияФайла.ПолноеИмяФайла = "";

          ДиалогОткрытияФайла.МножественныйВыбор = Ложь;

          Фильтр = "Текст(*.xls)|*.xls";

          ДиалогОткрытияФайла.Фильтр = Фильтр;

          ДиалогОткрытияФайла.Заголовок = "Выберите файл для импорта";

          Если  ДиалогОткрытияФайла.Выбрать() Тогда

               Объект.МедицинскиеРаботники.Очистить();

               ДанныеНачинаютсяС = 1;

              Если  Не ВвестиЧисло(ДанныеНачинаютсяС, "Данные начинаются со строки", 2,  0) Тогда

                    Возврат;

              КонецЕсли;

              МассивФайлов = ДиалогОткрытияФайла.ВыбранныеФайлы;

              ПомещаемыеФайлы = Новый Массив;

              Для  Каждого Файл Из МассивФайлов Цикл

                   ТекФайл = Новый Файл(Файл);

                   Описание = Новый ОписаниеПередаваемогоФайла(Файл, "");

                   ПомещаемыеФайлы.Добавить(Описание);

              КонецЦикла;

 

              ПомещенныеФайлы = Новый Массив;

 

              Если  ПоместитьФайлы(ПомещаемыеФайлы, ПомещенныеФайлы, , Ложь, УникальныйИдентификатор) Тогда

                   //Запуск импорта

                   ИмпортироватьФайлИзВременногоХранилищаВТЗ(ПомещенныеФайлы, ДанныеНачинаютсяС);

              КонецЕсли;

         Иначе

              Предупреждение("Файл(ы) не  выбран!");

         КонецЕсли;

     Иначе

          Предупреждение(НСтр("ru ='Данная возможность недоступна, так как не подключено расширение работы с файлами.'", "ru"));

     КонецЕсли;

КонецПроцедуры //ИмпортИзВнешнегоФайла()

Серверная процедура перебирает полученные на сервер файлы. Получает COM-объекты и импортирует данные.

Код 1C v 8.2 УП

 #НаСервере

Процедура ИмпортироватьФайлИзВременногоХранилищаВТЗ(МассивФайлов,  ДанныеНачинаютсяС)

    ДокументОбъект =  РеквизитФормыВЗначение("Объект");

 

    //Обход файлов, записанных  во временное хранилище

    Для Каждого  ЭлементМассива Из МассивФайлов Цикл

        ФайлИзХранилища =  ПолучитьИзВременногоХранилища(ЭлементМассива.Хранение);

        ВременныйФайл = ПолучитьИмяВременногоФайла("xls");

       //Сохранение во временнный файл на диске

       ФайлИзХранилища.Записать(ВременныйФайл);

 

       //Импорт

       Док =  ПолучитьCOMОбъект(ВременныйФайл);

       ФИОУчастника = Док.Sheets(1).Cells(ДанныеНачинаютсяС, 2).Value;

       Пока СокрЛП(ФИОУчастника) ="" Цикл

           //  Добавление строки с файла в документ

          НоваяСтрока = ДокументОбъект.МедицинскиеРаботники.Добавить();

          НоваяСтрока.Фио = ФИОУчастника;

          НоваяСтрока.Учреждение = Док.Sheets(1).Cells(ДанныеНачинаютсяС, 7).Value;

          НоваяСтрока.Адрес = Док.Sheets(1).Cells(ДанныеНачинаютсяС, 3).Value;

          НоваяСтрока.Телефон = Док.Sheets(1).Cells(ДанныеНачинаютсяС, 4).Value;

          НоваяСтрока.ЭлПочта = Док.Sheets(1).Cells(ДанныеНачинаютсяС, 5).Value;

          НоваяСтрока.Образование = Док.Sheets(1).Cells(ДанныеНачинаютсяС, 6).Value;

          ДанныеНачинаютсяС = ДанныеНачинаютсяС + 1;

          ФИОУчастника = Док.Sheets(1).Cells(ДанныеНачинаютсяС, 2).Value;

      КонецЦикла;

      Сообщить("Импорт завершён");

      Док.Application.Quit();

    КонецЦикла;

    ЗначениеВРеквизитФормы(ДокументОбъект, "Объект");

КонецПроцедуры  //ИмпортироватьФайлИзВременногоХранилищаВТЗ()

Источник

Категория: Работа с Microsoft Office и OpenOffice

Кнопка ~ Программное добавление на управляемую форму поля или кнопки?

Код 1C v 8.2 УП

 &НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

   

    // Добавляем новый реквизит в форму

    ДобавляемыеРеквизиты = Новый Массив;

    Реквизит = Новый РеквизитФормы("Реквизит1", Новый ОписаниеТипов("Строка"), , "Введите строку", Истина);

    ДобавляемыеРеквизиты.Добавить(Реквизит);

    ИзменитьРеквизиты(ДобавляемыеРеквизиты);

   

    //Добавляем новое поле ввода на форму

    Элемент = ЭтаФорма.Элементы.Добавить("Поле", Тип("ПолеФормы"), ЭтаФорма);

    Элемент.Вид = ВидПоляФормы.ПолеВвода;

    Элемент.ПутьКДанным = "Реквизит1";

   

    //Добавляем новую команду

    Кмд = ЭтаФорма.Команды.Добавить("Команда1");

    Кмд.Действие = "НажатиеКнопки";

    Кмд.Заголовок = "Нажатие кнопки";

   

    //Добавляем новую кнопку

    Элемент2 = ЭтаФорма.Элементы.Добавить("Кнопка1", Тип("КнопкаФормы"), ЭтаФорма);

    Элемент2.Вид = ВидКнопкиФормы.ОбычнаяКнопка;

    Элемент2.ИмяКоманды = "Команда1";

   

КонецПроцедуры



&НаКлиенте

Процедура НажатиеКнопки()

    // Вставить содержимое обработчика.

    ЭтаФорма.Реквизит1 = "Готово";

   

КонецПроцедуры

Программное добавление кнопок в управляемый интерфейс
Если упрощенно, то помог код следующего содержания:

Код 1C v 8.2 УП

 &НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

    Для Каждого ТекИмяКнопки Из Параметры.МассивИменКнопок Цикл

        КомандаФормы  = Команды.Добавить(ТекИмяКнопки);

        КомандаФормы.Действие = "ПроцедураОбработкиНажатия";

        Элементы.Добавить(ТекИмяКнопки,Тип("КнопкаФормы"), Элементы.ПоПравилуОбработкиПодменю);

        Элементы[ТекИмяКнопки].Заголовок = ТекИмяКнопки;

        Элементы[ТекИмяКнопки].ИмяКоманды = ТекИмяКнопки;

    КонецЦикла

КонецПроцедуры

Параметры.МассиИменКнопок – Массив, в котором содержаться имена создаваемых кнопок.
Элементы.ПоПравилуОбработкиПодменю – группа подменю, в которую добавляются кнопки.
«ПроцедураОбработкиНажатия» – имя процедуры, которая объявлена на стороне клиента. Именно ей будет передаваться управление в случае нажатия кнопки. Идентификацию того, какая именно кнопка была нажата проводил по имени команды.

Код 1C v 8.2 УП

 &НаКлиенте

Процедура ПроцедураОбработкиНажатия(Элемент)

    Состояние("Выполняется нажатие кнопки с командой" + Элемент.Имя);

КонецПроцедуры

Следует отметить, что обязательно создание команд. Если кнопке не определить имя команды, то платформа такую кнопку не покажет.

Категория: Работа с Формой (Диалог) и её элементами

Как связать 1C, PHP , MySQL?

В современном мире люди используют Интернет не только для поиска информации, но и для приобретения каких либо товаров и услуг. Поэтому организации, например имеющие статус среднего бизнеса, стараются разместить свои прайс-листы в интернете или даже создать Интернет-магазин. Создать его не так-то просто. Если вы имеете «реальный» бизнес и используете определенную систему учета товаров (или услуг), нужно учитывать несколько немаловажных факторов:
* Каждый уважающий себя Интернет-магазин должен показывать остаток товара на складе, а также не показывать тот товар, которого уже нет в наличии. (а может быть что товар есть на разных региональных складах)
* Цены не должны расходиться с ценами в реальном магазине. Не учитывая доставку, хотя и это уже давно стало бесплатным практически везде.

Я привел только 2 факта, в действительности их может быть гораздо больше, всё зависит от того, какую цель вы ставите перед своим Интернет-проектом.

Многие организации для ведения учета товаров или оказанных услуг используют ПО «1С» и как показывает практика, большая часть организаций работает с версией 7.7, и не торопятся перейти на 8.х. так как это влечет за собой накладные расходы.

Для Реализации работы с WEB в 1С7.7 есть прекрасное решение - WEB-расширение, но оно работает только с Microsoft Internet Information Server (IIS). IIS используют не все хостинг – провайдеры, да и те кто использует вряд ли разрешат подключить свой сервер к чужой БД.

А держать «у себя» IIS сервер достаточно накладно для организаций среднего бизнеса (оборудование + интернет канал + лицензии ОС и ПО = увеличение стоимости товара).

Другое дело «свободное» ПО и ОС: Linux, Apache, PHP, MySQL. Эти четыре продукта использует большинство хостинг – провадеров, поэтому их использование как платформы для создания Интернет-проектов наиболее оптимально.

Как связать 1С 7.7 с MySQL? Можно использовать внешнюю компоненту MySQL,dll, но её использование не всегда возможно, особенно если ваш Веб-сервер находиться удаленно или вы покупаете хостинг у сторонней организации, так как не безопасно открывать доступ к БД из Интернета.

Для решения этой задачи я использовал технологию передачи данных через URL.
Возможно, звучит это немного дико, и многие подумают, что это неправильное решение. Однако эта система работает и работает достаточно хорошо и корректно.
И сейчас я бы хотел поделиться с коллегами приобретенным опытом реализации это технологии.

Кратко о принципе:
Выглядит это так: из 1С вызывается url и через него же передаются данные PHP-скрипу, который в свою очередь делает с ними все, что необходимо.

Например, нам нужно передать остаток товара на складе: из 1С должен будет сформироваться url: http://www.server.com/script.php?good=201&count=302&date=2009-06-09, где:
* http://www.server.com – адрес сервера
* script.php – исполняющий скрипт
* good=201 – переменная и код товара
* count=302 – переменная и количество остатка
* date=2009-06-09 – дата на которую передается остаток
причем для работы данной схемы достаточно лишь иметь доступ в Интернет с того компьютера на котором выполняется операция по передачи данных. (сервер БД нет необходимости подключать к Интернету)
Встреча с возможными ошибками:

Для начала хотелось бы рассказать о тех проблемах, с которыми я столкнулся и о том, как можно их наиболее эффективно решить:
1. Проблема передачи дробных чисел, а именно трудности, возникающие при использовании символа «точка» (.)

Если необходимо передать любое дробное число, то в 1С оно будет храниться виде 1.1. При передаче числа через url точка, отделяющая целую часть от дробной, вызывает ошибку, так как символ «точка» служит для разделения доменов. Следовательно, необходимо преобразовать эту самую «точку» в другой символ наиболее подходящий для этого. И этот символ - «запятая» (,). Для того чтобы осуществить это преобразование, я написал функцию, листинг которой приведен ниже:

Код 1C v 7.x

 Функция ЧислоURL(Стр) 

	Возврат СтрЗаменить(Строка(Стр),".",",");

КонецФункции

Эта функция возвращает строку в которой все символы «.» заменены на «,» в строковой переменной Стр. Применимо это не только к числам, но и к текстовым данным.

Теперь при передаче число 1.1 будет иметь формат 1,1. Далее при получении мы должны привести это число обратно в «привычный» вид, это можно сделать на стороне PHP-скрипта функцией strtr() . краткое её описание я привел ниже:
Описание функции string strtr ( string $str , string $from , string $to ):

Эта функция возвращает строку str , в которой каждое вхождение любого символа из перечисленных в from заменено на соответствующий символ из строки to . (www.php.net)

Т.е. в нашем случае функция будет иметь вид strtr("1,1", ",", ".") и результатом её работы будет: 1.1

2. Проблема передачи даты. В 1С дата имеет вид «ДД.ММ.ГГГГ» например, 01.01.2009. При передаче такого вида данных будет вызвана такая же ошибка, как и при передаче числовых данных. Конечно, для решения и этой проблемы можно использовать указанную выше функцию ЧислоURL, но я решил пойти другим путём и конвертировал дату в формат MySQL, то есть «ГГГГ-ММ-ДД». Для этого я написал функцию МуДата, вот ее листинг:

Код 1C v 7.x

 Функция МуДата(Стр)  //дата в формате MySQL (ГГГГ-ММ-ДД)

	Возврат "" + ДатаГод(Стр) + "-" +ДатаМесяц(Стр) + "-" + ДатаЧисло(Стр);	

КонецФункции

Функция работает следующим образом – опять же выделяет из переменной Стр, Год, Месяц, Число и выстраивает их в формате ГГГГ-ММ-ДД, наиболее привычным при работе с MySQL. Об ошибках все.

Подготовка 1С:
Теперь расскажу о том, как заставить 1С работать с WEB.
Для того, чтобы иметь возможность работать с протоколом HTTP в 1С, я использовал библиотеку V7+, которая поставляется фирмой 1С и служит для расширения возможностей 1С 7.7.

Для начала необходимо подключить внешнюю компоненту (подробнее здесь), используя функцию «ЗагрузитьВнешнююКомпоненту("v7plus.dll")». Далее необходимо создать объект addin.v7httpreader, для этого я использовал переменную НТТР. А для передачи и получения данных используется метод ПолучитьКакСтроку(адрес, СтрокаДляПриёма); который получает данные в переменную СтрокаДляПриёма с адреса указанного в переменной адрес. В целом все это будет выглядеть примерно так:

Код 1C v 7.x

 Процедура Сформировать()

 	ПЕРЕМ СтрокаДляПриёма;

	ЗагрузитьВнешнююКомпоненту("v7plus.dll");

	HTTP=СоздатьОбъект("addin.v7httpreader");

	адрес="http://www.google.ru";

	HTTP. ПолучитьКакСтроку (адрес, СтрокаДляПриёма);

	сообщить (СтрокаДляПриёма);

КонецПроцедуры

Выше указанная процедура выведет в окно сообщений HTML-код заглавной страницы сайта http://www.google.ru
Таким образом, теперь мы знаем, как, из 1С, обратиться к нужному сайту, и получить его HTML-код.

Немного о PHP:
Теперь напишем PHP-скрипт, который просто будет выводить данные полученные методом GET. (ознакомиться с тем, как PHP получает данные можно здесь) Листинг такого скрипта:

Код

<?php
$text=$_GET['text']; // получаем значение переменной text
print $text;
?>

Назовем его test.php и поместим в корневую папку web-сервера. Далее для проверки работы скрипта введем в адресную строку браузера http://localhost/test.php?text=hello%20wolrd В том случае, если все сделано верно, на экране появиться страница с текстом hello world.

«Соединяем» 1С и PHP:
Далее создаем в 1С внешнюю обработку и вставим в её модуль следующий код:

Код 1C v 7.x

 Функция Сформировать()

   	ПЕРЕМ СтрокаДляПриёма;

	ЗагрузитьВнешнююКомпоненту("v7plus.dll");

	HTTP=СоздатьОбъект("addin.v7httpreader");

	адрес="http://localhost/test.php?text="+текст;

	HTTP. ПолучитьКакСтроку(адрес, СтрокаДляПриёма);

	Сообщить(СтрокаДляПриёма);

КонецФункции

Отличается она от алгоритма, который мы создавали выше лишь значением в переменной адрес.
И так в случае успешной работы 1С и РНР-скпипта в окне сообщений 1С мы увидим надпись hello world.

Теперь очевидно, что с помощью 1C можно передать данные PHP-скриптам, а они в свою очередь делают с ними все что необходимо, например, записывают их в БД.

Пример записи данных в БД MySQL:
Запись в БД MYSQL будет производиться средствами PHP, об этом сказано уже не мало. Поэтому чтобы не повторяться, опишу пример из собственной практики.

Для начала создадим обработку в 1С:
На форму положим поле ввода и присвоим ему идентификатор текст, далее немного переделаем процедуру описанную в разделом выше:

Код 1C v 7.x

 Процедура Сформировать()

   	ПЕРЕМ СтрокаДляПриёма;

	ЗагрузитьВнешнююКомпоненту("v7plus.dll");

	HTTP=СоздатьОбъект("addin.v7httpreader");

	адрес=адрес="http://localhost/test.php?text="+Стр;

	HTTP. ПолучитьКакСтроку(адрес, СтрокаДляПриёма);

	возврат(СтрокаДляПриёма);

КонецПроцедуры

Теперь необходимо создать БД в MySQL (как это сделать описано здесь). Создадим БД и присвоим ей имя TESTDB. Далее создадим таблицу с именем TEST:

Код

CREATE TABLE `test` (
`id` INT NOT NULL AUTO_INCREMENT ,
`text` TEXT NOT NULL ,
PRIMARY KEY ( `id` )
);

Как видно из запроса, в таблице всего 2 поля:
* id – уникальный номер сроки;
* text – текстовое поле, куда будут помещаться данные из 1С.

Теперь необходимо написать PHP-скрипт, который и будет записывать данные из 1С в MySQL. Листинг данного скрипта приведен ниже:

Код

<?php
$host='localhost'; //адрес сервера
$db='testdb'; //имя БД
$user='root'; // имя пользователя
$password=''; //пароль к БД
$link = mysql_connect($host, $user, $password); //установка соединения
mysql_S_elect_db($db, $link); //подключения в БД

$text=$_GET['text']; // получаем значение переменной text

$query = "I_nsert into test values (NULL, '$text')"; //генерируем запрос
mysql_query($query, $link); //отправляем запрос
print mysql_error(); //сообщаем об ошибке если ошибок не было то возвращает пустое значение.
?>

Все готово! Теперь открываем Внешнюю обработку в 1С и пишем в поле ввода слово Hello! Нажимаем кнопку «Сформировать». Если все сделано правильно, то в созданной нами таблице появится запись со словом Hello! В противном случае, в окне сообщений 1С появится текст ошибки.

Заключение:
Весь тот опыт, которым я поделился в этой статье, можно использовать не только в Интернет-торговли, но и в корпоративных целях, например для того, чтобы:
* Консолидировать данные в единую БД MySQL;
* Предоставлять отчеты компетентным лицам, где бы они не находились.

И это еще далеко не весь перечень, ведь WEB-технологии - очень гибкий инструмент с неограниченным спектром возможностей, при условии умелого их использования.
В общем-то, мной был не только реализован механизм отправки данных, но и приема через HTTP, но вот это уже совсем другая история!

Автор: Хамитов Руслан

Категория: COM-объекты, WMI, WSH