учетноменклатуры » Поиск

Результаты по ключевому слову: учетноменклатуры

Особенности работы с хранилищем конфигурации Категория: Администрирование

Полная регистрация изменений для узла

Код 1C v 8.х

 Процедура ПолнаяРегистрацияДанныхПоУзлу(Узел, РегистрироватьВсе) Экспорт

 

// Регистрация изменений всех данных для узла производится в случае

// значения параметра РегистрироватьВсе = Истина или

// значение склада в узле не установлено

Сообщение = Новый СообщениеПользователю();

Если РегистрироватьВсе Или Узел.Склад.Пустая() Тогда

Сообщение.Текст = "Регистрация всех данных по узлу " + Узел;

Сообщение.Сообщить();

ПланыОбмена.ЗарегистрироватьИзменения(Узел);  

Иначе

Сообщение.Текст = "Регистрация данных по узлу " + Узел + " -----------";

Сообщение.Сообщить();

ПланОбмена = Узел.Метаданные();

Состав = ПланОбмена.Состав;

Для Каждого ЭлементСостава Из Состав Цикл

Сообщение.Текст = "   Регистрация данных " + ЭлементСостава.Метаданные + " по узлу " + Узел;

Сообщение.Сообщить();

Если ЭлементСостава.Метаданные = Метаданные.Документы.РасходнаяНакладная Тогда

 

// Для документов РасходнаяНакладная регистрация изменений 

// для узла производится только при совпадении складов узла и накладной

// Выбираем документы РасходнаяНакладная по складу узла

Запрос = Новый Запрос("ВЫБРАТЬ 

|Ссылка 

|ИЗ 

|Документ.РасходнаяНакладная

|ГДЕ 

|Склад = &Склад");

Запрос.УстановитьПараметр("Склад", Узел.Склад);

Выборка = Запрос.Выполнить().Выбрать();

Пока Выборка.Следующий() Цикл

 

// регистрируем изменение документа для узла

ПланыОбмена.ЗарегистрироватьИзменения(Узел, Выборка.Ссылка);  

КонецЦикла;

ИначеЕсли ЭлементСостава.Метаданные = Метаданные.РегистрыНакопления.УчетНоменклатуры Тогда

 

// Выбираем всех различных регистраторов регистра

Запрос = Новый Запрос("ВЫБРАТЬ РАЗЛИЧНЫЕ 

|Регистратор 

|ИЗ 

|РегистрНакопления.УчетНоменклатуры

|ГДЕ 

|Склад = &Склад");

Запрос.УстановитьПараметр("Склад", Узел.Склад);

Выборка = Запрос.Выполнить().Выбрать();

Пока Выборка.Следующий() Цикл

 

// Создаем набор записей регистра с отбором по регистратору

НаборЗаписей = РегистрыНакопления.УчетНоменклатуры.СоздатьНаборЗаписей();

НаборЗаписей.Отбор.Регистратор.Установить(Выборка.Регистратор);

 

// регистрируем изменения набора записей для узла

ПланыОбмена.ЗарегистрироватьИзменения(Узел, НаборЗаписей);

КонецЦикла;

Иначе

 

// Регистрация изменений всех данных объекта для узла

ПланыОбмена.ЗарегистрироватьИзменения(Узел, ЭлементСостава.Метаданные);  

КонецЕсли;

КонецЦикла; // обход состава плана обмена

КонецЕсли;

 

КонецПроцедуры

В случае если в качестве второго параметра передается значение Ложь, расходные накладные и записи регистра накопления регистрируются как измененные только в случае совпадения склада со складом, определенным в узле плана обмена. Все остальные данные регистрируются обычным образом.

Категория: Конвертация данных, Обмен, Перенос

Особенности использования события ПриПолученииДанныхТабличногоПоля

Событие ПриПолученииДанных использется для оформления ячеек строк данных, отображаемых табличным полем. Обработчик данного события вызывается табличным полем в тех же случаях, что и обработчик ПриВыводеСтроки, т.е. при обновлении данных, отображаемых табличным полем или при поиске по подстроке. Важно отметить, что обработчик данного события вызывается табличным полем перед вызовом обработчиков события ПриВыводеСтроки для всех видимых строк табличного поля. Основным отличием данного события от события ПриВыводеСтроки является то, что в обработчике события ПриПолученииДанных можно изменять настройки ячеек группы строк, а не одной строки как в обработчике события ПриВыводеСтроки.

Обрабатывая данное событие можно изменять шрифт, цвет фона или текста, как определенной ячейки, так и всей строки табличного поля, устанавливать высоту или видимость ячеек строки табличного поля, а также устанавливать картинку, флажок или новый текст в ячейке. Параметром данного события является объект типа ОформлениеСтрок - коллекция объектов типа ОформлениеСтроки, являющихся оформлениями строк табличного поля.

Важно отметить, что в некоторых случаях обработчик события ПриПолученииДанных может вызываться табличным полем более одного раза. Например, если текущая строка табличного поля находится в середине видимой области, то при обновлении обработчик события ПриПолученииДанных будет вызван табличным полем два раза: первый раз для группы строк, начиная с текущей строки до верхней видимой и второй раз для строки, следующей за текущей до нижней видимой строки. Такое поведение табличного поля связано с тем, что при обновлении табличное поле пытается сохранить позицию текущий строки в видимой области.

Поясним использовании события ПриПолученииДанных на следующем примере. Пусть существует форма списка справочника "Номенклатура" с двумя табличными полями. Пусть одно из табличных полей отображает указанный список справочника как дерево, а другое как иерархический список. Требуется в табличном поле, отображающем данные как иерархический список, отображать остатки по позициям номенклатуры.

Наиболее эффективным способом решения данной задачи является использование события ПриПолученииДанных. В обработчике данного события формируется запрос к регистру накопления "УчетНоменклатуры" для получения остатков. В качестве параметра данного запроса передается массив, содержащий ссылки на отображаемые строки табличного поля. Затем выполняется запрос и получается выборка. Полученная выборка обходится и значения остатков устанавливаются в ячейке "Остаток".

Код 1C v 8.х

 Процедура СправочникСписокПриПолученииДанных(Элемент, ОформленияСтрок)



    // Соответствие создается для заполнения остатков в строках табличного поля

    Соответствие = Новый Соответствие; 



    // Заполнение параметра - массива значений ссылками на отображаемые строки 



    // табличного поля

    СсылкиМассив = Новый Массив;

    Для каждого Стр из ОформленияСтрок Цикл

        СсылкиМассив.Добавить(Стр.ДанныеСтроки.Ссылка);

        Соответствие.Вставить(Стр.ДанныеСтроки.Ссылка, Стр);

    КонецЦикла;



    // Сформировать запрос для получения остатков

    ЗапросОстатка = Новый Запрос;

    ЗапросОстатка.Текст = "ВЫБРАТЬ

                           | УчетНоменклатурыОстатки.Номенклатура,

                           | УчетНоменклатурыОстатки.КоличествоОстаток

                           |ИЗ

                           | РегистрНакопления.УчетНоменклатуры.Остатки(, 



                           |   Номенклатура В (&Номенклатура)) КАК 



                           |  УчетНоменклатурыОстатки";



    ЗапросОстатка.УстановитьПараметр("Номенклатура", СсылкиМассив);

    Выборка = ЗапросОстатка.Выполнить().Выбрать();



    // Вывести остаток в строку, найденную в соответствии по номенклатуре из 



    // запроса

    Пока Выборка.Следующий() Цикл

        Соответствие.Получить(Выборка.Номенклатура).Ячейки.Остаток.Значение = 



Выборка.КоличествоОстаток;

    КонецЦикла; 



КонецПроцедуры

Категория: Список Справочника, Документов, Регистров

Конструктор схемы компоновки данных - Закладка Набор данных - Запрос - Автозаполнение

У набора данных - запрос в схеме компоновки данных есть свойство АвтоЗаполнение. В данной статье мы рассмотрим, что происходит, если данное свойство установлено.

Свойство АвтоЗаполнение указывает, что система должна самостоятельно сделать доступными поля, описанные в запросе.

При автоматическом заполнении:
* Поля списка выборки запроса верхнего уровня становятся доступными для отбора, порядка, выбора, группировки. Заметим, что доступность поля будет определяться по его типу. Например, поле неограниченной длины не может быть использовано в качестве поля группировки.
* Поля виртуальных таблиц, на которые можно наложить условия в параметрах этих таблиц становятся доступными для отбора.
* Параметры виртуальных таблиц становятся доступными параметрами.

Разберем пример, будем рассматривать на регистре РегистрНакопления.УчетНоменклатуры у которого есть два измерения: Номенклатура и Склад и один ресурс: Количество.

Рассмотрим, какие поля и параметры будут доступны при автоматическом заполнении для следующего запроса:

Код 1C v 8.х

 ВЫБРАТЬ

 УчетНоменклатурыОбороты.Номенклатура,

 УчетНоменклатурыОбороты.КоличествоОборот,

 УчетНоменклатурыОбороты.КоличествоПриход,

 УчетНоменклатурыОбороты.КоличествоРасход

ИЗ

 РегистрНакопления.УчетНоменклатуры.Обороты КАК УчетНоменклатурыОбороты

Поля Номенклатура, КоличествоОборот, КоличествоПриход, КоличествоРасход будут доступны для отбора, порядка, группировки, выбора.
Поле Склад, хотя явно не присутствует в запросе, будет доступно для отбора, т.к. на него можно наложить отбор в параметрах виртуальной таблицы.
В доступные параметры из данного запроса попадут параметры НачалоПериода и КонецПериода, т.к. их можно указывать в виртуальной таблице.

В случае если в запросе в виртуальной таблице указаны имена параметров, то доступны будут параметры именно с указанными именами. Например, в следующем запросе, доступными будут параметры Начало и Конец вместо НачалоПериода и КонецПериода:

Код 1C v 8.х

 ВЫБРАТЬ

 УчетНоменклатурыОбороты.Номенклатура,

 УчетНоменклатурыОбороты.КоличествоОборот,

 УчетНоменклатурыОбороты.КоличествоПриход,

 УчетНоменклатурыОбороты.КоличествоРасход

ИЗ

 РегистрНакопления.УчетНоменклатуры.Обороты({&Начало}, {&Конец}) КАК УчетНоменклатурыОбороты

Категория: Схема Компоновки Данных

Получение итогов регистра накопления по иерархии элементов справочника

Для получения итогов по иерархии в запросе необходимо в предложении ИТОГИ ПО указать ключевое слово ИЕРАРХИЯ после указания поля, по которому будет рассчитываться итоги. Пример отчета "Обороты номенклатуры" с получением итогов по иерархии:

Код 1C v 8.х

 ВЫБРАТЬ

    УчетНоменклатурыОбороты.Номенклатура КАК Номенклатура, 

    УчетНоменклатурыОбороты.Номенклатура.Представление, 

    УчетНоменклатурыОбороты.КоличествоОборот КАК КоличествоОборот 

ИЗ 

    РегистрНакопления.УчетНоменклатуры.Обороты КАК УчетНоменклатурыОбороты 

ИТОГИ СУММА(КоличествоОборот) ПО 

   Номенклатура ИЕРАРХИЯ

В результате данного запроса будут рассчитаны итоги не только для каждой номенклатуры, но и для групп, к которым принадлежит та или иная номенклатура.

В случае, когда не нужны итоги по элементам, а нужны итоги только по группам, нам необходимо использовать в итогах конструкцию ТОЛЬКО ИЕРАРХИЯ. Пример:

Код 1C v 8.х

 

ВЫБРАТЬ

    УчетНоменклатурыОбороты.Номенклатура КАК Номенклатура, 

    УчетНоменклатурыОбороты.Номенклатура.Представление, 

    УчетНоменклатурыОбороты.КоличествоОборот КАК КоличествоОборот 

ИЗ 

    РегистрНакопления.УчетНоменклатуры.Обороты КАК УчетНоменклатурыОбороты 

ИТОГИ СУММА(КоличествоОборот) ПО 

   Номенклатура ТОЛЬКО ИЕРАРХИЯ

В результате данного запроса будут итоговые записи только для групп номенклатуры.

Категория: Регистры накопления

Выборка из результата запроса всех вошедших в него значений группировок

При обходе результата запроса нередко возникает необходимость получения всех значений группировок внутри какой-либо другой группировки. Такая возможность может понадобиться, например, при выводе кросс отчета. Для обеспечения такой возможности в объекте ВыборкаИзРезультатаЗапроса предусмотрен третий параметр функции Выбрать().

Рассмотрим пример. Пусть нам необходимо получить кросс-отчет по остаткам номенклатуры на различных складах. Номенклатуру необходимо вывести в строках, склады - в колонках.
Запрос для получения остатков будет выглядеть так:

Код 1C v 8.х

 ВЫБРАТЬ

    УчетНоменклатурыОстатки.Номенклатура КАК Номенклатура, 

    УчетНоменклатурыОстатки.Номенклатура.Представление, 

    УчетНоменклатурыОстатки.Склад КАК Склад, 

    УчетНоменклатурыОстатки.Склад.Представление, 

    УчетНоменклатурыОстатки.КоличествоОстаток КАК КоличествоОстаток 

ИЗ 

    РегистрНакопления.УчетНоменклатуры.Остатки КАК УчетНоменклатурыОстатки 

ИТОГИ СУММА(КоличествоОстаток) ПО 

    ОБЩИЕ, 

    Номенклатура, 

    Склад

Для обхода номенклатуры воспользуемся выборкой из результата запроса:

Код 1C v 8.х

 ВыборкаНоменклатура = Результат.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам, "Номенклатура");

Пока ВыборкаНоменклатура.Следующий() Цикл 

    ОбластьНоменклатура.Параметры.Заполнить(ВыборкаНоменклатура);

    ТабДок.Вывести(ОбластьНоменклатура);

Для обхода внутри номенклатуры всех складов, присутствующих в результате запроса, получим вложенную выборку от выборки номенклатуры, с указанием третьего параметра "ВСЕ":

Код 1C v 8.х

 ВыборкаСклад = ВыборкаНоменклатура.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам, "Склад", "ВСЕ");

Пока ВыборкаСклад.Следующий() Цикл 

    ОбластьСклад.Параметры.Заполнить(ВыборкаСклад);

    ТабДок.Присоединить(ОбластьСклад);

КонецЦикла;

В случае если необходимо построить несколько отдельных кросс-таблиц для каждого значения некой группировки, необходимо в качестве третьего параметра выборки указать имя группировки, внутри которой необходимо получить все значения, вошедшие в запрос.
Пример:

Код 1C v 8.х

 ВыборкаСклад = ВыборкаНоменклатура.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам, "Склад", "Организация");

В данном примере будут получены все значения складов, присутствующие в ранее выбранной организации.

Категория: Запросы

Дополнение результата запроса Датами в Установленном ПЕРИОДЕ

Иногда возникает необходимость вывести в отчет информацию таким образом, чтобы некоторые итоговые значения были рассчитаны на каждую дату в заданном интервале с указанной периодичностью. Например, требуется получить обороты по неделям вне зависимости от того, были ли обороты в конкретную неделю или нет. Для решения подобной задачи в языке запросов предусмотрена конструкция ПЕРИОДАМИ. Данная конструкция указывается в предложении ИТОГИ после поля "Период". После ключевого слова ПЕРИОДАМИ в скобках указывается вид периода (одно из Секунда, Минута, Час, День, Неделя, Месяц, Квартал, Год, Декада, Полугодие), начальная и конечные даты интересуемого периода. В случае если начальные и конечные даты не указаны, будут использованы первая и последняя даты, участвующие в результате.

Пример:

Код 1C v 8.х

 ВЫБРАТЬ 

    УчетНоменклатурыОбороты.Период КАК Период,

    УчетНоменклатурыОбороты.КоличествоОборот КАК КоличествоОборот

ИЗ

    РегистрНакопления.УчетНоменклатуры.Обороты(, , Неделя, ) КАК УчетНоменклатурыОбороты 



УПОРЯДОЧИТЬ ПО 

    Период 



ИТОГИ СУММА(КоличествоОборот) ПО

    Период ПЕРИОДАМИ(НЕДЕЛЯ,,)

Результат данного запроса будет дополнен записями на даты начала каждой недели.

Заметим, что так как для дополненных периодов в результате запроса отсутствуют детальные записи, то дополненные записи будут получаться из выборки только в том случае, если при обходе выборки будут получаться все периоды, участвующие в запросе, что достигается установкой третьего параметра функции "Выбрать" результата запроса.

Пример:

Код 1C v 8.х

 ВыборкаПериод = Результат.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам, "Период", "ВСЕ"); 

Пока ВыборкаПериод.Следующий() Цикл 

    ОбластьПериод.Параметры.Заполнить(ВыборкаПериод); 

    ТабДок.Вывести(ОбластьПериод, ВыборкаПериод.Уровень()); 

КонецЦикла;

Категория: Запросы

Выбрать движения, получить выборку записей регистра накопления

Пример 1 :

Код 1C v 8.х

 

//Взаиморасчеты за период, хотя, это лучше выбирать запросом , он в примере 3

Отбор = Новый Структура("Организация", Организация);

НаборЗаписей = РегистрыНакопления.ВзаиморасчетыСРаботникамиОрганизаций.Выбрать(ПериодРегистрации, КонецМесяца(ПериодРегистрации), Отбор); 

Пока Выборка.Следующий() Цикл

	// код обработки например:

	Сум=Сум+Выборка.СуммаВзаиморасчетов; 

КонецЦикла;

Пример 2 :

Код 1C v 8.х

 

// Посчитаем, сколько отгружено с начала года

УчетНоменклатуры = РегистрыНакопления.УчетНоменклатуры;

ОтборПоТовару = Новый Структура("Номенклатура");

ОтборПоТовару.Номенклатура = ВыбТовар;

НачДата = НачалоГода(ТекущаяДата());

КонДата = ТекущаяДата();

Выборка = УчетНоменклатуры.Выбрать(НачДата,КонДата,ОтборПоТовару);

Расход =0;

Пока Выборка.Следующий() Цикл

	Если Выборка.ВидДвижения = ВидДвиженияНакопления.Расход Тогда

		Расход = Расход + Выборка.Количество;

	КонецЕсли;

КонецЦикла;

Предупреждение("Отгружено с начала года """ + СокрЛП(ВыбТовар) + """ = "+ Расход + " шт.");

Пример 3 :

Код 1C v 8.х

 

Запрос=новый Запрос;

Запрос.Текст="

|ВЫБРАТЬ

|	ВзаиморасчетыСРаботникамиОрганизаций.СуммаВзаиморасчетов,

|	ВзаиморасчетыСРаботникамиОрганизаций.СуммаВUSD,

|	ВзаиморасчетыСРаботникамиОрганизаций.Физлицо

|ИЗ

|	РегистрНакопления.ВзаиморасчетыСРаботникамиОрганизаций КАК ВзаиморасчетыСРаботникамиОрганизаций

|ГДЕ

|	ВзаиморасчетыСРаботникамиОрганизаций.Физлицо = &Физлицо

|	И ВзаиморасчетыСРаботникамиОрганизаций.ПериодВзаиморасчетов = &ПериодВзаиморасчетов

|	И ВзаиморасчетыСРаботникамиОрганизаций.Организация = &Организация

|	И ВзаиморасчетыСРаботникамиОрганизаций.ХарактерВыплаты = &ХарактерВыплаты

|";

Запрос.УстановитьПараметр("Организация",Организация);

Запрос.УстановитьПараметр("ПериодВзаиморасчетов",ПериодРегистрации);

Запрос.УстановитьПараметр("Физлицо",ТекущаяСтрока.Физлицо);

Запрос.УстановитьПараметр("ХарактерВыплаты",Перечисления.ХарактерВыплатыЗарплаты.ПлановыйАванс);

Результат = Запрос.Выполнить();

Результат = Результат.Выбрать();

Пока Результат.Следующий() Цикл

	// код обработки например:

	СумАванс=СумАванс+Результат.СуммаВзаиморасчетов; 

КонецЦикла;

Категория: Регистры накопления

Значения NULL ( ЕСТЬ NULL и ЕСТЬNULL()) Категория: Запросы