напечатать » Поиск

Результаты по ключевому слову: напечатать

Конвертация экселя в картику

На листе екселя есть картинки, надписи в произвольной форме. Как это чудище с конвертировать в картинку. Нашел процедуру

ФайлПрограммы = НовыйФайл("C:\Program Files\Bullzip\PDF Printer\gs\gswin32c.exe");

Если Не ФайлПрограммы.Существует() Тогда ТекстСообщения = "Не установлена программа - Bullzip"; ОбщегоНазначенияКлиентСервер.СообщитьПользователю(ТекстСообщения);

Возврат "";

КонецЕсли;

ИмяКартинки = "Проба";

ПринтерPDF.SetValue("output", "D:\" +ИмяКартинки + ".jpg");

ПринтерPDF.SetValue("ShowSaveAS", "never");

ПринтерPDF.SetValue("ShowProgress", "no");

ПринтерPDF.SetValue("ShowProgressFinished", "no");

ПринтерPDF.SetValue("ShowSettings", "never");

ПринтерPDF.SetValue("ShowPDF", "no");

ПринтерPDF.SetValue("ConfirmOverwrite","no");

ПринтерPDF.SetValue("Device","jpeg");

ПринтерPDF.WriteSettings();

НастройкиПечатиОриентация= 1;// 1 - портерт, 2 - ландшафт.

НастройкиПечатиМасштаб= 100;// масштаб в процентах.

НастройкиПечатиРазложитьПоКопиям = 1;// 0 - не разбирать по копиям, 1 - разобрать по копиям.

НастройкиПечатиПолеЛев= 10;

НастройкиПечатиПолеПрав= 10;

НастройкиПечатиПолеВерх= 10;

НастройкиПечатиПолеНиз= 10;

НастройкиПечатиКолонтитулВерх= 0;

НастройкиПечатиКолонтитулНиз= 0;

НастройкиПечатиАвтомасштабПоШирине = 1;// 1 - включить, 0 - выключить.

НастройкиПечатиЧерноБелаяПечать = 0;// 1 - включить, 0 - выключить.

НастройкиПечатиИмяПринтера = "Bullzip PDF Printer";// Имя принтера в ОС

Таб.ПараметрыСтраницы(НастройкиПечатиОриентация, НастройкиПечатиМасштаб, НастройкиПечатиРазложитьПоКопиям,

НастройкиПечатиПолеЛев, НастройкиПечатиПолеПрав, НастройкиПечатиПолеВерх, НастройкиПечатиПолеНиз,

НастройкиПечатиКолонтитулВерх, НастройкиПечатиКолонтитулНиз, НастройкиПечатиАвтомасштабПоШирине,

НастройкиПечатиЧерноБелаяПечать, НастройкиПечатиИмяПринтера);

Таб.КоличествоЭкземпляров(1);

Таб.Напечатать(0);

Но есть вопрос? Как перетащить лист экселя в Таб? Нашел много способов и на этом форуме но перетаскиваются только текстовые данные, а мне нужно все.

Категория: Работа с Microsoft Office и OpenOffice

Синтаксический анализ JSON - выражения средствами 1С 7.7

Код 1C v 7.x

 



Перем Л_Лев_Фиг_Скобка, Л_Прав_Фиг_Скобка, Л_Лев_Кв_Скобка, Л_Прав_Кв_Скобка, Л_Кавычка, Л_Экран, Л_Двоеточие, Л_Запятая, Л_Число, Л_Строка, Л_Константа, Л_Финиш;

Перем Цифры1_9, Цифры0_9, ПервыеСимволыКонстант, ОдносимвольныеЛексемы;

Перем НомЛексемы, ТекЛексема;

Перем JSON_Error;

Перем В_Массив, В_Объект, В_Значение;

//*****

Перем НомерСимвола;

Перем ФлагОшибки;

Перем СписокСтроковыхКонстант;

Перем СтекЛексем;

Перем АнализируемаяСтрока;

//*****

Перем ТекКаталог, ТекФайл;

//*****

Функция ПолучитьОбъект_ТЗ() Далее

Функция ПолучитьМассив_ТЗ() Далее

//*****

Функция ТекущиеСимволы(Сколько)

	Возврат Сред(АнализируемаяСтрока, НомерСимвола, Сколько);

КонецФункции

//*****

Функция ПрошлыйСимвол(Сдвиг)

	Возврат Сред(АнализируемаяСтрока, НомерСимвола - Сдвиг, 1);

КонецФункции

//*****

Процедура ДобавитьЛексему(Лексема, Значение, Сдвиг)

	СтекЛексем.НоваяСтрока();

	СтекЛексем.Лексема	= Лексема;

	СтекЛексем.Значение	= Значение;	

	НомерСимвола		= НомерСимвола + Сдвиг;

КонецПроцедуры

//*****

Процедура ОбвестиОбласть(Обл)

	Обл.РамкаСнизу(1);

	Обл.РамкаСверху(1);

	Обл.РамкаСлева(1);

	Обл.РамкаСправа(1);

КонецПроцедуры

//*****

Процедура НапечататьТЗ(Таб, ТЗ, НомС, НомК)

Перем Тип, Обл1, НС, КС, Ключ, Зн, Обл2;

	Тип = ТЗ.ПолучитьЗначение(1, 1);

	НомС = НомС + 1;

	Обл1 = Таб.Область(НомС, НомК);

	ОбвестиОбласть(Обл1);

	Если Тип = В_Значение Тогда

		ТипЗн = ТЗ.ПолучитьЗначение(2, 1);

		Обл1.Текст = ТЗ.ПолучитьЗначение(2, 2);

		Обл1.ГоризонтальноеПоложение(1);

		Если ТипЗн = Л_Число Тогда

			Обл1.ГоризонтальноеПоложение(2);

		ИначеЕсли ТипЗн = Л_Константа Тогда

			Обл1.Полужирный(1);

		ИначеЕсли ТипЗн = Л_Строка Тогда

			Обл1.Контроль(4);

		КонецЕсли;

		Возврат;

	ИначеЕсли (Тип = В_Объект) Или (Тип = В_Массив) Тогда

		Обл1.Текст = Тип;

		Обл1.Полужирный(1);

		Обл1.ЦветФона(12648447);

		Обл1.РамкаСнизу(5);

		КС = ТЗ.КоличествоСтрок();

		Для НС = 2 По КС Цикл

			НомС = НомС + 1;

			Обл2 = Таб.Область(НомС, НомК);

			Обл2.Текст = ТЗ.ПолучитьЗначение(НС, 1);

			Если Тип = В_Массив Тогда

				Обл2.ГоризонтальноеПоложение(2);

			КонецЕсли;

			ОбвестиОбласть(Обл2);

			НомС = НомС - 1;

			НапечататьТЗ(Таб, ТЗ.ПолучитьЗначение(НС, 2), НомС, НомК + 1);

		КонецЦикла;

	Иначе

		Сообщить("Фигня " + Тип, "!");

	КонецЕсли;

КонецПроцедуры

//*****

Процедура ВыравнятьТЗ(Таб, ОграничениеШирины)

Перем НомерКол, НомерСтр, МаксШирина, Обл, ТекШирина, ТекДлина;

	Для НомерКол = 1 По Таб.ШиринаТаблицы() Цикл

		МаксШирина = 0;

		Для НомерСтр = 1 По Таб.ВысотаТаблицы() Цикл

			Обл = Таб.Область(НомерСтр, НомерКол);

			ТекШирина = Обл.ШиринаСтолбца();

			ТекДлина = СтрДлина(СокрЛП(Обл.Текст));

			МаксШирина = Макс(МаксШирина, ТекШирина, ТекДлина);

		КонецЦикла;

		Таб.Область(, НомерКол).ШиринаСтолбца(Мин(МаксШирина, ОграничениеШирины));

	КонецЦикла;

КонецПроцедуры

//*****

Процедура Напечатать_ТЗ(ТЗ)

Перем Таб, НС, НК, МаксШирина, ТекДлина, Обл;	

	Таб = СоздатьОбъект("Таблица");

	МаксНК = 1;

	НС = 0;

	НК = 1;

	НапечататьТЗ(Таб, ТЗ, НС, НК);

	ВыравнятьТЗ(Таб, 30);

	Таб.Область(1, 1, Таб.ВысотаТаблицы(), Таб.ШиринаТаблицы()).ВертикальноеПоложение(2);

	Таб.Опции(0, 0);

	Таб.Показать("JSON");

КонецПроцедуры

//*****

Функция Ошибка()

	ФлагОшибки = 1;

	Возврат 0;

КонецФункции

//*****

Функция ЧитатьКонстанту(ПервСимвол)

Перем КонстантаСтр, ДлинаКонстанты;	

	КонстантаСтр = СписокСтроковыхКонстант.Получить(ПервСимвол);

	ДлинаКонстанты = СтрДлина(КонстантаСтр);

	Если ТекущиеСимволы(ДлинаКонстанты) = КонстантаСтр Тогда

		ДобавитьЛексему(Л_Константа, КонстантаСтр, ДлинаКонстанты);

		Возврат 1;

	Иначе

		Возврат Ошибка();

	КонецЕсли;

КонецФункции

//*****

Процедура ДописатьСимвол(Стр)

	Стр = Стр + ТекущиеСимволы(1);

	НомерСимвола = НомерСимвола + 1;

КонецПроцедуры

//*****

Функция ЧитатьЧисло() 

Перем ЧислоСтр;

	ЧислоСтр = "";

	Если ТекущиеСимволы(1) = "-" Тогда

		ДописатьСимвол(ЧислоСтр);

	КонецЕсли;

	Если Найти(Цифры1_9, ТекущиеСимволы(1)) > 0 Тогда // не с нуля

		ДописатьСимвол(ЧислоСтр);

		Пока Найти(Цифры0_9, ТекущиеСимволы(1)) > 0 Цикл  // любые цыфры 

			ДописатьСимвол(ЧислоСтр);

		КонецЦикла;		

	ИначеЕсли ТекущиеСимволы(1) = "0" Тогда //с нуля - ничего дальше 

		ДописатьСимвол(ЧислоСтр);

	Иначе

		Возврат Ошибка();

	КонецЕсли;

	Если ТекущиеСимволы(1) = "." Тогда // десятичная точка

		ДописатьСимвол(ЧислоСтр);

		Пока Найти(Цифры0_9, ТекущиеСимволы(1)) > 0 Цикл  // любые цыфры

			ДописатьСимвол(ЧислоСтр);

		КонецЦикла;		

	КонецЕсли;

	Если ВРег(ТекущиеСимволы(1)) = "E" Тогда // значок e больное или маленькое

		ДописатьСимвол(ЧислоСтр);

		Если Найти("+-", ТекущиеСимволы(1)) > 0 Тогда  // унарный знак для порядка

			ДописатьСимвол(ЧислоСтр);

		КонецЕсли;

		Пока Найти(Цифры0_9, ТекущиеСимволы(1)) > 0 Цикл  // любые цыфры

			ДописатьСимвол(ЧислоСтр);

		КонецЦикла;		

	КонецЕсли;

	ДобавитьЛексему(Л_Число, ЧислоСтр, 0);

	Возврат 1;

КонецФункции

//*****

Функция ЧитатьСтроку()

Перем СтрокаСтр;

	СтрокаСтр = "";

	НомерСимвола = НомерСимвола + 1;

	Пока (ТекущиеСимволы(1) <> Л_Кавычка) Или ((ТекущиеСимволы(1) = Л_Кавычка) И (ПрошлыйСимвол(1) = Л_Экран) И (ПрошлыйСимвол(2) <> Л_Экран)) Цикл

		ДописатьСимвол(СтрокаСтр);

	КонецЦикла;

	ДобавитьЛексему(Л_Строка, СтрокаСтр, 1); 

	Возврат 1;

КонецФункции 

//*****

Функция ПрочитатьФайл(ИмяФайла)

Перем Т, НомерСтрокиФайла, СтрокаРез;

	Т = СоздатьОбъект("Текст");

	Т.Открыть(ИмяФайла);

	СтрокаРез = "";

	Для НомерСтрокиФайла = 1 По Т.КоличествоСтрок() Цикл

		СтрокаРез = СтрокаРез + Т.ПолучитьСтроку(НомерСтрокиФайла);

	КонецЦикла;

	Возврат СтрокаРез;

КонецФункции

//*****

Функция СледующаяЛексема()

	НомЛексемы = НомЛексемы + 1;

	СтекЛексем.ПолучитьСтрокуПоНомеру(НомЛексемы);

	ТекЛексема = СтекЛексем.Лексема;

	Возврат 1;

КонецФункции

//*****

Функция ОшибкаЛексемы()

Перем РезСтр, НомСтр, ТЛ, ТС;

	Сообщить("Ошибочная лексема № " + НомЛексемы + " : <" + ТекЛексема + ">", "!");

	РезСтр = "";

	Для НомСтр = НомЛексемы + 1 По СтекЛексем.КоличествоСтрок() Цикл

		СтекЛексем.ПолучитьСтрокуПоНомеру(НомСтр);

		ТЛ = СтекЛексем.Лексема;

		Если ТЛ = Л_Строка Тогда 

			ТС = "<" + ТЛ + "(" + СтекЛексем.Значение + ")>";

		ИначеЕсли ТЛ = Л_Константа Тогда

			ТС = "<" + ТЛ + "(" + СтекЛексем.Значение + ")>";

		Иначе

			ТС = "<" + ТЛ + ">";

		КонецЕсли;

		РезСтр = РезСтр + ТС + ",";

	КонецЦикла;

	Сообщить(Лев(РезСтр, 400), "!");

	Возврат 0;

КонецФункции

//*****

Процедура ДобавитьПару(ТЗ, Ключ, Значение)

	ТЗ.НоваяСтрока();

	ТЗ.Ключ		= Ключ;

	ТЗ.Значение	= Значение;

КонецПроцедуры

//*****

Функция НоваяТЗ(Тип)

Перем _ТЗ;

	_ТЗ = СоздатьОбъект("ТаблицаЗначений");

	_ТЗ.НоваяКолонка("Ключ");

	_ТЗ.НоваяКолонка("Значение");

	ДобавитьПару(_ТЗ, Тип, "");

	Возврат _ТЗ;

КонецФункции

//*****

Функция ПолучитьПроизвольноеЗначение_ТЗ()

Перем ТЗ;	

	Если (ТекЛексема = Л_Строка) Или (ТекЛексема = Л_Число) Или (ТекЛексема = Л_Константа) Тогда

		ТЗ = НоваяТЗ(В_Значение);

		ДобавитьПару(ТЗ, ТекЛексема, СтекЛексем.Значение);

		СледующаяЛексема();

		Возврат ТЗ;

	ИначеЕсли ТекЛексема = Л_Лев_Фиг_Скобка Тогда

		Возврат ПолучитьОбъект_ТЗ();

	ИначеЕсли ТекЛексема = Л_Лев_Кв_Скобка 	Тогда

		Возврат ПолучитьМассив_ТЗ();					

	КонецЕсли;

	Возврат ОшибкаЛексемы();

КонецФункции

//*****

Функция ДобавитьКлючЗначение(ТЗ)

Перем НовКлюч, НовЗначение;

	Если ТекЛексема <> Л_Строка Тогда

		Возврат 0;

	КонецЕсли;

	НовКлюч = СтекЛексем.Значение;

	СледующаяЛексема();

	Если ТекЛексема <> Л_Двоеточие Тогда

		Возврат ОшибкаЛексемы();

	КонецЕсли;

	СледующаяЛексема();

	НовЗначение = ПолучитьПроизвольноеЗначение_ТЗ();

	Если НовЗначение = 0 Тогда

		Возврат 0;

	КонецЕсли;

	ДобавитьПару(ТЗ, НовКлюч, НовЗначение);

	Возврат 1;

КонецФункции

//*****

Функция ПолучитьОбъект_ТЗ()

Перем ТЗ;

	ТЗ = НоваяТЗ(В_Объект);

	СледующаяЛексема();

	Если ТекЛексема = Л_Прав_Фиг_Скобка Тогда // пустой объект

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	Если ДобавитьКлючЗначение(ТЗ) = 0 Тогда   // первая пара ключ-значение

		Возврат 0;

	КонецЕсли;	

	Пока ТекЛексема = Л_Запятая Цикл			// пока запятые

		СледующаяЛексема();

		Если ДобавитьКлючЗначение(ТЗ) = 0 Тогда	// пара ключ-значение

			Возврат 0;

		КонецЕсли;

	КонецЦикла;

	Если ТекЛексема = Л_Прав_Фиг_Скобка Тогда

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	Возврат 0;

КонецФункции

//*****

Функция ПолучитьМассив_ТЗ()

Перем ТЗ, _Ключ, _Значение;

	ТЗ = НоваяТЗ(В_Массив);

	СледующаяЛексема();

	Если ТекЛексема = Л_Прав_Кв_Скобка Тогда

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	_Значение = ПолучитьПроизвольноеЗначение_ТЗ();

	Если _Значение = 0 Тогда

		Возврат 0;

	КонецЕсли;

	_Ключ = 0; // JS - индексы массиворв с нуля

	ДобавитьПару(ТЗ, _Ключ, _Значение);	

	Пока ТекЛексема = Л_Запятая Цикл

		СледующаяЛексема();

		_Значение = ПолучитьПроизвольноеЗначение_ТЗ();

		Если _Значение = 0 Тогда

			Возврат 0;

		КонецЕсли;

		_Ключ = _Ключ + 1;

		ДобавитьПару(ТЗ, _Ключ, _Значение);

	КонецЦикла;

	Если ТекЛексема = Л_Прав_Кв_Скобка Тогда

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	Возврат 0;

КонецФункции

//*****

Функция ПрочитатьОбъект_ТЗ()

Перем Рез;	

	НомЛексемы = 0;

	СледующаяЛексема();

	Если ТекЛексема = Л_Лев_Фиг_Скобка Тогда

		Рез = ПолучитьОбъект_ТЗ();

	ИначеЕсли ТекЛексема = Л_Лев_Кв_Скобка Тогда

		Рез = ПолучитьМассив_ТЗ();

	Иначе

		Рез = ПолучитьПроизвольноеЗначение_ТЗ();

	КонецЕсли;

	Если (Рез = 0) Или (ТекЛексема <> Л_Финиш) Тогда

		ОшибкаЛексемы();

		Возврат 0;

	КонецЕсли;

	Возврат Рез;	

КонецФункции

//*****

Функция СгенерироватьТЗ(НачАнализируемаяСтрока)

Перем НачальныйСимвол, Рез;

	АнализируемаяСтрока = НачАнализируемаяСтрока;

	СтекЛексем = СоздатьОбъект("ТаблицаЗначений");

	СтекЛексем.НоваяКолонка("Лексема" , "Строка");

	СтекЛексем.НоваяКолонка("Значение", "Строка");

	ФлагОшибки = 0;

	НомерСимвола = 1;

	Пока НомерСимвола <= СтрДлина(АнализируемаяСтрока) Цикл

		НачальныйСимвол = ТекущиеСимволы(1);

		Если Найти(" " + Симв(9), НачальныйСимвол) > 0 Тогда  // пробелы и разделители строк пропускаем

			НомерСимвола = НомерСимвола + 1;

		ИначеЕсли НачальныйСимвол = Л_Кавычка	Тогда // кавычка - читаем строку

			ЧитатьСтроку();

		ИначеЕсли Найти(ОдносимвольныеЛексемы, НачальныйСимвол) > 0 Тогда

			ДобавитьЛексему(НачальныйСимвол, "", 1);

		ИначеЕсли Найти(ПервыеСимволыКонстант, НачальныйСимвол) > 0 Тогда // первая буква из начала константы - константа null, true, false

			Если ЧитатьКонстанту(НачальныйСимвол) = 0 Тогда

				Прервать;

			КонецЕсли;

		ИначеЕсли Найти("-" + Цифры0_9, НачальныйСимвол) > 0 Тогда // число

			Если ЧитатьЧисло() = 0 Тогда

				Прервать;

			КонецЕсли;

		Иначе		// иных вариантов нет

			Сообщить("========= " + НомерСимвола, "!");

			Сообщить(НачальныйСимвол, "!");

			Сообщить("<" + НачальныйСимвол + "> " + КодСимв(НачальныйСимвол), "!");

			Сообщить(ТекущиеСимволы(100), "!");

			Возврат 0;

		КонецЕсли;

	КонецЦикла;

	Если ФлагОшибки <> 0 Тогда

		Сообщить("Ошибка парсинга JSON - выражения", "!");

		Возврат 0;

	ИначеЕсли СтекЛексем.КоличествоСтрок() = 0 Тогда

		Сообщить("Пустой стек", "!");

		Возврат 0;

	КонецЕсли;

	ДобавитьЛексему(Л_Финиш, "", 0);

	Возврат ПрочитатьОбъект_ТЗ();

КонецФункции

//*****

Функция JSON_Error(Стр = "")

	Если Стр <> "" Тогда

		Сообщить("JSON-ОШИБКА: " + Стр, "!");

	КонецЕсли;

	Возврат JSON_Error;

КонецФункции

//*****

Функция JSON_Type(Парам)

	Если ТипЗначенияСтр(Парам) <> "ТаблицаЗначений" Тогда

		Возврат JSON_Error();

	ИначеЕсли Парам.КоличествоКолонок() <> 2 Тогда

		Возврат JSON_Error();

	ИначеЕсли Парам.КоличествоСтрок() < 2 Тогда

		Возврат JSON_Error();

	КонецЕсли;

	Возврат Парам.ПолучитьЗначение(1, 1);

КонецФункции

//*****

Функция JSON_GetValue(Парам, Keys)

Перем Тип, До, После, ПозЗакр, Л1, П2, Инд, ИндСтр, НС, КвоСтрок;

	Тип = JSON_Type(Парам);

	ПозЗакр = Найти(Keys, "]");

	Если ПозЗакр = 0 Тогда

		ПозЗакр = СтрДлина(Keys) + 1;

	КонецЕсли;	

	До = Лев(Keys, ПозЗакр);

	После = Сред(Keys, ПозЗакр + 1);

	Л1 = Лев(До, 1);

	П2 = Найти(До, "]");

	Если Тип = JSON_Error Тогда

		Возврат JSON_Error("Параметра");

	КонецЕсли;

	КвоСтрок = Парам.КоличествоСтрок();

	Если До = "" Тогда // сам объект

		Если (Тип = В_Массив) Или (Тип = В_Объект) Тогда

			Возврат JSON_Error();

		ИначеЕсли Тип = В_Значение Тогда

			Возврат Парам.ПолучитьЗначение(2, 2);

		Иначе

			Возврат JSON_Error("№ 1");

		КонецЕсли;		

	ИначеЕсли До = ".length" Тогда // размер массива или объекта. Для значения - ошибка

		Если (Тип = В_Массив) Или (Тип = В_Объект) Тогда

			Возврат Парам.КоличествоСтрок() - 1;

		Иначе

			Возврат JSON_Error("Длина скаляра");

		КонецЕсли;

	ИначеЕсли Л1 = "[" Тогда // размер массива или объекта. Для значения - ошибка

		Если П2 = 0 Тогда

			Возврат JSON_Error("Индексация: <" + До + ">");

		КонецЕсли;

		Инд = Сред(До, 2, П2 - 2);

		Если (Найти("'""", Лев(Инд, 1)) > 0) И (Найти("'""", Прав(Инд, 1)) > 0) Тогда // строковый только объект

			ИндСтр = Сред(Инд, 2, СтрДлина(Инд) - 2);

			Если Тип <> В_Объект Тогда

				Возврат JSON_Error("Строковый индекс <" + ИндСтр + "> только для Объекта");

			КонецЕсли;

			НС = 0;

			Если Парам.НайтиЗначение(ИндСтр, НС, 1) = 1 Тогда

				Возврат JSON_GetValue(Парам.ПолучитьЗначение(НС, 2), После);

			КонецЕсли;

			Возврат JSON_Error("Нет индекса <" + ИндСтр + ">");

		КонецЕсли;

		ИндЧис = 0 + Инд;

		Если "" + ИндЧис <> Инд Тогда // защита от <5D>

			Возврат JSON_Error("Ошибка 1 числового индекса <" + Инд + ">");

		ИначеЕсли Цел(ИндЧис) <> ИндЧис Тогда // защита от неЦелого индекса

			Возврат JSON_Error("Ошибка 2 числового индекса <" + Инд + "> (нецелый)");

		ИначеЕсли ИндЧис < 0 Тогда

			Возврат JSON_Error("Ошибка 3 числового индекса <" + Инд + "> (отрицательный)");

		ИначеЕсли ИндЧис > (КвоСтрок - 2) Тогда

			Возврат JSON_Error("Ошибка 4 числового индекса <" + Инд + "> (" + ИндЧис + ">" + (КвоСтрок - 2) + ")");

		КонецЕсли;

		Возврат JSON_GetValue(Парам.ПолучитьЗначение(ИндЧис + 1, 2), После);

	Иначе

		Возврат JSON_Error("Ошибка 5 <" + До + ">");

	КонецЕсли;

КонецФункции

//*****

Процедура ПриОткрытии()

Перем Рез1, ТипУзла1, Зн1, Значение;	

	ОчиститьОкноСообщений();

	СтатусВозврата(0);

	Рез1 = СгенерироватьТЗ(ПрочитатьФайл(ТекКаталог + "j1.json"));

	Напечатать_ТЗ(Рез1);

	ТипУзла1 = JSON_Type(Рез1);

	Сообщить("Тип узла: " + ТипУзла1);

	Зн1 = JSON_GetValue(Рез1, ".length");									Сообщить("1) Размер: " 		+ Зн1);

	Зн3 = JSON_GetValue(Рез1, "['1']");										Сообщить("3) ['1']: <" 		+ Зн3 + ">");

	Зн4 = JSON_GetValue(Рез1, "[1]");										Сообщить("4) [1]: <" 		+ Зн4 + ">");

	Зн5 = JSON_GetValue(Рез1, "['Массив'][6]");								Сообщить("5) [*]: <" + Зн5 + ">");

	Зн6 = JSON_GetValue(Рез1, "['Соответствие']['ДопустимоеИмяСвойства']");	Сообщить("6) [*]: <" + Зн6 + ">");

КонецПроцедуры

//*****

Процедура ДобавитьСтроковуюКонстанту(КонстантаСтр)

Перем ПервыйСимвол;	

	ПервыйСимвол = Лев(КонстантаСтр, 1);

	ПервыеСимволыКонстант = ПервыеСимволыКонстант + ПервыйСимвол;

	СписокСтроковыхКонстант.Установить(ПервыйСимвол, КонстантаСтр);

КонецПроцедуры

//*****

РасположениеФайла(ТекКаталог, ТекФайл);

//*****

Л_Лев_Фиг_Скобка	= "{";

Л_Прав_Фиг_Скобка	= "}";

Л_Лев_Кв_Скобка		= "["; 

Л_Прав_Кв_Скобка	= "]";

Л_Двоеточие			= ":";

Л_Запятая			= ",";

Л_Экран				= "\";

Л_Кавычка			= """";

Л_Финиш				= "";

Л_Число				= "number";

Л_Строка			= "string";

Л_Константа			= "const";

ОдносимвольныеЛексемы = Л_Лев_Фиг_Скобка + Л_Прав_Фиг_Скобка + Л_Лев_Кв_Скобка + Л_Прав_Кв_Скобка + Л_Двоеточие + Л_Запятая;

//*****

Цифры1_9 = "123456789";

Цифры0_9 = "0" + Цифры1_9;

//*****

В_Массив   = "###array";

В_Объект   = "###object";

В_Значение = "###value";

//*****

СписокСтроковыхКонстант	= СоздатьОбъект("СписокЗначений");

ПервыеСимволыКонстант	= "";

ДобавитьСтроковуюКонстанту("null");

ДобавитьСтроковуюКонстанту("false");

ДобавитьСтроковуюКонстанту("true");

JSON_Error = "ERROR";

В качестве примера взят файл j1.json :

{

"999": 88,

"Null": null,

"Сэкраном": "\"",

"Ложь": false,

"ОдинСимв": "1",

"1": "11111",

"Пустышка": "",

"Истина": true,

"Число (плавающая точка)": 1.001e-2,

"Число (плавающая)": -1.001e-2,

"Число (фиксированная точка)": -1000.001,

"Дата": "2011-01-01T12:00:00Z",

"Строка (двойная кавычка)": "Двойная кавычка",

"Строка (одинарная кавычка)": "Одинарная кавычка",

"Маскируемые символы": " \\ \/ \b \t \n \f \r \" ",

"Заковыристая строка": "\\n\\",

"Проблемные символы": "Спец. символы: \u0000, \u0001, \u0002, ... , \u001e, \u001f; Юникод символы: \u0421\u0430\u0448\u0430\u0020\u003a\u0029",

"Кириллические символы": "’АБВГҐДЂЃЕ?ЁЄЖЗЅИ?ІЇЙЈКЛЉМНЊОПРСТЋЌУЎФХЦЧЏШЩЪЫЬЭЮЯ",

"Идентификатор": "a763cfbb-f94f-4c67-8e13-0e96a3a7f353",

"Пустой массив": [],

"Пустой объект": {},

"Массив": [

null,

false,

true,

1.001e-2,

-1000.001,

"2011-01-01T12:00:00Z",

"Двойная кавычка",

"Одинарная кавычка",

"a763cfbb-f94f-4c67-8e13-0e96a3a7f353",

[

"Первый элемент",

"Второй элемент"

{

"Имя": "Александр",

"Отчество": "Владимирович",

"Фамилия": "Переверзев"

{

"ДопустимоеИмяСвойства": true,

"Недопустимое Имя Свойства": false

}

"Структура":

{

"Имя": "Александр",

"Отчество": "Владимирович",

"Фамилия": "Переверзев"

"Соответствие":

{

"ДопустимоеИмяСвойства": true,

"Недопустимое Имя Свойства": false

"Ссылка":

{

"Ссылка": "00000000-0000-0000-0000-000000000000",

"Представление": "Неизвестная ссылка"

"COMSafeArray": [

]

}

Категория: HTML, JS, VML

Как при печати выводить шапку на каждой странице (ПовторятьПриПечатиСтроки)?

Необходимо при печати, если происходит переход на следующую страницу таблицы, выводить шапку таблицы вверху на новой странице.

для печати шапки на каждой странице в языке программирования есть специальный метод - ПовторятьПриПечатиСтроки

Примеры его использования:

Код 1C v 8.х

 ТабДок.ПовторятьПриПечатиСтроки = ТабДок.Область(1, , 2, );

ЭлементыФормы.Поле_ТД.ПовторятьПриПечатиСтроки = Макет.Область("Шапка_Спецификации"); //или так  

ЭлементыФормы.Поле_ТД.ПовторятьПриПечатиСтроки = Макет.Область("R777:R778");

Полный код вывода табличного документа с повторением шапки на каждой странице:

Код 1C v 8.х

 Функция ПечатьПриказаТ11а()



	ТабДокумент = Новый ТабличныйДокумент;

	ТабДокумент.ИмяПараметровПечати = "ПАРАМЕТРЫ_ПЕЧАТИ_ПечатнаяФорма_МатериальнаяПомощь_Т11а";

	ТабДокумент.ПовторятьПриПечатиСтроки = ТабДокумент.Область("R21:R22");

	

	Макет 		= ПолучитьМакет("Т11а");

	ОбластьМакетаШапкаДокумента = Макет.ПолучитьОбласть("Шапка");

	ОбластьПовторятьПриПечати	= Макет.ПолучитьОбласть("ПовторятьПриПечати");

	ОбластьМакетаСтрока 		= Макет.ПолучитьОбласть("Строка");

	ОбластьМакетаПодвал 		= Макет.ПолучитьОбласть("Подвал");





	ВыборкаДляШапкиДокумента = СформироватьЗапросДляШапкиДокумента().Выбрать();

	ВыборкаРаботники = СформироватьЗапросДляТабличнойЧасти(1).Выбрать();  		// ТЧ "Начисления"

	Если ВыборкаРаботники.Количество() = 0 Тогда

		ВыборкаРаботники = СформироватьЗапросДляТабличнойЧасти(2).Выбрать();	// ТЧ "Доп.Начисления"

	КонецЕсли;		

	

	// Массив с двумя строками - для разбиения на страницы

	ВыводимыеОбласти = Новый Массив();

	ВыводимыеОбласти.Добавить(ОбластьМакетаСтрока);

	

	// Вывод шапки документа

	Пока ВыборкаДляШапкиДокумента.Следующий() Цикл

		ОбластьМакетаШапкаДокумента.Параметры.Заполнить(ВыборкаДляШапкиДокумента);

 		ОбластьМакетаШапкаДокумента.Параметры.НазваниеОрганизации = СокрЛП(ОбластьМакетаШапкаДокумента.Параметры.НазваниеОрганизации);

	КонецЦикла;

	ТабДокумент.Вывести(ОбластьМакетаШапкаДокумента);

	ном=0;

	Пока ВыборкаРаботники.Следующий() Цикл

		ОбластьМакетаСтрока.Параметры.Заполнить(ВыборкаРаботники);

		ном=ном+1;

		ОбластьМакетаСтрока.Параметры.ПодразделениеОрганизации	= ВыборкаРаботники.ПодразделениеОрганизации.ПолноеНаименование();		

		ОбластьМакетаСтрока.Параметры.ном=ном;

		ТабДокумент.Вывести(ОбластьМакетаСтрока);

	КонецЦикла;

	

	ОбластьМакетаПодвал.Параметры.Заполнить(ВыборкаДляШапкиДокумента); // Из запроса шапка документа.

	ТабДокумент.Вывести(ОбластьМакетаПодвал);





	Если ТабДокумент.ВысотаТаблицы > 0 Тогда

		Возврат УниверсальныеМеханизмы.НапечататьДокумент(ТабДокумент, 1, Ложь, ОбщегоНазначения.СформироватьЗаголовокДокумента(СсылкаНаОбъект,"Приказ о поощрении работника "));

	КонецЕсли;

	//Возврат ТабДокумент;



КонецФункции

Категория: Табличный документ

Вывод Структуры на печать в табличный документ

Многие спрашивают: Как вывести структуру на печать?

Путем простого перебора и вывода в табличный документ, вот пример:

Код 1C v 8.х

 	ТабДок = Новый ТабличныйДокумент;	

	Макет = Справочники.Контрагенты.ПолучитьМакет("ПечатьСтруктуры");

	ОбластьЗаголовок = Макет.ПолучитьОбласть("Заголовок");

	ОбластьПодвал = Макет.ПолучитьОбласть("Подвал");

	ОбластьДетальныхЗаписей = Макет.ПолучитьОбласть("Детали");

	

	ТабДок.Очистить();

	ТабДок.Вывести(ОбластьЗаголовок);

	//Перебор СТРУКТУРЫ и вывод в Табличный документ. РК - Структура с данными

	Для Каждого Элемент из РК Цикл           

		//Сообщить(Элемент.Ключ + ": " + Элемент.Значение);

		Если ТипЗнч(Элемент.Значение) = Тип("Структура") Тогда

			Для Каждого ЭлементВ из Элемент.Значение Цикл 

				ОбластьДетальныхЗаписей.Параметры.Заполнить(ЭлементВ); ТабДок.Вывести(ОбластьДетальныхЗаписей);

			КонецЦикла;	

		Иначе

		ОбластьДетальныхЗаписей.Параметры.Заполнить(Элемент); ТабДок.Вывести(ОбластьДетальныхЗаписей);

		КонецЕсли;	

	КонецЦикла; 	

	ТабДок.Вывести(ОбластьПодвал);

	УниверсальныеМеханизмы.НапечататьДокумент(ТабДок); // или ТабДок.Показать();

Табличный документ

Категория: Работа с Массивом, Структурой, Соответств�…

Табличный документ: Колонтитулы и параметры страницы

Большинство обучающих материалов по программированию в системе 1С при описании формирования печатных форм на основе объекта «Табличный документ» ограничиваются выводом готовой формы на экран. Для пользователей же куда более важным является то, как документ будет выглядеть в распечатанном виде. Здесь, кроме хорошо сверстанного макета, играют роль и установки параметров печати.Почти все параметры, доступные в диалогах настройки печати (настройки принтера, свойства страницы), можно указать непосредственно при формировании табличного документа.Рассмотрим свойства и методы табличного документа, относящиеся к настройкам печати (в приведенных примерах «ТабДок» это объект типа «Табличный документ»).

Свойство «ИмяПринтера» позволяет задать для печати принтер, отличный от установленного по умолчанию. Имя должно совпадать с именем принтера, заданным в системе:

ТабДок.ИмяПринтера="HP LaserJet 3050 Series PCL 6";

При печати пакета документов можно сэкономить время, установив признак разбора по копиям:

ТабДок.РазборПоКопиям=истина;

Число копий можно указать так:

ТабДок.КоличествоЭкземпляров=5;

Разумеется, можно задать поля:

ТабДок.ПолеСлева=20;//Поле слева 20мм, остальные поля 10мм (по умолчанию)

Еще несколько свойств страницы:

ТабДок.ОриентацияСтраницы=ОриентацияСтраницы.Ландшафт; ТабДок.ЭкземпляровНаСтранице=2; //на листе будет размещено 2 страницы ТабДок.Автомасштаб=истина; //аналогично настройкам масштаба «по ширине страницы»

При необходимости можно указать конкретное значение масштабирования в процентах (свойство «МасштабПечати»).

Свойство «РазмерСтраницы» позволяет задать стандартные форматы страницы – “A3”, “A4”, “A5” (полный список вариантов доступен в справке 1С).

ТабДок.РазмерСтраницы="A3";// буква А должна быть английской

Для нестандартного размера бумаги (Custom) можно указать значения высоты и ширины страницы (в мм):

ТабДок.РазмерСтраницы="Custom";//нестандартный размер ТабДок.ВысотаСтраницы=350; ТабДок.ШиринаСтраницы=350;

Также в табличном документе доступно управление выводом колонтитулов и их содержимым. Для этого служат свойства «ВерхнийКолонтитул» и «НижнийКолонтитул». Например:

ТабДок.ВерхнийКолонтитул.Выводить=истина; //будет напечатан верхний колонтитул ТабДок.РазмерКолонтитулаСверху=7; //размер колонтитула 7мм (по умолчанию 10мм) ТабДок.ВерхнийКолонтитул.ВертикальноеПоложение=ВертикальноеПоложение.Верх; ТабДок.ВерхнийКолонтитул.НачальнаяСтраница=2;//колонтитул выводится со второй страницы ШрифтКолонтитула=Новый Шрифт("Courier New", 8,,Истина); ТабДок.ВерхнийКолонтитул.Шрифт=ШрифтКолонтитула; //наклонный шрифт ТабДок.ВерхнийКолонтитул.ТекстВЦентре="Верхний колонтитул"; ТабДок.ВерхнийКолонтитул.ТекстСправа="Стр.[&НомерСтраницы] из [&СтраницВсего]"; //нумерация страниц ТабДок.ВерхнийКолонтитул.ТекстСлева="[&Дата]";//текущая дата

Сформированный документ отправляется на печать с помощью метода «Напечатать()». Возможно два варианта вызова.

1) Непосредственно на принтер:ТабДок.Напечатать(РежимИспользованияДиалогаПечати.НеИспользовать); ТабДок.Напечатать(истина);

2) Перед печатью будет выведен диалог печати:ТабДок.Напечатать(РежимИспользованияДиалогаПечати.Использовать); ТабДок.Напечатать(ложь);

Кроме того можно управлять и разбиением документа на страницы. Оценить количество страниц в документе по настройкам текущего принтера можно так:

ТабДок.КоличествоСтраниц();

С помощью методов «ПроверитьВывод()» и «ПроверитьПрисоединение()» можно определить, умещается ли табличный документ или массив областей табличного документа на странице в высоту и в ширину при текущих настройках принтера.Надо иметь ввиду, что работа последних трех методов зависит от установленного принтера. Если методу не удается его найти, вызывается исключение.

Принудительно вставить разрывы страниц позволяют методы «ВывестиВертикальныйРазделительСтраниц()» и «ВывестиГоризонтальныйРазделительСтраниц()».Таким образом, можно управлять постраничным выводом на печать и контролировать заполнение страницы:

Если Не ТабДок.ПроверитьВывод(МассивВыводимыхОбластей) Тогда ТабДок.ВывестиГоризонтальныйРазделительСтраниц();КонецЕсли;

Категория: Табличный документ

Отображение PDF файлов в 1С используя ActiveX Adobe PDF Reader

Часто при разработке какого-либо функционала в 1С мы делаем прикрепление файлов pdf.
Итак, Первым делом идет Выбор файла, далее нужно быстро просмотреть приложенный файл.
Для решения используются следующие варианты:
файл Выбирается по кнопке Выбор файла и помещается в Реквизит с типом Хранилище Значений

Код 1C v 8.х

 Процедура КнопкаВыбратьСканНажатие(Элемент)

	Диалог = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);

	Диалог.Заголовок = "Выберите файл";

	Диалог.ПолноеИмяФайла = ""; 

	Фильтр = "Все файлы (*.*)|*.*";

	Диалог.Фильтр = Фильтр; 

	Если Диалог.Выбрать() Тогда

		Попытка

			ПутьКВнешнемуФайлу = Диалог.ПолноеИмяФайла;

			СканФайл = Новый ХранилищеЗначения(Новый ДвоичныеДанные(ПутьКВнешнемуФайлу));

			СканНазвание = СтрЗаменить(Диалог.ПолноеИмяФайла, Диалог.Каталог,"");

		Исключение

			СканНазвание = "ОШИБКА!";

			Сообщить(ОписаниеОшибки());

		КонецПопытки; 		

	КонецЕсли;  

КонецПроцедуры

Для открытия используем:
1. Открытие файла в программе Adobe Acrobat Reader
для этого используйте код:

Код 1C v 8.х

 Процедура ОсновныеДействияФормыПечатьСканВорд(Кнопка)

	ИмяМакета = СканФайл;	

	Если Прав(СканНазвание,3)="doc" или Прав(СканНазвание,3)="docx" Тогда

		Состояние("Идет печать в Word");

		УниверсальныеМеханизмы.НапечататьВнешнююФорму(Ссылка, ИмяМакета);

	Иначе

		ИмяКаталога = КаталогВременныхФайлов();

		ИмяФайла = "vrem" + Формат(ТекущаяДата(),"ДФ=yyyyMMddhhmmss")+СокрЛП(Прав(СканНазвание,5));

		ИмяФайла = РаботаСФайлами.ПолучитьИмяФайла(ИмяКаталога, ИмяФайла);

		ДвоичныеДанные = ИмяМакета.Получить();

		Если ДвоичныеДанные = Неопределено Тогда

			Предупреждение("Не могу открыть файл, прикрепите новый внешний файл!");

		Иначе

			ДвоичныеДанные.Записать(ИмяФайла);

			ЗапуститьПриложение(ИмяФайла);

		КонецЕсли; 

	КонецЕсли;  	

КонецПроцедуры

2. Добавляем на форму элемент ActiveX Adobe PDF Reader
для этого используйте код:

Код 1C v 8.х

 Процедура ОсновныеДействияФормыПечатьСканВорд(Кнопка)

	ИмяМакета = СканФайл;	

	Если Прав(СканНазвание,3)="doc" или Прав(СканНазвание,3)="docx" Тогда

		Состояние("Идет печать в Word");

		УниверсальныеМеханизмы.НапечататьВнешнююФорму(Ссылка, ИмяМакета);

	Иначе

		ИмяКаталога = КаталогВременныхФайлов();

		ИмяФайла = "vrem" + Формат(ТекущаяДата(),"ДФ=yyyyMMddhhmmss")+СокрЛП(Прав(СканНазвание,5));

		ИмяФайла = РаботаСФайлами.ПолучитьИмяФайла(ИмяКаталога, ИмяФайла);

		ДвоичныеДанные = ИмяМакета.Получить();

		Если ДвоичныеДанные = Неопределено Тогда

			Предупреждение("Не могу открыть файл, прикрепите новый внешний файл!");

		Иначе

			ДвоичныеДанные.Записать(ИмяФайла);

			// Вывод в элемент ActiveX Adobe PDF Reader

			ЭлементыФормы.PDFСканДоговор.LoadFile(ИмяФайла);

		КонецЕсли; 

	КонецЕсли;  	

КонецПроцедуры

Вот так это выглядит:
title

Категория: OLE, ActiveX

Как напечатать документ на определенном принтере из сеанса RDP (Терминал)

В 1С есть возможность обратиться к принтеру по имени перед печатью, однако при работе через терминал к названию принтера добавляется (перенаправлено N), где N постоянно меняется. Решение следующее:

Код 1C v 8.2 УП

 

&НаКлиенте

Функция ИмяПринтераRDP(ИмяПринтера) 

	Shell = Новый COMОбъект("Wscript.Shell");	

	Task = Shell.Exec("query session");

	РезультатЗапроса = Task.StdOut.ReadAll();

	РезультатЗапроса = Декодер(РезультатЗапроса, "windows-1251", "cp866");

        Task.Terminate();

	Shell = Неопределено;

	

	Network = Новый COMОбъект("WScript.Network");

	ПользовательОС = Network.UserName();

	Network = Неопределено;

	

        НомерСеанса = RegExpGetFirstMatch("rdp-tcp\S+\s+" + ПользовательОС + "\s+(\d+)", РезультатЗапроса);

	

	Возврат ИмяПринтера + " (перенаправлено " + НомерСеанса + ")";

	

КонецФункции





Функция Декодер(Стр, Вход, Выход)

	Stream = Новый COMОбъект("Adodb.Stream");

	Stream.Type = 2;

	Stream.Mode = 3;

	Stream.Charset = Вход;

	Stream.Open();

	Stream.WriteText(Стр);

	Stream.Position = 0;

	Stream.Charset = Выход;

	Результат = Stream.ReadText(-1);

	Stream.Close();

	Возврат Результат;

КонецФункции



Функция RegExpGetFirstMatch(Маска, Строка, МногострочныйРежим = Истина, ГлобальныйПоиск = Истина, БезУчетаРегистра = Истина) 

	

	RegExp = Новый COMОбъект("VBScript.RegExp");

	

	// Параметры

	RegExp.Multiline = МногострочныйРежим; 

	RegExp.Global = ГлобальныйПоиск;

	RegExp.IgnoreCase = БезУчетаРегистра;	

	RegExp.Pattern = Маска;	

	

	Matches = RegExp.Execute(Строка);

	

	Если Matches.Count = 1 тогда

		Возврат Matches.Item(0).SubMatches.Item(0);



	Иначе

		Возврат Неопределено;

			

	КонецЕсли;

		

КонецФункции

Категория: Полезные, Универсальные Функции

QR код в 1С

Столкнулся с интересной задачей реализации генерации QR-кода в 1С 8.2 ( QR-код — матричный код (двухмерный штрихкод) ) Для генерации было использовано api от google (http://chart.apis.google.com/chart). Вот сайт, который работает с ним. После того, как вы вводите все параметры кода и нажимаете кнопку генерировать, получаем что-то вроде такой ссылки. По сути эта ссылка нам и нужна. Создав необходимый url можно скачать картинку, которая генерируется с помощью api.
И так в чем заключается подход:
1. Генерируем текст, который надо прописать в qr-коде.
2. Используя ссылку «http://chart.apis.google.com/chart?cht=qr&chs=230?230&chl=» +»Наш текст» скачиваем картинку.
3. Размещаем картинку в нашем табличном документе.
Код реализации:

Код 1C v 8.2 УП

 &НаСервере

Функция hex(Знач Значение)

    Значение=Число(Значение);

    Если Значение<=0 Тогда

        Результат="0";

    Иначе

        Значение=Цел(Значение);

        Результат="";

        Пока Значение>0 Цикл

            Результат=Сред("0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ",Значение%16 + 1,1)+Результат;

            Значение=Цел(Значение/16) ;

        КонецЦикла;

    КонецЕсли;

    Если СтрДлина(Результат) < 2 Тогда



        Результат = "0" + Результат;



    КонецЕсли;

    Возврат "%" + Результат;

КонецФункции



&НаСервере

Функция EncodeURL(URL)

    Рез = "";

    Для Сч = 1 По СтрДлина(URL) Цикл

        ch = Сред(URL,Сч,1);

        vch = КодСимвола(ch);



        Если ("A" <= ch ) И ( ch <= "Z") Тогда      // "A".."Z"

            Рез = Рез + ch;

        ИначеЕсли ("a" <= ch ) И ( ch <= "z") Тогда // "a".."z"

            Рез = Рез + ch;

        ИначеЕсли ("0" <= ch ) И ( ch <= "9") Тогда // "0".."9"

            Рез = Рез + ch;

        ИначеЕсли (ch = " ") ИЛИ ( ch = "+") Тогда          // space

            Рез = Рез + "+";

        ИначеЕсли (ch = "-" ) ИЛИ ( ch = "_")       // unreserved

            ИЛИ (ch = ".") ИЛИ (ch = "!")

            ИЛИ (ch = "~") ИЛИ (ch = "*")

            ИЛИ (ch = "") ИЛИ (ch = "(")

            ИЛИ (ch = ")") Тогда

            Рез = Рез + ch;

        ИначеЕсли (vch <= 127) Тогда        // other ASCII

            Рез = Рез + hex(vch);

        ИначеЕсли (vch <= 2047) Тогда       // non-ASCII <= 0x7FF

            Рез = Рез + hex(192 + Цел(vch / 64));

            Рез = Рез + hex(128 + (vch % 64));

        Иначе                   // 0x7FF < ch <= 0xFFFF

            Рез = Рез + hex(224 + Цел(vch / 4096));

            Рез = Рез + hex(128 + (Цел(vch / 64) % 64));

            Рез = Рез + hex(128 + (vch % 64));

        КонецЕсли;

    КонецЦикла;



    Возврат Рез;

КонецФункции // ()



&НаСервере

Функция СохранитьДвоичныйБуферВФайл(Буфер, ИмяФайла) Экспорт

    Поток = Новый COMОбъект("ADODB.Stream");

    Поток.Type = 1;  //Бинарный

    Поток.Mode = 3;

    Поток.Open();

    Поток.Write(Буфер);

    Поток.SaveToFile(ИмяФайла);

    Поток.Close();

КонецФункции



&НаСервере

Функция НапечататьКодСервер(ЗаказСсылка)

    ТабДок = Новый ТабличныйДокумент;

    ИмяВременногоФайла = ПолучитьИмяВременногоФайла("png");

    АдресНачало = "http://chart.apis.google.com/chart?cht=qr&chs=230x230&chl=";

    АдресКонец = ЗаказСсылка.Номер  + Символы.ПС + Заказссылка.Контрагент.Наименование;

    АдресКонец = СтрЗаменить(АдресКонец, " ", "+");

    АдресКонец = EncodeURL(АдресКонец);



    Соединение = ПолучитьCOMОбъект("","Microsoft.XMLHTTP");

    Соединение.open("GET", АдресНачало + АдресКонец,0,,);

    Соединение.send(null);

    СохранитьДвоичныйБуферВФайл(Соединение.responseBody, ИмяВременногоФайла);



    //Печать

    Макет = Документы.ЗаказПокупателя.ПолучитьМакет("МакетПечатиКода");

    Область = Макет.ПолучитьОбласть("Код");

    Область.Рисунки.КодРисунок.Картинка = Новый Картинка(ИмяВременногоФайла);

    ТабДок.Вывести(Область);

    Возврат ТабДок;

КонецФункции

Источник

Категория: COM-объекты, WMI, WSH

Выгрузка в PDF из 1С (Средствами OpenOffice)

Возникла задача отправлять счета почтой. PDFcreator не подошёл поскольку не удалось вместить счёт на одну страницу по ширине. Решил попробовать OpenOffice. Как сохранять в PDF нашёл быстро, а вот как уместить счёт на одну страницу вширь искал долго.
В версии 1С 8.2.232 появилась возможность сохранять табличный документ в xls файл на сервера под линуксом. А вот работать с Опеном офисом из-под линукса пока не получается. Собственно комментари ненужны. Вот весь код. Самое интересное это бодание со стилями страниц в Опене Офисе. Жаль что этот фрагмент работает только на клиенте. На сервере вопрос не решается *08

Код 1C v 8.2 УП

 Процедура КнопкаВыполнитьНажатие(Кнопка)

    Если Письмо.Основание.Пустая() Тогда

        Возврат

    КонецЕсли;



    // Открыть OpenOffice

    Попытка

        ServiceManager = Новый COMОбъект("com.sun.star.ServiceManager");

    Исключение

        Возврат // опен офис не установлен :-(

    КонецПопытки;



    // получим печатную форму и запишем её во временный XLS файл

    Заказ = Письмо.Основание.ПолучитьОбъект();



    //Получим печатную форму

    Расшифровка=Новый Структура;

    Расшифровка.Вставить("СсылкаНаВнешнююОбработку",Константы.ПФСчетаДляКлиента.Получить());

    Расшифровка.Вставить("ВидПечатнойФормы",Перечисления.ВидыДополнительныхВнешнихОбработок.ПечатнаяФорма);

    Расшифровка.Вставить("НомерСтроки",1);

    тд = УниверсальныеМеханизмы.НапечататьВнешнююФорму(Заказ, Расшифровка);



    ВременныйФайл =ПолучитьИмяВременногоФайла();

    ВременныйФайлXLS =ВременныйФайл + ".xls";

    ВременныйФайлPDF =ВременныйФайл + ".pdf";

    тд.Записать(ВременныйФайлXLS, ТипФайлаТабличногоДокумента.XLS97);



    // Преобразовываем временный xls файл В PDF

    Desktop        = ServiceManager.createInstance("com.sun.star.frame.Desktop");



    НастройкиОткрытия = Новый COMSafeArray("VT_VARIANT", 1);

    PropertyValue = ServiceManager.Bridge_GetStruct("com.sun.star.beans.PropertyValue");

    PropertyValue.Name = "Hidden";

    PropertyValue.Value = Истина;

    НастройкиОткрытия.SetValue(0, PropertyValue);

    ВременныйФайлXLS_какУРЛ = "file:///" + СтрЗаменить(ВременныйФайлXLS, "\", "/"); // приводим путь к файлу из виндового формата в опен офисный



    // Откроем файл в опене офисе

    ОпенОфис = Desktop.LoadComponentFromURL(ВременныйФайлXLS_какУРЛ, "_blank", 0, НастройкиОткрытия);



    //ПараметрыСтраницы = ОпенОфис.createInstance("com.sun.star.style.PageStyle");

    //ПараметрыСтраницы.ScaleToPagesX = 1;

    //

    // Установим масштаб, чтобы счёт помещался на одной странице вширь

    // страниц почему-то много, поэтому устанавливаем масштаб для всех

    Стили = ОпенОфис.StyleFamilies.getByName("PageStyles");

    Для поз = 0 по Стили.count - 1 Цикл

        МойСтиль = Стили.getByIndex(поз);

        МойСтиль.ScaleToPagesX = 1; // уместить на одной странице вширь

        //МойСтиль.PageScale = 50; // масштаб 50%

    КонецЦикла;



    НастройкиСохранения = Новый COMSafeArray("VT_VARIANT", 1);

    PropertyValue = ServiceManager.Bridge_GetStruct("com.sun.star.beans.PropertyValue");

    PropertyValue.Name = "FilterName";

    PropertyValue.Value = "calc_pdf_Export";

    НастройкиСохранения.SetValue(0, PropertyValue);



    ВременныйФайлPDF_какУРЛ = "file:///" + СтрЗаменить(ВременныйФайлPDF, "\", "/"); // приводим путь к файлу из виндового формата в опен офисный

    ОпенОфис.storeToURL(ВременныйФайлPDF_какУРЛ, НастройкиСохранения); // сохранили PDF файл

    ОпенОфис.close(-1);

    ОпенОфис = Неопределено;



    // С опеном офисом разобрались. Прикрепляем вложение к письму и удаляем временные файлы.

    //Файл = Новый Файл(ВременныйФайлPDF);

    объектПисьмо = Письмо.ПолучитьОбъект();

    стрВложение = объектПисьмо.Вложения.Добавить();

    стрВложение.ИмяФайла = "Счёт " + Строка(Заказ.Номер) + ".pdf";

    стрВложение.Файл = Новый ХранилищеЗначения(Новый ДвоичныеДанные(ВременныйФайлPDF));

    объектПисьмо.Записать();

    Попытка

        УдалитьФайлы(ВременныйФайлXLS);

        УдалитьФайлы(ВременныйФайлPDF);

    Исключение

    КонецПопытки;



КонецПроцедуры

Автор: Трактор

Функция позволяющая выполнить выгрузку табличного документа в PDF средствами OpenOffice

Код 1C v 8.х

 // Функция превращает табличный документ в PDF документ

// Возвращаемое значение: тип "Строка" - имя созданного PDF файла, 0 - в случае ошибки

// Параметры: ДанныеВыгрузки - Табличный или текстовый документ, который нужно выгрузить в PDF

//            ПутьВыгрузки - тип "Строка", путь для сохраниения PDF файла (без имени и расширения файла)

//            ИмяФайлаБезРасширения - тип "Строка", имя для вновь сформированного PDF файла

// Тестировалось на OpenOffice 3.x

Функция ВыгрузитьТабличныйДокументВPDF(ДанныеВыгрузки, ПутьВыгрузки, ИмяФайлаБезРасширения)       

    Если НЕ ЗначениеЗаполнено(ПутьВыгрузки) Тогда

        ПутьВыгрузки = КаталогВременныхФайлов();

    КонецЕсли;   

    ПутьВыгрузки         = ?(Прав(ПутьВыгрузки, 1) = "\", ПутьВыгрузки, ПутьВыгрузки + "\");

   

    РасширениеXSL         = ".xls";

    РасширениеPDF         = ".pdf";

    ПолноеИмяФайлаXLS     = ПутьВыгрузки + ИмяФайлаБезРасширения + РасширениеXSL;

    //Выгрузка данных печати в файл XLS   

#Если Клиент Тогда

    Состояние("Создание временного файла...");

#КонецЕсли

    Попытка

        Если         ТипЗнч(ДанныеВыгрузки) = Тип("ТабличныйДокумент") Тогда        

            ДанныеВыгрузки.Записать(ПолноеИмяФайлаXLS, "XLS");

        ИначеЕсли     ТипЗнч(ДанныеВыгрузки) = Тип("ТекстовыйДокумент") Тогда

            ДанныеВыгрузки.Записать(ПолноеИмяФайлаXLS, "XLS");

        Иначе

#Если Клиент Тогда

            Сообщить("Данные для выгрузки переданы в неподдерживаемом формате. Дальнейшее выполнение невозможно." + Символы.ПС + ОписаниеОшибки());

#КонецЕсли

            Возврат 0;

        КонецЕсли;

    Исключение

#Если Клиент Тогда

        Сообщить("Произошла ошибка при выгрузке временного файла. Возможно ошибка доступа к папке, в которую происходит запись." + Символы.ПС + ОписаниеОшибки());

#КонецЕсли

        Возврат 0;

    КонецПопытки;

   

    Попытка

#Если Клиент Тогда

        Состояние("Открытие компоненты OpenOffice...");

#КонецЕсли

        ServiceManager    = Новый COMОбъект("com.sun.star.ServiceManager");       

       

        Скрипт             = Новый COMОбъект("MSScriptControl.ScriptControl");

        Скрипт.language    = "javascript";

        Скрипт.AddObject("OpenOffice", ServiceManager);

       

        //Открытие временного файла без отображения его окна

#Если Клиент Тогда           

        Состояние("Открытие временного файла...");

#КонецЕсли

        Скрипт.eval("Массив=new Array()");       

        Массив             = Скрипт.eval("Массив");   

        Скрипт.eval("Массив[0] = OpenOffice.Bridge_GetStruct('com.sun.star.beans.PropertyValue')");

        Скрипт.eval("Массив[0].Name     = 'Hidden'");

        Скрипт.eval("Массив[0].Value = true");

       

        Скрипт.AddCode("function SetItem(ind,val){Массив[ind]=val}");       

        Скрипт.AddObject("ServiceManager",ServiceManager);

        Desktop         = ServiceManager.createInstance("com.sun.star.frame.Desktop");       

        Document         = Desktop.LoadComponentFromURL("file:///" + ПолноеИмяФайлаXLS, "_blank", 0, Массив);

       

        //Сохранение в PDF встроенными средствами OpenOffice

#Если Клиент Тогда           

        Состояние("Запись в PDF...");

#КонецЕсли

        Скрипт.eval("Массив2=new Array()");       

        Массив2     = Скрипт.eval("Массив2");       

        Скрипт.eval("Массив2[0] = OpenOffice.Bridge_GetStruct('com.sun.star.beans.PropertyValue')");       

        Скрипт.eval("Массив2[0].Name  = 'FilterName'");

        Скрипт.eval("Массив2[0].Value = 'writer_pdf_Export'");

       

        ПолноеИмяФайлаPDF         = "file:///" + СтрЗаменить(ПолноеИмяФайлаXLS, РасширениеXSL, РасширениеPDF);

        ПолноеИмяФайлаPDF         = СтрЗаменить(ПолноеИмяФайлаPDF, ВРег(РасширениеXSL), РасширениеPDF);

        ПолноеИмяФайлаPDF        = СтрЗаменить(ПолноеИмяФайлаPDF, "\", "/");       

               

        Document.storeToURL(ПолноеИмяФайлаPDF, Массив2);

        Document.close(-1);        //Закрыть документ

       

        //Контрольная очистка переменных

        Document     = Неопределено;

        Desktop     = Неопределено;

       

        //Удаление временного файла

#Если Клиент Тогда           

        Состояние("Удаление временного файла...");

#КонецЕсли       

        Попытка

            УдалитьФайлы(ПолноеИмяФайлаXLS);

        Исключение

#Если Клиент Тогда           

            Сообщить("Произошла ошибка при удалении временного файла. Возможно, потребуется удалить его вручную." + Символы.ПС + ОписаниеОшибки());

#КонецЕсли

        КонецПопытки;

       

        ПолноеИмяФайлаPDF = СтрЗаменить(ПолноеИмяФайлаPDF, "file:///", "");

        ПолноеИмяФайлаPDF = СтрЗаменить(ПолноеИмяФайлаPDF, "/", "\");

#Если Клиент Тогда

        Состояние("Выгрузка выполнена.");

        Предупреждение("Выгрузка выполнена." + Символы.ПС + ПолноеИмяФайлаPDF);       

#КонецЕсли

        Возврат ПолноеИмяФайлаPDF;

    Исключение

        Document.close(-1);

#Если Клиент Тогда

        Предупреждение(ОписаниеОшибки());

#КонецЕсли

        Возврат 0;

    КонецПопытки   

КонецФункции

Автор: doom_2001

Категория: Работа с Microsoft Office и OpenOffice

Печать в PDF

Столкнулся с вопросом печати счета на оплату сразу в pdf.
Решение: установка виртуального принтера bioPDF скачать можно тут. И прописывание в 1с следующего кода:

Код 1C v 8.х

 

    Попытка

        ПДФ_принтер = Новый COMОбъект("bioPDF.PDFPrinterSettings");

    Исключение

        #Если Клиент Тогда

            Предупреждение("Не удалось подключиться к PDF-принтеру!", 60);

        #КонецЕсли

        Возврат;

    КонецПопытки;

    ПДФ_принтер_имя = ПДФ_принтер.GetPrinterName();

    ИмяФайла = Константы.КаталогФайловПДФ.Получить() +"" + Заголовок + ".pdf";



    ПДФ_принтер.SetValue("output",    ИмяФайла);

    ПДФ_принтер.SetValue("ConfirmOverwrite", "yes");

    ПДФ_принтер.SetValue("ShowSaveAS",   "never");

    ПДФ_принтер.SetValue("ShowSettings",  "never");

    ПДФ_принтер.SetValue("ShowPDF",    "no");

    ПДФ_принтер.SetValue("Target",    "printer");



    ПДФ_принтер.SetValue("Subject",  "Report generated at " + ТекущаяДата());

    ПДФ_принтер.SetValue("UseThumbs", "yes");

    ПДФ_принтер.SetValue("Zoom",  "100");



    ПДФ_принтер.SetValue("WatermarkFontSize", "10");

    ПДФ_принтер.SetValue("WatermarkTransparency", "50");

    ПДФ_принтер.SetValue("WatermarkVerticalPosition", "bottom");

    ПДФ_принтер.SetValue("WatermarkHorizontalPosition", "right");

    ПДФ_принтер.SetValue("WatermarkVerticalAdjustment", "3");

    ПДФ_принтер.SetValue("WatermarkHorizontalAdjustment", "1");

    ПДФ_принтер.SetValue("WatermarkRotation", "90");

    ПДФ_принтер.SetValue("WatermarkColor", "#ff0000");

    ПДФ_принтер.SetValue("WatermarkOutlineWidth", "1");

    ПДФ_принтер.WriteSettings(True);



    ПечатныйДокумент.ИмяПринтера = ПДФ_принтер_имя;

    ПечатныйДокумент.АвтоМасштаб = Истина;

    ПечатныйДокумент.Напечатать();

Как выяснилось во время печати в pdf есть проблема с передачей прозрачности картинки. Если вставлять прозрачную печать в счет поверх подписи, то в pdf-документе печать будет непрозрачной и затрет все собой. У меня был частный случай, когда печать находилась на одном и том же месте документа и за ней постоянно было одно и то же. Решением в данном случае стала генерация картинки печати с фоном, на котором она должна быть и вставка её в макет.

Так же решением может быть печать не в pdf а xps документ. Там с прозрачностью все нормально.
Автор: Андрей Данилюк

Экспорт печатных форм и любых данных из 1С в BMP, JPEG, PCX, PDF, PNG и TIFF.

Категория: COM-объекты, WMI, WSH

Экспорт печатных форм и любых данных из 1С в BMP, JPEG, PCX, PDF, PNG и TIFF.

Оптимальным решением является установка Bullzip PDF Printer . После установки в системе появляется виртуальный принтер, с помощью которого можно "печатать" в файл pdf из любого приложения. Программа бесплатная, работает в терминале и имеет поддержку русского языка.
После установки, можно печатать напрямую используя код:

Код 1C v 8.х

 

//Таб - ТабличныйДокумент

//ИмяФайла – путь для сохранения файла PDF  (например «D:\Torg12.pdf»)

Процедура СоздатьФайлПДФ(Таб, ИмяФайла)



Попытка

ПДФПринтер = Новый ComObject(«Bullzip.PDFPrinterSettings»);

ПДФПринтер.SetValue(«output», ИмяФайла);

ПДФПринтер.SetValue(«ShowSaveAS», «never»);

ПДФПринтер.SetValue(«ShowProgress», «no»);

ПДФПринтер.SetValue(«ShowProgressFinished», «no»);

ПДФПринтер.SetValue(«ShowSettings», «never»);

ПДФПринтер.SetValue(«ShowPDF», «no»);

ПДФПринтер.SetValue(«ConfirmOverwrite»,»no»);

ПДФПринтер.WriteSettings();

Таб.Автомасштаб = Истина;

Таб.ИмяПринтера = «Bullzip PDF Printer»;Таб.Напечатать(Истина);

PDFФайл = Новый Файл(ИмяФайла);



Пока НЕ PDFФайл.Существует() Цикл

ОбработкаПрерыванияПользователя();

КонецЦикла;



Исключение



Сообщить(ОписаниеОшибки());

Сообщить(«Скорее всего необходимо установить или переустановить «»Bullzip PDF Printer»);

КонецПопытки;

//устанавливаем принтер по умолчанию

Таб.ИмяПринтера = ПолучитьПринтерПоУмолчанию();

КонецПроцедуры

Здесь функция ПолучитьПринтерПоУмолчанию() нужна для того чтобы вернуть печатной форме принтер по умолчанию, т.к. если напечатать без предварительного просмотра то печать пойдет на виртуальный PDF принтер BullzipPDFPrinter.

Код 1C v 8.х

 //получаем принтер по умолчанию

Функция ПолучитьПринтерПоУмолчанию()



Скрипт = Новый ComObject(«MSScriptControl.ScriptControl»);

Скрипт.Language = «vbscript»;

Скрипт.AddCode(»

|Function GetDefaultPrinter()

|GetDefaultPrinter=vbNullString

|Set objWMIService=GetObject(«»winmgmts:»" _

|& «»{impersonationLevel=impersonate}!\\.\root\cimv2&#8243;»)

|Set colInstalledPrinters=objWMIService.ExecQuery _

|(«»S_elect * from Win32_Printer»")

|For Each objPrinter in colInstalledPrinters

|If objPrinter.Attributes and 4 Then

|GetDefaultPrinter=objPrinter.Name

|Exit For

|End If

|Next

|End Function»);

Возврат СокрЛП(Скрипт.run(«GetDefaultPrinter»));

КонецФункции

Печать в PDF используя bioPDF

Категория: Администрирование