текзапись » Поиск

Результаты по ключевому слову: текзапись

Событие ПередЗаписью регистра сведений. Как перед записью изменить значение реквизита записи?

Событие ПередЗаписью возникает перед выполнением записи набора регистра сведений. Процедура-обработчик вызывается после начала транзакции записи, но до начала записи набора регистра сведений.

Пример проверки на условие и заполнение реквизита Цвет:

Код 1C v 8.х

 Процедура ПередЗаписью(Отказ, Замещение)

	Для Каждого ТекЗапись Из ЭтотОбъект Цикл

		Если ТекЗапись.СерияНоменклатуры.Восстановленный Тогда 

			ТекЗапись.Цвет="2551650";	

		Иначе

			ТекЗапись.Цвет="";

		КонецЕсли;

	КонецЦикла;	

КонецПроцедуры

Ниже приведен пример процедуры ПередЗаписью для регистра сведений «Курсы», который содержит курсы валют по периодам. При попытке ввести или изменить курс валюты период которого раньше даты регистрации фирмы будет выведено два сообщения:

Код 1C v 8.2 УП

 Процедура ПередЗаписью (Отказ, Замещение)

            ДатаРегистрации = Константы.ДатаРегистрации.Получить ();

            Для Каждого ТекЗапись Из ЭтотОбъект Цикл

             

                        Если ТекЗапись.Период < ДатаРегистрации Тогда

// Если период раньше даты регистрации

            Отказ = Истина; // отказ от записи

                        Сообщить(" Запись от " + ТекЗапись.Период +

                                               " с курсом " + ТекЗапись.Курс +

                                               " раньше даты регистрации фирмы!");

                        КонецЕсли;

            КонецЦикла;

             

    Если Отказ Тогда

            Сообщить ("Запись не выполнена!");

            КонецЕсли;

КонецПроцедуры

Категория: Регистры сведений

Как изменить запись регистра сведений?

Код 1C v 8.х

 НаборЗаписей = РегистрыСведений.НумерацияДоговоров.СоздатьНаборЗаписей();  			

			НаборЗаписей.Отбор.Период.Установить(НачалоГода(Дата));

			НаборЗаписей.Отбор.Организация.Установить(Организация);

			НаборЗаписей.Прочитать();

			Если НаборЗаписей.Количество() = 0 Тогда

				НовыйНомер = НаборЗаписей.Добавить();

				НовыйНомер.Организация = Организация;

				НовыйНомер.Период = НачалоГода(Дата);

				НовыйНомер.Номер = 2; ном=1;

			ИначеЕсли НаборЗаписей.Количество() = 1 Тогда

				НовыйНомер = НаборЗаписей[0];

				ном = НовыйНомер.Номер;

				НовыйНомер.Номер = ном+1;

			КонецЕсли;

			НаборЗаписей.Записать();

			Номер = Организация.Префикс +  "-" + Ном + "/" + Строка(Прав(Год(ТекущаяДата()),2));

Код 1C v 8.х

 //Установить курс Валюты USD

КурсыВалют = РегистрыСведений.КурсыВалют;

НаборКурсов = КурсыВалют.СоздатьНаборЗаписей();

Доллар = Справочники.Валюты.НайтиПоНаименованию("USD");

НаборКурсов.Отбор.Валюта.Установить(Доллар);

НаборКурсов.Отбор.Период.Установить(НачалоДня(ТекущаяДата()));

НаборКурсов.Прочитать();

Если НаборКурсов.Количество() = 0 Тогда

    НовыйКурс = НаборКурсов.Добавить();

    НовыйКурс.Валюта = Доллар;

    НовыйКурс.Период = ТекущаяДата();

ИначеЕсли НаборКурсов.Количество() = 1 Тогда

    НовыйКурс = НаборКурсов[0];

Иначе

    Предупреждение("Курс валюты задается один раз в день.", 60);

    Возврат;

КонецЕсли;

НовыйКурс.Курс = 31.44;

НовыйКурс.Кратность = 1;

НаборКурсов.Записать();

Код 1C v 8.х

  //В регистр были ошибочно записаны штрихкоды. 

// Нужно по заданным Номенклатуре (Товар) и Характеристике (ХарактеристикаТовара) найти эту запись и заменить там штрихкод.

  Запрос = Новый Запрос;

    Запрос.Текст = 

    "ВЫБРАТЬ

    |    ШтрихкодыНоменклатуры.Штрихкод КАК Штрихкод

    |ИЗ

    |    РегистрСведений.ШтрихкодыНоменклатуры КАК ШтрихкодыНоменклатуры

    |ГДЕ

    |    ШтрихкодыНоменклатуры.Номенклатура = &Номенклатура И

    |    ШтрихкодыНоменклатуры.Характеристика = &Характеристика";

    

    Запрос.УстановитьПараметр("Номенклатура", Товар);

    Запрос.УстановитьПараметр("Характеристика", ХарактеристикаТовара);



    Выборка = Запрос.Выполнить().Выбрать();

        Если НЕ Выборка.Следующий() Тогда

        ТекЗапись = РегистрыСведений.ШтрихкодыНоменклатуры.СоздатьМенеджерЗаписи();

        ТекЗапись.Номенклатура = Товар;

        Если ЗначениеЗаполнено(ХарактеристикаТовара) Тогда

             ТекЗапись.Характеристика = ХарактеристикаТовара;

        Иначе    

             ТекЗапись.Характеристика = Справочники.ХарактеристикиНоменклатуры.ПустаяСсылка();

        КонецЕсли;

        ТекЗапись.Штрихкод  = ?(ПустаяСтрока(ШтрихКод),РегистрыСведений.ШтрихкодыНоменклатуры.СформироватьШтрихкодEAN13(), Штрихкод);

        Попытка

            ТекЗапись.Записать();

        Исключение

        КонецПопытки;

    Иначе

        НайденныйШтрихкод = Выборка.Штрихкод;

         ТекЗапись = РегистрыСведений.ШтрихкодыНоменклатуры.СоздатьМенеджерЗаписи();

        ТекЗапись.Штрихкод = НайденныйШтрихкод;

        ТекЗапись.Прочитать();

        

        ТекЗапись.Штрихкод  = Штрихкод;

        Попытка

            ТекЗапись.Записать();

        Исключение

        КонецПопытки;



    КонецЕсли;

Категория: Регистры сведений

Как заменить значение ресурса регистра сведений – универсальная процедура

В том случае, когда в каком-то регистре сведений нужно заменить несколько видов значений какого-то конкретного ресурса на заданное значение, лучше использовать вот такую универсальную процедуру (при ее вызове достаточно подставить название регистра, название ресурса и передать старые заменяемые значения и новое, на которое они заменяются):

Код 1C v 8.х

 // Процедура выполняет в независимом регистре сведений "ИмяРегистраСведений" замену 

// всех значений ресурса "ИмяИзменяемогоРесурса", // соответствующих массиву "МассивСтарыхЗначенийРесурса"

// на новое значение ресурса "НовоеЗначениеРесурса".

// В запрос можно передать дополнительное условие, ограничивающее выборку данных из регистра "ДопУсловие"

Процедура ЗаменаРесурсаНезависимогоРегистра(ИмяРегистраСведений, ИмяИзменяемогоРесурса, МассивСтарыхЗначенийРесурса, НовоеЗначениеРесурса, ДопУсловие = "")

	Запрос = Новый Запрос;

	Запрос.УстановитьПараметр("МассивСтарыхЗначенийИзмерения",	МассивСтарыхЗначенийРесурса);

	Запрос.УстановитьПараметр("НовоеЗначениеИзмерения",			НовоеЗначениеРесурса);



	// Подготовим таблицу значений для позиционирования (установки отбора) на нужных записях регистра:

	Запрос.Текст =

	"ВЫБРАТЬ *

	|ИЗ

	|	РегистрСведений." + ИмяРегистраСведений + " КАК Регистр

	|ГДЕ

	|	Регистр." + ИмяИзменяемогоРесурса + " В (&МассивСтарыхЗначенийИзмерения)" + ДопУсловие;



	Сообщить("1 Приступаем к выполнению запроса к данным регистра """ + ИмяРегистраСведений + """ - " + ТекущаяДата());



	ТаблицаЗаполнения = Запрос.Выполнить().Выгрузить();



	Сообщить("2 Приступаем к обработке результата запроса к регистру """ + ИмяРегистраСведений + """ - " + ТекущаяДата());



	// заполнение строки progress bar

	ЭлементыФормы.Индикатор2.Значение = 0; // обнуляем, чтобы при повторном запуске статусбар сбросился в 0

	ЭлементыФормы.Индикатор2.МаксимальноеЗначение = ТаблицаЗаполнения.Количество(); // задаем значение для 100%



	// для каждой строки таблицы значений установим отбор и перезапишем регистр

	Для Каждого СтрокаЗаполнения Из ТаблицаЗаполнения Цикл



		ЭлементыФормы.Индикатор2.Значение = ЭлементыФормы.Индикатор2.Значение + 1; //указываем прирост внутри цикла



		// попробуем через СоздатьМенеджерЗаписи()

		текЗапись = РегистрыСведений[ИмяРегистраСведений].СоздатьМенеджерЗаписи();



		ЗаполнитьЗначенияСвойств(текЗапись, СтрокаЗаполнения);



		// прочитаем эту запись (внимание, эта команда обязательна, иначе можно ненароком очистить весь регистр!)

		текЗапись.Прочитать();



		Если текЗапись.Выбран() Тогда // убедились, что спозиционироваться удалось

			// сообщаем, что именно и на какое значение нужно изменить в регистре

			текЗапись[ИмяИзменяемогоРесурса] = НовоеЗначениеРесурса;



			// записываем изменения в регистре

			текЗапись.Записать();



		Иначе // спозиционироваться не удалось, можно выходить

			Сообщить("Возникла проблема определения " + НовоеЗначениеРесурса + " в регистре через менеджер записи " + НовоеЗначениеРесурса);

		КонецЕсли;



	КонецЦикла;

	Сообщить("3 Окончание исправления  регистра """ + ИмяРегистраСведений + """ - " + ТекущаяДата());

КонецПроцедуры // ЗаменаИзмеренияНезависимогоРегистра()

Категория: Регистры сведений

Управляемый режим блокировки данных

Вопрос: Как использовать управляемый режим блокировки данных?
Ответ: Рассмотрим на примере удаления записей из регистра сведений.
1. В свойствах объекта, для которого используется управляемый режим блокировки данных установить поле «Режим управления блокировкой данных» в значение «Управляемый» (иначе будет сообщение об ошибке «Автоматический режим блокировки недопустим в этой транзакции»). Причем если это делается для документа, то необходимо перевести в этот же режим блокировки все регистры, в которых делает движения этот документ.
2. Пример кода управляемой блокировки регистра при удалении из него записи:
Например:

Код 1C v 8.х

 Процедура ОчиститьЗаПериод()

	Пока Истина Цикл

		НачатьТранзакцию(РежимУправленияБлокировкойДанных.Управляемый);

		Попытка

			текЗапрос = новый Запрос;

			текЗапрос.Текст = 



			"ВЫБРАТЬ

			|	усИсторияОстатковПоПоказателям.Склад,

			|	усИсторияОстатковПоПоказателям.Поклажедатель,

			|	усИсторияОстатковПоПоказателям.Показатель,

			|	усИсторияОстатковПоПоказателям.Период

			|ИЗ

			|	РегистрСведений.усИсторияОстатковПоПоказателям КАК усИсторияОстатковПоПоказателям

			|ГДЕ

			|	усИсторияОстатковПоПоказателям.Период МЕЖДУ &ПериодС И &ПериодПо";



			текЗапрос.УстановитьПараметр("ПериодС", ГраницаОчисткиС);

			текЗапрос.УстановитьПараметр("ПериодПо", ГраницаОчисткиПо);

			тбзЗаписиЖурнала = текЗапрос.Выполнить().Выгрузить();



			// Блокировка данных

			текБлокировка = Новый БлокировкаДанных;

			тбдЖурнал = текБлокировка.Добавить("РегистрСведений.усИсторияОстатковПоПоказателям");

			тбдЖурнал.Режим = РежимБлокировкиДанных.Исключительный;

			Если тбзЗаписиЖурнала.Количество() тогда

				тбдЖурнал.ИсточникДанных = тбзЗаписиЖурнала;

				тбдЖурнал.ИспользоватьИзИсточникаДанных("Склад", "Склад");

				тбдЖурнал.ИспользоватьИзИсточникаДанных("Поклажедатель", "Поклажедатель");

				тбдЖурнал.ИспользоватьИзИсточникаДанных("Показатель", "Показатель");



				// Заблокировать

				текБлокировка.Заблокировать();



				Для каждого текЗаписьЖурнала из тбзЗаписиЖурнала цикл

					текЗапись = РегистрыСведений.усИсторияОстатковПоПоказателям.СоздатьМенеджерЗаписи();

					ЗаполнитьЗначенияСвойств(текЗапись, текЗаписьЖурнала);

					текЗапись.Удалить();

				КонецЦикла;



			КонецЕсли;



			ЗафиксироватьТранзакцию();

			Прервать;



		Исключение // сообщим об ошибке

			стрОписаниеОшибки = ОписаниеОшибки();

			ОтменитьТранзакцию();

			Сообщить("Ошибка блокировки" + ОписаниеОшибки());

			Прервать;

		КонецПопытки;

	КонецЦикла;

КонецПроцедуры // ОчиститьЗаПериод()

Источник

Категория: Встроенные Функции

ДБФ, работа с Индекс, Ключ

Код 1C v 8.х

 ФайлНаДиске = Новый Файл(ИмяФайла);

Если НЕ(ФайлНаДиске.Существует()) Тогда

      Предупреждение("Файл с таким именем не существует " + ИмяФайла);

      Возврат;

КонецЕсли;



ДБФ = Новый xBase;

ДБФ.Кодировка  = КодировкаXBase.OEM;

ДБФ.ОткрытьФайл(ИмяФайла);

Если ДБФ.Открыта() = 0 Тогда

      Предупреждение("Неудалось открыть файл. Возможно он занят другим приложением!");

      Возврат;

КонецЕсли;

     

ДБФ.Индексы.Добавить("IDX_vE","VAL(EXTENSION)",Ложь,Ложь,"PREFLEN1>0");

ДБФ.СоздатьИндексныйФайл(ИмяИндекса);

ДБФ.ТекущийИндекс = ДБФ.Индексы.IDX_vE;



ДБФ.Ключ.EXTENSION = "1002";

Если ДБФ.НайтиПоКлючу("=") = Истина Тогда

      ТекЗапись=ДБФ.НомерЗаписи();

      Пока СокрЛП(ДБФ.EXTENSION) = "1002" Цикл

            Сообщить("-" + ДБФ.EXTENSION + " - " + ДБФ.НомерЗаписи() + "-");

            ДБФ.Следующая();

      КонецЦикла;

Иначе

      Сообщить("Нет записи!");

КонецЕсли;



ДБФ.ЗакрытьФайл();

УдалитьФайлы(ИмяИндекса);

Код 1C v 8.х

 // Перекачка справочника "Подразделение" в DBF-файле

   

   ФайлБД=КаталогИмя+"Spr_podr.";   // Название файла без расширения

   xБД=Новый Файл(ФайлБД+"dbf");   // Создание объекта файла в среде 1С

   

   // Удалить, если файлы уже есть (в том числе и индексный файл)

   Если xБД.Существует() Тогда

      УдалитьФайлы(ФайлБД,"*");

   КонецЕсли;

   

   // Создание файлов

   xБД = Новый XBase; // создание объекта файла формата xBase

   // добавим поля

   xБД.Поля.Добавить("Id", "S", 5);

   xБД.Поля.Добавить("Name", "S", 25);

   xБД.СоздатьФайл(ФайлБД+"dbf"); // создадим реальный файл из объекта

   // Индексное выражение

   ИндВр="Id";

   xБД.индексы.Добавить("Id",ИндВр,Истина);

   ИБД = xБД.СоздатьИндексныйФайл(ФайлБД+"cdx"); // создание индексного файла

   xБД.АвтоСохранение=Истина;

   xБД.ЗакрытьФайл();

   

   // Выкачка данных

   xБД.ОткрытьФайл(ФайлБД+"dbf",ФайлБД+"cdx");

   xБД.ТекущийИндекс = xБД.индексы.Id;

   Выборка=Справочники.Подразделения.Выбрать();

   Пока Выборка.Следующий() Цикл

      xБД.Добавить();

      xБД.ID=Выборка.Код;

      xБД.Name=Выборка.Наименование;

      xБД.Записать();

   КонецЦикла;

   xБД.ЗакрытьФайл();

   

   // проверка работы индекса

   xБД.ОткрытьФайл(ФайлБД+"dbf",ФайлБД+"cdx");

   xБД.ТекущийИндекс = xБД.индексы.Id;

   Если xБД.Найти("00003",">=") Тогда

      Сообщить(xБД.ID+" - "+xБД.NAME);

      Пока xБД.Следующая() Цикл

         Сообщить(xБД.ID+" - "+xБД.NAME);

      КонецЦикла;

   КонецЕсли;      

   xБД.ЗакрытьФайл();

Категория: JSON, XML, TXT, CSV, DBF