Функция ПолучитьПотокЧтенияСтрок(Файл)

  Попытка

    // Используется для доступа к параметрам файлов или каталогов. 

    ТекстовыйФайл = Новый Файл(Файл);

    Если ТекстовыйФайл.Существует() = Ложь Тогда

      Сообщить("Файла "+Файл+" не существует!");

      Возврат Неопределено;

    КонецЕсли;



    // Текстовый документ предназначен для работы с текстами. 

    // Объект позволяет получать и сохранять текст в файле, 

    // работать со строками

    ПотокЧтенияСтрок = Новый ТекстовыйДокумент();

    ПотокЧтенияСтрок.Прочитать(ТекстовыйФайл);

  Исключение

    Сообщить("Файл не прочитан.", СтатусСообщения.Внимание);

    Сообщить(ОписаниеОшибки());

    Возврат Неопределено;

  КонецПопытки;



  // Возвращает текст, извлеченный из файла

  Возврат ПотокЧтенияСтрок;



КонецФункции // ПолучитьПотокЧтенияСтрок





// Исходный код функции загрузки строк в табличное поле:



Процедура ЧтениеТХТФайла(Элемент)



  // Проверка на наличие имени файла

  Если ПустаяСтрока(ИмяФайла) Тогда

    Предупреждение("Для запуска обработки необходимо предварительно выбрать файл данных.");

    Возврат;

  КонецЕсли;



  // Открыть файл, создать текстовый документ, прочитать

  ПотокСтрок = ПолучитьПотокЧтенияСтрок(ИмяФайла);



  // Очистить предыдущие значения

  ТаблицаДокумента.Очистить();

  ТаблицаДокумента.Колонки.Очистить();



  // Создать колонки табличного документа

  ТаблицаДокумента.Колонки.Добавить("Номер",,"Номер",5);

  ТаблицаДокумента.Колонки.Добавить("Артикул",,"Артикул",11);

  ТаблицаДокумента.Колонки.Добавить("Номенклатура",,"Номенклатура",25);

  ТаблицаДокумента.Колонки.Добавить("Цена",,"Цена",6);



  // Последовательное чтение строк текстового файла

  КоличествоСтрок = ПотокСтрок.КоличествоСтрок();

  Для Строка = 1 По КоличествоСтрок Цикл



    // Обработка нажатия Ctrl + Break

    ОбработкаПрерыванияПользователя();



    // Чтение строки из файла тхт / csv

    СтрокаИзФайла = ПотокСтрок.ПолучитьСтроку(Строка);



    // Разбор строки в массив, используя в качествен символа-разделителя "|"

    МассивСтрок = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(СтрокаИзФайла,"|");



    // Добавить данные в табличную часть экранной формы

    Стр=ТаблицаДокумента.Добавить();

    Стр.Номер	 = Строка;

    Стр.Артикул = МассивСтрок[0];

    Стр.Номенклатура = МассивСтрок[1];

    Стр.Цена = МассивСтрок[2];

    // Отобразить информацию о ходе выполнения обработки

    Состояние("Обработка строки файла : "

      + "строка " + Строка + " из " + КоличествоСтрок);



  КонецЦикла;



  // Отобразить результаты загрузки в форме элемента

  ЭлементыФормы.ТаблицаДокумента.Значение = ТаблицаДокумента;

  ЭлементыФормы.ТаблицаДокумента.СоздатьКолонки();



КонецПроцедуры // ЧтениеTXTФайла(Элемент)   

 Процедура Нарисовать (Кнопка)

// Подготовить текст запроса для выборки данных из

// регистра сведений Курсы валют

SQL = Новый Запрос;

SQL.Текст = "ВЫБРАТЬ

|КурсыВалют.Валюта,

|КурсыВалют.Курс,

|ДЕНЬГОДА(КурсыВалют.Период) КАК Точки

|ИЗ

|РегистрСведений.КурсыВалют КАК КурсыВалют

|ГДЕ

|КурсыВалют.Период МЕЖДУ &НачПериода И &КонПериода

|И КурсыВалют.Валюта.Наименование <> &исключитьРуб

|УПОРЯДОЧИТЬ ПО

|КурсыВалют.Период";



// Установить период выборки данных

SQL.УстановитьПараметр("НачПериода",НачПериода);

SQL.УстановитьПараметр("КонПериода",КонПериода);

// Исключить курсы валюты рубли



SQL.УстановитьПараметр("исключитьРуб","Руб.");   

 // Получить доступ к диаграмме, как элементу экранной формы

курсы = ЭлементыФормы.ГрафикКурсов;



// Подготовить элемент к формированию графика

// Сброить данные серий и точек

// Очистить старые значения графика

курсы.Очистить();

курсы.КоличествоСерий = 0;

курсы.КоличествоТочек = 0;

// Отключить обновление диаграммы на время вывода данных.

курсы.Обновление = Ложь;

// Задать заголовок диаграммы

курсы.ОбластьЗаголовка.Текст = "Анализатор курсов валют";



// Сформировать соответствие номеров серий и наименований валют

// Ключ - название валюты,

// Значение - номер серии

серии = Новый Структура;

серии.Вставить("БВЛ",0);

серии.Вставить("USD",1);

серии.Вставить("EUR",2);

серии.Вставить("GBP",3);



// Добавить в диаграмму серии графиков

Для каждого график из серии Цикл

серия = курсы.Серии.Добавить(Строка(график.Ключ));

серия.Маркер = ТипМаркераДиаграммы.Нет;

КонецЦикла;    

 

// Выполнить запрос и начать выборку

Query = SQL.Выполнить().Выбрать();



сменаТочки = 0;

Пока Query.Следующий() Цикл

// Добавляем новую точку после заполнения всех серий

Если сменаТочки <> Query.Точки Тогда

курсы.Точки.Добавить(Query.Точки);

сменаТочки = Query.Точки;

КонецЕсли;



Попытка

// Установка значения графика в точке и серии

курсы.УстановитьЗначение(

Курсы.Точки.Количество()-1,

серии[Строка(Query.Валюта)], Query.Курс);

Исключение

КонецПопытки;

КонецЦикла;   

 // Заполнение расчетных значений для точек и серий

график = 0;

Пока график < Курсы.Точки.Количество() Цикл

// Создание графика бивалютной корзины

Корзина = (курсы.ПолучитьЗначение(график,серии["USD"]).Значение*0.55 +

курсы.ПолучитьЗначение(график,серии["EUR"]).Значение*0.45);

курсы.УстановитьЗначение(график,серии["БВЛ"], Корзина);

график = график + 1;

КонецЦикла;



// Обновить диаграмму в экранной форме.

курсы.Обновление = Истина;

КонецПроцедуры   

 Процедура PNG(Кнопка)

// Получить картинку диаграммы

График = ЭлементыФормы.ГрафикКурсов.ПолучитьКартинку( 500, 300, ФорматКартинки.PNG );

// Записать картинку из 1С в PNG

График.Записать( "C:\TEMP\Диаграмма.png" );

КонецПроцедуры   

 Процедура ОсновныеДействияФормыЭкспорт(Кнопка)

  Попытка

    Попытка



      // Загрузка объекта Microsoft Excel

      Состояние("Выгрузка данных из 1С в Microsoft Excel...");

      ExcelПриложение = Новый COMОбъект("Excel.Application");

    Исключение

      Сообщить("Ошибка при запуске Microsoft Excel."

        + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);

      Возврат;

    КонецПопытки;



    // Создадим книгу, по умолчанию в ней уже есть листы

    Книга = ExcelПриложение.WorkBooks.Add();



    // Используем первый лист книги Excel

    Лист = Книга.WorkSheets(1);



    // Сформировать шапку документа в первой строке листа

    Колонка = 1;

    Для каждого стр из ТП цикл

      Если стр.Выгружать Тогда

        Лист.Cells(1, Колонка).Value = стр.НазваниеРеквизита;

        Колонка = Колонка + 1;

      КонецЕсли;

    КонецЦикла;



    // Выгрузить данные справочника

    выборка = Справочники[ИмяСправочника].Выбрать();

    СтрокаЛиста = 2;

    Пока выборка.Следующий() Цикл

      Колонка = 1;

      Для каждого стр из ТП цикл



      Если стр.Выгружать Тогда

      Попытка

        // Установить значение в строке и колонке

        Если ТипЗнч(выборка[стр.НазваниеРеквизита])=Тип("Число") Тогда

        // Установить формат для типа Число

        Лист.Cells(СтрокаЛиста, Колонка).NumberFormat = "0,00";

        Лист.Cells(СтрокаЛиста, Колонка).Value =

          Формат(выборка[стр.НазваниеРеквизита],"ЧГ=0");

        иначе

          // Для всех других типов установим формат "Текстовый"

          Лист.Cells(СтрокаЛиста, Колонка).NumberFormat = "@";

          Лист.Cells(СтрокаЛиста, Колонка).Value =

            Строка(выборка[стр.НазваниеРеквизита]);

        КонецЕсли;

      исключение

        // в случае ошибки вывести номер строки и колонки

        Сообщить("Ошибка установки значения для: " +

          выборка[стр.НазваниеРеквизита]);

        Сообщить("Стр: " +СтрокаЛиста+ " Кол: " +

          Колонка+ " Рек: " + стр.НазваниеРеквизита);

      КонецПопытки;

      Колонка = Колонка + 1;

      КонецЕсли;



    КонецЦикла;

    СтрокаЛиста = СтрокаЛиста + 1;

    Состояние("Экспорт из 1С в Excel " + СтрокаЛиста);

    КонецЦикла;



    // Сохраним созданную книгу в файл xls

    Книга.SaveAs(имяФайла);



    // Обязательно закроем соединение с COM объектом для освобождения памяти

    ExcelПриложение.Quit();



    Сообщить("Файл выгружен успешно: " + имяФайла );



  Исключение

    // Обработка ошибок экспорта данных из 1С в Excel

    Сообщить("Ошибка записи данных файла :" + имяФайла);

    Сообщить(ОписаниеОшибки());

    Попытка

      ExcelПриложение.Quit();

    Исключение

    КонецПопытки;

  КонецПопытки;

КонецПроцедуры   

 Процедура ЧтениеXLSФайла(Элемент)



  Если ПустаяСтрока(ИмяФайла) Тогда

    Предупреждение("Для запуска обработки необходимо предварительно выбрать файл Microsoft Excel.");

    Возврат;

  КонецЕсли;



  Попытка

    // Загрузка Microsoft Excel

    Состояние("Загрузка Microsoft Excel...");

    ExcelПриложение = Новый COMОбъект("Excel.Application");

  Исключение

    Сообщить("Ошибка при загрузке Microsoft Excel." + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);

    Возврат;

  КонецПопытки;



  Попытка

    // Открытие файла Microsoft Excel

    Состояние("Открытие файла Microsoft Excel...");

    ExcelФайл = ExcelПриложение.WorkBooks.Open(ИмяФайла);

  Исключение

    Сообщить("Ошибка открытия файла Microsoft Excel." + ИмяФайла + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);

  КонецПопытки;



  Попытка

    // Обработка файла Microsoft Excel

    Состояние("Обработка файла Microsoft Excel...");

    // Читаем данные первого листа книги

    ExcelЛист = ExcelФайл.Sheets(1);



    // Определить количество строк и колонок выбранного листа книги Excel

    xlCellTypeLastCell = 11;

    ExcelПоследняяСтрока = ExcelЛист.Cells.SpecialCells(xlCellTypeLastCell).Row;

    ExcelПоследняяКолонка = ExcelЛист.Cells.SpecialCells(xlCellTypeLastCell).Column;

  Исключение

    Сообщить("Ошибка открытия листа №1 Microsoft Excel." + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);

    // Закрыть COM соединение для экономии памяти

    ExcelПриложение.Quit();

  КонецПопытки;



  // Создание описателя типов для таблицы значений

  КЧ = Новый КвалификаторыЧисла(15,2);

  КС = Новый КвалификаторыСтроки(50);

  Массив = Новый Массив;

  Массив.Добавить(Тип("Строка"));

  ОписаниеТиповС = Новый ОписаниеТипов(Массив, , КС);

  Массив.Очистить();

  Массив.Добавить(Тип("Число"));

  ОписаниеТиповЧ = Новый ОписаниеТипов(Массив, , ,КЧ);



  // Очистить предыдущие значения

  ТаблицаДокумента.Очистить();

  ТаблицаДокумента.Колонки.Очистить();



  // Создать колонки табличного документа

  ТаблицаДокумента.Колонки.Добавить("Номер",ОписаниеТиповС,"Номер",5);

  ТаблицаДокумента.Колонки.Добавить("Артикул",ОписаниеТиповС,"Артикул",11);

  ТаблицаДокумента.Колонки.Добавить("Описание",ОписаниеТиповС,"Описание",25);

  ТаблицаДокумента.Колонки.Добавить("Цена",ОписаниеТиповЧ,"Цена",6);



  // Последовательное чтение строк с выбранного листа

  Для Строка = 1 По ExcelПоследняяСтрока Цикл



    // Обработка нажатия Ctrl + Break

    ОбработкаПрерыванияПользователя();



    // Добавить данные в табличную часть экранной формы

    Стр=ТаблицаДокумента.Добавить();

    Стр.Номер = Строка;

    Попытка

      Стр.Артикул = ExcelЛист.Cells(Строка, 1).Value;

      Стр.Описание = ExcelЛист.Cells(Строка, 2).Value;

      Стр.Цена = ExcelЛист.Cells(Строка, 3).Value;

    Исключение

      // Не редко происходит ошибка конвертации отдельной ячейки документа

      Сообщить("Ошибка чтения строки файла Microsoft Excel." + Строка + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);

    КонецПопытки;

    // Отобразить информацию о ходе выполнения обработки

    Состояние("Обработка файла Microsoft Excel : "

      + "строка " + Строка + " из " + ExcelПоследняяСтрока);



  КонецЦикла;



  // Закрыть COM соединение для экономии памяти

  ExcelПриложение.Quit();



  // Отобразить результаты загрузки в форме элемента

  ЭлементыФормы.ТаблицаДокумента.Значение = ТаблицаДокумента;

  ЭлементыФормы.ТаблицаДокумента.СоздатьКолонки();



КонецПроцедуры // ЧтениеXLSФайла(Элемент)