построение » Поиск

Результаты по ключевому слову: построение

17 правил для составления оптимального ЗАПРОСа к данным базы 1С

Для формирования и выполнения запросов к таблицам базы данных в платформе 1С используется специальный объект языка программирования Запрос. Создается этот объект вызовом конструкции Новый Запрос. Запрос удобно использовать, когда требуется получить сложную выборку данных, сгруппированную и отсортированную необходимым образом. Классический пример применения запроса - получение сводки по состоянию регистра накопления на определенный момент времени. Так же, механизм запросов позволяет легко получать информацию в различных временных разрезах.

Текст запроса – это инструкция, в соответствии с которой должен быть выполнен запрос. В тексте запроса описывается:

таблицы информационной базы, используемые в качестве источников данных запроса;
поля таблиц, которые требуется обрабатывать в запросе;
правила группировки;
сортировки результатов;
и т. д.

Инструкция составляется на специальном языке – языке запросов и состоит из отдельных частей – секций, предложений, ключевых слов, функций, арифметических и логических операторов, комментариев, констант и параметров.

Язык запросов платформы 1С очень похож на синтаксис других SQL-языков, но имеются отличия. Основными преимуществами встроенного языка запросов являются: разыменование полей, наличие виртуальных таблиц, удобная работа с итогами, нетипизированные поля в запросах.

Рекомендации по написанию запросов к базе данных на языке запросов платформы 1С:

1) Текст запроса может содержать предопределенные данные конфигурации, такие как:

значения перечислений;
предопределенные данные:
справочников;
планов видов характеристик;
планов счетов;
планов видов расчетов;
пустые ссылки;
значения точек маршрута бизнес-процессов.

Также текст запроса может содержать значения системных перечислений, которые могут быть присвоены полям в таблицах базы данных: ВидДвиженияНакопления, ВидСчета и ВидДвиженияБухгалтерии. Обращение в запросах к предопределенным данным конфигурации и значениям системных перечислений осуществляется с помощью литерала функционального типа ЗНАЧЕНИЕ. Данный литерал позволяет повысить удобочитаемость запроса и уменьшить количество параметров запроса.

Пример использования литерала ЗНАЧЕНИЕ:

ГДЕ Город = ЗНАЧЕНИЕ(Справочник.Города.Москва)
ГДЕ Город = ЗНАЧЕНИЕ(Справочник.Города.ПустаяСсылка)
ГДЕ ТипТовара = ЗНАЧЕНИЕ(Перечисление.ВидыТоваров.Услуга)
ГДЕ ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход)
ГДЕ ТочкаМаршрута = ЗНАЧЕНИЕ(БизнесПроцесс.БизнесПроцесс1.ТочкаМаршрута.Действие1

2) Использование инструкции АВТОУПОРЯДОЧИВАНИЕ в запросе может сильно время выполнения запроса, поэтому, если сортировка не требуется, то лучше вообще ее не использовать. Во большинстве случаях лучше всего применять сортировку с помощью инструкции УПОРЯДОЧИТЬ ПО.

Автоупорядочивание работает по следующим принципам:

Если в запросе было указано предложение УПОРЯДОЧИТЬ ПО, то каждая ссылка на таблицу, находящаяся в этом предложении, будет заменена полями, по которым по умолчанию сортируется таблица (для справочников это код или наименование, для документов – дата документа). Если поле для упорядочивания ссылается на иерархический справочник, то будет применена иерархическая сортировка по этому справочнику.
Если в запросе отсутствует предложение УПОРЯДОЧИТЬ ПО, но есть предложение ИТОГИ, тогда результат запроса будет упорядочен по полям, присутствующим в предложении ИТОГИ после ключевого слова ПО, в той же последовательности и, в случае если итоги рассчитывались по полям – ссылкам, то по полям сортировки по умолчанию таблиц, на которые были ссылки.
Если в запросе отсутствуют предложения УПОРЯДОЧИТЬ ПО и ИТОГИ, но есть предложение СГРУППИРОВАТЬ ПО, тогда результат запроса будет упорядочен по полям, присутствующим в предложении, в той же последовательности и, в случае если группировка велась по полям – ссылкам, то по полям сортировки по умолчанию таблиц, на которые были ссылки.
В случае же, если в запросе отсутствуют предложения и УПОРЯДОЧИТЬ ПО, ИТОГИ и СГРУППИРОВАТЬ ПО, результат будет упорядочен по полям сортировки по умолчанию для таблиц, из которых выбираются данные, в порядке их появления в запросе.
В случае, если запрос содержит предложение ИТОГИ, каждый уровень итогов упорядочивается отдельно.

3) Что бы избежать повторного запроса к базе данных при выводе результата запроса пользователю (например, построение запроса или отображение результата запроса с помощью табличного документа) полезно использовать инструкцию ПРЕДСТАВЛЕНИЕССЫЛКИ, которая позволяет получать представление ссылочного значения. Пример:

Код 1C v 8.х

 ВЫБРАТЬ

ПРЕДСТАВЛЕНИЕССЫЛКИ(РасходнаяНакладнаяСостав.Номенклатура) КАК НоменклатураПредставление<br>

Так же возможно использование инструкции ПРЕДСТАВЛЕНИЕ - предназначена для получения строкового представления значения произвольного типа. Отличие этих инструкций в том, что в первом случае, если инструкции передать ссылку, результатом будет строка, В остальных случаях результатом будет значение переданного параметра. Во втором случае, результатом инструкции всегда будет строка!

4) Если в запросе имеется поле с составным типом, то для таких полей возникает необходимость привести значения поля к какому-либо определенному типу с помощью инструкции ВЫРАЗИТЬ, что позволит убрать лишние таблицы из левого соединения с полем составного типа данных и ускорить выполнение запроса. Пример:

Имеется регистра накопления ОстаткиТоваров, у которого поле Регистратор имеет составной тип. В запросе выбираются Дата и Номер документов ПоступлениеТоваров, при этом при обращении к реквизитам документа через поле Регистратор не происходит множество левых соединений таблицы регистра накопления с таблицами документов-регистраторов.

Код 1C v 8.х

 ВЫБРАТЬ

ВЫРАЗИТЬ(ОстаткиТоваров.Регистратор КАК Документ.ПоступлениеТоваров).Номер КАК НомерПоступления,

ВЫРАЗИТЬ(ОстаткиТоваров.Регистратор КАК Документ.ПоступлениеТоваров).Дата КАК ДатаПоступления

ИЗ

РегистрНакопления.ОстаткиТоваров КАК ОстаткиТоваров<br>

Если приведение типа считается не осуществимым, то результатом приведения типа будет значение NULL.

5) Не стоит забывать про инструкцию РАЗРЕШЕННЫЕ, которая означает, что запрос выберет только те записи, на которые у текущего пользователя есть права. Если данное слово не указать, то в случае, когда запрос выберет записи, на которые у пользователя нет прав, запрос отработает с ошибкой.

6) В случае, если в запросе используется объединение, и в некоторых частях объединения присутствуют вложенные таблицы (документ с табличной частью), а в некоторых нет, возникает необходимость дополнения списка выборки полями – пустыми вложенными таблицами. Делается это при помощи ключевого слова ПУСТАЯТАБЛИЦА, после которого в скобках указываются псевдонимы полей, из которых будет состоять вложенная таблица. Пример:

Код 1C v 8.х

 // Выбрать поля Номер и Состав

// из виртуальной таблицы Документ.РасхНакл

ВЫБРАТЬ Ссылка.Номер, ПУСТАЯТАБЛИЦА.(Ном, Тов, Кол) КАК Состав

ИЗ Документ.РасхНакл

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ Ссылка.Номер, Состав.(НомерСтроки, Товар, Количество)

ИЗ Документ.РасхНакл Документ.РасходнаяНакладная.Состав.*<br>

7) Что бы в результат запроса не попали повторяющиеся строки, следует использовать инструкцию РАЗЛИЧНЫЕ, потому что так нагляднее и понятнее, а инструкция СГРУППИРОВАТЬ ПО применяется для группировки с помощью агрегатных функций. Ксати, при использовании агрегатных функций предложение СГРУППИРОВАТЬ ПО может быть и не указано совсем, при этом все результаты запроса будут сгруппированы в одну единственную строку. Пример:

Код 1C v 8.х

 // Необходимо узнать, каким вообще контрагентам

// отгружался товар за период.

Выбрать Различные

Документ.РасходнаяНакладная.Контрагент<br>

8) Инструкция СГРУППИРОВАТЬ ПО позволяет обращаться к полям верхнего уровня, без группировки результатов по этим полям, если агрегатные функции применены к полям вложенной таблицы. Хотя в справке 1С написано, при группировке результатов запроса в списке полей выборки обязательно должны быть указаны агрегатные функции, а помимо агрегатных функций в списке полей выборки допускается указывать только поля, по которым осуществляется группировка. Пример:

Код 1C v 8.х

 ВЫБРАТЬ

ПоступлениеТоваровИУслуг.Товары.(СУММА(Количество),Номенклатура),

ПоступлениеТоваровИУслуг.Ссылка,

ПоступлениеТоваровИУслуг.Контрагент

ИЗ

Документ.ПоступлениеТоваровИУслуг КАК ПоступлениеТоваровИУслуг

СГРУППИРОВАТЬ ПО

ПоступлениеТоваровИУслуг.Товары.(Номенклатура)<br>

9) Инструкция ЕСТЬNULL предназначена для замены значения NULL на другое значение, но не забываем, что второй параметр будет преобразован к типу первого в случае, если тип первого параметра является строкой или числом.

10) При обращении к главной таблице можно в условии обратиться к данным подчиненной таблицы. Такая возможность называется разыменование полей подчиненной таблицы.

Пример (поиск документов, содержащих в табличной части определенный товар):

Код 1C v 8.х

 ВЫБРАТЬ

Приходная.Ссылка

ИЗ

Документ.Приходная Где Приходная.Товары.Номенклатура =Номенклатура.<br>

Преимущество этого запроса перед запросом к подчиненной таблице Приходная.Товары в том, что если есть дубли в документах, результат запроса вернет только уникальные документы без использования ключевого слова РАЗЛИЧНЫЕ.

11) Интересный вариант оператора В - это проверка вхождения упорядоченного набора в множество таких наборов (Поле1, Поле2, ... , ПолеN) В (Поле1, Поле2, ... , ПолеN).

Пример:

Код 1C v 8.х

 ВЫБРАТЬ

Контрагенты.Ссылка

ГДЕ

(Контрагенты.Ссылка, Товары.Ссылка) В

(ВЫБРАТЬ Продажи.Покупатель, Продажи.Товар

ИЗ РегистрНакопления.Продажи КАК Продажи)

ИЗ

Справочник.Контрагенты,

Справочник.Товары<br>

12) При любой возможности используйте виртуальные таблицы запросов. При создании запроса система предоставляет в качестве источников данных некоторое количество виртуальных таблиц - это таблицы, которые так же являются результатом запроса, который система формирует в момент выполнения соответствующего участка кода.

Разработчик может самостоятельно получить те же самые данные, которые система предоставляет ему в качестве виртуальных таблиц, однако алгоритм получения этих данных не будет оптимизирован, так как:

Все виртуальные таблицы параметризованы, т. е. разработчику предоставляется возможность задать некоторые параметры, которые система будет использовать при формировании запроса создания виртуальной таблицы. В зависимости от того, какие параметры виртуальной таблицы указаны разработчиком, система может формировать РАЗЛИЧНЫЕ запросы для получения одной и той же виртуальной таблицы, причем они будут оптимизированы с точки зрения переданных параметров.

Не всегда разработчик имеет возможность получить доступ к тем данным, к которым имеет доступ система.

13) В клиент-серверном варианте работы функция ПОДСТРОКА() реализуется при помощи функции SUBSTRING() соответствующего оператора SQL, передаваемого серверу баз данных SQL Server, который вычисляет тип результата функции SUBSTRING() по сложным правилам в зависимости от типа и значений ее параметров, а так же в зависимости от контекста, в котором она используется. В большинстве случаев эти правила не оказывают влияния на выполнение запроса, но бывают случаи, когда для выполнения запроса существенна максимальная длина строки результата, вычисленная SQL Server. Важно иметь в виду, что в некоторых контекстах использования функции ПОДСТРОКА() максимальная длина ее результата может оказаться равной максимальной длине строки ограниченной длины, которая в SQL Server равна 4000 символам. Это может привести к неожиданному аварийному завершению выполнения запроса:

Microsoft OLE DB Provider for SQL Server: Warning: The query processor could not produce a query plan from the optimizer because the total length of all the columns in the GROUP BY or ORDER BY clause exceeds 8000 bytes.

HRESULT=80040E14, SQLSTATE=42000, native=8618

Чтобы избежать такой ошибки, не рекомендуют использовать функцию ПОДСТРОКА() с целью приведения строк неограниченной длины к строкам ограниченной длины. Вместо нее лучше использовать операцию приведения типа ВЫРАЗИТЬ().

14) С осторожностью используйте ИЛИ в конструкции ГДЕ, так как использование условия с ИЛИ может значительно "утяжелить" запрос. Решить проблему можно конструкцией ОБЪЕДИНИТЬ ВСЕ. Пример:

Код 1C v 8.х

 ВЫБРАТЬ

_ДемоКонтрагенты.НаименованиеПолное

ИЗ

Справочник._ДемоКонтрагенты КАК _ДемоКонтрагенты

ГДЕ

_ДемоКонтрагенты.Ссылка =Ссылка1

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ

_ДемоКонтрагенты.НаименованиеПолное

ИЗ

Справочник._ДемоКонтрагенты КАК _ДемоКонтрагенты

ГДЕ

_ДемоКонтрагенты.Ссылка =Ссылка2<br>

15) Условие НЕ В в конструкции ГДЕ увеличивает время исполнения запроса, так как это своего рода НЕ (ИЛИ1 ИЛИ2 ... ИЛИn), поэтому для больших таблиц старайтесь использовать ЛЕВОЕ СОЕДИНЕНИЕ с условием ЕСТЬ NULL. Пример:

Код 1C v 8.х

 ВЫБРАТЬ

_ДемоКонтрагенты.Ссылка

ИЗ

Справочник._ДемоКонтрагенты КАК _ДемоКонтрагенты

ЛЕВОЕ СОЕДИНЕНИЕ Документ._ДемоЗаказПокупателя КАК _ДемоЗаказПокупателя

ПО _ДемоКонтрагенты.Ссылка = _ДемоЗаказПокупателя.Контрагент

ГДЕ

_ДемоЗаказПокупателя.Контрагент ЕСТЬ NULL<br>

16) При использовании Временных таблиц нужно индексировать поля условий и соединений в этих таблицах, НО, при использовании индексов запрос может выполняться еще медленнее. Поэтому необходимо анализировать каждый запрос с применением индекса и без, замерять скорость выполнения запроса и принимать окончательное решение.

Если вы помещаете во временную таблицу данные, которые изначально индексированы по некоторым полям, то во временной таблице индекса по этим полям уже не будет.

17) Если вы не используете Менеджер временных таблиц, то явно удалять временную таблицу не требуется, она будет удалена после завершения выполнения пакетного запроса, иначе следует удалить временную таблицу одним из способов: командой УНИЧТОЖИТЬ в запросе, вызвать метод МенеджерВременныхТаблиц.Закрыть().

Источник

И в дополнении видео от Евгения Гилева : Типовые ошибки при написании запросов на 1С:

Категория: Запросы

Обход метаданных (полезные функции)

При написании небольших автоматизированных тестов часто надо обойти всю конфигурацию и проверить, например, для всех форм какое-нибудь свойство. Это всё легко делается через свойство глобального контекста "Метаданные", но чтоб дорбаться до обхода реквизитов надо написать кучу вложенных циклов. При этом код становится слабочитаемым и слабомодифицируемым.

Ниже приведен небольшой модуль, который решает задачу легко и удобно. Создана специальная функция РазвернутьСтрокуОбходаМетаданных, которая может по строке типа "Метаданные.Справочники.*.Реквизиты.*" построить массив строк с перечислением всех реквизитов всех справочников. При помощи этой и нескольких других функций в экспортных функциях модуля реализованы вполне прикладные задачи - получение всех реквизитов, всех макетов, всех форм конфигурации и построение таблицы всех составных типов.

Код 1C v 8.х

  // Автор: Alexander Speshilov

// Рекрсивная функция, которая разворачивает строку вида "Метаданные.Справочники.*[Имя].Реквизиты.*.Тип" 

// в массив строк, заменяя "*" или другой символ, задаваемый параметрами обходом всех элементов 

// коллекции. Допускает выполнение функций встроенного языка (не стоит отдавать ввод параметров 

// пользователям). При этом выражение, используемое для получения по умолчанию может быть задано в 

// квадратных скобках или параметром функции.

//

// Параметры

//  СтрокаОбхода  - Строка - Разворачиваемая строка

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Массив строк

//

Функция РазвернутьСтрокуОбходаМетаданных(СтрокаОбхода, ЗаменяемоеЗначение = "*", ПредставлениеПоУмолчанию = "")

    

    Рез = Новый Массив;

    

    ЧастиСтрокиОбхода = РазобратьСтрокуОбхода(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

    Если ЧастиСтрокиОбхода = Неопределено тогда 

        Рез.Добавить(СтрокаОбхода); //фактически это ограничение рекурсии.

    Иначе

        ОбъектКоллекции = Вычислить(ЧастиСтрокиОбхода.СтрокаКоллекции);

        РазвернутаяКоллекция = РазвернутьКоллекциюВПредставления(ОбъектКоллекции, ЧастиСтрокиОбхода.СтрокаПредставление);

        Для каждого ЭлементРазвернутойКоллекции Из РазвернутаяКоллекция Цикл

            

            // рекурсивный вызов

            ТекущаяСтрокаОбхода = ЧастиСтрокиОбхода.СтрокаНачало + ЭлементРазвернутойКоллекции + ЧастиСтрокиОбхода.СтрокаКонец;

            МассивЭлемента = РазвернутьСтрокуОбходаМетаданных(ТекущаяСтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

            

            Для каждого ПримитивныйЭлементОбхода Из МассивЭлемента Цикл

                Рез.Добавить(ПримитивныйЭлементОбхода);

            КонецЦикла;

            

        КонецЦикла;

    КонецЕсли;

    

    Возврат Рез;

    

КонецФункции // РазвернутьСтрокуОбходаМетаданных()



// Разбирает строку обхода на удобные для работы поля

//

// Параметры

//  СтрокаОбхода  - Строка - Разворачиваемая строка

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Структура с полями ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец

// или Неопределено (если строка не содержит ЗаменяемоеЗначение)

//

Функция РазобратьСтрокуОбхода(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию)

    

    Если ПустаяСтрока(ЗаменяемоеЗначение) Тогда 

        ВызватьИсключение "Некорректное выражение заменяемого значения";

    КонецЕсли;

    

    ПозицияЗамены = Найти(СтрокаОбхода, ЗаменяемоеЗначение);

    

    // Если не найдена строка - возвращаем неопределено, как индикатор

    Если ПозицияЗамены = 0 Тогда 

        Возврат Неопределено; 

    КонецЕсли;

    

    СтрокаНачало = Лев(СтрокаОбхода,ПозицияЗамены - 1);

    

    //Получение строки для выражения-коллекции

    СтрокаКоллекции = СтрокаНачало;

    Если Прав(СтрокаКоллекции, 1) = "." Тогда 

        СтрокаКоллекции = Лев(СтрокаКоллекции,СтрДлина(СтрокаКоллекции) - 1);

    КонецЕсли;

    

    ПозицияОкончанияЗамены = ПозицияЗамены + СтрДлина(ЗаменяемоеЗначение);

    

    ОстатокВыражения = Сред(СтрокаОбхода, ПозицияОкончанияЗамены);

    

    //Обработка явного задания представления

    ОткрывающаяСкобка = "[";

    ЗакрывающаяСкобка = "]";

    Если Найти(ОстатокВыражения, ОткрывающаяСкобка) = 1 Тогда

        ОстатокВыражения = Сред(ОстатокВыражения, СтрДлина(ОткрывающаяСкобка) + 1);

        ПозицияЗакрывающейСкобки = Найти(ОстатокВыражения, ЗакрывающаяСкобка);

        Если ПозицияЗакрывающейСкобки = 0 Тогда 

            ВызватьИсключение "Синтаксическая ошибка разбора выражения";

        КонецЕсли;

        СтрокаПредставление = Лев(ОстатокВыражения, ПозицияЗакрывающейСкобки - 1);

        ОстатокВыражения = Сред(ОстатокВыражения, ПозицияЗакрывающейСкобки + СтрДлина(ЗакрывающаяСкобка));

    Иначе

        СтрокаПредставление = ПредставлениеПоУмолчанию;

    КонецЕсли;

    СтрокаКонец = ОстатокВыражения;

    

    Рез = Новый Структура("ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец",

    ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец);

    

    Возврат Рез;

    

КонецФункции // РазобратьСтрокуОбхода()



// Разворачивает объект коллекции в массив представления элементов

//

// Параметры

//  Коллекция  - Произвольный - Коллекция, которую можно обойти через "Для каждого"

//  ПредставлениеЭлемента  - Строка - необяз., свойство элементов коллекции, которое 

//               используется для получения представления.

//

// Возвращаемое значение:

//   Массив   - Массив представлений коллекции

//

Функция РазвернутьКоллекциюВПредставления(Коллекция, Знач ПредставлениеЭлемента = "")

    

    //Проверка и подгонка параметров

    Если не ПустаяСтрока(ПредставлениеЭлемента) Тогда 

        Если Найти(ПредставлениеЭлемента, ";")>0 Тогда 

            ВызватьИсключение "Некорректное выражение представления";

        КонецЕсли;

        ПредставлениеЭлемента = "." + ПредставлениеЭлемента;

    КонецЕсли;

    

    Рез = Новый Массив;

    Для каждого ЭлементКоллекции Из Коллекция Цикл

        ТекПредставление = Строка(Вычислить("ЭлементКоллекции" + ПредставлениеЭлемента));

        Рез.Добавить(ТекПредставление);

    КонецЦикла; 

    Возврат Рез;

    

КонецФункции // РазвернутьКоллекцию()



// Разворачивает массив строк через РазвернутьСтрокуОбходаМетаданных

//

// Параметры

//  МассивСтрокОбхода  - Массив - Массив разворачиваемых строк

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Массив строк

//

Функция РазвернутьМассивСтрокОбходаМетаданных(МассивСтрокОбхода, ЗаменяемоеЗначение = "*", ПредставлениеПоУмолчанию = "Имя")

    

    Рез = Новый Массив;

    

    Для каждого СтрокаОбхода Из МассивСтрокОбхода Цикл

        

        ДополнениеРезультата = РазвернутьСтрокуОбходаМетаданных(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

        Для каждого ТекСтрока Из ДополнениеРезультата Цикл

            Рез.Добавить(ТекСтрока);

        КонецЦикла; 

        

    КонецЦикла; 

    

    Возврат Рез;

    

КонецФункции // РазвернутьМассивСтрокОбходаМетаданных()



// Преобразует строку в массив одиночных строк по разделителю Символы.ПС

//

// Параметры

//  ПреобразуемаяСтрока - строка для преобразования

//    ИгнорироватьПустые - Булево - Пропускать пустые строки

//  СокращатьПробелы - Использовать СокрЛП

//

// Возвращаемое значение:

//   Массив строк

//

Функция ПолучитьМассивСтрокМногострочнойСтроки(ПреобразуемаяСтрока, ИгнорироватьПустые = Истина, СокращатьПробелы = Истина)

    

    Рез = Новый Массив;

    ЧислоСтрок = СтрЧислоСтрок(ПреобразуемаяСтрока);

    

    Для Сч = 1 По ЧислоСтрок Цикл

        

        ТекСтрока = СтрПолучитьСтроку(ПреобразуемаяСтрока, Сч);

        Если ИгнорироватьПустые и ПустаяСтрока(ТекСтрока) Тогда

            Продолжить;

        КонецЕсли; 

        Если СокращатьПробелы Тогда

            ТекСтрока = СокрЛП(ТекСтрока);

        КонецЕсли; 

        Рез.Добавить(ТекСтрока);

        

    КонецЦикла;

    

    Возврат Рез;

    

КонецФункции // ПолучитьМассивСтрокМногострочнойСтроки()



// Возвращает все реквизиты конфигурации, которые сохраняются в ИБ

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеХранимыеРеквизитыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.Константы.*

    |Метаданные.ПланыОбмена.*.Реквизиты.*

    |Метаданные.ПланыОбмена.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Справочники.*.Реквизиты.*

    |Метаданные.Справочники.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Документы.*.Реквизиты.*

    |Метаданные.Документы.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Последовательности.*.Измерения.*

    |Метаданные.ПланыВидовХарактеристик.*.Реквизиты.*

    |Метаданные.ПланыВидовХарактеристик.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.ПланыСчетов.*.Реквизиты.*

    |Метаданные.ПланыСчетов.*.ПризнакиУчета.*

    |Метаданные.ПланыСчетов.*.ПризнакиУчетаСубконто.*

    |Метаданные.ПланыСчетов.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.ПланыВидовРасчета.*.Реквизиты.*

    |Метаданные.ПланыВидовРасчета.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.РегистрыСведений.*.Измерения.*

    |Метаданные.РегистрыСведений.*.Ресурсы.*

    |Метаданные.РегистрыСведений.*.Реквизиты.*

    |Метаданные.РегистрыНакопления.*.Измерения.*

    |Метаданные.РегистрыНакопления.*.Ресурсы.*

    |Метаданные.РегистрыНакопления.*.Реквизиты.*

    |Метаданные.РегистрыБухгалтерии.*.Измерения.*

    |Метаданные.РегистрыБухгалтерии.*.Ресурсы.*

    |Метаданные.РегистрыБухгалтерии.*.Реквизиты.*

    |Метаданные.РегистрыРасчета.*.Измерения.*

    |Метаданные.РегистрыРасчета.*.Ресурсы.*

    |Метаданные.РегистрыРасчета.*.Реквизиты.*

    |Метаданные.БизнесПроцессы.*.Реквизиты.*

    |Метаданные.БизнесПроцессы.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Задачи.*.Реквизиты.*

    |Метаданные.Задачи.*.РеквизитыАдресации.*

    |Метаданные.Задачи.*.ТабличныеЧасти.*.Реквизиты.*

    |";

    ВсеХранимыеРеквизитыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеХранимыеРеквизитыКонфигурации;

    

КонецФункции // ПолучитьВсеХранимыеРеквизитыКонфигурации()



// Возвращает все реквизиты конфигурации составного типа, которые сохраняются в ИБ

//

// Параметры - Нет

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция ПолучитьВсеХранимыеРеквизитыКонфигурацииСоставногоТипа() Экспорт

    

    ВсеХранимыеРеквизитыКонфигурации = ПолучитьВсеХранимыеРеквизитыКонфигурации();

    Рез = Новый ТаблицаЗначений;

    Рез.Колонки.Добавить("Имя", Новый ОписаниеТипов("Строка"));

    Рез.Колонки.Добавить("Тип", Новый ОписаниеТипов("ОписаниеТипов"));

    Рез.Колонки.Добавить("КоличествоПростыхТипов", Новый ОписаниеТипов("Число"));

    

    Для каждого ТекРеквизит Из ВсеХранимыеРеквизитыКонфигурации Цикл

        

        Реквизит = Вычислить(ТекРеквизит);

        Тип = Реквизит.Тип;

        КоличествоПростыхТипов = Тип.Типы().Количество();

        Если КоличествоПростыхТипов<>1 Тогда 

    	    ТекСтрока = Рез.Добавить();

            ТекСтрока.Имя = ТекРеквизит;

            ТекСтрока.Тип = Тип;

            ТекСтрока.КоличествоПростыхТипов = КоличествоПростыхТипов;

        КонецЕсли;

    

    КонецЦикла; 

    

    Возврат Рез;

    

КонецФункции // ПолучитьВсеХранимыеРеквизитыКонфигурации()



// Возвращает все формы конфигурации

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеФормыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.ПланыОбмена.*.Формы.*

    |Метаданные.КритерииОтбора.*.Формы.*

    |Метаданные.ОбщиеФормы.*

    |Метаданные.Справочники.*.Формы.*

    |Метаданные.Документы.*.Формы.*

    |Метаданные.ЖурналыДокументов.*.Формы.*

    |Метаданные.Перечисления.*.Формы.*

    |Метаданные.Отчеты.*.Формы.*

    |Метаданные.Обработки.*.Формы.*

    |Метаданные.ПланыВидовХарактеристик.*.Формы.*

    |Метаданные.ПланыСчетов.*.Формы.*

    |Метаданные.ПланыВидовРасчета.*.Формы.*

    |Метаданные.РегистрыСведений.*.Формы.*

    |Метаданные.РегистрыНакопления.*.Формы.*

    |Метаданные.РегистрыБухгалтерии.*.Формы.*

    |Метаданные.РегистрыРасчета.*.Формы.*

    |Метаданные.БизнесПроцессы.*.Формы.*

    |Метаданные.Задачи.*.Формы.*

    |";

    ВсеФормыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеФормыКонфигурации;

    

КонецФункции // ПолучитьВсеФормыКонфигурации()



// Возвращает все макеты конфигурации

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеМакетыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.ПланыОбмена.*.Макеты.*

    |Метаданные.ОбщиеМакеты.*

    |Метаданные.Справочники.*.Макеты.*

    |Метаданные.Документы.*.Макеты.*

    |Метаданные.ЖурналыДокументов.*.Макеты.*

    |Метаданные.Перечисления.*.Макеты.*

    |Метаданные.Отчеты.*.Макеты.*

    |Метаданные.Обработки.*.Макеты.*

    |Метаданные.ПланыВидовХарактеристик.*.Макеты.*

    |Метаданные.ПланыСчетов.*.Макеты.*

    |Метаданные.ПланыВидовРасчета.*.Макеты.*

    |Метаданные.РегистрыСведений.*.Макеты.*

    |Метаданные.РегистрыНакопления.*.Макеты.*

    |Метаданные.РегистрыБухгалтерии.*.Макеты.*

    |Метаданные.РегистрыРасчета.*.Макеты.*

    |Метаданные.БизнесПроцессы.*.Макеты.*

    |Метаданные.Задачи.*.Макеты.*

    |";

    ВсеМакетыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеМакетыКонфигурации;

    

КонецФункции // ПолучитьВсеМакетыКонфигурации()

Категория: Метаданные

Особенности работы с хранилищем конфигурации Категория: Администрирование

Использование Web-сервисов для синхронизации баз данных в режиме online 1с 8.х Категория: WEB-сервисы, WS-ссылки, XDTO-пакеты

Обмен 1С c клиентом используя web сервисы 1С Категория: WEB-сервисы, WS-ссылки, XDTO-пакеты

Яндекс, Google, Рамблер Карты и 1С

Обработка демонстрирует возможности интеграции 1С с картографическими сервисами, в ней поддерживается работа трех поставщиков услуг / карт — Яндекс, Google. Рамблер.
Автор: Діма Головаченко - http://smaylukk.com.ua
но так вот сама обработка + еще 2 : Скачивать файлы может только зарегистрированный пользователь!

Код Модуля Обработки:

Код 1C v 8.х

 Перем СтруктураПоставщиковКарт Экспорт;

Перем СтруктураЧисел;



/////////////////////////РАБОТА С JSON //////////////////////////////////////////

Функция СформироватьСтрокуJSONИзМассива(Объект)

	

	СтрокаJSON = "[";

	

	Для каждого Элемент Из Объект Цикл

		СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент) + ",";

	КонецЦикла;

	

	Если Прав(СтрокаJSON, 1) = "," Тогда

		СтрокаJSON = Лев(СтрокаJSON, СтрДлина(СтрокаJSON)-1);

	КонецЕсли;

	

	Возврат СтрокаJSON + "]";

	

КонецФункции



Функция СформироватьСтрокуJSONИзСтруктуры(Объект)

	

	СтрокаJSON = "{";

	

	Для каждого Элемент Из Объект Цикл

		

		Если Элемент.Значение = "" Тогда

			Продолжить;

		КонецЕсли;

		

		СтрокаJSON = СтрокаJSON + """" + Элемент.Ключ + """" + ":";

		

		Если ТипЗнч(Элемент.Значение) = Тип("Строка") Тогда

			СтрокаJSON = СтрокаJSON + """" + URLEncode(Элемент.Значение) + """";

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Число") Тогда

			СтрокаJSON = СтрокаJSON + СтрЗаменить(Строка(Элемент.Значение), Символы.НПП, "");

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Булево") Тогда

			СтрокаJSON = СтрокаJSON + Формат(Элемент.Значение, "БЛ=false; БИ=true");

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Дата") Тогда

			// преобразование в unixtime

			СтрокаJSON = СтрокаJSON + Формат(ТекущаяДата() - Дата(1970,1,1,1,0,0), "ЧГ=0");

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Массив") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент.Значение);

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Структура") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент.Значение);

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("ТаблицаЗначений") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент.Значение);

			

		Иначе

			СтрокаJSON = СтрокаJSON + """" + URLEncode(Строка(Элемент.Значение)) + """";

			

		КонецЕсли;

		

		СтрокаJSON = СтрокаJSON + ",";

		

	КонецЦикла;

	

	Если Прав(СтрокаJSON, 1) = "," Тогда

		СтрокаJSON = Лев(СтрокаJSON, СтрДлина(СтрокаJSON)-1);

	КонецЕсли;

	

	Возврат СтрокаJSON + "}";

	

КонецФункции



Функция СформироватьСтрокуJSON(Объект) Экспорт

	

	СтрокаJSON = "";

	

	Если ТипЗнч(Объект) = Тип("Массив") Тогда

		СтрокаJSON = СформироватьСтрокуJSONИзМассива(Объект);

		

	ИначеЕсли ТипЗнч(Объект) = Тип("Структура") Тогда

		СтрокаJSON = СформироватьСтрокуJSONИзСтруктуры(Объект);

		

	ИначеЕсли ТипЗнч(Объект) = Тип("ТаблицаЗначений") Тогда

		// преобразуем таблицу значений в массив структур - работает дольше, но кода меньше

		// если нужна скорость, то нужно отдельно обработать таблицу значений

		

		СоставСтруктуры = "";

		Для каждого Колонка Из Объект.Колонки Цикл

			СоставСтруктуры = СоставСтруктуры + ?(ЗначениеЗаполнено(СоставСтруктуры), ",", "") + Колонка.Имя;

		КонецЦикла;

		

		МассивСтрок = Новый Массив;

		Для каждого Строка Из Объект Цикл

			СтруктураКолонок = Новый Структура(СоставСтруктуры);

			ЗаполнитьЗначенияСвойств(СтруктураКолонок, Строка);

			МассивСтрок.Добавить(СтруктураКолонок);

		КонецЦикла;

		

		СтрокаJSON = СформироватьСтрокуJSONИзМассива(МассивСтрок);

		

	КонецЕсли;

	

	Возврат СтрокаJSON;

	

КонецФункции



Процедура ЗаполнитьДанныеИзОтветаJSON(Результат, ТекстJSON, ТипДанных)

	

	ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));	// удалим открывающий символ структуры(массива)

	

	НомерЗначения = 0;

	

	Пока ТекстJSON <> "" Цикл

		

		ПервыйСимвол = Лев(ТекстJSON, 1);

		Если ПервыйСимвол = "{" Тогда

			// вложенная структура

			Значение = Новый Структура;

			ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Структура");

			

			Если ТипДанных = "Структура" Тогда

				Результат.Вставить("Значение" + ?(НомерЗначения = 0, "", НомерЗначения), Значение);

				НомерЗначения = НомерЗначения + 1;

			ИначеЕсли ТипДанных = "Массив" Тогда

				Результат.Добавить(Значение);

			КонецЕсли;

		

		ИначеЕсли ПервыйСимвол = "[" Тогда

			// вложенный массив

			Значение = Новый Массив;

			ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Массив");

			

			Если ТипДанных = "Структура" Тогда

				Результат.Вставить("Значение" + ?(НомерЗначения = 0, "", НомерЗначения), Значение);

				НомерЗначения = НомерЗначения + 1;

			Иначе

				Результат.Добавить(Значение);

			КонецЕсли;

			

		ИначеЕсли ПервыйСимвол = "}" И ТипДанных = "Структура" Тогда

			// структура закончилась

			ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			Если Лев(ТекстJSON, 1) = "," Тогда

				ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			КонецЕсли;

			

			Возврат;

			

		ИначеЕсли ПервыйСимвол = "]" И ТипДанных = "Массив" Тогда

			// массив закончился

			ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			Если Лев(ТекстJSON, 1) = "," Тогда

				ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			КонецЕсли;

			

			Возврат;

			

		Иначе

			

			Если ТипДанных = "Структура" Тогда

				//ПервыйКавычка = Ложь;

				//Если Лев(ТекстJSON, 1) = """" Тогда

				//	ПервыйКавычка = Истина;

				//КонецЕсли;

				

				Поз = Найти(ТекстJSON, ":");

				Если Поз = 0 Тогда

					// неверный формат, прервемся

					Прервать;

				КонецЕсли;

				

				//ПредпоследнийКавычка = Ложь;

				//Если Сред(ТекстJSON, Поз - 1, 1) = """" Тогда

				//	ПредпоследнийКавычка = Истина;

				//КонецЕсли;



				

				ИмяЗначения = СокрЛП(Лев(ТекстJSON, Поз - 1));

				ИмяЗначения = СтрЗаменить(ИмяЗначения, """", "");

				

				ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз+1));

								

				Если Лев(ТекстJSON, 1) = "{" Тогда

					// значение является структурой

					Значение = Новый Структура;

					ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Структура");

					

				ИначеЕсли Лев(ТекстJSON, 1) = "[" Тогда

					// значение является массивом

					Значение = Новый Массив;

					ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Массив");

					

				Иначе

					// обычное значение

					ПервыйКавычка = Ложь;

					ПредпоследнийКавычка = Ложь;

					Поз = 0;

					Для Сч = 1 По СтрДлина(ТекстJSON) Цикл

						Символ = Сред(ТекстJSON, Сч, 1);

						

						Если Символ = """" Тогда

							Если ПервыйКавычка Тогда

								ПредпоследнийКавычка = Истина;

							Иначе

								ПервыйКавычка = Истина;

							КонецЕсли;							

						КонецЕсли;

						

						Если (Символ = "," И ((ПервыйКавычка И ПредпоследнийКавычка) Или (Не ПервыйКавычка И Не ПредпоследнийКавычка))) ИЛИ Символ = "]" ИЛИ Символ = "}" Тогда

							Поз = Сч;

							Прервать;

						КонецЕсли;

					КонецЦикла;

					

					//ПредпоследнийКавычка = Ложь;

					//Если Сред(ТекстJSON, Поз - 1, 1) = """" Тогда

					//	ПредпоследнийКавычка = Истина;

					//КонецЕсли;

					

					Если Поз = 0 Тогда

						Значение = ТекстJSON;

						ТекстJSON = "";

						

					Иначе

						Значение = Лев(ТекстJSON, Поз - 1);

						Значение = СтрЗаменить(Значение, """", "");

						ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз + ?(Сред(ТекстJSON, Поз, 1) = ",", 1, 0)));						

					КонецЕсли;

					

					Значение = СокрЛП(Значение);

					

				КонецЕсли;

				

				Результат.Вставить(ИмяЗначения, Значение);

				

			ИначеЕсли ТипДанных = "Массив" Тогда

				

				// обычное значение

				Поз = 0;

				Для Сч = 1 По СтрДлина(ТекстJSON) Цикл

					Символ = Сред(ТекстJSON, Сч, 1);

					Если Символ = "," ИЛИ Символ = "]" ИЛИ Символ = "}" Тогда

						Поз = Сч;

						Прервать;

					КонецЕсли;

				КонецЦикла;

				

				//ПредпоследнийКавычка = Ложь;

				//Если Сред(ТекстJSON, Поз - 1, 1) = """" Тогда

				//	ПредпоследнийКавычка = Истина;

				//КонецЕсли;

				

				Если Поз = 0 Тогда

					Значение = ТекстJSON;

					ТекстJSON = "";

					

				Иначе

					Значение = Лев(ТекстJSON, Поз - 1);

					Значение = СтрЗаменить(Значение, """", "");

					ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз + ?(Сред(ТекстJSON, Поз, 1) = ",", 1, 0)));

					

				КонецЕсли;

				

				Значение = СокрЛП(Значение);

				

				Результат.Добавить(Значение);

				

			КонецЕсли;

				

			

		КонецЕсли;

		

	КонецЦикла;

	

КонецПроцедуры



Функция ЗаполнитьСтруктуруИзОтветаJSON(Знач ТекстJSON) Экспорт

	

	Результат = Новый Структура;

	

	ТекстJSON = СтрЗаменить(ТекстJSON, "\""", """");	// заменим последовательность \" на "

	//ТекстJSON = СтрЗаменить(ТекстJSON, """", "");		// а теперь удалим все кавычки

	

	Если Лев(ТекстJSON, 1) = "{" Тогда

		// начало структуры

		ЗаполнитьДанныеИзОтветаJSON(Результат, ТекстJSON, "Структура");

		

	ИначеЕсли Лев(ТекстJSON, 1) = "[" Тогда

		// начало массива

		МассивДанных = Новый Массив;

		ЗаполнитьДанныеИзОтветаJSON(МассивДанных, ТекстJSON, "Массив");

		

		Результат.Вставить("Значение", МассивДанных);

		

	КонецЕсли;

		

	Возврат Результат;

	

КонецФункции



Функция КодСимволаASCII(Символ) 

   КодUNICODE = КодСимвола(Символ); 

   Если ((КодUNICODE > 1039) И (КодUNICODE < 1104)) Тогда 

       Возврат (КодUNICODE - 848); 

   ИначеЕсли КодUNICODE = 8470 Тогда 

       Возврат 185; 

   ИначеЕсли КодUNICODE = 1105 Тогда 

       Возврат 184; 

   ИначеЕсли КодUNICODE = 1025 Тогда 

       Возврат 168; 

   Иначе 

       Возврат КодUNICODE; 

   КонецЕсли; 

КонецФункции



Функция URLEncode(value)



    table = "%00%01%02%03%04%05%06%07%08%09%0A%0B%0C%0D%0E%0F%10%11%12%13%14" +

            "%15%16%17%18%19%1A%1B%1C%1D%1E%1F%20%21%22%23%24%25%26%27%28" +

            "%29%2A%2B%2C%2D%2E%2F%30%31%32%33%34%35%36%37%38%39%3A%3B%3C" +

            "%3D%3E%3F%40%41%42%43%44%45%46%47%48%49%4A%4B%4C%4D%4E%4F%50" +

            "%51%52%53%54%55%56%57%58%59%5A%5B%5C%5D%5E%5F%60%61%62%63%64" +

            "%65%66%67%68%69%6A%6B%6C%6D%6E%6F%70%71%72%73%74%75%76%77%78" +

            "%79%7A%7B%7C%7D%7E%7F%80%81%82%83%84%85%86%87%88%89%8A%8B%8C" +

            "%8D%8E%8F%90%91%92%93%94%95%96%97%98%99%9A%9B%9C%9D%9E%9F%A0" +

            "%A1%A2%A3%A4%A5%A6%A7%A8%A9%AA%AB%AC%AD%AE%AF%B0%B1%B2%B3%B4" +

            "%B5%B6%B7%B8%B9%BA%BB%BC%BD%BE%BF%C0%C1%C2%C3%C4%C5%C6%C7%C8" +

            "%C9%CA%CB%CC%CD%CE%CF%D0%D1%D2%D3%D4%D5%D6%D7%D8%D9%DA%DB%DC" +

            "%DD%DE%DF%E0%E1%E2%E3%E4%E5%E6%E7%E8%E9%EA%EB%EC%ED%EE%EF%F0" +

            "%F1%F2%F3%F4%F5%F6%F7%F8%F9%FA%FB%FC%FD%FE%FF";

    

    result = "";        

            

    length = СтрДлина( value );        

    

    Для i = 1 По  length Цикл        

        symbol = Сред( value, i, 1 );        

        //code = КодСимвола( symbol );    

        code = КодСимволаASCII( symbol );

        result = result + Сред( table, code*3 + 1, 3 );        

    КонецЦикла;

    

    

    

    Возврат result;

КонецФункции

/////////////////////////РАБОТА С JSON //////////////////////////////////////////



//Функция декодирует полученный unicod текст - из ответа геокодера Рамблера

// в привычный нам

//Параметры:

// Строка

//Возвращаемое значение:

// Строка

Функция UnicodeEncode(Строка) Экспорт 

	Результат = Истина;

	

	Попытка

		//регулярное выражение

		Рег = Новый COMОбъект("VBScript.RegExp");

		Рег.IgnoreCase = Истина;

		Рег.Global = Истина;

		Рег.Multiline = Ложь;

		Рег.Pattern = "u[0-9a-f]+";

		Колекция = Рег.Execute(Строка);

		Для Каждого Элемент Из Колекция Цикл

			Если СтрДЛина(Элемент.value) = 1 Тогда

				Продолжить;

			КонецЕсли;		

			

			КодСимвола = ПереводЧислаИз16в10(Сред(ВРег(Элемент.value), 2));

			Символ = Символ(КодСимвола);

			Строка = СтрЗаменить(Строка, "\" + Элемент.value, Символ); 

		КонецЦикла;	

	Исключение

		Результат = Ложь;

		Сообщить("Ошибка преобразования из Unicode", СтатусСообщения.Информация);

	КонецПопытки;

	

	Возврат Результат;

КонецФункции



Функция ПереводЧислаИз16в10(Знач Значение)

	Результат = 0;

	

	//перевод значения в строку

	Если ТипЗнч(Значение) <> Тип("Строка") Тогда

		Значение = СокрЛП(Строка(Значение));

	КонецЕсли;

	

	МаксРазрядЦелых = 0;

	МаксРазрядЦелых = СтрДлина(Значение) - 1;

	

	н = МаксРазрядЦелых;

	Ин = 1;

	Пока н >= 0 Цикл

		ТекЗначение = СтруктураЧисел.Получить(Сред(Значение, Ин, 1)) * Pow(16, н);

		Результат = Результат + ТекЗначение;

		н = н - 1;

		Ин = Ин + 1;

	КонецЦикла;

	

	Возврат Результат;

КонецФункции



///////////////////////////

СтруктураПоставщиковКарт = Новый Соответствие;

СтруктураПоставщиковКарт.Вставить(0, "Яндекс");

СтруктураПоставщиковКарт.Вставить(1, "Гугл");

СтруктураПоставщиковКарт.Вставить(2, "2ГИС");

СтруктураПоставщиковКарт.Вставить(3, "Рамблер");





СтруктураЧисел = Новый Соответствие;

СтруктураЧисел.Вставить("0", 0);

СтруктураЧисел.Вставить("1", 1);

СтруктураЧисел.Вставить("2", 2);

СтруктураЧисел.Вставить("3", 3);

СтруктураЧисел.Вставить("4", 4);

СтруктураЧисел.Вставить("5", 5);

СтруктураЧисел.Вставить("6", 6);

СтруктураЧисел.Вставить("7", 7);

СтруктураЧисел.Вставить("8", 8);

СтруктураЧисел.Вставить("9", 9);

СтруктураЧисел.Вставить("A", 10);

СтруктураЧисел.Вставить("B", 11);

СтруктураЧисел.Вставить("C", 12);

СтруктураЧисел.Вставить("D", 13);

СтруктураЧисел.Вставить("E", 14);

СтруктураЧисел.Вставить("F", 15);

Код Формы Управляемой:

Код 1C v 8.2 УП

 



&НаКлиенте

Процедура НайтиАдрес(Команда)

	НайтиАдресНаКарте(ТекАдрес);

КонецПроцедуры



&НаКлиенте

Процедура ИнициализацияКарты(Команда)

	ИнициализироватьКарту();

КонецПроцедуры



&НаКлиенте

Процедура СправочнаяИнформация(Команда)

	Элементы.ГруппаСправка.Видимость = Не Элементы.ГруппаСправка.Видимость;

КонецПроцедуры



&НаКлиенте

Процедура Разработчик(Команда)

	ЗапуститьПриложение("http://smaylukk.com.ua/?lang=Ru");

КонецПроцедуры



&НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

	Объект.ТипКарты = Параметры.ТипКарты;

	ТекОбъект = РеквизитФормыВЗначение("Объект");

	Поставщик = ТекОбъект.СтруктураПоставщиковКарт.Получить(Объект.ТипКарты);

	

	Макет = ТекОбъект.ПолучитьМакет("Справка");

	ТекстСправки = Макет.ПолучитьОбласть("Справка" + Поставщик).Область().Текст;

	Справка = ТекстСправки;

КонецПроцедуры



&НаКлиенте

Процедура ПриОткрытии(Отказ)

	Элементы.ГруппаСправка.Видимость = Ложь;

	Заголовок = "Работа с картами. Поставщик - " + Поставщик;

	ИнициализироватьКарту();

КонецПроцедуры



&НаКлиенте

Процедура ПриЗакрытии()

	//удаление временных файлов

	Для Каждого ТекЭлемент Из МассивВременныхФайлов Цикл

		УдалитьФайлы(ТекЭлемент.Значение);

	КонецЦикла;

КонецПроцедуры



&НаКлиенте

//Процедура составляет  имя процедуры поставщика

// и запускает ее на исполнение

//Параметры:

// НачалоИмени - Строка

Процедура ВыполнитьПроцедуруПоставщика(ИмяПроцедуры)

	Выполнить ИмяПроцедуры;

КонецПроцедуры



&НаКлиенте

//процедура инициализирует карту постащика из макета

Процедура ИнициализироватьКарту()

	Текст = ПолучитьТекстМакета("Макет" + Поставщик);

	

	Эксплорер = Текст;

КонецПроцедуры



&НаСервере

Функция ПолучитьТекстМакета(ИмяМакета)

	Макет = РеквизитФормыВЗначение("Объект").ПолучитьМакет(ИмяМакета);

	Результат = Макет.ПолучитьТекст();

	Возврат Результат;

КонецФункции



&НаКлиенте

Процедура ОчисткаКарты()

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "Reset()";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



///////////////////////////////////////////////////////////////////////

///////////////////ГЕОКОДИРОВАНИЕ И ПОИСК АДРЕСА///////////////////////

///////////////////////////////////////////////////////////////////////



&НаКлиенте

Процедура НайтиАдресНаКарте(Адрес = "")	

	//поиск адреса

	Если Адрес = "" Тогда

		Адрес = "Москва";		

	КонецЕсли;

	

	// дальше пробуем с помощью геокодинга вывести данные поиска в таблицу

	ТаблицаАдресов.Очистить();

	

	ПоискАдреса(Адрес);

	Если Поставщик = "Яндекс" Тогда

		ПроизвестиГеокодинг_Яндекс();

	ИначеЕсли Поставщик = "Гугл" Тогда

		ПроизвестиГеокодинг_Гугл();

	ИначеЕсли Поставщик = "Рамблер" Тогда

		ПроизвестиГеокодинг_Рамблер();

	КонецЕсли;

КонецПроцедуры



&НаКлиенте

Процедура ПоискАдреса(Адрес)

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "FindAdres(""" + Адрес + """);";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаСервере

//Процедура выводит в таблицу данные геокдинга Яндекса

//

//Параметры:

// ТекАдрес - Строка

Процедура ПроизвестиГеокодинг_Яндекс()

	Яндекс = Новый HTTPСоединение("geocode-maps.yandex.ru");

	

	ВременныйФайл = КаталогВременныхФайлов() + "Yandex_geocode_" + СокрЛП(Новый УникальныйИдентификатор);

	Попытка

		Яндекс.Получить("/1.x/?geocode=" + ТекАдрес + "&results=10", ВременныйФайл);

	Исключение

		Сообщить("Ошибка при попытке геокодировать по яндексу адрес: " + ТекАдрес);

		Сообщить(ОписаниеОшибки());

		Возврат;

	КонецПопытки;

	

	ЧтениеXML = Новый ЧтениеXML;

	ЧтениеXML.ОткрытьФайл(ВременныйФайл);

	

	ПостроительDOM 			= Новый ПостроительDOM;

	ДокументДОМ 			= ПостроительDOM.Прочитать(ЧтениеXML);

	

	СписокText 				= ДокументДОМ.ПолучитьЭлементыПоИмени("text");

	СписокPos 				= ДокументДОМ.ПолучитьЭлементыПоИмени("pos");

		

	Если (СписокText.Количество() = 0) ИЛИ (СписокPos.Количество() = 0) Тогда

		Возврат;	

	КонецЕсли;

	

	Для ъ = 0 по СписокText.Количество()-1 Цикл

		Координаты = СписокPos[Ъ].ТекстовоеСодержимое;

		Разделитель = Найти(Координаты," ");

		Широта = Число(Сред(Координаты, Разделитель + 1));

		Долгота = Число(Лев(Координаты, Разделитель - 1));

		

		Если Широта = 0 ИЛИ Долгота = 0 Тогда

			Продолжить;

		КонецЕсли;

		

		стрАдрес = ТаблицаАдресов.Добавить();

		Если СписокText.Количество() > ъ Тогда

			стрАдрес.Адрес = СписокText[Ъ].ТекстовоеСодержимое;

			стрАдрес.Широта = Широта;

			стрАдрес.Долгота = Долгота;

		КонецЕсли;		

	КонецЦикла;	

	МассивВременныхФайлов.Добавить(ВременныйФайл);

КонецПроцедуры



&НаСервере

//Процедура выводит в таблицу данные геокдинга Гугл

//

//Параметры:

// ТекАдрес - Строка

Процедура ПроизвестиГеокодинг_Гугл()

	Гугл = Новый HTTPСоединение("maps.googleapis.com");

	

	ВременныйФайл = КаталогВременныхФайлов() + "Google_geocode_" + СокрЛП(Новый УникальныйИдентификатор);

	Попытка

		Гугл.Получить("/maps/api/geocode/xml?address=" + ТекАдрес + "&language=ru&sensor=false", ВременныйФайл);

	Исключение

		Сообщить("Ошибка при попытке геокодировать по Google адрес: " + ТекАдрес);

		Сообщить(ОписаниеОшибки());

		Возврат;

	КонецПопытки;

	

	ЧтениеXML = Новый ЧтениеXML;

	ЧтениеXML.ОткрытьФайл(ВременныйФайл);

	

	ПостроительDOM 			= Новый ПостроительDOM;

	ДокументДОМ 			= ПостроительDOM.Прочитать(ЧтениеXML);

	ТаблицаРезультатов = ДокументДОМ.ПолучитьЭлементыПоИмени("result");

	

	Если ДокументДОМ.ПолучитьЭлементыПоИмени("status")[0].ТекстовоеСодержимое <> "OK" ИЛИ ТаблицаРезультатов.Количество() = 0 Тогда 

		Возврат;

	КонецЕсли;

		

	Для ТекРезультат = 0 по ТаблицаРезультатов.Количество() -1 Цикл 

		

		СписокText 				= ТаблицаРезультатов[ТекРезультат].ПолучитьЭлементыПоИмени("formatted_address");

		ЭлементыШиротаДолгота = ТаблицаРезультатов[ТекРезультат].ПолучитьЭлементыПоИмени("location");

		Широта = ЭлементыШиротаДолгота[0].ПолучитьЭлементыПоИмени("lat")[0].ТекстовоеСодержимое;

		Долгота = ЭлементыШиротаДолгота[0].ПолучитьЭлементыПоИмени("lng")[0].ТекстовоеСодержимое;

		Если Широта = 0 ИЛИ Долгота = 0 Тогда

			Продолжить;

		КонецЕсли;

			

		стрАдрес = ТаблицаАдресов.Добавить();

		стрАдрес.Широта = Широта;

		стрАдрес.Долгота = Долгота;

		стрАдрес.Адрес = СписокText[0].ТекстовоеСодержимое;  

	КонецЦикла;

	МассивВременныхФайлов.Добавить(ВременныйФайл);

КонецПроцедуры



&НаСервере

//Процедура выводит в таблицу данные геокдинга Рамблер

//

//Параметры:

// ТекАдрес - Строка

Процедура ПроизвестиГеокодинг_Рамблер()

	ТемпАдрес = СтрЗаменить(ТекАдрес, " ", "+");

	

	Рамблер = Новый HTTPСоединение("maps.rambler.ru");	

	ВременныйФайл = КаталогВременныхФайлов() + "Рамблер_geocode_" + СокрЛП(Новый УникальныйИдентификатор);

	Попытка

		Рамблер.Получить("/search/?&a=search&q=" + ТемпАдрес + "&n=10", ВременныйФайл);

	Исключение

		Сообщить("Ошибка при попытке геокодировать по Рамблер адрес: " + ТекАдрес);

		Сообщить(ОписаниеОшибки());

		Возврат;

	КонецПопытки;

	

	а = 1;

	Т = Новый ТекстовыйДокумент;

	Т.Прочитать(ВременныйФайл);

	СтрокаОтвет = Т.ПолучитьТекст();

	Результат = РеквизитФормыВЗначение("Объект").UnicodeEncode(СтрокаОтвет);

	Если Результат Тогда

		СтруктураJSON = РеквизитФормыВЗначение("Объект").ЗаполнитьСтруктуруИзОтветаJSON(СтрокаОтвет);

	КонецЕсли;

	

	МассивРезультатов = СтруктураJSON.res;

	//обрабатываем элементы массива - только адреса. POI можно обработать отдельно пожеланию

	Для Каждого Результат Из МассивРезультатов Цикл

		Для Каждого ТекРезультат Из Результат.matches Цикл				

			стрАдрес = ТаблицаАдресов.Добавить();

			стрАдрес.Долгота = Число(ТекРезультат.x);

			стрАдрес.Широта = Число(ТекРезультат.y);

			Если Результат.type = "addr" Тогда  //Результат.type = "poi" - содержит в себе список точек интереса

				стрАдрес.Адрес = ТекРезультат.addr;

			Иначе

				стрАдрес.Адрес = ТекРезультат.name + " - " + ТекРезультат.addr;

			КонецЕсли;

		КонецЦикла;

	КонецЦикла;

	МассивВременныхФайлов.Добавить(ВременныйФайл);

КонецПроцедуры



&НаКлиенте

Процедура ОбратнПоискАдреса(Широта, Долгота, Адрес)

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "ReverseSearchAdres(" + Широта + "," + Долгота + ", """ + Адрес + """);";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

Процедура ТаблицаАдресовВыбор(Элемент, ВыбраннаяСтрока, Поле, СтандартнаяОбработка)

	Если ЗначениеЗаполнено(ТаблицаАдресов[ВыбраннаяСтрока].Широта) И ЗначениеЗаполнено(ТаблицаАдресов[ВыбраннаяСтрока].Долгота) Тогда

		СтандартнаяОбработка = Ложь;

	КонецЕсли;

	

	Широта = Формат(ТаблицаАдресов[ВыбраннаяСтрока].Широта, "ЧЦ=10; ЧДЦ=7; ЧРД=.; ЧРГ=");

	Долгота = Формат(ТаблицаАдресов[ВыбраннаяСтрока].Долгота, "ЧЦ=10; ЧДЦ=7; ЧРД=.; ЧРГ=");

	

	ОбратнПоискАдреса(Широта, Долгота, ТаблицаАдресов[ВыбраннаяСтрока].Адрес);

КонецПроцедуры



&НаКлиенте

Процедура ТекАдресПриИзменении(Элемент)

	НайтиАдресНаКарте(ТекАдрес);

КонецПроцедуры





///////////////////////////////////////////////////////////////////////

///////////////////МАРШРУТИЗАЦИЯ, КЛАСТЕРА И ПОЛИГОН///////////////////////////////////////

///////////////////////////////////////////////////////////////////////



&НаКлиенте

Процедура ЭксплорерПриНажатии(Элемент, ДанныеСобытия, СтандартнаяОбработка)

	ПолучитьКоординаты();

КонецПроцедуры



&НаКлиенте

Процедура ПостроитьМаршрут(Команда)

	Если ТаблицаТочек.Количество() <= 1 Тогда

		Предупреждение("Недостаточно точек для построение маршрута!");

		Возврат;

	КонецЕсли;

	

	Если Поставщик = "Яндекс" Тогда

		ПостроитьМаршрут_Яндекс();

	ИначеЕсли Поставщик = "Гугл" Тогда

		ПостроитьМаршрут_Гугл();

	ИначеЕсли Поставщик = "Рамблер" Тогда

		ПостроитьМаршрут_Рамблер();

	КонецЕсли;

КонецПроцедуры



&НаКлиенте

//Процедура выстраивает маршрут для Яндекса

//

//Параметры:

//

Процедура ПостроитьМаршрут_Яндекс()

	ПараметрыМаршрута = ПолучитьПараметрыМаршрутаЯндекс();

	

	ОчисткаКарты();

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "calcRoute(" + ПараметрыМаршрута + ")";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

//Функция получает массив точек, для передачи параметров в Яндекс

//

//Параметры:

//

//Возвращаемое значение:

// Строка

Функция ПолучитьПараметрыМаршрутаЯндекс()

	Результат = "";

	

	Результат = Результат + "[[" + СтрЗаменить(Строка(ТаблицаТочек[0].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[0].Долгота), ",", ".") + "],";

		

	Для Ин = 1 По ТаблицаТочек.Количество() - 2 Цикл

		Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ин].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ин].Долгота), ",", ".") + "],";

	КонецЦикла;

		

	Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Долгота), ",", ".") + "]]";

		

	Возврат Результат;

КонецФункции



&НаКлиенте

//Процедура выстраивает маршрут для Гугл

//

//Параметры:

//

Процедура ПостроитьМаршрут_Гугл()

	ПараметрыМаршрута = ПолучитьПараметрыМаршрутаГугл();

	

	ОчисткаКарты();

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "calcRoute(" + ПараметрыМаршрута + ")";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

//Функция получает массив точек, для передачи параметров в Гугл

//

//Параметры:

//

//Возвращаемое значение:

// Строка

Функция ПолучитьПараметрыМаршрутаГугл()

	Результат = "";

	ВнутрМассив = "";

	

	Результат = Результат + "[[" + СтрЗаменить(Строка(ТаблицаТочек[0].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[0].Долгота), ",", ".") + "],";

	

	Если ТаблицаТочек.Количество() = 2 Тогда

		Результат = Результат + "[],"; 

	Иначе

		Для Ин = 1 По ТаблицаТочек.Количество() - 2 Цикл

			ВнутрМассив = ВнутрМассив + "[" + СтрЗаменить(Строка(ТаблицаТочек[ин].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ин].Долгота), ",", ".") + "],";

		КонецЦикла;

		Результат = Результат + "[" + Сред(ВнутрМассив, 1, СтрДлина(ВнутрМассив) - 1) + "],";

	КонецЕсли;

	

	Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Долгота), ",", ".") + "]]";

		

	Возврат Результат;

КонецФункции



&НаКлиенте

//Процедура выстраивает маршрут для Рамблера

//

//Параметры:

//

Процедура ПостроитьМаршрут_Рамблер()

	ПараметрыМаршрута = ПолучитьПараметрыМаршрутаРамблер();

	

	ОчисткаКарты();

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "calcRoute(" + ПараметрыМаршрута + ")";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

//Функция получает массив точек, для передачи параметров в Рамблер

//

//Параметры:

//

//Возвращаемое значение:

// Строка

Функция ПолучитьПараметрыМаршрутаРамблер()

	Результат = "";

	

	Результат = Результат + "[[" + СтрЗаменить(Строка(ТаблицаТочек[0].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[0].Долгота), ",", ".") + "],";

		

	Для Ин = 1 По ТаблицаТочек.Количество() - 2 Цикл

		Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ин].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ин].Долгота), ",", ".") + "],";

	КонецЦикла;

		

	Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Долгота), ",", ".") + "]]";

		

	Возврат Результат;

КонецФункции



&НаКлиенте

Процедура СоздатьКластер(Команда)

	Если ТаблицаТочек.Количество() <= 1 Тогда

		Предупреждение("Недостаточно точек для построение кластера!");

		Возврат;

	КонецЕсли;

	

	ОчисткаКарты();

	

	ПостроитьКластера();

КонецПроцедуры



&НаКлиенте

Процедура ПостроитьКластера()

	Кол = ТаблицаТочек.Количество();

	Индекс = 1;

	Для Каждого ТекСтрока Из ТаблицаТочек Цикл

		Широта = формат(ТекСтрока.Широта, "ЧРД=.");

		Долгота = формат(ТекСтрока.Долгота, "ЧРД=.");

		СодержимоеТочки = "Содерижмое точки";  //опять же можно вставить свое название

		Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "addToPointArray(" + Широта + "," + Долгота + ", '" + ТекСтрока.Точка + "', """ + СодержимоеТочки + """);";

		Элементы.Эксплорер.document.getElementById("WebClient").click();

		

		Состояние("Обработан " + Индекс + " из " + кол);

		Индекс = Индекс + 1;

	КонецЦикла;

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "drawCluster();";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

Процедура ОчиститьВсе(Команда)

	ОчисткаКарты();

	ТаблицаТочек.Очистить();

КонецПроцедуры



&НаКлиенте

Процедура ОчиститьКарту(Команда)

	ОчисткаКарты();

КонецПроцедуры



&НаКлиенте

Процедура ОчиститьТаблицу(Команда)

	ТаблицаТочек.Очистить();

КонецПроцедуры



&НаКлиенте

//Процедура получает координаты установленной точки

Процедура ПолучитьКоординаты()

	Попытка

		ЧислоТип = Новый ОписаниеТипов("Число", Новый КвалификаторыЧисла(15, 12));

		

		КоординатаX = Элементы.Эксплорер.document.getElementById("CoordX").value;

		КоординатаX = ЧислоТип.ПривестиЗначение(КоординатаX);

		

		КоординатаY = Элементы.Эксплорер.document.getElementById("CoordY").value;

		КоординатаY = ЧислоТип.ПривестиЗначение(КоординатаY);

		

		Кол = ТаблицаТочек.Количество();

		Если КоординатаX > 0 И КоординатаY > 0 И (Кол = 0 Или КоординатаX <> ТаблицаТочек[Кол - 1].Широта И КоординатаY <> ТаблицаТочек[Кол - 1].Долгота) Тогда

			НоваяСтрока = ТаблицаТочек.Добавить();

			НоваяСтрока.Точка = "Точка" + ТаблицаТочек.Количество();

			НоваяСтрока.Широта = КоординатаX;

			НоваяСтрока.Долгота = КоординатаY;

		КонецЕсли;

	Исключение

	КонецПопытки;

КонецПроцедуры



&НаКлиенте

Процедура ПострениеПолигона(Команда)

	Если ТаблицаТочек.Количество() <= 1 Тогда

		Предупреждение("Недостаточно точек для построение полигона!");

		Возврат;

	КонецЕсли;

	

	ОчисткаКарты();

	

	ПостроитьПолигон();

КонецПроцедуры



&НаКлиенте

//Процедура выстраивает маршрут для Рамблера

//

//Параметры:

//

Процедура ПостроитьПолигон()

	МассивТочек = "[";

	Для Каждого ТекТочка Из ТаблицаТочек Цикл

		Широта = формат(ТекТочка.Широта, "ЧРД=.");

		Долгота = формат(ТекТочка.Долгота, "ЧРД=.");

		МассивТочек = МассивТочек + "[" + Широта + "," + Долгота + "],"; 

	КонецЦикла;

	МассивТочек = Сред(МассивТочек, 1, СтрДлина(МассивТочек) - 1) + "]";

	

	Цвет16 = Получить16Цвет();

	

	Название = "Полигон";//вставить свое 

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "createPolygon(" + МассивТочек + ", '" + Название + "', '" + Цвет16 + "');";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаСервере

//Функция возвращает значение случайного цвета в 16-ричном формате

//

//Параметры:

//  нет

//Возвращаемое значение:

//  Строка

Функция Получить16Цвет()

	Результат = "";

	

	Строка16 = "0123456789ABCDEF";

	ГСЧ = Новый ГенераторСлучайныхЧисел;

	Результат = "#";

	Для н = 1 По 6 Цикл

		м = ГСЧ.СлучайноеЧисло(1, 16);

		Результат = Результат + Сред(Строка16, м, 1);

	КонецЦикла;

	

	Возврат Результат;

КонецФункции

Категория: COM-объекты, WMI, WSH

Параметры виртуальных таблиц Категория: Запросы

Внешние обработки, печатные формы, обработки по заполнению табличных частей Категория: Внешние печатные формы, отчеты и обработк�…

Построение диаграммы

Код 1C v 8.х

 Процедура ФормДиаграммы()

           Траб=Новый ТаблицаЗначений;

           Траб.Очистить();

           Траб.Колонки.Добавить("ххх");

           Траб.Колонки.Добавить("Норм");

           Траб.Колонки.Добавить("Факт");

          

           НовСтр=Траб.Добавить();

           НовСтр.ххх="а1";

           НовСтр.Норм=5;

           НовСтр.Факт=10;

           НовСтр=Траб.Добавить();

           НовСтр.ххх="а2";

           НовСтр.Норм=2;

           НовСтр.Факт=15;

           НовСтр=Траб.Добавить();

           НовСтр.ххх="а3";

           НовСтр.Норм=8;

           НовСтр.Факт=14;

                                     

           ТабДок = Новый ТабличныйДокумент;

           Макет = Отчеты.УчетнаяКарточка.ПолучитьМакет("Диагр");

          

           ОблДиаграмма = Макет.ПолучитьОбласть("Диагр1");

           Диаграмма = ОблДиаграмма.Рисунки.D1.Объект;

          

           Диаграмма.СерииВСтроках = Ложь;

           Диаграмма.Обновление=Ложь;

          

           Диаграмма.ИсточникДанных = Траб;

          

           Диаграмма.Обновление=Истина;

           ТабДок.Вывести(ОблДиаграмма);

          

           ТабДок.АвтоМасштаб=Истина;

           ТабДок.ОриентацияСтраницы=ОриентацияСтраницы.Ландшафт;

           ТабДок.Показать();

КонецПроцедуры

Полезная процедура формирования диаграммы в макете
Строить можно и в макете и в форме.

Код 1C v 8.х

 

Процедура ПостроитьДиаграмму(Траб,Диаграмма)



Для Каждого Колонка из Траб.Колонки Цикл

 Если Траб.Колонки.Индекс(Колонка) <> 0 Тогда

  Диаграмма.Серии.Добавить(Колонка.Имя);

 КонецЕсли;

КонецЦикла;



Для Каждого СтрТраб из Траб Цикл

 Точка=Диаграмма.Точки.Добавить(СтрТраб.Получить(0));

 Индекс=0;

 Для Каждого Серия из Диаграмма.Серии Цикл

  Индекс=Индекс+1;

  Диаграмма.УстановитьЗначение(Точка,Серия,СтрТраб.Получить(Индекс));

 КонецЦикла;

КонецЦикла;

КонецПроцедуры

gwa. Григорьев В.

Категория: Диаграмма