helpf.pro
  Регистрация
Все категории » Прочие вопросы Прочие вопросы 
 +10 
 
 
Распечатать

Универсальный отчет в прикладных решениях фирмы 1С

Как настроить Универсальный отчет?
Все настройки универсального отчета описываются в процедуре УстановитьНачальныеНастройки:
Код 1C v 8.х
 Процедура УстановитьНачальныеНастройки(ДополнительныеПараметры = Неопределено) Экспорт

	

	// Настройка общих параметров универсального отчета

	

           //начальный вариант оформления цветовой схемы

            УниверсальныйОтчет.ВариантОформления = СтандартноеОформление.Песок;



	// Содержит название отчета, которое будет выводиться в шапке.

	// Тип: Строка.

	// Пример:

	// УниверсальныйОтчет.мНазваниеОтчета = "Название отчета";

	УниверсальныйОтчет.мНазваниеОтчета = СокрЛП(ЭтотОбъект.Метаданные().Синоним);

	

	// Содержит признак необходимости отображения надписи и поля выбора раздела учета в форме настройки.

	// Тип: Булево.

	// Значение по умолчанию: Истина.

	// Пример:

	// УниверсальныйОтчет.мВыбиратьИмяРегистра = Ложь;

	УниверсальныйОтчет.мВыбиратьИмяРегистра = Ложь;

	

	// Содержит имя регистра, по метаданным которого будет выполняться заполнение настроек отчета.

	// Тип: Строка.

	// Пример:

	// УниверсальныйОтчет.ИмяРегистра = "ТоварыНаСкладах";

	УниверсальныйОтчет.ИмяРегистра = "-";

	

	// Содержит признак необходимости вывода отрицательных значений показателей красным цветом.

	// Тип: Булево.

	// Значение по умолчанию: Ложь.

	// Пример:

	// УниверсальныйОтчет.ОтрицательноеКрасным = Истина;

	УниверсальныйОтчет.ОтрицательноеКрасным = Истина;

	

	// Содержит признак необходимости вывода в отчет общих итогов.

	// Тип: Булево.

	// Значение по умолчанию: Истина.

	// Пример:

	// УниверсальныйОтчет.ВыводитьОбщиеИтоги = Ложь;

	УниверсальныйОтчет.ВыводитьОбщиеИтоги = Истина;

	

	// Содержит признак необходимости вывода детальных записей в отчет.

	// Тип: Булево.

	// Значение по умолчанию: Ложь.

	// Пример:

	// УниверсальныйОтчет.ВыводитьДетальныеЗаписи = Истина;

	УниверсальныйОтчет.ВыводитьДетальныеЗаписи = Ложь;

	

	// Содержит признак необходимости отображения флага использования свойств и категорий в форме настройки.

	// Тип: Булево.

	// Значение по умолчанию: Истина.

	// Пример:

	// УниверсальныйОтчет.мВыбиратьИспользованиеСвойств = Ложь;

	УниверсальныйОтчет.мВыбиратьИспользованиеСвойств = Истина;

	

	// Содержит признак использования свойств и категорий при заполнении настроек отчета.

	// Тип: Булево.

	// Значение по умолчанию: Ложь.

	// Пример:

	// УниверсальныйОтчет.ИспользоватьСвойстваИКатегории = Истина;

	//УниверсальныйОтчет.ИспользоватьСвойстваИКатегории = ЛОЖЬ;

	

	// Содержит признак использования простой формы настроек отчета без группировок колонок.

	// Тип: Булево.

	// Значение по умолчанию: Ложь.

	// Пример:

	// УниверсальныйОтчет.мРежимФормыНастройкиБезГруппировокКолонок = Истина;

	

	// Дополнительные параметры, переданные из отчета, вызвавшего расшифровку.

	// Информация, передаваемая в переменной ДополнительныеПараметры, может быть использована

	// для реализации специфичных для данного отчета параметрических настроек.

	

	// Описание исходного текста запроса.

	

		ТекстЗапроса = "ВЫБРАТЬ РАЗРЕШЕННЫЕ

		               |	CRM_ПредложенияОбороты.Номенклатура КАК Номенклатура,

			    	   |	ПРЕДСТАВЛЕНИЕ(CRM_ПредложенияОбороты.Номенклатура) КАК НоменклатураПредставление,							   

		               |	CRM_ПредложенияОбороты.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,

			    	   |	ПРЕДСТАВЛЕНИЕ(CRM_ПредложенияОбороты.ХарактеристикаНоменклатуры) КАК ХарактеристикаНоменклатурыПредставление,							   					   

					   |	CRM_ПредложенияОбороты.Контрагент КАК Контрагент,

			    	   |	ПРЕДСТАВЛЕНИЕ(CRM_ПредложенияОбороты.Контрагент) КАК КонтрагентПредставление,							   

		               |	CRM_ПредложенияОбороты.ДокументПредложения КАК Документ,

			    	   |	ПРЕДСТАВЛЕНИЕ(CRM_ПредложенияОбороты.ДокументПредложения) КАК ДокументПредставление,							   

		               |	CRM_ПредложенияОбороты.ДокументПредложения.Ответственный КАК Ответственный,

			    	   |	ПРЕДСТАВЛЕНИЕ(CRM_ПредложенияОбороты.ДокументПредложения.Ответственный) КАК ОтветственныйПредставление,							   

		               |	CRM_ПредложенияОбороты.КоличествоОборот КАК КоличествоОборот,

		               |	CRM_ПредложенияОбороты.СтоимостьОборот КАК СтоимостьОборот,

		               |	0 КАК СкидкаОборот,

		               |	1 КАК Количество,

					   |	CRM_ПредложенияОбороты.СтоимостьБезСкидокОборот КАК СтоимостьБезСкидокОборот

					   |	//ПОЛЯ_СВОЙСТВА

					   |	//ПОЛЯ_КАТЕГОРИИ					   

					   |{ВЫБРАТЬ

		               |	Контрагент.*,

		               |	Номенклатура.*,

		               |	ХарактеристикаНоменклатуры.*,

		               |	Ответственный.*,

		               |	Документ.*, 

		               |	КоличествоОборот, 

		               |	СтоимостьОборот, 

		               |	СкидкаОборот, 

		               |	Количество,

					   |	(ЕСТЬNULL(ИсточникиИнформацииПриОбращении.ИсточникИнформации,ЗНАЧЕНИЕ(Справочник.ИсточникиИнформацииПриОбращенииПокупателей.ПустаяСсылка))).* КАК ИсточникИнформации

					   |	//ПСЕВДОНИМЫ_СВОЙСТВА

					   |	//ПСЕВДОНИМЫ_КАТЕГОРИИ

					   |}

		               |ИЗ

		               |	РегистрНакопления.CRM_Предложения.Обороты(&ДатаНач, &ДатаКон, , ) КАК CRM_ПредложенияОбороты					   

					   |{ЛЕВОЕ СОЕДИНЕНИЕ	РегистрСведений.ИсточникИнформацииПриОбращении.СрезПоследних(&ДатаКон) КАК ИсточникиИнформацииПриОбращении		

					   |ПО CRM_ПредложенияОбороты.Контрагент = ИсточникиИнформацииПриОбращении.Контрагент}

					   |//СОЕДИНЕНИЯ

		               |{ГДЕ

		               |	CRM_ПредложенияОбороты.Контрагент.* КАК Контрагент,

		               |	CRM_ПредложенияОбороты.Номенклатура.* КАК Номенклатура,

		               |	CRM_ПредложенияОбороты.ХарактеристикаНоменклатуры.* КАК ХарактеристикаНоменклатуры,

		               |	CRM_ПредложенияОбороты.ДокументПредложения.Ответственный.* КАК Ответственный,

		               |	CRM_ПредложенияОбороты.ДокументПредложения.* КАК Документ,

					   |	(ЕСТЬNULL(ИсточникиИнформацииПриОбращении.ИсточникИнформации,ЗНАЧЕНИЕ(Справочник.ИсточникиИнформацииПриОбращенииПокупателей.ПустаяСсылка))).* КАК ИсточникИнформации					   

					   |	//УСЛОВИЯ_СВОЙСТВА

					   |	//УСЛОВИЯ_КАТЕГОРИИ

					   |}

		               |{УПОРЯДОЧИТЬ ПО

	        	       |	Контрагент.*,

		               |	Номенклатура.*,

		               |	ХарактеристикаНоменклатуры.*,

		               |	Ответственный.*,

		               |	Документ.*,

					   |	(ЕСТЬNULL(ИсточникиИнформацииПриОбращении.ИсточникИнформации,ЗНАЧЕНИЕ(Справочник.ИсточникиИнформацииПриОбращенииПокупателей.ПустаяСсылка))).* КАК ИсточникИнформации

					   |	//ПСЕВДОНИМЫ_СВОЙСТВА

					   |	//ПСЕВДОНИМЫ_КАТЕГОРИИ

					   |}

		               |

					   |ИТОГИ

		               |	СУММА(КоличествоОборот),

		               |	СУММА(СтоимостьОборот),

		               |	СУММА(СтоимостьБезСкидокОборот - СтоимостьОборот) КАК СкидкаОборот,

		               |	КОЛИЧЕСТВО(РАЗЛИЧНЫЕ(Документ)) КАК Количество

		               |ПО

		               |	ОБЩИЕ

		               |{ИТОГИ ПО

       			       |	Контрагент.*,

		               |	Номенклатура.*,

		               |	ХарактеристикаНоменклатуры.*,

		               |	Ответственный.*,

		               |	Документ.*, 

					   |	(ЕСТЬNULL(ИсточникиИнформацииПриОбращении.ИсточникИнформации,ЗНАЧЕНИЕ(Справочник.ИсточникиИнформацииПриОбращенииПокупателей.ПустаяСсылка))).* КАК ИсточникИнформации,

		               |	НАЧАЛОПЕРИОДА(CRM_ПредложенияОбороты.ДокументПредложения.Дата, ДЕНЬ) КАК ПериодДень,

		               |	НАЧАЛОПЕРИОДА(CRM_ПредложенияОбороты.ДокументПредложения.Дата, НЕДЕЛЯ) КАК ПериодНеделя,

		               |	НАЧАЛОПЕРИОДА(CRM_ПредложенияОбороты.ДокументПредложения.Дата, МЕСЯЦ) КАК ПериодМесяц,

		               |	НАЧАЛОПЕРИОДА(CRM_ПредложенияОбороты.ДокументПредложения.Дата, КВАРТАЛ) КАК ПериодКвартал,

		               |	НАЧАЛОПЕРИОДА(CRM_ПредложенияОбороты.ДокументПредложения.Дата, ГОД) КАК ПериодГод

					   |	//ПСЕВДОНИМЫ_СВОЙСТВА

					   |	//ПСЕВДОНИМЫ_КАТЕГОРИИ

					   |}";

	

	

	

	// В универсальном отчете включен флаг использования свойств и категорий.

	Если УниверсальныйОтчет.ИспользоватьСвойстваИКатегории Тогда

		

		// Добавление свойств и категорий поля запроса в таблицу полей.

		// Необходимо вызывать для каждого поля запроса, предоставляющего возможность использования свойств и категорий.

		

		// УниверсальныйОтчет.ДобавитьСвойстваИКатегорииДляПоля(<ПсевдонимТаблицы>.<Поле> , <ПсевдонимПоля>, <Представление>, <Назначение>);

		УниверсальныйОтчет.ДобавитьСвойстваИКатегорииДляПоля("CRM_ПредложенияОбороты.Номенклатура" , "Номенклатура", "Номенклатура", ПланыВидовХарактеристик.НазначенияСвойствКатегорийОбъектов.Справочник_Номенклатура);

		УниверсальныйОтчет.ДобавитьСвойстваИКатегорииДляПоля("CRM_ПредложенияОбороты.ХарактеристикаНоменклатуры" , "ХарактеристикаНоменклатуры", "Характеристика номенклатуры", ПланыВидовХарактеристик.НазначенияСвойствКатегорийОбъектов.Справочник_Номенклатура);

		УниверсальныйОтчет.ДобавитьСвойстваИКатегорииДляПоля("CRM_ПредложенияОбороты.Контрагент" , "Контрагент", "Контрагент", ПланыВидовХарактеристик.НазначенияСвойствКатегорийОбъектов.Справочник_Номенклатура);

		УниверсальныйОтчет.ДобавитьСвойстваИКатегорииДляПоля("CRM_ПредложенияОбороты.ДокументПредложения" , "Документ", "Коммерческое предложение", ПланыВидовХарактеристик.НазначенияСвойствКатегорийОбъектов.Документ_CRM_КоммерческоеПредложение);

		

		// Добавление свойств и категорий в исходный текст запроса.

		УниверсальныйОтчет.ДобавитьВТекстЗапросаСвойстваИКатегории(ТекстЗапроса);

		

	КонецЕсли;

		

	// Инициализация текста запроса построителя отчета

	УниверсальныйОтчет.ПостроительОтчета.Текст = ТекстЗапроса;

	

	// Представления полей отчета.

	// Необходимо вызывать для каждого поля запроса.

	// УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить(<ИмяПоля>, <ПредставлениеПоля>);

	

	УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("ХарактеристикаНоменклатуры", "Характеристика номенклатуры");

	УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("Документ", "Коммерческое предложение");

	УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("ИсточникИнформации", "Источник информации при обращении покупателя");

	                                                           

	// Добавление показателей

	// Необходимо вызывать для каждого добавляемого показателя.

	// УниверсальныйОтчет.ДобавитьПоказатель(<ИмяПоказателя>, <ПредставлениеПоказателя>, <ВключенПоУмолчанию>, <Формат>, <ИмяГруппы>, <ПредставлениеГруппы>);

	

	//УниверсальныйОтчет.ДобавитьПоказатель("Задача", "Задача", Истина,);

	УниверсальныйОтчет.ДобавитьПоказатель("Количество", "Количество документов", Истина, "ЧЦ = 15 ; ЧДЦ = 3");

	УниверсальныйОтчет.ДобавитьПоказатель("КоличествоОборот", "Количество номенклатуры", Истина, "ЧЦ = 15 ; ЧДЦ = 3",,);

	УниверсальныйОтчет.ДобавитьПоказатель("СтоимостьОборот", "Сумма", Истина, "ЧЦ = 15 ; ЧДЦ = 2");

	УниверсальныйОтчет.ДобавитьПоказатель("СкидкаОборот", "Скидка", Истина, "ЧЦ = 15 ; ЧДЦ = 2",,);

	

	// Добавление предопределенных группировок строк отчета.

	// Необходимо вызывать для каждой добавляемой группировки строки.

	// УниверсальныйОтчет.ДобавитьИзмерениеСтроки(<ПутьКДанным>);

	УниверсальныйОтчет.ДобавитьИзмерениеСтроки("Контрагент");

	УниверсальныйОтчет.ДобавитьИзмерениеСтроки("Номенклатура");

	

	// Добавление предопределенных группировок колонок отчета.

	// Необходимо вызывать для каждой добавляемой группировки колонки.

	// УниверсальныйОтчет.ДобавитьИзмерениеКолонки(<ПутьКДанным>);

	

	// Добавление предопределенных отборов отчета.

	// Необходимо вызывать для каждого добавляемого отбора.

	// УниверсальныйОтчет.ДобавитьОтбор(<ПутьКДанным>);

	УниверсальныйОтчет.ДобавитьОтбор("Контрагент");

	УниверсальныйОтчет.ДобавитьОтбор("Номенклатура");

	УниверсальныйОтчет.ДобавитьОтбор("Ответственный");

	УниверсальныйОтчет.ДобавитьОтбор("Документ");

	

	// Добавление предопределенных полей порядка отчета.

	// Необходимо вызывать для каждого добавляемого поля порядка.

	// УниверсальныйОтчет.ДобавитьПорядок(<ПутьКДанным>);

	

	// Установка связи подчиненных и родительских полей

	// УниверсальныйОтчет.УстановитьСвязьПолей(<ПутьКДанным>, <ПутьКДаннымРодитель>);

	//УниверсальныйОтчет.УстановитьСвязьПолей("ТочкаМаршрута","Задача");

	

	

	// Установка связи полей и измерений

	// УниверсальныйОтчет.УстановитьСвязьПоляИИзмерения(<ИмяПоля>, <ИмяИзмерения>);

	



	// Установка представлений полей

	УниверсальныйОтчет.УстановитьПредставленияПолей(УниверсальныйОтчет.мСтруктураПредставлениеПолей, УниверсальныйОтчет.ПостроительОтчета);

	

	// Установка типов значений свойств в отборах отчета

	УниверсальныйОтчет.УстановитьТипыЗначенийСвойствДляОтбора();

	

	// Заполнение начальных настроек универсального отчета

	УниверсальныйОтчет.УстановитьНачальныеНастройки(Ложь);

	

	// Добавление предопределенных отборов отчета.

	// Необходимо вызывать для каждого добавляемого отбора.

	// УниверсальныйОтчет.ДобавитьОтбор(<ПутьКДанным>);

	УниверсальныйОтчет.ДобавитьОтбор("Контрагент");

	УниверсальныйОтчет.ДобавитьОтбор("Номенклатура");

	УниверсальныйОтчет.ДобавитьОтбор("Ответственный");

	УниверсальныйОтчет.ДобавитьОтбор("Документ");



	

	// Добавление дополнительных полей

	// Необходимо вызывать для каждого добавляемого дополнительного поля.

	// УниверсальныйОтчет.ДобавитьДополнительноеПоле(<ПутьКДанным>, <Размещение>, <Положение>);

	

      	УниверсальныйОтчет.мСтруктураФорматаПолей.Вставить("ДатаВыполнения", "ДЛФ=DDT");

	УниверсальныйОтчет.мСтруктураФорматаПолей.Вставить("ДатаФактическогоВыполнения", "ДЛФ=DDT");

	УниверсальныйОтчет.мМинимальнаяШиринаКолонкиПоказатель = 10;

	УниверсальныйОтчет.мМаксимальнаяШиринаКолонки = 80;



КонецПроцедуры // УстановитьНачальныеНастройки()


Как настроить условное оформление в Универсальном отчете?
Выравнивание значений влево:
Код 1C v 8.х
 ЭлементОформления = УниверсальныйОтчет.ПостроительОтчета.УсловноеОформление.Добавить("Номенклатура", "Номенклатура");

	ЭлементОформления.Область.Добавить("Номенклатура", "Номенклатура", ТипОбластиОформления.Поле);

	ЭлементОформления.Оформление.ГоризонтальноеПоложение.Значение = ГоризонтальноеПоложение.Лево;

	ЭлементОформления.Оформление.ГоризонтальноеПоложение.Использование = Истина;

	ЭлементОформления.Использование = Истина;

	

	ЭлементОформления = УниверсальныйОтчет.ПостроительОтчета.УсловноеОформление.Добавить("ХарактеристикаНоменклатуры", "ХарактеристикаНоменклатуры");

	ЭлементОформления.Область.Добавить("ХарактеристикаНоменклатуры", "ХарактеристикаНоменклатуры", ТипОбластиОформления.Поле);

	ЭлементОформления.Оформление.ГоризонтальноеПоложение.Значение = ГоризонтальноеПоложение.Лево;

	ЭлементОформления.Оформление.ГоризонтальноеПоложение.Использование = Истина;

	ЭлементОформления.Использование = Истина;  

	

	УниверсальныйОтчет.мМинимальнаяШиринаКолонкиПоказатель = 7;

	УниверсальныйОтчет.мМаксимальнаяШиринаКолонки = 50;

Изменение цвета текста и т.д.
Код 1C v 8.х
 // Условное оформление поля "Состояние"

	ЭлементОформления = УниверсальныйОтчет.ПостроительОтчета.УсловноеОформление.Добавить("ТребуетсяЗаказать", "Требуется заказать");

	

	ЭлементОформления.Область.Добавить("Состояние", "Состояние", ТипОбластиОформления.Поле);

	ЭлементОтбора = ЭлементОформления.Отбор.Добавить("Состояние");

	ЭлементОтбора.ВидСравнения = ВидСравнения.Равно;

	ЭлементОтбора.Значение = 0;

	ЭлементОтбора.Использование = Истина;

	ЭлементОформления.Оформление.ЦветТекста.Значение = WebЦвета.Красный;

	ЭлементОформления.Оформление.ЦветТекста.Использование = Истина;

	ЭлементОформления.Оформление.Текст.Значение = "Требуется заказать";

	ЭлементОформления.Оформление.Текст.Использование = Истина;

	

	ЭлементОформления.Использование = Истина;

	

	ЭлементОформления = УниверсальныйОтчет.ПостроительОтчета.УсловноеОформление.Добавить("РекомендуетсяЗаказать", "Рекомендуется заказать");

	

	ЭлементОформления.Область.Добавить("Состояние", "Состояние", ТипОбластиОформления.Поле);

	ЭлементОтбора = ЭлементОформления.Отбор.Добавить("Состояние");

	ЭлементОтбора.ВидСравнения = ВидСравнения.Равно;

	ЭлементОтбора.Значение = 1;

	ЭлементОтбора.Использование = Истина;

	ЭлементОформления.Оформление.ЦветТекста.Значение = WebЦвета.Коричневый;

	ЭлементОформления.Оформление.ЦветТекста.Использование = Истина;

	ЭлементОформления.Оформление.Текст.Значение = "Рекомендуется заказать";

	ЭлементОформления.Оформление.Текст.Использование = Истина;	

	ЭлементОформления.Использование = Истина;

	

	ЭлементОформления = УниверсальныйОтчет.ПостроительОтчета.УсловноеОформление.Добавить("НеТребуетсяЗаказывать", "Не требуется заказывать");

	

	ЭлементОформления.Область.Добавить("Состояние", "Состояние", ТипОбластиОформления.Поле);

	ЭлементОтбора = ЭлементОформления.Отбор.Добавить("Состояние");

	ЭлементОтбора.ВидСравнения = ВидСравнения.Равно;

	ЭлементОтбора.Значение = 2;

	ЭлементОтбора.Использование = Истина;

	ЭлементОформления.Оформление.ЦветТекста.Значение = WebЦвета.Зеленый;

	ЭлементОформления.Оформление.ЦветТекста.Использование = Истина;

	ЭлементОформления.Оформление.Текст.Значение = "Не требуется заказывать";

	ЭлементОформления.Оформление.Текст.Использование = Истина;	

	ЭлементОформления.Использование = Истина;



	ЭлементОформления = УниверсальныйОтчет.ПостроительОтчета.УсловноеОформление.Добавить("ЗонаПоСумме", "Зона По Сумме");

	ЭлементОформления.Область.Добавить("ЗонаПоСумме", "ЗонаПоСумме", ТипОбластиОформления.Поле);

	ЭлементОтбора = ЭлементОформления.Отбор.Добавить("ЗонаПоСумме");

	ЭлементОтбора.ВидСравнения = ВидСравнения.Равно;

	ЭлементОтбора.Значение = "крас";

	ЭлементОтбора.Использование = Истина;

	ЭлементОформления.Оформление.ЦветФона.Значение = WebЦвета.Красный;

	ЭлементОформления.Оформление.ЦветФона.Использование = Истина;

	ЭлементОформления.Оформление.Текст.Значение = "";

	ЭлементОформления.Оформление.Текст.Использование = Истина;

	ЭлементОформления.Использование = Истина;

	ЭлементОформления = УниверсальныйОтчет.ПостроительОтчета.УсловноеОформление.Добавить("ЗонаПоСумме", "Зона По Сумме");

	ЭлементОформления.Область.Добавить("ЗонаПоСумме", "ЗонаПоСумме", ТипОбластиОформления.Поле);

	ЭлементОтбора = ЭлементОформления.Отбор.Добавить("ЗонаПоСумме");

	ЭлементОтбора.ВидСравнения = ВидСравнения.Равно;

	ЭлементОтбора.Значение = "зелн";

	ЭлементОтбора.Использование = Истина;

	ЭлементОформления.Оформление.ЦветТекста.Значение = WebЦвета.Зеленый;

	ЭлементОформления.Оформление.ЦветТекста.Использование = Истина;

	ЭлементОформления.Оформление.Шрифт.Значение = Новый Шрифт(,,Истина);

	ЭлементОформления.Оформление.Шрифт.Использование = Истина;

	ЭлементОформления.Оформление.Текст.Значение = "|||||||||||||||||";

	ЭлементОформления.Оформление.Текст.Использование = Истина;

	ЭлементОформления.Использование = Истина;

Для типа «Дата»:
Код 1C v 8.х
 ЭлементОформления = УниверсальныйОтчет.ПостроительОтчета.УсловноеОформление.Добавить("ДатаЗаписи", "Дата записи");

ЭлементОформления.Область.Добавить("ДатаЗаписи", "Дата записи", ТипОбластиОформления.Поле);

ЭлементОформления.Оформление.Формат.Значение = "ДФ=dd.MM.yyyy";

ЭлементОформления.Оформление.Формат.Использование = Истина;

ЭлементОформления.Использование = Истина;

Для типа «Булево»:
Код 1C v 8.х
 ЭлементОформления = УниверсальныйОтчет.ПостроительОтчета.УсловноеОформление.Добавить("Печать", "Печать");

ЭлементОформления.Область.Добавить("Печать", "Печать", ТипОбластиОформления.Поле);

ЭлементОформления.Оформление.ГоризонтальноеПоложение.Значение = ГоризонтальноеПоложение.Центр;

ЭлементОформления.Оформление.Формат.Значение  =  «БЛ=Нет; БИ=Напечатан»;

ЭлементОформления.Оформление.ГоризонтальноеПоложение.Использование = Истина;

ЭлементОформления.Использование = Истина;
Разместил:   Версии: | 8.x |  Дата:   Прочитано: 62995
 +10 
 
 
Распечатать
Возможно, вас также заинтересует
17 правил для составления оптимального ЗАПРОСа к данным базы 1С  50
  Для формирования и выполнения запросов к таблицам базы данных в платформе 1С используется специальный объект языка программирования Запрос . Создается этот объект вызовом конструкции Новый Запрос . Запрос удобно использовать, когда требуется получ
Excel файл как Внешний источник данных  16
 Подключимся и загрузим из файла Excel данные в таблицу значений 1С. Сделать теперь это очень просто. 1. В конфигурации добавляет новый объект метаданных типа " Внешние источники данных" и назовем его просто " Excel" . https://helpf.pro/uploads/img
PostgreSQL: установка, настройка, обслуживание  11
  PostgreSQL напрямую "из коробки" применяться для использования с 1С Предприятем не может. Необходима именно адаптированная версия от 1С, превращающая PostgreSQL в блокировочник, причем нужно понимать, что блокировки будут накладываться на всю таблиц
Автоматизация обмена данных используя обработку "Универсальный обмен данными в формате XML"  10
  Автоматизация обмена между базами используя обработку " Универсальный обмен данными в формате XML" В основу данной публикации положены найденные мною материалы по cозданию обмена между двумя базами с использованием обработки " Универсальный обме
Автоматическая архивация баз 1С с использованием Cobian Backup и VBS скриптов  8
  Клиент попросил настроить автоматическую архивацию баз 1С раз в три дня и выгрузку архивов на Dropbox и на FTP Сервер. Кроме 1С нужно архивировать папку с рабочими документами. Хочет - так хочет, делаем: Первым делом настроим автоматическую архивац
Посмотреть все результаты поиска похожих
Комментарии
andogskiy
22.11.2016 12:52Комментарий: 14
andogskiy

В типовом отчете Продажи в УТ 10.3 нужно сделать группировку по основному менеджеру покупателя и установить представление этого поля "Менеджер". С группировкой я разобрался. Никак не могу изменить представление. Не подскажете, как можно программно изменить представление поля? Или подскажите другой способ решения этой задачи?

uol92
05.12.2014 11:11Комментарий: 13
uol92

А есть возможность сделать вложенные группировки? У меня есть группа Продажи, в ней наличные и безналичные. Я хоче ещё безналичные разбить на POS-терминал и онлайн оплата. Есть ли такая возможность?

zlenko
02.10.2013 16:38Комментарий: 12
zlenko
Спасибо за примеры условного оформления. Использовал в своем отчете http://infostart.ru/public/176720/
ZLENKO.PRO - PROJECTS & PROGRAMS - "1С: Предприятие 8.2"
baibolaika
21.05.2013 07:40Комментарий: 11
baibolaika
E_Migachev, это понятно. А как же сделать, чтобы только нужная колонка была доступна для ввода? Как же получить ее?
E_Migachev
20.05.2013 22:04Комментарий: 10
E_Migachev
baibolaika, так все просто:
Код 1C v 8.х
      ТабДок.Защита = Ложь;

     ТабДок.ТолькоПросмотр = Ложь;
baibolaika
20.05.2013 15:51Комментарий: 9
baibolaika
E_Migachev, подскажите примерчиком, если можно, пожалуйста
E_Migachev
20.05.2013 14:47Комментарий: 8
E_Migachev
baibolaika, а все - понял о чем вы, тут аналогично, просто разрешите редактирование табдокумента
baibolaika
20.05.2013 14:05Комментарий: 7
baibolaika
E_Migachev, просто снимаю защиту с поля макета.
E_Migachev
20.05.2013 13:58Комментарий: 6
E_Migachev
baibolaika, а как вы это через построитель делаете?
baibolaika
20.05.2013 12:08Комментарий: 5
baibolaika
да, понимаю. а вот например в отчете, построенном через ПостроительОтчета можно же ведь...как нибудь так же возможно?
E_Migachev
20.05.2013 12:01Комментарий: 4
E_Migachev
baibolaika, нет, это же отчет, а не обработка *09
baibolaika
20.05.2013 11:00Комментарий: 3
baibolaika
Возможно ли добавить колонку с полями, в которые можно будет вводить какие-нибудь числа?
E_Migachev
15.03.2013 00:08Комментарий: 2
E_Migachev
ab, Группируются по следующему шаблону:
Код 1C v 8.х
 // УниверсальныйОтчет.ДобавитьПоказатель(<ИмяПоказателя>, <ПредставлениеПоказателя>, <ВключенПоУмолчанию>, <Формат>, <ИмяГруппы>, <ПредставлениеГруппы>);
а вот реальный пример:
Код 1C v 8.х
 	УниверсальныйОтчет.ДобавитьПоказатель("ВремяПодачи", "Время подачи", Истина, "ДФ=H:mm", "Данные", "Введенные в доставку данные");

	УниверсальныйОтчет.ДобавитьПоказатель("ВремяПриездаЭкспедитораФакт", "Время Приезда Экспед.", Истина, "ДФ=H:mm", "Данные", "Введенные в доставку данные");

	УниверсальныйОтчет.ДобавитьПоказатель("ПодачаМашины", "Подача Машины", Истина, "ДФ=H:mm", "Данные", "Введенные в доставку данные");

	УниверсальныйОтчет.ДобавитьПоказатель("ВыдачаРазрешения", "Выдача Разрешения", Истина, "ДФ=H:mm", "Данные", "Введенные в доставку данные");

	УниверсальныйОтчет.ДобавитьПоказатель("ВремяОтъезда", "Время отъезда", Истина, "ДФ=H:mm", "Данные", "Введенные в доставку данные");

	УниверсальныйОтчет.ДобавитьПоказатель("ПриездККлиенту", "Приезд к клиенту", Истина, "ДФ=H:mm", "Данные", "Введенные в доставку данные");

	УниверсальныйОтчет.ДобавитьПоказатель("ОкончаниеРаботы", "Оконч. работы", Истина, "ДФ=H:mm", "Данные", "Введенные в доставку данные"); 	

	УниверсальныйОтчет.ДобавитьПоказатель("ОпозданиеЭкспедитора", "Опозд. экспедитора", Истина, "ЧДЦ=0", "Рассчет", "Рассчетные показатели в минутах");

	УниверсальныйОтчет.ДобавитьПоказатель("ОпозданиеМашины", "Опозд. машины", Истина, "ЧДЦ=0", "Рассчет", "Рассчетные показатели в минутах");

	УниверсальныйОтчет.ДобавитьПоказатель("ОжиданиеРазрешения", "Ожидан. разрешения", Истина, "ЧДЦ=0", "Рассчет", "Рассчетные показатели в минутах");

	УниверсальныйОтчет.ДобавитьПоказатель("ВремяНаСкладе", "Время на складе", Истина, "ЧДЦ=0", "Рассчет", "Рассчетные показатели в минутах");

	УниверсальныйОтчет.ДобавитьПоказатель("ВремяВПути", "Время в пути", Истина, "ЧДЦ=0", "Рассчет", "Рассчетные показатели в минутах"); 	

	УниверсальныйОтчет.ДобавитьПоказатель("Разгрузка", "Разгрузка", Истина, "ЧДЦ=0", "Рассчет", "Рассчетные показатели в минутах");

	УниверсальныйОтчет.ДобавитьПоказатель("Итог", "Итог", Истина, "ЧДЦ=0", "Рассчет", "Рассчетные показатели в минутах");
ab
14.03.2013 19:05Комментарий: 1
ab
Хорошо бы ещё показать как показатели отчета можно объединять в группы
Вы не можете отправить комментарий анонимно, пожалуйста войдите или зарегистрируйтесь.