журналы » Поиск

Результаты по ключевому слову: журналы

Полезные советы по интерфейсу "Такси"

Чтобы шрифт не казался крупным, и формы помещались на экране, можно уменьшить масштаб

Для этого нужно воспользоваться Меню «Вид – Изменить масштаб».

Чтобы быстро найти нужный пункт меню, можно воспользоваться поиском меню

Найти окно поиска меню на любой панели. В верхнем правом углу написать ключевое слово для поиска.

Так же используя поиск можно быстро искать необходимые документы или элементы справочника

Чтобы на форме помещалось больше информации, можно сократить панель разделов

Вызвать настройку панели разделов, для этого нужно воспользоваться Меню «Вид – Настройка панели разделов». Убрать надписи с панели разделов и оставить только картинку в окне «Показывать».

Чтобы на форме были видны нужные колонки и не видны ненужные, можно настроить форму

Открыть форму и воспользоваться кнопкой «Еще». В верхней правой части формы снять флажки с ненужных колонок, а нужные колонки передвинуть вперед.

Чтобы добавить журналы документов покупателей и поставщиков, можно настроить панели «Продажи» и «Покупки»

Нажать меню «Продажи». В правом верхнем углу нажать на серую шестеренку «Настройки». Выбрать меню «Настройка навигации». В списке слева щелкнуть два раза на «Документы покупателей».

Фильтры / отборы в журнале

Нажать на меню «Операции». Открыть «Журнал операций». В левом верхнем углу в поле «Контрагент» указать покупателя.

Все функции и стандартные операции

Откройте Меню-Сервис-Параметры, установите галку Отображать команду Все функции и нажмите ОК

Стандартные

Внизу раздел Стандартные:

Как вернуть стандартную настроку списка документов или справочника

Избранное - быстрый доступ к документам, справочникам

Для добавления в избранное нажмите на значек звездочки в открытом списке

или в меню раздела

Для быстрого доступа к избранному нажмите на звездочку в левом верхнем углу

Категория: 1С Общие вопросы - Управляемые формы и Такс…

Обход метаданных (полезные функции)

При написании небольших автоматизированных тестов часто надо обойти всю конфигурацию и проверить, например, для всех форм какое-нибудь свойство. Это всё легко делается через свойство глобального контекста "Метаданные", но чтоб дорбаться до обхода реквизитов надо написать кучу вложенных циклов. При этом код становится слабочитаемым и слабомодифицируемым.

Ниже приведен небольшой модуль, который решает задачу легко и удобно. Создана специальная функция РазвернутьСтрокуОбходаМетаданных, которая может по строке типа "Метаданные.Справочники.*.Реквизиты.*" построить массив строк с перечислением всех реквизитов всех справочников. При помощи этой и нескольких других функций в экспортных функциях модуля реализованы вполне прикладные задачи - получение всех реквизитов, всех макетов, всех форм конфигурации и построение таблицы всех составных типов.

Код 1C v 8.х

  // Автор: Alexander Speshilov

// Рекрсивная функция, которая разворачивает строку вида "Метаданные.Справочники.*[Имя].Реквизиты.*.Тип" 

// в массив строк, заменяя "*" или другой символ, задаваемый параметрами обходом всех элементов 

// коллекции. Допускает выполнение функций встроенного языка (не стоит отдавать ввод параметров 

// пользователям). При этом выражение, используемое для получения по умолчанию может быть задано в 

// квадратных скобках или параметром функции.

//

// Параметры

//  СтрокаОбхода  - Строка - Разворачиваемая строка

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Массив строк

//

Функция РазвернутьСтрокуОбходаМетаданных(СтрокаОбхода, ЗаменяемоеЗначение = "*", ПредставлениеПоУмолчанию = "")

    

    Рез = Новый Массив;

    

    ЧастиСтрокиОбхода = РазобратьСтрокуОбхода(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

    Если ЧастиСтрокиОбхода = Неопределено тогда 

        Рез.Добавить(СтрокаОбхода); //фактически это ограничение рекурсии.

    Иначе

        ОбъектКоллекции = Вычислить(ЧастиСтрокиОбхода.СтрокаКоллекции);

        РазвернутаяКоллекция = РазвернутьКоллекциюВПредставления(ОбъектКоллекции, ЧастиСтрокиОбхода.СтрокаПредставление);

        Для каждого ЭлементРазвернутойКоллекции Из РазвернутаяКоллекция Цикл

            

            // рекурсивный вызов

            ТекущаяСтрокаОбхода = ЧастиСтрокиОбхода.СтрокаНачало + ЭлементРазвернутойКоллекции + ЧастиСтрокиОбхода.СтрокаКонец;

            МассивЭлемента = РазвернутьСтрокуОбходаМетаданных(ТекущаяСтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

            

            Для каждого ПримитивныйЭлементОбхода Из МассивЭлемента Цикл

                Рез.Добавить(ПримитивныйЭлементОбхода);

            КонецЦикла;

            

        КонецЦикла;

    КонецЕсли;

    

    Возврат Рез;

    

КонецФункции // РазвернутьСтрокуОбходаМетаданных()



// Разбирает строку обхода на удобные для работы поля

//

// Параметры

//  СтрокаОбхода  - Строка - Разворачиваемая строка

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Структура с полями ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец

// или Неопределено (если строка не содержит ЗаменяемоеЗначение)

//

Функция РазобратьСтрокуОбхода(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию)

    

    Если ПустаяСтрока(ЗаменяемоеЗначение) Тогда 

        ВызватьИсключение "Некорректное выражение заменяемого значения";

    КонецЕсли;

    

    ПозицияЗамены = Найти(СтрокаОбхода, ЗаменяемоеЗначение);

    

    // Если не найдена строка - возвращаем неопределено, как индикатор

    Если ПозицияЗамены = 0 Тогда 

        Возврат Неопределено; 

    КонецЕсли;

    

    СтрокаНачало = Лев(СтрокаОбхода,ПозицияЗамены - 1);

    

    //Получение строки для выражения-коллекции

    СтрокаКоллекции = СтрокаНачало;

    Если Прав(СтрокаКоллекции, 1) = "." Тогда 

        СтрокаКоллекции = Лев(СтрокаКоллекции,СтрДлина(СтрокаКоллекции) - 1);

    КонецЕсли;

    

    ПозицияОкончанияЗамены = ПозицияЗамены + СтрДлина(ЗаменяемоеЗначение);

    

    ОстатокВыражения = Сред(СтрокаОбхода, ПозицияОкончанияЗамены);

    

    //Обработка явного задания представления

    ОткрывающаяСкобка = "[";

    ЗакрывающаяСкобка = "]";

    Если Найти(ОстатокВыражения, ОткрывающаяСкобка) = 1 Тогда

        ОстатокВыражения = Сред(ОстатокВыражения, СтрДлина(ОткрывающаяСкобка) + 1);

        ПозицияЗакрывающейСкобки = Найти(ОстатокВыражения, ЗакрывающаяСкобка);

        Если ПозицияЗакрывающейСкобки = 0 Тогда 

            ВызватьИсключение "Синтаксическая ошибка разбора выражения";

        КонецЕсли;

        СтрокаПредставление = Лев(ОстатокВыражения, ПозицияЗакрывающейСкобки - 1);

        ОстатокВыражения = Сред(ОстатокВыражения, ПозицияЗакрывающейСкобки + СтрДлина(ЗакрывающаяСкобка));

    Иначе

        СтрокаПредставление = ПредставлениеПоУмолчанию;

    КонецЕсли;

    СтрокаКонец = ОстатокВыражения;

    

    Рез = Новый Структура("ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец",

    ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец);

    

    Возврат Рез;

    

КонецФункции // РазобратьСтрокуОбхода()



// Разворачивает объект коллекции в массив представления элементов

//

// Параметры

//  Коллекция  - Произвольный - Коллекция, которую можно обойти через "Для каждого"

//  ПредставлениеЭлемента  - Строка - необяз., свойство элементов коллекции, которое 

//               используется для получения представления.

//

// Возвращаемое значение:

//   Массив   - Массив представлений коллекции

//

Функция РазвернутьКоллекциюВПредставления(Коллекция, Знач ПредставлениеЭлемента = "")

    

    //Проверка и подгонка параметров

    Если не ПустаяСтрока(ПредставлениеЭлемента) Тогда 

        Если Найти(ПредставлениеЭлемента, ";")>0 Тогда 

            ВызватьИсключение "Некорректное выражение представления";

        КонецЕсли;

        ПредставлениеЭлемента = "." + ПредставлениеЭлемента;

    КонецЕсли;

    

    Рез = Новый Массив;

    Для каждого ЭлементКоллекции Из Коллекция Цикл

        ТекПредставление = Строка(Вычислить("ЭлементКоллекции" + ПредставлениеЭлемента));

        Рез.Добавить(ТекПредставление);

    КонецЦикла; 

    Возврат Рез;

    

КонецФункции // РазвернутьКоллекцию()



// Разворачивает массив строк через РазвернутьСтрокуОбходаМетаданных

//

// Параметры

//  МассивСтрокОбхода  - Массив - Массив разворачиваемых строк

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Массив строк

//

Функция РазвернутьМассивСтрокОбходаМетаданных(МассивСтрокОбхода, ЗаменяемоеЗначение = "*", ПредставлениеПоУмолчанию = "Имя")

    

    Рез = Новый Массив;

    

    Для каждого СтрокаОбхода Из МассивСтрокОбхода Цикл

        

        ДополнениеРезультата = РазвернутьСтрокуОбходаМетаданных(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

        Для каждого ТекСтрока Из ДополнениеРезультата Цикл

            Рез.Добавить(ТекСтрока);

        КонецЦикла; 

        

    КонецЦикла; 

    

    Возврат Рез;

    

КонецФункции // РазвернутьМассивСтрокОбходаМетаданных()



// Преобразует строку в массив одиночных строк по разделителю Символы.ПС

//

// Параметры

//  ПреобразуемаяСтрока - строка для преобразования

//    ИгнорироватьПустые - Булево - Пропускать пустые строки

//  СокращатьПробелы - Использовать СокрЛП

//

// Возвращаемое значение:

//   Массив строк

//

Функция ПолучитьМассивСтрокМногострочнойСтроки(ПреобразуемаяСтрока, ИгнорироватьПустые = Истина, СокращатьПробелы = Истина)

    

    Рез = Новый Массив;

    ЧислоСтрок = СтрЧислоСтрок(ПреобразуемаяСтрока);

    

    Для Сч = 1 По ЧислоСтрок Цикл

        

        ТекСтрока = СтрПолучитьСтроку(ПреобразуемаяСтрока, Сч);

        Если ИгнорироватьПустые и ПустаяСтрока(ТекСтрока) Тогда

            Продолжить;

        КонецЕсли; 

        Если СокращатьПробелы Тогда

            ТекСтрока = СокрЛП(ТекСтрока);

        КонецЕсли; 

        Рез.Добавить(ТекСтрока);

        

    КонецЦикла;

    

    Возврат Рез;

    

КонецФункции // ПолучитьМассивСтрокМногострочнойСтроки()



// Возвращает все реквизиты конфигурации, которые сохраняются в ИБ

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеХранимыеРеквизитыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.Константы.*

    |Метаданные.ПланыОбмена.*.Реквизиты.*

    |Метаданные.ПланыОбмена.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Справочники.*.Реквизиты.*

    |Метаданные.Справочники.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Документы.*.Реквизиты.*

    |Метаданные.Документы.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Последовательности.*.Измерения.*

    |Метаданные.ПланыВидовХарактеристик.*.Реквизиты.*

    |Метаданные.ПланыВидовХарактеристик.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.ПланыСчетов.*.Реквизиты.*

    |Метаданные.ПланыСчетов.*.ПризнакиУчета.*

    |Метаданные.ПланыСчетов.*.ПризнакиУчетаСубконто.*

    |Метаданные.ПланыСчетов.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.ПланыВидовРасчета.*.Реквизиты.*

    |Метаданные.ПланыВидовРасчета.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.РегистрыСведений.*.Измерения.*

    |Метаданные.РегистрыСведений.*.Ресурсы.*

    |Метаданные.РегистрыСведений.*.Реквизиты.*

    |Метаданные.РегистрыНакопления.*.Измерения.*

    |Метаданные.РегистрыНакопления.*.Ресурсы.*

    |Метаданные.РегистрыНакопления.*.Реквизиты.*

    |Метаданные.РегистрыБухгалтерии.*.Измерения.*

    |Метаданные.РегистрыБухгалтерии.*.Ресурсы.*

    |Метаданные.РегистрыБухгалтерии.*.Реквизиты.*

    |Метаданные.РегистрыРасчета.*.Измерения.*

    |Метаданные.РегистрыРасчета.*.Ресурсы.*

    |Метаданные.РегистрыРасчета.*.Реквизиты.*

    |Метаданные.БизнесПроцессы.*.Реквизиты.*

    |Метаданные.БизнесПроцессы.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Задачи.*.Реквизиты.*

    |Метаданные.Задачи.*.РеквизитыАдресации.*

    |Метаданные.Задачи.*.ТабличныеЧасти.*.Реквизиты.*

    |";

    ВсеХранимыеРеквизитыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеХранимыеРеквизитыКонфигурации;

    

КонецФункции // ПолучитьВсеХранимыеРеквизитыКонфигурации()



// Возвращает все реквизиты конфигурации составного типа, которые сохраняются в ИБ

//

// Параметры - Нет

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция ПолучитьВсеХранимыеРеквизитыКонфигурацииСоставногоТипа() Экспорт

    

    ВсеХранимыеРеквизитыКонфигурации = ПолучитьВсеХранимыеРеквизитыКонфигурации();

    Рез = Новый ТаблицаЗначений;

    Рез.Колонки.Добавить("Имя", Новый ОписаниеТипов("Строка"));

    Рез.Колонки.Добавить("Тип", Новый ОписаниеТипов("ОписаниеТипов"));

    Рез.Колонки.Добавить("КоличествоПростыхТипов", Новый ОписаниеТипов("Число"));

    

    Для каждого ТекРеквизит Из ВсеХранимыеРеквизитыКонфигурации Цикл

        

        Реквизит = Вычислить(ТекРеквизит);

        Тип = Реквизит.Тип;

        КоличествоПростыхТипов = Тип.Типы().Количество();

        Если КоличествоПростыхТипов<>1 Тогда 

    	    ТекСтрока = Рез.Добавить();

            ТекСтрока.Имя = ТекРеквизит;

            ТекСтрока.Тип = Тип;

            ТекСтрока.КоличествоПростыхТипов = КоличествоПростыхТипов;

        КонецЕсли;

    

    КонецЦикла; 

    

    Возврат Рез;

    

КонецФункции // ПолучитьВсеХранимыеРеквизитыКонфигурации()



// Возвращает все формы конфигурации

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеФормыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.ПланыОбмена.*.Формы.*

    |Метаданные.КритерииОтбора.*.Формы.*

    |Метаданные.ОбщиеФормы.*

    |Метаданные.Справочники.*.Формы.*

    |Метаданные.Документы.*.Формы.*

    |Метаданные.ЖурналыДокументов.*.Формы.*

    |Метаданные.Перечисления.*.Формы.*

    |Метаданные.Отчеты.*.Формы.*

    |Метаданные.Обработки.*.Формы.*

    |Метаданные.ПланыВидовХарактеристик.*.Формы.*

    |Метаданные.ПланыСчетов.*.Формы.*

    |Метаданные.ПланыВидовРасчета.*.Формы.*

    |Метаданные.РегистрыСведений.*.Формы.*

    |Метаданные.РегистрыНакопления.*.Формы.*

    |Метаданные.РегистрыБухгалтерии.*.Формы.*

    |Метаданные.РегистрыРасчета.*.Формы.*

    |Метаданные.БизнесПроцессы.*.Формы.*

    |Метаданные.Задачи.*.Формы.*

    |";

    ВсеФормыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеФормыКонфигурации;

    

КонецФункции // ПолучитьВсеФормыКонфигурации()



// Возвращает все макеты конфигурации

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеМакетыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.ПланыОбмена.*.Макеты.*

    |Метаданные.ОбщиеМакеты.*

    |Метаданные.Справочники.*.Макеты.*

    |Метаданные.Документы.*.Макеты.*

    |Метаданные.ЖурналыДокументов.*.Макеты.*

    |Метаданные.Перечисления.*.Макеты.*

    |Метаданные.Отчеты.*.Макеты.*

    |Метаданные.Обработки.*.Макеты.*

    |Метаданные.ПланыВидовХарактеристик.*.Макеты.*

    |Метаданные.ПланыСчетов.*.Макеты.*

    |Метаданные.ПланыВидовРасчета.*.Макеты.*

    |Метаданные.РегистрыСведений.*.Макеты.*

    |Метаданные.РегистрыНакопления.*.Макеты.*

    |Метаданные.РегистрыБухгалтерии.*.Макеты.*

    |Метаданные.РегистрыРасчета.*.Макеты.*

    |Метаданные.БизнесПроцессы.*.Макеты.*

    |Метаданные.Задачи.*.Макеты.*

    |";

    ВсеМакетыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеМакетыКонфигурации;

    

КонецФункции // ПолучитьВсеМакетыКонфигурации()

Категория: Метаданные

Структура и название таблиц использыемых для хранения данных в БД 1С 8.х Категория: Полезные, Универсальные Функции

Удаление записей в журнале расчетов Категория: Журналы расчетов

Выгрузка метаданных конфигурации в Microsoft Word и Excel

Код 1C v 8.х

 

Перем ОбъектыКонфы;

Перем СтруктКонфы;



Процедура ВыгрузитьВWord()

	Попытка

		Word = Новый COMОбъект("Word.Application");

	Исключение 

		Сообщить("Не удалось открыть Word");

		Возврат;

	КонецПопытки;

	

	Word.Documents.Add();

	Документ = Word.ActiveDocument();



    // Перебор типов метаданных

	Для Каждого ТипОбъекта Из ОбъектыКонфы Цикл

		Состояние(ТипОбъекта.Значение);

		

		Если Метаданные[ТипОбъекта.Ключ].Количество() > 0 Тогда

			// Добавляем новый параграф

			Документ.Paragraphs.Add();

			Номер = Документ.Paragraphs.Count();

			Документ.Paragraphs(Номер-1).Range().I_nsertAfter(ТипОбъекта.Значение);

			Документ.Paragraphs(Номер).Range().Style="Заголовок 1";



			//Перебираем конктретные объекты

			Для каждого Объект Из Метаданные[ТипОбъекта.Ключ] Цикл

				// Добавляем новый параграф

				Документ.Paragraphs.Add();

				Номер = Документ.Paragraphs.Count();

				Документ.Paragraphs(Номер-1).Range().I_nsertAfter(Объект.Синоним);

				Документ.Paragraphs(Номер).Range().Style="Заголовок 2";

				

				// Перебираем параметры метаданных

				Для каждого Параметр Из СтруктКонфы Цикл

					Попытка

						Количество = Объект[Параметр.Ключ].Количество();

					Исключение

						Продолжить;

					КонецПопытки;

						

					Если Количество > 0 Тогда

						// Добавляем новый параграф

						Документ.Paragraphs.Add();

						Номер = Документ.Paragraphs.Count();

						Документ.Paragraphs(Номер-1).Range().I_nsertAfter(Параметр.Значение + " (" + Количество + ")");

						Документ.Paragraphs(Номер).Range().Style="Заголовок 3";

						

						// Добавляем новый параграф

						Документ.Paragraphs.Add();

						Номер=Документ.Paragraphs.Count();

						// Добавляем новую таблицу

						Документ.Tables.Add(Документ.Paragraphs(Номер).Range(),Количество+1,4);

						

						Счетчик = 1;

						// Заполняем шапку таблицы

						Таблица = Документ.Tables(Документ.Tables.Count());

						Таблица.Cell(Счетчик,1).Range().I_nsertAfter("Имя");

						Таблица.Cell(Счетчик,2).Range().I_nsertAfter("Синоним");

						Таблица.Cell(Счетчик,3).Range().I_nsertAfter("Тип");

						Таблица.Cell(Счетчик,4).Range().I_nsertAfter("Комментарий");

						// Устанавливаем жирный шрифт для шапки таблицы

						Документ.Range(Таблица.Cell(Счетчик,1).Range.Start,Таблица.Cell(Счетчик,4).Range.End).Font.Bold = Истина;

						

						Для каждого Значение Из Объект[Параметр.Ключ] Цикл

							Счетчик = Счетчик + 1;

							// Заполняем содержимое таблицы

							Попытка

								Таблица.Cell(Счетчик,1).Range().I_nsertAfter(Значение.Имя);

							Исключение

							КонецПопытки;

							Попытка

								Таблица.Cell(Счетчик,2).Range().I_nsertAfter(Значение.Синоним);

							Исключение

							КонецПопытки;

							Попытка

								СтрокаТипов = "";

								// Выводим все типы

								Для каждого Тип Из Значение.Тип.Типы() Цикл

									СтрокаТипов = СтрокаТипов + " " + Строка(Тип);

								КонецЦикла; 

								Таблица.Cell(Счетчик,3).Range().I_nsertAfter(СтрокаТипов);

							Исключение

							КонецПопытки;

							Попытка

								Таблица.Cell(Счетчик,4).Range().I_nsertAfter(Значение.Комментарий);

							Исключение

							КонецПопытки;

						КонецЦикла; 

					КонецЕсли; 

				КонецЦикла; 

			КонецЦикла;

		КонецЕсли;

	КонецЦикла;

	

	// Показываем документ

	Word.Visible = Истина;

	// Устанавливаем активность документа

	Word.Activate();

	Word = Неопределено;

КонецПроцедуры



Процедура ВыгрузитьВExcel()

	Попытка

		Excel = Новый COMОбъект("Excel.Application");

	Исключение 

		Сообщить("Не удалось открыть Excel");

		Возврат;

	КонецПопытки;



	// Добавляем новый лист

	Excel.Application.Workbooks.Add(1);

	Лист = Excel.ActiveSheet;

	// Задаем имя закладки

	Лист.Name = "Данные";

	

	НомерСтроки = 0;

	

	// Перебор типов метаданных

	Для Каждого ТипОбъекта Из ОбъектыКонфы Цикл

		Состояние(ТипОбъекта.Значение);

		

		Если Метаданные[ТипОбъекта.Ключ].Количество() > 0 Тогда

			// Добавляем новую строку

			НомерСтроки = НомерСтроки + 1;

			// Устанавливаем текст в ячейку

			Лист.Cells(НомерСтроки, 1).Value = ТипОбъекта.Значение;

			// Устанавливаем размер шрифта

			Лист.Cells(НомерСтроки, 1).Font.Size = 16;

			// Устанавливаем цвет

			Лист.Cells(НомерСтроки, 1).Font.ColorIndex = 3;



			//Перебираем конктретные объекты

			Для каждого Объект Из Метаданные[ТипОбъекта.Ключ] Цикл

				// Добавляем новую строку

				НомерСтроки = НомерСтроки + 1;

				// Устанавливаем текст в ячейку

				Лист.Cells(НомерСтроки, 1).Value = Объект.Синоним;

				// Устанавливаем отступ в 2 символа

				Лист.Cells(НомерСтроки, 1).I_nsertIndent(2);

				// Устанавливаем размер шрифта

				Лист.Cells(НомерСтроки, 1).Font.Size = 12;

				// Устанавливаем цвет

				Лист.Cells(НомерСтроки, 1).Font.ColorIndex = 5;

				

				// Перебираем параметры метаданных

				Для каждого Параметр Из СтруктКонфы Цикл

					Попытка

						Количество = Объект[Параметр.Ключ].Количество();

					Исключение

						Продолжить;

					КонецПопытки;

						

					Если Количество > 0 Тогда

						// Добавляем новую строку

						НомерСтроки = НомерСтроки + 1;

						Лист.Cells(НомерСтроки, 1).Value = Параметр.Значение + " (" + Количество + ")";

						Лист.Cells(НомерСтроки, 1).I_nsertIndent(4);

						// Устанавливаем жирный шрифт

						Лист.Cells(НомерСтроки, 1).Font.Bold = Истина;

						// Устанавливаем цвет

						Лист.Cells(НомерСтроки, 1).Font.ColorIndex = 16;

						

						// Добавляем новую таблицу

						НомерСтроки = НомерСтроки + 1;

						Лист.Cells(НомерСтроки, 1).Value = "Имя";

						Лист.Cells(НомерСтроки, 2).Value = "Синоним";

						Лист.Cells(НомерСтроки, 3).Value = "Тип";

						Лист.Cells(НомерСтроки, 4).Value = "Комментарий";

						

						Для Ном = 1 По 4 Цикл

							// Устанавливаем ширину колонки

							Лист.Cells(НомерСтроки, Ном).ColumnWidth = 20;

							Лист.Cells(НомерСтроки, Ном).Font.Bold = Истина;

							// Очищаем все границы

							Лист.Cells(НомерСтроки, Ном).Borders(5).LineStyle = -4142;

							// Устанавливаем левую границу

							Лист.Cells(НомерСтроки, Ном).Borders(7).LineStyle = 1;

							// Устанавливаем верхнюю границу

							Лист.Cells(НомерСтроки, Ном).Borders(8).LineStyle = 1;

							// Устанавливаем нижнюю границу

							Лист.Cells(НомерСтроки, Ном).Borders(9).LineStyle = 1;

							// Устанавливаем правую границу

							Лист.Cells(НомерСтроки, Ном).Borders(10).LineStyle = 1;

							// Устанавливаем цвет фона

							Лист.Cells(НомерСтроки, Ном).Interior.ColorIndex = 34;

						КонецЦикла; 



						Для каждого Значение Из Объект[Параметр.Ключ] Цикл

							НомерСтроки = НомерСтроки + 1;

							// Заполняем содержимое таблицы

							Попытка

								Лист.Cells(НомерСтроки, 1).Value = Значение.Имя;

							Исключение

							КонецПопытки;

							Попытка

								Лист.Cells(НомерСтроки, 2).Value = Значение.Синоним;

							Исключение

							КонецПопытки;

							Попытка

								СтрокаТипов = "";

								// Выводим все типы

								Для каждого Тип Из Значение.Тип.Типы() Цикл

									СтрокаТипов = СтрокаТипов + " " + Строка(Тип);

								КонецЦикла; 

								Лист.Cells(НомерСтроки, 3).Value = СтрокаТипов;

							Исключение

							КонецПопытки;

							Попытка

								Лист.Cells(НомерСтроки, 4).Value = Значение.Комментарий;

							Исключение

							КонецПопытки;

							

							Для Ном = 1 По 4 Цикл

								// Установка границ

								Лист.Cells(НомерСтроки, Ном).Borders(5).LineStyle = -4142;

								Лист.Cells(НомерСтроки, Ном).Borders(7).LineStyle = 1;

								Лист.Cells(НомерСтроки, Ном).Borders(8).LineStyle = 1;

								Лист.Cells(НомерСтроки, Ном).Borders(9).LineStyle = 1;

								Лист.Cells(НомерСтроки, Ном).Borders(10).LineStyle = 1;

								

								// Устанавливаем выравнивание по левому краю

								Лист.Cells(НомерСтроки, Ном).VerticalAlignment = -4160;

								// Устанавливаем перенос слов

								Лист.Cells(НомерСтроки, Ном).WrapText = Истина;

							КонецЦикла; 

						КонецЦикла; 

					КонецЕсли; 

				КонецЦикла; 

			КонецЦикла;

		КонецЕсли;

	КонецЦикла;

	

	// Показываем документ

	Excel.Visible = Истина;

	Excel = Неопределено;

КонецПроцедуры



Процедура Сформировать()	

	// Определяем все возможные объекты метаданных

	ОбъектыКонфы = Новый Структура();

	ОбъектыКонфы.Вставить("ОбщиеМодули",				"Общие модули");

	ОбъектыКонфы.Вставить("ОбщиеФормы",				"Общие формы");

	ОбъектыКонфы.Вставить("ОбщиеМакеты",				"Общие макеты");

	ОбъектыКонфы.Вставить("ОбщиеКартинки",			"Общие картинки");

	ОбъектыКонфы.Вставить("Роли",					"Роли");

	ОбъектыКонфы.Вставить("Интерфейсы",				"Интерфейсы");

	ОбъектыКонфы.Вставить("Стили",					"Стили");

	ОбъектыКонфы.Вставить("Языки",					"Языки");

	ОбъектыКонфы.Вставить("ПланыОбмена",				"Планы обмена");

	ОбъектыКонфы.Вставить("Константы",				"Константы");

	ОбъектыКонфы.Вставить("КритерииОтбора",			"Критерии отбора");

	ОбъектыКонфы.Вставить("Справочники",				"Справочники");

	ОбъектыКонфы.Вставить("Документы",				"Документы");

	ОбъектыКонфы.Вставить("ЖурналыДокументов",		"Журналы документов");

	ОбъектыКонфы.Вставить("Перечисления",			"Перечисления");

	ОбъектыКонфы.Вставить("Отчеты",					"Отчеты");

	ОбъектыКонфы.Вставить("Обработки",				"Обработки");

	ОбъектыКонфы.Вставить("ПланыВидовХарактеристик",	"Планы видов характеристик");

	ОбъектыКонфы.Вставить("ПланыСчетов",				"Планы счетов");

	ОбъектыКонфы.Вставить("ПланыВидовРасчета",		"Планы видов расчета");

	ОбъектыКонфы.Вставить("РегистрыСведений",		"Регистры сведений");

	ОбъектыКонфы.Вставить("РегистрыБухгалтерии",		"Регистры бухгалтерии");

	ОбъектыКонфы.Вставить("РегистрыРасчета",			"Регистры расчета");

	

	// Определяем все возможные параметры

	СтруктКонфы = Новый Структура();

	СтруктКонфы.Вставить("Измерения",			"Измерения");

	СтруктКонфы.Вставить("Ресурсы",			"Ресурсы");

	СтруктКонфы.Вставить("Реквизиты",			"Реквизиты");

	СтруктКонфы.Вставить("Формы",				"Формы");

	СтруктКонфы.Вставить("Макеты",				"Макеты");

	СтруктКонфы.Вставить("Графы",				"Графы");

	СтруктКонфы.Вставить("ТабличныеЧасти",		"Табличные части");

	СтруктКонфы.Вставить("Значения",			"Значения");

	

	ВыгрузитьВWord();  // из 1С в Microsoft Word

	ВыгрузитьВExcel(); // из 1C в Microsoft Excel

КонецПроцедуры

Код 1C v 7.x

 

Процедура Справочник()

	Ворд=СоздатьОбъект("Word.Application");

	Ворд.DisplayAlerts=0;

	

	Ворд.ActiveDocument.ActiveWindow.S_election.I_nsertRowsBelow(1);

	Ворд.ActiveDocument.ActiveWindow.S_election.MoveLeft(1,1);

	Ворд.ActiveDocument.ActiveWindow.S_election.TypeText("Код");

	Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

	Тип=?(Метаданные.Справочник(СокрЛП(Имя)).ТипКода="Текстовый","Строка","Число");

	Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(Тип+" ("+СокрЛП(Метаданные.Справочник(СокрЛП(Имя)).ДлинаКода)+")");

	Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

	Ворд.ActiveDocument.ActiveWindow.S_election.TypeText("");

	

	Ворд.ActiveDocument.ActiveWindow.S_election.I_nsertRowsBelow(1);

	Ворд.ActiveDocument.ActiveWindow.S_election.MoveLeft(1,1);

	Ворд.ActiveDocument.ActiveWindow.S_election.TypeText("Наименование");

	Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

	Ворд.ActiveDocument.ActiveWindow.S_election.TypeText("Строка ("+СокрЛП(Метаданные.Справочник(СокрЛП(Имя)).ДлинаНаименования)+")");

	Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

	Ворд.ActiveDocument.ActiveWindow.S_election.TypeText("");

	

	Для Сч=1 По Метаданные.Справочник(СокрЛП(Имя)).Реквизит() Цикл

		Ворд.ActiveDocument.ActiveWindow.S_election.I_nsertRowsBelow(1);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveLeft(1,1);

		Реквизит=Метаданные.Справочник(СокрЛП(Имя)).Реквизит(Сч);

		Синоним=Реквизит.Синоним;

		Если ПустоеЗначение(Синоним)=0 Тогда

			Если нрег(СтрЗаменить(Синоним," ",""))<>нрег(Реквизит.Идентификатор) Тогда

				Синоним=" ("+Синоним+")";

			Иначе

				Синоним="";

			КонецЕсли;

		КонецЕсли;

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(СокрЛП(Реквизит.Идентификатор)+Синоним);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Тип=Реквизит.Тип;

		Если Тип="Строка" Тогда

			Тип=Тип+" ("+СокрЛП(Реквизит.Длина)+")";

		ИначеЕсли Тип="Число" Тогда

			Тип=Тип+" ("+СокрЛП(Реквизит.Длина);

			Если ПустоеЗначение(Реквизит.Точность)=0 Тогда

				Тип=Тип+"."+СокрЛП(Реквизит.Точность);

			КонецЕсли;

			Тип=Тип+")";

		Иначе

			Тип=Тип+"."+Реквизит.Вид;

		КонецЕсли;

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(Тип);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(Реквизит.Комментарий);

	КонецЦикла;

	Предупреждение("Готово",5);

КонецПроцедуры



Процедура Документ()

	Ворд=СоздатьОбъект("Word.Application");

	Ворд.DisplayAlerts=0;

	

	Для Сч=1 По Метаданные.Документ(СокрЛП(Имя)).РеквизитШапки() Цикл

		Ворд.ActiveDocument.ActiveWindow.S_election.I_nsertRowsBelow(1);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveLeft(1,1);

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText("Шапка");

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Реквизит=Метаданные.Документ(СокрЛП(Имя)).РеквизитШапки(Сч);

		Синоним=Реквизит.Синоним;

		Если ПустоеЗначение(Синоним)=0 Тогда

			Если нрег(СтрЗаменить(Синоним," ",""))<>нрег(Реквизит.Идентификатор) Тогда

				Синоним=" ("+Синоним+")";

			Иначе

				Синоним="";

			КонецЕсли;

		КонецЕсли;

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(СокрЛП(Реквизит.Идентификатор)+Синоним);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Тип=Реквизит.Тип;

		Если Тип="Строка" Тогда

			Тип=Тип+" ("+СокрЛП(Реквизит.Длина)+")";

		ИначеЕсли Тип="Число" Тогда

			Тип=Тип+" ("+СокрЛП(Реквизит.Длина);

			Если ПустоеЗначение(Реквизит.Точность)=0 Тогда

				Тип=Тип+"."+СокрЛП(Реквизит.Точность);

			КонецЕсли;

			Тип=Тип+")";

		Иначе

			Тип=Тип+"."+Реквизит.Вид;

		КонецЕсли;

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(Тип);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(Реквизит.Комментарий);

	КонецЦикла;

	Для Сч=1 По Метаданные.Документ(СокрЛП(Имя)).РеквизитТабличнойЧасти() Цикл

		Ворд.ActiveDocument.ActiveWindow.S_election.I_nsertRowsBelow(1);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveLeft(1,1);

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText("Таб. часть");

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Реквизит=Метаданные.Документ(СокрЛП(Имя)).РеквизитТабличнойЧасти(Сч);

		Синоним=Реквизит.Синоним;

		Если ПустоеЗначение(Синоним)=0 Тогда

			Если нрег(СтрЗаменить(Синоним," ",""))<>нрег(Реквизит.Идентификатор) Тогда

				Синоним=" ("+Синоним+")";

			Иначе

				Синоним="";

			КонецЕсли;

		КонецЕсли;

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(СокрЛП(Реквизит.Идентификатор)+Синоним);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Тип=Реквизит.Тип;

		Если Тип="Строка" Тогда

			Тип=Тип+" ("+СокрЛП(Реквизит.Длина)+")";

		ИначеЕсли Тип="Число" Тогда

			Тип=Тип+" ("+СокрЛП(Реквизит.Длина);

			Если ПустоеЗначение(Реквизит.Точность)=0 Тогда

				Тип=Тип+"."+СокрЛП(Реквизит.Точность);

			КонецЕсли;

			Тип=Тип+")";

		Иначе

			Тип=Тип+"."+Реквизит.Вид;

		КонецЕсли;

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(Тип);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(Реквизит.Комментарий);

	КонецЦикла;

	Предупреждение("Готово",5);

КонецПроцедуры



Процедура Общие()

	Ворд=СоздатьОбъект("Word.Application");

	Ворд.DisplayAlerts=0;

	

	Для Сч=1 По Метаданные.ОбщийРеквизитДокумента() Цикл

		Ворд.ActiveDocument.ActiveWindow.S_election.I_nsertRowsBelow(1);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveLeft(1,1);

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText("Шапка");

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Реквизит=Метаданные.ОбщийРеквизитДокумента(Сч);

		Синоним=Реквизит.Синоним;

		Если ПустоеЗначение(Синоним)=0 Тогда

			Если нрег(СтрЗаменить(Синоним," ",""))<>нрег(Реквизит.Идентификатор) Тогда

				Синоним=" ("+Синоним+")";

			Иначе

				Синоним="";

			КонецЕсли;

		КонецЕсли;

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(СокрЛП(Реквизит.Идентификатор)+Синоним);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Тип=Реквизит.Тип;

		Если Тип="Строка" Тогда

			Тип=Тип+" ("+СокрЛП(Реквизит.Длина)+")";

		ИначеЕсли Тип="Число" Тогда

			Тип=Тип+" ("+СокрЛП(Реквизит.Длина);

			Если ПустоеЗначение(Реквизит.Точность)=0 Тогда

				Тип=Тип+"."+СокрЛП(Реквизит.Точность);

			КонецЕсли;

			Тип=Тип+")";

		Иначе

			Тип=Тип+"."+Реквизит.Вид;

		КонецЕсли;

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(Тип);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(Реквизит.Комментарий);

	КонецЦикла;

	Предупреждение("Готово",5);

КонецПроцедуры



Процедура СтруктураРегистра()

	Ворд=СоздатьОбъект("Word.Application");

	Ворд.DisplayAlerts=0;

	

	Для Сч=1 По Метаданные.Регистр(СокрЛП(Имя)).Измерение() Цикл

		Ворд.ActiveDocument.ActiveWindow.S_election.I_nsertRowsBelow(1);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveLeft(1,1);

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText("Измерение");

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Реквизит=Метаданные.Регистр(СокрЛП(Имя)).Измерение(Сч);

		Синоним=Реквизит.Синоним;

		Если ПустоеЗначение(Синоним)=0 Тогда

			Если нрег(СтрЗаменить(Синоним," ",""))<>нрег(Реквизит.Идентификатор) Тогда

				Синоним=" ("+Синоним+")";

			Иначе

				Синоним="";

			КонецЕсли;

		КонецЕсли;

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(СокрЛП(Реквизит.Идентификатор)+Синоним);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Тип=Реквизит.Тип;

		Если Тип="Строка" Тогда

			Тип=Тип+" ("+СокрЛП(Реквизит.Длина)+")";

		ИначеЕсли Тип="Число" Тогда

			Тип=Тип+" ("+СокрЛП(Реквизит.Длина);

			Если ПустоеЗначение(Реквизит.Точность)=0 Тогда

				Тип=Тип+"."+СокрЛП(Реквизит.Точность);

			КонецЕсли;

			Тип=Тип+")";

		Иначе

			Тип=Тип+"."+Реквизит.Вид;

		КонецЕсли;

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(Тип);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(Реквизит.Комментарий);

	КонецЦикла;

	Для Сч=1 По Метаданные.Регистр(СокрЛП(Имя)).Ресурс() Цикл

		Ворд.ActiveDocument.ActiveWindow.S_election.I_nsertRowsBelow(1);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveLeft(1,1);

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText("Ресурс");

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Реквизит=Метаданные.Регистр(СокрЛП(Имя)).Ресурс(Сч);

		Синоним=Реквизит.Синоним;

		Если ПустоеЗначение(Синоним)=0 Тогда

			Если нрег(СтрЗаменить(Синоним," ",""))<>нрег(Реквизит.Идентификатор) Тогда

				Синоним=" ("+Синоним+")";

			Иначе

				Синоним="";

			КонецЕсли;

		КонецЕсли;

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(СокрЛП(Реквизит.Идентификатор)+Синоним);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Тип=Реквизит.Тип;

		Если Тип="Строка" Тогда

			Тип=Тип+" ("+СокрЛП(Реквизит.Длина)+")";

		ИначеЕсли Тип="Число" Тогда

			Тип=Тип+" ("+СокрЛП(Реквизит.Длина);

			Если ПустоеЗначение(Реквизит.Точность)=0 Тогда

				Тип=Тип+"."+СокрЛП(Реквизит.Точность);

			КонецЕсли;

			Тип=Тип+")";

		Иначе

			Тип=Тип+"."+Реквизит.Вид;

		КонецЕсли;

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(Тип);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(Реквизит.Комментарий);

	КонецЦикла;

	Для Сч=1 По Метаданные.Регистр(СокрЛП(Имя)).Реквизит() Цикл

		Ворд.ActiveDocument.ActiveWindow.S_election.I_nsertRowsBelow(1);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveLeft(1,1);

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText("Реквизит");

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Реквизит=Метаданные.Регистр(СокрЛП(Имя)).Реквизит(Сч);

		Синоним=Реквизит.Синоним;

		Если ПустоеЗначение(Синоним)=0 Тогда

			Если нрег(СтрЗаменить(Синоним," ",""))<>нрег(Реквизит.Идентификатор) Тогда

				Синоним=" ("+Синоним+")";

			Иначе

				Синоним="";

			КонецЕсли;

		КонецЕсли;

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(СокрЛП(Реквизит.Идентификатор)+Синоним);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Тип=Реквизит.Тип;

		Если Тип="Строка" Тогда

			Тип=Тип+" ("+СокрЛП(Реквизит.Длина)+")";

		ИначеЕсли Тип="Число" Тогда

			Тип=Тип+" ("+СокрЛП(Реквизит.Длина);

			Если ПустоеЗначение(Реквизит.Точность)=0 Тогда

				Тип=Тип+"."+СокрЛП(Реквизит.Точность);

			КонецЕсли;

			Тип=Тип+")";

		Иначе

			Тип=Тип+"."+Реквизит.Вид;

		КонецЕсли;

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(Тип);

		Ворд.ActiveDocument.ActiveWindow.S_election.MoveRight(1,1);

		Ворд.ActiveDocument.ActiveWindow.S_election.TypeText(Реквизит.Комментарий);

	КонецЦикла;

	Предупреждение("Готово",5);

КонецПроцедуры

Категория: Работа с Microsoft Office и OpenOffice

Состав информационной базы 1С:Предприятие 7.7 Категория: Администрирование

Журнал регистрации

Журнал регистрации относится к информационной базе и служит для сохранения информации о событиях, возникающих в процессе работы пользователей с данной информационной базой .
Эта информация может быть важной с организационной точки зрения , но не является необходимой для функционирования прикладного решения на базе 1 С : Предприятия . Журналы регистрации хранятся в специальных каталогах 1Cv8Log по одному на каждую информационную базу . Каждый каталог содержит файл 1Cv8.elf и несколько файлов с именами вида yyyyMMddhhmmss.log, где yyyy - номер года , MM - номер месяца , dd - номер дня в месяце, hh - номер часа , mm - номер минуты , ss - номер секунды . Например, " 20070525200000.log ". Файл 1Cv8.elf содержит общую информацию журнала регистрации . Каждый файл yyyyMMddhhmmss.log содержит фрагмент журнала регистрации за соответствующий период . Имя файла представляет момент времени начала периода . Длина периода определяется настройкой журнала регистрации " Разделять хранение журнала по периодам ".
В файловом варианте информационной базы журнал регистрации располагается в каталоге информационной базы , в том же, что и файл самой информационной базы . Например , если информационная база хранится в файле C:/EnterpriseInfoBase/1Cv8.1CD, то журнал регистрации будет находиться в каталоге C:/EnterpriseInfoBase/1Cv8log.
В клиент- серверном варианте информационной базы журнал регистрации располагается в подкаталоге рабочего каталога кластера . Имя подкаталога определяется идентификатором информационной базы . Например : " C:/Program
Files/1cv81/server/reg_1541/fb9d9cc4 - ccd0 -4be7 - 87e8 - c5182945291e/1Cv8Log". Подробно о рабочем каталоге центрального сервера и кластера можно прочитать в разделе "Хранение настроек кластера серверов 1С : Предприятия 8.1".

Категория: Администрирование