уникальным » Поиск

Результаты по ключевому слову: уникальным

Передача файлов и данных на веб-сервер из 1С методами GET и POST

При интеграции 1С с веб-сайтами всегда встает вопрос о передачи некоторых данных на веб-сервер. Будь то это передача параметров запроса для получения данных от веб-сервера в 1С или же передача данных из 1С, которые должны быть сохранены или каким-то образом обработаны на веб-сервере. Передаваться могут как простые данные в виде строк, чисел, так и целые файлы (изображения, XML-файлы и прочее). Для передачи и получения файлов и данных на веб-сервер в 1С используется объект HTTPСоединение.

Создание и инициализация HTTP соединения в 1С
Для инициализации HTTP соединения в 1С необходимо создать объект HTTPСоединение и в конструкторе указать параметры HTTP соединения.

Код 1C v 8.х

 Новый HTTPСоединение(<Сервер>, <Порт>, <ИмяПользователя>, <Пароль>, <Прокси>, <ЗащищенноеСоединение>)

<Сервер> (обязательный) - адрес сервера, с которым необходимо установить соединение.
<Порт> (необязательный) - порт сервера, с которым устанавливается соединение.
Значение по умолчанию зависит от защищенности соединения (80 для незащищенного и 443 для SSL-соединения).
<ИмяПользователя> (необязательный) - имя пользователя на указанном сервере.
<Пароль> (необязательный) - пароль пользователя на указанном сервере.
<Прокси> (необязательный). Тип - ИнтернетПрокси. Прокси, используемый для соединения с сервером.
<ЗащищенноеСоединение> (необязательный). Тип - Булево. Определяет используемый протокол -
http или https. По умолчанию Ложь.
Ниже приведен примеры создания HTTPСоединения с сайтом http://www.mysite.ru/.

Код 1C v 8.х

 // соединение с параметрами по умолчанию

Соединение = Новый HTTPСоединение("www.mysite.ru");

 

// сервер использует порт 8080

Соединение = Новый HTTPСоединение("www.mysite.ru", 8080);

 

// сервер использует защищенное соединение (https),

// для подключения к серверу используется прокси

ПроксиСервер = Новый интернетПрокси;

ПроксиСервер.Пользователь = имяПользователя;

ПроксиСервер.Пароль       = парольПользователя;

 

Соединение = Новый HTTPСоединение("www.mysite.ru",,,, ПроксиСервер, Истина);

Передача данных на веб-сервер из 1С методом GET.
Для передачи данных на веб-сервер из 1С методом GET используется процедура Получить() объекта HTTPСоединение.

Код 1C v 8.х

 Получить(<Источник>, <ИмяВыходногоФайла>, <Заголовки>)

<Источник> (обязательный). Тип - Строка. Адрес ресурса на сервере.
<ИмяВыходногоФайла> (обязательный). Тип - Строка. Имя файла на диске, в который
помещаются данные, полученные от сервера (ответ сервера).
<Заголовки> (необязательный). Тип - Строка. Заголовки, добавляемые к запросу на сервер.
Текстовые пары вида <Заголовок>:<Значение>, разделенные комбинацией ВК + ПС.
(подробнее о заголовках будет сказано ниже).
Рассмотрим параметры процедуры Получить() более подробно:

В качестве источника указывается строка с адресом запроса, идущая после названия домена и символа "/". Так, если необходимо отправить данные на адрес https://www.mysite.com/getusers.php, то при создании HTTP соединения в конструкторе HTTPСоединение в поле "Сервер" указывается "www.mysite.com", признак защищенного соединения устанавливается в Истина, а в процедуре Получить() в параметре Источник указывается "getUsers.php".

В поле ИмяВыходногоФайла указывает имя файла на диске, в который будут сохранены данные, полученные от сервере в результате запроса. Так, например, если сервер возвращает список пользователей в формате XML, то на диск в указанный файл будет сохранен XML файл со списком пользователей.

О заголовках более подробно будет сказано ниже.

Так же, при запросе к веб-серверу зачастую передаются дополнительные данные (параметры) для этого запроса. Параметры от адреса источника отделяются символом "?". Каждый параметр задается в формате <Имя_Параметры>=<Значение_Параметры>. Параметры от адреса источника отделяются символом "?". Сами же параметры отделяются друг от друга символом "&". В результате строка адреса источника может выглядеть следующим образом: getUsers.php?owner_id=263544&count=100.

Ниже приведен пример, поясняющий все выше сказанное.

Код 1C v 8.х

 // необходимо выполнить запрос по адресу

// https://www.mysite.com/getUsers.php?owner_id=263544&amp;count=100

// ответ от сервера приходит в виде XML файла

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml");

 

Соединение = Новый HTTPСоединение("www.mysite.com",,,,, Истина);

Соединение.Получить("getUsers.php?owner_id=263544&amp;count=100", имяВыходногоФайла);

 

ЧтениеXML = Новый ЧтениеXML;

ЧтениеXML.ОткрытьФайл(имяВыходногоФайла);

 

Пока ЧтениеXML.Прочитать() Цикл

    // чтение ответа в виде XML файла

    ...

КонецЦикла;

 

ЧтениеXML.Закрыть();

 

// удаляем файл после использования

УдалитьФайлы(имяВыходногоФайла);

Заголовки HTTP
Ниже приведена общая информация о HTTP заголовках из википедии.
Заголовки HTTP (англ. HTTP Headers) — это строки в HTTP-сообщении, содержащие разделённую двоеточием пару имя-значение. Формат заголовков соответствует общему формату заголовков текстовых сетевых сообщений ARPA. Заголовки должны отделяться от тела сообщения хотя бы одной пустой строкой.

Все заголовки разделяются на четыре основных группы:

General Headers (рус. Основные заголовки) — должны включаться в любое сообщение клиента и сервера.
Request Headers (рус. Заголовки запроса) — используются только в запросах клиента.
Response Headers (рус. Заголовки ответа) — только для ответов от сервера.
Entity Headers (рус. Заголовки сущности) — сопровождают каждую сущность сообщения.
Именно в таком порядке рекомендуется посылать заголовки получателю.

Более подробно о заголовках HTTP можно прочитать здесь. Так же можно ознакомится со списком заголовков HTTP.

От себя лишь добавлю, что, если это явно не указано в требованиях к отправке данных веб-серверу заголовки HTTP для метода GET можно не указывать. Для метода POST обычно нужно указать заголовки Content-Type (тип передаваемых данных, например: "Content-Type: text/html;charset=utf-8") и Content-Length (размер передаваемых данных в байтах, например: "Content-Length: 1348").

Напомню, что HTTP заголовки в 1С указываются строкой в виде текстовых пар "<Заголовок>:<Значение>", разделенных комбинацией символов ВК+ПС.
Также заголовки можно задать типом Соответствие, где в качестве ключа указывается заголовок, а в качестве значения - значение заголовка.
Ниже приведены поясняющие примеры:

Код 1C v 8.х

 источник = "owner=263544&amp;count=100";

 

// Передача заголовков строкой

ЗаголовкиHTTP = "Content-Type:text/html;charset=utf-8" + Символ.ВК + Символ.ПС +

            "Content-Length: "+СтрДлина(источник);

Соединение.Получить("", имяВыходногоФайла, ЗаголовкиHTTP);

 

// Вставить символы ВК+ПС можно и таким способом

ЗаголовкиHTTP = "Content-Type:text/html;charset=utf-8

            |Content-Length: 1348";

Соединение.Получить("", имяВыходногоФайла, ЗаголовкиHTTP);

 

// Установка заголовков типом Соответствие

ЗаголовкиHTTP = Новый Соответствие;

ЗаголовкиHTTP.Вставить("Content-Type", "text/html;charset=utf-8");

ЗаголовкиHTTP.Вставить("Content-Length", СтрДлина(источник));

 

Соединение.Получить(источник, имяВыходногоФайла, ЗаголовкиHTTP);

Передача данных на веб-сервер из 1С методом POST.
Общие сведения.
Для передачи данных на веб-сервер из 1С методом POST используется процедура ОтправитьДляОбработки() объекта HTTPСоединение.

Код 1C v 8.х

 ОтправитьДляОбработки(<Источник>, <АдресРесурса>, <ИмяВыходногоФайла>, <Заголовки>)

<Источник> (обязательный) - Имя файла-источника, который будет отправлен
на сервер для обработки.
<АдресРесурса> (обязательный). Тип - строка. Адрес ресурса на сервере,
в который посылаются данные из источника.
<ИмяВыходногФайла> (обязательный) - Имя файла на диске, в который записываются
полученные с сервера данные.
<Заголовки> (необязательный). Тип - строка. Заголовки, добавляемые к запросу на сервер.
Текстовые пары вида <Заголовок>:<Значение>, разделенные комбинацией ВК + ПС.
(подробнее о заголовках будет сказано ниже).
Рассмотрим параметры процедуры ОтправитьДляОбработки() подробнее:

В качестве источника указывается файл, содержимое которого необходимо отправить на сервер для обработки. Подробнее о формировании содержимого файла-источника будет сказано ниже.

Поле АдресРесурса аналогично полю Источник процедуры Получить(), т.е. указывается строка с адресом запроса, идущая после имени домена и символа "/".

Поле ИмяВыходногоФайла также аналогично одноименному полю процедуры Получить(), т.е. содержит имя файла, в котором будут сохранены данные, полученные от сервера в результате обработки исходных данных.

О заголовках было упомянуто выше. Напомню лишь, что для метода POST обычно указываются заголовки Content-Type и Content-Length. В качестве параметра заголовка Content-Length указывается размер файла-источника, преобразованный с помощью функции XMLСтрока().

Ниже приведен пример, поясняющий все выше сказанное.

Код 1C v 8.х

 имяФайлаОтправки = "d:\data\request.txt"; // файл с отсылаемыми для обработки данными

 

// Определим размер файла-источника

// и установим HTTP заголовки

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "text/html;charset=utf-8");

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml");

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "addPost.php", имяВыходногоФайла, Заголовки);

Передача параметров методом POST.
Для передачи параметров, аналогично методу GET, можно сформировать строку параметров, записать их в текстовый файл и отправить этот файл на сервер для обработки. Ниже приведен пример аналогичный примеру отправки методом GET, но теперь те же данные отправляются методом POST.

Код 1C v 8.х

 // сформируем файл для отправки на сервер

 

имяФайлаОтправки = ПолучитьимяВременногоФайла("txt");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаОтправки);

ЗаписьТекста.Записать("owner=263544&amp;count=100");

ЗаписьТекста.Закрыть();

 

// отправим файл на сервер для обработки

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml"); // наш сервер возвращает ответы в виде XML

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "text/html;charset=utf-8");

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "addPost.php", имяВыходногоФайла, Заголовки);

 

// удалим файл отправки - он больше не нужен

Попытка

    УдалитьФайлы(имяФайлаОтправки);

Исключение

КонецПопытки;

 

// обработаем ответ сервера

 

ЧтениеXML = Новый ЧтениеXML;

ЧтениеXML.ОткрытьФайл(имяВыходногоФайла);

 

Пока ЧтениеXML.Прочитать() Цикл

    // чтение ответа в виде XML файла

    ...

КонецЦикла;

 

ЧтениеXML.Закрыть();

 

// удаляем файл после использования

Попытка

    УдалитьФайлы(имяВыходногоФайла); 

Исключение

КонецПопытки;

Передача файлов методом POST.
Зачастую данные для обработки задаются не виде строки параметров разделенных "&", как в рассматриваемых выше примерах, а виде файла определенного формата, например XML или JSON. Рассмотрим пример отправки данных на веб-сервер для обработки методом POST, которые задаются в формате XML. Например, сервер может добавить ваш комментарий к материалу. В описании процедуры добавлении сказано, что данные необходимо отправлять по адресу www.mysite.com/addComment.php. Сами данные должны быть переданы в следующем виде:

Код

<?xml version="1.0" encoding="UTF-8"?>
<request>
<user_id>ID_Пользователя</user_id>
<post_id>ID_Материала</post_id>
<message>Текст_Комментария</message>
</request>

где:
<ID_Пользователя> - id пользователя на сайте, от имени которого добавляется комментарий;
<ID_Материала> - id материала на сайте, к которому добавляется комментарий;
<Текст_Комментария> - текст комментария.

Предположим, что нам уже известны id пользователя и материала и они хранятся в переменных user_id и post_id. Ниже приведен пример, решающий нашу задачу.

Код 1C v 8.х

 // подготовим файл с данными для отправки

имяФайлаОтправки = ПолучитьимяВременногоФайла("xml");

 

ОбъектXML = Новый ЗаписьXML;

ОбъектXML.ОткрытьФайл(имяФайлаОтправки, "UTF-8");

ОбъектXML.ЗаписатьОбъявлениеXML();

ОбъектXML.ЗаписатьБезОбработки(

"<request>

|    <user_id>" + user_id + "</user_id>

|    <post_id>" + post_id + "</post_id>

|    <message>" + ТекстКомментария + "</message>

|</request>");

ОбъектXML.Закрыть();

 

// отправим файл на сервер для обработки

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml"); // наш сервер возвращает ответы в виде XML

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "text/html;charset=utf-8");

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "addComment.php", имяВыходногоФайла, Заголовки);

 

// удалим файл отправки - он больше не нужен

Попытка

    УдалитьФайлы(имяФайлаОтправки);

Исключение

КонецПопытки;

 

// обработаем ответ сервера

 

ЧтениеXML = Новый ЧтениеXML;

ЧтениеXML.ОткрытьФайл(имяВыходногоФайла);

 

Пока ЧтениеXML.Прочитать() Цикл

    // чтение ответа в виде XML файла

    ...

КонецЦикла;

 

ЧтениеXML.Закрыть();

 

// удаляем файл после использования

Попытка

    УдалитьФайлы(имяВыходногоФайла); 

Исключение

КонецПопытки;

Загрузка файлов (изображений, документов и т.п.) на веб-сервер методом POST.
Зачастую возникает необходимость загрузки файлов на веб-сервер. Это может быть, например, изображение к статье на сайте, или фотография для альбома, или архив для файлообменника. Ранее мы рассматривали передачу методом POST параметров или просто файлов. Таким же образом можно и передавать двоичные файлы. Но как быть, если файлы необходимо отправлять вместе с параметрами? Для возможности отправки файлов в этом случае используется HTTP заголовок ContentType:multipart/form-data. Следует заметить, что обычно таким способом передаются файлы через веб-браузеры. Т.е. когда на сайте вы выбираете файл и нажимаете кнопку "Загрузить", то файл передается способом описанным ниже. При таком способе сам файл также задается как переменная, т.е., например, файл передается через параметр file или image. Однако, мы не можем просто передать file=<Двоичные_Данные>. А вот как все таки передать файл мы и рассмотрим ниже.

Для возможности вместе с параметрами передавать и двоичные данные (файлы) необходимо сформировать HTTP заголовок Content-Type следующим образом:
Content-Type: multipart/form-data, boundary=<уникальные_данные>
где <уникальные_данные> - это любой набор цифр и/или символов, который будет служить для отделения значений друг от друга. Значение boundary должно быть уникальным в пределах пересылаемой информации, т.е. таких символов не должно встречаться в пересылаемых файлах и переменных.

Bounday можно сформировать, например, таким образом

Код 1C v 8.х

 boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

Все данные отделяются друг от друга разделителем boundary. Начинать разделитель нужно с "--":

Код

--<boundary>
Content-Disposition: form-data; name="<имя_переменной>"
<пустая_строка>
<значение_переменной>
Для отправки файла необходимо еще добавить тип и имя файла:

--<boundary>
Content-Disposition: form-data; name="<имя_переменной>"; filename="<имя_файла>"
Content-Type: <тип_файла> (например image/jpeg или text/plain)
<пустая_строка>
<данные_файла>

В конце данных нужно закрыть разделитель, добавили в конце разделителя "--", т.е. вид будет "--<boundary>--".

Итак, например, нам нужно передать на веб-сервер текстовый файл через параметр "text", его описание через параметр "desc" и id пользователя через параметр "uid", для которого будет загружен наш файл.

Предположим, что файл содержит следующий текст:
Мороз и солнце; день чудесный!
Еще ты дремлешь, друг прелестный -
Пора, красавица, проснись:
Открой сомкнуты негой взоры
Навстречу северной Авроры,
Звездою севера явись!
Описание должно содержать "Стих А.С. Пушкина", а id пользователя равно "0123456". Тогда файл должен быть сформирован следующим образом (для упрощения предположим, что bounday мы уже сформировали и он равен "ccf8111910")

Код

--ccf8111910
Content-Disposition: form-data; name="uid"

0123456
--ccf8111910
Content-Disposition: form-data; name="desc"

Стих А.С. Пушкина
--ccf8111910
Content-Disposition: form-data; name="text"; filename="stih.txt"
Content-Type: text/plain

Мороз и солнце; день чудесный!
Еще ты дремлешь, друг прелестный -
Пора, красавица, проснись:
Открой сомкнуты негой взоры
Навстречу северной Авроры,
Звездою севера явись!
--ccf8111910--

А теперь перейдем непосредственно к 1С. Пусть у нас будет форма с реквизитами "Пользователь", "Описание" и "ИмяФайла". Реализуем отправку данных, описанным выше способом

Код 1C v 8.х

 // подготовим файл с данными для отправки

имяФайлаОтправки = ПолучитьимяВременногоФайла("txt");

Boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаОтправки);

 

// параметр "uid"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""uid""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(Пользователь);

 

// параметр "desc"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""desc""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(Описание);

 

// параметр "text"

ФайлДляПередачи = Новый ТекстовыйДокумент;

ФайлДляПередачи.Прочитать(имяФайла);

 

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""text""; filename=""stih.txt""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: text/plain");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.Записать(ФайлДляПередачи.ПолучитьТекст());

ЗаписьТекста.ЗаписатьСтроку("");

 

// закроем разделитель

ЗаписьТекста.ЗаписатьСтроку("--"+boundary+"--");

 

ЗаписьТекста.Закрыть();

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

// передадим данные на сервер 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "multipart/form-data, boundary="+boundary);

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "postFile.php", имяВыходногоФайла, Заголовки);

Передача текстовых файлов таким способом проблем не вызывает. Сложнее дело обстоит с файлами, содержащими двоичные данные (изображения, архивы и т.п.). Все дело в том, что в 1С просто нет методов для чтение двоичных файлов в строку. Если мы делаем обмен со своим сайтом, которые сами и разрабатывали, то можно просто преобразовать файл в строку Base64 при помощи процедуры Base64Строка(), а на стороне сервера преобразовать строку Base64 обратно.

Код 1C v 8.х

 // подготовим файл с данными для отправки

имяФайлаДанных = "d:\photo\birthday.jpg";

 

имяФайлаОтправки = ПолучитьимяВременногоФайла("txt");

Boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаОтправки);

 

// параметр "file"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""file""; filename=""photo.jpg""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: image/jpeg");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.Записать(Base64Строка(Новый ДвоичныеДанные(имяФайлаДанных)));

ЗаписьТекста.ЗаписатьСтроку("");

 

// закроем разделитель

ЗаписьТекста.ЗаписатьСтроку("--"+boundary+"--");

 

ЗаписьТекста.Закрыть();

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

// передадим данные на сервер 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "multipart/form-data, boundary="+boundary);

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "uploadFile.php", имяВыходногоФайла, Заголовки);

А как же быть если мы загружаем файл на сторонний сервер, который принимает файл как есть без преобразование его в строку Base64(). В это случае можно пойти на хитрость. В 1С есть процедура ОбъединитьФайлы(), которая объединяет несколько файлов на диске в один результирующий файл

Код 1C v 8.х

 ОбъединитьФайлы(<ИменаЧастей>, <ИмяРезультирующегоФайла>)

<ИменаЧастей> (обязательный). Тип - Массив. Массив имен частей файлов, которые
требуется объединить. Объединение будет происходить в порядке, в котором заданы
имена файлов в массиве.
<ИмяРезультирующегоФайла> (обязательный). Тип - Строка. Имя файла, который будет
создан в результате объединения файлов.
Т.е. мы можем сформировать текстовый файл с запросом, объединить его с файлом(-ами), которые необходимо передать на веб-сервер и передать уже файл, получившийся в результате объединения исходных файлов. Ниже демонстрируется процесс передачи двух zip архивов на сервер с дополнительными параметрами user_id и post_id.

Код 1C v 8.х

 // подготовим файлы с данными для отправки

 

массивФайлов = Новый Массив;

 

Boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

 

имяФайлаСПараметрами = ПолучитьимяВременногоФайла("txt"); // первый файл, содержащий параметры

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаСПараметрами);

 

// параметр "user_id"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""user_id""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(user_id);

 

// параметр "post_id"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""post_id""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(post_id);

 

// начало параметра "file1"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""file1""; filename=""archive1.zip""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: application/x-zip-compressed");

ЗаписьТекста.ЗаписатьСтроку("");

 

ЗаписьТекста.Закрыть(); // заканчиваем работу с файлом 1

 

массивФайлов.Добавить(имяФайлаСПараметрами); // добавляем 1-ый файл для объединения

массивФайлов.Добавить(имяФайлаАрхива1); // добавляем 1-ый архив для объединения

 

// второй файл параметров, содержаший начало параметра "file2"

имяФайлаСПараметрами = ПолучитьимяВременногоФайла("txt");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаСПараметрами);

 

// начало параметра "file2"

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""file2""; filename=""archive2.zip""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: application/x-zip-compressed");

ЗаписьТекста.ЗаписатьСтроку("");

 

ЗаписьТекста.Закрыть(); // заканчиваем работу с файлом 2

 

массивФайлов.Добавить(имяФайлаСПараметрами); // добавляем 2-ой файл для объединения

массивФайлов.Добавить(имяФайлаАрхива2); // добавляем 2-ой архив для объединения

 

ЗаписьТекста.Записать(ФайлДляПередачи.ПолучитьТекст());

ЗаписьТекста.ЗаписатьСтроку("");

 

// третий файл, закрывающий параметры

имяФайлаСПараметрами = ПолучитьимяВременногоФайла("txt");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаСПараметрами);

 

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку("--"+boundary+"--");

 

ЗаписьТекста.Закрыть(); // заканчиваем работу с файлом 3

 

массивФайлов.Добавить(имяФайлаСПараметрами); // добавляем 3-ий файл, закрывающий параметры

 

// результирующий файл, который и будет отправлен

имяФайлаОтправки = ПолучитимяВременногоФайла("out");

 

// объединим все файлы

ОбъединитьФайлы(массивФайлов, имяФайлаОтправки);

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

// передадим данные на сервер 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "multipart/form-data, boundary="+boundary);

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "postFile.php", имяВыходногоФайла, Заголовки);

Ну вот, вроде бы, и все, что я хотел рассказать о способах передачи файлов и данных на веб-сервер из 1С. Если что-то не понятно, что-то хотите уточнить или нашли ошибки - пишите в комментариях.
Автор: Павел

Категория: Работа с Интернет, Почтой (Mail), FTP

Создание и работа с БД MySQL из 1С

Появилась необходимость выложить часть данных из 1С в открытый доступ большому числу пользователей.
Что бы не нарушать условий лицензирования и обеспечить безопасность данных, было принято решение развернуть новую базу на MySQL. Так как особо модерировать ее никто не хочет, пришлось сделать управление MySQL-ной БД из 1С, и начал с создания структуры БД. Итак:
Создаем 2 справочника неирархических, один подчинен другому.
а. Таблицы
б. Колонки

Таблицы - реквизиты:
Автокод - Булево (Определяет необходимость нумеровать запись уникальным кодом, или отдать нумерование на откуп MySQL)
Таблицы - колонки:
ТипДанных - Число (в коде определим тип хранящихся данных по числу)
Длина - Число (длина хранящихся данных)
МожетБытьНоль - булево (может ли хранится пустое значение)
Связь - СсылкаНа таблицу (С которой есть связь все к одному)

Заполняем значениями справочники...

Теперь подключаемся:

Код 1C v 8.х

 Connection = Новый COMОбъект("ADODB.Connection");

СтрокаПодключения =   "DRIVER={MySQL ODBC 5.1 Driver};OPTION=3;DATABASE=" + константы.lk_БД.Получить() + ";PWD=" + константы.lk_Пароль.Получить() + ";PORT=3306;SERVER=" + константы.lk_Сервер.Получить() + ";UID=" + константы.lk_Пользователь.Получить() + ";";

Connection.Open(СокрЛП(СтрокаПодключения));

Сначала удалим таблицы если они есть:

Код 1C v 8.х

     Результат = Новый COMОбъект("ADODB.Command");

    Результат.ActiveConnection = Connection; // работаем через это соединение

    Результат.CommandTimeOut = Connection.CommandTimeOut; // таков тайм-аут

    Результат.CommandType = "adCmdText";

   

    Запрос = Новый Запрос;

    Запрос.Текст = "ВЫБРАТЬ

    |   Таблицы.Наименование КАК Таблица

    |   ИЗ

    |    Справочник.Таблицы КАК Таблицы";

    ВыборкаТаблиц = Запрос.Выполнить().Выбрать();

    Пока ВыборкаТаблиц.Следующий() Цикл

        Результат.CommandText =        " D_rop TABLE IF EXISTS " + ВыборкаТаблиц.Таблица + " ;";

        Результат.Execute();

    КонецЦикла;

Теперь приступим к созданию таблиц БД:

Код 1C v 8.х

  Запрос = Новый Запрос;

    Запрос.Текст = "ВЫБРАТЬ

    |    Таблицы.Наименование КАК Таблица,

    |    Колонки.Наименование КАК Колонка,

    |    Колонки.ТипДанных,

    |    Колонки.Длина,

    |    Колонки.МожетБытьНоль,

    |    Колонки.Связь.Наименование КАК Связь

    |ИЗ

    |    Справочник.Колонки КАК Колонки

    |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.Таблицы КАК Таблицы

    |        ПО Колонки.Владелец = Таблицы.Ссылка

    |

    |ИТОГИ ПО

    |    Таблица";

   

    ВыборкаТаблиц = Запрос.Выполнить().Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);

    Пока ВыборкаТаблиц.Следующий() Цикл

 

        Скрипт =         " CREATE TABLE " + ВыборкаТаблиц.Таблица + " ( " + символ(13) +

        " " + ПолучитьКолонкуID(ВыборкаТаблиц.Таблица) + " int(11) NOT NULL " + ?(Справочники.Lk_Таблицы.НайтиПоНаименованию(ВыборкаТаблиц.Таблица).АвтоКод,"auto_increment","") + "," + символ(13);

       

        Выборка = ВыборкаТаблиц.Выбрать();

        Строчека = "" ;

        Ключики = "";

       

        Пока Выборка.Следующий() цикл

         Строчека = Строчека + "`" + Выборка.Колонка + "` " + ПолучитьПродолжениеСкрипта(Выборка.ТипДанных,Выборка.длина,Выборка.МожетБытьНоль) + "," + символ(13);

           

            ЕСли ЗначениеЗаполнено(Выборка.Связь) Тогда

                Ключики = Ключики + ", KEY `FK_" + ВыборкаТаблиц.Таблица + "-" + Выборка.Колонка + "` (`" + Выборка.Колонка + "`),

                | CONSTRAINT `FK_" + ВыборкаТаблиц.Таблица + "-" + Выборка.Колонка + "` FOREIGN KEY (`" + Выборка.Колонка + "`) REFERENCES `" + Выборка.Связь + "` (`" + ПолучитьКолонкуID(Выборка.Связь) + "`)" + Символ(13)    ;   

            КонецЕсли;               

        КонецЦикла;

       

        Скрипт = Скрипт + Строчека;

        Скрипт = Скрипт + "  PRIMARY KEY  (" + ПолучитьКолонкуID(ВыборкаТаблиц.Таблица) + ") " + символ(13) +  Ключики +

        " ) ENGINE=InnoDB DEFAULT CHARSET=utf8;";

        Сообщить("Таблица создана: " + ВыборкаТаблиц.Таблица);

        Результат.CommandText =        скрипт;

        Результат.Execute();

     КонецЦикла;

    Connection.Close();

И под закуску недостающие функции, использованные в основном тексте:

Код 1C v 8.х

 Функция ПолучитьКолонкуID(зн) экспорт

    ПрефиксКончился = Ложь;

    Колонка = "";

    Для сч = 1 по СтрДлина(зн) Цикл

              Символик = Mid(зн,Сч, 1);

             

          Если ПрефиксКончился Тогда

        Колонка = Колонка + Символик;     

          КонецЕсли;

 

             

              Если Символик = "_" Тогда

                  ПрефиксКончился = Истина;

              КонецЕсли;

             

          КонецЦикла;

          Если Колонка = "" Тогда

              Колонка = зн;

          КонецЕсли;

          Колонка = Колонка + "ID";

          Возврат Колонка;

КонецФункции

Предполагается что название таблиц идут с префиксом например: prefix_NameTable

Код 1C v 8.х

 Функция ПолучитьПродолжениеСкрипта(ТипД,ДлинаД,Ноль) экспорт

   

    Если ТипД = 1 тогда  //строка

     Зн = " varchar(" + Строка(ДлинаД) + ") " + ?(Ноль, "null","NOT NULL");

    ИначеЕсли ТипД = 2 Тогда     //число

     Зн = " int(11) " + ?(Ноль, "null","NOT NULL");

    ИначеЕсли ТипД = 3 Тогда          //смаллчисло

     Зн = " smallint(6) " + ?(Ноль, "null","NOT NULL");

    ИначеЕсли типД = 4 тогда    //текст

     Зн = " text";

    ИначеЕсли ТипД = 5 тогда // дата

     Зн = " date " + ?(Ноль, "null","NOT NULL");

    ИначеЕсли ТипД = 6 Тогда          //смаллчисло

     Зн = " bit(1) " + ?(Ноль, "null","NOT NULL");

 ИначеЕсли ТипД = 7 Тогда // Дата и время

          Зн = " dateTime " + ?(Ноль, "null","NOT NULL");

 КонецЕсли;   

         

    Возврат Зн;

КонецФункции

Источник

Категория: COM-объекты, WMI, WSH

Хранение записей о внешних компонентах в реестре Windows

Зарегистрированная внешняя компонента хранится в реестре следующим образом:
Предположим, что у нас есть внешняя компонента E:\Events\Events.dll.
В 1С мы пишем:

Код 1C v 7.x

 

ЗагрузитьВнешнююКомпоненту("e:\Events\Events.dll");

vk=СоздатьОбъект("Addin.Events");

Теперь зайдем в программу regedit.exe (Пуск-Выполнить-Regedit.exe).

Если регистрация прошла успешно, то в реестре мы увидим следующие записи (я сделал поиск по подстроке "AddIn.Events" в редакторе реестра regedit.exe, нажав сочетание клавиш Ctrl-F):

Код

[HKEY_CLASSES_ROOT\AddIn.Events\Clsid]
@="{2E5E6B2C-EFE0-4872-9AB6-DF187B9CE397}"

[HKEY_CLASSES_ROOT\CLSID\{2E5E6B2C-EFE0-4872-9AB6-DF187B9CE397}]
@="V7 AddIn 2.0"

[HKEY_CLASSES_ROOT\CLSID\{2E5E6B2C-EFE0-4872-9AB6-DF187B9CE397}\InprocServer32]
@="E:\\Events\\Events.dll"

[HKEY_CLASSES_ROOT\CLSID\{2E5E6B2C-EFE0-4872-9AB6-DF187B9CE397}\ProgID]
@="AddIn.Events"

Значение {2E5E6B2C-EFE0-4872-9AB6-DF187B9CE397} является уникальным для каждого OLE-объекта идентификатором (CLSID). Его должен явно задать разработчик в коде внешней компоненты.

Значение ProgID, которое в нашем случае - "AddIn.Events" также задает разработчик внешней компоненты.

Чтобы в реестре появились эти записи, необходимы права доступа:

Начиная с Windows 2000, обычный пользователь не имеет прав доступа к указанным выше ветвям реестра. Нужны права или администратора, или привилегированного пользователя Windows. После первой загрузки компонента пропишет себя в реестре, и ее смогут использовать и непривилегированные пользователи Windows.

Где 1С ищет внешнюю компоненту?

Если при загрузке внешней компоненты вы не указываете полный путь, такой как E:\Events\Events.dll или сетевой путь наподобие \\ВашСервер\ПапкаГдеЛежатВК\Events.dll, то 1С ищет внешние компоненты

-относительно папки 1Cv7\BIN (КаталогПрограммы())
-относительно каталога информационной базы (КаталогИБ())

Метод ЗагрузитьВнешнююКомпоненту(), обнаружив ВК по новому пути, обновляет ее регистрацию в реестре

Это означает, например, что на терминальном сервере программист, который вошел в тестовую базу, где лежит ВК, и потом ее стер, оставит у всех пользователей запись в реестре о несуществующей ВК.
Аналогичная проблема - когда ВК по данному пути недоступна тем или иным пользователям.
А поскольку пользователи не имеют права на изменение записей в реестре, то у них перестанет загружаться и внешняя компонента.

В 1С:Предприятие 8.0 убрана возможность загрузки ВК относительно каталога ИБ.

В 7.7 же, чтобы избежать проблем, всегда убирайте ВК из каталога ИБ, и прописывайте полные пути (или складывайте DLL в общую для всех пользователей папку BIN).

Кардинальное решение проблемы - VKLoader и RegsvrEx

Имеется компонента VKLoader.dll (автор - Александр Орефков), которая позволяет решить проблемы с регистрацией компонент.

http://openconf.1cpp.ru/vk/vkloader/

Цитата:
"vkloader (далее ВК) - внешняя компонента для 1С-Предприятия 7.7, которая может загружаться без ее регистрации в реестре, и загружать другие внешние компоненты без их регистрации. Предназначена для беспроблемной загрузки внешних компонент пользователями, не имеющими прав на запись в HKCR ветку реестра.
Принцип работы основан на перехвате обращения 1С к WinAPI функциям CLSIDFromProgID и CoCreateInstance.
Также ВК решает проблему "зависания" процесса 1С в памяти при закрытии программы при использовании несовсем корректно написанных сторонних внешних компонент".

Пример использования vkloader:

Код 1C v 7.x

 ЗагрузитьВнешнююКомпоненту("vkloader.dll"); //регистрации не требует

Загрузчик = СоздатьОбъект("ЗагрузчикВК");

Результат = Загрузчик.ЗагрузитьВК("Events.dll", "Addin.Events=2E5E6B2C-EFE0-4872-9AB6-DF187B9CE397");

Замечу, что сама vkloader "умеет" загружать себя без прав доступа к реестру.

Еще одно решение: RegsvrEx

Автор - AlexQC.
Регистрирует компоненты (OLE-объекты) в пользовательской ветке реестра.
RegsvrEX

Пример использования:

Код 1C v 7.x

 Попытка

    Объект=СоздатьОбъект("cool.object");

Исключение

    ИмяДЛЛ=КаталогИБ()+"cool.ocx";

    КомандаСистемы(КаталогИБ()+"regsvrex.exe /s /c "+ИмяДЛЛ);

    Попытка

        Объект=СоздатьОбъект("cool.object");

    Исключение

        Сообщить("Ошибка загрузки компоненты: "+ИмяDLL,"!");

    КонецПопытки;

КонецПопытки;

Источник: kb.mista.ru

Категория: Внешние компоненты

Маркировка ключей защиты 1С:Предприятия

Для 1С 8 в настоящий момент используется 4 типа ключей:
title

- Однопользовательский. Это HASP HL Basic. Ключ синего цвета, не имеет внутренней памяти и персонального номера.
title

- Сетевой. HASP HL Net. Ключ красного цвета, имеет персональный номер и внутреннюю память в которой записано количество лицензий.
title

- Ключ на 32х битный сервер 1С:Предприятие. HASP HL Pro.У ключа есть маркировка ENSR8 Ключ фиолетового цвета, с внутренней памятью (фактически не используется) и уникальным идентификатором.
title

- Ключ на 64х битный сервер 1С:Предприятие. HASP HL Max. Ключ зеленого цвета. У ключа есть маркировка EN8SA, при этом данный ключи поддерживает 32-битный сервер (если у клиента есть лицензия на 64-битный сервер, он может, не меняя ключа, использовать также и 32-битную версию). C внутренней памятью (фактически не используется) и уникальным идентификатором.

Разобрались с цветами, попытаемся понять буковки:
В первой строчке ключа его тип и максимальное количество лицензий.
Hasp4 или Н4 - тип ключа.
М1 - локальный с памятью 112 байт
NetXX - сетевой, где ХХ - количество лицензий.
Других 1С пока не использует.
Во второй строчке первые пять знаков - код разработчика (заказчика) ключа.
В приложении к 1С - это назначение ключа.
ORGL8 - пользовательский от восьмерки.
ENSR8 - сервер предприятия восьмерки 32x.
EN8SA - сервер предприятия восьмерки 64x.
Остальные знаки никакого интереса не представляют.

Подробнее:
Серверные ключи:
1С:Предприятие 8.0 (8.1, 8.2) Лицензия на сервер (х32) маркируется "H4 M1 Pro ENSR8" (фиолетовый цвет ключа)
1С:Предприятие 8.0 (8.1, 8.2) Лицензия на сервер (x64) маркируется "H4 M1 Max EN8SA" (зеленый цвет ключа)

Однопользовательские ключи: (синий цвет ключа)
Ключи для всех версий программ маркируются "H4 M1 ORGL8"
Сетевые (многопользовательские) ключи: (красный цвет ключа)

Ключи маркируются в зависимости от числа клиентских лицензий:
Программы группы "1С:Бухгалтерия 8" маркируются "H4 NET5 ORGL8"
Ключи на 5 пользователей маркируются "H4 NET5 ORGL8"
Ключи на 10 пользователей маркируются "H4 NET10 ORGL8"
Ключи на 20 пользователей маркируются "H4 NET20 ORGL8"
Ключи на 50 пользователей маркируются "H4 NET50 ORGL8"
Ключи на 100 пользователей маркируются "H4 NET100 ORGL8"
Ключи на 300 пользователей маркируются "NET250+ ORG8A"
Ключи на 500 пользователей маркируются "NET250+ ORG8B"

Комплекты ключей:
Комплект из 2 ключей "1С:Предприятие 8 Управление производственным предприятием" на 10 пользователй + сервер, а так же комплект из 2 ключей "1С:Предприятие 8 Комплексная автоматизация" на 10 пользователей + сервер, ключи маркируются "H4 NET10 ORGL8" и "H4 M1 ENSR8"
Комплект из 2 ключей "1С:Предприятие 8 Учебный комлект" на 20 пользователей + сервер, ключи маркируются "H4 NET20 ORGL8" и "H4 M1 ENSR8"

Данная система маркировки была введена для удобства идентификации ключа разработчиками и пользователями программного обеспечения.
Для установки однопользовательского и серверного ключей достаточно установить драйвер ключа защиты и вставить ключ защиты в порт.

Для установки многопользовательского ключа защиты требуется определить, какая из машин в сети будет являться сервером. Далее нужно установить на этот компьютер драйвер ключа защиты (HASP4_driver_setup.zip) и службу ключа защиты (HASP_LM_setup.zip), после чего вставить ключ защиты в порт.

Для 1С 7
Сетевые ключи - Красные
Локальные - Серые
+ на ключе шла расшифровка ACC- Бухгалтерия, TRD- Торговля, SAL - Зарплата

Программы однопользовательской группы:
Программы группы "1С:Бухгалтерия 7.7" маркируются "H4 M1 ACCNT"
Программы группы "1С:Зарплата и кадры 7.7" маркируются "H4 M1 QXDXD"
Программы группы "1С:Торговля и склад 7.7" маркируются "H4 M1 WRBQB"
Программы группы "1С:Предприятие 7.7 Комплексная" маркируются "H4 M1 WRBQB"

Программы сетевой (многопользовательской) группы:
Программы группы "1С:Предприятие 7.7 Бухгалтерский учет" маркируются "H4 Net5 ACCNT"
Программы группы "1С:Предприятие 7.7 Зарплата + Кадры" маркируются "H4 Net5 QXDXD"
Программы группы "1С:Предприятие 7.7 Торговля + Склад" маркируются "H4 Net5 WRBQB"
Программы группы "1С:Предприятие 7.7 Комплексная поставка" маркируются "H4 Net5 WRBQB"
Программы группы "1С:Предприятие 7.7 Налогоплательщик" маркируются "H4 Net5 TAXPR"
Программы группы "1С:Предприятие 7.7 Небольшая фирма" маркируются "ACCNT" / "WRBQB" / "QXDXD"
Программы группы "1С:Предприятие 7.7 Управление распределенными информационными базами" маркируются "H4 Net5 DISTR"
Программы группы "1С:Предприятие 7.7 Web-расширение" маркируются "H4 Net5 W31CK"

Категория: Администрирование