установитьтекущийкаталог » Поиск

Результаты по ключевому слову: установитьтекущийкаталог

Фоновые задания: Пример запуска выполнения процедуры / функции на сервере

Как в 1С производится запуск фоновых заданий, каким образом можно получить список заданий при помощи метода "ПолучитьФоновыеЗадания()?

В одном проекте понадобилось запускать выполнение выгрузки на сайт с сервера.

Пользователь на своем клиенте открывает обработку, устанавливает параметры и нажимает выгрузить.

Выгрузка идет не с компьютера клиента, а создается фоновое задание на сервере!

На клиенте в модуле Кнопки Выгрузить:

Код 1C v 8.3

 Процедура КоманднаяПанель1ВыгрузитьНаСайт(Кнопка)

	

	//Выгружается фоновым заданием на серваке

	ПараметрыФоновогоЗадания = Новый Массив;

	ПараметрыФоновогоЗадания.Добавить(Группа); //Группа номенклатуры

	ФоновыеЗадания.Выполнить("МодульРегламентныхЗаданий.ВыгрузкаПрайсаНАФТП",

				ПараметрыФоновогоЗадания, Новый УникальныйИдентификатор, 

				"Выгрузка прайса на сайт"); 	

	ПоказатьОповещениеПользователя("Выгрузка прайса на сайт", ,"Запущено задание выгрузки прайса на сайт, проверьте данные на сайте через 2-3 минуты...", БиблиотекаКартинок.Информация32);

ПараметрыФоновогоЗадания - это переменные функции, они задаются по порядку как определены в вызываемой функции.

На сервере в общем модуле МодульРегламентныхЗаданий:

Код 1C v 8.3

 Процедура ВыгрузкаПрайсаНАФТП(Группа) Экспорт   	

	Запрос = Новый Запрос();

	Запрос.Текст = 

	"ВЫБРАТЬ

	|	ПрайсЛист1СрезПоследних.НоменклатураПрайса,

	|	ПрайсЛист1СрезПоследних.Цена

	|ИЗ

	|	РегистрСведений.ПрайсЛист.СрезПоследних(, Поставщик = ЗНАЧЕНИЕ(Справочник.Контрагенты.ПустаяСсылка)) КАК ПрайсЛист1СрезПоследних

	|ГДЕ

	|	&Условие

	|	И ПрайсЛист1СрезПоследних.НоменклатураПрайса.ИДдляСайта > 0";

	

	Если ЗначениеЗаполнено(Группа) Тогда

		Запрос.Текст = СтрЗаменить(Запрос.Текст, "&Условие", "ПрайсЛист1СрезПоследних.НоменклатураПрайса В ИЕРАРХИИ(&НоменклатураПрайса)")

	Иначе

		Запрос.Текст = СтрЗаменить(Запрос.Текст, "&Условие", "ИСТИНА")

	КонецЕсли;	

	Запрос.УстановитьПараметр("НоменклатураПрайса", Группа);

	Выборка = Запрос.Выполнить().Выбрать();	

	Текст = Новый ТекстовыйДокумент; 	

	Пока Выборка.Следующий() Цикл

		НомПрайса = Выборка.НоменклатураПрайса;

		ЦенаА = Выборка.Цена;

		Цена = Ценообразование.ОкруглитьЦену(ЦенаА * ( 1 + НомПрайса.Наценка20 / 100) + НомПрайса.Надбавка20, НомПрайса.ПорядокОкругления, НомПрайса.ОкруглятьВБольшуюСторону); 		

		Если Цена > 0 Тогда

			Текст.ДобавитьСтроку(""+Формат(НомПрайса.ИДдляСайта, "ЧГ=0")+";"+Формат(Цена, "ЧГ=0"));

		КонецЕсли;

	КонецЦикла;

	

	// запись в текстовый файл

	ПутьКФайлВыгр = "\\FG-1\1c_data\naSite\vigruz.csv";//"D:\!!!For1C!!!\naSite\vigruz.csv";

	Текст.Записать(ПутьКФайлВыгр, "windows-1251");

	КаталогНаSFTPСервере = "/sitetest.ru/public_html/p";	

	Попытка

		ИмяПользователя = "serveruser";

		ПарольПользователя = "password";

		Сервер = "192.253.6.47";

		Порт = "21";  		

		Прокси = Новый ИнтернетПрокси();

		Прокси.Пользователь = ИмяПользователя;

		Прокси.Пароль = ПарольПользователя;

		

		FTPСоединение = Новый FTPСоединение(Сервер,,ИмяПользователя,ПарольПользователя,,Ложь);

		FTPСоединение.УстановитьТекущийКаталог(КаталогНаSFTPСервере);

		//FTPСоединение.ПассивныйРежим(Ложь);

		ТекущийКаталог = FTPСоединение.ТекущийКаталог();

	Исключение

	КонецПопытки;

	FTPСоединение.Записать(ПутьКФайлВыгр,"vigruz.csv"); 

	

	//Вызов PHP скрипта для иморта данных из csv файла на сайт

	НТТР = Новый HTTPСоединение("sitetest.ru");

	ФайлРезультата = ПолучитьИмяВременногоФайла();

	НТТР.Получить("/p/import_price.php", ФайлРезультата);



КонецПроцедуры

Как Получить фоновые задания?

Напишем в процедуре обработки нажания следующий код:

Код 1C v 8.2 УП

 &НаКлиенте

Процедура ПолучитьФоновыеЗадания(Команда)

	ПолучитьФоновыеЗаданияНаСервере();	

КонецПроцедуры

Текст процедуры на сервере:

Код 1C v 8.2 УП

 &НаСервере

Процедура ПолучитьФоновыеЗаданияНаСервере()



	ПараметрыОтбора = Новый Структура("Наименование", "Тестовое задание");	

	СписокФоновыхЗаданий = ФоновыеЗадания.ПолучитьФоновыеЗадания(ПараметрыОтбора);

	

	Для каждого Задание Из СписокФоновыхЗаданий Цикл

		Сообщить(Задание.Наименование);

	КонецЦикла;



КонецПроцедуры // ПолучитьФоновыеЗаданияНаСервере()

В окно сообщений выведутся наименования выполняющихся и выполненных в 1С фоновых заданий с наименованием "Тестовое задание", так как мы сделали отбор именно по этому наименованию.

Категория: Регламентные задания, Фоновые задания

Как Выгрузить файлы и папки из каталога на FTP

Код 1C v 8.2 УП

 

Функция ВыгрузитьФайлыИПапкиНаFTP_Рекурсивно(Соединение, НачальныйКаталогВыгрузкиFTP, НачальнаяПапкаВыгрузкиКомп, ТекущаяПапка=Неопределено)

	Рез = Истина;

	Если ТекущаяПапка = Неопределено Тогда ТекущаяПапка = НачальнаяПапкаВыгрузкиКомп КонецЕсли; 

	МассивФайлов = НайтиФайлы(ТекущаяПапка, "*");

	ТекКаталог = СтрЗаменить(НачальныйКаталогВыгрузкиFTP + СтрЗаменить(СтрЗаменить(ТекущаяПапка, НачальнаяПапкаВыгрузкиКомп, ""), "\", "/"), "//", "/");

	Если Прав(ТекКаталог, 1) <> "/" Тогда

		ТекКаталог = ТекКаталог + "/";

	КонецЕсли;

	

	Для Каждого НайденныйФайл Из МассивФайлов Цикл

		Файл = Новый Файл(НайденныйФайл.ПолноеИмя);

		Если Файл.ЭтоКаталог() Тогда

			ЕстьТакаяПапка = Соединение.НайтиФайлы(НачальныйКаталогВыгрузкиFTP + СтрЗаменить(СтрЗаменить(НайденныйФайл.Путь, НачальнаяПапкаВыгрузкиКомп + "\", ""), "\", "/"), НайденныйФайл.Имя).Количество() > 0;

			

			Если не ЕстьТакаяПапка Тогда

				НомерПопытки = 1;

				Успешно = Ложь;

				Пока НомерПопытки < 4 и не Успешно Цикл

					Попытка

					Соединение.УстановитьТекущийКаталог(ТекКаталог);

						Успешно = Истина;

					Исключение

						Сообщить("Попытка №" + НомерПопытки + ", установка каталога " + ТекКаталог + " - " + ОписаниеОшибки());

						НомерПопытки = НомерПопытки + 1;

					КонецПопытки;

				КонецЦикла;

				Если Не Успешно Тогда

					Возврат Ложь;

				КонецЕсли;

				

				НомерПопытки = 1;

				Успешно = Ложь;

				Пока НомерПопытки < 4 и не Успешно Цикл

					Попытка

						Соединение.СоздатьКаталог(НайденныйФайл.Имя);

						Успешно = Истина;

					Исключение

						Сообщить("Попытка №" + НомерПопытки + ", каталог " + НайденныйФайл.Имя + " - " + ОписаниеОшибки());

						НомерПопытки = НомерПопытки + 1;

					КонецПопытки;

				КонецЦикла;

				

				Если Не Успешно Тогда

					Возврат Ложь;

				КонецЕсли;

				

				

			КонецЕсли;

			

			НомерПопытки = 1;

			Успешно = Ложь;

			Пока НомерПопытки < 4 и не Успешно Цикл

				Попытка

					Соединение.УстановитьТекущийКаталог(НачальныйКаталогВыгрузкиFTP + СтрЗаменить(СтрЗаменить(НайденныйФайл.ПолноеИмя, НачальнаяПапкаВыгрузкиКомп + "\", ""), "\", "/") + "/");

					Успешно = Истина;

				Исключение

					Сообщить("Попытка №" + НомерПопытки + ", установка каталога " + ТекКаталог + " - " + ОписаниеОшибки());

					НомерПопытки = НомерПопытки + 1;

				КонецПопытки;

			КонецЦикла;

			Если Не Успешно Тогда

				Возврат Ложь;

			КонецЕсли;

			

			ВыгрузитьФайлыИПапкиНаFTP_Рекурсивно(Соединение, НачальныйКаталогВыгрузкиFTP, НачальнаяПапкаВыгрузкиКомп, НайденныйФайл.ПолноеИмя);



			Если не Рез Тогда

				Возврат Ложь;

			КонецЕсли;

			

		Иначе

			НомерПопытки = 1;

			Успешно = Ложь;

			Пока НомерПопытки < 4 и не Успешно Цикл

				Попытка

					Соединение.УстановитьТекущийКаталог(ТекКаталог);

					Успешно = Истина;

				Исключение

					Сообщить("Попытка №" + НомерПопытки + ", установка каталога " + ТекКаталог + " - " + ОписаниеОшибки());

					НомерПопытки = НомерПопытки + 1;

				КонецПопытки;

			КонецЦикла;

			Если Не Успешно Тогда

				Возврат Ложь;

			КонецЕсли;

		

			

			

			// почему-то иногда при большой выгрузке глюкает ((

			// а со второй попытки выкладывается.... странно...

			НомерПопытки = 1;

			Успешно = Ложь;

			Пока НомерПопытки < 4 и не Успешно Цикл

				Попытка

					Соединение.Записать(НайденныйФайл.ПолноеИмя, НайденныйФайл.Имя);

					Успешно = Истина;

				Исключение

					Сообщить("Попытка №" + НомерПопытки + ", файл " + НайденныйФайл.ПолноеИмя + " - " + ОписаниеОшибки());

					НомерПопытки = НомерПопытки + 1;

				КонецПопытки;

			КонецЦикла;

			

			Если Не Успешно Тогда

				Возврат Ложь;

			КонецЕсли;

			

			#Если Клиент Тогда

				Состояние("Выгрузка файла: " + НайденныйФайл.ПолноеИмя);

			#КонецЕсли

			

		КонецЕсли;

	КонецЦикла;

	

	Возврат Рез;

	

КонецФункции





// ПРИМЕР обращения к функции

КаталогиДляПередачиНаFTP = Новый Соответствие;

// цикл и в нем

КаталогиДляПередачиНаFTP.Вставить(СсылкаНаЭлементСправочника);

// Конец цикла



// Теперь Выгрузим все на FTP

	Для Каждого Выборка из КаталогиДляПередачиНаFTP Цикл

	ВыборкаДетальныеЗаписи = Выборка.Ключ;

	Соединение = Новый FTPСоединение(ВыборкаДетальныеЗаписи.FTPСервер,

	ВыборкаДетальныеЗаписи.FTPПорт,

	ВыборкаДетальныеЗаписи.FTPПользователь,

	ВыборкаДетальныеЗаписи.FTPПароль, ,Ложь);

	ВыгрузитьФайлыИПапкиНаFTP_Рекурсивно(Соединение, ВыборкаДетальныеЗаписи.FTPКаталогВыгрузки, ВыборкаДетальныеЗаписи.КаталогВыгрузкиДанных);

	КонецЦикла;

Как загрузить файлы с FTP

Категория: Работа с Интернет, Почтой (Mail), FTP

Выгрузка форматированного документа 1С на свой сайт

Пользователи в 1с ведут описание объектов, которые редактируются в объекте ФорматированныйДокумент. Необходимо обеспечить выгрузку форматированного документа на фтп.

Для решения этой задачи воспользуемся методом форматированного документа ПолучитьHTML(). Этот метод вернет нам сам текст html документа и структуру картинок. После выполнения данного метода нам следует выгрузить картинки на наш сайт. Во время выгрузки картинок определяем тип картинки и на основании этого определяем расширение файла. Поэтому нам надо и подкорректировать сам текст html, так как источник картинки в нем по умолчанию прописывается в виде «image001″ (без расширения). Эта корректировка не критична для нас, страница будет отображаться нормально, но отдельно по ссылке открыть рисунок будет проблематично.
Код функции:

Код 1C v 8.2 УП

 &НаСервере

Функция ВыгрузитьОбъект(ТекОбъект)  Экспорт

    РезультатВыгрузки = "";



    //проверим есть ли описание объекта в базе

    ФорматированныйДокумент = ТекОбъект.Описание.Получить();

    Если ФорматированныйДокумент = Неопределено Тогда

        РезультатВыгрузки = "   У данного объекта не определено описание. Выгрузка объекта остановлена";

        Возврат РезультатВыгрузки;

    КонецЕсли;



    //Определяем настройки подключения к фтп

    Сервер = ХранилищеНастроек.ФТПСервер;

    Порт = ХранилищеНастроек.ФТПпорт;

    ИмяПользователяФТП = ХранилищеНастроек.ФТПИмяПользователя;

    ПарольПользователяФТП = ХранилищеНастроек.ФТППароль;

    ТекущийКаталогFTP = ХранилищеНастроек.ФТПТекущийКаталог;



    ФТП = Новый FTPСоединение(Сервер,,ИмяПользователяФТП,ПарольПользователяФТП);



    Попытка

        ФТП.УстановитьТекущийКаталог(ТекущийКаталогFTP);

    Исключение

        РезультатВыгрузки = "Невозможно подключиться к фтп";

        Возврат РезультатВыгрузки;

    КонецПопытки;



    ИмяКаталогаОбъекта = Формат(ТекОбъект.Ссылка.Код, "ЧЦ=5; ЧВН=; ЧГ=");



    //Каталог для элемента

    Попытка

        ФТП.УстановитьТекущийКаталог(ТекущийКаталогFTP + "/" + ИмяКаталогаОбъекта);

    Исключение

        ФТП.СоздатьКаталог(ИмяКаталогаОбъекта);

        ФТП.УстановитьТекущийКаталог(ТекущийКаталогFTP + "/" + ИмяКаталогаОбъекта);

        РезультатВыгрузки = РезультатВыгрузки + Символы.ПС + "   Создан каталог " + ТекущийКаталогFTP + "/" + ИмяКаталогаОбъекта;

    КонецПопытки;



    //Чистка имеющихся элементов в каталоге элемента

    ФТП.Удалить(ТекущийКаталогFTP + "/" + ИмяКаталогаОбъекта,"*.*");



    ТекстХТМЛ = "";

    СтруктураКартинок = Новый Структура;

    ФорматированныйДокумент.ПолучитьHTML(ТекстХТМЛ, СтруктураКартинок);



    //Выгрузка картинок и корректировка ХТМЛ

    Для Каждого ТекКартинка Из СтруктураКартинок Цикл

        ИмяТемпФайла = ПолучитьИмяВременногоФайла();

        ТекКартинка.Значение.Записать(ИмяТемпФайла);

        ФорматТекущейКартинки = Строка(ТекКартинка.Значение.Формат());

        Если Не ФорматТекущейКартинки = ФорматКартинки.НеизвестныйФормат Тогда

            ФорматТекущейКартинкиСтрока = Строка(ФорматТекущейКартинки);

            ТекстХТМЛ = СтрЗаменить(ТекстХТМЛ,ТекКартинка.Ключ,ТекКартинка.Ключ+ "." + ФорматТекущейКартинкиСтрока);

            ФТП.Записать(ИмяТемпФайла, ТекКартинка.Ключ+ "." + ФорматТекущейКартинкиСтрока);

            РезультатВыгрузки = РезультатВыгрузки + Символы.ПС + "   Записан файл " + ТекКартинка.Ключ+ "." + ФорматТекущейКартинкиСтрока;

        Иначе

            ФТП.Записать(ИмяТемпФайла, ТекКартинка.Ключ);

            РезультатВыгрузки = РезультатВыгрузки + Символы.ПС + "   Записан файл " + ТекКартинка.Ключ;

        КонецЕсли;

    КонецЦикла;



    //ВыгрузкаХТМЛ

    ИмяТемпФайла = ПолучитьИмяВременногоФайла("html");

    ФайлHТМЛ = Новый ТекстовыйДокумент;

    ФайлHТМЛ.ДобавитьСтроку(ТекстХТМЛ);

    ФайлHТМЛ.Записать(ИмяТемпФайла);



    //Собственно запись хтмл

    ФТП.Записать(ИмяТемпФайла, ИмяКаталогаОбъекта + ".html");

    РезультатВыгрузки = РезультатВыгрузки + Символы.ПС + "   Записан файл " + ИмяКаталогаОбъекта + ".html";



    Возврат РезультатВыгрузки;

КонецФункции

Андрей Данилюк

Категория: Форматированный документ

Загрузка и Просмотр файлов на FTP сервер

Код 1C v 8.х

  // Загрузка файлов на FTP сервер

Процедура ЗагрузитьОтмеченные(Кнопка)

Сервер = Новый FTPСоединение(FTPServer);

Для Каждого Файл Из ПолеСписка Цикл

   Если Файл.Пометка Тогда

     Сервер.Получить(Файл.Значение.ПолноеИмя, "с:\temp" + Файл.Значение.ПолноеИмя);

     Файл.Пометка = Ложь;

   КонецЕсли;

КонецЦикла;

КонецПроцедуры



// Просмотр файлов на FTP сервере

Процедура Просмотреть(Кнопка)

Сервер = Новый FTPСоединение(FTPServer);

МассивФайлов = Сервер.НайтиФайлы("/","*.*");

Для Каждого Файл Из МассивФайлов Цикл

   Если Файл.ЭтоФайл() Тогда

     ПолеСписка.Добавить(Файл, Файл.Имя)

   КонецЕсли;

КонецЦикла;

КонецПроцедуры

Код 1C v 8.х

  ПапкаКонтрагена = "Kontr";

    Попытка

        ИмяFTPСервера               = "*******";

        ПортFTPСоединения           = "21";

        ПользовательFTPСоединения   = "****" ;

        ПарольFTPСоединения         =  "*****" ;

        ПассивноеFTPСоединение      =  Ложь;

        Соединение = Новый FTPСоединение(ИмяFTPСервера, ПортFTPСоединения,ПользовательFTPСоединения,ПарольFTPСоединения, ,ПассивноеFTPСоединение);

        Массив = Соединение.НайтиФайлы("/"+ПапкаКонтрагена+"/", "");

        Если Массив.Количество() = 0 Тогда

           Соединение.СоздатьКаталог(ПапкаКонтрагена);           

         КонецЕсли;

        Соединение.УстановитьТекущийКаталог(ПапкаКонтрагена);

        Соединение.Записать(ИмяФайлаЗаписи, "file.txt"); 

    Исключение

        Сообщить("Ошибка записи файла на FTP!!!");

        Возврат ""; 

    КонецПопытки;

Категория: Работа с Интернет, Почтой (Mail), FTP