ширины » Поиск

Результаты по ключевому слову: ширины

Синтаксический анализ JSON - выражения средствами 1С 7.7 Категория: HTML, JS, VML

Табличный документ: Колонтитулы и параметры страницы

Большинство обучающих материалов по программированию в системе 1С при описании формирования печатных форм на основе объекта «Табличный документ» ограничиваются выводом готовой формы на экран. Для пользователей же куда более важным является то, как документ будет выглядеть в распечатанном виде. Здесь, кроме хорошо сверстанного макета, играют роль и установки параметров печати.Почти все параметры, доступные в диалогах настройки печати (настройки принтера, свойства страницы), можно указать непосредственно при формировании табличного документа.Рассмотрим свойства и методы табличного документа, относящиеся к настройкам печати (в приведенных примерах «ТабДок» это объект типа «Табличный документ»).

Свойство «ИмяПринтера» позволяет задать для печати принтер, отличный от установленного по умолчанию. Имя должно совпадать с именем принтера, заданным в системе:

ТабДок.ИмяПринтера="HP LaserJet 3050 Series PCL 6";

При печати пакета документов можно сэкономить время, установив признак разбора по копиям:

ТабДок.РазборПоКопиям=истина;

Число копий можно указать так:

ТабДок.КоличествоЭкземпляров=5;

Разумеется, можно задать поля:

ТабДок.ПолеСлева=20;//Поле слева 20мм, остальные поля 10мм (по умолчанию)

Еще несколько свойств страницы:

ТабДок.ОриентацияСтраницы=ОриентацияСтраницы.Ландшафт; ТабДок.ЭкземпляровНаСтранице=2; //на листе будет размещено 2 страницы ТабДок.Автомасштаб=истина; //аналогично настройкам масштаба «по ширине страницы»

При необходимости можно указать конкретное значение масштабирования в процентах (свойство «МасштабПечати»).

Свойство «РазмерСтраницы» позволяет задать стандартные форматы страницы – “A3”, “A4”, “A5” (полный список вариантов доступен в справке 1С).

ТабДок.РазмерСтраницы="A3";// буква А должна быть английской

Для нестандартного размера бумаги (Custom) можно указать значения высоты и ширины страницы (в мм):

ТабДок.РазмерСтраницы="Custom";//нестандартный размер ТабДок.ВысотаСтраницы=350; ТабДок.ШиринаСтраницы=350;

Также в табличном документе доступно управление выводом колонтитулов и их содержимым. Для этого служат свойства «ВерхнийКолонтитул» и «НижнийКолонтитул». Например:

ТабДок.ВерхнийКолонтитул.Выводить=истина; //будет напечатан верхний колонтитул ТабДок.РазмерКолонтитулаСверху=7; //размер колонтитула 7мм (по умолчанию 10мм) ТабДок.ВерхнийКолонтитул.ВертикальноеПоложение=ВертикальноеПоложение.Верх; ТабДок.ВерхнийКолонтитул.НачальнаяСтраница=2;//колонтитул выводится со второй страницы ШрифтКолонтитула=Новый Шрифт("Courier New", 8,,Истина); ТабДок.ВерхнийКолонтитул.Шрифт=ШрифтКолонтитула; //наклонный шрифт ТабДок.ВерхнийКолонтитул.ТекстВЦентре="Верхний колонтитул"; ТабДок.ВерхнийКолонтитул.ТекстСправа="Стр.[&НомерСтраницы] из [&СтраницВсего]"; //нумерация страниц ТабДок.ВерхнийКолонтитул.ТекстСлева="[&Дата]";//текущая дата

Сформированный документ отправляется на печать с помощью метода «Напечатать()». Возможно два варианта вызова.

1) Непосредственно на принтер:ТабДок.Напечатать(РежимИспользованияДиалогаПечати.НеИспользовать); ТабДок.Напечатать(истина);

2) Перед печатью будет выведен диалог печати:ТабДок.Напечатать(РежимИспользованияДиалогаПечати.Использовать); ТабДок.Напечатать(ложь);

Кроме того можно управлять и разбиением документа на страницы. Оценить количество страниц в документе по настройкам текущего принтера можно так:

ТабДок.КоличествоСтраниц();

С помощью методов «ПроверитьВывод()» и «ПроверитьПрисоединение()» можно определить, умещается ли табличный документ или массив областей табличного документа на странице в высоту и в ширину при текущих настройках принтера.Надо иметь ввиду, что работа последних трех методов зависит от установленного принтера. Если методу не удается его найти, вызывается исключение.

Принудительно вставить разрывы страниц позволяют методы «ВывестиВертикальныйРазделительСтраниц()» и «ВывестиГоризонтальныйРазделительСтраниц()».Таким образом, можно управлять постраничным выводом на печать и контролировать заполнение страницы:

Если Не ТабДок.ПроверитьВывод(МассивВыводимыхОбластей) Тогда ТабДок.ВывестиГоризонтальныйРазделительСтраниц();КонецЕсли;

Категория: Табличный документ

Как сжать ширину колонок табличного поля Категория: Табличный документ

Выгрузка данных в Excel с установкой разных параметров

Код 1C v 8.х

 // Процедура выгружает из указанного справочника данные в режиме экспорта в файл в формате Microsoft Excel

// с указанным именем, используя преобразование данных к типу число и типу строка;

Процедура ОсновныеДействияФормыЭкспорт(Кнопка)

  Попытка

    Попытка

      // Загрузка объекта Microsoft Excel

      Состояние("Выгрузка данных из 1С в Microsoft Excel...");

      ExcelПриложение = Новый COMОбъект("Excel.Application");

    Исключение

      Сообщить("Ошибка при запуске Microsoft Excel."

        + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);

      Возврат;

    КонецПопытки;



    // Создадим книгу, по умолчанию в ней уже есть листы

    Книга = ExcelПриложение.WorkBooks.Add();



    // Используем первый лист книги Excel

    Лист = Книга.WorkSheets(1);



    // Сформировать шапку документа в первой строке листа

    Колонка = 1;

    Для каждого стр из ТП цикл

      Если стр.Выгружать Тогда

        Лист.Cells(1, Колонка).Value = стр.НазваниеРеквизита;

        Колонка = Колонка + 1;

      КонецЕсли;

    КонецЦикла;



    // Выгрузить данные справочника

    выборка = Справочники[ИмяСправочника].Выбрать();

    СтрокаЛиста = 2;

    Пока выборка.Следующий() Цикл

      Колонка = 1;

      Для каждого стр из ТП цикл



      Если стр.Выгружать Тогда

      Попытка

        // Установить значение в строке и колонке

        Если ТипЗнч(выборка[стр.НазваниеРеквизита])=Тип("Число") Тогда

        // Установить формат для типа Число

        Лист.Cells(СтрокаЛиста, Колонка).NumberFormat = "0,00";

        Лист.Cells(СтрокаЛиста, Колонка).Value =

          Формат(выборка[стр.НазваниеРеквизита],"ЧГ=0");

        иначе

          // Для всех других типов установим формат "Текстовый"

          Лист.Cells(СтрокаЛиста, Колонка).NumberFormat = "@";

          Лист.Cells(СтрокаЛиста, Колонка).Value =

            Строка(выборка[стр.НазваниеРеквизита]);

        КонецЕсли;

      исключение

        // в случае ошибки вывести номер строки и колонки

        Сообщить("Ошибка установки значения для: " +

          выборка[стр.НазваниеРеквизита]);

        Сообщить("Стр: " +СтрокаЛиста+ " Кол: " +

          Колонка+ " Рек: " + стр.НазваниеРеквизита);

      КонецПопытки;

      Колонка = Колонка + 1;

      КонецЕсли;



    КонецЦикла;

    СтрокаЛиста = СтрокаЛиста + 1;

    Состояние("Экспорт из 1С в Excel " + СтрокаЛиста);

    КонецЦикла;



    // Сохраним созданную книгу в файл xls

    Книга.SaveAs(имяФайла);



    // Обязательно закроем соединение с COM объектом для освобождения памяти

    ExcelПриложение.Quit();



    Сообщить("Файл выгружен успешно: " + имяФайла );



  Исключение

    // Обработка ошибок экспорта данных из 1С в Excel

    Сообщить("Ошибка записи данных файла :" + имяФайла);

    Сообщить(ОписаниеОшибки());

    Попытка

      ExcelПриложение.Quit();

    Исключение

    КонецПопытки;

  КонецПопытки;

КонецПроцедуры

Код 1C v 7.x

 //Простейший пример вывода из 1С:Предприятия 7.7 в MS Excel. Обеспечение наличия у рабочей книги единственного листа,

//установка размера, жирности и цвета шрифта, ширины колонок, рамок и заливки ячеек. Выравнивание текста

//ячеек, группировка строк, установка числового формата ячеек, закрепление области.

 

Процедура Вывод()

    Попытка

        Application=СоздатьОбъект("Excel.Application");

    Исключение

        Сообщить(ОписаниеОшибки(),"!!!");

        Сообщить("Возможно, MS Excel не установлен на этом компьютере.");

        Возврат;

    КонецПопытки;

    

    //Создание рабочей книги

 

    WorkBook=Application.WorkBooks.Add();

    //Получение окна

 

    Window=WorkBook.Windows(1);

    //Установка невидимости окна для убыстрения вывода

 

    Window.Visible=0;

    //Обеспечение наличия у рабочей книги единственного листа

 

    Если WorkBook.Worksheets.Count=0 Тогда

        WorkBook.Worksheets.Add();

    Иначе

        Application.DisplayAlerts=0;//не выдавать предупреждений

 

        Пока WorkBook.Worksheets.Count>1 Цикл

            WorkBook.Worksheets(1).Delete();

        КонецЦикла;

        Application.DisplayAlerts=-1;//восстановление флага выдачи предупреждений

 

    КонецЕсли;

    //Получение рабочего листа

 

    Worksheet=WorkBook.Worksheets(1);

    //Задание имени рабочего листа

 

    Worksheet.Name="Пример вывода";

    

    //Заголовок документа

 

    Worksheet.Range("A1").Value="Пример вывода из 1С:Предприятия в MS Excel";

    Worksheet.Range("A2").Value="сегодня "+ТекущаяДата();

    Worksheet.Range("A1:A2").Font.Size=14;//размер шрифта

 

    Worksheet.Range("A1:A2").Font.Bold=-1;//жирный шрифт

 

    

    //Задание ширины колонок

 

    Worksheet.Columns(1).ColumnWidth=60;

    Worksheet.Columns(2).ColumnWidth=15;

    Worksheet.Columns(3).ColumnWidth=15;

    

    //Шапка документа

 

    Worksheet.Range("A4").Value="Первая колонка";

    Для ы=7 по 10 Цикл//рамки

 

        Worksheet.Range("A4").Borders(ы).LineStyle=1;

        Worksheet.Range("A4").Borders(ы).Weight=-4138;//xlMedium

 

    КонецЦикла;

    Worksheet.Range("A4").Interior.ColorIndex=15;//заливка серым

 

    Worksheet.Range("A4").HorizontalAlignment=-4108;//выравнивание текста по центру

 

    

    Worksheet.Range("B4").Value="Вторая";

    Для ы=7 по 10 Цикл

        Worksheet.Range("B4").Borders(ы).LineStyle=1;

        Worksheet.Range("B4").Borders(ы).Weight=-4138;

    КонецЦикла;

    Worksheet.Range("B4").Interior.ColorIndex=15;

    Worksheet.Range("B4").HorizontalAlignment=-4108;

    

    Worksheet.Range("C4").Value="Третья";

    Для ы=7 по 10 Цикл

        Worksheet.Range("C4").Borders(ы).LineStyle=1;

        Worksheet.Range("C4").Borders(ы).Weight=-4138;

    КонецЦикла;

    Worksheet.Range("C4").Interior.ColorIndex=15;

    Worksheet.Range("C4").HorizontalAlignment=-4108;

    

    //Для группировки строк:

     Worksheet.Outline.SummaryRow=0;//"итоговые" строки отображать сверху (если снизу, то 1)

     

    //Вывод строк

     Worksheet.Range("A5").Value="Объект аналитики";

    Worksheet.Range("A5").Font.ColorIndex=5;//цвет шрифта - синий

 

    Worksheet.Range("B5").Value=123.45;

    Worksheet.Range("B5").Font.ColorIndex=5;

    Worksheet.Range("C5").Value=678.9;

    Worksheet.Range("C5").Font.ColorIndex=5;

    

    Worksheet.Range("A6").Value="Объект аналитики";

    Worksheet.Range("A6").Font.ColorIndex=3;//цвет шрифта - красный

 

    Worksheet.Range("B6").Value=123.45;

    Worksheet.Range("B6").Font.ColorIndex=3;

    Worksheet.Range("C6").Value=678.9;

    Worksheet.Range("C6").Font.ColorIndex=3;

    

    Worksheet.Range("A7").Value="Объект аналитики";

    Worksheet.Range("B7").Value=123.45;

    Worksheet.Range("C7").Value=678.9;

    

    Worksheet.Range("A8").Value="Объект аналитики";

    Worksheet.Range("B8").Value=123.45;

    Worksheet.Range("C8").Value=678.9;

    

    Worksheet.Range("A9").Value="Объект аналитики";

    Worksheet.Range("A9").Font.ColorIndex=3;//цвет шрифта - красный

 

    Worksheet.Range("B9").Value=123.45;

    Worksheet.Range("B9").Font.ColorIndex=3;

    Worksheet.Range("C9").Value=678.9;

    Worksheet.Range("C9").Font.ColorIndex=3;

    

    Worksheet.Range("A10").Value="Объект аналитики";

    Worksheet.Range("B10").Value=123.45;

    Worksheet.Range("C10").Value=678.9;

    

    Worksheet.Range("A11").Value="Объект аналитики";

    Worksheet.Range("B11").Value=123.45;

    Worksheet.Range("C11").Value=678.9;

    

    Worksheet.Range("A12").Value="Объект аналитики";

    Worksheet.Range("A12").Font.ColorIndex=5;//цвет шрифта - синий

 

    Worksheet.Range("B12").Value=123.45;

    Worksheet.Range("B12").Font.ColorIndex=5;

    Worksheet.Range("C12").Value=678.9;

    Worksheet.Range("C12").Font.ColorIndex=5;

    

    Worksheet.Range("A13").Value="Объект аналитики";

    Worksheet.Range("A13").Font.ColorIndex=3;//цвет шрифта - красный

 

    Worksheet.Range("B13").Value=123.45;

    Worksheet.Range("B13").Font.ColorIndex=3;

    Worksheet.Range("C13").Value=678.9;

    Worksheet.Range("C13").Font.ColorIndex=3;

    

    Worksheet.Range("A14").Value="Объект аналитики";

    Worksheet.Range("B14").Value=123.45;

    Worksheet.Range("C14").Value=678.9;

    

    Worksheet.Range("A15").Value="Объект аналитики";

    Worksheet.Range("B15").Value=123.45;

    Worksheet.Range("C15").Value=678.9;

    

    Worksheet.Range("A16").Value="Объект аналитики";

    Worksheet.Range("A16").Font.ColorIndex=3;//цвет шрифта - красный

 

    Worksheet.Range("B16").Value=123.45;

    Worksheet.Range("B16").Font.ColorIndex=3;

    Worksheet.Range("C16").Value=678.9;

    Worksheet.Range("C16").Font.ColorIndex=3;

    

    Worksheet.Range("A17").Value="Объект аналитики";

    Worksheet.Range("B17").Value=123.45;

    Worksheet.Range("C17").Value=678.9;

    

    Worksheet.Range("A18").Value="Объект аналитики";

    Worksheet.Range("B18").Value=123.45;

    Worksheet.Range("C18").Value=678.9;

    

    //Установка рамок

 

    Для НомСтр=5 по 18 Цикл

        Для ы=7 по 10 Цикл

            Worksheet.Range("A"+НомСтр).Borders(ы).LineStyle=1;

            Worksheet.Range("B"+НомСтр).Borders(ы).LineStyle=1;

            Worksheet.Range("C"+НомСтр).Borders(ы).LineStyle=1;

        КонецЦикла;

    КонецЦикла;

    

    //Группировка строк

 

    Worksheet.Range("7:8").Rows.Group();

    Worksheet.Range("10:11").Rows.Group();

    Worksheet.Range("14:15").Rows.Group();

    Worksheet.Range("17:18").Rows.Group();

    Worksheet.Range("6:11").Rows.Group();

    Worksheet.Range("13:18").Rows.Group();

    

    //Свёртка группировок до первого уровня

 

    Worksheet.Outline.ShowLevels(1);

    

    //Установка числового формата

 

    Попытка

        Worksheet.Range("B5:C18").NumberFormat="# ##0.00";

 

    Исключение

        Попытка

            Worksheet.Range("B5:C18").NumberFormat="# ##0,00";

 

        Исключение

        КонецПопытки;

    КонецПопытки;

    

    //Установка видимости приложения и его окна 

 

    Application.Visible=-1;

    Window.Visible=-1;

    

    //Закрепление области

 

    Worksheet.Range("A5").S_elect();

    Window.FreezePanes = -1;

КонецПроцедуры //Вывод

Категория: Работа с Microsoft Office и OpenOffice

Автоматическая установка ширины колонки табличного документа.

Процедура, которая "примерно" делает автоширину колонок (навроде, как если бы выделить все колонки и дважды щелкнуть мышкой по границе заголовка колонки). Привожу текст, работает неахти, но лучше чем ничего:

Код 1C v 8.х

 Процедура РасчетШириныКолонок(ТабличныйДокумент)

    

    Перем МаксимальноеКоличествоСтрок, МаксимальнаяШиринаКолонки;

    Перем КонечнаяСтрока, НачальнаяСтрока, ТекущаяКолонка, ТекущаяСтрока, НачалоДанных;

    Перем ОбластьШапки, ОбластьПодвала;

    Перем ШиринаКолонки, ТекстЯчейки, НомерСтрокиТекста;

    Перем КоличествоУровнейГруппировокСтрок, Отступ;

    Перем ШириныКолонок;

    

    // Максимальное количество строк отчета, которые будут использованы для расчета ширин колонок

 

    МаксимальноеКоличествоСтрок = 50;

    // Ограничение максимальной ширины колонки

 

    МаксимальнаяШиринаКолонки = 50;

    // Массив, в который будут помещаться ширины колонок

 

    ШириныКолонок = Новый Массив;

    // Получим количество уровней группировок в отчете для учета автоматического отступа

 

    КоличествоУровнейГруппировокСтрок = ТабличныйДокумент.КоличествоУровнейГруппировокСтрок();

    

    // Инициализируем начальные строки

 

    НачальнаяСтрока = 0;

    НачалоДанных = 0;

    

    // Найдем в результирующем документе область шапки таблицы

 

    ОбластьШапки = ТабличныйДокумент.Области.Найти("ШапкаТаблицы");

    Если ТипЗнч(ОбластьШапки) = Тип("ОбластьЯчеекТабличногоДокумента") Тогда

        

        // Из шапки таблицы получим начальную строку с которой будем рассчитывать ширины

         НачальнаяСтрока = ОбластьШапки.Верх;

        НачалоДанных = ОбластьШапки.Низ + 1;

    Иначе

        

        // Если область шапки таблицы не найдена, найдем область шапки строк

         ОбластьШапки = ТабличныйДокумент.Области.Найти("ШапкаСтрок");

        Если ТипЗнч(ОбластьШапки) = Тип("ОбластьЯчеекТабличногоДокумента") Тогда

            

            // Из шапки таблицы получим начальную строку с которой будем рассчитывать ширины

             НачальнаяСтрока = ОбластьШапки.Верх;

            НачалоДанных = ОбластьШапки.Низ + 1;

            

        КонецЕсли;

    КонецЕсли;

    

    // Получим область подвала отчета и вычислим конечную строку расчета

 

    ОбластьПодвала = ТабличныйДокумент.Области.Найти("Подвал");

    Если ТипЗнч(ОбластьПодвала) = Тип("ОбластьЯчеекТабличногоДокумента") Тогда

        // Область подвала найдена

        КонечнаяСтрока = ОбластьПодвала.Верх - 1;

        Если КонечнаяСтрока - НачальнаяСтрока > МаксимальноеКоличествоСтрок Тогда

            КонечнаяСтрока = НачальнаяСтрока + МаксимальноеКоличествоСтрок;

        КонецЕсли;

    Иначе 

            // Область подвала не найдена

        КонечнаяСтрока = НачальнаяСтрока + МаксимальноеКоличествоСтрок;

    КонецЕсли;

    

    // Ограничим конечную строку

    КонечнаяСтрока = Мин(КонечнаяСтрока, ТабличныйДокумент.ВысотаТаблицы);

    // Переберем все колонки отчета

    Для ТекущаяКолонка = 1 По ТабличныйДокумент.ШиринаТаблицы Цикл

        АвтоОтступ = 0;

        // Переберем строки, которые будут использованы для расчета ширин колонок

        Для ТекущаяСтрока = НачальнаяСтрока По КонечнаяСтрока Цикл

            ШиринаКолонки = 0;

            // Получим область текущей ячейки

            ОбластьЯчейки = ТабличныйДокумент.Область(ТекущаяСтрока, ТекущаяКолонка);

            Если ОбластьЯчейки.Лево <> ТекущаяКолонка Или ОбластьЯчейки.Верх <> ТекущаяСтрока Тогда

                // Данная ячейка принадлежит объединенным ячейкам и не является начальной ячейкой

                Продолжить;

            КонецЕсли;

            Если КоличествоУровнейГруппировокСтрок > 0 И ТекущаяСтрока = НачалоДанных Тогда

                // Для первой строки с данными получим значение автоотступа

                АвтоОтступ = ОбластьЯчейки.АвтоОтступ;

            КонецЕсли;

            // Получим текст ячейки

            ТекстЯчейки = ОбластьЯчейки.Текст;

            // Для каждой строки из текста ячейки рассчитаем количество символов в строке

            Для НомерСтрокиТекста = 1 По СтрЧислоСтрок(ТекстЯчейки) Цикл

                ШиринаТекстаЯчейки = СтрДлина(СтрПолучитьСтроку(ТекстЯчейки, НомерСтрокиТекста));

                // Если используется автоотступ, то прибавим к ширине ячейки его величину

                Если АвтоОтступ <> Неопределено И АвтоОтступ > 0 Тогда

                    ШиринаТекстаЯчейки = ШиринаТекстаЯчейки + КоличествоУровнейГруппировокСтрок * АвтоОтступ;

                КонецЕсли;

                ШиринаКолонки = Макс(ШиринаКолонки, ШиринаТекстаЯчейки);

            КонецЦикла;



            Если ШиринаКолонки > МаксимальнаяШиринаКолонки Тогда

                // Ограничим ширину колонки

                ШиринаКолонки = МаксимальнаяШиринаКолонки;

            КонецЕсли;

            Если ШиринаКолонки <> 0 Тогда

                // Ширина колонки рассчитана

                // Определим, сколько ячеек по ширине используется в области для текущей ячейки

                КоличествоКолонок = ОбластьЯчейки.Право - ОбластьЯчейки.Лево;

                // Переберем все ячейки, расположенные в области

                 Для НомерКолонки = 0 По КоличествоКолонок Цикл

                    Если ШириныКолонок.ВГраница() > ТекущаяКолонка - 1 + НомерКолонки Тогда

                        // В массиве ширин колонок уже был элемент для текущей колонки

                        Если ШириныКолонок[ТекущаяКолонка - 1 + НомерКолонки] = Неопределено Тогда

                            // Значение ширины колонки еще не было установлено

                            ШириныКолонок[ТекущаяКолонка - 1 + НомерКолонки] = ШиринаКолонки / (КоличествоКолонок + 1);

                        Иначе

                            // Значение ширины колонки уже было установлено

                             // Вычислим максимум ширины колонки

                             ШириныКолонок[ТекущаяКолонка - 1 + НомерКолонки] = 

                                Макс(ШириныКолонок[ТекущаяКолонка - 1 + НомерКолонки], ШиринаКолонки / (КоличествоКолонок + 1));

                        КонецЕсли;

                    Иначе

                        // В массиве ширин колонок еще не было элемента для данной колонки

                        // Добавим элемент в массив ширин колонок

                        ШириныКолонок.Вставить(ТекущаяКолонка - 1 + НомерКолонки, ШиринаКолонки / (КоличествоКолонок + 1));

                    КонецЕсли;

                КонецЦикла;

            КонецЕсли;

        КонецЦикла;    // Конец цикла перебора строк

    КонецЦикла;    // Конец цикла перебора колонок

    

    // Переберем все элементы в массиве вычисленных ширин колонок

     Для ТекущаяКолонка = 0 По ШириныКолонок.ВГраница() Цикл

        Если ШириныКолонок[ТекущаяКолонка] <> Неопределено Тогда

            // Ширина колонок установлена

            // Установим ширину области ячеек

            ТабличныйДокумент.Область(, ТекущаяКолонка + 1, НачалоДанных, ТекущаяКолонка + 1).ШиринаКолонки = ШириныКолонок[ТекущаяКолонка] + 1;

        КонецЕсли;

    КонецЦикла;

КонецПроцедуры

Очень полезная штука при условии, что у Вас заранее невозможно определить размер итоговых колонок в печатной форме. А так, надо просто "натравить" процедуру с соответствующими параметрами на нужные ячейки таблицы, и они сами "выровняются" и приобретут необходимый размер (ширину).

Код 1C v 7.x

 //<!-- Патырило С.С. 22-04-2004 : Автоматическая установка ширины колонки

//  Для изменения ширины колонки уже сформированной таблицы, требуется передать

// в качестве параметров переменную с объектом "Таблица", координаты ячейки (группы ячеек)

// для которых нужно установить ширину столбца и ширину столбца в символах.

// При этом не обязательно передавать координаты требуемой ячейки (итоговой),

// (т.е. когда нет возможности или сложно определить позицию итоговой строки)

// достаточно указать ячейку из данного столбца (например первую).

//  Процедура установит ширину столбца выбрав максимальное из значений - 

// текущего размера (установленного в конфигураторе, или программно перед вызовом 

// функции) и переданного в качестве параметра. 

Процедура глУстШиринуЯчейки(Таб, Строка1, Столбец1, Строка2, Столбец2, ДлТекста = 0) Экспорт

	Если ДлТекста = 0 Тогда

	    врДлина	= СтрДлина(СокрЛП(Таб.Область(Строка1, Столбец1, Строка2, Столбец2).Текст));

	Иначе

		врДлина	= ДлТекста;

	КонецЕсли;

	Таб.Область(Строка1, Столбец1, Строка2, Столбец2).ШиринаСтолбца(Макс(Таб.Область(Строка1, Столбец1, Строка2, Столбец2).ШиринаСтолбца(), врДлина));

КонецПроцедуры

// --> Патырило С.С. 22-04-2004

Категория: Табличный документ

Группировка строк Excel

В ниже указанном коде нужно убрать символ _

Код 1C v 8.х

 

//Группировка строк по уровню 2 

    Worksheet.Range("7:8").Rows.Group();

    Worksheet.Range("10:11").Rows.Group();

    Worksheet.Range("14:15").Rows.Group();

    Worksheet.Range("17:18").Rows.Group();  



    //Группировка строк по уровню 1  

    Worksheet.Range("6:11").Rows.Group();

    Worksheet.Range("13:18").Rows.Group();

    

    //Свёртка группировок до первого уровня

     Worksheet.Outline.ShowLevels(1);



//или



Excel.Range("A3:A6").S_elect();

Excel.S_election.Rows.Group();



// еще пример

BegCell = Лист.Cells(1,1);

EndCell = Лист.Cells(4,1);

Лист.Range(BegCell,EndCell).Rows.Group();

Код 1C v 7.x

 

//Простейший пример вывода из 1С:Предприятия 7.7 в MS Excel. Обеспечение наличия у рабочей книги единственного листа,

 

//установка размера, жирности и цвета шрифта, ширины колонок, рамок и заливки ячеек. Выравнивание текста

 

//ячеек, группировка строк, установка числового формата ячеек, закрепление области.

 

Процедура Вывод()

    Попытка

        Application=СоздатьОбъект("Excel.Application");

    Исключение

        Сообщить(ОписаниеОшибки(),"!!!");

        Сообщить("Возможно, MS Excel не установлен на этом компьютере.");

        Возврат;

    КонецПопытки;

    

    //Создание рабочей книги

 

    WorkBook=Application.WorkBooks.Add();

    //Получение окна

 

    Window=WorkBook.Windows(1);

    //Установка невидимости окна для убыстрения вывода

 

    Window.Visible=0;

    //Обеспечение наличия у рабочей книги единственного листа

 

    Если WorkBook.Worksheets.Count=0 Тогда

        WorkBook.Worksheets.Add();

    Иначе

        Application.DisplayAlerts=0;//не выдавать предупреждений

 

        Пока WorkBook.Worksheets.Count>1 Цикл

            WorkBook.Worksheets(1).Delete();

        КонецЦикла;

        Application.DisplayAlerts=-1;//восстановление флага выдачи предупреждений

 

    КонецЕсли;

    //Получение рабочего листа

 

    Worksheet=WorkBook.Worksheets(1);

    //Задание имени рабочего листа

 

    Worksheet.Name="Пример вывода";

    

    //Заголовок документа

 

    Worksheet.Range("A1").Value="Пример вывода из 1С:Предприятия в MS Excel";

    Worksheet.Range("A2").Value="сегодня "+ТекущаяДата();

    Worksheet.Range("A1:A2").Font.Size=14;//размер шрифта

 

    Worksheet.Range("A1:A2").Font.Bold=-1;//жирный шрифт

 

    

    //Задание ширины колонок

 

    Worksheet.Columns(1).ColumnWidth=60;

    Worksheet.Columns(2).ColumnWidth=15;

    Worksheet.Columns(3).ColumnWidth=15;

    

    //Шапка документа

 

    Worksheet.Range("A4").Value="Первая колонка";

    Для ы=7 по 10 Цикл//рамки

 

        Worksheet.Range("A4").Borders(ы).LineStyle=1;

        Worksheet.Range("A4").Borders(ы).Weight=-4138;//xlMedium

 

    КонецЦикла;

    Worksheet.Range("A4").Interior.ColorIndex=15;//заливка серым

 

    Worksheet.Range("A4").HorizontalAlignment=-4108;//выравнивание текста по центру

 

    

    Worksheet.Range("B4").Value="Вторая";

    Для ы=7 по 10 Цикл

        Worksheet.Range("B4").Borders(ы).LineStyle=1;

        Worksheet.Range("B4").Borders(ы).Weight=-4138;

    КонецЦикла;

    Worksheet.Range("B4").Interior.ColorIndex=15;

    Worksheet.Range("B4").HorizontalAlignment=-4108;

    

    Worksheet.Range("C4").Value="Третья";

    Для ы=7 по 10 Цикл

        Worksheet.Range("C4").Borders(ы).LineStyle=1;

        Worksheet.Range("C4").Borders(ы).Weight=-4138;

    КонецЦикла;

    Worksheet.Range("C4").Interior.ColorIndex=15;

    Worksheet.Range("C4").HorizontalAlignment=-4108;

    

    //Для группировки строк:

 

    Worksheet.Outline.SummaryRow=0;//"итоговые" строки отображать сверху (если снизу, то 1)

 

    

    //Вывод строк

 

    Worksheet.Range("A5").Value="Объект аналитики";

    Worksheet.Range("A5").Font.ColorIndex=5;//цвет шрифта - синий

 

    Worksheet.Range("B5").Value=123.45;

    Worksheet.Range("B5").Font.ColorIndex=5;

    Worksheet.Range("C5").Value=678.9;

    Worksheet.Range("C5").Font.ColorIndex=5;

    

    Worksheet.Range("A6").Value="Объект аналитики";

    Worksheet.Range("A6").Font.ColorIndex=3;//цвет шрифта - красный

 

    Worksheet.Range("B6").Value=123.45;

    Worksheet.Range("B6").Font.ColorIndex=3;

    Worksheet.Range("C6").Value=678.9;

    Worksheet.Range("C6").Font.ColorIndex=3;

    

    Worksheet.Range("A7").Value="Объект аналитики";

    Worksheet.Range("B7").Value=123.45;

    Worksheet.Range("C7").Value=678.9;

    

    Worksheet.Range("A8").Value="Объект аналитики";

    Worksheet.Range("B8").Value=123.45;

    Worksheet.Range("C8").Value=678.9;

    

    Worksheet.Range("A9").Value="Объект аналитики";

    Worksheet.Range("A9").Font.ColorIndex=3;//цвет шрифта - красный

 

    Worksheet.Range("B9").Value=123.45;

    Worksheet.Range("B9").Font.ColorIndex=3;

    Worksheet.Range("C9").Value=678.9;

    Worksheet.Range("C9").Font.ColorIndex=3;

    

    Worksheet.Range("A10").Value="Объект аналитики";

    Worksheet.Range("B10").Value=123.45;

    Worksheet.Range("C10").Value=678.9;

    

    Worksheet.Range("A11").Value="Объект аналитики";

    Worksheet.Range("B11").Value=123.45;

    Worksheet.Range("C11").Value=678.9;

    

    Worksheet.Range("A12").Value="Объект аналитики";

    Worksheet.Range("A12").Font.ColorIndex=5;//цвет шрифта - синий

 

    Worksheet.Range("B12").Value=123.45;

    Worksheet.Range("B12").Font.ColorIndex=5;

    Worksheet.Range("C12").Value=678.9;

    Worksheet.Range("C12").Font.ColorIndex=5;

    

    Worksheet.Range("A13").Value="Объект аналитики";

    Worksheet.Range("A13").Font.ColorIndex=3;//цвет шрифта - красный

 

    Worksheet.Range("B13").Value=123.45;

    Worksheet.Range("B13").Font.ColorIndex=3;

    Worksheet.Range("C13").Value=678.9;

    Worksheet.Range("C13").Font.ColorIndex=3;

    

    Worksheet.Range("A14").Value="Объект аналитики";

    Worksheet.Range("B14").Value=123.45;

    Worksheet.Range("C14").Value=678.9;

    

    Worksheet.Range("A15").Value="Объект аналитики";

    Worksheet.Range("B15").Value=123.45;

    Worksheet.Range("C15").Value=678.9;

    

    Worksheet.Range("A16").Value="Объект аналитики";

    Worksheet.Range("A16").Font.ColorIndex=3;//цвет шрифта - красный

 

    Worksheet.Range("B16").Value=123.45;

    Worksheet.Range("B16").Font.ColorIndex=3;

    Worksheet.Range("C16").Value=678.9;

    Worksheet.Range("C16").Font.ColorIndex=3;

    

    Worksheet.Range("A17").Value="Объект аналитики";

    Worksheet.Range("B17").Value=123.45;

    Worksheet.Range("C17").Value=678.9;

    

    Worksheet.Range("A18").Value="Объект аналитики";

    Worksheet.Range("B18").Value=123.45;

    Worksheet.Range("C18").Value=678.9;

    

    //Установка рамок

 

    Для НомСтр=5 по 18 Цикл

        Для ы=7 по 10 Цикл

            Worksheet.Range("A"+НомСтр).Borders(ы).LineStyle=1;

            Worksheet.Range("B"+НомСтр).Borders(ы).LineStyle=1;

            Worksheet.Range("C"+НомСтр).Borders(ы).LineStyle=1;

        КонецЦикла;

    КонецЦикла;

    

    //Группировка строк

 

    Worksheet.Range("7:8").Rows.Group();

    Worksheet.Range("10:11").Rows.Group();

    Worksheet.Range("14:15").Rows.Group();

    Worksheet.Range("17:18").Rows.Group();

    Worksheet.Range("6:11").Rows.Group();

    Worksheet.Range("13:18").Rows.Group();

    

    //Свёртка группировок до первого уровня

 

    Worksheet.Outline.ShowLevels(1);

    

    //Установка числового формата

 

    Попытка

        Worksheet.Range("B5:C18").NumberFormat="# ##0.00";

 

    Исключение

        Попытка

            Worksheet.Range("B5:C18").NumberFormat="# ##0,00";

 

        Исключение

        КонецПопытки;

    КонецПопытки;

    

    //Установка видимости приложения и его окна 

 

    Application.Visible=-1;

    Window.Visible=-1;

    

    //Закрепление области

 

    Worksheet.Range("A5").S_elect();

    Window.FreezePanes = -1;

КонецПроцедуры //Вывод

Категория: Работа с Microsoft Office и OpenOffice

Вывод (печать) таблицы значений в табличный документ

Пример кода быстрая Печать таблицы значений

Код 1C v 8.х

  //ТПОтчета - Табличное поле с формы (Таблица значений) с данными

ПострПечать = Новый ПостроительОтчета;

    ПострПечать.ИсточникДанных = Новый ОписаниеИсточникаДанных(ТПОтчета);

    ПострПечать.МакетОформления = ПолучитьМакетОформления(СтандартноеОформление.Интерфейс);

    ПострПечать.Выполнить();

    Для каждого Колонка Из ПострПечать.ВыбранныеПоля Цикл

        Колонка.Представление = ТПОтчета.Колонки[Колонка.Имя].Заголовок;

    КонецЦикла; 

    ПострПечать.Вывести();

Пример функций Печать таблицы значений с использованием Макета

Код 1C v 8.х

 //Процедура  формирует и выводит отчет по переданной таблице значений

// Параметры :

// ТЗ - ТаблицаЗначений

Процедура УниверсальныйОтчетПоТЗ(ТЗ)



Табл=Новый ТабличныйДокумент;

Макет = ЭтотОбъект.ПолучитьМакет("Макет");

ОбластьШапкаОсновной=Макет.ПолучитьОбласть("Шапка|Основной");

ОбластьСтрокаОсновной=Макет.ПолучитьОбласть("Строка|Основной");

ОбластьИтогОсновной=Макет.ПолучитьОбласть("Итог|Основной");

ОбластьШапкаДОП=Макет.ПолучитьОбласть("Шапка|Показатели");

ОбластьСтрокаДОП=Макет.ПолучитьОбласть("Строка|Показатели");

ОбластьИтогДОП=Макет.ПолучитьОбласть("Итог|Показатели");

Табл.Вывести(ОбластьШапкаОсновной);



Для Каждого Колонка из Тз.Колонки ЦИКЛ

 ОбластьШапкаДОП.Параметры.ИмяПоказателя=Колонка.Имя;

 Табл.Присоединить(ОбластьШапкаДОП);

КонецЦикла;



счетчик=0;

Для каждого стр из Тз Цикл

 счетчик=счетчик+1;

 ОбластьСтрокаОсновной.Параметры.счетчик=счетчик; 

 Табл.Вывести(ОбластьСтрокаОсновной);

  Для Каждого Колонка из Тз.Колонки ЦИКЛ

   ОбластьСтрокаДОП.Параметры.ЗначениеКолонки=стр[Колонка.Имя];

   Табл.Присоединить(ОбластьСтрокаДОП);

  КонецЦикла;

КонецЦикла;

Табл.Вывести(ОбластьИтогОсновной);



Для Каждого Колонка из Тз.Колонки ЦИКЛ

 ОбластьИтогДОП.Параметры.Итог=Тз.Итог(Колонка.Имя);

 Табл.Присоединить(ОбластьИтогДОП);

КонецЦикла;



Табл.Показать();

КонецПроцедуры

Код 1C v 7.x

 

//Вывести таблицу значений

Процедура ПечатьТЗвТаб(ТЗ, Заголовок = "",КолонкиПоНазваниям = 0) Экспорт

	Перем ТТЗ;

	ТЗ.Выгрузить(ТТЗ);

	МаксШирина = 50;    // максимальная ширина колонки 

	СпШирина = СоздатьОбъект("СписокЗначений"); // список ширин колонок по таблице

	Для сч = 1 по ТТЗ.КоличествоКолонок() Цикл

		Если КолонкиПоНазваниям = 0  Тогда

			ИмяРек = ТТЗ.ПолучитьПараметрыКолонки(сч);

		Иначе

			ИмяРек = "";

			ТТЗ.ПолучитьПараметрыКолонки(сч,,,,ИмяРек,);

		КонецЕсли;

		СпШирина.ДобавитьЗначение(СтрДлина(ИмяРек)*1.2); // с поправкой на размер шрифта

	КонецЦикла;	

	

	// просто печать таблицы - вывод всех строк и колонок

	// числовые значения - по правому краю. Автоподбор ширины - в пределах МаксШирина

	Таб=СоздатьОбъект("Таблица");

	Таб.ИсходнаяТаблица("ПечатьТЗ");

	Если СокрЛП(Заголовок) <> "" Тогда

		Таб.ВывестиСекцию("Шапка");

	КонецЕсли;

	// заголовки таблицы

	Таб.ВывестиСекцию("Строка|Общая");

	Для сч=1 по ТТЗ.КоличествоКолонок() Цикл

		Если КолонкиПоНазваниям = 0  Тогда

			ИмяРек = ТТЗ.ПолучитьПараметрыКолонки(сч);

		Иначе

			ИмяРек = ""; 

			Ном = "";

			ТТЗ.ПолучитьПараметрыКолонки(сч,,,,ИмяРек,);

		КонецЕсли;

		Таб.ПрисоединитьСекцию("Строка|Столбец");  

	КонецЦикла;

	ВысотаШапки = Таб.ВысотаТаблицы();

	// данные таблицы по строкам

	ТТЗ.ВыбратьСтроки();

	Пока ТТЗ.ПолучитьСтроку()=1 Цикл

		Ном = ТТЗ.НомерСтроки;

		Таб.ВывестиСекцию("Строка|Общая");

		Выс = Таб.ВысотаТаблицы();

		Для сч=1 по ТТЗ.КоличествоКолонок() Цикл

			ИмяРек=ТТЗ.ПолучитьЗначение(Ном,сч);

			Таб.ПрисоединитьСекцию("Строка|Столбец");

			Если ТипЗначения(ИмяРек) = 1 Тогда

				Обл = Таб.Область("R"+Выс+"C"+(Сч+1)); // ячейка в которую поместили данные

				Обл.ГоризонтальноеПоложение(2); // числа - вправо

			КонецЕсли;

			НачШирина = СпШирина.ПолучитьЗначение(Сч);

			Ширина = СтрДлина(ИмяРек);

			СпШирина.УстановитьЗначение(Сч,Макс(НачШирина,Ширина));

		КонецЦикла;

	КонецЦикла;

	

	Для сч = 1 по СпШирина.РазмерСписка() Цикл

		Обл = Таб.Область("R"+ВысотаШапки+"C"+(Сч+1));

		// форматируем ширину таблицы

		Ширина = Мин(МаксШирина,2+СпШирина.ПолучитьЗначение(Сч));

		Обл.ШиринаСтолбца(Ширина);   

		// форматируем заголовок

		Обл.Полужирный(1);

	КонецЦикла;	

	Таб.Показать(Заголовок);

	Таб.ТолькоПросмотр(1);

КонецПроцедуры

ИЛИ

Код 1C v 7.x

 Процедура глВывестиТаблицуЗначений(ТаблицаЗначений, Заголовок = "") Экспорт

Перем Таб, ИИ, ЖЖ, НазваниеКолонки, ТипКолонки, Ширина, Значение, Сообщение;



Таб = СоздатьОбъект("Таблица");



Если ТипЗначенияСтр(ТаблицаЗначений) <> "ТаблицаЗначений" Тогда

Сообщение = "В процедуру ""глВывестиТаблицуЗначений()"" передана переменная не типа ""ТаблицаЗначений"", "+

"а типа """+СокрЛП(ТипЗначенияСтр(ТаблицаЗначений))+"""";

Таб.Область(1, 1, 1, 1).Текст = Сообщение;

Таб.Область(1, 1, 1, 1).ШиринаСтолбца(СтрДлина(Сообщение));



Таб.ТолькоПросмотр(1);

Таб.Показать("Не таблица значений: "+Заголовок);



Возврат;

КонецЕсли;



Для ЖЖ = 1 по ТаблицаЗначений.КоличествоКолонок() цикл

ТаблицаЗначений.ПолучитьПараметрыКолонки(ЖЖ,,,, НазваниеКолонки);

Таб.Область(1, ЖЖ, 1, ЖЖ).Текст = СокрЛП(НазваниеКолонки);

Таб.Область(1, ЖЖ, 1, ЖЖ).РамкаОбвести(5, 5, 5, 5);

Таб.Область(1, ЖЖ, 1, ЖЖ).ВертикальноеПоложение(3);

Таб.Область(1, ЖЖ, 1, ЖЖ).ГоризонтальноеПоложение(3);

Таб.Область(1, ЖЖ, 1, ЖЖ).РазмерШрифта(7);

Таб.Область(1, ЖЖ, 1, ЖЖ).Полужирный(1);



Ширина = Таб.Область(1, ЖЖ, 1, ЖЖ).ШиринаСтолбца();

Ширина = Макс(Ширина, СтрДлина(СокрЛП(НазваниеКолонки)));

Таб.Область(1, ЖЖ, 1, ЖЖ).ШиринаСтолбца(Ширина);

КонецЦикла;



Для ИИ = 1 по ТаблицаЗначений.КоличествоСтрок() цикл

Для ЖЖ = 1 по ТаблицаЗначений.КоличествоКолонок() цикл

Значение = ТаблицаЗначений.ПолучитьЗначение(ИИ, ЖЖ);

Таб.Область(ИИ+1, ЖЖ, ИИ+1, ЖЖ).Текст = Значение;

Таб.Область(ИИ+1, ЖЖ, ИИ+1, ЖЖ).Расшифровка(Значение, 0);

Таб.Область(ИИ+1, ЖЖ, ИИ+1, ЖЖ).РамкаОбвести(3, 0, 3, 0);



Ширина = Таб.Область(1, ЖЖ, 1, ЖЖ).ШиринаСтолбца();

Ширина = Макс(Ширина, СтрДлина(СокрЛП(Строка(Значение))));

Таб.Область(1, ЖЖ, 1, ЖЖ).ШиринаСтолбца(Ширина);



ТаблицаЗначений.ПолучитьПараметрыКолонки(ЖЖ, ТипКолонки); ;

Если ТипКолонки = "Число" тогда

Таб.Область(ИИ+1, ЖЖ, ИИ+1, ЖЖ).ГоризонтальноеПоложение(2);

КонецЕсли;

Если ИИ = ТаблицаЗначений.ТекущаяСтрока() тогда

Таб.Область(ИИ+1, ЖЖ, ИИ+1, ЖЖ).ЦветФона(255, 0, 0);

КонецЕсли;

КонецЦикла;

КонецЦикла;



Таб.ТолькоПросмотр(1);

Таб.Показать("Таблица значений: "+Заголовок);

КонецПроцедуры

Категория: Работа с Таблицей Значений