ненужны » Поиск

Результаты по ключевому слову: ненужны

Полезные советы по интерфейсу "Такси"

Чтобы шрифт не казался крупным, и формы помещались на экране, можно уменьшить масштаб

Для этого нужно воспользоваться Меню «Вид – Изменить масштаб».

Чтобы быстро найти нужный пункт меню, можно воспользоваться поиском меню

Найти окно поиска меню на любой панели. В верхнем правом углу написать ключевое слово для поиска.

Так же используя поиск можно быстро искать необходимые документы или элементы справочника

Чтобы на форме помещалось больше информации, можно сократить панель разделов

Вызвать настройку панели разделов, для этого нужно воспользоваться Меню «Вид – Настройка панели разделов». Убрать надписи с панели разделов и оставить только картинку в окне «Показывать».

Чтобы на форме были видны нужные колонки и не видны ненужные, можно настроить форму

Открыть форму и воспользоваться кнопкой «Еще». В верхней правой части формы снять флажки с ненужных колонок, а нужные колонки передвинуть вперед.

Чтобы добавить журналы документов покупателей и поставщиков, можно настроить панели «Продажи» и «Покупки»

Нажать меню «Продажи». В правом верхнем углу нажать на серую шестеренку «Настройки». Выбрать меню «Настройка навигации». В списке слева щелкнуть два раза на «Документы покупателей».

Фильтры / отборы в журнале

Нажать на меню «Операции». Открыть «Журнал операций». В левом верхнем углу в поле «Контрагент» указать покупателя.

Все функции и стандартные операции

Откройте Меню-Сервис-Параметры, установите галку Отображать команду Все функции и нажмите ОК

Стандартные

Внизу раздел Стандартные:

Как вернуть стандартную настроку списка документов или справочника

Избранное - быстрый доступ к документам, справочникам

Для добавления в избранное нажмите на значек звездочки в открытом списке

или в меню раздела

Для быстрого доступа к избранному нажмите на звездочку в левом верхнем углу

Категория: 1С Общие вопросы - Управляемые формы и Такс…

ДеревоЗначений в ТекстовыйДокумент

Код 1C v 8.2 УП

 // Выводит данные ДереваЗначений в ТекстовыйДокумент, пригодный к рассмотрению в отладчике, окне сообщений и показу.

//

// Параметры:

//    рВетка - дерево значений, подлежащее выводу. Может иметь почти любую глубину иерархии, количество и тип колонок. Если хватит

//        объявленных позиционных строк-заполнителей, всё поместится. Если иерархия слишком глубока, строки просто надо нарастить;

//    рТекст - на входе должен быть равен Неопределено; на выходе по окончании работы содержит результатный текстовый документ;

//    рПараметры - структура дополнительных настроек, допустимые ключи:

//        Колонки - структура колонок, которые подлежат выводу. Если пуста или имеет тип, отличный от структуры, выводятся все колонки;

//           если в ключах структуры указаны имена колонок, будут выведены только они. В значениях структуры можно передать строковое

//           представление формата, согласно которому должны будут форматироваться выводимые значения. По умолчанию формата нет;

//        ПоказыватьУровни - булево, управляет выводом №№ уровней (метод Уровень()), по умолчанию выключено;

//        ШагОтступа - число, определяющее шаг в символах, используемый для показа псевдографики иерархии веток в дереве.

//

&НаСервереБезКонтекста

Процедура ВывестиДеревоЗначенийВТекст(Знач рВетка,рТекст,Знач рПараметры=Неопределено)

Попытка

    Если рТекст=Неопределено Тогда // первая итерация, шапочный вызов исходной части

        //---------------------------------------------------------------------------------------------------------------------------

        // Разбираем входные данные

        Если ТипЗнч(рВетка)<>Тип("ДеревоЗначений") Тогда Возврат КонецЕсли;

        Если ТипЗнч(рПараметры)<>Тип("Структура") Тогда рПараметры=Новый Структура КонецЕсли;

        стрКолонок=?(рПараметры.Свойство("Колонки"),рПараметры.Колонки,Неопределено);

        Если ТипЗнч(стрКолонок)<>Тип("Структура") Тогда стрКолонок=Новый Структура КонецЕсли;

        рПоказыватьУровни=?(рПараметры.Свойство("ПоказыватьУровни"),рПараметры.ПоказыватьУровни,Ложь); // затратное дело, кстати

        рШагОтступа=?(рПараметры.Свойство("ШагОтступа"),рПараметры.ШагОтступа,2); // для отображения отступа в колонке иерархии





        //---------------------------------------------------------------------------------------------------------------------------

        // Определяем максимальное количество уровней

        // Также можно получить максимальный уровень, "плоско" перебрав все строки (например, получив их через НайтиСтроки)

        // и в цикле для каждой вызывая Уровень() и определяя максимум.

        // Вариант через СКД и служебное поле "Уровень" ни на одной известной мне платформе не работоспособен (нехватка памяти).

        //

        //

        //рДеревоДляТеста=КакНибудьСкопироватьДерево(рВетка);

        //рДеревоДляТеста.Колонки.Вставить(0,"_Level",Новый ОписаниеТипов("Булево")); // самый экономный вариант, с сохранением иерархии

        //мНенужных=Новый Массив;

        //Для й=1 По рДеревоДляТеста.Колонки.Количество()-1 Цикл

        //  мНенужных.Добавить(рДеревоДляТеста.Колонки[й]);

        //КонецЦикла;

        //Для каждого кол Из мНенужных Цикл

        //  рДеревоДляТеста.Колонки.Удалить(кол);

        //КонецЦикла;

        //

        рДеревоДляТеста=рВетка; // пока сериализуем прямо всё дерево (неоптимально, но...)

        рЗапись=Новый ЗаписьXML;

        рЗапись.УстановитьСтроку();

        СериализаторXDTO.ЗаписатьXML(рЗапись,рДеревоДляТеста);

        стро=рЗапись.Закрыть();

        //

        стро=СтрЗаменить(стро,"xmlns=","xmlns:myns1C="); // иначе не будет работать XPath

        //

        рЧтение=Новый ЧтениеXML;

        рЧтение.УстановитьСтроку(стро);

        постр=Новый ПостроительDOM;

        рДокументДОМ=постр.Прочитать(рЧтение);





        рВыражение="/ValueTree/row"; максКолвоУровней=1;

        рРазыменователь=Новый РазыменовательПространствИменDOM(рДокументДОМ);

        Пока Истина Цикл

            #Если Клиент Тогда

                ОбработкаПрерыванияПользователя();

            #КонецЕсли

            рРезультат=рДокументДОМ.ВычислитьВыражениеXPath(рВыражение,рДокументДОМ,рРазыменователь,ТипРезультатаDOMXPath.Любой);

            Если рРезультат.ПолучитьСледующий()=Неопределено Тогда Прервать КонецЕсли;

            рВыражение=рВыражение+"/row";

            максКолвоУровней=максКолвоУровней+1;

        КонецЦикла;

        максКолвоУровней=максКолвоУровней-1; // можно и так: СтрЧислоВхождений(рВыражение,"/row")-1;





        //---------------------------------------------------------------------------------------------------------------------------

        // готовим исходный макет вывода

        строПробелы="                                                                                                                                                                                                                 ";

        строРазделители="===============================================================================================";

        строОтступы="___________________________________________________________________________________________"; // тут нужны чуть для другого

        //

        секШапка1="|[_HCS"+Лев(строПробелы,максКолвоУровней*рШагОтступа)+"]|"; // HierarchyColumnShow

        секГорРазделитель1="|"+Лев(строОтступы,максКолвоУровней*рШагОтступа+6)+"|"; // здесь именно Отступы!

        рШиринаКолонкиИерархии=СтрДлина(секШапка1)-2;

        строПолейШапки="#Поле _HCS

        |   #Выравнивание Центр";

        строПолейЗаписи="";

        //

        Если рПоказыватьУровни Тогда

            секШапка1=секШапка1+"[_Level]|";

            секГорРазделитель1=секГорРазделитель1+Лев(строРазделители,8)+"|";

            строПолейШапки=строПолейШапки+"

            |#Поле _Level

            |   #Выравнивание Центр";

            строПолейЗаписи="#Поле _Level

            |   #Выравнивание Центр

            |   #Забивать Истина";

        КонецЕсли;

        //

        мИменКолонок=Новый Массив;

        Для каждого кол Из рВетка.Колонки Цикл

            Если стрКолонок.Количество()<>0 и не стрКолонок.Свойство(кол.Имя) Тогда Продолжить КонецЕсли; // чётко указаны конкретные колонки

            рДлинаИмениКолонки=СтрДлина(кол.Имя);

            рНужнаяШирина=Макс(?(кол.Ширина<3,10,кол.Ширина),рДлинаИмениКолонки);

            // к сожалению, ключевое слово "#Поля" неприменимо - платформа падает - поэтому делаем всё сами

            секШапка1=секШапка1+"["+кол.Имя+Лев(строПробелы,рНужнаяШирина-рДлинаИмениКолонки)+"]|";

            секГорРазделитель1=секГорРазделитель1+Лев(строРазделители,рНужнаяШирина+1)+"=|";

            строПолейШапки=строПолейШапки+"

            |#Поле "+кол.Имя+"

            |   #Выравнивание Центр";

            рОписТипов=кол.ТипЗначения;

            Если рОписТипов.Типы().Количество()=1 и рОписТипов.СодержитТип(Тип("Булево")) Тогда

                рВыравнивание="Центр";

            ИначеЕсли рОписТипов.СодержитТип(Тип("Число")) Тогда

                рВыравнивание="Право";

            ИначеЕсли рОписТипов.СодержитТип(Тип("Строка")) и рОписТипов.КвалификаторыСтроки.Длина=0 Тогда

                рВыравнивание="ПоШирине";

            Иначе

                рВыравнивание="Лево";

            КонецЕсли;

            строПолейЗаписи=строПолейЗаписи+?(ПустаяСтрока(строПолейЗаписи),"",Символы.ПС)+"#Поле "+кол.Имя+"

            |   #Выравнивание "+рВыравнивание;

            Попытка

                Если ЗначениеЗаполнено(стрКолонок[кол.Имя]) Тогда // указан формат, уточняющий показ колонки

                    строПолейЗаписи=строПолейЗаписи+"

                    |   #Формат """+СокрЛП(стрКолонок[кол.Имя])+"""";

                КонецЕсли;

            Исключение

            КонецПопытки;

            мИменКолонок.Добавить(кол.Имя);

        КонецЦикла;

        секШапка2=СтрЗаменить(СтрЗаменить(секШапка1,"[","<"),"]",">");

        секЗапись1=секШапка1; секЗапись2=секШапка2; // пусть они по дизайну пока не отличаются

        секГорРазделитель2=СтрЗаменить(СтрЗаменить(секГорРазделитель1,"=","-"),"|","+");

        // обработаем нормальное обрамление шапки колонки иерархии

        секГорРазделитель1=СтрЗаменить(секГорРазделитель1,"_","=");

        секГорРазделитель2=СтрЗаменить(секГорРазделитель2,"_"," ");

        //

        тМакет=Новый ТекстовыйДокумент;

        тМакет.ДобавитьСтроку("#Область Шапка");

        тМакет.ДобавитьСтроку(строПолейШапки);

        тМакет.ДобавитьСтроку(секГорРазделитель1);

        тМакет.ДобавитьСтроку(секШапка1);

        тМакет.ДобавитьСтроку(секШапка2);

        тМакет.ДобавитьСтроку(секГорРазделитель1);

        тМакет.ДобавитьСтроку("#КонецОбласти");

        тМакет.ДобавитьСтроку("");

        тМакет.ДобавитьСтроку("#Область Запись");

        тМакет.ДобавитьСтроку(строПолейЗаписи);

        тМакет.ДобавитьСтроку(секЗапись1);

        тМакет.ДобавитьСтроку(секЗапись2);

        тМакет.ДобавитьСтроку(секГорРазделитель2);

        тМакет.ДобавитьСтроку("#КонецОбласти");

        рПараметры.Вставить("ИсходныйМакет",тМакет); // пусть будет





        //---------------------------------------------------------------------------------------------------------------------------

        // Запускаем вывод в итоговый документ

        рТекст=Новый ТекстовыйДокумент;

        сек=тМакет.ПолучитьОбласть("Шапка");

        сек.Параметры._HCS="Иерархия";

        Для каждого имякол Из мИменКолонок Цикл

            кол=рВетка.Колонки[имякол];

            сек.Параметры[кол.Имя]=?(ПустаяСтрока(кол.Заголовок),кол.Имя,кол.Заголовок);

        КонецЦикла;

        рТекст.Вывести(сек);

        //

        пар=Новый Структура;

        пар.Вставить("МассивИмёнКолонок",мИменКолонок);

        пар.Вставить("ТекущаяСекция",тМакет.ПолучитьОбласть("Запись"));

        пар.Вставить("ШиринаКолонкиИерархии",рШиринаКолонкиИерархии);

        пар.Вставить("ПоказыватьУровни",рПоказыватьУровни);

        пар.Вставить("Отступ",0);

        пар.Вставить("ШагОтступа",рШагОтступа);

        ВывестиДеревоЗначенийВТекст(рВетка,рТекст,пар);





    Иначе

        // очередная итерация, вывод в текстовый документ

        мИменКолонок=рПараметры.МассивИмёнКолонок;

        рСекция=рПараметры.ТекущаяСекция;

        рОтступ=рПараметры.Отступ;

        рШиринаКолонкиИерархии=рПараметры.ШиринаКолонкиИерархии;

        рПоказыватьУровни=рПараметры.ПоказыватьУровни;

        //

        строОтступы="_________________________________________________________________________________________________________";

        строПробелы="                                                                                                                                                                                                                 ";

        //

        пар=Новый Структура;

        пар.Вставить("МассивИмёнКолонок",мИменКолонок);

        пар.Вставить("ТекущаяСекция",рПараметры.ТекущаяСекция);

        пар.Вставить("ШиринаКолонкиИерархии",рШиринаКолонкиИерархии);

        пар.Вставить("ПоказыватьУровни",рПоказыватьУровни);

        пар.Вставить("ШагОтступа",рПараметры.ШагОтступа);

        пар.Вставить("Отступ",рОтступ+рПараметры.ШагОтступа);

        //

        Для каждого рПодветка Из рВетка.Строки Цикл

            рСекция.Параметры._HCS=Лев(строПробелы,рОтступ)+"\"+Лев(строОтступы,рШиринаКолонкиИерархии-рОтступ-1);

            Если рПоказыватьУровни Тогда

                рСекция.Параметры._Level=рПодветка.Уровень();

            КонецЕсли;

            Для каждого имякол Из мИменКолонок Цикл

                рСекция.Параметры[имякол]=рПодветка[имякол];

            КонецЦикла;

            рТекст.Вывести(рСекция);

            ВывестиДеревоЗначенийВТекст(рПодветка,рТекст,пар)

        КонецЦикла;

        //

    КонецЕсли;

Исключение

    Сообщить("ВывестиДеревоЗначенийВТекст, ошибка: "+ОписаниеОшибки(),СтатусСообщения.ОченьВажное);

КонецПопытки;

КонецПроцедуры

Источник

Категория: Работа с Деревом Значений

Как удалить две повторяющихся строки подряд?

У нас есть таблица в которой есть повторяющиеся подряд строки (после сортировки) и обе они ненужны!

Например в таблице будут будущие проводки и если суммы совпадают, то эти проводки нам не нужны.

Значит нужно удалить повторяющиеся строки:

Код 1C v 8.х

 #Область УдалениеЛишнихСтрок

 Индекс=0;

 Для каждого СтрТаб Из ТаблицаКурсовыхРазниц Цикл

  Индекс = ТаблицаКурсовыхРазниц.Индекс(СтрТаб);

   СтрТаб2 = ТаблицаКурсовыхРазниц.Получить(Индекс);

   Если СтрТаб.СубконтоДт1 = СтрТаб2.СубконтоДт1 И СтрТаб.Сумма = СтрТаб2.Сумма Тогда //Условие совпадиния

    ТаблицаКурсовыхРазниц.Удалить(Индекс+1);

    ТаблицаКурсовыхРазниц.Удалить(Индекс);

  КонецЕсли;

 КонецЦикла;

#КонецОбласти

На выходе получим уже чистую таблицу.

Категория: Работа с Таблицей Значений

Тормозит сервер 1С или компьютер с 1С - Настройка и Оптимизация

Очень часто ко мне обращаются с вопросами вида:

из-за чего тормозит сервер 1С?
компьютер с 1С работает очень медленно
жутко тормозит клиент 1С

Что же делать и как это победить, и так по порядку:

Клиенты очень медленно работают с серверной версией 1С

Кроме медленной работы 1С, так же наблюдается медленная работа с сетевыми файлами. Проблема встречается при обычной работе и при RDP

для решения этого, после каждой установки Семерки или 2008-го сервера всегда запускаю

netsh int tcp set global autotuning=disabled

netsh int tcp set global autotuninglevel=disabled

netsh int tcp set global rss=disabled chimney=disabled

и сеть работает без проблем

иногда оптимальным является:
netsh interface tcp set global autotuning= HighlyRestricted

вот как выглядит установка

Далее посмотрите настройки брандмауэра Windows

Настроить брандмауэр Антивируса или Windows

Как настроить брандмауэр Антивируса или Windows для работы сервера 1С (связка из Сервера 1С: Предприятие и MS SQL 2008, например).

Добавьте правила:

Если сервер SQL принимает подключения на стандартный порт TCP 1433, то разрешаем его.
Если порт SQL динамический, то необходимо разрешить подключения к приложению %ProgramFiles%\Microsoft SQL Server\MSSQL10_50.MSSQLSERVER\MSSQL\Binn\sqlservr.exe.
Сервер 1С работает на портах 1541, кластер 1540 и диапазоне 1560-1591. По совершенно мистическим причинам иногда такой список открытых портов все равно не позволяет выполнять подключения к серверу. Чтобы заработало наверняка, разрешите диапазон 1540-1591.

Настройка производительности Сервера / Компьютера

Для того чтобы компьютер работал с максимальной производительностью - нужно настроить его на это:

1. Настройки BIOS

В BIOS сервера отключаем все настройки по экономии электропитания процессора.
Если есть «C1E» & обязательно ОТКЛЮЧАЕМ!!
Для некоторых не очень параллельных задач также рекомендуется выключить гипертрейдинг в биосе
В некоторых случаях (особенно для HP!) надо зайти в BIOS сервера, и ВЫКЛЮЧИТЬ там пункты, в названии которых есть EIST, Intel SpeedStep и C1E.
Взамен надо там же найти пункты, связанные с процессором, в названии которых есть Turbo Boost, и ВКЛЮЧИТЬ их.
Если в биосе есть общее указание режима энергосбережения & включить его в режим максимальной производительности (он ещё может называться «агрессивный»)

2. Настройки схемы в операционной системе - Высокая производительность

Сервера с архитектурой Intel Sandy Bridge умеют динамически менять частоты процессора.

Скачайте утилиту PowerSchemeEd.7z , распакуйте с помощь 7zip и запустите PowerSchemeEd.exe

Выберите раздел Управление питанием процессора и выставите параметры 01. Порог при питании от сети 30% и отключите 27. Переопределение ядра... как на картинке.

3. На серверах 1С и MS SQL Server использование антивирусов (даже сам факт инсталяции без включения) будет приводить к снижению производительности в виде периодических массовых замедлений и подвисаний интерфейса.

4. Совмещение ролей сервера 1С и сервера MS SQL Server дает большую производительность, особенно если использовать протокол обмена данных напрямую через память «Shared Memory».

Очень многие не недооценивают важность настройки сервера, когда роли сервера 1С и сервера СУБД совмещены на одном физическом компьютере.

Убедиться, что к примеру используется протокол Shared Memory можно следующим образом:

Код SQL

 select program_name,net_transport

from sys.dm_exec_sessions as t1

left join sys.dm_exec_connections AS t2 ON t1.session_id=t2.session_id

where not t1.program_name is null

Обратите внимание, что в версиях платформы некоторые релизы «переключались» на протокол «именнованых каналов».

Для работы 1С Предприятие в режиме Shared Memory с SQL Server 2012 должен быть установлен NativeClient от SQL Server 2008 (backward compatibility connectivity components из дистрибутива SQL Server 2012 или отдельный пакет)

5. Отключение ненужных служб Виндовс

Одним из самых действенных способов ускорения компьютера является отключение неиспользуемых (ненужных) служб операционной системы. У ОС Windows по умолчанию включено огромное количество служб, на работу которых требуется большое количество ресурсов системы. Многие из них можно отключить без потери функциональности и снижения безопасности системы.

Какие службы можно отключить для оптимизации Windows:

Авто настройка WWAN – в том случае, если у Вас нет CDMA или GSM модулей, эту службу можно безболезненно отключить
Адаптивная регулировка яркости – эта служба регулирует яркость экрана при наличии датчика освещенности, если такой датчик отсутствует – отключаем.
Брандмауэр Windows – предназначен для защиты компьютера. Рекомендуется пользоваться сторонними приложениями для этих целей (например, Comodo, KIS, DrWEB и т.п.).
Защитник Windows – отключаем, совершенно ненужная служба!
Служба помощника по совместимости программ (Program Compatibility Assistant) – эту службу можно отключить, только в случае несовместимости программ нужно будет вручную устанавливать параметры, что бывает не так уж часто.
Служба автоматического обнаружения веб-прокси WinHTTP – можно отключать.
Служба политики диагностики (Diagnostic Policy Service) – практически не нужна.
Смарт-карта – если Вы не пользуетесь такими картами, то отключаем.
Удаленный реестр (Remote Registry) – обязательно отключаем в целях безопасности.
Центр обеспечения безопасности (Security Center) – напоминает о различных событиях вроде отсутствия антивируса, устаревших обновлениях и т.п. – отключаем, если не хотите их видеть.

Список, конечно, получился не особо емким, на самом деле служб, которые можно отключить, намного больше. Кроме того, среди стандартных служб появятся дополнительные службы сторонних программ, которые установлены на Вашем ПК, их также можно отключить.

Кэширование записей на дисках в Windows

Кэшированием записей на устройстве хранения называется использование высокоскоростной энергозависимой памяти для накопления команд записи, отправляемых на устройства хранения данных, и их кэширования до тех пор, пока их не обработает более медленный носитель (либо физические диски, либо недорогая флэш-память). Для большинства устройств, использующих кэширование записей, требуется непрерывная подача электропитания.

Для управления кэшированием записей на диске откройте Панель управления - Диспетчер устройств.

В разделе Дисковые устройства дважды щелкните нужный диск.

Перейдите на вкладку Политики

В статье использован личный опыт и cайт Вячеслава Гилева

Буду рад конструктивным комментариям

Категория: Администрирование

Как отсечь ненужные пробелы из выборки запроса при заполнении параметров макета

Поскольку отсечь ненужные пробелы в самом запросе достаточно проблематично, приходиться обрезать пробелы при установке параметров. Но часто значительно удобнее заполнить параметры макета "скопом" без отдельного присваивания каждого из них. В таком случае можно обрезать лишние пробелы уже после заполнения:

Код 1C v 8.х

 Таб = Новый ТабличныйДокумент;

Макет = ПолучитьМакет("Макет");

Обл = Макет.ПолучитьОбласть("Обл");

Обл.Параметры.Заполнить(ВыборкаЗапроса);

Для Индекс=0 По Обл.Параметры.Количество()-1 Цикл

   ЗначениеПараметра = Обл.Параметры[Индекс];

   Если ТипЗнч(ЗначениеПараметра) = Тип("Строка") Тогда

      Обл.Параметры[Индекс] = СокрЛП(ЗначениеПараметра);

   КонецЕсли; 

КонецЦикла; 

Таб.Вывести(Обл);

Категория: Табличный документ

Срез последних (остатки) на каждую дату

Бывают ситуации, когда в запросе требуется получить остатки не на фиксированную дату (параметр - один на весь отчет), а на произвольную, (когда дата остатков в каждой строке своя).

Существует несколько способов получить нужные данные.

1.Непосредственно в запросе (через реальную таблицу регистра)
Способ подходит практически для любой ситуации, и поэтому наиболее универсален. Единственный, пожалуй, минус этого способа - если в отчете пользователю не требуется курс, то запрос быдет выбирать избыточные данные.

Вызов СрезПоследних() можно использовать только с передачей в него заранее готового значения даты, на которую требуется получить значения. Поэтому сабж делается через стыковку нескольких запросов - основной, к нему стыкуется запрос по регистру сведений с условием по дате и поиском записи с максимальной датой (периодом).

Код 1C v 8.х

 ВЫБРАТЬ

   Таб1.СсылкаДок,

   Таб1.ДатаДок,

   Таб1.ВалютаДок,

   Таб2.Курс

ИЗ

   (ВЫБРАТЬ

    ЗаказПокупателя.Ссылка КАК СсылкаДок,

    ЗаказПокупателя.Дата КАК ДатаДок,

    ЗаказПокупателя.ВалютаДокумента КАК ВалютаДок,

    МАКСИМУМ(Валюты.Период) КАК ПериодДок

   ИЗ

    Документ.ЗаказПокупателя КАК ЗаказПокупателя

    ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КурсыВалют КАК Валюты

      ПО Валюты.Период <= ЗаказПокупателя.Дата И 

      Валюты.Валюта = ЗаказПокупателя.ВалютаДокумента

   СГРУППИРОВАТЬ ПО

    ЗаказПокупателя.Ссылка) КАК Таб1

    ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КурсыВалют КАК Таб2

    ПО Таб1.ПериодДок = Таб2.Период И Таб1.ВалютаДок = Таб2.Валюта

Для общего развития:
Что есть срез последних в платформе?

Код 1C v 8.х

 ВЫБРАТЬ

  Рег.Период,

  Рег.Измерение,

  Рег.Ресурс

ИЗ

  РегситрСведений.ПериодическийРегистр.СрезПоследних(&Дата) КАК Рег

В зависимости от периодичности регистра (по времени, по позизии регистратора) ВТ разворачивается в следующий запрос:
1. По времени (год, месяц, ... секунда)

Код 1C v 8.х

 ВЫБРАТЬ

 Таблица3.Ресурс,

 Таблица3.Измерение,

 Таблица3.Период

ИЗ

 (ВЫБРАТЬ

  Таблица1.Измерение КАК Измерение,

  МАКСИМУМ(Таблица1.Период) КАК Период

 ИЗ

  РегистрСведений.ПериодическийРегистр КАК Таблица1

ГДЕ

  Таблица1.Период <= &Дата

 СГРУППИРОВАТЬ ПО

  Таблица1.Измерение) КАК Таблица2

  ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ПериодическийРегистр КАК Таблица3

  ПО Таблица2.Измерение= Таблица3.Измерение

   И Таблица2.Период = Таблица3.Период

2. По позиции регистратора
В данном случае нужно еще раз обернуть выборку

Код 1C v 8.х

 ВЫБРАТЬ

 Таблица5.Ресурс,

 Таблица5.Измерение,

 Таблица5.Период,

 Таблица5.Регистратор

ИЗ

(ВЫБРАТЬ

 МАКСИМУМ(Таблица3.Регистратор) КАК Регистратор,

 Таблица3.Измерение

ИЗ

 (ВЫБРАТЬ

  Таблица1.Измерение КАК Измерение,

  МАКСИМУМ(Таблица1.Период) КАК Период

 ИЗ

  РегистрСведений.ПериодическийРегистр КАК Таблица1

ГДЕ

  Таблица1.Период <= &Дата

 СГРУППИРОВАТЬ ПО

  Таблица1.Измерение) КАК Таблица2

  ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ПериодическийРегистр КАК Таблица3

  ПО Таблица2.Измерение= Таблица3.Измерение

   И Таблица2.Период = Таблица3.Период

СГРУППИРОВАТЬ ПО

  Таблица3.Измерение) КАК Таблица4

  ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ПериодическийРегистр КАК Таблица5

  ПО Таблица4.Измерение = Таблица5.Измерение

   И Таблица4.Регистратор = Таблица5.Регистратор

Все это можно увидеть посмотрев технологический журнал с включенным режимом протоколирования запросов

2.Система компоновки данных (передача набора значений одной таблицы в параметр виртуальной таблицы)
Данный способ подходит для отчетов. Из очевидных плюсов - если курс (или другие данные) не нужны для построения отчета, то СКД не будет их получать. Однако быстродействие такого отчета может оказаться и несколько ниже, чем в первом способе.

Для примера сделаем отчет - список заказов покупателей.

Для этого создадим набор данных "Документы" - запрос:

Код 1C v 8.х

 ВЫБРАТЬ

    ЗаказПокупателя.Ссылка КАК ЗаказПокупателя,

    ЗаказПокупателя.Дата КАК Дата,

    ЗаказПокупателя.ВалютаДокумента КАК ВалютаДокумента,

    ЗаказПокупателя.СуммаДокумента КАК СуммаДокумента

{ВЫБРАТЬ

    ЗаказПокупателя.*,

    Дата,

    ВалютаДокумента.*,

    СуммаДокумента}

ИЗ

    Документ.ЗаказПокупателя КАК ЗаказПокупателя

{ГДЕ

    ЗаказПокупателя.Ссылка.* КАК ЗаказПокупателя,

    ЗаказПокупателя.СуммаДокумента}

Для того, чтобы потом успешно свзать наборы данных, в запрос необходимо включить поля "Дата" и "ВалютаДокумента". Чтобы они не появлялись в списке доступных полей, если это необходимо, их можно убрать, установив флажки ограничений в таблице "Поля" схемы компоновки. В остальном запрос вряд ли требует комментариев.
title

Для того, чтобы получить информацию о курсах валют, добавим второй набор данных-запрос, "Курсы валют":

Код 1C v 8.х

 ВЫБРАТЬ

    &Дата КАК Дата,

    КурсыВалютСрезПоследних.Валюта КАК Валюта,

    КурсыВалютСрезПоследних.Курс КАК Курс,

    КурсыВалютСрезПоследних.Кратность КАК Кратность

{ВЫБРАТЬ

    Дата,

    Валюта.*,

    Курс,

    Кратность}

ИЗ

    РегистрСведений.КурсыВалют.СрезПоследних(&Дата, Валюта = &Валюта) КАК КурсыВалютСрезПоследних

{ГДЕ

    КурсыВалютСрезПоследних.Курс,

    КурсыВалютСрезПоследних.Кратность}

В этом запросе имеются 2 параметра: "Дата" и "Валюта". Эти параметры будут установлены СКД при соединении наборов. Кроме того, параметр "Дата" указан в выбранных полях - это нужно для соединения таблиц.
Для ненужный полей "Дата" и "Валюта" также устанавливаем флажки ограничений, чтобы они не появлялись в доступных полях.
title

Перейдем к соединению наборов. На странице "Связи наборов данных" добавим 2 связи:
1. Источник связи - набор "Документы", приемник - набор "Курсы валют". Выражение источник - "Дата", выражение приемник - "Дата", Параметр - "Дата"
2. Источник связи - набор "Документы", приемник - набор "Курсы валют". Выражение источник - "ВалютаДокумента", выражение приемник - "Валюта", Параметр - "Валюта"
title

Главное здесь - параметры связи. При соединении наборов данных, если указан параметр, СКД передает в подчиненный набор (в нашем случае - запрос "Курсы валют") параметры, указанные в соединении. Значениями параметров будут значения соответствующих полей набора-источника.

Перейдем к вычисляемым полям. Добавим вычисляемое поле "СуммаВВалютеУпрУчета". Выражение поля - "СуммаДокумента * Курс / Кратность".
title

Также укажем поля "СуммаДокумента" и "СуммаВВалютеУпрУчета" как ресурсы
title

Настроим отчет.
Добавим одну группировку "Детальные записи", в выбранных полях укажем "ЗаказПолкупателя", "Курс" и "Кратность". Добавим ресурсы "СуммаДокумента" и "СуммаВВалютеУпрУчета"
title

Можно формировать отчет
title

Категория: Регистры накопления

Консоль заданий для управления фоновыми задачами

Работа программ на платформе 1С: Предприятие 8 подразумевает то, что многие операции необходимо выполнять с заданной периодичностью. Перечень таких задач (обмен данными, проверка текстовых сообщений и прочее) достаточно велик, поэтому их выполнение вручную будет занимать достаточно много времени.

Разработчики 1С позаботились о том, чтобы в процессе работы с программами 1С: Предприятие 8 пользователь тратил как можно меньше времени на однотипную рутинную работу, а поэтому выполнение Конфигураторе большинства этих заданий предопределено. Однако столь большое количество регулярно выполняемых операций может быть излишним. Например, операция «Обновление текстового индекса» выполняется через каждые 150 секунд, «Проверка почты» - тоже часто. В процессе выполнения каждой операции пользователь отмечает как бы «замирание» работы программы на несколько секунд. А ведь их много, а это значит, что выполнение ненужных процессов в значительной степени ухудшает быстродействие программы.
Но и в этом случае разработчики 1С все предусмотрели. Настроить расписание выполнения фоновых операций, исключив ненужные задания, можно с помощью внешней обработки «Консоль заданий»:
title

В открывшемся окне вы увидите две таблицы: одна - с фоновыми заданиями, другая – с регламентными. С помощью командной панели вы можете убрать лишние фоновые задачи, а также изменить расписание необходимых вплоть до дней, часов и минут. Такая оптимизация выполнения фоновых операций позволяет в значительной степени увеличить быстродействие программы. Причем особенно актуально это для тех пользователей, которые в работе используют компьютеры с невысокими вычислительными способностями. Следует отметить, что используя обработку «Консоль заданий» пользователь также может изменить аналогичным способом расписание выполнения регламентных операций.

В архиве две обработки:
- Консоль заданий
- Обработка принудительного запуска выполнения регламентированного задания
Скачивать файлы может только зарегистрированный пользователь!

Категория: Встроенные Функции

Параметры виртуальных таблиц

При организации выборок в реальных задачах в подавляющем большинстве случаев организуется отбор данных в соответствии с некоторыми критериями.

В случае, когда выборка делается из реальной таблицы, никаких сложностей не возникает. Данные обрабатываются абсолютно тривиально:
title

В том случае, когда источником в запросе выступает виртуальная таблица, ситуация становится несколько сложнее.

Язык запросов позволяет наложить условие на выборку из виртуальных таблиц двумя способами: в предложении ГДЕ и с помощью параметров виртуальных таблиц. Оба способа приведут к одному результату (за исключением некоторых специфических случаев), но, тем не менее, они далеко не эквиваленты.

Мы уже знаем, что виртуальные таблицы потому и называются виртуальными, что в базе их на самом деле нет. Формируются они только в тот момент, когда к ним обращается запрос. Несмотря на это, нам (то есть, тем, кто составляет запрос) удобно рассматривать виртуальные таблицы именно как реально существующие. Что же произойдёт в системе 1С Предприятие 8, когда составленный нами запрос всё-таки обратится к виртуальной таблице?

На первом шаге, система построит виртуальную таблицу. На втором шаге из полученной таблицы будут выбраны записи, удовлетворяющие условию, заданному в предложении ГДЕ:
title

Хорошо видно, что в итоговую выборку попадут не все записи из виртуальной таблицы (а, следовательно, и из базы данных), а только те, которые удовлетворяют заданному условию. А остальные записи просто будут исключены из результата.

Таким образом, система проделает не просто бесполезную, а двойную бесполезную работу! Сначала будут затрачены ресурсы на построение виртуальной таблицы на основе лишних данных (на рисунке они помечены как «области данных А и Б»), а потом ещё будет проделана работа по фильтрации этих данных из окончательного результата.

Нельзя ли сразу, на этапе построения виртуальной таблицы, отказаться от использования ненужных данных? Оказывается, можно. Именно для этого и предназначены параметры виртуальных таблиц:
title

Параметризируя виртуальную таблицу, мы сразу ограничиваем объём данных, который будет обрабатываться запросом.

В чем заключается различие значений параметра виртуальной таблицы "МетодДополнения"?
Когда МетодДополнения установлен в "движения", то будут выданы только те периоды в которых были движения. Когда установлен "ДвиженияИГраницыПериода", тогда к вышеуказанным движениям добавятся 2 записи: движения на начало и конец заданного в параметрах ВТ периода. Поле "Регистратор" при этом для этих 2-х записей будет пустым.

Категория: Запросы

Как получить Срез Последних значений на Каждую Дату

Данный способ подходит для отчетов. Из очевидных плюсов - если курс (или другие данные) не нужны для построения отчета, то СКД не будет их получать. Однако быстродействие такого отчета может оказаться и несколько ниже, чем в первом способе.

Для примера сделаем отчет - список заказов покупателей.
Для этого создадим набор данных "Документы" - запрос:

Код 1C v 8.х

 ВЫБРАТЬ

    ЗаказПокупателя.Ссылка КАК ЗаказПокупателя,

    ЗаказПокупателя.Дата КАК Дата,

    ЗаказПокупателя.ВалютаДокумента КАК ВалютаДокумента,

    ЗаказПокупателя.СуммаДокумента КАК СуммаДокумента

{ВЫБРАТЬ

    ЗаказПокупателя.*,

    Дата,

    ВалютаДокумента.*,

    СуммаДокумента}

ИЗ

    Документ.ЗаказПокупателя КАК ЗаказПокупателя

{ГДЕ

    ЗаказПокупателя.Ссылка.* КАК ЗаказПокупателя,

    ЗаказПокупателя.СуммаДокумента}

Для того, чтобы получить информацию о курсах валют, добавим второй набор данных-запрос, "Курсы валют":

Код 1C v 8.х

 ВЫБРАТЬ

    &Дата КАК Дата,

    КурсыВалютСрезПоследних.Валюта КАК Валюта,

    КурсыВалютСрезПоследних.Курс КАК Курс,

    КурсыВалютСрезПоследних.Кратность КАК Кратность

{ВЫБРАТЬ

    Дата,

    Валюта.*,

    Курс,

    Кратность}

ИЗ

    РегистрСведений.КурсыВалют.СрезПоследних(&Дата, Валюта = &Валюта) КАК КурсыВалютСрезПоследних

{ГДЕ

    КурсыВалютСрезПоследних.Курс,

    КурсыВалютСрезПоследних.Кратность}

Также укажем поля "СуммаДокумента" и "СуммаВВалютеУпрУчета" как ресурсы
title

Можно формировать отчет
title

Defender aka LINN

Как получить Срез Последних на Каждую Дату

То же самое простым запросом

Категория: Схема Компоновки Данных

Выгрузка в PDF из 1С (Средствами OpenOffice)

Возникла задача отправлять счета почтой. PDFcreator не подошёл поскольку не удалось вместить счёт на одну страницу по ширине. Решил попробовать OpenOffice. Как сохранять в PDF нашёл быстро, а вот как уместить счёт на одну страницу вширь искал долго.
В версии 1С 8.2.232 появилась возможность сохранять табличный документ в xls файл на сервера под линуксом. А вот работать с Опеном офисом из-под линукса пока не получается. Собственно комментари ненужны. Вот весь код. Самое интересное это бодание со стилями страниц в Опене Офисе. Жаль что этот фрагмент работает только на клиенте. На сервере вопрос не решается *08

Код 1C v 8.2 УП

 Процедура КнопкаВыполнитьНажатие(Кнопка)

    Если Письмо.Основание.Пустая() Тогда

        Возврат

    КонецЕсли;



    // Открыть OpenOffice

    Попытка

        ServiceManager = Новый COMОбъект("com.sun.star.ServiceManager");

    Исключение

        Возврат // опен офис не установлен :-(

    КонецПопытки;



    // получим печатную форму и запишем её во временный XLS файл

    Заказ = Письмо.Основание.ПолучитьОбъект();



    //Получим печатную форму

    Расшифровка=Новый Структура;

    Расшифровка.Вставить("СсылкаНаВнешнююОбработку",Константы.ПФСчетаДляКлиента.Получить());

    Расшифровка.Вставить("ВидПечатнойФормы",Перечисления.ВидыДополнительныхВнешнихОбработок.ПечатнаяФорма);

    Расшифровка.Вставить("НомерСтроки",1);

    тд = УниверсальныеМеханизмы.НапечататьВнешнююФорму(Заказ, Расшифровка);



    ВременныйФайл =ПолучитьИмяВременногоФайла();

    ВременныйФайлXLS =ВременныйФайл + ".xls";

    ВременныйФайлPDF =ВременныйФайл + ".pdf";

    тд.Записать(ВременныйФайлXLS, ТипФайлаТабличногоДокумента.XLS97);



    // Преобразовываем временный xls файл В PDF

    Desktop        = ServiceManager.createInstance("com.sun.star.frame.Desktop");



    НастройкиОткрытия = Новый COMSafeArray("VT_VARIANT", 1);

    PropertyValue = ServiceManager.Bridge_GetStruct("com.sun.star.beans.PropertyValue");

    PropertyValue.Name = "Hidden";

    PropertyValue.Value = Истина;

    НастройкиОткрытия.SetValue(0, PropertyValue);

    ВременныйФайлXLS_какУРЛ = "file:///" + СтрЗаменить(ВременныйФайлXLS, "\", "/"); // приводим путь к файлу из виндового формата в опен офисный



    // Откроем файл в опене офисе

    ОпенОфис = Desktop.LoadComponentFromURL(ВременныйФайлXLS_какУРЛ, "_blank", 0, НастройкиОткрытия);



    //ПараметрыСтраницы = ОпенОфис.createInstance("com.sun.star.style.PageStyle");

    //ПараметрыСтраницы.ScaleToPagesX = 1;

    //

    // Установим масштаб, чтобы счёт помещался на одной странице вширь

    // страниц почему-то много, поэтому устанавливаем масштаб для всех

    Стили = ОпенОфис.StyleFamilies.getByName("PageStyles");

    Для поз = 0 по Стили.count - 1 Цикл

        МойСтиль = Стили.getByIndex(поз);

        МойСтиль.ScaleToPagesX = 1; // уместить на одной странице вширь

        //МойСтиль.PageScale = 50; // масштаб 50%

    КонецЦикла;



    НастройкиСохранения = Новый COMSafeArray("VT_VARIANT", 1);

    PropertyValue = ServiceManager.Bridge_GetStruct("com.sun.star.beans.PropertyValue");

    PropertyValue.Name = "FilterName";

    PropertyValue.Value = "calc_pdf_Export";

    НастройкиСохранения.SetValue(0, PropertyValue);



    ВременныйФайлPDF_какУРЛ = "file:///" + СтрЗаменить(ВременныйФайлPDF, "\", "/"); // приводим путь к файлу из виндового формата в опен офисный

    ОпенОфис.storeToURL(ВременныйФайлPDF_какУРЛ, НастройкиСохранения); // сохранили PDF файл

    ОпенОфис.close(-1);

    ОпенОфис = Неопределено;



    // С опеном офисом разобрались. Прикрепляем вложение к письму и удаляем временные файлы.

    //Файл = Новый Файл(ВременныйФайлPDF);

    объектПисьмо = Письмо.ПолучитьОбъект();

    стрВложение = объектПисьмо.Вложения.Добавить();

    стрВложение.ИмяФайла = "Счёт " + Строка(Заказ.Номер) + ".pdf";

    стрВложение.Файл = Новый ХранилищеЗначения(Новый ДвоичныеДанные(ВременныйФайлPDF));

    объектПисьмо.Записать();

    Попытка

        УдалитьФайлы(ВременныйФайлXLS);

        УдалитьФайлы(ВременныйФайлPDF);

    Исключение

    КонецПопытки;



КонецПроцедуры

Автор: Трактор

Функция позволяющая выполнить выгрузку табличного документа в PDF средствами OpenOffice

Код 1C v 8.х

 // Функция превращает табличный документ в PDF документ

// Возвращаемое значение: тип "Строка" - имя созданного PDF файла, 0 - в случае ошибки

// Параметры: ДанныеВыгрузки - Табличный или текстовый документ, который нужно выгрузить в PDF

//            ПутьВыгрузки - тип "Строка", путь для сохраниения PDF файла (без имени и расширения файла)

//            ИмяФайлаБезРасширения - тип "Строка", имя для вновь сформированного PDF файла

// Тестировалось на OpenOffice 3.x

Функция ВыгрузитьТабличныйДокументВPDF(ДанныеВыгрузки, ПутьВыгрузки, ИмяФайлаБезРасширения)       

    Если НЕ ЗначениеЗаполнено(ПутьВыгрузки) Тогда

        ПутьВыгрузки = КаталогВременныхФайлов();

    КонецЕсли;   

    ПутьВыгрузки         = ?(Прав(ПутьВыгрузки, 1) = "\", ПутьВыгрузки, ПутьВыгрузки + "\");

   

    РасширениеXSL         = ".xls";

    РасширениеPDF         = ".pdf";

    ПолноеИмяФайлаXLS     = ПутьВыгрузки + ИмяФайлаБезРасширения + РасширениеXSL;

    //Выгрузка данных печати в файл XLS   

#Если Клиент Тогда

    Состояние("Создание временного файла...");

#КонецЕсли

    Попытка

        Если         ТипЗнч(ДанныеВыгрузки) = Тип("ТабличныйДокумент") Тогда        

            ДанныеВыгрузки.Записать(ПолноеИмяФайлаXLS, "XLS");

        ИначеЕсли     ТипЗнч(ДанныеВыгрузки) = Тип("ТекстовыйДокумент") Тогда

            ДанныеВыгрузки.Записать(ПолноеИмяФайлаXLS, "XLS");

        Иначе

#Если Клиент Тогда

            Сообщить("Данные для выгрузки переданы в неподдерживаемом формате. Дальнейшее выполнение невозможно." + Символы.ПС + ОписаниеОшибки());

#КонецЕсли

            Возврат 0;

        КонецЕсли;

    Исключение

#Если Клиент Тогда

        Сообщить("Произошла ошибка при выгрузке временного файла. Возможно ошибка доступа к папке, в которую происходит запись." + Символы.ПС + ОписаниеОшибки());

#КонецЕсли

        Возврат 0;

    КонецПопытки;

   

    Попытка

#Если Клиент Тогда

        Состояние("Открытие компоненты OpenOffice...");

#КонецЕсли

        ServiceManager    = Новый COMОбъект("com.sun.star.ServiceManager");       

       

        Скрипт             = Новый COMОбъект("MSScriptControl.ScriptControl");

        Скрипт.language    = "javascript";

        Скрипт.AddObject("OpenOffice", ServiceManager);

       

        //Открытие временного файла без отображения его окна

#Если Клиент Тогда           

        Состояние("Открытие временного файла...");

#КонецЕсли

        Скрипт.eval("Массив=new Array()");       

        Массив             = Скрипт.eval("Массив");   

        Скрипт.eval("Массив[0] = OpenOffice.Bridge_GetStruct('com.sun.star.beans.PropertyValue')");

        Скрипт.eval("Массив[0].Name     = 'Hidden'");

        Скрипт.eval("Массив[0].Value = true");

       

        Скрипт.AddCode("function SetItem(ind,val){Массив[ind]=val}");       

        Скрипт.AddObject("ServiceManager",ServiceManager);

        Desktop         = ServiceManager.createInstance("com.sun.star.frame.Desktop");       

        Document         = Desktop.LoadComponentFromURL("file:///" + ПолноеИмяФайлаXLS, "_blank", 0, Массив);

       

        //Сохранение в PDF встроенными средствами OpenOffice

#Если Клиент Тогда           

        Состояние("Запись в PDF...");

#КонецЕсли

        Скрипт.eval("Массив2=new Array()");       

        Массив2     = Скрипт.eval("Массив2");       

        Скрипт.eval("Массив2[0] = OpenOffice.Bridge_GetStruct('com.sun.star.beans.PropertyValue')");       

        Скрипт.eval("Массив2[0].Name  = 'FilterName'");

        Скрипт.eval("Массив2[0].Value = 'writer_pdf_Export'");

       

        ПолноеИмяФайлаPDF         = "file:///" + СтрЗаменить(ПолноеИмяФайлаXLS, РасширениеXSL, РасширениеPDF);

        ПолноеИмяФайлаPDF         = СтрЗаменить(ПолноеИмяФайлаPDF, ВРег(РасширениеXSL), РасширениеPDF);

        ПолноеИмяФайлаPDF        = СтрЗаменить(ПолноеИмяФайлаPDF, "\", "/");       

               

        Document.storeToURL(ПолноеИмяФайлаPDF, Массив2);

        Document.close(-1);        //Закрыть документ

       

        //Контрольная очистка переменных

        Document     = Неопределено;

        Desktop     = Неопределено;

       

        //Удаление временного файла

#Если Клиент Тогда           

        Состояние("Удаление временного файла...");

#КонецЕсли       

        Попытка

            УдалитьФайлы(ПолноеИмяФайлаXLS);

        Исключение

#Если Клиент Тогда           

            Сообщить("Произошла ошибка при удалении временного файла. Возможно, потребуется удалить его вручную." + Символы.ПС + ОписаниеОшибки());

#КонецЕсли

        КонецПопытки;

       

        ПолноеИмяФайлаPDF = СтрЗаменить(ПолноеИмяФайлаPDF, "file:///", "");

        ПолноеИмяФайлаPDF = СтрЗаменить(ПолноеИмяФайлаPDF, "/", "\");

#Если Клиент Тогда

        Состояние("Выгрузка выполнена.");

        Предупреждение("Выгрузка выполнена." + Символы.ПС + ПолноеИмяФайлаPDF);       

#КонецЕсли

        Возврат ПолноеИмяФайлаPDF;

    Исключение

        Document.close(-1);

#Если Клиент Тогда

        Предупреждение(ОписаниеОшибки());

#КонецЕсли

        Возврат 0;

    КонецПопытки   

КонецФункции

Автор: doom_2001

Категория: Работа с Microsoft Office и OpenOffice