шрифтом » Поиск

Результаты по ключевому слову: шрифтом

Печать штрихкода в управляемом приложении

Программируя под 8.2, работающем в режиме управляемого приложения, я столкнулся с проблемой печати штрихкода. Для платформы 8.1 и платформы 8.2 в режиме обычного приложения такой проблемы не было: устанавливаем элемент «1С:Печать штрихкодов» в макет и наслаждаемся вертикальными черточками. В режиме управляемого приложения вываливается ошибка:

Код 1C v 8.2 УП

 ОбластьВывода.Рисунки.ШтрихКод.Объект – неопределено

Что же случилось?
Дело в том, что для управляемого приложения внешние компоненты разрабатываются по другой технологии. Пример внешней компоненты для печати штрих-кода в 8.2 есть в демонстрационной конфигурации "Управляемое приложение" в макетах справочника Товары либо в конфигурации «1С:Управление торговлей» версии 11, макеты обработки «Печать этикеток и ценников».
Данная компонента, получив в качестве параметра строку штрихкода, возвращает картинку – штрихкод, которую программисту предлагается поместить в любое удобное место печатной формы.

Теперь как это сделать.
Всего обработок аж четыре штуки:
КомпонентаПечатиШтрихкодовWindows32
КомпонентаПечатиШтрихкодовWindows64
КомпонентаПечатиШтрихкодовLinux32
КомпонентаПечатиШтрихкодовLinux64

Все они загружены в одноименные макеты. Функция, подключающая внешнюю компоненту в зависимости от платформы может выглядеть так:

Код 1C v 8.х

 Функция ПодключитьВнешнююКомпонентуПечатиШтрихкода() Экспорт

	

	// В зависимости от типа платформы подключим соответствующую внешнюю компоненту

	СистемнаяИнформация = Новый СистемнаяИнформация;



	Если СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Windows_x86 Тогда

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовWindows32", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	ИначеЕсли СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Windows_x86_64 Тогда

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовWindows64", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	ИначеЕсли СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Linux_x86 Тогда

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовLinux32", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	Иначе

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовLinux64", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	КонецЕсли;



	// Создадим объект внешней компоненты

	Если ПодключениеВыполнено Тогда

		ВнешняяКомпонента = Новый("AddIn.КартинкаШтрихкода.Barcode");

	Иначе

		Возврат Неопределено;

	КонецЕсли;

	

	// Если нет возможности рисовать

	Если НЕ ВнешняяКомпонента.ГрафикаУстановлена Тогда

		// То картинку сформировать не сможем

		Возврат Неопределено;

	Иначе

		

		// Установим основные параметры компоненты

		

		// Если в системе установлен шрифт Tahoma

		Если ВнешняяКомпонента.НайтиШрифт("Tahoma") = Истина Тогда

			// Выбираем его как шрифт для формирования картинки

			ВнешняяКомпонента.Шрифт = "Tahoma";

		Иначе

			

			// Шрифт Tahoma в системе отсутствует

			// Обойдем все доступные компоненте шрифты

			Для Сч = 0 По ВнешняяКомпонента.КоличествоШрифтов -1 Цикл

				// Получим очередной шрифт, доступный компоненте

				ТекущийШрифт = ВнешняяКомпонента.ШрифтПоИндексу(Сч);

				// Если шрифт доступен

				Если ТекущийШрифт <> Неопределено Тогда

					// Они и будет шрифтом для формирования штри-кода

					ВнешняяКомпонента.Шрифт = ТекущийШрифт;

					Прервать;

				КонецЕсли;

			КонецЦикла;

		КонецЕсли;

		

		// Утановим размер шрифта

		ВнешняяКомпонента.РазмерШрифта = 10;

		

		Возврат ВнешняяКомпонента;

		

	КонецЕсли;

	

КонецФункции

В коде выше все компоненты загружены в макеты обработки «ПечатьЭтикетокИЦенников». В принципе ничто не мешает поместить их в любое иное место. Вызов функции осуществляется командой:

Код 1C v 8.х

 ВнешняяКомпонента = ПодключитьВнешнююКомпонентуПечатиШтрихкода();

Если что-то не получилось – возвращает НЕОПРЕДЕЛЕНО.

Далее опишем функцию, которая, получив данные, сформирует нужную нам картинку с штрихкодом:

Код 1C v 8.х

 Функция ПолучитьКартинкуШтрихкода(ВнешняяКомпонента, Штрихкод, Ширина, Высота) Экспорт

	

	// Зададим размер картинки

	ВнешняяКомпонента.Ширина =Ширина;

	ВнешняяКомпонента.Высота =Высота;

	

	// Разрешим компоненте самой определять тип кода

	ВнешняяКомпонента.АвтоТип = истина;

	

	// Если код содержит контрольный символ, обязательно указываем

	ВнешняяКомпонента.СодержитКС = СтрДлина(Штрихкод) = 13;

	

	// Если отображать контрольный символ не нужно

	// ВнешняяКомпонента.ВидимостьКС = Ложь;

	

	// Формируем картинку штрихкода

	ВнешняяКомпонента.ЗначениеКода = Штрихкод;

	

	// Если установленная нами ширина меньше минимально допустимой для этого штрихкода

	Если ВнешняяКомпонента.Ширина < ВнешняяКомпонента.МинимальнаяШиринаКода Тогда

		// Скорректируем ширину

		ВнешняяКомпонента.Ширина = ВнешняяКомпонента.МинимальнаяШиринаКода + 10;

	КонецЕсли;

	

	// Сформируем картинку

	ДвоичныеДанныеКартинки = ВнешняяКомпонента.ПолучитьШтрихкод();

	

	// Если картинка сформировалась

	Если ДвоичныеДанныеКартинки <> Неопределено Тогда

		// Формируем из двоичных данных

		Возврат Новый Картинка(ДвоичныеДанныеКартинки);

	КонецЕсли;

	

	Возврат Неопределено;

	

КонецФункции

В данной функции используется автоопределение типа штрихкода командой

Код 1C v 8.х

 ВнешняяКомпонента.АвтоТип = истина;

Можно тип штрихкода указать вручную:

Код 1C v 8.х

 ВнешняяКомпонента.АвтоТип = Ложь;

ВнешняяКомпонента.ТипКода = 1; // указан тип EAN13

ТипКода - число от 0 до 15: 0 - EAN8, 1 - EAN13, 2 - EAN128. Вот полный список типов по порядку:
EAN8, EAN13, EAN128, Code39, Code128, Code16k, PDF417, Standart (Industrial) 2 of 5, Interleaved 2 of 5, Расширение Code39, Code93, ITF14, RSS14, CodaBar, EAN13 AddOn 2, EAN13 AddOn 5.

Кроме типа штрихкода, компонента имеет ряд других свойств, например ВнешняяКомпонента.ОтображатьТекст, ВнешняяКомпонента.РазмерШрифта и прочие, можно посмотреть в свойствах.

Наконец последнее - вывод штрихкода. Для этого в макет поместим картинку с именем «Штрихкод». Получаем и выводим штрихкод в область командой:

Код 1C v 8.х

 ОбластьЗначение.Рисунки.Штрихкод.Картинка = ПолучитьКартинкуШтрихкода(ВнешняяКомпонента, Штрихкод, 50, 30);

Где Штрихкод – переменная, содержащая строку штрихкода номенклатуры, 50 – требуемая ширина, 30 – высота картинки. В макете размер картинки лучше всего поставить «Реальный размер».

Замечание. Сразу бросается в глаза то, что я вручную указываю размер требуемой картинки – 50 на 30. Возникает вопрос, а нельзя ли размеры требуемой картинки получить из картинки на макете? Конечно можно:

Код 1C v 8.х

 ОбластьЗначение.Рисунки.Штрихкод.Ширина

ОбластьЗначение.Рисунки.Штрихкод.Высота

К сожалению, цифры получаемые этими командами почему-то слишком малы. Как получить реальный видимый размер картинки я пока не знаю, может кто подскажет?
Источник

Категория: Штрих-код (barcode)

Добавление поддержки нестандартного штрих-кода в обработке ПечатьЭтикеток

Обработка ПечатьЭтикеток использует компоненту "1С:Печать штрихкодов"(доступную на диске ИТС) для печати штрих-кодов(далее ШК). Эта компонента поддерживает следующие типы штрих-кодов: EAN8, EAN13, EAN128, Code39, Code128.

Что делать если на предприятии используется отличный ШК, например Interleave 2 of 5, для которго есть системный шрифт @IDAutomationSHI25M, используемый для вывода ШК на экран или на принтер.

Рассмотрим как проще всего добавить поддержку этого типа ШК в обработке ПечатьЭтикеток.

Первым делом скопируем общий макет Этикетка в макет для вывода нашего штрих-кода ЭтикеткаInterleave. В этом макете надо удалить элемент управления, связанный с компонентой "1С:Печать штрихкодов". И оформить центральное поле как параметр табличного документа ШтрихКод, выводимый шрифтом @IDAutomationSHI25M.
title

Далее разрешаем запуск обработки даже с неустановленной компонентой т.к. для вывода нашего ШК компонента не нужна. Для этого комментируем строчку в модуле формы обработки:

Код 1C v 8.х

 Процедура ПередОткрытием(Отказ, СтандартнаяОбработка)

    Попытка

        КомпонентШК = Новый COMОбъект("V8.Barcod.1");

        Макет                   = ПолучитьОбщийМакет("Этикетка");

        ЭтикеткаОбласть         = Макет.ПолучитьОбласть(1,1,4,2);

        ЭтикеткаОбласть.Рисунки.Штрихкод.Объект.Сообщение = "1111111111116";

    Исключение

        Сообщить("Компонента 1С:Печать штрихкодов не установлена на данном компьютере!

                 |Возможна печать только штрих-кодов Interleave!", СтатусСообщения.Важное);

        //Отказ = Истина;

    КонецПопытки;



КонецПроцедуры

В общем модуле УправлениеРозничнойТорговлей также есть место проверки на компоненту

Код 1C v 8.х

 #Если Клиент Тогда

// Печать этикеток со штрих-кодом

//

Процедура ПечатьЭтикеток(Товары = Неопределено) Экспорт



//am+ Эта проверка нам не нужна, во первых она выполняется ПередОткрытием в форме обработки.

// Кроме того у нас есть тип штрихкода, который печататется без компоненты.

//Попытка

// КомпонентШК = Новый COMОбъект("V8.Barcod.1");

//Исключение

// Сообщить("Компонента 1С:Печать штрихкодов не установлена на данном компьютере!", СтатусСообщения.Важное);

// Возврат;

//КонецПопытки;

//am-

В обработке есть место, где выполняется проверка типа ШК. Наш ШК сейчас не пройдет проверку и печать выполнена не будет. Чтоб печать выполнялась необходимо исправить функцию в общем модуле УправлениеРозничнойТорговлей.

Код 1C v 8.х

 

// Возвращает значение типа штрих-кода для использования в ЭУ

// "1С:Печать штрих-кодов"

//

// Параметры

//  ТипКода -   ПланыВидовХарактеристик.ТипыШтрихкодов - тип, значение для которого

//              нужно получить

//

// Возвращаемое значение:

//   Число, которое может быть присвоено свойству ЭУ "ТипКода"

//

Функция ПолучитьЗначениеТипаШтрихкодаДляЭУ(ТипКода) Экспорт

    Перем Значение;



    Если ТипКода = ПланыВидовХарактеристик.ТипыШтрихкодов.EAN8 Тогда

        Значение = 0;

    ИначеЕсли ТипКода = ПланыВидовХарактеристик.ТипыШтрихкодов.EAN13 Тогда

        Значение = 1;

    ИначеЕсли ТипКода = ПланыВидовХарактеристик.ТипыШтрихкодов.EAN128 Тогда

        Значение = 2;

    ИначеЕсли ТипКода = ПланыВидовХарактеристик.ТипыШтрихкодов.Code39 Тогда

        Значение = 3;

    ИначеЕсли ТипКода = ПланыВидовХарактеристик.ТипыШтрихкодов.Code128 Тогда

        Значение = 4;



//am+

    ИначеЕсли ТипКода = ПланыВидовХарактеристик.ТипыШтрихкодов.Interleave20FS Тогда

        Значение = 100;

//am-



    Иначе

        Значение = -1;

    КонецЕсли;



    Возврат Значение;

КонецФункции // ПолучитьЗначениеТипаШтрихкодаДляЭУ()

Мы на завершающем этапе, вносим изменения непосредственно в обработку.

Код 1C v 8.х

 Процедура Печать(ТаблицаТоваров) Экспорт



    //am+ Так как у нас два разных макета, то нам нельзя смешивать типы ШК

    //    печатаемые в разных макетах. Выполним проверку.



    флВремЕстьInterleave = Ложь;

    флВремЕстьНеInterleave = Ложь;

    Для Каждого СтрокаИзСписка Из ТаблицаТоваров Цикл

        Если СтрокаИзСписка.ТипШтрихкода = ПланыВидовХарактеристик.ТипыШтрихкодов.Interleave20FS Тогда

            флВремЕстьInterleave = Истина;

        Иначе

            флВремЕстьНеInterleave = Истина;

        КонецЕсли;

        Если флВремЕстьInterleave и флВремЕстьНеInterleave Тогда

            Предупреждение("В списке одновременно встречаются штрих-коды несовместимых типов,

                           |Штрих-коды Interleave необходимо печатать отдельно от остальных!");

            Возврат;

        КонецЕсли;

    КонецЦикла;

    //am-



    Таб                     = Новый ТабличныйДокумент;

    Таб.ИмяПараметровПечати =   "ПАРАМЕТРЫ_ПЕЧАТИ_Этикетка"+СокрЛП(ИмяКомпьютера());

    //am+ Используем наш макет.

    Если флВремЕстьInterleave Тогда

        Макет                   = ПолучитьОбщийМакет("ЭтикеткаInterleave");

    Иначе

    //am-

        Макет                   = ПолучитьОбщийМакет("Этикетка");

    КонецЕсли;



    //am+ Некоторые строки в нашем макете не заработают, необходимо добавить условие.

    Если Не флВремЕстьInterleave Тогда

    //am-

        РисунокШтрихкод         = ЭтикеткаОбласть.Рисунки.Штрихкод;

    КонецЕсли;



    //am+

    Если Не флВремЕстьInterleave Тогда

    //am-

        РисунокШтрихкод.Расположить(ОбластьШтрихкод);

    КонецЕсли;





        Если УправлениеРозничнойТорговлей.ПроверитьШтрихКод(СтрокаИзСписка.ШтрихКод,

            СтрокаИзСписка.ТипШтрихкода) Тогда

            //am+ здесь мы установим размер шрифта (об этом в конце статьи) и зададим параметр ШтрихКод нашего макета для вывода

            Если флВремЕстьInterleave Тогда

                ЭтикеткаОбласть.Параметры.Установить(0,

              СформироватьШтрихКодДляМакетаЭтикеткаInterleave(СтрокаИзСписка.ШтрихКод));

                ЭтикеткаОбласть.Области.ОбластьШтрихкод.Шрифт =

              Новый Шрифт(ЭтикеткаОбласть.Области.ОбластьШтрихкод.Шрифт,,РезмерШрифтаInterleave);

            Иначе

            //am-

                Попытка //попытку нужно добавить т.к. если компонента не установлена, то будут ошибки.

                    ЭтикеткаОбласть.Рисунки.Штрихкод.Объект.ТипКода = ТипКода;

                    ЭтикеткаОбласть.Рисунки.Штрихкод.Объект.Сообщение = СтрокаИзСписка.ШтрихКод;

                Исключение

                КонецПопытки;

            КонецЕсли;

Последний штрих это добавить регулятор размера шрифта (в коде переменная РезмерШрифтаInterleave) на форму обработки:
title

источник

Категория: Штрих-код (barcode)