структураколонок » Поиск

Результаты по ключевому слову: структураколонок

Функции сохранения таблицы значений в файл и чтения из файла

В данном примере хочу привести несколько универсальных функций по выгрузке таблицы значений в файл и дальнейшего чтения из файла:

Порядок программных действий при выгрузке в файл выглядит так:

Подготавливаем таблицу значений (выгружаем из табличной части, выбираем колонки);
Конвертируем таблицу значений в табличный документ;
Сохраняем табличный документ в MXL.

При загрузке таблицы порядок действий такой:

Читаем из файла табличный документ;
Конвертируем табличный документ в таблицу значений;
Используем эту таблицу значений в своих целях (загружаем в табличную часть).

Соответственно файл для хранения данных таблицы имеет расширение *.mxl.

Основные функции для реализации поставленной задачи следующие:

ПреобразоватьТДвТЗ – Функция преобразования табличного документа в таблицу значений.

ПреобразоватьТЗвТД – Функция обратного преобразования таблицы значений в табличный документ.

ПрочитатьТЗИзMXL – Читает из файла данные, определяет колонки таблицы и преобразует эти данные в таблицу значений.

ЗаписатьТЗВMXL – Преобразует таблицу значений в табличный документ и записывает его в файл.

Код 1C v 8.3

 // Преобразовать табличный документ в таблицу значений.

//

// Параметры:

//	ТабДок - <ТабличныйДокумент> - Исходный табличный документ;

//	СтруктураКолонок - <Структура>, <ТаблицаЗначений> - Структура колонок;

//	НачалоСтрока - <Число> - Строка начала области;

//	НачалоСтолбец - <Число> - Столбец начала области;

//	КонецСтрока - <Число> - Строка конца области;

//	КонецСтолбец - <Число> - Столбец конца области.

//	

// Возвращаемое значение:

//	<ТаблицаЗначений> - Полученная таблица значений.

//

Функция ПреобразоватьТДвТЗ(ТабДок, СтруктураКолонок, Знач НачалоСтрока = Неопределено, Знач НачалоСтолбец = Неопределено, Знач КонецСтрока = Неопределено, Знач КонецСтолбец = Неопределено) Экспорт

 

	// Определение габаритов таблицы

	Если НачалоСтрока = Неопределено И НачалоСтолбец = Неопределено Тогда

		НачалоСтрока = 1;

		НачалоСтолбец = 1;

	КонецЕсли;

 

	Если НачалоСтрока = Неопределено Тогда

		НачалоСтрока = 1;

		Пока НЕ ТабДок.Область(НачалоСтрока, НачалоСтолбец).СодержитЗначение 

		 И НачалоСтрока < ТабДок.ВысотаТаблицы 

		Цикл

			НачалоСтрока = НачалоСтрока + 1;

		КонецЦикла;

	ИначеЕсли НачалоСтолбец = Неопределено Тогда

		НачалоСтолбец = 1;

		Пока НЕ ТабДок.Область(НачалоСтрока, НачалоСтолбец).СодержитЗначение 

		 И НачалоСтолбец < ТабДок.ШиринаТаблицы

		Цикл

			НачалоСтолбец = НачалоСтолбец + 1;

		КонецЦикла;

	КонецЕсли;

 

	КонецСтрока = ?(КонецСтрока = Неопределено, ТабДок.ВысотаТаблицы, КонецСтрока);

	КонецСтолбец = ?(КонецСтолбец = Неопределено, ТабДок.ШиринаТаблицы, КонецСтолбец);

 

	// Преобразование

	ЭтоТаблица = (ТипЗнч(СтруктураКолонок) = Тип("ТаблицаЗначений"));

	ТабЗначений = ПолучитьТаблицуВывода(СтруктураКолонок);

 

	Для ИндексСтроки = НачалоСтрока По КонецСтрока Цикл

		СтрокаТЗ = ТабЗначений.Добавить();

 

		ИндексКолонки = НачалоСтолбец;

		Для Каждого Колонка Из СтруктураКолонок Цикл

			НаименованиеКолонки = ?(ЭтоТаблица, Колонка.Наименование, Колонка.Ключ);

			пИндексКолонки = ?(ЭтоТаблица, Колонка.СтолбецОтчёт, ИндексКолонки);

 

			Если ТабДок.Область(ИндексСтроки, пИндексКолонки).СодержитЗначение Тогда

				СтрокаТЗ[НаименованиеКолонки] = ТабДок.Область(ИндексСтроки, пИндексКолонки).Значение;

			Иначе

				СтрокаТЗ[НаименованиеКолонки] = ТабДок.Область(ИндексСтроки, пИндексКолонки).Текст;

			КонецЕсли;

 

			ИндексКолонки = ИндексКолонки + 1;

		КонецЦикла;

	КонецЦикла;

 

	Возврат ТабЗначений;

КонецФункции;



// Преобразовать таблицу значений в табличный документ.

//

// Параметры:

//	ТабЗначений - <ТаблицаЗначений> - Исходная таблица значений;

//	ТабДок - <ТабличныйДокумент> - Полученный табличный документ. Если параметр не задан, 

//	 то документ создаётся заново и возвращается функцией;

//	НачалоСтрока - <Число> - Строка начала области;

//	НачалоСтолбец - <Число> - Столбец начала области;

//	ВыводитьЗаголовки - <Булево> - Определяет выводить ли имена колонок или нет.

//	

// Возвращаемое значение:

//	<ТабличныйДокумент> - Полученный табличный документ (возвращает параметр "ТабДок").

//

Функция ПреобразоватьТЗвТД(ТабЗначений, ТабДок = Неопределено, Знач НачалоСтрока = Неопределено, Знач НачалоСтолбец = Неопределено, ВыводитьЗаголовки = Ложь) Экспорт

 

	Если ТабДок = Неопределено Тогда

		ТабДок = Новый ТабличныйДокумент;

	КонецЕсли;

 

	// Определение габаритов таблицы

	НачалоСтрока = ?(НачалоСтрока = Неопределено, 1, НачалоСтрока);

	НачалоСтолбец = ?(НачалоСтолбец = Неопределено, 1, НачалоСтолбец);

 

	// Преобразование

	ИндексСтроки = НачалоСтрока;

	Если ВыводитьЗаголовки Тогда

		ИндексКолонки = НачалоСтолбец;

		Для Каждого Колонка Из ТабЗначений.Колонки Цикл

			ТабДок.Область(ИндексСтроки, ИндексКолонки).Текст = ?(ПустаяСтрока(Колонка.Заголовок), Колонка.Имя, Колонка.Заголовок);

			ИндексКолонки = ИндексКолонки + 1;

		КонецЦикла;

		ИндексСтроки = ИндексСтроки + 1;

	КонецЕсли;

 

	Для Каждого Элемент Из ТабЗначений Цикл

		ИндексКолонки = НачалоСтолбец;

		Для Каждого Колонка Из ТабЗначений.Колонки Цикл

			ТабДок.Область(ИндексСтроки, ИндексКолонки).СодержитЗначение = Истина;

			ТабДок.Область(ИндексСтроки, ИндексКолонки).ТипЗначения = Новый ОписаниеТипов(Колонка.ТипЗначения);

			ТабДок.Область(ИндексСтроки, ИндексКолонки).Значение = Элемент[Колонка.Имя];

			ИндексКолонки = ИндексКолонки + 1;

		КонецЦикла;

		ИндексСтроки = ИндексСтроки + 1;

	КонецЦикла;

 

	Возврат ТабДок;

КонецФункции;



// Читает табличный документ из файла MXL и преобразует его в таблицу значений.

//

// Параметры:

//	ИмяФайла - <Строка> - Путь к файлу MXL;

//	СтруктураКолонок - <Структура>, <ТаблицаЗначений> - Структура колонок. Если этот параметр

//		не задан, то структура колонок формируется из самого табличного документа;

//	ЕстьЗаголовок - <Булево> - Есть ли первая строка с заголовками или нет.

//	

// Возвращаемое значение:

//	<ТаблицаЗначений> - Полученная таблица значений.

//

Функция ПрочитатьТЗИзMXL(ИмяФайла, СтруктураКолонок = Неопределено, ЕстьЗаголовок = Истина) Экспорт

 

	ТабДок = Новый ТабличныйДокумент;

	ТабДок.Прочитать(ИмяФайла);

 

	Если СтруктураКолонок = Неопределено И ЕстьЗаголовок Тогда

		СтруктураКолонок = Новый Структура;

		Для ИндексКолонки = 1 По ТабДок.ШиринаТаблицы Цикл

			Обл1 = ТабДок.Область(1, ИндексКолонки);

			Обл2 = ТабДок.Область(2, ИндексКолонки);

			ИмяКолонки = СокрЛП(Обл1.Текст);

			ИмяКолонки = ?(Найти(ИмяКолонки, " ") > 0, СтрЗаменить(ТРег(ИмяКолонки), " ", ""), ИмяКолонки);

			СтруктураКолонок.Вставить(ИмяКолонки, ?(Обл2.СодержитЗначение, Обл2.ТипЗначения, Новый ОписаниеТипов));

		КонецЦикла;

	ИначеЕсли СтруктураКолонок = Неопределено И НЕ ЕстьЗаголовок Тогда

		СтруктураКолонок = Новый Структура;

		Для ИндексКолонки = 1 По ТабДок.ШиринаТаблицы Цикл

			Обл2 = ТабДок.Область(1, ИндексКолонки);

			ИмяКолонки = "К" + Формат(ИндексКолонки, "ЧДЦ=0; ЧН=0; ЧГ=0");

			СтруктураКолонок.Вставить(ИмяКолонки, ?(Обл2.СодержитЗначение, Обл2.ТипЗначения, Новый ОписаниеТипов));

		КонецЦикла;

	КонецЕсли;

 

    Таблица = ПреобразоватьТДвТЗ(ТабДок, СтруктураКолонок, ?(ЕстьЗаголовок, 2, 1), 1);

 

	Возврат Таблица;

КонецФункции;



// Сохраняет таблицу значений в файле в виде табличного документа.

//

// Параметры:

//	ИмяФайла - <Строка> - Путь к файлу MXL;

//	ТабЗначений - <ТаблицаЗначений> - Сохраняемая таблица значений;

//	ЕстьЗаголовок - <Булево> - Есть ли первая строка с заголовками или нет.

//

Процедура ЗаписатьТЗВMXL(ИмяФайла, ТабЗначений, ЕстьЗаголовок = Истина) Экспорт

 

	ТабДок = ПреобразоватьТЗвТД(ТабЗначений, Неопределено, 1, 1, ЕстьЗаголовок);

	ТабДок.Записать(ИмяФайла, ТипФайлаТабличногоДокумента.MXL);

 

КонецПроцедуры;

Еще небольшой набор функций для вывода таблицы значений в табличный документ. После формирования табличного документа, - сохраняем его в файл mxl.

Табличный документ можно сохранить a файлы следующих типов:

ANSITXT - Текстовый документ
DOCX - документ MS Word
HTML
HTML3
HTML4
HTML5
MXL
MXL7
ODS - Файл Open Office
PDF - файл Acrobat Readr
TXT - Текстовый документ
XLS - файл Excel
XLS95 - файл Excel95
XLS97 - файл Excel97
XLSX - файл Excel2010

Код 1C v 8.3

 // Получаем таблицу значения из файла. 

Функция ЗагрузитьТЗизФайла(ИмяФайла)    

    Путь = КаталогВременныхФайлов() + ИмяФайла; 

    Текст = Новый ЧтениеТекста(Путь, КодировкаТекста.UTF8); 

    стрТЗ = Текст.Прочитать(); 

    Текст.Закрыть(); 

    // получим таблицу значений из строки

    ТЗ = ЗначениеИзСтрокиВнутр(стрТЗ);    

    Возврат ТЗ;    

КонецФункции    



// Заполнить ячейки в строке  значениями 

//

Функция ЗаписьТЗ2ТабДок(записьТЗ,НомерСтроки,ТабличныйДокумент)

    НомерКолонки = 1;

    Символ160 = Символ(160);    

    // цикл по колонкам таблицы

    // РезультатЗапроса.Колонки.Количество()    // - количество колонок

    Для каждого полеТЗ из ЗаписьТЗ цикл 

        // значения ячейки в Excel

        типПоляТЗ = ТипЗнч(полеТЗ);

        если типПоляТЗ = Тип("Число") тогда             

            полеТЗ=Строка(полеТЗ); 

            полеТЗ=СтрЗаменить(полеТЗ,Символ160,"");

            полеТЗ=СтрЗаменить(полеТЗ,",",".");

        иначеесли типПоляТЗ = Тип("Строка") тогда      

        иначе        

            полеТЗ = строка(полеТЗ);

        КонецЕсли;    

        имяОбласти = "R" + номерСтроки + "C" + НомерКолонки;

        имяОбласти = СтрЗаменить(имяОбласти,Символ(160),"");         

        Ячейка = ТабличныйДокумент.Область(имяОбласти);

        Ячейка.Текст = полеТЗ;

        НомерКолонки = НомерКолонки + 1;

    КонецЦикла;            

КонецФункции



// Заполнить наименованиями колонок таблицу

Функция НаимКолонок2Mxl(ТаблицаЗначений,ТабличныйДокумент)

    // массКолонки = новый массив();

    номерСтроки=1;

    номКолонки=1; 

    ТабличныйДокумент = новый ТабличныйДокумент;

    // цикл по коллекции колонок

    Для НомКол=0 по ТаблицаЗначений.Колонки.Количество() - 1 Цикл

        //Сообщить(Колонка.Имя + "(" + Колонка.ТипЗначения + ")" );            

        имяКолонки=ТаблицаЗначений.Колонки[НомКол].Имя;

        //ТабличныйДокумент.Область(

        имяОбласти = "R" + номерСтроки + "C" + номКолонки;

        имяОбласти = СтрЗаменить(имяОбласти,Символ(160),"");         

        Ячейка = ТабличныйДокумент.Область(имяОбласти);

        //значениеЯчейки = СтрЗаменить(имяОбласти,Символ(160),"");         

        Ячейка.Текст = имяКолонки;

        // на основе текущего шрифта сделаем Жирный

        ЖирныйШрифт = ?(ЖирныйШрифт = Неопределено,Новый Шрифт(Ячейка.Шрифт,,,Истина),ЖирныйШрифт);         

        Ячейка.Шрифт = ЖирныйШрифт;

        номКолонки = номКолонки + 1;        

    КонецЦикла;

КонецФункции





// Заполнить построчно табличный документ

Функция Таблица2Mxl(ТаблицаЗначений,ТабличныйДокумент)

    //Выборка = РезультатЗапроса.Выбрать();

    НомСтр=1; // заполняем данными начиная со 2-й строки    

    // цикл по строкам таблицы

    Для каждого записьТЗ из ТаблицаЗначений Цикл

        НомСтр = НомСтр + 1;

        // цикл по колонкам таблицы        

        ЗаписьТЗ2ТабДок(записьТЗ,НомСтр,ТабличныйДокумент);         

    КонецЦикла;    

КонецФункции



// Таблица значений в табличный документ

Функция ТаблицаЗначений2Mxl(ТаблицаЗначений,ФайлMxl)

    ТабличныйДокумент = новый ТабличныйДокумент;

    // вывести колонки

    НаимКолонок2Mxl(ТаблицаЗначений,ТабличныйДокумент);

    // вывести содержимое таблицы    

    Таблица2Mxl(ТаблицаЗначений,ТабличныйДокумент);

    ТабличныйДокумент.Записать(ФайлMxl,ТипФайлаТабличногоДокумента.MXL);

    ТабличныйДокумент.Показать(ФайлMxl,ФайлMxl);

    Возврат 0;

КонецФункции





Функция    Тест_ВыгрузитьТЗвMxl();

    файл_мТЗИсходныеДанные = "мТЗИсходныеДанные.dat";        

    ТЗ = ЗагрузитьТЗизФайла(файл_мТЗИсходныеДанные);    

    ФайлMxl = КаталогВременныхФайлов() + СтрЗаменить(файл_мТЗИсходныеДанные,".dat",".mxl");  

    ТаблицаЗначений2Mxl(ТЗ,ФайлMxl);

КонецФункции



Тест_ВыгрузитьТЗвMxl();

Пример выгруженной таблицы значений в файл:

Категория: Работа с Таблицей Значений

Обмен данными с сайтом используя формат JSON в 1С

Формат JSON в 1С до версии 8.3.6 не реализован, но нижет я приведу примеры функций которые можно использовать для полноценной работы JSON в 1С предыдущий версий.

JSON (JavaScript Object Notation) это текстовый формат обмена данными, широко используемый в веб-приложениях. По сравнению с XML он является более лаконичным и занимает меньше места. Кроме этого все браузеры имеют встроенные средства для работы с JSON.

Необходимость работы с этим форматом на уровне платформы обусловлена не только тем, что это «модный современный» формат, который прикладные решения 1С:Предприятия сами по себе могут использовать для интеграции со сторонними приложениями. Другая причина заключается ещё и в том, что JSON активно используется в HTTP интерфейсах. А в 1С:Предприятии как раз есть такие механизмы, в которых хочется использовать этот формат. Это REST интерфейс приложения, автоматически генерируемый платформой, и HTTP-сервисы, которые вы можете создавать самостоятельно.

В платформе с версии 8.3.6:

Потоковое чтение и запись JSON:

Объекты потоковой работы - это общие объекты ЧтениеJSON и ЗаписьJSON. Они последовательно читают JSON из файла или строки, или последовательно записывают JSON в файл или строку. Таким образом, чтение и запись JSON происходят без формирования всего документа в памяти.

В качестве иллюстрации потокового чтения JSON можно привести следующий пример:

Код 1C v 8.3

 //  Пример чтения  JSON. 

ЧтениеJSON = Новый ЧтениеJSON;

// Либо открыть файл, из которого будет выполняться чтение, // либо установить строку, из которой будет выполняться чтение.

ЧтениеJSON.ОткрытьФайл("ИмяФайла");

//ЧтениеJSON.УстановитьСтроку("СтрокаJSON");

Пока ЧтениеJSON.Прочитать()   Цикл

TипJSON = ЧтениеJSON.ТипТекущегоЗначения;

Если TипJSON = ТипЗначенияJSON.Число     ИЛИ TипJSON = ТипЗначенияJSON.Строка ИЛИ TипJSON = ТипЗначенияJSON.Булево  ИЛИ TипJSON = ТипЗначенияJSON.Null  Тогда

// Обработать значение

Значение = ЧтениеJSON.ТекущееЗначение;

ИначеЕсли ТипJSON = ТипЗначенияJSON.Комментарий Тогда

// Обработать комментарий

Комментарий =  ЧтениеJSON.ТекущееЗначение;

ИначеЕсли TипJSON = ТипЗначенияJSON.ИмяСвойства Тогда

// Обработать имя свойства

ИмяСвойства = ЧтениеJSON.ТекущееЗначение;

ИначеЕсли TипJSON = ТипЗначенияJSON.НачалоМассива ИЛИ TипJSON = ТипЗначенияJSON.КонецМассива ИЛИ TипJSON = ТипЗначенияJSON.НачалоОбъекта ИЛИ TипJSON = ТипЗначенияJSON.КонецОбъекта ИЛИ TипJSON = ТипЗначенияJSON.Ничего Тогда

// Обработать начало/коней массива/объекта или отсутствие данных, // ТекущееЗначение читать не нужно.

КонеиЕсли;

КокецЦикла;

ЧтениеJSON.Закрыть();



// При записи JSON вы самостоятельно формируете его структуру. Чтобы «подстраховать» вас от ошибок, объект ЗаписьJSON автоматически проверяет правильность записываемой структуры. 

// Для увеличения скорости работы эту проверку можно отключить. В примере ниже это строка:

ЗаписьJSON.ПроверятьСтруктуру = Ложь;



// Также при записи вы можете управлять некоторыми параметрами формируемого текста, например использованием двойных кавычек, переносом строк, символами отступа и экранированием символов. 

// В примере ниже для форматирования текста используется символ табуляции:

ПараметрыЗаписиJSON = Новый ПараметрыЗаписиJSON( , Символы.Таб) ; 

ЗаписьJSON.ОткрытьФайл("ИмяФайла", , , ПараметрыЗаписиJSON);



// Потоковая запись JSON может выглядеть следующим образом. Записывается массив из четырёх элементов. Три из них примитивного типа, а четвёртый элемент - это объект с двумя свойствами:

// Пример записи JSON. ЗаписьJSON = Новый ЗаписьJSON;

// Для увеличения скорости работы можно отключить автоматическую проверку // правильности структуры записываемого документа JSON. ЗаписьиЗСЖ.ПроверятьСтруктуру = Ложь;

// Для красоты результирующего текста можно увеличить "лесенку".

// Стандартный отступ - 1 пробел.

ПараметрыЗаписиJSON = Новый ПараметрыЗаписиJSON( , Символы.Таб);

// Либо открыть файл, в который будет выполнена запись,

// либо указать, что запись будет выполнена в строку, которую вернет метод Закрыть().

ЗаписьJSON.ОткрытьФайл("ИмяФайла", , , ПараметрыЗаписиJSON);

//ЗаписьJSON.УстановитьСтроку(ПараметрыЗаписиJSON);

// Записать массив.

ЗаписьJSON.ЗаписатьНачалоОбъекта();

ЗаписьJSON.ЗаписатьИмяСвойства("СвойствоТипаМассив");

ЗаписьJSON.ЗаписатьНачалоМассива();

// Первый элемент массива - Строка. ЗаписьJSON.ЗаписатьЗначение("Значение строка");

// Второй элемент массива - Число. ЗаписьJSON.ЗаписатьЗначение(12.345, Истина);

// Третий элемент массива - Булево. ЗаписьJSON-ЗаписатьЗначение(Истина);

// Четвертый элемент массива - объект с двумя свойствами. ЗаписьJSON.ЗаписатьНачалоОбъекта();

// Первое свойство объекта - Строка

ЗаписьJSON.ЗаписатьИмяСвойства("СвойствоТипаСтрока");

ЗаписьJSON.ЗаписатьЗначение("Значение строка");

// Второе свойство объекта - Неопределено

ЗаписьJSON.ЗаписатьИмяСвойства("СвойствоТипаНеопределено");

ЗаписьJSON.ЗаписатьЗначение(Неопределено);

ЗаписьJSON.ЗаписатьКонецОбъекта();

Запись JSON. ЗаписатьКонецМассива () ;

ЗаписьJSON.ЗаписатьКонецОбъекта();

ЗаписьJSON.Закрыть();

//CTpoKaJSON = ЗаписьJSON.Закрыть();

Результат такой записи:

Код 1C v 8.х

 

{

	"СвойствоТипаМассив": [

		"Значение строка",

		1.2345E1,

		true,

		{

			"СвойствоТипаСтрока": "Значение строка",

			"СвойствоТипаНеопределено": null

		}

	]

}

Сериализация примитивных типов и коллекций в JSON

Вторая группа средств работы с JSON хороша тем, что избавляет вас от рутинной работы по чтению/записи каждого отдельного значения или свойства. При чтении документы JSON отображаются в фиксированный набор типов платформы: Строка, Число, Булево, Неопределено, Массив, ФиксированныйМассив, Структура, ФиксированнаяСтруктура, Соответствие, Дата. Соответственно, в обратную сторону, композиция объектов этих типов позволяет сформировать в памяти и быстро записать в файл структуру JSON. Таким образом, чтение и запись небольшого объема JSON заранее известной структуры можно производить немногими строчками кода.

Основное назначение этих средств мы видим в обмене информацией с внешними системами, чтении конфигурационных файлов в формате JSON.

Сериализацию вы можете выполнять с помощью методов глобального контекста ПрочитатьJSON() и ЗаписатьJSON(). Они работают в связке с объектами ЧтениеJSON и ЗаписьJSON.

В качестве примера десериализации JSON можно рассмотреть чтение массива из двух объектов:

Код 1C v 8.3

 // В качестве примера десериализации JSON можно рассмотреть чтение массива из двух объектов:

[

	{

		"имя": "Anton",

		"фамилия": "Иванов",

		"возраст": 25

	},

	{

		"имя": "Ирина",

		"фамилия": "Иванова",

		"возраст": 20

	}

]

// Код 1С:Предприятия, выполняющий десериализацию, может выглядеть следующим образом:

// Пример чтения JSON. 

ЧтениеJSON = Новый ЧтениеJSON(); 

ЧтениеJSON.ОткрытьФайл("ИмяФайла"); 

Сотрудники = ПрочитатьJSON(ЧтениеJSON); 

ЧтениеJSON.Закрыть();

Для каждого Сотрудник из Сотрудники Цикл

// Обработать данные сотрудника. 

ИмяСотрудника = Сотрудник.имя; ФамилияСотрудника = Сотрудник.фамилия; ВозрастСотрудника = Сотрудник.возраст;

КонецЦикла;





// А пример сериализации (записи) в JSON может выглядеть так:

// Пример записи JSON

Структура = Новый Структура; 

Вставить("Фамилия","Иванов"); 

Зставить("Имя", "Иван"); 

Вставить("Отчество", "Иванович"); 

Зставить("Возраст", 40) ; 

Зставить("Женат", Истина);

Телефоны = Новый Массив;

Телефоны.Добавить("8-999-999-99-90") ;

Телефоны.Добавить("8-999-999-99-91") ;

Структура.Вставить("Телефоны", Телефены);





ЗаписьJSON = Новый ЗаписьJSON; 

ЗаписьJSON.ОткрытьФайл("ИмяФайла", , , Новый ПapaмeтpыЗaпиcиJS0N( , Символы.Таб) ) ;

ЗаписатьJSON(ЗаписьJSON, Структура); 

ЗаписьJSON.Закрыть();





// Результат записи:

{

	"Фамилия": "Иванов",

	"Имя": "Иван",

	"Отчество": "Иванович",

	"Возраст": 40,

	"Женат": true,

	"Телефоны": [

		"8-999-999-99-90",

		"8-999-999-99-91"

	]

}

Подробнее вы можете посмотреть здесь

В платформе с версии 8.3.7:

Полностью автоматизировали работу с JSON и реализовали в платформе третью группу средств. Они позволяют сериализовать в JSON прикладные типы 1С:Предприятия: ссылки, объекты, наборы записей и вообще любые типы, для которых поддерживается XDTO сериализация. Конечно же, мы обеспечили и обратную операцию - десериализацию. Зачем это нужно!?

Прежде всего, и в основном, XDTO сериализацию в JSON мы рекомендуем использовать при обмене данными между двумя прикладными решениями 1С:Предприятия. По сравнению с XML формат JSON более компактный, сериализация/десериализация в/из JSON выполняется быстрее. Кроме этого мы предприняли дополнительные меры для того, чтобы сократить объём передаваемых данных.

Кроме обмена между приложениями 1С:Предприятия этот механизм можно использовать и для обмена с внешними системами, готовыми принимать типы данных 1С:Предприятия. Например, XDTO сериализацию в JSON можно использовать для организации собственного HTTP интерфейса прикладного решения. Сервис на платформе 1С:Предприятия будет формировать ответ в памяти в виде строки JSON. А затем передавать её при помощи объекта HTTPСервисОтвет. Реализованный нами механизм сериализации полностью соответствует стандарту JSON. Поэтому внешняя система не должна испытывать каких-либо трудностей с десериализацией.

Использование XDTO сериализации в JSON для других задач видится нам маловероятным. Потому что если внешняя система не готова работать с прикладными типами 1С:Предприятия, то зачем их ей передавать? А если предполагается обмениваться только примитивными типами и коллекциями, то для этой задачи хорошо подходят методы ПрочитатьJSON() и ЗаписатьJSON(). Подробнее здесь

ДО платформы версии 8.3.6, т.е. 8.3.5 и ниже:

На HelpF уже есть статья где описан пример: Работа с форматом JSON в 1С но не приведены функции, вот они:

Код 1C v 8.х

 Функция ПреобразоватьвСистему(Число10,система) Экспорт

	Если система > 36 или система < 2 тогда

		Сообщить("Выбранная система исчисления не поддерживается");

		Возврат -1;

	КонецЕсли;

	

	СтрокаЗначений = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ";

	СтрокаСистема = "";

	Пока Число10 > 0 цикл

		РезДеления = Число10/система;

		ЧислоСистема = цел(РезДеления);

		остатокОтДеления = Число10 - система*(ЧислоСистема);

		СтрокаСистема = сред(СтрокаЗначений,остатокОтДеления+1,1)+ СтрокаСистема;

		Число10 = ?(ЧислоСистема=0,0,РезДеления); 

	КонецЦикла;

	

	Нечётное = стрДлина(СтрокаСистема) - цел(стрДлина(СтрокаСистема)/2)*2;

	Если Нечётное тогда

		СтрокаСистема = "0"+СтрокаСистема;

	КонецЕсли;

	

	Возврат СтрокаСистема;

КонецФункции





Функция URLEncode(стр) Экспорт	

	Длина=СтрДлина(Стр);

	Итог="";

	Для Н=1 По Длина Цикл

		Знак=Сред(Стр,Н,1);

		Код=КодСимвола(Знак);

		

		если ((Знак>="a")и(Знак<="z")) или

			 ((Знак>="A")и(Знак<="Z")) или

			 ((Знак>="0")и(Знак<="9")) тогда

			Итог=Итог+Знак;

		Иначе

			Если (Код>=КодСимвола("А"))И(Код<=КодСимвола("п")) Тогда

				Итог=Итог+"%"+ПреобразоватьвСистему(208,16)+"%"+ПреобразоватьвСистему(144+Код-КодСимвола("А"),16);

			ИначеЕсли (Код>=КодСимвола("р"))И(Код<=КодСимвола("я")) Тогда

				Итог=Итог+"%"+ПреобразоватьвСистему(209,16)+"%"+ПреобразоватьвСистему(128+Код-КодСимвола("р"),16);

			ИначеЕсли (Знак="ё") Тогда

				Итог=Итог+"%"+ПреобразоватьвСистему(209,16)+"%"+ПреобразоватьвСистему(145,16);

			ИначеЕсли (Знак="Ё") Тогда

				Итог=Итог+"%"+ПреобразоватьвСистему(208,16)+"%"+ПреобразоватьвСистему(129,16);

			Иначе

				Итог=Итог+"%"+ПреобразоватьвСистему(Код,16);

			КонецЕсли;

		КонецЕсли;

	КонецЦикла;

	Возврат Итог;

КонецФункции





Функция СформироватьСтрокуJSONИзМассива(Объект)

	СтрокаJSON = "[";

	

	Для каждого Элемент Из Объект Цикл

		Если ТипЗнч(Элемент) = Тип("Строка") Тогда

			СтрокаJSON = СтрокаJSON + """" + Элемент + """";

		ИначеЕсли ТипЗнч(Элемент) = Тип("Число") Тогда

			СтрокаJSON = СтрокаJSON + СтрЗаменить(Строка(Элемент), Символы.НПП, "");

		ИначеЕсли ТипЗнч(Элемент) = Тип("Булево") Тогда

			СтрокаJSON = СтрокаJSON + Формат(Элемент, "БЛ=false; БИ=true");

		ИначеЕсли ТипЗнч(Элемент) = Тип("Дата") Тогда

			СтрокаJSON = СтрокаJSON + Формат(Элемент - Дата(1970,1,1,1,0,0), "ЧГ=0");

		ИначеЕсли ТипЗнч(Элемент) = Тип("Массив") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент);

		ИначеЕсли ТипЗнч(Элемент) = Тип("Структура") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент);

		ИначеЕсли ТипЗнч(Элемент) = Тип("ТаблицаЗначений") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент);

		Иначе

			СтрокаJSON = СтрокаJSON + """" + URLEncode(Строка(Элемент)) + """";

		КонецЕсли;

		

		СтрокаJSON = СтрокаJSON + ",";

	КонецЦикла;

	

	Если Прав(СтрокаJSON, 1) = "," Тогда

		СтрокаJSON = Лев(СтрокаJSON, СтрДлина(СтрокаJSON)-1);

	КонецЕсли;

	

	Возврат СтрокаJSON + "]";

КонецФункции





Функция СформироватьСтрокуJSONИзСтруктуры(Объект)

	СтрокаJSON = "{";

	

	Для каждого Элемент Из Объект Цикл

		Если Элемент.Значение = "" Тогда

			Продолжить;

		КонецЕсли;

		

		СтрокаJSON = СтрокаJSON + """" + Элемент.Ключ + """" + ":";

		

		Если ТипЗнч(Элемент.Значение) = Тип("Строка") Тогда

			СтрокаJSON = СтрокаJSON + """" + Элемент.Значение + """";

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Число") Тогда

			СтрокаJSON = СтрокаJSON + СтрЗаменить(Строка(Элемент.Значение), Символы.НПП, "");

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Булево") Тогда

			СтрокаJSON = СтрокаJSON + Формат(Элемент.Значение, "БЛ=false; БИ=true");

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Дата") Тогда

			СтрокаJSON = СтрокаJSON + Формат(Элемент.Значение - Дата(1970,1,1,1,0,0), "ЧГ=0");

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Массив") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент.Значение);

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Структура") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент.Значение);

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("ТаблицаЗначений") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент.Значение);

		Иначе

			СтрокаJSON = СтрокаJSON + """" + URLEncode(Строка(Элемент.Значение)) + """";

		КонецЕсли;

		

		СтрокаJSON = СтрокаJSON + ",";

	КонецЦикла;

	

	Если Прав(СтрокаJSON, 1) = "," Тогда

		СтрокаJSON = Лев(СтрокаJSON, СтрДлина(СтрокаJSON)-1);

	КонецЕсли;

	

	Возврат СтрокаJSON + "}";

КонецФункции





Функция СформироватьСтрокуJSON(Объект) Экспорт

	СтрокаJSON = "";

	

	Если ТипЗнч(Объект) = Тип("Массив") Тогда

		СтрокаJSON = СформироватьСтрокуJSONИзМассива(Объект);

	ИначеЕсли ТипЗнч(Объект) = Тип("Структура") Тогда

		СтрокаJSON = СформироватьСтрокуJSONИзСтруктуры(Объект);

	ИначеЕсли ТипЗнч(Объект) = Тип("ТаблицаЗначений") Тогда

		СоставСтруктуры = "";

		Для каждого Колонка Из Объект.Колонки Цикл

			СоставСтруктуры = СоставСтруктуры + ?(ЗначениеЗаполнено(СоставСтруктуры), ",", "") + Колонка.Имя;

		КонецЦикла;

		

		МассивСтрок = Новый Массив;

		Для каждого Строка Из Объект Цикл

			СтруктураКолонок = Новый Структура(СоставСтруктуры);

			ЗаполнитьЗначенияСвойств(СтруктураКолонок, Строка);

			МассивСтрок.Добавить(СтруктураКолонок);

		КонецЦикла;

		

		СтрокаJSON = СформироватьСтрокуJSONИзМассива(МассивСтрок);

	КонецЕсли;

	

	Возврат СтрокаJSON;

КонецФункции





Процедура ЗаполнитьДанныеИзОтветаJSON(Результат, ТекстJSON, ТипДанных)

	ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));	

	НомерЗначения = 0;

	

	Пока ТекстJSON <> "" Цикл

		ПервыйСимвол = Лев(ТекстJSON, 1);

		Если ПервыйСимвол = "{" Тогда

			Значение = Новый Структура;

			ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Структура");

			

			Если ТипДанных = "Структура" Тогда

				Результат.Вставить("Значение" + ?(НомерЗначения = 0, "", НомерЗначения), Значение);

				НомерЗначения = НомерЗначения + 1;

			ИначеЕсли ТипДанных = "Массив" Тогда

				Результат.Добавить(Значение);

			КонецЕсли;

		ИначеЕсли ПервыйСимвол = "[" Тогда

			Значение = Новый Массив;

			ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Массив");

			

			Если ТипДанных = "Структура" Тогда

				Результат.Вставить("Значение" + ?(НомерЗначения = 0, "", НомерЗначения), Значение);

				НомерЗначения = НомерЗначения + 1;

			Иначе

				Результат.Добавить(Значение);

			КонецЕсли;

		ИначеЕсли ПервыйСимвол = "}" И ТипДанных = "Структура" Тогда

			ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			Если Лев(ТекстJSON, 1) = "," Тогда

				ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			КонецЕсли;

			

			Возврат;

		ИначеЕсли ПервыйСимвол = "]" И ТипДанных = "Массив" Тогда

			ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			Если Лев(ТекстJSON, 1) = "," Тогда

				ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			КонецЕсли;

			

			Возврат;

		Иначе

			Если ТипДанных = "Структура" Тогда

				

				Поз = Найти(ТекстJSON, ":");

				Если Поз = 0 Тогда

					Прервать;

				КонецЕсли;

				

				ИмяЗначения = СокрЛП(Лев(ТекстJSON, Поз-1));

				

				ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз+1));

				

				Если Лев(ТекстJSON, 1) = "{" Тогда

					Значение = Новый Структура;

					ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Структура");

				ИначеЕсли Лев(ТекстJSON, 1) = "[" Тогда

					Значение = Новый Массив;

					ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Массив");

				Иначе

					Поз = 0;

					Для Сч = 1 По СтрДлина(ТекстJSON) Цикл

						Символ = Сред(ТекстJSON, Сч, 1);

						Если Символ = "," ИЛИ Символ = "]" ИЛИ Символ = "}" Тогда

							Поз = Сч;

							Прервать;

						КонецЕсли;

					КонецЦикла;

					

					Если Поз = 0 Тогда

						Значение = ТекстJSON;

						ТекстJSON = "";

					Иначе

						Значение = Лев(ТекстJSON, Поз-1);

						ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз + ?(Сред(ТекстJSON, Поз, 1) = ",", 1, 0)));

					КонецЕсли;

					

					Значение = СокрЛП(Значение);

				КонецЕсли;

				

				Результат.Вставить(ИмяЗначения, Значение);

			ИначеЕсли ТипДанных = "Массив" Тогда

				Поз = 0;

				Для Сч = 1 По СтрДлина(ТекстJSON) Цикл

					Символ = Сред(ТекстJSON, Сч, 1);

					Если Символ = "," ИЛИ Символ = "]" ИЛИ Символ = "}" Тогда

						Поз = Сч;

						Прервать;

					КонецЕсли;

				КонецЦикла;

				

				Если Поз = 0 Тогда

					Значение = ТекстJSON;

					ТекстJSON = "";

				Иначе

					Значение = Лев(ТекстJSON, Поз-1);

					ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз + ?(Сред(ТекстJSON, Поз, 1) = ",", 1, 0)));

				КонецЕсли;

				

				Значение = СокрЛП(Значение);

				

				Результат.Добавить(Значение);

			КонецЕсли;

		КонецЕсли;

	КонецЦикла;

КонецПроцедуры





Функция ЗаполнитьСтруктуруИзОтветаJSON(Знач ТекстJSON) Экспорт

	Результат = Новый Структура;

	

	ТекстJSON = СтрЗаменить(ТекстJSON, "\""", """");

	ТекстJSON = СтрЗаменить(ТекстJSON, """", "");	

	Если Лев(ТекстJSON, 1) = "{" Тогда

		ЗаполнитьДанныеИзОтветаJSON(Результат, ТекстJSON, "Структура");

	ИначеЕсли Лев(ТекстJSON, 1) = "[" Тогда

		МассивДанных = Новый Массив;

		ЗаполнитьДанныеИзОтветаJSON(МассивДанных, ТекстJSON, "Массив");

		

		Результат.Вставить("Значение", МассивДанных);

	КонецЕсли;

		

	Возврат Результат;

КонецФункции

Примеры их использования:

Код 1C v 8.х

 ////////////////////////////////////////////////////////

// преобразование простой структуры

Данные = Новый Структура("server,user,hash",

            10234, 3745, "8263ad83ce");

СтрокаJSON = СформироватьСтрокуJSONИзСтруктуры(Данные);

// результатом будет строка

// {"server":"10234","user":"3745","hash":"8263ad83ce"} 

 

////////////////////////////////////////////////////////

// преобразования массива

Данные = Новый Массив;

Данные.Добавить("Nissan");

Данные.Добавить("Ford");

Данные.Добавить("Audi");

 

СтрокаJSON = СформироватьСтрокуJSONИзСтруктуры(Данные);

// результатом будет строка

// ["Nissan","Ford","Audi"] 

 

////////////////////////////////////////////////////////

// преобразование сложной структуры

Данные = Новый Структура;

Данные.Добавить("server", 10234);

Данные.Добавить("users", Новый Массив);

Данные.Добавить("hash", "8263ad83ce");

 

Данные.users.Добавить(3745);

Данные.users.Добавить(7462);

Данные.users.Добавить(2374);

 

СтрокаJSON = СформироватьСтрокуJSONИзСтруктуры(Данные);

// результатом будет строка

// {"server":"10234","users":["3745","7462","2374"],"hash":"8263ad83ce"}

 

////////////////////////////////////////////////////////

// еще один пример массива

Данные = Новый Структура;

Данные.Вставить("server", 10234);

Данные.Вставить("users", Новый Массив);

 

Данные.users.Добавить(Новый Структура("id,name", 3745, "Jack"));

Данные.users.Добавить(Новый Структура("id,name", 7246, "Nick"));

 

СтрокаJSON = СформироватьСтрокуJSONИзСтруктуры(Данные);

// результатом будет строка

// {"server":"10234","users":[{"id":"3745","name":"Jack"},{"id":"7462","name":"Nick"}>

 

////////////////////////////////////////////////////////

// преобразование таблицы значений

ТаблПользователей = Новый ТаблицаЗначений;

ТаблПользователей.Колонки.Добавить("id");

ТаблПользователей.Колонки.Добавить("name");

 

НоваяСтрока = ТаблПользователей.Добавить();

НоваяСтрока.id = 3276;

НоваяСтрока.name = "Jack";

 

НоваяСтрока = ТаблПользователей.Добавить();

НоваяСтрока.id = 3276;

НоваяСтрока.name = "Nick";

 

СтрокаJSON = СформироватьСтрокуJSONИзСтруктуры(Данные);

// результатом будет строка

// [{"id":"3745","name":"Jack"},{"id":"7462","name":"Nick"}]

Пишите комменты

Категория: Работа с Интернет, Почтой (Mail), FTP

Яндекс, Google, Рамблер Карты и 1С

Обработка демонстрирует возможности интеграции 1С с картографическими сервисами, в ней поддерживается работа трех поставщиков услуг / карт — Яндекс, Google. Рамблер.
Автор: Діма Головаченко - http://smaylukk.com.ua
но так вот сама обработка + еще 2 : Скачивать файлы может только зарегистрированный пользователь!

Код Модуля Обработки:

Код 1C v 8.х

 Перем СтруктураПоставщиковКарт Экспорт;

Перем СтруктураЧисел;



/////////////////////////РАБОТА С JSON //////////////////////////////////////////

Функция СформироватьСтрокуJSONИзМассива(Объект)

	

	СтрокаJSON = "[";

	

	Для каждого Элемент Из Объект Цикл

		СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент) + ",";

	КонецЦикла;

	

	Если Прав(СтрокаJSON, 1) = "," Тогда

		СтрокаJSON = Лев(СтрокаJSON, СтрДлина(СтрокаJSON)-1);

	КонецЕсли;

	

	Возврат СтрокаJSON + "]";

	

КонецФункции



Функция СформироватьСтрокуJSONИзСтруктуры(Объект)

	

	СтрокаJSON = "{";

	

	Для каждого Элемент Из Объект Цикл

		

		Если Элемент.Значение = "" Тогда

			Продолжить;

		КонецЕсли;

		

		СтрокаJSON = СтрокаJSON + """" + Элемент.Ключ + """" + ":";

		

		Если ТипЗнч(Элемент.Значение) = Тип("Строка") Тогда

			СтрокаJSON = СтрокаJSON + """" + URLEncode(Элемент.Значение) + """";

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Число") Тогда

			СтрокаJSON = СтрокаJSON + СтрЗаменить(Строка(Элемент.Значение), Символы.НПП, "");

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Булево") Тогда

			СтрокаJSON = СтрокаJSON + Формат(Элемент.Значение, "БЛ=false; БИ=true");

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Дата") Тогда

			// преобразование в unixtime

			СтрокаJSON = СтрокаJSON + Формат(ТекущаяДата() - Дата(1970,1,1,1,0,0), "ЧГ=0");

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Массив") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент.Значение);

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Структура") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент.Значение);

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("ТаблицаЗначений") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент.Значение);

			

		Иначе

			СтрокаJSON = СтрокаJSON + """" + URLEncode(Строка(Элемент.Значение)) + """";

			

		КонецЕсли;

		

		СтрокаJSON = СтрокаJSON + ",";

		

	КонецЦикла;

	

	Если Прав(СтрокаJSON, 1) = "," Тогда

		СтрокаJSON = Лев(СтрокаJSON, СтрДлина(СтрокаJSON)-1);

	КонецЕсли;

	

	Возврат СтрокаJSON + "}";

	

КонецФункции



Функция СформироватьСтрокуJSON(Объект) Экспорт

	

	СтрокаJSON = "";

	

	Если ТипЗнч(Объект) = Тип("Массив") Тогда

		СтрокаJSON = СформироватьСтрокуJSONИзМассива(Объект);

		

	ИначеЕсли ТипЗнч(Объект) = Тип("Структура") Тогда

		СтрокаJSON = СформироватьСтрокуJSONИзСтруктуры(Объект);

		

	ИначеЕсли ТипЗнч(Объект) = Тип("ТаблицаЗначений") Тогда

		// преобразуем таблицу значений в массив структур - работает дольше, но кода меньше

		// если нужна скорость, то нужно отдельно обработать таблицу значений

		

		СоставСтруктуры = "";

		Для каждого Колонка Из Объект.Колонки Цикл

			СоставСтруктуры = СоставСтруктуры + ?(ЗначениеЗаполнено(СоставСтруктуры), ",", "") + Колонка.Имя;

		КонецЦикла;

		

		МассивСтрок = Новый Массив;

		Для каждого Строка Из Объект Цикл

			СтруктураКолонок = Новый Структура(СоставСтруктуры);

			ЗаполнитьЗначенияСвойств(СтруктураКолонок, Строка);

			МассивСтрок.Добавить(СтруктураКолонок);

		КонецЦикла;

		

		СтрокаJSON = СформироватьСтрокуJSONИзМассива(МассивСтрок);

		

	КонецЕсли;

	

	Возврат СтрокаJSON;

	

КонецФункции



Процедура ЗаполнитьДанныеИзОтветаJSON(Результат, ТекстJSON, ТипДанных)

	

	ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));	// удалим открывающий символ структуры(массива)

	

	НомерЗначения = 0;

	

	Пока ТекстJSON <> "" Цикл

		

		ПервыйСимвол = Лев(ТекстJSON, 1);

		Если ПервыйСимвол = "{" Тогда

			// вложенная структура

			Значение = Новый Структура;

			ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Структура");

			

			Если ТипДанных = "Структура" Тогда

				Результат.Вставить("Значение" + ?(НомерЗначения = 0, "", НомерЗначения), Значение);

				НомерЗначения = НомерЗначения + 1;

			ИначеЕсли ТипДанных = "Массив" Тогда

				Результат.Добавить(Значение);

			КонецЕсли;

		

		ИначеЕсли ПервыйСимвол = "[" Тогда

			// вложенный массив

			Значение = Новый Массив;

			ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Массив");

			

			Если ТипДанных = "Структура" Тогда

				Результат.Вставить("Значение" + ?(НомерЗначения = 0, "", НомерЗначения), Значение);

				НомерЗначения = НомерЗначения + 1;

			Иначе

				Результат.Добавить(Значение);

			КонецЕсли;

			

		ИначеЕсли ПервыйСимвол = "}" И ТипДанных = "Структура" Тогда

			// структура закончилась

			ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			Если Лев(ТекстJSON, 1) = "," Тогда

				ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			КонецЕсли;

			

			Возврат;

			

		ИначеЕсли ПервыйСимвол = "]" И ТипДанных = "Массив" Тогда

			// массив закончился

			ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			Если Лев(ТекстJSON, 1) = "," Тогда

				ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			КонецЕсли;

			

			Возврат;

			

		Иначе

			

			Если ТипДанных = "Структура" Тогда

				//ПервыйКавычка = Ложь;

				//Если Лев(ТекстJSON, 1) = """" Тогда

				//	ПервыйКавычка = Истина;

				//КонецЕсли;

				

				Поз = Найти(ТекстJSON, ":");

				Если Поз = 0 Тогда

					// неверный формат, прервемся

					Прервать;

				КонецЕсли;

				

				//ПредпоследнийКавычка = Ложь;

				//Если Сред(ТекстJSON, Поз - 1, 1) = """" Тогда

				//	ПредпоследнийКавычка = Истина;

				//КонецЕсли;



				

				ИмяЗначения = СокрЛП(Лев(ТекстJSON, Поз - 1));

				ИмяЗначения = СтрЗаменить(ИмяЗначения, """", "");

				

				ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз+1));

								

				Если Лев(ТекстJSON, 1) = "{" Тогда

					// значение является структурой

					Значение = Новый Структура;

					ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Структура");

					

				ИначеЕсли Лев(ТекстJSON, 1) = "[" Тогда

					// значение является массивом

					Значение = Новый Массив;

					ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Массив");

					

				Иначе

					// обычное значение

					ПервыйКавычка = Ложь;

					ПредпоследнийКавычка = Ложь;

					Поз = 0;

					Для Сч = 1 По СтрДлина(ТекстJSON) Цикл

						Символ = Сред(ТекстJSON, Сч, 1);

						

						Если Символ = """" Тогда

							Если ПервыйКавычка Тогда

								ПредпоследнийКавычка = Истина;

							Иначе

								ПервыйКавычка = Истина;

							КонецЕсли;							

						КонецЕсли;

						

						Если (Символ = "," И ((ПервыйКавычка И ПредпоследнийКавычка) Или (Не ПервыйКавычка И Не ПредпоследнийКавычка))) ИЛИ Символ = "]" ИЛИ Символ = "}" Тогда

							Поз = Сч;

							Прервать;

						КонецЕсли;

					КонецЦикла;

					

					//ПредпоследнийКавычка = Ложь;

					//Если Сред(ТекстJSON, Поз - 1, 1) = """" Тогда

					//	ПредпоследнийКавычка = Истина;

					//КонецЕсли;

					

					Если Поз = 0 Тогда

						Значение = ТекстJSON;

						ТекстJSON = "";

						

					Иначе

						Значение = Лев(ТекстJSON, Поз - 1);

						Значение = СтрЗаменить(Значение, """", "");

						ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз + ?(Сред(ТекстJSON, Поз, 1) = ",", 1, 0)));						

					КонецЕсли;

					

					Значение = СокрЛП(Значение);

					

				КонецЕсли;

				

				Результат.Вставить(ИмяЗначения, Значение);

				

			ИначеЕсли ТипДанных = "Массив" Тогда

				

				// обычное значение

				Поз = 0;

				Для Сч = 1 По СтрДлина(ТекстJSON) Цикл

					Символ = Сред(ТекстJSON, Сч, 1);

					Если Символ = "," ИЛИ Символ = "]" ИЛИ Символ = "}" Тогда

						Поз = Сч;

						Прервать;

					КонецЕсли;

				КонецЦикла;

				

				//ПредпоследнийКавычка = Ложь;

				//Если Сред(ТекстJSON, Поз - 1, 1) = """" Тогда

				//	ПредпоследнийКавычка = Истина;

				//КонецЕсли;

				

				Если Поз = 0 Тогда

					Значение = ТекстJSON;

					ТекстJSON = "";

					

				Иначе

					Значение = Лев(ТекстJSON, Поз - 1);

					Значение = СтрЗаменить(Значение, """", "");

					ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз + ?(Сред(ТекстJSON, Поз, 1) = ",", 1, 0)));

					

				КонецЕсли;

				

				Значение = СокрЛП(Значение);

				

				Результат.Добавить(Значение);

				

			КонецЕсли;

				

			

		КонецЕсли;

		

	КонецЦикла;

	

КонецПроцедуры



Функция ЗаполнитьСтруктуруИзОтветаJSON(Знач ТекстJSON) Экспорт

	

	Результат = Новый Структура;

	

	ТекстJSON = СтрЗаменить(ТекстJSON, "\""", """");	// заменим последовательность \" на "

	//ТекстJSON = СтрЗаменить(ТекстJSON, """", "");		// а теперь удалим все кавычки

	

	Если Лев(ТекстJSON, 1) = "{" Тогда

		// начало структуры

		ЗаполнитьДанныеИзОтветаJSON(Результат, ТекстJSON, "Структура");

		

	ИначеЕсли Лев(ТекстJSON, 1) = "[" Тогда

		// начало массива

		МассивДанных = Новый Массив;

		ЗаполнитьДанныеИзОтветаJSON(МассивДанных, ТекстJSON, "Массив");

		

		Результат.Вставить("Значение", МассивДанных);

		

	КонецЕсли;

		

	Возврат Результат;

	

КонецФункции



Функция КодСимволаASCII(Символ) 

   КодUNICODE = КодСимвола(Символ); 

   Если ((КодUNICODE > 1039) И (КодUNICODE < 1104)) Тогда 

       Возврат (КодUNICODE - 848); 

   ИначеЕсли КодUNICODE = 8470 Тогда 

       Возврат 185; 

   ИначеЕсли КодUNICODE = 1105 Тогда 

       Возврат 184; 

   ИначеЕсли КодUNICODE = 1025 Тогда 

       Возврат 168; 

   Иначе 

       Возврат КодUNICODE; 

   КонецЕсли; 

КонецФункции



Функция URLEncode(value)



    table = "%00%01%02%03%04%05%06%07%08%09%0A%0B%0C%0D%0E%0F%10%11%12%13%14" +

            "%15%16%17%18%19%1A%1B%1C%1D%1E%1F%20%21%22%23%24%25%26%27%28" +

            "%29%2A%2B%2C%2D%2E%2F%30%31%32%33%34%35%36%37%38%39%3A%3B%3C" +

            "%3D%3E%3F%40%41%42%43%44%45%46%47%48%49%4A%4B%4C%4D%4E%4F%50" +

            "%51%52%53%54%55%56%57%58%59%5A%5B%5C%5D%5E%5F%60%61%62%63%64" +

            "%65%66%67%68%69%6A%6B%6C%6D%6E%6F%70%71%72%73%74%75%76%77%78" +

            "%79%7A%7B%7C%7D%7E%7F%80%81%82%83%84%85%86%87%88%89%8A%8B%8C" +

            "%8D%8E%8F%90%91%92%93%94%95%96%97%98%99%9A%9B%9C%9D%9E%9F%A0" +

            "%A1%A2%A3%A4%A5%A6%A7%A8%A9%AA%AB%AC%AD%AE%AF%B0%B1%B2%B3%B4" +

            "%B5%B6%B7%B8%B9%BA%BB%BC%BD%BE%BF%C0%C1%C2%C3%C4%C5%C6%C7%C8" +

            "%C9%CA%CB%CC%CD%CE%CF%D0%D1%D2%D3%D4%D5%D6%D7%D8%D9%DA%DB%DC" +

            "%DD%DE%DF%E0%E1%E2%E3%E4%E5%E6%E7%E8%E9%EA%EB%EC%ED%EE%EF%F0" +

            "%F1%F2%F3%F4%F5%F6%F7%F8%F9%FA%FB%FC%FD%FE%FF";

    

    result = "";        

            

    length = СтрДлина( value );        

    

    Для i = 1 По  length Цикл        

        symbol = Сред( value, i, 1 );        

        //code = КодСимвола( symbol );    

        code = КодСимволаASCII( symbol );

        result = result + Сред( table, code*3 + 1, 3 );        

    КонецЦикла;

    

    

    

    Возврат result;

КонецФункции

/////////////////////////РАБОТА С JSON //////////////////////////////////////////



//Функция декодирует полученный unicod текст - из ответа геокодера Рамблера

// в привычный нам

//Параметры:

// Строка

//Возвращаемое значение:

// Строка

Функция UnicodeEncode(Строка) Экспорт 

	Результат = Истина;

	

	Попытка

		//регулярное выражение

		Рег = Новый COMОбъект("VBScript.RegExp");

		Рег.IgnoreCase = Истина;

		Рег.Global = Истина;

		Рег.Multiline = Ложь;

		Рег.Pattern = "u[0-9a-f]+";

		Колекция = Рег.Execute(Строка);

		Для Каждого Элемент Из Колекция Цикл

			Если СтрДЛина(Элемент.value) = 1 Тогда

				Продолжить;

			КонецЕсли;		

			

			КодСимвола = ПереводЧислаИз16в10(Сред(ВРег(Элемент.value), 2));

			Символ = Символ(КодСимвола);

			Строка = СтрЗаменить(Строка, "\" + Элемент.value, Символ); 

		КонецЦикла;	

	Исключение

		Результат = Ложь;

		Сообщить("Ошибка преобразования из Unicode", СтатусСообщения.Информация);

	КонецПопытки;

	

	Возврат Результат;

КонецФункции



Функция ПереводЧислаИз16в10(Знач Значение)

	Результат = 0;

	

	//перевод значения в строку

	Если ТипЗнч(Значение) <> Тип("Строка") Тогда

		Значение = СокрЛП(Строка(Значение));

	КонецЕсли;

	

	МаксРазрядЦелых = 0;

	МаксРазрядЦелых = СтрДлина(Значение) - 1;

	

	н = МаксРазрядЦелых;

	Ин = 1;

	Пока н >= 0 Цикл

		ТекЗначение = СтруктураЧисел.Получить(Сред(Значение, Ин, 1)) * Pow(16, н);

		Результат = Результат + ТекЗначение;

		н = н - 1;

		Ин = Ин + 1;

	КонецЦикла;

	

	Возврат Результат;

КонецФункции



///////////////////////////

СтруктураПоставщиковКарт = Новый Соответствие;

СтруктураПоставщиковКарт.Вставить(0, "Яндекс");

СтруктураПоставщиковКарт.Вставить(1, "Гугл");

СтруктураПоставщиковКарт.Вставить(2, "2ГИС");

СтруктураПоставщиковКарт.Вставить(3, "Рамблер");





СтруктураЧисел = Новый Соответствие;

СтруктураЧисел.Вставить("0", 0);

СтруктураЧисел.Вставить("1", 1);

СтруктураЧисел.Вставить("2", 2);

СтруктураЧисел.Вставить("3", 3);

СтруктураЧисел.Вставить("4", 4);

СтруктураЧисел.Вставить("5", 5);

СтруктураЧисел.Вставить("6", 6);

СтруктураЧисел.Вставить("7", 7);

СтруктураЧисел.Вставить("8", 8);

СтруктураЧисел.Вставить("9", 9);

СтруктураЧисел.Вставить("A", 10);

СтруктураЧисел.Вставить("B", 11);

СтруктураЧисел.Вставить("C", 12);

СтруктураЧисел.Вставить("D", 13);

СтруктураЧисел.Вставить("E", 14);

СтруктураЧисел.Вставить("F", 15);

Код Формы Управляемой:

Код 1C v 8.2 УП

 



&НаКлиенте

Процедура НайтиАдрес(Команда)

	НайтиАдресНаКарте(ТекАдрес);

КонецПроцедуры



&НаКлиенте

Процедура ИнициализацияКарты(Команда)

	ИнициализироватьКарту();

КонецПроцедуры



&НаКлиенте

Процедура СправочнаяИнформация(Команда)

	Элементы.ГруппаСправка.Видимость = Не Элементы.ГруппаСправка.Видимость;

КонецПроцедуры



&НаКлиенте

Процедура Разработчик(Команда)

	ЗапуститьПриложение("http://smaylukk.com.ua/?lang=Ru");

КонецПроцедуры



&НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

	Объект.ТипКарты = Параметры.ТипКарты;

	ТекОбъект = РеквизитФормыВЗначение("Объект");

	Поставщик = ТекОбъект.СтруктураПоставщиковКарт.Получить(Объект.ТипКарты);

	

	Макет = ТекОбъект.ПолучитьМакет("Справка");

	ТекстСправки = Макет.ПолучитьОбласть("Справка" + Поставщик).Область().Текст;

	Справка = ТекстСправки;

КонецПроцедуры



&НаКлиенте

Процедура ПриОткрытии(Отказ)

	Элементы.ГруппаСправка.Видимость = Ложь;

	Заголовок = "Работа с картами. Поставщик - " + Поставщик;

	ИнициализироватьКарту();

КонецПроцедуры



&НаКлиенте

Процедура ПриЗакрытии()

	//удаление временных файлов

	Для Каждого ТекЭлемент Из МассивВременныхФайлов Цикл

		УдалитьФайлы(ТекЭлемент.Значение);

	КонецЦикла;

КонецПроцедуры



&НаКлиенте

//Процедура составляет  имя процедуры поставщика

// и запускает ее на исполнение

//Параметры:

// НачалоИмени - Строка

Процедура ВыполнитьПроцедуруПоставщика(ИмяПроцедуры)

	Выполнить ИмяПроцедуры;

КонецПроцедуры



&НаКлиенте

//процедура инициализирует карту постащика из макета

Процедура ИнициализироватьКарту()

	Текст = ПолучитьТекстМакета("Макет" + Поставщик);

	

	Эксплорер = Текст;

КонецПроцедуры



&НаСервере

Функция ПолучитьТекстМакета(ИмяМакета)

	Макет = РеквизитФормыВЗначение("Объект").ПолучитьМакет(ИмяМакета);

	Результат = Макет.ПолучитьТекст();

	Возврат Результат;

КонецФункции



&НаКлиенте

Процедура ОчисткаКарты()

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "Reset()";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



///////////////////////////////////////////////////////////////////////

///////////////////ГЕОКОДИРОВАНИЕ И ПОИСК АДРЕСА///////////////////////

///////////////////////////////////////////////////////////////////////



&НаКлиенте

Процедура НайтиАдресНаКарте(Адрес = "")	

	//поиск адреса

	Если Адрес = "" Тогда

		Адрес = "Москва";		

	КонецЕсли;

	

	// дальше пробуем с помощью геокодинга вывести данные поиска в таблицу

	ТаблицаАдресов.Очистить();

	

	ПоискАдреса(Адрес);

	Если Поставщик = "Яндекс" Тогда

		ПроизвестиГеокодинг_Яндекс();

	ИначеЕсли Поставщик = "Гугл" Тогда

		ПроизвестиГеокодинг_Гугл();

	ИначеЕсли Поставщик = "Рамблер" Тогда

		ПроизвестиГеокодинг_Рамблер();

	КонецЕсли;

КонецПроцедуры



&НаКлиенте

Процедура ПоискАдреса(Адрес)

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "FindAdres(""" + Адрес + """);";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаСервере

//Процедура выводит в таблицу данные геокдинга Яндекса

//

//Параметры:

// ТекАдрес - Строка

Процедура ПроизвестиГеокодинг_Яндекс()

	Яндекс = Новый HTTPСоединение("geocode-maps.yandex.ru");

	

	ВременныйФайл = КаталогВременныхФайлов() + "Yandex_geocode_" + СокрЛП(Новый УникальныйИдентификатор);

	Попытка

		Яндекс.Получить("/1.x/?geocode=" + ТекАдрес + "&results=10", ВременныйФайл);

	Исключение

		Сообщить("Ошибка при попытке геокодировать по яндексу адрес: " + ТекАдрес);

		Сообщить(ОписаниеОшибки());

		Возврат;

	КонецПопытки;

	

	ЧтениеXML = Новый ЧтениеXML;

	ЧтениеXML.ОткрытьФайл(ВременныйФайл);

	

	ПостроительDOM 			= Новый ПостроительDOM;

	ДокументДОМ 			= ПостроительDOM.Прочитать(ЧтениеXML);

	

	СписокText 				= ДокументДОМ.ПолучитьЭлементыПоИмени("text");

	СписокPos 				= ДокументДОМ.ПолучитьЭлементыПоИмени("pos");

		

	Если (СписокText.Количество() = 0) ИЛИ (СписокPos.Количество() = 0) Тогда

		Возврат;	

	КонецЕсли;

	

	Для ъ = 0 по СписокText.Количество()-1 Цикл

		Координаты = СписокPos[Ъ].ТекстовоеСодержимое;

		Разделитель = Найти(Координаты," ");

		Широта = Число(Сред(Координаты, Разделитель + 1));

		Долгота = Число(Лев(Координаты, Разделитель - 1));

		

		Если Широта = 0 ИЛИ Долгота = 0 Тогда

			Продолжить;

		КонецЕсли;

		

		стрАдрес = ТаблицаАдресов.Добавить();

		Если СписокText.Количество() > ъ Тогда

			стрАдрес.Адрес = СписокText[Ъ].ТекстовоеСодержимое;

			стрАдрес.Широта = Широта;

			стрАдрес.Долгота = Долгота;

		КонецЕсли;		

	КонецЦикла;	

	МассивВременныхФайлов.Добавить(ВременныйФайл);

КонецПроцедуры



&НаСервере

//Процедура выводит в таблицу данные геокдинга Гугл

//

//Параметры:

// ТекАдрес - Строка

Процедура ПроизвестиГеокодинг_Гугл()

	Гугл = Новый HTTPСоединение("maps.googleapis.com");

	

	ВременныйФайл = КаталогВременныхФайлов() + "Google_geocode_" + СокрЛП(Новый УникальныйИдентификатор);

	Попытка

		Гугл.Получить("/maps/api/geocode/xml?address=" + ТекАдрес + "&language=ru&sensor=false", ВременныйФайл);

	Исключение

		Сообщить("Ошибка при попытке геокодировать по Google адрес: " + ТекАдрес);

		Сообщить(ОписаниеОшибки());

		Возврат;

	КонецПопытки;

	

	ЧтениеXML = Новый ЧтениеXML;

	ЧтениеXML.ОткрытьФайл(ВременныйФайл);

	

	ПостроительDOM 			= Новый ПостроительDOM;

	ДокументДОМ 			= ПостроительDOM.Прочитать(ЧтениеXML);

	ТаблицаРезультатов = ДокументДОМ.ПолучитьЭлементыПоИмени("result");

	

	Если ДокументДОМ.ПолучитьЭлементыПоИмени("status")[0].ТекстовоеСодержимое <> "OK" ИЛИ ТаблицаРезультатов.Количество() = 0 Тогда 

		Возврат;

	КонецЕсли;

		

	Для ТекРезультат = 0 по ТаблицаРезультатов.Количество() -1 Цикл 

		

		СписокText 				= ТаблицаРезультатов[ТекРезультат].ПолучитьЭлементыПоИмени("formatted_address");

		ЭлементыШиротаДолгота = ТаблицаРезультатов[ТекРезультат].ПолучитьЭлементыПоИмени("location");

		Широта = ЭлементыШиротаДолгота[0].ПолучитьЭлементыПоИмени("lat")[0].ТекстовоеСодержимое;

		Долгота = ЭлементыШиротаДолгота[0].ПолучитьЭлементыПоИмени("lng")[0].ТекстовоеСодержимое;

		Если Широта = 0 ИЛИ Долгота = 0 Тогда

			Продолжить;

		КонецЕсли;

			

		стрАдрес = ТаблицаАдресов.Добавить();

		стрАдрес.Широта = Широта;

		стрАдрес.Долгота = Долгота;

		стрАдрес.Адрес = СписокText[0].ТекстовоеСодержимое;  

	КонецЦикла;

	МассивВременныхФайлов.Добавить(ВременныйФайл);

КонецПроцедуры



&НаСервере

//Процедура выводит в таблицу данные геокдинга Рамблер

//

//Параметры:

// ТекАдрес - Строка

Процедура ПроизвестиГеокодинг_Рамблер()

	ТемпАдрес = СтрЗаменить(ТекАдрес, " ", "+");

	

	Рамблер = Новый HTTPСоединение("maps.rambler.ru");	

	ВременныйФайл = КаталогВременныхФайлов() + "Рамблер_geocode_" + СокрЛП(Новый УникальныйИдентификатор);

	Попытка

		Рамблер.Получить("/search/?&a=search&q=" + ТемпАдрес + "&n=10", ВременныйФайл);

	Исключение

		Сообщить("Ошибка при попытке геокодировать по Рамблер адрес: " + ТекАдрес);

		Сообщить(ОписаниеОшибки());

		Возврат;

	КонецПопытки;

	

	а = 1;

	Т = Новый ТекстовыйДокумент;

	Т.Прочитать(ВременныйФайл);

	СтрокаОтвет = Т.ПолучитьТекст();

	Результат = РеквизитФормыВЗначение("Объект").UnicodeEncode(СтрокаОтвет);

	Если Результат Тогда

		СтруктураJSON = РеквизитФормыВЗначение("Объект").ЗаполнитьСтруктуруИзОтветаJSON(СтрокаОтвет);

	КонецЕсли;

	

	МассивРезультатов = СтруктураJSON.res;

	//обрабатываем элементы массива - только адреса. POI можно обработать отдельно пожеланию

	Для Каждого Результат Из МассивРезультатов Цикл

		Для Каждого ТекРезультат Из Результат.matches Цикл				

			стрАдрес = ТаблицаАдресов.Добавить();

			стрАдрес.Долгота = Число(ТекРезультат.x);

			стрАдрес.Широта = Число(ТекРезультат.y);

			Если Результат.type = "addr" Тогда  //Результат.type = "poi" - содержит в себе список точек интереса

				стрАдрес.Адрес = ТекРезультат.addr;

			Иначе

				стрАдрес.Адрес = ТекРезультат.name + " - " + ТекРезультат.addr;

			КонецЕсли;

		КонецЦикла;

	КонецЦикла;

	МассивВременныхФайлов.Добавить(ВременныйФайл);

КонецПроцедуры



&НаКлиенте

Процедура ОбратнПоискАдреса(Широта, Долгота, Адрес)

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "ReverseSearchAdres(" + Широта + "," + Долгота + ", """ + Адрес + """);";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

Процедура ТаблицаАдресовВыбор(Элемент, ВыбраннаяСтрока, Поле, СтандартнаяОбработка)

	Если ЗначениеЗаполнено(ТаблицаАдресов[ВыбраннаяСтрока].Широта) И ЗначениеЗаполнено(ТаблицаАдресов[ВыбраннаяСтрока].Долгота) Тогда

		СтандартнаяОбработка = Ложь;

	КонецЕсли;

	

	Широта = Формат(ТаблицаАдресов[ВыбраннаяСтрока].Широта, "ЧЦ=10; ЧДЦ=7; ЧРД=.; ЧРГ=");

	Долгота = Формат(ТаблицаАдресов[ВыбраннаяСтрока].Долгота, "ЧЦ=10; ЧДЦ=7; ЧРД=.; ЧРГ=");

	

	ОбратнПоискАдреса(Широта, Долгота, ТаблицаАдресов[ВыбраннаяСтрока].Адрес);

КонецПроцедуры



&НаКлиенте

Процедура ТекАдресПриИзменении(Элемент)

	НайтиАдресНаКарте(ТекАдрес);

КонецПроцедуры





///////////////////////////////////////////////////////////////////////

///////////////////МАРШРУТИЗАЦИЯ, КЛАСТЕРА И ПОЛИГОН///////////////////////////////////////

///////////////////////////////////////////////////////////////////////



&НаКлиенте

Процедура ЭксплорерПриНажатии(Элемент, ДанныеСобытия, СтандартнаяОбработка)

	ПолучитьКоординаты();

КонецПроцедуры



&НаКлиенте

Процедура ПостроитьМаршрут(Команда)

	Если ТаблицаТочек.Количество() <= 1 Тогда

		Предупреждение("Недостаточно точек для построение маршрута!");

		Возврат;

	КонецЕсли;

	

	Если Поставщик = "Яндекс" Тогда

		ПостроитьМаршрут_Яндекс();

	ИначеЕсли Поставщик = "Гугл" Тогда

		ПостроитьМаршрут_Гугл();

	ИначеЕсли Поставщик = "Рамблер" Тогда

		ПостроитьМаршрут_Рамблер();

	КонецЕсли;

КонецПроцедуры



&НаКлиенте

//Процедура выстраивает маршрут для Яндекса

//

//Параметры:

//

Процедура ПостроитьМаршрут_Яндекс()

	ПараметрыМаршрута = ПолучитьПараметрыМаршрутаЯндекс();

	

	ОчисткаКарты();

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "calcRoute(" + ПараметрыМаршрута + ")";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

//Функция получает массив точек, для передачи параметров в Яндекс

//

//Параметры:

//

//Возвращаемое значение:

// Строка

Функция ПолучитьПараметрыМаршрутаЯндекс()

	Результат = "";

	

	Результат = Результат + "[[" + СтрЗаменить(Строка(ТаблицаТочек[0].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[0].Долгота), ",", ".") + "],";

		

	Для Ин = 1 По ТаблицаТочек.Количество() - 2 Цикл

		Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ин].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ин].Долгота), ",", ".") + "],";

	КонецЦикла;

		

	Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Долгота), ",", ".") + "]]";

		

	Возврат Результат;

КонецФункции



&НаКлиенте

//Процедура выстраивает маршрут для Гугл

//

//Параметры:

//

Процедура ПостроитьМаршрут_Гугл()

	ПараметрыМаршрута = ПолучитьПараметрыМаршрутаГугл();

	

	ОчисткаКарты();

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "calcRoute(" + ПараметрыМаршрута + ")";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

//Функция получает массив точек, для передачи параметров в Гугл

//

//Параметры:

//

//Возвращаемое значение:

// Строка

Функция ПолучитьПараметрыМаршрутаГугл()

	Результат = "";

	ВнутрМассив = "";

	

	Результат = Результат + "[[" + СтрЗаменить(Строка(ТаблицаТочек[0].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[0].Долгота), ",", ".") + "],";

	

	Если ТаблицаТочек.Количество() = 2 Тогда

		Результат = Результат + "[],"; 

	Иначе

		Для Ин = 1 По ТаблицаТочек.Количество() - 2 Цикл

			ВнутрМассив = ВнутрМассив + "[" + СтрЗаменить(Строка(ТаблицаТочек[ин].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ин].Долгота), ",", ".") + "],";

		КонецЦикла;

		Результат = Результат + "[" + Сред(ВнутрМассив, 1, СтрДлина(ВнутрМассив) - 1) + "],";

	КонецЕсли;

	

	Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Долгота), ",", ".") + "]]";

		

	Возврат Результат;

КонецФункции



&НаКлиенте

//Процедура выстраивает маршрут для Рамблера

//

//Параметры:

//

Процедура ПостроитьМаршрут_Рамблер()

	ПараметрыМаршрута = ПолучитьПараметрыМаршрутаРамблер();

	

	ОчисткаКарты();

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "calcRoute(" + ПараметрыМаршрута + ")";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

//Функция получает массив точек, для передачи параметров в Рамблер

//

//Параметры:

//

//Возвращаемое значение:

// Строка

Функция ПолучитьПараметрыМаршрутаРамблер()

	Результат = "";

	

	Результат = Результат + "[[" + СтрЗаменить(Строка(ТаблицаТочек[0].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[0].Долгота), ",", ".") + "],";

		

	Для Ин = 1 По ТаблицаТочек.Количество() - 2 Цикл

		Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ин].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ин].Долгота), ",", ".") + "],";

	КонецЦикла;

		

	Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Долгота), ",", ".") + "]]";

		

	Возврат Результат;

КонецФункции



&НаКлиенте

Процедура СоздатьКластер(Команда)

	Если ТаблицаТочек.Количество() <= 1 Тогда

		Предупреждение("Недостаточно точек для построение кластера!");

		Возврат;

	КонецЕсли;

	

	ОчисткаКарты();

	

	ПостроитьКластера();

КонецПроцедуры



&НаКлиенте

Процедура ПостроитьКластера()

	Кол = ТаблицаТочек.Количество();

	Индекс = 1;

	Для Каждого ТекСтрока Из ТаблицаТочек Цикл

		Широта = формат(ТекСтрока.Широта, "ЧРД=.");

		Долгота = формат(ТекСтрока.Долгота, "ЧРД=.");

		СодержимоеТочки = "Содерижмое точки";  //опять же можно вставить свое название

		Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "addToPointArray(" + Широта + "," + Долгота + ", '" + ТекСтрока.Точка + "', """ + СодержимоеТочки + """);";

		Элементы.Эксплорер.document.getElementById("WebClient").click();

		

		Состояние("Обработан " + Индекс + " из " + кол);

		Индекс = Индекс + 1;

	КонецЦикла;

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "drawCluster();";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

Процедура ОчиститьВсе(Команда)

	ОчисткаКарты();

	ТаблицаТочек.Очистить();

КонецПроцедуры



&НаКлиенте

Процедура ОчиститьКарту(Команда)

	ОчисткаКарты();

КонецПроцедуры



&НаКлиенте

Процедура ОчиститьТаблицу(Команда)

	ТаблицаТочек.Очистить();

КонецПроцедуры



&НаКлиенте

//Процедура получает координаты установленной точки

Процедура ПолучитьКоординаты()

	Попытка

		ЧислоТип = Новый ОписаниеТипов("Число", Новый КвалификаторыЧисла(15, 12));

		

		КоординатаX = Элементы.Эксплорер.document.getElementById("CoordX").value;

		КоординатаX = ЧислоТип.ПривестиЗначение(КоординатаX);

		

		КоординатаY = Элементы.Эксплорер.document.getElementById("CoordY").value;

		КоординатаY = ЧислоТип.ПривестиЗначение(КоординатаY);

		

		Кол = ТаблицаТочек.Количество();

		Если КоординатаX > 0 И КоординатаY > 0 И (Кол = 0 Или КоординатаX <> ТаблицаТочек[Кол - 1].Широта И КоординатаY <> ТаблицаТочек[Кол - 1].Долгота) Тогда

			НоваяСтрока = ТаблицаТочек.Добавить();

			НоваяСтрока.Точка = "Точка" + ТаблицаТочек.Количество();

			НоваяСтрока.Широта = КоординатаX;

			НоваяСтрока.Долгота = КоординатаY;

		КонецЕсли;

	Исключение

	КонецПопытки;

КонецПроцедуры



&НаКлиенте

Процедура ПострениеПолигона(Команда)

	Если ТаблицаТочек.Количество() <= 1 Тогда

		Предупреждение("Недостаточно точек для построение полигона!");

		Возврат;

	КонецЕсли;

	

	ОчисткаКарты();

	

	ПостроитьПолигон();

КонецПроцедуры



&НаКлиенте

//Процедура выстраивает маршрут для Рамблера

//

//Параметры:

//

Процедура ПостроитьПолигон()

	МассивТочек = "[";

	Для Каждого ТекТочка Из ТаблицаТочек Цикл

		Широта = формат(ТекТочка.Широта, "ЧРД=.");

		Долгота = формат(ТекТочка.Долгота, "ЧРД=.");

		МассивТочек = МассивТочек + "[" + Широта + "," + Долгота + "],"; 

	КонецЦикла;

	МассивТочек = Сред(МассивТочек, 1, СтрДлина(МассивТочек) - 1) + "]";

	

	Цвет16 = Получить16Цвет();

	

	Название = "Полигон";//вставить свое 

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "createPolygon(" + МассивТочек + ", '" + Название + "', '" + Цвет16 + "');";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаСервере

//Функция возвращает значение случайного цвета в 16-ричном формате

//

//Параметры:

//  нет

//Возвращаемое значение:

//  Строка

Функция Получить16Цвет()

	Результат = "";

	

	Строка16 = "0123456789ABCDEF";

	ГСЧ = Новый ГенераторСлучайныхЧисел;

	Результат = "#";

	Для н = 1 По 6 Цикл

		м = ГСЧ.СлучайноеЧисло(1, 16);

		Результат = Результат + Сред(Строка16, м, 1);

	КонецЦикла;

	

	Возврат Результат;

КонецФункции

Категория: COM-объекты, WMI, WSH

Подключение к EXCEL и чтение данных из листа Excel

Код 1C v 8.х

 Ex = Новый COMObject("Excel.Application");

   Ex.Workbooks.Open(Путь);

   Ex.Visible = 1;    

   ТекЛист=Ex.WorkSheets(1);        

   Для Ячейка = 1 по 400 цикл

       Если НЕ  ТекЛист.Cells(Ячейка,1).Value  = Неопределено тогда

           Сообщить(Строка(ТекЛист.Cells(Ячейка,1).Value));    

           Карта = Справочники.Номенклатура.НайтиПоКоду(ИзЧислаВСтроку(ТекЛист.Cells(Ячейка,1).Value));    

           Если Карта.Пустая() тогда        

               Сообщить(" Пустой элемент "  + ТекЛист.Cells(Ячейка,1));

           иначе

               Объект = Карта.ПолучитьОбъект();

               Объект.ОсновнойПоставщик = ОсновнойКлиент;

               Объект.Записать();

               конецесли;    

       конецесли;

   конеццикла;

Примеры процедур для чтения данных из EXCEL

Код 1C v 8.х

 

// Функция получает данные из файла Excel

//

// Параметры:

//   пФайл - Имя файла

//   пЛист - Имя листа с данными

//   СтруктураКолонок - Структура вида "ИмяКолонки" - "НомерКолонки"

//                      если не задано, созадуться колонки вида "К1", "К2"

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция Excel_ПолучитьДанные_ADO(пФайл, пЛист, СтруктураКолонок = Неопределено, Знач НачСтрока = 0, Знач КонСтрока = 0) Экспорт



    #Если Клиент Тогда

    Состояние("Установка соединения с Excel");

    #КонецЕсли



    //ЗаголовкиВСтроке1 = "HDR=YES;"

    ЗаголовкиВСтроке1 = "HDR=NO;";



    СтрокаСоединения ="Provider=Microsoft.Jet.OLEDB.4.0;Data Source= " + СокрЛП(пФайл) +" ;Extended Properties=""Excel 8.0;" + ЗаголовкиВСтроке1 + "IMEX=1;""";



    Connection = Новый COMОбъект("ADODB.Connection");

    Connection.ConnectionString =  СтрокаСоединения;



    Попытка

        Connection.Open();

    Исключение

        Сообщить ("Проблемы с подключением к Excel" );

        Возврат Неопределено;

    КонецПопытки;



    RS = Новый COMОбъект("ADODB.Recordset");



    ТекстЗапроса =

    "S_elect

    |    Лист.*

    |FROM

    |    [" + пЛист + "$] as Лист";



    Попытка

        RS.Open(ТекстЗапроса, Connection);

    Исключение

        Сообщить ("Проблемы с выполнением запроса");

        Возврат Неопределено;

    КонецПопытки;



    Таблица = Новый ТаблицаЗначений;



    Если СтруктураКолонок = Неопределено Тогда



        Для Счетчик = 1 По RS.Fields.Count Цикл

            Поле = RS.Fields.Item(Счетчик - 1);

            Колонка = Таблица.Колонки.Добавить("К" + Счетчик, , Поле.Name);

        КонецЦикла;



    Иначе



        Для каждого КлючИЗначение Из СтруктураКолонок Цикл

            Колонка = Таблица.Колонки.Добавить(КлючИЗначение.Ключ);

        КонецЦикла;



    КонецЕсли;



    НомерСтроки = 0;

    КолвоСтрок  = RS.RecordCount;



    Пока RS.EOF() = 0 Цикл



        НомерСтроки = НомерСтроки + 1;



        #Если Клиент Тогда

        Состояние("Чтение файла: " + Формат(НомерСтроки) + " из " + Формат(КолвоСтрок));

        ОбработкаПрерыванияПользователя();

        #КонецЕсли



        Если НомерСтроки < НачСтрока Тогда

            RS.MoveNext();

            Продолжить;

        КонецЕсли;



        Если КонСтрока > 0 И НомерСтроки > КонСтрока Тогда

            Прервать;

        КонецЕсли;



        НоваяСтрока = Таблица.Добавить();



        Если СтруктураКолонок = Неопределено Тогда



            Для Счетчик = 1 По RS.Fields.Count Цикл



                Поле = RS.Fields.Item(Счетчик - 1);

                НоваяСтрока["К" + Счетчик] = Поле.Value;



            КонецЦикла;



        Иначе



            Для каждого КлючИЗначение Из СтруктураКолонок Цикл



                Поле = RS.Fields.Item(КлючИЗначение.Значение - 1);

                НоваяСтрока[КлючИЗначение.Ключ] = Поле.Value;



            КонецЦикла;



        КонецЕсли;



        // Обработка других полей

        RS.MoveNext();



    КонецЦикла;



    // Завершение работы



    RS.Close();

    Connection.Close();



    Возврат Таблица;



КонецФункции



// Функция получает данные из файла Excel

//

// Параметры:

//   пФайл     - Имя файла

//   пЛист     - Имя листа с данными

//   СтруктураКолонок - Структура вида "ИмяКолонки" - "НомерКолонки"

//                      если не задано, созадуться колонки вида "К1", "К2"

//   XLSОбъект - COM объект типа "Excel.Application"

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция Excel_ПолучитьДанные_COM(пФайл, пЛист, СтруктураКолонок = Неопределено, Знач НачСтрока = 0, Знач КонСтрока = 0, XLSОбъект = Неопределено) Экспорт



    #Если Клиент Тогда

    Состояние("Открытие Excel");

    #КонецЕсли



    Если XLSОбъект = Неопределено Тогда

        XLSОбъект = Новый COMОбъект("Excel.Application");

        XLSОбъект.Visible       = Ложь;

        XLSОбъект.DisplayAlerts = Ложь;

    КонецЕсли;



    Попытка

        Book = XLSОбъект.Workbooks.Open(пФайл, , Истина);

    Исключение

        Сообщить ("Проблемы с подключением к Excel" );

        Возврат Неопределено;

    КонецПопытки;



    Лист = Book.Sheets(1);

    КолвоКолонок = Лист.Cells(1,1).SpecialCells(11).Column;

    КолвоСтрок   = Лист.Cells(1,1).SpecialCells(11).Row;



    Таблица = Новый ТаблицаЗначений;



    Если СтруктураКолонок = Неопределено Тогда



        Для Счетчик = 1 По КолвоКолонок Цикл

            Колонка = Таблица.Колонки.Добавить("К" + Счетчик);

        КонецЦикла;



    Иначе



        Для каждого КлючИЗначение Из СтруктураКолонок Цикл

            Колонка = Таблица.Колонки.Добавить(КлючИЗначение.Ключ);

        КонецЦикла;



    КонецЕсли;



    НачСтрока = ?(НачСтрока = 0, 1, НачСтрока);

    КонСтрока = ?(КонСтрока = 0, КолвоСтрок, КонСтрока);

    КонСтрока = Мин(КонСтрока, КолвоСтрок);



    Для НомерСтроки = НачСтрока По КонСтрока Цикл



        #Если Клиент Тогда

        Состояние("Чтение файла: " + Формат(НомерСтроки) + " из " + Формат(КонСтрока));

        ОбработкаПрерыванияПользователя();

        #КонецЕсли



        НоваяСтрока = Таблица.Добавить();



        Если СтруктураКолонок = Неопределено Тогда



            Для НомерКолонки = 1 По КолвоКолонок Цикл



                Поле = Лист.Cells(НомерСтроки, НомерКолонки);

                НоваяСтрока["К" + Формат(НомерКолонки, "ЧГ=0")] = Поле.Value;



            КонецЦикла;



        Иначе



            Для каждого КлючИЗначение Из СтруктураКолонок Цикл



                Поле = Лист.Cells(НомерСтроки, КлючИЗначение.Значение);

                НоваяСтрока[КлючИЗначение.Ключ] = Поле.Value;



            КонецЦикла;



        КонецЕсли;



    КонецЦикла;



    XLSОбъект.Application.Quit();

    Возврат Таблица;



КонецФункции



// Функция получает данные из файла Excel

//

// Параметры:

//   пФайл     - Имя файла

//   пЛист     - Имя листа с данными

//   СтруктураКолонок - Структура вида "ИмяКолонки" - "НомерКолонки"

//                      если не задано, созадуться колонки вида "К1", "К2"

//   XLSОбъект - COM объект типа "Excel.Application"

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция Excel_ПолучитьДанные_COMArray(пФайл, пЛист, СтруктураКолонок = Неопределено, Знач НачСтрока = 0, Знач КонСтрока = 0, XLSОбъект = Неопределено) Экспорт



    #Если Клиент Тогда

    Состояние("Открытие Excel");

    #КонецЕсли



    Если XLSОбъект = Неопределено Тогда

        XLSОбъект = Новый COMОбъект("Excel.Application");

        XLSОбъект.Visible       = Ложь;

        XLSОбъект.DisplayAlerts = Ложь;

    КонецЕсли;



    Попытка

        Book = XLSОбъект.Workbooks.Open(пФайл, , Истина);

    Исключение

        Сообщить ("Проблемы с подключением к Excel" );

        Возврат Неопределено;

    КонецПопытки;



    Лист = Book.Sheets(1);

    КолвоКолонок = Лист.Cells(1,1).SpecialCells(11).Column;

    КолвоСтрок   = Лист.Cells(1,1).SpecialCells(11).Row;



    Таблица = Новый ТаблицаЗначений;



    Если СтруктураКолонок = Неопределено Тогда



        Для Счетчик = 1 По КолвоКолонок Цикл

            Колонка = Таблица.Колонки.Добавить("К" + Счетчик);

        КонецЦикла;



    Иначе



        МаксимальныйНомерКолонки = 0;

        Для каждого КлючИЗначение Из СтруктураКолонок Цикл

            Колонка = Таблица.Колонки.Добавить(КлючИЗначение.Ключ);

            МаксимальныйНомерКолонки = Макс(МаксимальныйНомерКолонки, КлючИЗначение.Значение);

        КонецЦикла;



        КолвоКолонок = Мин(КолвоКолонок, МаксимальныйНомерКолонки);



    КонецЕсли;



    НачСтрока = ?(НачСтрока = 0, 1, НачСтрока);

    КонСтрока = ?(КонСтрока = 0, КолвоСтрок, КонСтрока);

    КонСтрока = Мин(КонСтрока, КолвоСтрок);



    // Массив типа COMSafeArray

    Массив = Лист.Range(Лист.Cells(НачСтрока, 1), Лист.Cells(КонСтрока, КолвоКолонок)).Value;

    КолвоСтрок   = Массив.GetUpperBound(1);



    Для НомерСтроки = 1 По КолвоСтрок Цикл



        #Если Клиент Тогда

        Состояние("Чтение файла: " + Формат(НомерСтроки) + " из " + Формат(КолвоСтрок));

        ОбработкаПрерыванияПользователя();

        #КонецЕсли



        НоваяСтрока = Таблица.Добавить();



        Если СтруктураКолонок = Неопределено Тогда



            Для НомерКолонки = 1 По КолвоКолонок Цикл



                НоваяСтрока["К" + Формат(НомерКолонки, "ЧГ=0")] = Массив.GetValue(НомерКолонки, НомерСтроки);



            КонецЦикла;



        Иначе



            Для каждого КлючИЗначение Из СтруктураКолонок Цикл



                НоваяСтрока[КлючИЗначение.Ключ] = Массив.GetValue(КлючИЗначение.Значение, НомерСтроки);



            КонецЦикла;



        КонецЕсли;



    КонецЦикла;



    XLSОбъект.Application.Quit();

    Возврат Таблица;



КонецФункции



// Функция получает список листов Excel

//

// Параметры:

//   пФайл - Имя файла

//   XLSОбъект - COM объект типа "Excel.Application"

//

// Возвращаемое значение:

//   СписокЗначений

//

Функция Excel_ПолучитьСписокЛистов(пФайл, XLSОбъект = Неопределено) Экспорт



    Если XLSОбъект = Неопределено Тогда

        XLSОбъект = Новый COMОбъект("Excel.Application");

        XLSОбъект.Visible       = Ложь;

        XLSОбъект.DisplayAlerts = Ложь;

    КонецЕсли;



    Попытка

        Book = XLSОбъект.Workbooks.Open(пФайл, , Истина);

    Исключение

        Возврат Новый СписокЗначений;

    КонецПопытки;



    СписокЛистов = Новый СписокЗначений;

    Для каждого Лист Из XLSОбъект.Sheets Цикл

        СписокЛистов.Добавить(Лист.Name);

    КонецЦикла;



    XLSОбъект.Application.Quit();

    Возврат СписокЛистов;



КонецФункции

Код 1C v 7.x

 Попытка

  Excel = СоздатьОбъект("Excel.Application");

 Исключение

  Сообщить(ОписаниеОшибки()+"; программа Excel не установлена на данном компьютере!");

     Возврат;

 КонецПопытки;

РабочиеКниги=Excel.WorkBooks;  // создаем рабочую книгу



 Попытка // открываем файл

  Отчет=РабочиеКниги.Open(Каталог+ИмяФайла); 

 Исключение 

  Сообщить(ОписаниеОшибки()+"; фаил с макросом не найден!");

  Возврат;

 КонецПопытки;



// заносим в таблицу какие-либо данные



 Лист = Отчет.Worksheets(1);



 Для Ном=1 По 20 Цикл

      Ячейка = Лист .Cells(ном,1); Ячейка.Value;

      Сообщить(Ячейка );

 КонецЦикла; 



Excel.Visible=1;



Попытка

      Отчет.Save();

Исключение

     Сообщить(ОписаниеОшибки()+"; не могу сохранить отчет!");

  Возврат;

 КонецПопытки;

Категория: Работа с Microsoft Office и OpenOffice