формировал » Поиск

Результаты по ключевому слову: формировал

Как сформировать отчет СКД без проверки прав (в привилегированном режиме)?

Что при разработке отчетов требуется чтобы у пользователя с ограниченными правами, отчет формировался полностью без проверки прав!

Особенно если настроен RLS

Есть несколько способов как это сделать:

1. Установить привилегированный режим в модуле отчета

Форма отчета должна быть Управляемой, далее в модуле отчета процедура обработчика «При компоновке результата»:

Код 1C v 8.3

 //Перехватываем событие вывода компоновки данных в табличный документ и выводим со своим заголовком

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

	СтандартнаяОбработка = Ложь; 

	УстановитьПривилегированныйРежим(Истина);	

	

	//Сформируем отчет

	СформироватьОтчет(ДокументРезультат, ДанныеРасшифровки);

	

	УстановитьПривилегированныйРежим(Ложь);

КонецПроцедуры

2. Формирование в привилегированном режиме через Общий модуль с галкой Привелигерованный

Создаем общий модуль

так же как в пункте 1 в обработчике «При компоновке результата» пишем:

Код 1C v 8.3

 //Перехватываем событие вывода компоновки данных в табличный документ и выводим со своим заголовком

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

	СтандартнаяОбработка = Ложь;  

	

	МЕ_ДляОтчетаСКД_ПривелРежим.СформироватьОтчетПривРеж(ДокументРезультат, СхемаКомпоновкиДанных, ДанныеРасшифровки, КомпоновщикНастроек);



КонецПроцедуры

В общем модуле МЕ_ДляОтчетаСКД_ПривелРежим код:

Код 1C v 8.3

 Процедура СформироватьОтчетПривРеж(ТабличныйДокумент, СхемаКомпоновкиДанных, ДанныеРасшифровки, КомпоновщикНастроек) Экспорт 



	ТабличныйДокумент.Очистить();  

	

	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных; 	

	МакетКомпоновкиДанных = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки, ДанныеРасшифровки,,,Ложь);

	

	ВнешниеНаборыДанных  = Новый Структура;

	/// можно передать внешние данные ВнешниеНаборыДанных.Вставить("тзПродаж", СформироватьТЗПродаж());

	

	ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;

	ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновкиДанных,ВнешниеНаборыДанных,ДанныеРасшифровки);

	

	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

	ПроцессорВывода.УстановитьДокумент(ТабличныйДокумент);

	ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

	

КонецПроцедуры

3. Если включен режим Использовать ограничение на уровне прав доступа - RLS

Часто используется в типовых. Тут в модуле для текущего пользователя можно на время формирования отчету установить параметр сеанса ИспользоватьОграниченияПравДоступаНаУровнеЗаписей в Ложь и RLS не сработает.

Код 1C v 8.3

 ПараметрыСеанса.ИспользоватьОграниченияПравДоступаНаУровнеЗаписей=Ложь;

После завершения формирования, не забудьте включить rls обратно установив = Истина

4. Если в запросе используется конструкция вида регистратор.дата и это поле не отображается в полях отчета СКД

Допустим Вы сделали запрос по регистру накоплений и через регистратор обратились к дате или сумме документа и при формировании отчета СКД, эти поля недоступны !? как же быть?

Проблема в том - что у регистратором может выступать несколько документов и видимо права чтение/просмотр есть не на все - поэтому через скд эта таблица целиком недоступна, решение:

1. открыть доступ на все регистраторы регистра

2. в запросе четко обозначить тип

Код 1C v 8.3

 //примеры

ВЫРАЗИТЬ(ДокументыОплаты.Регистратор КАК Документ.ПлатежноеПоручениеВходящее).СуммаДокумента

//или так

ВЫБОР

 КОГДА РАЗНОСТЬДАТ(ВЫРАЗИТЬ(ВзаиморасчетыПоДокументам.ДокументРасчетовСКонтрагентом КАК Документ.ПоступлениеТоваровУслуг).Дата,КонецПериода, ДЕНЬ) > ВзаиморасчетыПоДокументам.ДоговорКонтрагента.ДопустимоеЧислоДнейЗадолженности

   ТОГДА ДОБАВИТЬКДАТЕ(ВЫРАЗИТЬ(ВзаиморасчетыПоДокументам.ДокументРасчетовСКонтрагентом КАК Документ.ПоступлениеТоваровУслуг).Дата, ДЕНЬ, ВзаиморасчетыПоДокументам.ДоговорКонтрагента.ДопустимоеЧислоДнейЗадолженности)

 ИНАЧЕ ДАТАВРЕМЯ(1, 1, 1)

КОНЕЦ КАК ДеньВозникновенияЗадолженности

В дополнении у пункту 1, код процедуры сформировать отчет(). Для вывода отчета я использую шаблон All4CF.ru_Template_SKD_v4.1 в нем уже реализованы почти все необходимые функции и работает в Обычных и УП формах:

Код 1C v 8.3

 // Процедура выполняет формирование табличного документа по настройкам СКД

Процедура СформироватьОтчет(ТабличныйДокумент, ДанныеРасшифровки) 

	УстановитьПривилегированныйРежим(Истина);	

	// если отчет открывается по расшифровке, отбору, упорядочиванию, 

	// группировке или условному оформлению - восстановим настройки вывода заголовка,

	// т.к., в переданных настройках при этом, вывод заголовка отключен

	// для того, чтобы не выводился встроенный заголовок компоновки.                                                                         

	ВосстановитьНастройкиВыводаЗаголовка();

	

	ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;

	

	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

	

	ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;

	

	ТабличныйДокумент.Очистить();

	

	// установим обязательные настройки отчета

	УстановитьПараметрыОтчета();

	

	// Сделаем копию настроек вывода заголовка

	СохранитьНастройкиВыводаЗаголовка();

	

	ВыводитьЗаголовок = ВыводитьЗаголовокОтчета();

	Если ВыводитьЗаголовок Тогда

		ПрисоединитьЗаголовокОтчетаКТабличномуДокументу(ТабличныйДокумент, ПолучитьТекстЗаголовкаОтчета());

		

		// Отключим в настройках вывод встроенного заголовка

		НайденнаяНастройкаВыводаЗаголовка = КомпоновщикНастроек.Настройки.ПараметрыВывода.Элементы.Найти("ВыводитьЗаголовок");

		НайденнаяНастройкаВыводаЗаголовка.Значение		= ТипВыводаТекстаКомпоновкиДанных.НеВыводить;

		НайденнаяНастройкаВыводаЗаголовка.Использование	= Истина;

	КонецЕсли;

	

	КопияДополнительныхНастроек = УстановитьДополнительныеНастройкиДляРасшифровки();

	

	МакетКомпоновкиДанных = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки, ДанныеРасшифровки);

	

	// при необходимости вставим внешние наборы данных в СКД

	ВнешниеНаборыДанных = Новый Структура;

	

	ТаблицаВнешнегоНабораДанных = ПолучитьТаблицуВнешнегоНабораДанных();

	ВнешниеНаборыДанных.Вставить("ТаблицаВнешнегоНабораДанных",ТаблицаВнешнегоНабораДанных);

	

	ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновкиДанных,ВнешниеНаборыДанных,ДанныеРасшифровки);

	

	ВывестиРезультатКомпоновкиСАвтофиксациейСтрок(ТабличныйДокумент, ПроцессорКомпоновкиДанных, ДанныеРасшифровки.Элементы,,,КоличествоФиксируемыхСтолбцов);

	

	ДополнительнаяОбработкаРезультатаОтчета(ТабличныйДокумент);

	

	Если ВыводитьЗаголовок Тогда

		// вернем настройки вывода заголовка на место		

		ВосстановитьНастройкиВыводаЗаголовка();

	КонецЕсли;

	

	// восстановим дополнительные настройки

	Для Каждого ЭлементСтруктуры Из КопияДополнительныхНастроек Цикл

		КомпоновщикНастроек.Настройки.ДополнительныеСвойства.Вставить(ЭлементСтруктуры.Ключ, ЭлементСтруктуры.Значение);

	КонецЦикла;

	

	// сохраненные настройки нужны только при расшифровке и т.п.

	// и не будуть давать изменить вывоз заголовка при обычном формировании.

	ОчиститьСохраненныеНастройкиВыводаЗаголовка();





	УстановитьВидимостьЗаголовкаОтчета(ТабличныйДокумент);

	УстановитьВидимостьПараметровОтчета(ТабличныйДокумент);    

    УстановитьПривилегированныйРежим(Ложь);

КонецПроцедуры // СформироватьОтчет()

Категория: Схема Компоновки Данных

Формирование HTML-документа, содержащего ссылки на объекты базы данных

В данной статье рассматривается способ программного формирования HTML документа, содержащего ссылки на объекты базы данных 1С, такие как справочники, документы и т.д. Показан пример построения обработчика события OnClick ПоляHTMLДокумента, для обработки клика на html-ссылке.

Предисловие
Однажды, дописывая обработку, создающую и модифицирующую, не суть важно какие документы, я подумал, что неплохо было бы вывести для пользователя некое резюме:
“Создан документ такой-то”
“Изменен документ такой-то” и т.д.
От обычного, в таких случаях, вывода информации в окно сообщений я сразу отказался, так как не удобно это, сначала читать в окне сообщений “Создан документ … ” а потом запоминать его номер, открывать соответствующий журнал (или форму списка) и искать там этот документ. А если документов много и пользователь хочет посмотреть все документы?(или выборочно) Насколько это неудобно я убедился при отладке обработки …
То, что в форме есть элемент управления именуемый ПолеHTMLДокумента я конечно знал, но вот представилась возможность познакомиться с ним поближе. Было решено реестр обработанных документов выводить в виде html документа содержащего ссылки на эти самые документы, а по клику на ссылке открывать форму соответствующего документа. Здесь мне многие могут возразить: “А почему бы для этих целей не использовать обычный макет, выводимый в табличный документ, а для открытия документов использовать расшифровку? И чем Ваш способ лучше?” Отвечаю: Конечно можно использовать, и мой способ ничем не лучше. Он просто другой. Ведь у хорошего программиста для решения одной задачи должно быть в арсенале несколько инструментов.
Итак, перейдем от слов к делу, в рамках данной статьи рассмотрим следующую задачу: Сформировать html-документ, содержащий ссылки на элементы справочника номенклатура, по клику требуется открывать форму соответствующего элемента. Создаем новый отчет, его форму, на форме размещаем элемент управления ПолеHTMLДокумента.

Текст модуля формы:

Код 1C v 8.х

  Процедура ДобавитьТекстHTML(ТекстHTML, Элемент);

    // Ссылку будем формировать хитро:

    // Предполагаем что символ "-" не входит в имена объектов метаданных, 

    // учавствующих в формировании html

    // Тогда ссылка будет иметь следующий вид: 

    // Номенклатура-d341d377-b3b1-11dc-a100-0011d85708ff

    // Передавать нашу ссылку будем через атрибут id

    СсылкаНаЭлемент = Элемент.Метаданные().Имя+"-"

    +Элемент.Ссылка.УникальныйИдентификатор();

    ТекстHTML.ДобавитьСтроку("<A id=""" + СсылкаНаЭлемент + """ href= """ 

    + Элемент + """ >"+Элемент+"</A><BR>");

КонецПроцедуры



Процедура ДействияФормыСформировать(Кнопка)

    Запрос = Новый Запрос("

    |ВЫБРАТЬ

    |    Номенклатура.Ссылка

    |ИЗ

    |    Справочник.Номенклатура КАК Номенклатура");

    ТекстHTML = Новый ТекстовыйДокумент;

    Выборка = Запрос.Выполнить().Выбрать();

    Пока Выборка.Следующий() Цикл

        ДобавитьТекстHTML(ТекстHTML, Выборка.Ссылка);

    КонецЦикла;

ЭлементыФормы.ПолеHTMLДокумента.УстановитьТекст(ТекстHTML.ПолучитьТекст());

КонецПроцедуры

Ну вот html мы сформировали, теперь чтобы ссылки “ожили” надо написать обработчик события OnClick элемента управления ПолеHTMLДокумента.

Код 1C v 8.х

  // Функция получает элемент - <A> по данному элементу

// Производит поиск элемента <A> среди родительских элементов данного

//

// Параметры:

// Элемент - COMОбъект, элемент HTML документа,

// по которому нужно найти ссылку

//

// Возвращаемое значение:

// COMОбъект - если ссылка обнаружена, иначе - Неопределено



Функция НайтиСсылку(Элемент)

    Врем = Элемент;

    Пока Врем <> Неопределено Цикл

        Если НРег(Врем.tagName) = "a" Тогда

            Возврат Врем;

        КонецЕсли;

        Врем = Врем.parentElement;

    КонецЦикла;

    Возврат Неопределено;

КонецФункции    // НайтиСсылку(Элемент)



Процедура ПолеHTMLДокументаonclick(Элемент, pEvtObj)

    htmlElement = НайтиСсылку(pEvtObj.srcElement);

    // Анализируем если произошло нажание не ссылку

    Если htmlElement <> Неопределено Тогда

        // Если у ссылки есть идентификатор

        Если СокрЛП(htmlElement.id) <> "" Тогда

            // Получаем адрес ссылки из атрибута id

            СсылкаНаЭлемент = htmlElement.id;

            Разделитель = Найти(СсылкаНаЭлемент,"-");

            Если Разделитель > 0 Тогда

                // Получаем тип элемента

                ТипЭлемента = Лев(СсылкаНаЭлемент,Разделитель-1);

                // Получаем УникальныйИдентификатор

                ГУИД = Сред(СсылкаНаЭлемент,Разделитель+1);

                Справочники[ТипЭлемента].ПолучитьСсылку(

             Новый УникальныйИдентификатор(ГУИД)).ПолучитьФорму().Открыть();

            КонецЕсли;

            // Не отработали нажатие

            pEvtObj.returnValue = Ложь;

        КонецЕсли;

    КонецЕсли;

КонецПроцедуры

Всё можно пробовать!

Заключение
Обратите внимание что ссылку я формировал следующим образом:
<ИмяОбъектаМетаданных>-<УникальныйИдентификатор> это сделано для того, чтобы в обработчике onclick можно было определить к какому объекту метаданных относится данный УникальныйИдентификатор, потому что имея ТОЛЬКО УникальныйИдентификатор невозможно определить к какому объекту метаданных он относиться. Точнее возможно, но уж слишком долго и неудобно – путем перебора всех метаданных в цикле, для каждого объекта метаданных выполнять попытку <ОбъектМетаданных>.ПолучитьСсылку(Новый УникальныйИдентификатор(НашУникальныйИдентификатор))
Хотя в нашем примере только один справочник, и указывать его вид было необязательно, и так понятно что это УникальныйИдентификатор элемента справочника Номенклатура, но вдруг Вам потребуется работать с несколькими справочниками, вот тут то мой способ задания ссылки Вам и пригодится. Скачивать файлы может только зарегистрированный пользователь!

P.S. Платформа 8.2 имеет встроенный механизм работы со ссылками на объекты БД и данная задача наверняка упростится, но это уже другая тема.
Источник: obrabotki.com

Категория: Работа с Интернет, Почтой (Mail), FTP

Передача файлов и данных на веб-сервер из 1С методами GET и POST

При интеграции 1С с веб-сайтами всегда встает вопрос о передачи некоторых данных на веб-сервер. Будь то это передача параметров запроса для получения данных от веб-сервера в 1С или же передача данных из 1С, которые должны быть сохранены или каким-то образом обработаны на веб-сервере. Передаваться могут как простые данные в виде строк, чисел, так и целые файлы (изображения, XML-файлы и прочее). Для передачи и получения файлов и данных на веб-сервер в 1С используется объект HTTPСоединение.

Создание и инициализация HTTP соединения в 1С
Для инициализации HTTP соединения в 1С необходимо создать объект HTTPСоединение и в конструкторе указать параметры HTTP соединения.

Код 1C v 8.х

 Новый HTTPСоединение(<Сервер>, <Порт>, <ИмяПользователя>, <Пароль>, <Прокси>, <ЗащищенноеСоединение>)

<Сервер> (обязательный) - адрес сервера, с которым необходимо установить соединение.
<Порт> (необязательный) - порт сервера, с которым устанавливается соединение.
Значение по умолчанию зависит от защищенности соединения (80 для незащищенного и 443 для SSL-соединения).
<ИмяПользователя> (необязательный) - имя пользователя на указанном сервере.
<Пароль> (необязательный) - пароль пользователя на указанном сервере.
<Прокси> (необязательный). Тип - ИнтернетПрокси. Прокси, используемый для соединения с сервером.
<ЗащищенноеСоединение> (необязательный). Тип - Булево. Определяет используемый протокол -
http или https. По умолчанию Ложь.
Ниже приведен примеры создания HTTPСоединения с сайтом http://www.mysite.ru/.

Код 1C v 8.х

 // соединение с параметрами по умолчанию

Соединение = Новый HTTPСоединение("www.mysite.ru");

 

// сервер использует порт 8080

Соединение = Новый HTTPСоединение("www.mysite.ru", 8080);

 

// сервер использует защищенное соединение (https),

// для подключения к серверу используется прокси

ПроксиСервер = Новый интернетПрокси;

ПроксиСервер.Пользователь = имяПользователя;

ПроксиСервер.Пароль       = парольПользователя;

 

Соединение = Новый HTTPСоединение("www.mysite.ru",,,, ПроксиСервер, Истина);

Передача данных на веб-сервер из 1С методом GET.
Для передачи данных на веб-сервер из 1С методом GET используется процедура Получить() объекта HTTPСоединение.

Код 1C v 8.х

 Получить(<Источник>, <ИмяВыходногоФайла>, <Заголовки>)

<Источник> (обязательный). Тип - Строка. Адрес ресурса на сервере.
<ИмяВыходногоФайла> (обязательный). Тип - Строка. Имя файла на диске, в который
помещаются данные, полученные от сервера (ответ сервера).
<Заголовки> (необязательный). Тип - Строка. Заголовки, добавляемые к запросу на сервер.
Текстовые пары вида <Заголовок>:<Значение>, разделенные комбинацией ВК + ПС.
(подробнее о заголовках будет сказано ниже).
Рассмотрим параметры процедуры Получить() более подробно:

В качестве источника указывается строка с адресом запроса, идущая после названия домена и символа "/". Так, если необходимо отправить данные на адрес https://www.mysite.com/getusers.php, то при создании HTTP соединения в конструкторе HTTPСоединение в поле "Сервер" указывается "www.mysite.com", признак защищенного соединения устанавливается в Истина, а в процедуре Получить() в параметре Источник указывается "getUsers.php".

В поле ИмяВыходногоФайла указывает имя файла на диске, в который будут сохранены данные, полученные от сервере в результате запроса. Так, например, если сервер возвращает список пользователей в формате XML, то на диск в указанный файл будет сохранен XML файл со списком пользователей.

О заголовках более подробно будет сказано ниже.

Так же, при запросе к веб-серверу зачастую передаются дополнительные данные (параметры) для этого запроса. Параметры от адреса источника отделяются символом "?". Каждый параметр задается в формате <Имя_Параметры>=<Значение_Параметры>. Параметры от адреса источника отделяются символом "?". Сами же параметры отделяются друг от друга символом "&". В результате строка адреса источника может выглядеть следующим образом: getUsers.php?owner_id=263544&count=100.

Ниже приведен пример, поясняющий все выше сказанное.

Код 1C v 8.х

 // необходимо выполнить запрос по адресу

// https://www.mysite.com/getUsers.php?owner_id=263544&amp;count=100

// ответ от сервера приходит в виде XML файла

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml");

 

Соединение = Новый HTTPСоединение("www.mysite.com",,,,, Истина);

Соединение.Получить("getUsers.php?owner_id=263544&amp;count=100", имяВыходногоФайла);

 

ЧтениеXML = Новый ЧтениеXML;

ЧтениеXML.ОткрытьФайл(имяВыходногоФайла);

 

Пока ЧтениеXML.Прочитать() Цикл

    // чтение ответа в виде XML файла

    ...

КонецЦикла;

 

ЧтениеXML.Закрыть();

 

// удаляем файл после использования

УдалитьФайлы(имяВыходногоФайла);

Заголовки HTTP
Ниже приведена общая информация о HTTP заголовках из википедии.
Заголовки HTTP (англ. HTTP Headers) — это строки в HTTP-сообщении, содержащие разделённую двоеточием пару имя-значение. Формат заголовков соответствует общему формату заголовков текстовых сетевых сообщений ARPA. Заголовки должны отделяться от тела сообщения хотя бы одной пустой строкой.

Все заголовки разделяются на четыре основных группы:

General Headers (рус. Основные заголовки) — должны включаться в любое сообщение клиента и сервера.
Request Headers (рус. Заголовки запроса) — используются только в запросах клиента.
Response Headers (рус. Заголовки ответа) — только для ответов от сервера.
Entity Headers (рус. Заголовки сущности) — сопровождают каждую сущность сообщения.
Именно в таком порядке рекомендуется посылать заголовки получателю.

Более подробно о заголовках HTTP можно прочитать здесь. Так же можно ознакомится со списком заголовков HTTP.

От себя лишь добавлю, что, если это явно не указано в требованиях к отправке данных веб-серверу заголовки HTTP для метода GET можно не указывать. Для метода POST обычно нужно указать заголовки Content-Type (тип передаваемых данных, например: "Content-Type: text/html;charset=utf-8") и Content-Length (размер передаваемых данных в байтах, например: "Content-Length: 1348").

Напомню, что HTTP заголовки в 1С указываются строкой в виде текстовых пар "<Заголовок>:<Значение>", разделенных комбинацией символов ВК+ПС.
Также заголовки можно задать типом Соответствие, где в качестве ключа указывается заголовок, а в качестве значения - значение заголовка.
Ниже приведены поясняющие примеры:

Код 1C v 8.х

 источник = "owner=263544&amp;count=100";

 

// Передача заголовков строкой

ЗаголовкиHTTP = "Content-Type:text/html;charset=utf-8" + Символ.ВК + Символ.ПС +

            "Content-Length: "+СтрДлина(источник);

Соединение.Получить("", имяВыходногоФайла, ЗаголовкиHTTP);

 

// Вставить символы ВК+ПС можно и таким способом

ЗаголовкиHTTP = "Content-Type:text/html;charset=utf-8

            |Content-Length: 1348";

Соединение.Получить("", имяВыходногоФайла, ЗаголовкиHTTP);

 

// Установка заголовков типом Соответствие

ЗаголовкиHTTP = Новый Соответствие;

ЗаголовкиHTTP.Вставить("Content-Type", "text/html;charset=utf-8");

ЗаголовкиHTTP.Вставить("Content-Length", СтрДлина(источник));

 

Соединение.Получить(источник, имяВыходногоФайла, ЗаголовкиHTTP);

Передача данных на веб-сервер из 1С методом POST.
Общие сведения.
Для передачи данных на веб-сервер из 1С методом POST используется процедура ОтправитьДляОбработки() объекта HTTPСоединение.

Код 1C v 8.х

 ОтправитьДляОбработки(<Источник>, <АдресРесурса>, <ИмяВыходногоФайла>, <Заголовки>)

<Источник> (обязательный) - Имя файла-источника, который будет отправлен
на сервер для обработки.
<АдресРесурса> (обязательный). Тип - строка. Адрес ресурса на сервере,
в который посылаются данные из источника.
<ИмяВыходногФайла> (обязательный) - Имя файла на диске, в который записываются
полученные с сервера данные.
<Заголовки> (необязательный). Тип - строка. Заголовки, добавляемые к запросу на сервер.
Текстовые пары вида <Заголовок>:<Значение>, разделенные комбинацией ВК + ПС.
(подробнее о заголовках будет сказано ниже).
Рассмотрим параметры процедуры ОтправитьДляОбработки() подробнее:

В качестве источника указывается файл, содержимое которого необходимо отправить на сервер для обработки. Подробнее о формировании содержимого файла-источника будет сказано ниже.

Поле АдресРесурса аналогично полю Источник процедуры Получить(), т.е. указывается строка с адресом запроса, идущая после имени домена и символа "/".

Поле ИмяВыходногоФайла также аналогично одноименному полю процедуры Получить(), т.е. содержит имя файла, в котором будут сохранены данные, полученные от сервера в результате обработки исходных данных.

О заголовках было упомянуто выше. Напомню лишь, что для метода POST обычно указываются заголовки Content-Type и Content-Length. В качестве параметра заголовка Content-Length указывается размер файла-источника, преобразованный с помощью функции XMLСтрока().

Ниже приведен пример, поясняющий все выше сказанное.

Код 1C v 8.х

 имяФайлаОтправки = "d:\data\request.txt"; // файл с отсылаемыми для обработки данными

 

// Определим размер файла-источника

// и установим HTTP заголовки

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "text/html;charset=utf-8");

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml");

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "addPost.php", имяВыходногоФайла, Заголовки);

Передача параметров методом POST.
Для передачи параметров, аналогично методу GET, можно сформировать строку параметров, записать их в текстовый файл и отправить этот файл на сервер для обработки. Ниже приведен пример аналогичный примеру отправки методом GET, но теперь те же данные отправляются методом POST.

Код 1C v 8.х

 // сформируем файл для отправки на сервер

 

имяФайлаОтправки = ПолучитьимяВременногоФайла("txt");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаОтправки);

ЗаписьТекста.Записать("owner=263544&amp;count=100");

ЗаписьТекста.Закрыть();

 

// отправим файл на сервер для обработки

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml"); // наш сервер возвращает ответы в виде XML

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "text/html;charset=utf-8");

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "addPost.php", имяВыходногоФайла, Заголовки);

 

// удалим файл отправки - он больше не нужен

Попытка

    УдалитьФайлы(имяФайлаОтправки);

Исключение

КонецПопытки;

 

// обработаем ответ сервера

 

ЧтениеXML = Новый ЧтениеXML;

ЧтениеXML.ОткрытьФайл(имяВыходногоФайла);

 

Пока ЧтениеXML.Прочитать() Цикл

    // чтение ответа в виде XML файла

    ...

КонецЦикла;

 

ЧтениеXML.Закрыть();

 

// удаляем файл после использования

Попытка

    УдалитьФайлы(имяВыходногоФайла); 

Исключение

КонецПопытки;

Передача файлов методом POST.
Зачастую данные для обработки задаются не виде строки параметров разделенных "&", как в рассматриваемых выше примерах, а виде файла определенного формата, например XML или JSON. Рассмотрим пример отправки данных на веб-сервер для обработки методом POST, которые задаются в формате XML. Например, сервер может добавить ваш комментарий к материалу. В описании процедуры добавлении сказано, что данные необходимо отправлять по адресу www.mysite.com/addComment.php. Сами данные должны быть переданы в следующем виде:

Код

<?xml version="1.0" encoding="UTF-8"?>
<request>
<user_id>ID_Пользователя</user_id>
<post_id>ID_Материала</post_id>
<message>Текст_Комментария</message>
</request>

где:
<ID_Пользователя> - id пользователя на сайте, от имени которого добавляется комментарий;
<ID_Материала> - id материала на сайте, к которому добавляется комментарий;
<Текст_Комментария> - текст комментария.

Предположим, что нам уже известны id пользователя и материала и они хранятся в переменных user_id и post_id. Ниже приведен пример, решающий нашу задачу.

Код 1C v 8.х

 // подготовим файл с данными для отправки

имяФайлаОтправки = ПолучитьимяВременногоФайла("xml");

 

ОбъектXML = Новый ЗаписьXML;

ОбъектXML.ОткрытьФайл(имяФайлаОтправки, "UTF-8");

ОбъектXML.ЗаписатьОбъявлениеXML();

ОбъектXML.ЗаписатьБезОбработки(

"<request>

|    <user_id>" + user_id + "</user_id>

|    <post_id>" + post_id + "</post_id>

|    <message>" + ТекстКомментария + "</message>

|</request>");

ОбъектXML.Закрыть();

 

// отправим файл на сервер для обработки

 

имяВыходногоФайла = ПолучитьимяВременногоФайла("xml"); // наш сервер возвращает ответы в виде XML

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "text/html;charset=utf-8");

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "addComment.php", имяВыходногоФайла, Заголовки);

 

// удалим файл отправки - он больше не нужен

Попытка

    УдалитьФайлы(имяФайлаОтправки);

Исключение

КонецПопытки;

 

// обработаем ответ сервера

 

ЧтениеXML = Новый ЧтениеXML;

ЧтениеXML.ОткрытьФайл(имяВыходногоФайла);

 

Пока ЧтениеXML.Прочитать() Цикл

    // чтение ответа в виде XML файла

    ...

КонецЦикла;

 

ЧтениеXML.Закрыть();

 

// удаляем файл после использования

Попытка

    УдалитьФайлы(имяВыходногоФайла); 

Исключение

КонецПопытки;

Загрузка файлов (изображений, документов и т.п.) на веб-сервер методом POST.
Зачастую возникает необходимость загрузки файлов на веб-сервер. Это может быть, например, изображение к статье на сайте, или фотография для альбома, или архив для файлообменника. Ранее мы рассматривали передачу методом POST параметров или просто файлов. Таким же образом можно и передавать двоичные файлы. Но как быть, если файлы необходимо отправлять вместе с параметрами? Для возможности отправки файлов в этом случае используется HTTP заголовок ContentType:multipart/form-data. Следует заметить, что обычно таким способом передаются файлы через веб-браузеры. Т.е. когда на сайте вы выбираете файл и нажимаете кнопку "Загрузить", то файл передается способом описанным ниже. При таком способе сам файл также задается как переменная, т.е., например, файл передается через параметр file или image. Однако, мы не можем просто передать file=<Двоичные_Данные>. А вот как все таки передать файл мы и рассмотрим ниже.

Для возможности вместе с параметрами передавать и двоичные данные (файлы) необходимо сформировать HTTP заголовок Content-Type следующим образом:
Content-Type: multipart/form-data, boundary=<уникальные_данные>
где <уникальные_данные> - это любой набор цифр и/или символов, который будет служить для отделения значений друг от друга. Значение boundary должно быть уникальным в пределах пересылаемой информации, т.е. таких символов не должно встречаться в пересылаемых файлах и переменных.

Bounday можно сформировать, например, таким образом

Код 1C v 8.х

 boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

Все данные отделяются друг от друга разделителем boundary. Начинать разделитель нужно с "--":

Код

--<boundary>
Content-Disposition: form-data; name="<имя_переменной>"
<пустая_строка>
<значение_переменной>
Для отправки файла необходимо еще добавить тип и имя файла:

--<boundary>
Content-Disposition: form-data; name="<имя_переменной>"; filename="<имя_файла>"
Content-Type: <тип_файла> (например image/jpeg или text/plain)
<пустая_строка>
<данные_файла>

В конце данных нужно закрыть разделитель, добавили в конце разделителя "--", т.е. вид будет "--<boundary>--".

Итак, например, нам нужно передать на веб-сервер текстовый файл через параметр "text", его описание через параметр "desc" и id пользователя через параметр "uid", для которого будет загружен наш файл.

Предположим, что файл содержит следующий текст:
Мороз и солнце; день чудесный!
Еще ты дремлешь, друг прелестный -
Пора, красавица, проснись:
Открой сомкнуты негой взоры
Навстречу северной Авроры,
Звездою севера явись!
Описание должно содержать "Стих А.С. Пушкина", а id пользователя равно "0123456". Тогда файл должен быть сформирован следующим образом (для упрощения предположим, что bounday мы уже сформировали и он равен "ccf8111910")

Код

--ccf8111910
Content-Disposition: form-data; name="uid"

0123456
--ccf8111910
Content-Disposition: form-data; name="desc"

Стих А.С. Пушкина
--ccf8111910
Content-Disposition: form-data; name="text"; filename="stih.txt"
Content-Type: text/plain

Мороз и солнце; день чудесный!
Еще ты дремлешь, друг прелестный -
Пора, красавица, проснись:
Открой сомкнуты негой взоры
Навстречу северной Авроры,
Звездою севера явись!
--ccf8111910--

А теперь перейдем непосредственно к 1С. Пусть у нас будет форма с реквизитами "Пользователь", "Описание" и "ИмяФайла". Реализуем отправку данных, описанным выше способом

Код 1C v 8.х

 // подготовим файл с данными для отправки

имяФайлаОтправки = ПолучитьимяВременногоФайла("txt");

Boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаОтправки);

 

// параметр "uid"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""uid""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(Пользователь);

 

// параметр "desc"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""desc""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(Описание);

 

// параметр "text"

ФайлДляПередачи = Новый ТекстовыйДокумент;

ФайлДляПередачи.Прочитать(имяФайла);

 

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""text""; filename=""stih.txt""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: text/plain");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.Записать(ФайлДляПередачи.ПолучитьТекст());

ЗаписьТекста.ЗаписатьСтроку("");

 

// закроем разделитель

ЗаписьТекста.ЗаписатьСтроку("--"+boundary+"--");

 

ЗаписьТекста.Закрыть();

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

// передадим данные на сервер 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "multipart/form-data, boundary="+boundary);

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "postFile.php", имяВыходногоФайла, Заголовки);

Передача текстовых файлов таким способом проблем не вызывает. Сложнее дело обстоит с файлами, содержащими двоичные данные (изображения, архивы и т.п.). Все дело в том, что в 1С просто нет методов для чтение двоичных файлов в строку. Если мы делаем обмен со своим сайтом, которые сами и разрабатывали, то можно просто преобразовать файл в строку Base64 при помощи процедуры Base64Строка(), а на стороне сервера преобразовать строку Base64 обратно.

Код 1C v 8.х

 // подготовим файл с данными для отправки

имяФайлаДанных = "d:\photo\birthday.jpg";

 

имяФайлаОтправки = ПолучитьимяВременногоФайла("txt");

Boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаОтправки);

 

// параметр "file"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""file""; filename=""photo.jpg""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: image/jpeg");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.Записать(Base64Строка(Новый ДвоичныеДанные(имяФайлаДанных)));

ЗаписьТекста.ЗаписатьСтроку("");

 

// закроем разделитель

ЗаписьТекста.ЗаписатьСтроку("--"+boundary+"--");

 

ЗаписьТекста.Закрыть();

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

// передадим данные на сервер 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "multipart/form-data, boundary="+boundary);

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "uploadFile.php", имяВыходногоФайла, Заголовки);

А как же быть если мы загружаем файл на сторонний сервер, который принимает файл как есть без преобразование его в строку Base64(). В это случае можно пойти на хитрость. В 1С есть процедура ОбъединитьФайлы(), которая объединяет несколько файлов на диске в один результирующий файл

Код 1C v 8.х

 ОбъединитьФайлы(<ИменаЧастей>, <ИмяРезультирующегоФайла>)

<ИменаЧастей> (обязательный). Тип - Массив. Массив имен частей файлов, которые
требуется объединить. Объединение будет происходить в порядке, в котором заданы
имена файлов в массиве.
<ИмяРезультирующегоФайла> (обязательный). Тип - Строка. Имя файла, который будет
создан в результате объединения файлов.
Т.е. мы можем сформировать текстовый файл с запросом, объединить его с файлом(-ами), которые необходимо передать на веб-сервер и передать уже файл, получившийся в результате объединения исходных файлов. Ниже демонстрируется процесс передачи двух zip архивов на сервер с дополнительными параметрами user_id и post_id.

Код 1C v 8.х

 // подготовим файлы с данными для отправки

 

массивФайлов = Новый Массив;

 

Boundary = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", "");

 

имяФайлаСПараметрами = ПолучитьимяВременногоФайла("txt"); // первый файл, содержащий параметры

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаСПараметрами);

 

// параметр "user_id"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""user_id""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(user_id);

 

// параметр "post_id"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""post_id""");

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку(post_id);

 

// начало параметра "file1"

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""file1""; filename=""archive1.zip""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: application/x-zip-compressed");

ЗаписьТекста.ЗаписатьСтроку("");

 

ЗаписьТекста.Закрыть(); // заканчиваем работу с файлом 1

 

массивФайлов.Добавить(имяФайлаСПараметрами); // добавляем 1-ый файл для объединения

массивФайлов.Добавить(имяФайлаАрхива1); // добавляем 1-ый архив для объединения

 

// второй файл параметров, содержаший начало параметра "file2"

имяФайлаСПараметрами = ПолучитьимяВременногоФайла("txt");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаСПараметрами);

 

// начало параметра "file2"

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку("--"+boundary);

ЗаписьТекста.ЗаписатьСтроку("Content-Disposition: form-data; name=""file2""; filename=""archive2.zip""");

ЗаписьТекста.ЗаписатьСтроку("Content-Type: application/x-zip-compressed");

ЗаписьТекста.ЗаписатьСтроку("");

 

ЗаписьТекста.Закрыть(); // заканчиваем работу с файлом 2

 

массивФайлов.Добавить(имяФайлаСПараметрами); // добавляем 2-ой файл для объединения

массивФайлов.Добавить(имяФайлаАрхива2); // добавляем 2-ой архив для объединения

 

ЗаписьТекста.Записать(ФайлДляПередачи.ПолучитьТекст());

ЗаписьТекста.ЗаписатьСтроку("");

 

// третий файл, закрывающий параметры

имяФайлаСПараметрами = ПолучитьимяВременногоФайла("txt");

 

ЗаписьТекста = Новый ЗаписьТекста(имяФайлаСПараметрами);

 

ЗаписьТекста.ЗаписатьСтроку("");

ЗаписьТекста.ЗаписатьСтроку("--"+boundary+"--");

 

ЗаписьТекста.Закрыть(); // заканчиваем работу с файлом 3

 

массивФайлов.Добавить(имяФайлаСПараметрами); // добавляем 3-ий файл, закрывающий параметры

 

// результирующий файл, который и будет отправлен

имяФайлаОтправки = ПолучитимяВременногоФайла("out");

 

// объединим все файлы

ОбъединитьФайлы(массивФайлов, имяФайлаОтправки);

 

ФайлОтправки = Новый Файл(имяФайлаОтправки);

РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

 

// передадим данные на сервер 

Заголовки = Новый Соответствие();

Заголовки.Вставить("Content-Type", "multipart/form-data, boundary="+boundary);

Заголовки.Вставить("Content-Lenght", РазмерФайлаОтправки);

 

Соединение = Новый HTTPСоединение("www.mysite.com");

Соединение.ОтправитьДляОбработки(имяФайлОтправки, "postFile.php", имяВыходногоФайла, Заголовки);

Ну вот, вроде бы, и все, что я хотел рассказать о способах передачи файлов и данных на веб-сервер из 1С. Если что-то не понятно, что-то хотите уточнить или нашли ошибки - пишите в комментариях.
Автор: Павел

Категория: Работа с Интернет, Почтой (Mail), FTP

Печать штрихкода в управляемом приложении

Программируя под 8.2, работающем в режиме управляемого приложения, я столкнулся с проблемой печати штрихкода. Для платформы 8.1 и платформы 8.2 в режиме обычного приложения такой проблемы не было: устанавливаем элемент «1С:Печать штрихкодов» в макет и наслаждаемся вертикальными черточками. В режиме управляемого приложения вываливается ошибка:

Код 1C v 8.2 УП

 ОбластьВывода.Рисунки.ШтрихКод.Объект – неопределено

Что же случилось?
Дело в том, что для управляемого приложения внешние компоненты разрабатываются по другой технологии. Пример внешней компоненты для печати штрих-кода в 8.2 есть в демонстрационной конфигурации "Управляемое приложение" в макетах справочника Товары либо в конфигурации «1С:Управление торговлей» версии 11, макеты обработки «Печать этикеток и ценников».
Данная компонента, получив в качестве параметра строку штрихкода, возвращает картинку – штрихкод, которую программисту предлагается поместить в любое удобное место печатной формы.

Теперь как это сделать.
Всего обработок аж четыре штуки:
КомпонентаПечатиШтрихкодовWindows32
КомпонентаПечатиШтрихкодовWindows64
КомпонентаПечатиШтрихкодовLinux32
КомпонентаПечатиШтрихкодовLinux64

Все они загружены в одноименные макеты. Функция, подключающая внешнюю компоненту в зависимости от платформы может выглядеть так:

Код 1C v 8.х

 Функция ПодключитьВнешнююКомпонентуПечатиШтрихкода() Экспорт

	

	// В зависимости от типа платформы подключим соответствующую внешнюю компоненту

	СистемнаяИнформация = Новый СистемнаяИнформация;



	Если СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Windows_x86 Тогда

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовWindows32", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	ИначеЕсли СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Windows_x86_64 Тогда

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовWindows64", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	ИначеЕсли СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Linux_x86 Тогда

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовLinux32", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	Иначе

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовLinux64", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	КонецЕсли;



	// Создадим объект внешней компоненты

	Если ПодключениеВыполнено Тогда

		ВнешняяКомпонента = Новый("AddIn.КартинкаШтрихкода.Barcode");

	Иначе

		Возврат Неопределено;

	КонецЕсли;

	

	// Если нет возможности рисовать

	Если НЕ ВнешняяКомпонента.ГрафикаУстановлена Тогда

		// То картинку сформировать не сможем

		Возврат Неопределено;

	Иначе

		

		// Установим основные параметры компоненты

		

		// Если в системе установлен шрифт Tahoma

		Если ВнешняяКомпонента.НайтиШрифт("Tahoma") = Истина Тогда

			// Выбираем его как шрифт для формирования картинки

			ВнешняяКомпонента.Шрифт = "Tahoma";

		Иначе

			

			// Шрифт Tahoma в системе отсутствует

			// Обойдем все доступные компоненте шрифты

			Для Сч = 0 По ВнешняяКомпонента.КоличествоШрифтов -1 Цикл

				// Получим очередной шрифт, доступный компоненте

				ТекущийШрифт = ВнешняяКомпонента.ШрифтПоИндексу(Сч);

				// Если шрифт доступен

				Если ТекущийШрифт <> Неопределено Тогда

					// Они и будет шрифтом для формирования штри-кода

					ВнешняяКомпонента.Шрифт = ТекущийШрифт;

					Прервать;

				КонецЕсли;

			КонецЦикла;

		КонецЕсли;

		

		// Утановим размер шрифта

		ВнешняяКомпонента.РазмерШрифта = 10;

		

		Возврат ВнешняяКомпонента;

		

	КонецЕсли;

	

КонецФункции

В коде выше все компоненты загружены в макеты обработки «ПечатьЭтикетокИЦенников». В принципе ничто не мешает поместить их в любое иное место. Вызов функции осуществляется командой:

Код 1C v 8.х

 ВнешняяКомпонента = ПодключитьВнешнююКомпонентуПечатиШтрихкода();

Если что-то не получилось – возвращает НЕОПРЕДЕЛЕНО.

Далее опишем функцию, которая, получив данные, сформирует нужную нам картинку с штрихкодом:

Код 1C v 8.х

 Функция ПолучитьКартинкуШтрихкода(ВнешняяКомпонента, Штрихкод, Ширина, Высота) Экспорт

	

	// Зададим размер картинки

	ВнешняяКомпонента.Ширина =Ширина;

	ВнешняяКомпонента.Высота =Высота;

	

	// Разрешим компоненте самой определять тип кода

	ВнешняяКомпонента.АвтоТип = истина;

	

	// Если код содержит контрольный символ, обязательно указываем

	ВнешняяКомпонента.СодержитКС = СтрДлина(Штрихкод) = 13;

	

	// Если отображать контрольный символ не нужно

	// ВнешняяКомпонента.ВидимостьКС = Ложь;

	

	// Формируем картинку штрихкода

	ВнешняяКомпонента.ЗначениеКода = Штрихкод;

	

	// Если установленная нами ширина меньше минимально допустимой для этого штрихкода

	Если ВнешняяКомпонента.Ширина < ВнешняяКомпонента.МинимальнаяШиринаКода Тогда

		// Скорректируем ширину

		ВнешняяКомпонента.Ширина = ВнешняяКомпонента.МинимальнаяШиринаКода + 10;

	КонецЕсли;

	

	// Сформируем картинку

	ДвоичныеДанныеКартинки = ВнешняяКомпонента.ПолучитьШтрихкод();

	

	// Если картинка сформировалась

	Если ДвоичныеДанныеКартинки <> Неопределено Тогда

		// Формируем из двоичных данных

		Возврат Новый Картинка(ДвоичныеДанныеКартинки);

	КонецЕсли;

	

	Возврат Неопределено;

	

КонецФункции

В данной функции используется автоопределение типа штрихкода командой

Код 1C v 8.х

 ВнешняяКомпонента.АвтоТип = истина;

Можно тип штрихкода указать вручную:

Код 1C v 8.х

 ВнешняяКомпонента.АвтоТип = Ложь;

ВнешняяКомпонента.ТипКода = 1; // указан тип EAN13

ТипКода - число от 0 до 15: 0 - EAN8, 1 - EAN13, 2 - EAN128. Вот полный список типов по порядку:
EAN8, EAN13, EAN128, Code39, Code128, Code16k, PDF417, Standart (Industrial) 2 of 5, Interleaved 2 of 5, Расширение Code39, Code93, ITF14, RSS14, CodaBar, EAN13 AddOn 2, EAN13 AddOn 5.

Кроме типа штрихкода, компонента имеет ряд других свойств, например ВнешняяКомпонента.ОтображатьТекст, ВнешняяКомпонента.РазмерШрифта и прочие, можно посмотреть в свойствах.

Наконец последнее - вывод штрихкода. Для этого в макет поместим картинку с именем «Штрихкод». Получаем и выводим штрихкод в область командой:

Код 1C v 8.х

 ОбластьЗначение.Рисунки.Штрихкод.Картинка = ПолучитьКартинкуШтрихкода(ВнешняяКомпонента, Штрихкод, 50, 30);

Где Штрихкод – переменная, содержащая строку штрихкода номенклатуры, 50 – требуемая ширина, 30 – высота картинки. В макете размер картинки лучше всего поставить «Реальный размер».

Замечание. Сразу бросается в глаза то, что я вручную указываю размер требуемой картинки – 50 на 30. Возникает вопрос, а нельзя ли размеры требуемой картинки получить из картинки на макете? Конечно можно:

Код 1C v 8.х

 ОбластьЗначение.Рисунки.Штрихкод.Ширина

ОбластьЗначение.Рисунки.Штрихкод.Высота

К сожалению, цифры получаемые этими командами почему-то слишком малы. Как получить реальный видимый размер картинки я пока не знаю, может кто подскажет?
Источник

Категория: Штрих-код (barcode)

Ошибочное формирование регистра налогового учета по НДФЛ

У меня релиз 7.70.318 от 19.12.2011. Меня интересует вопрос, почему в отчете "Регистр налогового учета по НДФЛ" при ситуации, когда у сотрудника доход меньше чем налоговые вычеты в разделе 5, во-первых, неправильно указывается сумма налоговых вычетов в последнем месяце, а во-вторых, она с копейками.
Например:
ОКАТО / КПП Код вычета Сумма вычета
65478000000/661501001 103 4 800.00
65478000000/661501001 114 12 000.00
65478000000/661501001 115 10 072.23
Итого: 26 872.23
На сколько я понимаю налоговые вычеты не могут быть с копейками(кроме 311 кода). На второго ребенка тоже должно было встать 12 000.00, а тут какая то разница непонятная?!
До этого релиза у меня был релиз 7.70.313 и все правильно формировалось, но когда добавились новые налоговые вычеты начались проблемы. Что мне сделать? Какие изменения нужно внести чтобы отчеты по НДФЛ формировались правильно.

Категория: 1С Зарплата и Управление Персоналом 2.5

Как отразить доходы учредителя в программе, чтобы сформировалась справка 2-НДФЛ?

Чтобы отобразить доход учредителя в программе 1С нужно:
1. Добавить учредителя в справочник ФизЛиц
2. Внести его доходы и налоги документом:
В Бухгалтерии:
Зарплата - Учет НДФЛ и Налогов с ФОТ - Документы учета НДФЛ и Налогов с ФОТ
Кнопка добавить и в списке документ Ввод Доходов, НДФЛ и Налогов с ФОТ
В ЗУПе :
Расчет зарплаты по организациям - Налоги и взносы - Корректировка учета НДФЛ и Страхов. Взносов

3. Далее, как обычно, формируете справку 2-НДФЛ

Категория: 1С Бухгалтерия 2.0

ПолеHTMLДокумента ~ Программное формирование HTML-документа, содержащего Ссылки на объекты БД

Программное формирование HTML-документа, содержащего ссылки на объекты базы данных 1С
В данной статье рассматривается способ программного формирования HTML документа, содержащего ссылки на объекты базы данных 1С, такие как справочники, документы и т.д. Показан пример построения обработчика события OnClick ПоляHTMLДокумента, для обработки клика на html-ссылке.

Предисловие
Однажды, дописывая обработку, создающую и модифицирующую, не суть важно какие документы, я подумал, что неплохо было бы вывести для пользователя некое резюме:
“Создан документ такой-то”
“Изменен документ такой-то” и т.д.
От обычного, в таких случаях, вывода информации в окно сообщений я сразу отказался, так как не удобно это, сначала читать в окне сообщений “Создан документ … ” а потом запоминать его номер, открывать соответствующий журнал (или форму списка) и искать там этот документ. А если документов много и пользователь хочет посмотреть все документы?(или выборочно) Насколько это неудобно я убедился при отладке обработки …
То, что в форме есть элемент управления именуемый ПолеHTMLДокумента я конечно знал, но вот представилась возможность познакомиться с ним поближе. Было решено реестр обработанных документов выводить в виде html документа содержащего ссылки на эти самые документы, а по клику на ссылке открывать форму соответствующего документа. Здесь мне многие могут возразить: “А почему бы для этих целей не использовать обычный макет, выводимый в табличный документ, а для открытия документов использовать расшифровку? И чем Ваш способ лучше?” Отвечаю: Конечно можно использовать, и мой способ ничем не лучше. Он просто другой. Ведь у хорошего программиста для решения одной задачи должно быть в арсенале несколько инструментов.
Итак, перейдем от слов к делу, в рамках данной статьи рассмотрим следующую задачу: Сформировать html-документ, содержащий ссылки на элементы справочника номенклатура, по клику требуется открывать форму соответствующего элемента. Создаем новый отчет, его форму, на форме размещаем элемент управления ПолеHTMLДокумента.

Код 1C v 8.х

 Процедура ДобавитьТекстHTML(ТекстHTML, Элемент);

    // Ссылку будем формировать хитро:

    // Предполагаем что символ "-" не входит в имена объектов метаданных, 

    // учавствующих в формировании html

    // Тогда ссылка будет иметь следующий вид: 

    // Номенклатура-d341d377-b3b1-11dc-a100-0011d85708ff

    // Передавать нашу ссылку будем через атрибут id

    СсылкаНаЭлемент = Элемент.Метаданные().Имя+"-"

    +Элемент.Ссылка.УникальныйИдентификатор();

    ТекстHTML.ДобавитьСтроку("<A id=""" + СсылкаНаЭлемент + """ href= """ 

    + Элемент + """ >"+Элемент+"</A><BR>");

КонецПроцедуры



Процедура ДействияФормыСформировать(Кнопка)

    Запрос = Новый Запрос("

    |ВЫБРАТЬ

    |    Номенклатура.Ссылка

    |ИЗ

    |    Справочник.Номенклатура КАК Номенклатура");

    ТекстHTML = Новый ТекстовыйДокумент;

    Выборка = Запрос.Выполнить().Выбрать();

    Пока Выборка.Следующий() Цикл

        ДобавитьТекстHTML(ТекстHTML, Выборка.Ссылка);

    КонецЦикла;

ЭлементыФормы.ПолеHTMLДокумента.УстановитьТекст(ТекстHTML.ПолучитьТекст());

КонецПроцедуры

Код 1C v 8.х

 // Функция получает элемент - <A> по данному элементу

// Производит поиск элемента <A> среди родительских элементов данного

//

// Параметры:

// Элемент - COMОбъект, элемент HTML документа,

// по которому нужно найти ссылку

//

// Возвращаемое значение:

// COMОбъект - если ссылка обнаружена, иначе - Неопределено



Функция НайтиСсылку(Элемент)

    Врем = Элемент;

    Пока Врем <> Неопределено Цикл

        Если НРег(Врем.tagName) = "a" Тогда

            Возврат Врем;

        КонецЕсли;

        Врем = Врем.parentElement;

    КонецЦикла;

    Возврат Неопределено;

КонецФункции    // НайтиСсылку(Элемент)



Процедура ПолеHTMLДокументаonclick(Элемент, pEvtObj)

    htmlElement = НайтиСсылку(pEvtObj.srcElement);

    // Анализируем если произошло нажание не ссылку

    Если htmlElement <> Неопределено Тогда

        // Если у ссылки есть идентификатор

        Если СокрЛП(htmlElement.id) <> "" Тогда

            // Получаем адрес ссылки из атрибута id

            СсылкаНаЭлемент = htmlElement.id;

            Разделитель = Найти(СсылкаНаЭлемент,"-");

            Если Разделитель > 0 Тогда

                // Получаем тип элемента

                ТипЭлемента = Лев(СсылкаНаЭлемент,Разделитель-1);

                // Получаем УникальныйИдентификатор

                ГУИД = Сред(СсылкаНаЭлемент,Разделитель+1);

                Справочники[ТипЭлемента].ПолучитьСсылку(

             Новый УникальныйИдентификатор(ГУИД)).ПолучитьФорму().Открыть();

            КонецЕсли;

            // Не отработали нажатие

            pEvtObj.returnValue = Ложь;

        КонецЕсли;

    КонецЕсли;

КонецПроцедуры

Всё можно пробовать ( Скачивать файлы может только зарегистрированный пользователь!

) !

Заключение
Обратите внимание что ссылку я формировал следующим образом:
<ИмяОбъектаМетаданных>-<УникальныйИдентификатор> это сделано для того, чтобы в обработчике onclick можно было определить к какому объекту метаданных относится данный УникальныйИдентификатор, потому что имея ТОЛЬКО УникальныйИдентификатор невозможно определить к какому объекту метаданных он относиться. Точнее возможно, но уж слишком долго и неудобно – путем перебора всех метаданных в цикле, для каждого объекта метаданных выполнять попытку <ОбъектМетаданных>.ПолучитьСсылку(Новый УникальныйИдентификатор(НашУникальныйИдентификатор))
Хотя в нашем примере только один справочник, и указывать его вид было необязательно, и так понятно что это УникальныйИдентификатор элемента справочника Номенклатура, но вдруг Вам потребуется работать с несколькими справочниками, вот тут то мой способ задания ссылки Вам и пригодится.
P.S. Платформа 8.2 имеет встроенный механизм работы со ссылками на объекты БД и данная задача наверняка упростится, но это уже другая тема.
Источник

Категория: Работа с Формой (Диалог) и её элементами

Как сделать, чтобы при открытии отчет сразу Сформировался?

Код 1C v 8.х

 // Сформируем отчет СКД, сразу при открытии, чтобы не нажимать кнопку сформировать

Процедура ПриОткрытии()

    // Вставить содержимое обработчика. 

     ОтчетОбъект.СкомпоноватьРезультат(ЭлементыФормы.Результат);

КонецПроцедуры

Код 1C v 8.2 УП

 СкомпоноватьРезультат()

Категория: Схема Компоновки Данных

Настройка обмена УТ в БП через План обмена

На примере демо базы УТ и чистой базы БП:

1. Заходим в УТ - Сервис — Обмена данными с 1С Бухгалтерия 8 — Настройка обмена.
В данном случае файловый вариант. Прописываем путь к базе БП.
title

2. Один из самых важных параметров Перенос себестоимости списания. Для того, чтобы себестоимость формировалась по данным конфигурации БП выбираем Не переносить, т.к. в конфигурацию БП могут быть введены док которые отсутствуют в УТ. Если выбрать Переносить, то колонки Документ оприходования и Сумма списания в док Реализация будут заполнены данными из УТ.
title

3. Далее укажем дату начала обмена и префикс документов. Префикс Базы будет прибавляться к Префиксу организации, так что количество символов для нумерации уменьшится. Лучше задавать Префикс базы и Префикс организации из одного символа.

title

4. Не будем делать полную синхронизацию (не известно сколько времени это займет, да и зачем), а выберем вариант в Фоновом режиме. По кнопке Дополнительно можно изменить количество объектов принудительной синхронизации. Оставим без изменения = 500.
title

5. По кнопке Готово произойдет создание элемента справочника НастройкаОбменаДанными и элменета Плана обмена. Будет предложено произвести обмен. Жмем НЕТ. На рисунке показан элемент справочника НастройкаОбменаДанными и ссылка на узел, элемент Плана обмена.
title

6. Теперь, если закрыть все окна, то узел обмена можно зайти Сервис - Обмен данными с 1С Бухгалтерия 8 — Выполнить обмен данными. Изменим правила. Поставим дату обмена с 01.06.2007 и обменяемся малым количеством документов.
title

7. Пока мы не собираемся включать автообмен и закладки Автообмен и Доп настройки автообмена для нас не важны. Перейдем на закладку Дополнительно. По умолчанию Элементов в транзакции = 0. т.е. при обмене будет записываться каждый элемент по отдельности. Это не оптимально. Вспоминаем, что при Проведении по партиям 1С автоматически предлагает 1000. Выбирайте значение от 200 до 1000.

title

8. Поскольку это наш первый обмен никакие изменения в базе НЕ зарегистрированы и если мы сразу сделаем обмен, то в него попадут только справочники и регистры сведений. Есть два способа регистрации изменений для выгрузки:
- перепроведение документов,
- обработкой Регистрация изменений для обмена.

9. Поскольку перепровести документы несложно рассмотрим работу с обработкой. Заходим в обработку (как показано на рисунке для релиза 10.3.5 или для релизе 10.3.6 в обработку через интерфейс не зайти, только Операции – Обработка – Регистрация изменений – Обмен данными управление торговлей бухгалтерия) и нажимаем кнопку «Зарегистрировать все – Для всех элементов». Несмотря на то, что изменения зарегистрированы для всех объектов и в табличной части обработки это видно, обмен произойдет с ограничением по дате в Плане обмена, т.е. с 01.06.07.
title

10. Галочка «Отображать объекты, для кот зарег изм» означает, что под всеми типами объектов обмена (Справочниками, Регистрами, Документами) мы получим ВСЕ ссылки на объекты обмена (например, док Реализация). Если нам необходимо посмотреть какие объекты обмениваются, то можно встав на тип объекта, например, РеализацияТоваровУслуг, нажать кнопку «Показать зарегистрированные изменения данного типа». Даже для демо база показ всех реализаций (их очень мало) подвисает на 1 минуту. Если нужно удалить объект из обмена, в данном случае документ Реализации, то нажимаем Ctrl + C.
title

11. В нашем случае уже все изменения зарегистрированы. Информация для ознакомления: есть возможность по кнопке «Добавить документы для обмена». Например, Расходный кассовый ордер. При этом программа предложит зарегистрировать все объекты данного типа (т.е. все Расходные кассовые ордера). Ответив «НЕТ» получим возможность подобрать документы вручную.
title

12. И еще маленький нюанс. Кнопка «Изменить номера» сообщений изменяет порядковый номер обмена. Это нужно если мы восстановили базу из архива и, соответственно, нумерация сообщений там будет старая.
title

13. Нажимаем «Выполнить обмен». При этом в базе БП можно работать. Все документы загружаются не проведенными.
title

14. После первого обмена, если зайти в Регистрацию изменений для обмена то можно увидеть, что все наши объекты так и остались зарегистрированными для обмена. Се ля 1С. Только после проведения второго обмена объекты уйдут из регистрации (т.е. база УТ получит подтверждение о том, что объекты успешно загружены в БП). Так, что нажимаем Выполнить обмен еще раз.

15. Теперь в базе БП у нас появились не проведенные документы. Заходим в БП Сервис – Проведение документов – выбираем “Проведенные и непроведенные” и период. Здесь внимательно. Надо предупредить пользователей, что сделать документ не проведенным не достаточно. Не нужные документы необходимо, помечать на удаление, а еще лучше регулярно удалять.

16. Не забывайте, если вы удалите «Узел обмена», то в базе останется «План обмена» и привязанный к нему регистр сведений «Соответствие объектов для обмена» останется целым. Регистр придется удалять как-нибудь самим. Такова воля создателя обмена.

Категория: Конвертация данных, Обмен, Перенос

Персонифицированный учет НР и УСЕН

Столкнулся с проблемой:
Все начисления по страховым и накопительным взносам попадают только в пачку СЗВ6-2 для категории НР, а пачка СЗВ6-2 для категории УСЕН создается,но взносов нет.
Бухгалтерия 1С 7.7 рел.516

Ответ:
Для того чтобы формировалось УСЕН Вам нобходимо:
1. Зайдите в Операции - Константы
2. Основной тариф Страховых взносов - установить плательщик ЕНВД, далее нажмите F5, вы попадете в истоию переодических реквизитов - здесь установите так чтобы "Организация является плательщиком ЕНВД" - было с 01.01.10
3. Проверьте консанту Организация является плательщиком ЕНВД - должно быть Да
Теперь перезаполняйте пачки...

Категория: 1С Бухгалтерия 2.0