// Выводит данные ДереваЗначений в ТекстовыйДокумент, пригодный к рассмотрению в отладчике, окне сообщений и показу.

//

// Параметры:

//    рВетка - дерево значений, подлежащее выводу. Может иметь почти любую глубину иерархии, количество и тип колонок. Если хватит

//        объявленных позиционных строк-заполнителей, всё поместится. Если иерархия слишком глубока, строки просто надо нарастить;

//    рТекст - на входе должен быть равен Неопределено; на выходе по окончании работы содержит результатный текстовый документ;

//    рПараметры - структура дополнительных настроек, допустимые ключи:

//        Колонки - структура колонок, которые подлежат выводу. Если пуста или имеет тип, отличный от структуры, выводятся все колонки;

//           если в ключах структуры указаны имена колонок, будут выведены только они. В значениях структуры можно передать строковое

//           представление формата, согласно которому должны будут форматироваться выводимые значения. По умолчанию формата нет;

//        ПоказыватьУровни - булево, управляет выводом №№ уровней (метод Уровень()), по умолчанию выключено;

//        ШагОтступа - число, определяющее шаг в символах, используемый для показа псевдографики иерархии веток в дереве.

//

&НаСервереБезКонтекста

Процедура ВывестиДеревоЗначенийВТекст(Знач рВетка,рТекст,Знач рПараметры=Неопределено)

Попытка

    Если рТекст=Неопределено Тогда // первая итерация, шапочный вызов исходной части

        //---------------------------------------------------------------------------------------------------------------------------

        // Разбираем входные данные

        Если ТипЗнч(рВетка)<>Тип("ДеревоЗначений") Тогда Возврат КонецЕсли;

        Если ТипЗнч(рПараметры)<>Тип("Структура") Тогда рПараметры=Новый Структура КонецЕсли;

        стрКолонок=?(рПараметры.Свойство("Колонки"),рПараметры.Колонки,Неопределено);

        Если ТипЗнч(стрКолонок)<>Тип("Структура") Тогда стрКолонок=Новый Структура КонецЕсли;

        рПоказыватьУровни=?(рПараметры.Свойство("ПоказыватьУровни"),рПараметры.ПоказыватьУровни,Ложь); // затратное дело, кстати

        рШагОтступа=?(рПараметры.Свойство("ШагОтступа"),рПараметры.ШагОтступа,2); // для отображения отступа в колонке иерархии





        //---------------------------------------------------------------------------------------------------------------------------

        // Определяем максимальное количество уровней

        // Также можно получить максимальный уровень, "плоско" перебрав все строки (например, получив их через НайтиСтроки)

        // и в цикле для каждой вызывая Уровень() и определяя максимум.

        // Вариант через СКД и служебное поле "Уровень" ни на одной известной мне платформе не работоспособен (нехватка памяти).

        //

        //

        //рДеревоДляТеста=КакНибудьСкопироватьДерево(рВетка);

        //рДеревоДляТеста.Колонки.Вставить(0,"_Level",Новый ОписаниеТипов("Булево")); // самый экономный вариант, с сохранением иерархии

        //мНенужных=Новый Массив;

        //Для й=1 По рДеревоДляТеста.Колонки.Количество()-1 Цикл

        //  мНенужных.Добавить(рДеревоДляТеста.Колонки[й]);

        //КонецЦикла;

        //Для каждого кол Из мНенужных Цикл

        //  рДеревоДляТеста.Колонки.Удалить(кол);

        //КонецЦикла;

        //

        рДеревоДляТеста=рВетка; // пока сериализуем прямо всё дерево (неоптимально, но...)

        рЗапись=Новый ЗаписьXML;

        рЗапись.УстановитьСтроку();

        СериализаторXDTO.ЗаписатьXML(рЗапись,рДеревоДляТеста);

        стро=рЗапись.Закрыть();

        //

        стро=СтрЗаменить(стро,"xmlns=","xmlns:myns1C="); // иначе не будет работать XPath

        //

        рЧтение=Новый ЧтениеXML;

        рЧтение.УстановитьСтроку(стро);

        постр=Новый ПостроительDOM;

        рДокументДОМ=постр.Прочитать(рЧтение);





        рВыражение="/ValueTree/row"; максКолвоУровней=1;

        рРазыменователь=Новый РазыменовательПространствИменDOM(рДокументДОМ);

        Пока Истина Цикл

            #Если Клиент Тогда

                ОбработкаПрерыванияПользователя();

            #КонецЕсли

            рРезультат=рДокументДОМ.ВычислитьВыражениеXPath(рВыражение,рДокументДОМ,рРазыменователь,ТипРезультатаDOMXPath.Любой);

            Если рРезультат.ПолучитьСледующий()=Неопределено Тогда Прервать КонецЕсли;

            рВыражение=рВыражение+"/row";

            максКолвоУровней=максКолвоУровней+1;

        КонецЦикла;

        максКолвоУровней=максКолвоУровней-1; // можно и так: СтрЧислоВхождений(рВыражение,"/row")-1;





        //---------------------------------------------------------------------------------------------------------------------------

        // готовим исходный макет вывода

        строПробелы="                                                                                                                                                                                                                 ";

        строРазделители="===============================================================================================";

        строОтступы="___________________________________________________________________________________________"; // тут нужны чуть для другого

        //

        секШапка1="|[_HCS"+Лев(строПробелы,максКолвоУровней*рШагОтступа)+"]|"; // HierarchyColumnShow

        секГорРазделитель1="|"+Лев(строОтступы,максКолвоУровней*рШагОтступа+6)+"|"; // здесь именно Отступы!

        рШиринаКолонкиИерархии=СтрДлина(секШапка1)-2;

        строПолейШапки="#Поле _HCS

        |   #Выравнивание Центр";

        строПолейЗаписи="";

        //

        Если рПоказыватьУровни Тогда

            секШапка1=секШапка1+"[_Level]|";

            секГорРазделитель1=секГорРазделитель1+Лев(строРазделители,8)+"|";

            строПолейШапки=строПолейШапки+"

            |#Поле _Level

            |   #Выравнивание Центр";

            строПолейЗаписи="#Поле _Level

            |   #Выравнивание Центр

            |   #Забивать Истина";

        КонецЕсли;

        //

        мИменКолонок=Новый Массив;

        Для каждого кол Из рВетка.Колонки Цикл

            Если стрКолонок.Количество()<>0 и не стрКолонок.Свойство(кол.Имя) Тогда Продолжить КонецЕсли; // чётко указаны конкретные колонки

            рДлинаИмениКолонки=СтрДлина(кол.Имя);

            рНужнаяШирина=Макс(?(кол.Ширина<3,10,кол.Ширина),рДлинаИмениКолонки);

            // к сожалению, ключевое слово "#Поля" неприменимо - платформа падает - поэтому делаем всё сами

            секШапка1=секШапка1+"["+кол.Имя+Лев(строПробелы,рНужнаяШирина-рДлинаИмениКолонки)+"]|";

            секГорРазделитель1=секГорРазделитель1+Лев(строРазделители,рНужнаяШирина+1)+"=|";

            строПолейШапки=строПолейШапки+"

            |#Поле "+кол.Имя+"

            |   #Выравнивание Центр";

            рОписТипов=кол.ТипЗначения;

            Если рОписТипов.Типы().Количество()=1 и рОписТипов.СодержитТип(Тип("Булево")) Тогда

                рВыравнивание="Центр";

            ИначеЕсли рОписТипов.СодержитТип(Тип("Число")) Тогда

                рВыравнивание="Право";

            ИначеЕсли рОписТипов.СодержитТип(Тип("Строка")) и рОписТипов.КвалификаторыСтроки.Длина=0 Тогда

                рВыравнивание="ПоШирине";

            Иначе

                рВыравнивание="Лево";

            КонецЕсли;

            строПолейЗаписи=строПолейЗаписи+?(ПустаяСтрока(строПолейЗаписи),"",Символы.ПС)+"#Поле "+кол.Имя+"

            |   #Выравнивание "+рВыравнивание;

            Попытка

                Если ЗначениеЗаполнено(стрКолонок[кол.Имя]) Тогда // указан формат, уточняющий показ колонки

                    строПолейЗаписи=строПолейЗаписи+"

                    |   #Формат """+СокрЛП(стрКолонок[кол.Имя])+"""";

                КонецЕсли;

            Исключение

            КонецПопытки;

            мИменКолонок.Добавить(кол.Имя);

        КонецЦикла;

        секШапка2=СтрЗаменить(СтрЗаменить(секШапка1,"[","<"),"]",">");

        секЗапись1=секШапка1; секЗапись2=секШапка2; // пусть они по дизайну пока не отличаются

        секГорРазделитель2=СтрЗаменить(СтрЗаменить(секГорРазделитель1,"=","-"),"|","+");

        // обработаем нормальное обрамление шапки колонки иерархии

        секГорРазделитель1=СтрЗаменить(секГорРазделитель1,"_","=");

        секГорРазделитель2=СтрЗаменить(секГорРазделитель2,"_"," ");

        //

        тМакет=Новый ТекстовыйДокумент;

        тМакет.ДобавитьСтроку("#Область Шапка");

        тМакет.ДобавитьСтроку(строПолейШапки);

        тМакет.ДобавитьСтроку(секГорРазделитель1);

        тМакет.ДобавитьСтроку(секШапка1);

        тМакет.ДобавитьСтроку(секШапка2);

        тМакет.ДобавитьСтроку(секГорРазделитель1);

        тМакет.ДобавитьСтроку("#КонецОбласти");

        тМакет.ДобавитьСтроку("");

        тМакет.ДобавитьСтроку("#Область Запись");

        тМакет.ДобавитьСтроку(строПолейЗаписи);

        тМакет.ДобавитьСтроку(секЗапись1);

        тМакет.ДобавитьСтроку(секЗапись2);

        тМакет.ДобавитьСтроку(секГорРазделитель2);

        тМакет.ДобавитьСтроку("#КонецОбласти");

        рПараметры.Вставить("ИсходныйМакет",тМакет); // пусть будет





        //---------------------------------------------------------------------------------------------------------------------------

        // Запускаем вывод в итоговый документ

        рТекст=Новый ТекстовыйДокумент;

        сек=тМакет.ПолучитьОбласть("Шапка");

        сек.Параметры._HCS="Иерархия";

        Для каждого имякол Из мИменКолонок Цикл

            кол=рВетка.Колонки[имякол];

            сек.Параметры[кол.Имя]=?(ПустаяСтрока(кол.Заголовок),кол.Имя,кол.Заголовок);

        КонецЦикла;

        рТекст.Вывести(сек);

        //

        пар=Новый Структура;

        пар.Вставить("МассивИмёнКолонок",мИменКолонок);

        пар.Вставить("ТекущаяСекция",тМакет.ПолучитьОбласть("Запись"));

        пар.Вставить("ШиринаКолонкиИерархии",рШиринаКолонкиИерархии);

        пар.Вставить("ПоказыватьУровни",рПоказыватьУровни);

        пар.Вставить("Отступ",0);

        пар.Вставить("ШагОтступа",рШагОтступа);

        ВывестиДеревоЗначенийВТекст(рВетка,рТекст,пар);





    Иначе

        // очередная итерация, вывод в текстовый документ

        мИменКолонок=рПараметры.МассивИмёнКолонок;

        рСекция=рПараметры.ТекущаяСекция;

        рОтступ=рПараметры.Отступ;

        рШиринаКолонкиИерархии=рПараметры.ШиринаКолонкиИерархии;

        рПоказыватьУровни=рПараметры.ПоказыватьУровни;

        //

        строОтступы="_________________________________________________________________________________________________________";

        строПробелы="                                                                                                                                                                                                                 ";

        //

        пар=Новый Структура;

        пар.Вставить("МассивИмёнКолонок",мИменКолонок);

        пар.Вставить("ТекущаяСекция",рПараметры.ТекущаяСекция);

        пар.Вставить("ШиринаКолонкиИерархии",рШиринаКолонкиИерархии);

        пар.Вставить("ПоказыватьУровни",рПоказыватьУровни);

        пар.Вставить("ШагОтступа",рПараметры.ШагОтступа);

        пар.Вставить("Отступ",рОтступ+рПараметры.ШагОтступа);

        //

        Для каждого рПодветка Из рВетка.Строки Цикл

            рСекция.Параметры._HCS=Лев(строПробелы,рОтступ)+"\"+Лев(строОтступы,рШиринаКолонкиИерархии-рОтступ-1);

            Если рПоказыватьУровни Тогда

                рСекция.Параметры._Level=рПодветка.Уровень();

            КонецЕсли;

            Для каждого имякол Из мИменКолонок Цикл

                рСекция.Параметры[имякол]=рПодветка[имякол];

            КонецЦикла;

            рТекст.Вывести(рСекция);

            ВывестиДеревоЗначенийВТекст(рПодветка,рТекст,пар)

        КонецЦикла;

        //

    КонецЕсли;

Исключение

    Сообщить("ВывестиДеревоЗначенийВТекст, ошибка: "+ОписаниеОшибки(),СтатусСообщения.ОченьВажное);

КонецПопытки;

КонецПроцедуры   

Источник

Нужно сделать РМК (рабочее место кассира) с работающим сканером и другим нужным функционалом.

Порядок действий:

1. Ставим 1с, конфигурацию.

Для начала сделаем пару пользователей, первый он всегда «Админ«, второго назовем «Кассир» и дадим ему полные права (для теста, по хорошему надо настраивать персональные права) .

В конфигураторе (от админа) подправим пользователя «Кассир». Ставим «тип запуска» & «обычное приложение»

Идем дальше, что бы в «Администрировании» появился пункт «Подключаемое оборудование» (иначе как мы его будем настраивать? ) нужно поставить галку на

«Использовать подключаемое оборудование» и «Использовать группы пользователей»

Администрирование & Настройка параметров учета.

Возможности пользователя в РМК настраиваем в Администрировании & Дополнительные права пользователя

2. Настраиваем сканер на эмуляцию com порта, это позволит нам работать в РМК со сканером без лишних заморочек.

Для этого мне потребовалось скачать драйвер Symbol COM Port Emulation Driver v 1.8.5

т.к. проверять уже не охота, а перед установкой драйвера была применена вот эта инструкция:

Настройка_сканеров_Symbol_в_1С прикладываю и ее, в ней показаны штрих кода для программирования сканера на эмуляцию и настройка в 1с сканера.

Ну и в принципе на этом настройка сканера завершена. Теперь в РМК будет перехватывать все сканированные штрихкода.

Все тоже самое только на Windows 7

Сканер установился автоматом. Заставить эмулировать его COM порт я не стал. Сканер работает как клавиатура. Для 1с пришлось настроить сканер что бы он сначала слал F7 (ввод по штриху) + сам штрих + enter.

Прежде чем купить сканер штрих кода обратите особое внимание на то, каким образом будет подключаться сканер к компьютеру.

Несмотря на обилие видов сканеров штрих кода на рынке все они, в конечном счете, подключаются через один из четырех типов коннекторов или интерфейсных портов:

- PS/2 Разрыв клавиатуры – из названия следует что сканер штрих кода подключается в разрыв между компьютером и клавиатурой.

- USB Эмуляция ( фактически подключение через порт usb а настройки как в PS/2)

- RS-232 Последовательный (Com) порт – подключается в Com порт компьютера, однако требует дополнительно блок питания.

- USB Эмуляция ( фактически подключение через порт usb а настройки как в RS-232)

Настройка сканера штрих-кода в программах 1С в разрыв клавиатуры

Настроить сканер штрих-кода 1С, подключаемый в разрыв клавиатуры, совсем не сложная задача. Первое что надо сделать - настроить префикс сканера штрих-кода. По умолчанию сканер штрих-кода, подключаемый в разрыв клавиатуры при сканировании штрих-кода товара он возвращает цифры штрих-кода и символ возврата – это аналогично тому, как если бы вы нажимали после сканирования клавишу ENTER на клавиатуре компьютера. Однако для сканирования штрих – кода товара в программе 1С нажать клавишу F7 - Возврат каретки необходимо. Чтобы постоянно не нажимать F7, нам и поможет добавление специального символа – префикса. Префиксом называется в данном случае некий набор символов, которые сканер отсылает перед отправкой штрих-кода. В качестве префикса в основном используют значение “150” - это ASCII-код клавиши F7. Этот способ подойдет и для USB-сканера в том случае, когда нет возможности установить драйвер эмуляции COM-порта.

Настройка сканера штрих-кода в программах 1С через порт USB.

Программа 1C не видит сканеры штрих-кода подключенные через USB-разъем, зато их прекрасно “видит” операционная система Windows. При первом включении сканера операционная система предложит установить его драйвер, но мы ей этого не позволим и откажемся от автоматической установки, а поставим драйвер вручную. Как правило, драйвер эмуляции COM-порта находится на диске из комплекта поставки сканера штрих-кода, там же есть и специализированные утилиты для настройки свойств самого сканера штрих-кода, такие как: громкость бипера, префикс, суфикс и т.п. Или же имеется специальное руководство пользователя с конфигурационными штрих-кодами, сканируя которые можно определенным образом настроить сканер. В процессе установки этого драйвера, операционная система создает виртуальный COM-порт. Далее нужно произвести конфигурирование порта. После того как настроен сам сканер – переходим к настройке в 1С. Для этого в меню Сервис?Настройки торгового оборудования?Находим закладку Сканеры и переходим в нее и устанавливаем новый сканер штрих-кодов. В качестве обработки обычно используют входящую в поставку стандартную обработку обслуживания «1CScanOPOSScan_v2.epf». Далее заходим в “Параметры” настраиваем COM-порт и параметр Скорость сканера. Сканер штрих-кода настроен!

Настройка сканера штрих кода в программах 1С через COM-порт.

Настройка сканера штрих-кода 1С производим как в предыдущем примере. После того как настроен сам сканер – переходим к настройке в 1С. Для этого в меню Сервис?Настройки торгового оборудования?Находим закладку Сканеры и переходим в нее и устанавливаем новый сканер штрих-кодов. В качестве обработки обычно используют входящую в поставку стандартную обработку обслуживания «1CScanOPOSScan_v2.epf». Далее заходим в “Параметры” настраиваем COM-порт и параметр Скорость сканера. Сканер штрих-кода настроен!

Устанавливал клиенту Розницу 1С и сканер штрихкода Honeywell Voyager 1450. При стандартной настройке - сканер работает в режиме клавиатуры. Но в таком режиме, как известно, работать невыносимо: Приходится перед вводом штрих кода вызывать окно ввода через  Alt+7. Добавление префикса не помогло

Было решено подключить через COM:

1. До подсоединения сканера, установить драйвер «Honeywell Scanning and Mobility (HSM) USB Serial Driver» с страницы (раздел «Программное Обеспечение»). На сайте производителя

2. Подсоединить сканер к USB порту ПК. Дождаться установки устройств.

3. Считать управляющий штрих-код «USB Serial» (TERMID130) из руководства по установке. Вот его скрин:

Должно появиться новое устройство в секции «Порты (COM и LPT)».

В свойствах настройки я переключил на COM4.

В 1С выбираем драйвер 1С Native Api - он подходит и работает. Стандартный COM не подошел, т.к. суффикс NONE нам отсутствует!

В открывшемся окне нажмите кнопки Функции -> Тест устройства

В новом окне нажмите кнопку очистить , а затем сосканируйте любой ШК и в окне появится результат сканирования и будет ясно к какому по номеру СОМ подключен сканер.

Закройте окно Теста устройства и Запишите настройки сканера ШК.

Замечание:В моем случаем поле Суффикс нужно было указать NONE, но бывает что нужно устанавливать (13)CR - зависит от модели сканера.

Все - сканер работает

Для возвращения к режиму USB сосканируйте TRMUSB130 из скрина выше или вот код восстановления стандартных настроек сканера:

И вот случилось долгожданное: Вышел 1C: Enterprise Development Tools - это среда для разработки конфигурации в IDE Eclipse. С сайта 1С:

«1C:Enterprise Development Tools» – это инструмент нового поколения для разработчиков бизнес-приложений системы программ «1С:Предприятие 8». 

Планируется, что он будет использоваться для создания приложений параллельно с текущим инструментом (конфигуратором). При этом формат разрабатываемых приложений будет полностью соответствовать текущим версиям 1С:Предприятия 8. Преимуществами нового инструмента разработки являются: интегрированная среда разработки (соответствие современным тенденциям и требованиям), быстрое развитие инструментов разработки, возможность расширения инструментов разработки. В DT заложена принципиально новая архитектура, которая обеспечивает большой запас развития для реализации различных механизмов автоматизации разработки и повышения удобства разработки. В ознакомительной версии возможности этой архитектуры задействованы только в небольшой части. В данный момент важно реализовать функциональность, аналогичную конфигуратору, но основное предназначение DT в возможности создания новых мощных инструментов для разработчика.

DT разработан с использованием открытой платформы Eclipse (www.eclipse.org). За счет данной интеграции технологий, инструмент объединил в себе преимущества как инструментов разработки «1С:Предприятия», так и стандартных возможностей Eclipse.

Схема работы Конфигуратора

Конфигуратор (входящий в состав системы программ «1С:Предприятие» версии 8.x) работает с конфигурацией, описывающей прикладное решение. Конфигуратор подключается к информационной базе, в которой (во внутреннем формате) хранится конфигурация. В один момент времени конфигуратор может работать только с одной информационной базой, и, как следствие, только с той конфигурацией, которая хранится в этой информационной базе. Более того, для запуска и отладки используется одна версия платформы «1С:Предприятие» – та, с помощью которой выполняется подключение к информационной базе.

Схема работы «1C:Enterprise Development Tools»

DT предлагает принципиально другую схему работы.

Во-первых, конфигурация хранится не в информационной базе, а в файловой системе. Из этого вытекает возможность использования популярной системы контроля версий (git, svn), что, очевидно, является вторым существенным преимуществом. При этом следует понимать, что DT не реализует работу с системой контроля версий самостоятельно, а использует готовые механизмы платформы Eclipse. Поэтому использоваться может только та система контроля версий, поддержка (расширение) которой есть в Eclipse.

Хранение редактируемой конфигурации в файловой системе, а не в информационной базе, означает, что редактирование конфигурации можно выполнять вообще без системы «1С:Предприятие», установленной на компьютере разработчика. Однако, при необходимости запустить прикладное решение или отладить какой-то механизм, наличие установленной версии «1С:Предприятия» является обязательным.

Главные Enterprise Development Tools отличия от обычного Конфигуратора:

1. Платформа Eclipse и возможность написания своих плагинов для удобства работы

2 . Кросплатформенность, т.е наконец-то можно работать на Mac

3. Конфигурация хранится не в информационной базе, а в файловой системе. Из этого вытекает возможность использования популярной системы контроля версий (git, svn)

4. Разрабатываемая конфигурация может использоваться с разными информационными базами и разными версиями «1С:Предприятия»

5. Одновременно можно редактировать несколько конфигураций

6. Работа в DT имеет некоторые отличия в части работы с объектами конфигурации и сохранения результатов работы, т.к. используется платформа Eclipse

7. Более удобная и быстрая командная разработка

Скачиваем и запускаем установку:

1. Сначала платформу 8.3.6

2. потом Enterprise Development Tools

Скачиваем, разархивируем и запускаем DT.exe и получаем ошибку , но это не проблема

Надо установить Java RE, идем на сайт oracle и скачиваем соответствующую вашей операционной системе версию и устанавливаем

иииииии - барабанная дробь вот она, новая среда разработки:

При первом запуске будет запрошен каталог хранения рабочей области. Установка флажка Use this as the default and do not ask again (Использовать это значение по умолчанию в дальнейшем) приведет к тому, что указанный каталог будет автоматически использовать при последующих запусках DT. Для смены рабочей области следует использовать команду File – Switch Workspace (Файл – Сменить рабочую область).

Открылся 1C: Enterprise Development Tools:

Добавление конфигурации

Добавить конфигурации можно по разному, можно загрузить из файла, можно из файлов, можно из git, а можно через импорт существующей базы.

В правом нижнем углу отображены Информационные базы, импортируем одну для теста:

Появляется окно

Если что-то не так, то изменяем и жмем Готово (Кстати, если база открыта в обычном конфигураторе, то вылетит ошибка!)

Идет импорт, спросит пользователя и пароль...

На моем Core i5 с 6 ГБ оперативки, импорт тестовой базы размером 2.5 мегабайта шел чуть больше минуты. И вот с открытым справочником Номенклатура:

Форма

Модуль (подсветка синтаксиса попроще)

Мгновенное определение ошибок (наведя курсор):

Щелкнув по красному крестику - предлагает решение, Создать Элемен  , хотя надо просто дописать букву т

Слева в разделе Схема отражены все функции модуля, можно быстро перемещаться по ним:

Синтаксис-помощник мгновенно показывает информацию по свойству или функции на которой установлен курсор

Еще один интересный раздел, все огрехи в конфигурации:

Схема компоновки данных из отчета:

Так же мгновенно показывает ошибки и недочеты в запросе!

Конструктор запроса выглядит так:

Открыть Перспективу

Отладка -  думаю, понятно и не буду останавливаться

Ресурсы  - показывает разложенную по файлам конфигурацию. Каждый файл можно открыть для просмотра:

Синхронизация совместной работы - допустим через Git

Git - Подключение к Git

Справочная система

Справка , по сути, как и в обычном конфигураторе, только дополненная, выглядит так:

Использование помощника HelpF.pro

Наш помощник пока работает только под Windows, но вскоре мы скомпилируем под Linux и Mac

Открыв код, жмем Alt+H и в появившемся окне вводим запрос (например проверка это новый?) и жмем Найти

В результатах поиска выбираем нужное нам:

Далее в статье (1) выделяем нужный нам код и (2) жмем появившуюся кнопку Вставить

Результат вставки:

Кроме этого работают и горячие клавиши:

Вот пример нажатия Alt+D (Внимание! Alt - правый, левый работает штатно):

Скачать Онлайн помощника 1С

Подведем итоги

В целом новая платформа порадовала и удивила. Подождем когда она выйдет из тестовой версии и будут работать все объекты. 

И наконец-то Eclipse - свои плагины, Git - нормальное хранение версий и командная работа. В общем - 1С идет в ногу со временем и старается для нас!