ширине » Поиск

Результаты по ключевому слову: ширине

Как уменьшить вес картинок в базе данных или изменить размер, ширину или высоту картинок?

Иногда возникает необходимость обработать фотографии в 1С автоматически, уменьшить вес картинок в килобайтах, за счет удаления из файла не нужной технической информации и сглаживания цветов, или изменить размер, уменьшить картинку пропорционально задав максимальный размер по ширине или высоте.В этом случае можно:1) установить специальные библиотеки в операционной системе для работы с графикой, н-р GFLAx и подключать их как com-объекты2) использовать api сервисов, таких как optipic.io.

Рассмотрим оба варианта:1) Использование GFLAxСкачиваем и устанавливаем библиотеку GFLAx, скачать можно здесь https://www.xnview.com/en/#downloads

Далее её надо зарегистрировать в Windows. Для этого запускаем CMD.exe с правами администратора и набираем: regsrv32 "путь_к_DLL\GFLAx.dll"Далее уже в программе, для пропорционального изменения размера файла до максимального размера в 500 пикселей можно вставить такой код:

Код 1C v 8.х

 GFLAx = Новый COMОбъект("GFLAx.GFLAx");

GFLAx.LoadBitmap(ИмяИсходногоФайла);

// Получаем исходный размер картинки

Ширина = GFLAx.Width;

Высота = GFLAx.Height;

//определяем максимальную сторону по которой будем проводить пропорциональное изменениеДелитель= ?(Ширина>Высота, Делитель=Ширина/500, Делитель=Высота/500);

НоваяШирина = Ширина/Делитель;

НоваяВысота = Высота/Делитель;

GFLAx.Resize(Цел(НоваяШирина),Цел(НоваяВысота));

GFLAx.SaveBitmapИмяВыходногоФайла);

Данный способ требует специальных настроек операционной системы, навыков системного администрирования и данный способ не проводит полноценную оптимизацию картинки.Кроме того, на компьютере или сервере, где производиться оптимизация эта библиотека должна быть установлена.2) Использование сервиса optipic.ioПодобные сервисы обычно платные, но стоимость использования не высокая, а качество и гибкость существенно выше.

Преимущества использования сервиса optipic.io в проектах 1С:

Легко подключить
Не нужно устанавливать дополнительные библиотеки в операционной системе
Можно использовать как для оптимизации изображений, так и для изменения размера изображения в пикселях (ресайз)
Не зависит от операционной системы и типа используемого клиента
Конфигурация будет работать после переезда на другой компьютер или сервер
Качество и эффективность сжатия производятся в самом оптимальном виде

Использование сервиса можно легко встроить в любой свой проект на 1С. Для этого можно добавить себе функцию, в которую передавать имя файла с исходной картинкой и параметры оптимизации. А в качестве ответа получить имя файла уже оптимизированного сервисом.

Пример такой функции для 1C8:

Код 1C v 8.х

 Функция ОптимизироватьКартинку(ФайлКартинкиИсходный, Качество=70, НужноИзменятьРазмер=Ложь, МаксимальнаяШирина=1000, МаксимальнаяВысота=1000) Экспорт

	ssl = Новый ЗащищенноеСоединениеOpenSSL(Неопределено, Неопределено); 

	email  = "ВашEmail";

	Пароль = "ВашПароль";

	Соедиенение = Новый HTTPСоединение("optipic.io", , email, Пароль, , ,ssl);

	СкриптНаСайте = "api/compress?quality="+Качество+"&from=1c";

	Если НужноИзменятьРазмер Тогда

		СкриптНаСайте = СкриптНаСайте + "&maxwidth="+Формат(МаксимальнаяШирина, "ЧГ=")+"&maxheight="+Формат(МаксимальнаяВысота, "ЧГ=");

	КонецЕсли;

	

	НовыйФайлКартинки = ПолучитьИмяВременногоФайла();

	

	Попытка

		Результат  = Соедиенение.ОтправитьДляОбработки(ФайлКартинкиИсходный, СкриптНаСайте, НовыйФайлКартинки);

		Возврат НовыйФайлКартинки;

		

	Исключение

		//Обработка ошибки

		//Не удалось получить файл

		//Или нужно пополнить баланс

		Возврат ФайлКартинкиИсходный;

	КонецПопытки;

		

КонецФункции

И далее в коде обращаться к данной функции, н-р так

Код 1C v 8.х

 НовыйФайл = ОптимизироватьКартинку(ФайлКартинкиИсходный, 70, Истина, 500, 500);

Категория: 1С ERP Управление предприятием 2.0

ДеревоЗначений в ТекстовыйДокумент

Код 1C v 8.2 УП

 // Выводит данные ДереваЗначений в ТекстовыйДокумент, пригодный к рассмотрению в отладчике, окне сообщений и показу.

//

// Параметры:

//    рВетка - дерево значений, подлежащее выводу. Может иметь почти любую глубину иерархии, количество и тип колонок. Если хватит

//        объявленных позиционных строк-заполнителей, всё поместится. Если иерархия слишком глубока, строки просто надо нарастить;

//    рТекст - на входе должен быть равен Неопределено; на выходе по окончании работы содержит результатный текстовый документ;

//    рПараметры - структура дополнительных настроек, допустимые ключи:

//        Колонки - структура колонок, которые подлежат выводу. Если пуста или имеет тип, отличный от структуры, выводятся все колонки;

//           если в ключах структуры указаны имена колонок, будут выведены только они. В значениях структуры можно передать строковое

//           представление формата, согласно которому должны будут форматироваться выводимые значения. По умолчанию формата нет;

//        ПоказыватьУровни - булево, управляет выводом №№ уровней (метод Уровень()), по умолчанию выключено;

//        ШагОтступа - число, определяющее шаг в символах, используемый для показа псевдографики иерархии веток в дереве.

//

&НаСервереБезКонтекста

Процедура ВывестиДеревоЗначенийВТекст(Знач рВетка,рТекст,Знач рПараметры=Неопределено)

Попытка

    Если рТекст=Неопределено Тогда // первая итерация, шапочный вызов исходной части

        //---------------------------------------------------------------------------------------------------------------------------

        // Разбираем входные данные

        Если ТипЗнч(рВетка)<>Тип("ДеревоЗначений") Тогда Возврат КонецЕсли;

        Если ТипЗнч(рПараметры)<>Тип("Структура") Тогда рПараметры=Новый Структура КонецЕсли;

        стрКолонок=?(рПараметры.Свойство("Колонки"),рПараметры.Колонки,Неопределено);

        Если ТипЗнч(стрКолонок)<>Тип("Структура") Тогда стрКолонок=Новый Структура КонецЕсли;

        рПоказыватьУровни=?(рПараметры.Свойство("ПоказыватьУровни"),рПараметры.ПоказыватьУровни,Ложь); // затратное дело, кстати

        рШагОтступа=?(рПараметры.Свойство("ШагОтступа"),рПараметры.ШагОтступа,2); // для отображения отступа в колонке иерархии





        //---------------------------------------------------------------------------------------------------------------------------

        // Определяем максимальное количество уровней

        // Также можно получить максимальный уровень, "плоско" перебрав все строки (например, получив их через НайтиСтроки)

        // и в цикле для каждой вызывая Уровень() и определяя максимум.

        // Вариант через СКД и служебное поле "Уровень" ни на одной известной мне платформе не работоспособен (нехватка памяти).

        //

        //

        //рДеревоДляТеста=КакНибудьСкопироватьДерево(рВетка);

        //рДеревоДляТеста.Колонки.Вставить(0,"_Level",Новый ОписаниеТипов("Булево")); // самый экономный вариант, с сохранением иерархии

        //мНенужных=Новый Массив;

        //Для й=1 По рДеревоДляТеста.Колонки.Количество()-1 Цикл

        //  мНенужных.Добавить(рДеревоДляТеста.Колонки[й]);

        //КонецЦикла;

        //Для каждого кол Из мНенужных Цикл

        //  рДеревоДляТеста.Колонки.Удалить(кол);

        //КонецЦикла;

        //

        рДеревоДляТеста=рВетка; // пока сериализуем прямо всё дерево (неоптимально, но...)

        рЗапись=Новый ЗаписьXML;

        рЗапись.УстановитьСтроку();

        СериализаторXDTO.ЗаписатьXML(рЗапись,рДеревоДляТеста);

        стро=рЗапись.Закрыть();

        //

        стро=СтрЗаменить(стро,"xmlns=","xmlns:myns1C="); // иначе не будет работать XPath

        //

        рЧтение=Новый ЧтениеXML;

        рЧтение.УстановитьСтроку(стро);

        постр=Новый ПостроительDOM;

        рДокументДОМ=постр.Прочитать(рЧтение);





        рВыражение="/ValueTree/row"; максКолвоУровней=1;

        рРазыменователь=Новый РазыменовательПространствИменDOM(рДокументДОМ);

        Пока Истина Цикл

            #Если Клиент Тогда

                ОбработкаПрерыванияПользователя();

            #КонецЕсли

            рРезультат=рДокументДОМ.ВычислитьВыражениеXPath(рВыражение,рДокументДОМ,рРазыменователь,ТипРезультатаDOMXPath.Любой);

            Если рРезультат.ПолучитьСледующий()=Неопределено Тогда Прервать КонецЕсли;

            рВыражение=рВыражение+"/row";

            максКолвоУровней=максКолвоУровней+1;

        КонецЦикла;

        максКолвоУровней=максКолвоУровней-1; // можно и так: СтрЧислоВхождений(рВыражение,"/row")-1;





        //---------------------------------------------------------------------------------------------------------------------------

        // готовим исходный макет вывода

        строПробелы="                                                                                                                                                                                                                 ";

        строРазделители="===============================================================================================";

        строОтступы="___________________________________________________________________________________________"; // тут нужны чуть для другого

        //

        секШапка1="|[_HCS"+Лев(строПробелы,максКолвоУровней*рШагОтступа)+"]|"; // HierarchyColumnShow

        секГорРазделитель1="|"+Лев(строОтступы,максКолвоУровней*рШагОтступа+6)+"|"; // здесь именно Отступы!

        рШиринаКолонкиИерархии=СтрДлина(секШапка1)-2;

        строПолейШапки="#Поле _HCS

        |   #Выравнивание Центр";

        строПолейЗаписи="";

        //

        Если рПоказыватьУровни Тогда

            секШапка1=секШапка1+"[_Level]|";

            секГорРазделитель1=секГорРазделитель1+Лев(строРазделители,8)+"|";

            строПолейШапки=строПолейШапки+"

            |#Поле _Level

            |   #Выравнивание Центр";

            строПолейЗаписи="#Поле _Level

            |   #Выравнивание Центр

            |   #Забивать Истина";

        КонецЕсли;

        //

        мИменКолонок=Новый Массив;

        Для каждого кол Из рВетка.Колонки Цикл

            Если стрКолонок.Количество()<>0 и не стрКолонок.Свойство(кол.Имя) Тогда Продолжить КонецЕсли; // чётко указаны конкретные колонки

            рДлинаИмениКолонки=СтрДлина(кол.Имя);

            рНужнаяШирина=Макс(?(кол.Ширина<3,10,кол.Ширина),рДлинаИмениКолонки);

            // к сожалению, ключевое слово "#Поля" неприменимо - платформа падает - поэтому делаем всё сами

            секШапка1=секШапка1+"["+кол.Имя+Лев(строПробелы,рНужнаяШирина-рДлинаИмениКолонки)+"]|";

            секГорРазделитель1=секГорРазделитель1+Лев(строРазделители,рНужнаяШирина+1)+"=|";

            строПолейШапки=строПолейШапки+"

            |#Поле "+кол.Имя+"

            |   #Выравнивание Центр";

            рОписТипов=кол.ТипЗначения;

            Если рОписТипов.Типы().Количество()=1 и рОписТипов.СодержитТип(Тип("Булево")) Тогда

                рВыравнивание="Центр";

            ИначеЕсли рОписТипов.СодержитТип(Тип("Число")) Тогда

                рВыравнивание="Право";

            ИначеЕсли рОписТипов.СодержитТип(Тип("Строка")) и рОписТипов.КвалификаторыСтроки.Длина=0 Тогда

                рВыравнивание="ПоШирине";

            Иначе

                рВыравнивание="Лево";

            КонецЕсли;

            строПолейЗаписи=строПолейЗаписи+?(ПустаяСтрока(строПолейЗаписи),"",Символы.ПС)+"#Поле "+кол.Имя+"

            |   #Выравнивание "+рВыравнивание;

            Попытка

                Если ЗначениеЗаполнено(стрКолонок[кол.Имя]) Тогда // указан формат, уточняющий показ колонки

                    строПолейЗаписи=строПолейЗаписи+"

                    |   #Формат """+СокрЛП(стрКолонок[кол.Имя])+"""";

                КонецЕсли;

            Исключение

            КонецПопытки;

            мИменКолонок.Добавить(кол.Имя);

        КонецЦикла;

        секШапка2=СтрЗаменить(СтрЗаменить(секШапка1,"[","<"),"]",">");

        секЗапись1=секШапка1; секЗапись2=секШапка2; // пусть они по дизайну пока не отличаются

        секГорРазделитель2=СтрЗаменить(СтрЗаменить(секГорРазделитель1,"=","-"),"|","+");

        // обработаем нормальное обрамление шапки колонки иерархии

        секГорРазделитель1=СтрЗаменить(секГорРазделитель1,"_","=");

        секГорРазделитель2=СтрЗаменить(секГорРазделитель2,"_"," ");

        //

        тМакет=Новый ТекстовыйДокумент;

        тМакет.ДобавитьСтроку("#Область Шапка");

        тМакет.ДобавитьСтроку(строПолейШапки);

        тМакет.ДобавитьСтроку(секГорРазделитель1);

        тМакет.ДобавитьСтроку(секШапка1);

        тМакет.ДобавитьСтроку(секШапка2);

        тМакет.ДобавитьСтроку(секГорРазделитель1);

        тМакет.ДобавитьСтроку("#КонецОбласти");

        тМакет.ДобавитьСтроку("");

        тМакет.ДобавитьСтроку("#Область Запись");

        тМакет.ДобавитьСтроку(строПолейЗаписи);

        тМакет.ДобавитьСтроку(секЗапись1);

        тМакет.ДобавитьСтроку(секЗапись2);

        тМакет.ДобавитьСтроку(секГорРазделитель2);

        тМакет.ДобавитьСтроку("#КонецОбласти");

        рПараметры.Вставить("ИсходныйМакет",тМакет); // пусть будет





        //---------------------------------------------------------------------------------------------------------------------------

        // Запускаем вывод в итоговый документ

        рТекст=Новый ТекстовыйДокумент;

        сек=тМакет.ПолучитьОбласть("Шапка");

        сек.Параметры._HCS="Иерархия";

        Для каждого имякол Из мИменКолонок Цикл

            кол=рВетка.Колонки[имякол];

            сек.Параметры[кол.Имя]=?(ПустаяСтрока(кол.Заголовок),кол.Имя,кол.Заголовок);

        КонецЦикла;

        рТекст.Вывести(сек);

        //

        пар=Новый Структура;

        пар.Вставить("МассивИмёнКолонок",мИменКолонок);

        пар.Вставить("ТекущаяСекция",тМакет.ПолучитьОбласть("Запись"));

        пар.Вставить("ШиринаКолонкиИерархии",рШиринаКолонкиИерархии);

        пар.Вставить("ПоказыватьУровни",рПоказыватьУровни);

        пар.Вставить("Отступ",0);

        пар.Вставить("ШагОтступа",рШагОтступа);

        ВывестиДеревоЗначенийВТекст(рВетка,рТекст,пар);





    Иначе

        // очередная итерация, вывод в текстовый документ

        мИменКолонок=рПараметры.МассивИмёнКолонок;

        рСекция=рПараметры.ТекущаяСекция;

        рОтступ=рПараметры.Отступ;

        рШиринаКолонкиИерархии=рПараметры.ШиринаКолонкиИерархии;

        рПоказыватьУровни=рПараметры.ПоказыватьУровни;

        //

        строОтступы="_________________________________________________________________________________________________________";

        строПробелы="                                                                                                                                                                                                                 ";

        //

        пар=Новый Структура;

        пар.Вставить("МассивИмёнКолонок",мИменКолонок);

        пар.Вставить("ТекущаяСекция",рПараметры.ТекущаяСекция);

        пар.Вставить("ШиринаКолонкиИерархии",рШиринаКолонкиИерархии);

        пар.Вставить("ПоказыватьУровни",рПоказыватьУровни);

        пар.Вставить("ШагОтступа",рПараметры.ШагОтступа);

        пар.Вставить("Отступ",рОтступ+рПараметры.ШагОтступа);

        //

        Для каждого рПодветка Из рВетка.Строки Цикл

            рСекция.Параметры._HCS=Лев(строПробелы,рОтступ)+"\"+Лев(строОтступы,рШиринаКолонкиИерархии-рОтступ-1);

            Если рПоказыватьУровни Тогда

                рСекция.Параметры._Level=рПодветка.Уровень();

            КонецЕсли;

            Для каждого имякол Из мИменКолонок Цикл

                рСекция.Параметры[имякол]=рПодветка[имякол];

            КонецЦикла;

            рТекст.Вывести(рСекция);

            ВывестиДеревоЗначенийВТекст(рПодветка,рТекст,пар)

        КонецЦикла;

        //

    КонецЕсли;

Исключение

    Сообщить("ВывестиДеревоЗначенийВТекст, ошибка: "+ОписаниеОшибки(),СтатусСообщения.ОченьВажное);

КонецПопытки;

КонецПроцедуры

Источник

Категория: Работа с Деревом Значений

Конвертация экселя в картику Категория: Работа с Microsoft Office и OpenOffice

Табличный документ: Колонтитулы и параметры страницы

Большинство обучающих материалов по программированию в системе 1С при описании формирования печатных форм на основе объекта «Табличный документ» ограничиваются выводом готовой формы на экран. Для пользователей же куда более важным является то, как документ будет выглядеть в распечатанном виде. Здесь, кроме хорошо сверстанного макета, играют роль и установки параметров печати.Почти все параметры, доступные в диалогах настройки печати (настройки принтера, свойства страницы), можно указать непосредственно при формировании табличного документа.Рассмотрим свойства и методы табличного документа, относящиеся к настройкам печати (в приведенных примерах «ТабДок» это объект типа «Табличный документ»).

Свойство «ИмяПринтера» позволяет задать для печати принтер, отличный от установленного по умолчанию. Имя должно совпадать с именем принтера, заданным в системе:

ТабДок.ИмяПринтера="HP LaserJet 3050 Series PCL 6";

При печати пакета документов можно сэкономить время, установив признак разбора по копиям:

ТабДок.РазборПоКопиям=истина;

Число копий можно указать так:

ТабДок.КоличествоЭкземпляров=5;

Разумеется, можно задать поля:

ТабДок.ПолеСлева=20;//Поле слева 20мм, остальные поля 10мм (по умолчанию)

Еще несколько свойств страницы:

ТабДок.ОриентацияСтраницы=ОриентацияСтраницы.Ландшафт; ТабДок.ЭкземпляровНаСтранице=2; //на листе будет размещено 2 страницы ТабДок.Автомасштаб=истина; //аналогично настройкам масштаба «по ширине страницы»

При необходимости можно указать конкретное значение масштабирования в процентах (свойство «МасштабПечати»).

Свойство «РазмерСтраницы» позволяет задать стандартные форматы страницы – “A3”, “A4”, “A5” (полный список вариантов доступен в справке 1С).

ТабДок.РазмерСтраницы="A3";// буква А должна быть английской

Для нестандартного размера бумаги (Custom) можно указать значения высоты и ширины страницы (в мм):

ТабДок.РазмерСтраницы="Custom";//нестандартный размер ТабДок.ВысотаСтраницы=350; ТабДок.ШиринаСтраницы=350;

Также в табличном документе доступно управление выводом колонтитулов и их содержимым. Для этого служат свойства «ВерхнийКолонтитул» и «НижнийКолонтитул». Например:

ТабДок.ВерхнийКолонтитул.Выводить=истина; //будет напечатан верхний колонтитул ТабДок.РазмерКолонтитулаСверху=7; //размер колонтитула 7мм (по умолчанию 10мм) ТабДок.ВерхнийКолонтитул.ВертикальноеПоложение=ВертикальноеПоложение.Верх; ТабДок.ВерхнийКолонтитул.НачальнаяСтраница=2;//колонтитул выводится со второй страницы ШрифтКолонтитула=Новый Шрифт("Courier New", 8,,Истина); ТабДок.ВерхнийКолонтитул.Шрифт=ШрифтКолонтитула; //наклонный шрифт ТабДок.ВерхнийКолонтитул.ТекстВЦентре="Верхний колонтитул"; ТабДок.ВерхнийКолонтитул.ТекстСправа="Стр.[&НомерСтраницы] из [&СтраницВсего]"; //нумерация страниц ТабДок.ВерхнийКолонтитул.ТекстСлева="[&Дата]";//текущая дата

Сформированный документ отправляется на печать с помощью метода «Напечатать()». Возможно два варианта вызова.

1) Непосредственно на принтер:ТабДок.Напечатать(РежимИспользованияДиалогаПечати.НеИспользовать); ТабДок.Напечатать(истина);

2) Перед печатью будет выведен диалог печати:ТабДок.Напечатать(РежимИспользованияДиалогаПечати.Использовать); ТабДок.Напечатать(ложь);

Кроме того можно управлять и разбиением документа на страницы. Оценить количество страниц в документе по настройкам текущего принтера можно так:

ТабДок.КоличествоСтраниц();

С помощью методов «ПроверитьВывод()» и «ПроверитьПрисоединение()» можно определить, умещается ли табличный документ или массив областей табличного документа на странице в высоту и в ширину при текущих настройках принтера.Надо иметь ввиду, что работа последних трех методов зависит от установленного принтера. Если методу не удается его найти, вызывается исключение.

Принудительно вставить разрывы страниц позволяют методы «ВывестиВертикальныйРазделительСтраниц()» и «ВывестиГоризонтальныйРазделительСтраниц()».Таким образом, можно управлять постраничным выводом на печать и контролировать заполнение страницы:

Если Не ТабДок.ПроверитьВывод(МассивВыводимыхОбластей) Тогда ТабДок.ВывестиГоризонтальныйРазделительСтраниц();КонецЕсли;

Категория: Табличный документ

Быстрая выгрузка отчетов в Excel, наложение Фильта и отображение ярлыка

Вместо Таб.Показать() используем глобальную функцию - и отчет показывается сразу в Excel в удобоваримом виде - с форматированием колонок по ширине, автофильтром и ярлычками листов

Код 1C v 7.x

 Процедура глОткрытьВЭкселе(Таб,ИмяФайла="",НеИзменятьВысотуСтроки=0) Экспорт

	Попытка 

		// запускаем Excel-Server 

		Excel = СоздатьОбъект("Excel.Application");

	Исключение       

		Excel = 0;

		Предупреждение("MS Excel не загружен!");

		Возврат;

	КонецПопытки;   

	

	Если ТипЗначенияСтр(Таб)="Строка" Тогда

		Excel.WorkBooks.Open(Таб);

	Иначе                                                          

		Если НеИзменятьВысотуСтроки=0 Тогда

			ШиринаТаблицы=Таб.ШиринаТаблицы();

			Область=Таб.Область(1,1,Таб.ВысотаТаблицы(),ШиринаТаблицы);

			Область.ВысотаСтроки(12);                 

		КонецЕсли;

		

		Если Найти(ИмяФайла,":")=0 Тогда

			ИмяФайла=КаталогПользователя()+ИмяФайла;

		КонецЕсли;

		Если Найти(Врег(ИмяФайла),"XLS")=0 Тогда

			ИмяФайла=ИмяФайла+".xls";

		КонецЕсли;

		

		Таб.Записать(?(ПустоеЗначение(ИмяФайла)=0,ИмяФайла,КаталогПользователя()+"Таблица.xls"),"XLS");

		Excel.WorkBooks.Open(ИмяФайла);

		

		Excel.Visible = 0;

		

		//добавляем автофильтр и форматирование колонок по ширине

		Excel.Columns.AutoFit();

		Range = Excel.Range(Excel.Cells(1, 1), Excel.Cells(1, ШиринаТаблицы));

		Range.S_elect();

		Range.AutoFilter();

		

		//показываем вечно прячущиеся ярлычки листов

		Excel.ActiveWindow.DisplayWorkbookTabs = -1;

		Excel.ActiveWindow.TabRatio = 0.25;

	КонецЕсли;

	

	Excel.Visible=1;	  

	Excel=0;

КонецПроцедуры

mikukrnet

Категория: Работа с Microsoft Office и OpenOffice

Выгрузка в PDF из 1С (Средствами OpenOffice)

Возникла задача отправлять счета почтой. PDFcreator не подошёл поскольку не удалось вместить счёт на одну страницу по ширине. Решил попробовать OpenOffice. Как сохранять в PDF нашёл быстро, а вот как уместить счёт на одну страницу вширь искал долго.
В версии 1С 8.2.232 появилась возможность сохранять табличный документ в xls файл на сервера под линуксом. А вот работать с Опеном офисом из-под линукса пока не получается. Собственно комментари ненужны. Вот весь код. Самое интересное это бодание со стилями страниц в Опене Офисе. Жаль что этот фрагмент работает только на клиенте. На сервере вопрос не решается *08

Код 1C v 8.2 УП

 Процедура КнопкаВыполнитьНажатие(Кнопка)

    Если Письмо.Основание.Пустая() Тогда

        Возврат

    КонецЕсли;



    // Открыть OpenOffice

    Попытка

        ServiceManager = Новый COMОбъект("com.sun.star.ServiceManager");

    Исключение

        Возврат // опен офис не установлен :-(

    КонецПопытки;



    // получим печатную форму и запишем её во временный XLS файл

    Заказ = Письмо.Основание.ПолучитьОбъект();



    //Получим печатную форму

    Расшифровка=Новый Структура;

    Расшифровка.Вставить("СсылкаНаВнешнююОбработку",Константы.ПФСчетаДляКлиента.Получить());

    Расшифровка.Вставить("ВидПечатнойФормы",Перечисления.ВидыДополнительныхВнешнихОбработок.ПечатнаяФорма);

    Расшифровка.Вставить("НомерСтроки",1);

    тд = УниверсальныеМеханизмы.НапечататьВнешнююФорму(Заказ, Расшифровка);



    ВременныйФайл =ПолучитьИмяВременногоФайла();

    ВременныйФайлXLS =ВременныйФайл + ".xls";

    ВременныйФайлPDF =ВременныйФайл + ".pdf";

    тд.Записать(ВременныйФайлXLS, ТипФайлаТабличногоДокумента.XLS97);



    // Преобразовываем временный xls файл В PDF

    Desktop        = ServiceManager.createInstance("com.sun.star.frame.Desktop");



    НастройкиОткрытия = Новый COMSafeArray("VT_VARIANT", 1);

    PropertyValue = ServiceManager.Bridge_GetStruct("com.sun.star.beans.PropertyValue");

    PropertyValue.Name = "Hidden";

    PropertyValue.Value = Истина;

    НастройкиОткрытия.SetValue(0, PropertyValue);

    ВременныйФайлXLS_какУРЛ = "file:///" + СтрЗаменить(ВременныйФайлXLS, "\", "/"); // приводим путь к файлу из виндового формата в опен офисный



    // Откроем файл в опене офисе

    ОпенОфис = Desktop.LoadComponentFromURL(ВременныйФайлXLS_какУРЛ, "_blank", 0, НастройкиОткрытия);



    //ПараметрыСтраницы = ОпенОфис.createInstance("com.sun.star.style.PageStyle");

    //ПараметрыСтраницы.ScaleToPagesX = 1;

    //

    // Установим масштаб, чтобы счёт помещался на одной странице вширь

    // страниц почему-то много, поэтому устанавливаем масштаб для всех

    Стили = ОпенОфис.StyleFamilies.getByName("PageStyles");

    Для поз = 0 по Стили.count - 1 Цикл

        МойСтиль = Стили.getByIndex(поз);

        МойСтиль.ScaleToPagesX = 1; // уместить на одной странице вширь

        //МойСтиль.PageScale = 50; // масштаб 50%

    КонецЦикла;



    НастройкиСохранения = Новый COMSafeArray("VT_VARIANT", 1);

    PropertyValue = ServiceManager.Bridge_GetStruct("com.sun.star.beans.PropertyValue");

    PropertyValue.Name = "FilterName";

    PropertyValue.Value = "calc_pdf_Export";

    НастройкиСохранения.SetValue(0, PropertyValue);



    ВременныйФайлPDF_какУРЛ = "file:///" + СтрЗаменить(ВременныйФайлPDF, "\", "/"); // приводим путь к файлу из виндового формата в опен офисный

    ОпенОфис.storeToURL(ВременныйФайлPDF_какУРЛ, НастройкиСохранения); // сохранили PDF файл

    ОпенОфис.close(-1);

    ОпенОфис = Неопределено;



    // С опеном офисом разобрались. Прикрепляем вложение к письму и удаляем временные файлы.

    //Файл = Новый Файл(ВременныйФайлPDF);

    объектПисьмо = Письмо.ПолучитьОбъект();

    стрВложение = объектПисьмо.Вложения.Добавить();

    стрВложение.ИмяФайла = "Счёт " + Строка(Заказ.Номер) + ".pdf";

    стрВложение.Файл = Новый ХранилищеЗначения(Новый ДвоичныеДанные(ВременныйФайлPDF));

    объектПисьмо.Записать();

    Попытка

        УдалитьФайлы(ВременныйФайлXLS);

        УдалитьФайлы(ВременныйФайлPDF);

    Исключение

    КонецПопытки;



КонецПроцедуры

Автор: Трактор

Функция позволяющая выполнить выгрузку табличного документа в PDF средствами OpenOffice

Код 1C v 8.х

 // Функция превращает табличный документ в PDF документ

// Возвращаемое значение: тип "Строка" - имя созданного PDF файла, 0 - в случае ошибки

// Параметры: ДанныеВыгрузки - Табличный или текстовый документ, который нужно выгрузить в PDF

//            ПутьВыгрузки - тип "Строка", путь для сохраниения PDF файла (без имени и расширения файла)

//            ИмяФайлаБезРасширения - тип "Строка", имя для вновь сформированного PDF файла

// Тестировалось на OpenOffice 3.x

Функция ВыгрузитьТабличныйДокументВPDF(ДанныеВыгрузки, ПутьВыгрузки, ИмяФайлаБезРасширения)       

    Если НЕ ЗначениеЗаполнено(ПутьВыгрузки) Тогда

        ПутьВыгрузки = КаталогВременныхФайлов();

    КонецЕсли;   

    ПутьВыгрузки         = ?(Прав(ПутьВыгрузки, 1) = "\", ПутьВыгрузки, ПутьВыгрузки + "\");

   

    РасширениеXSL         = ".xls";

    РасширениеPDF         = ".pdf";

    ПолноеИмяФайлаXLS     = ПутьВыгрузки + ИмяФайлаБезРасширения + РасширениеXSL;

    //Выгрузка данных печати в файл XLS   

#Если Клиент Тогда

    Состояние("Создание временного файла...");

#КонецЕсли

    Попытка

        Если         ТипЗнч(ДанныеВыгрузки) = Тип("ТабличныйДокумент") Тогда        

            ДанныеВыгрузки.Записать(ПолноеИмяФайлаXLS, "XLS");

        ИначеЕсли     ТипЗнч(ДанныеВыгрузки) = Тип("ТекстовыйДокумент") Тогда

            ДанныеВыгрузки.Записать(ПолноеИмяФайлаXLS, "XLS");

        Иначе

#Если Клиент Тогда

            Сообщить("Данные для выгрузки переданы в неподдерживаемом формате. Дальнейшее выполнение невозможно." + Символы.ПС + ОписаниеОшибки());

#КонецЕсли

            Возврат 0;

        КонецЕсли;

    Исключение

#Если Клиент Тогда

        Сообщить("Произошла ошибка при выгрузке временного файла. Возможно ошибка доступа к папке, в которую происходит запись." + Символы.ПС + ОписаниеОшибки());

#КонецЕсли

        Возврат 0;

    КонецПопытки;

   

    Попытка

#Если Клиент Тогда

        Состояние("Открытие компоненты OpenOffice...");

#КонецЕсли

        ServiceManager    = Новый COMОбъект("com.sun.star.ServiceManager");       

       

        Скрипт             = Новый COMОбъект("MSScriptControl.ScriptControl");

        Скрипт.language    = "javascript";

        Скрипт.AddObject("OpenOffice", ServiceManager);

       

        //Открытие временного файла без отображения его окна

#Если Клиент Тогда           

        Состояние("Открытие временного файла...");

#КонецЕсли

        Скрипт.eval("Массив=new Array()");       

        Массив             = Скрипт.eval("Массив");   

        Скрипт.eval("Массив[0] = OpenOffice.Bridge_GetStruct('com.sun.star.beans.PropertyValue')");

        Скрипт.eval("Массив[0].Name     = 'Hidden'");

        Скрипт.eval("Массив[0].Value = true");

       

        Скрипт.AddCode("function SetItem(ind,val){Массив[ind]=val}");       

        Скрипт.AddObject("ServiceManager",ServiceManager);

        Desktop         = ServiceManager.createInstance("com.sun.star.frame.Desktop");       

        Document         = Desktop.LoadComponentFromURL("file:///" + ПолноеИмяФайлаXLS, "_blank", 0, Массив);

       

        //Сохранение в PDF встроенными средствами OpenOffice

#Если Клиент Тогда           

        Состояние("Запись в PDF...");

#КонецЕсли

        Скрипт.eval("Массив2=new Array()");       

        Массив2     = Скрипт.eval("Массив2");       

        Скрипт.eval("Массив2[0] = OpenOffice.Bridge_GetStruct('com.sun.star.beans.PropertyValue')");       

        Скрипт.eval("Массив2[0].Name  = 'FilterName'");

        Скрипт.eval("Массив2[0].Value = 'writer_pdf_Export'");

       

        ПолноеИмяФайлаPDF         = "file:///" + СтрЗаменить(ПолноеИмяФайлаXLS, РасширениеXSL, РасширениеPDF);

        ПолноеИмяФайлаPDF         = СтрЗаменить(ПолноеИмяФайлаPDF, ВРег(РасширениеXSL), РасширениеPDF);

        ПолноеИмяФайлаPDF        = СтрЗаменить(ПолноеИмяФайлаPDF, "\", "/");       

               

        Document.storeToURL(ПолноеИмяФайлаPDF, Массив2);

        Document.close(-1);        //Закрыть документ

       

        //Контрольная очистка переменных

        Document     = Неопределено;

        Desktop     = Неопределено;

       

        //Удаление временного файла

#Если Клиент Тогда           

        Состояние("Удаление временного файла...");

#КонецЕсли       

        Попытка

            УдалитьФайлы(ПолноеИмяФайлаXLS);

        Исключение

#Если Клиент Тогда           

            Сообщить("Произошла ошибка при удалении временного файла. Возможно, потребуется удалить его вручную." + Символы.ПС + ОписаниеОшибки());

#КонецЕсли

        КонецПопытки;

       

        ПолноеИмяФайлаPDF = СтрЗаменить(ПолноеИмяФайлаPDF, "file:///", "");

        ПолноеИмяФайлаPDF = СтрЗаменить(ПолноеИмяФайлаPDF, "/", "\");

#Если Клиент Тогда

        Состояние("Выгрузка выполнена.");

        Предупреждение("Выгрузка выполнена." + Символы.ПС + ПолноеИмяФайлаPDF);       

#КонецЕсли

        Возврат ПолноеИмяФайлаPDF;

    Исключение

        Document.close(-1);

#Если Клиент Тогда

        Предупреждение(ОписаниеОшибки());

#КонецЕсли

        Возврат 0;

    КонецПопытки   

КонецФункции

Автор: doom_2001

Категория: Работа с Microsoft Office и OpenOffice

Пример вывода в шапке отчета произвольного текста и Картинки

Многие спрашивают "Как в шапке отчета созданом с помощи СКД разместить произвольный текст и Картинку?", так вот:

1. Для примера буду использовать отчет созданный в Пример разработки простого отчета - Схема Компоновки Данных (СКД)
2. В отчете создадим основную форму и для кнопки сформировать пропишем процедуру ПечатьНажатие:
title

Код 1C v 8.х

 Процедура ПечатьНажатие(Элемент)

 СхемаКомпоновкиДанных = ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");

 

 КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

 ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;

 Настройки = КомпоновщикНастроек.Настройки;

 МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки, ДанныеРасшифровки);

      

 ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;

    ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки,, ДанныеРасшифровки);

 

 ДокументРезультат = ЭлементыФормы.Результат;

 ДокументРезультат.АвтоМасштаб = Истина; // Сделаем по ширине листа

 //А если сделать так как на следующей строчке, то можно вывести в новый Табличный документ

 //ДокументРезультат = Новый ТабличныйДокумент;

 

 //Вывод текста и картинки

 Макет = ПолучитьМакет("НазваниеСРисунком");

 ОбластьВывести = Макет.ПолучитьОбласть("Вывести");

    ОбластьВывести.Параметры.ТекДата=ТекущаяДата();

 ДокументРезультат.Вывести(ОбластьВывести);

 //Текст и картинку вывели, теперь сам отчет

 

 ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

    ПроцессорВывода.УстановитьДокумент(ДокументРезультат);

 ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

 

 ДокументРезультат.ОтображатьСетку = Ложь;

 ДокументРезультат.ОтображатьЗаголовки = Ложь;

 ДокументРезультат.Показать();

КонецПроцедуры

3. И создаем макет "НазваниеСРисунком"
title

4. Сохраняем, запускаем, получаем:
title

Автор: Евгений Мигачев

Категория: Схема Компоновки Данных

Автоматическая установка ширины колонки табличного документа.

Процедура, которая "примерно" делает автоширину колонок (навроде, как если бы выделить все колонки и дважды щелкнуть мышкой по границе заголовка колонки). Привожу текст, работает неахти, но лучше чем ничего:

Код 1C v 8.х

 Процедура РасчетШириныКолонок(ТабличныйДокумент)

    

    Перем МаксимальноеКоличествоСтрок, МаксимальнаяШиринаКолонки;

    Перем КонечнаяСтрока, НачальнаяСтрока, ТекущаяКолонка, ТекущаяСтрока, НачалоДанных;

    Перем ОбластьШапки, ОбластьПодвала;

    Перем ШиринаКолонки, ТекстЯчейки, НомерСтрокиТекста;

    Перем КоличествоУровнейГруппировокСтрок, Отступ;

    Перем ШириныКолонок;

    

    // Максимальное количество строк отчета, которые будут использованы для расчета ширин колонок

 

    МаксимальноеКоличествоСтрок = 50;

    // Ограничение максимальной ширины колонки

 

    МаксимальнаяШиринаКолонки = 50;

    // Массив, в который будут помещаться ширины колонок

 

    ШириныКолонок = Новый Массив;

    // Получим количество уровней группировок в отчете для учета автоматического отступа

 

    КоличествоУровнейГруппировокСтрок = ТабличныйДокумент.КоличествоУровнейГруппировокСтрок();

    

    // Инициализируем начальные строки

 

    НачальнаяСтрока = 0;

    НачалоДанных = 0;

    

    // Найдем в результирующем документе область шапки таблицы

 

    ОбластьШапки = ТабличныйДокумент.Области.Найти("ШапкаТаблицы");

    Если ТипЗнч(ОбластьШапки) = Тип("ОбластьЯчеекТабличногоДокумента") Тогда

        

        // Из шапки таблицы получим начальную строку с которой будем рассчитывать ширины

         НачальнаяСтрока = ОбластьШапки.Верх;

        НачалоДанных = ОбластьШапки.Низ + 1;

    Иначе

        

        // Если область шапки таблицы не найдена, найдем область шапки строк

         ОбластьШапки = ТабличныйДокумент.Области.Найти("ШапкаСтрок");

        Если ТипЗнч(ОбластьШапки) = Тип("ОбластьЯчеекТабличногоДокумента") Тогда

            

            // Из шапки таблицы получим начальную строку с которой будем рассчитывать ширины

             НачальнаяСтрока = ОбластьШапки.Верх;

            НачалоДанных = ОбластьШапки.Низ + 1;

            

        КонецЕсли;

    КонецЕсли;

    

    // Получим область подвала отчета и вычислим конечную строку расчета

 

    ОбластьПодвала = ТабличныйДокумент.Области.Найти("Подвал");

    Если ТипЗнч(ОбластьПодвала) = Тип("ОбластьЯчеекТабличногоДокумента") Тогда

        // Область подвала найдена

        КонечнаяСтрока = ОбластьПодвала.Верх - 1;

        Если КонечнаяСтрока - НачальнаяСтрока > МаксимальноеКоличествоСтрок Тогда

            КонечнаяСтрока = НачальнаяСтрока + МаксимальноеКоличествоСтрок;

        КонецЕсли;

    Иначе 

            // Область подвала не найдена

        КонечнаяСтрока = НачальнаяСтрока + МаксимальноеКоличествоСтрок;

    КонецЕсли;

    

    // Ограничим конечную строку

    КонечнаяСтрока = Мин(КонечнаяСтрока, ТабличныйДокумент.ВысотаТаблицы);

    // Переберем все колонки отчета

    Для ТекущаяКолонка = 1 По ТабличныйДокумент.ШиринаТаблицы Цикл

        АвтоОтступ = 0;

        // Переберем строки, которые будут использованы для расчета ширин колонок

        Для ТекущаяСтрока = НачальнаяСтрока По КонечнаяСтрока Цикл

            ШиринаКолонки = 0;

            // Получим область текущей ячейки

            ОбластьЯчейки = ТабличныйДокумент.Область(ТекущаяСтрока, ТекущаяКолонка);

            Если ОбластьЯчейки.Лево <> ТекущаяКолонка Или ОбластьЯчейки.Верх <> ТекущаяСтрока Тогда

                // Данная ячейка принадлежит объединенным ячейкам и не является начальной ячейкой

                Продолжить;

            КонецЕсли;

            Если КоличествоУровнейГруппировокСтрок > 0 И ТекущаяСтрока = НачалоДанных Тогда

                // Для первой строки с данными получим значение автоотступа

                АвтоОтступ = ОбластьЯчейки.АвтоОтступ;

            КонецЕсли;

            // Получим текст ячейки

            ТекстЯчейки = ОбластьЯчейки.Текст;

            // Для каждой строки из текста ячейки рассчитаем количество символов в строке

            Для НомерСтрокиТекста = 1 По СтрЧислоСтрок(ТекстЯчейки) Цикл

                ШиринаТекстаЯчейки = СтрДлина(СтрПолучитьСтроку(ТекстЯчейки, НомерСтрокиТекста));

                // Если используется автоотступ, то прибавим к ширине ячейки его величину

                Если АвтоОтступ <> Неопределено И АвтоОтступ > 0 Тогда

                    ШиринаТекстаЯчейки = ШиринаТекстаЯчейки + КоличествоУровнейГруппировокСтрок * АвтоОтступ;

                КонецЕсли;

                ШиринаКолонки = Макс(ШиринаКолонки, ШиринаТекстаЯчейки);

            КонецЦикла;



            Если ШиринаКолонки > МаксимальнаяШиринаКолонки Тогда

                // Ограничим ширину колонки

                ШиринаКолонки = МаксимальнаяШиринаКолонки;

            КонецЕсли;

            Если ШиринаКолонки <> 0 Тогда

                // Ширина колонки рассчитана

                // Определим, сколько ячеек по ширине используется в области для текущей ячейки

                КоличествоКолонок = ОбластьЯчейки.Право - ОбластьЯчейки.Лево;

                // Переберем все ячейки, расположенные в области

                 Для НомерКолонки = 0 По КоличествоКолонок Цикл

                    Если ШириныКолонок.ВГраница() > ТекущаяКолонка - 1 + НомерКолонки Тогда

                        // В массиве ширин колонок уже был элемент для текущей колонки

                        Если ШириныКолонок[ТекущаяКолонка - 1 + НомерКолонки] = Неопределено Тогда

                            // Значение ширины колонки еще не было установлено

                            ШириныКолонок[ТекущаяКолонка - 1 + НомерКолонки] = ШиринаКолонки / (КоличествоКолонок + 1);

                        Иначе

                            // Значение ширины колонки уже было установлено

                             // Вычислим максимум ширины колонки

                             ШириныКолонок[ТекущаяКолонка - 1 + НомерКолонки] = 

                                Макс(ШириныКолонок[ТекущаяКолонка - 1 + НомерКолонки], ШиринаКолонки / (КоличествоКолонок + 1));

                        КонецЕсли;

                    Иначе

                        // В массиве ширин колонок еще не было элемента для данной колонки

                        // Добавим элемент в массив ширин колонок

                        ШириныКолонок.Вставить(ТекущаяКолонка - 1 + НомерКолонки, ШиринаКолонки / (КоличествоКолонок + 1));

                    КонецЕсли;

                КонецЦикла;

            КонецЕсли;

        КонецЦикла;    // Конец цикла перебора строк

    КонецЦикла;    // Конец цикла перебора колонок

    

    // Переберем все элементы в массиве вычисленных ширин колонок

     Для ТекущаяКолонка = 0 По ШириныКолонок.ВГраница() Цикл

        Если ШириныКолонок[ТекущаяКолонка] <> Неопределено Тогда

            // Ширина колонок установлена

            // Установим ширину области ячеек

            ТабличныйДокумент.Область(, ТекущаяКолонка + 1, НачалоДанных, ТекущаяКолонка + 1).ШиринаКолонки = ШириныКолонок[ТекущаяКолонка] + 1;

        КонецЕсли;

    КонецЦикла;

КонецПроцедуры

Очень полезная штука при условии, что у Вас заранее невозможно определить размер итоговых колонок в печатной форме. А так, надо просто "натравить" процедуру с соответствующими параметрами на нужные ячейки таблицы, и они сами "выровняются" и приобретут необходимый размер (ширину).

Код 1C v 7.x

 //<!-- Патырило С.С. 22-04-2004 : Автоматическая установка ширины колонки

//  Для изменения ширины колонки уже сформированной таблицы, требуется передать

// в качестве параметров переменную с объектом "Таблица", координаты ячейки (группы ячеек)

// для которых нужно установить ширину столбца и ширину столбца в символах.

// При этом не обязательно передавать координаты требуемой ячейки (итоговой),

// (т.е. когда нет возможности или сложно определить позицию итоговой строки)

// достаточно указать ячейку из данного столбца (например первую).

//  Процедура установит ширину столбца выбрав максимальное из значений - 

// текущего размера (установленного в конфигураторе, или программно перед вызовом 

// функции) и переданного в качестве параметра. 

Процедура глУстШиринуЯчейки(Таб, Строка1, Столбец1, Строка2, Столбец2, ДлТекста = 0) Экспорт

	Если ДлТекста = 0 Тогда

	    врДлина	= СтрДлина(СокрЛП(Таб.Область(Строка1, Столбец1, Строка2, Столбец2).Текст));

	Иначе

		врДлина	= ДлТекста;

	КонецЕсли;

	Таб.Область(Строка1, Столбец1, Строка2, Столбец2).ШиринаСтолбца(Макс(Таб.Область(Строка1, Столбец1, Строка2, Столбец2).ШиринаСтолбца(), врДлина));

КонецПроцедуры

// --> Патырило С.С. 22-04-2004

Категория: Табличный документ