периоду » Поиск

Результаты по ключевому слову: периоду

Добавление в набор сторно-записей

Если в рассчитываемом регистре установлено свойство Период действия, в сформированном наборе могут присутствовать записи, у которых период действия принадлежит более раннему периоду, чем период регистрации. В этом случае они могут вступать в конкуренцию на этом периоде действия с записями более раннего периода регистрации. Чтобы такие записи могли иметь непустой фактический период действия, необходимо допол- нить сформированный набор соответствующими сторно-записями.

Добавление сторно-записей происходит с использованием метода ПолучитьДополнение() набора записей регистра. Ниже приведен текст модуля, позволяющий добавить в набор сторно-записи. Добавление записи происходит при помощи вызова процедуры ДобавитьСтрокуСторноОсновныхНачислений(), которая должна быть описана в процедуре РассчитатьОсновныеНачисления(). При этом для каждой сторно- записи необходимо добавить новую строку в табличную часть документа, чтобы при проведении эта запись попала в регистр

Код 1C v 8.х

 // Добавить сторно-записи в набор и в табличную часть.

Процедура ДобавитьСтрокуСторноОсновныхНачислений(ДанныеСтроки,

НаборЗаписей, ТабличнаяЧасть = Неопределено)

Движение = НаборЗаписей.Добавить();

// Предопределенные поля.

Движение.ПериодРегистрации = ДанныеСтроки.ПериодРегистрацииСторно;

Движение.ПериодДействияНачало = ДанныеСтроки.ПериодДействияНачалоСторно;

Движение.ПериодДействияКонец = ДанныеСтроки.ПериодДействияКонецСторно;

Движение.ВидРасчета = ДанныеСтроки.ВидРасчета;

Движение.Сторно = Истина;

// Измерения.



Движение.ФизЛицо = ДанныеСтроки.ФизЛицо;



Движение.Организация = ДанныеСтроки.Организация;

// Реквизиты.

Движение.ГрафикРаботы = ДанныеСтроки.ГрафикРаботы;

Движение.Размер = ДанныеСтроки.Размер;

Движение.ВидУчетаВремени = ДанныеСтроки.ВидУчетаВремени;

Движение.Подразделение = ДанныеСтроки.Подразделение;

Движение.СтатьяЗатрат = ДанныеСтроки.СтатьяЗатрат;

Если Не ТабличнаяЧасть = Неопределено Тогда

НоваяСтрока = ТабличнаяЧасть.Добавить();

НоваяСтрока.ФизЛицо = ДанныеСтроки.ФизЛицо;

НоваяСтрока.ВидРасчета = ДанныеСтроки.ВидРасчета;

НоваяСтрока.ДатаНачало = ДанныеСтроки.ПериодДействияНачалоСторно;

НоваяСтрока.ДатаКонец = ДанныеСтроки.ПериодДействияКонецСторно;

НоваяСтрока.Размер = ДанныеСтроки.Размер;

НоваяСтрока.Подразделение = ДанныеСтроки.Подразделение;

НоваяСтрока.Сторно = Истина;

КонецЕсли;

КонецПроцедуры // ДобавитьСтрокуСторноОсновныхНачислений

// Процедура расчета основных начислений.

Процедура РассчитатьОсновныеНачисления() Экспорт

НачатьТранзакцию();

// Сформировать набор записей.

// …

// Сформировать таблицу сторно-записей.

ТаблицаСторно = НаборОсновныеНачисления.ПолучитьДополнение();

// Добавить сторно-записи в набор.

Для Каждого СтрокаСторно из ТаблицаСторно Цикл

ДобавитьСтрокуСторноОсновныхНачислений(СтрокаСторно,

НаборОсновныеНачисления,

ОсновныеНачисления);

КонецЦикла;



// …

ЗафиксироватьТранзакцию();

КонецПроцедуры // РассчитатьОсновныеНачисления

При формировании сторно-записей данные всех измерений и реквизитов записи указаны в строке дополнения. Также в этой строке содержатся данные о периоде регистрации и периоде действия сторно-записи. Ресурсы сторно-записи не заполняются, так как запись будет рассчитана в общем порядке

Категория: Регистры расчета

Как в запросе получить срез последних на Каждую Дату

Данная задача может быть решена как с использованием вложенных запросов, так и с помощью. временных таблиц. Попробуем решить задачу, используя временные таблицы. Сначала приведем весь текст запроса, а потом кратко разберем по частям принцип его работы.

Текст запроса:

Код 1C v 8.х

 ВЫБРАТЬ

    ПродажиОбороты.Период КАК Дата,

    ПродажиОбороты.Контрагент КАК Контрагент,

    ПродажиОбороты.Номенклатура КАК Номенклатура,

    СУММА(ПродажиОбороты.КоличествоОборот) КАК Количество,

    СУММА(ПродажиОбороты.СтоимостьОборот) КАК Стоимость

ПОМЕСТИТЬ втБезЦены

ИЗ

    РегистрНакопления.Продажи.Обороты(&НачалоПериода, &КонецПериода, День, ) КАК ПродажиОбороты



СГРУППИРОВАТЬ ПО

    ПродажиОбороты.Период,

    ПродажиОбороты.Контрагент,

    ПродажиОбороты.Номенклатура



ИНДЕКСИРОВАТЬ ПО

    Номенклатура,

    Дата,

    Контрагент

;



////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ

    втБезЦены.Дата КАК Дата,

    втБезЦены.Контрагент КАК Контрагент,

    втБезЦены.Номенклатура КАК Номенклатура,

    втБезЦены.Количество,

    втБезЦены.Стоимость,

    МАКСИМУМ(ЦеныНоменклатуры.Период) КАК Период

ПОМЕСТИТЬ втМаксПериод

ИЗ

    втБезЦены КАК втБезЦены

        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры

        ПО втБезЦены.Номенклатура = ЦеныНоменклатуры.Номенклатура

            И втБезЦены.Дата >= ЦеныНоменклатуры.Период



СГРУППИРОВАТЬ ПО

    втБезЦены.Дата,

    втБезЦены.Контрагент,

    втБезЦены.Номенклатура,

    втБезЦены.Количество,

    втБезЦены.Стоимость



ИНДЕКСИРОВАТЬ ПО

    Номенклатура,

    Дата,

    Контрагент,

    Период

;



////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ

    втМаксПериод.Дата,

    втМаксПериод.Контрагент,

    втМаксПериод.Номенклатура,

    втМаксПериод.Количество,

    втМаксПериод.Стоимость,

    ЦеныНоменклатуры.Цена

ИЗ

    втМаксПериод КАК втМаксПериод

        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры

        ПО втМаксПериод.Номенклатура = ЦеныНоменклатуры.Номенклатура

            И втМаксПериод.Период = ЦеныНоменклатуры.Период

ГДЕ

    ЦеныНоменклатуры.ТипЦен = &ТипЦен

АВТОУПОРЯДОЧИВАНИЕ

Данный пакетный запрос содержит три подзапроса. Рассмотрим их подробнее.

Первый запрос пакета группирует данные по периоду, контрагенту и номенклатуре и помещает их во временную таблицу втБезЦены. Далее мы будем соединять эту таблицу с таблицей цен номенклатуры и получим небольшой выигрыш в том, что соединять будем уже сгруппированные данные.

Во втором подзапросе мы соединяем временную таблицу с регистром сведений «ЦеныНоменклатуры» при этом из регистра сведений мы выбираем МАКСИМАЛЬНУЮ дату из меньших или равных дат. Результат этого подзапроса также помещаем во временную таблицу (втМаксПериод). Посмотрим, какие данные попадают в эту таблицу:
title

Рис. 8 Временная таблица втМаксПериод

В последнем запросе пакета, мы еще раз соединяем временную таблицу с таблицей цен номенклатуры. На этот мы соединяем таблице по номенклатуре и периоду.

Итоговый результат запроса:
title

То же самое средсвами СКД

Категория: Запросы

Как в периодическом независимом регистре сведений удалить все записи по валютам с наименованиями?

Как в периодическом независимом регистре сведений «КурсыВалют» удалить все записи по валютам с наименованиями «EUR» и «USD», период которых меньше 01 января 2005 года?

Сначала получим таблицу записей, которые необходимо оставить. Поскольку условий несколько, да еще и не все они на равенство, оптимальнее это сделать при помощи запроса. Следующий запрос даст нам желаемое:

Код 1C v 8.х

 // Получение нужных записей

Запрос = Новый Запрос;

Запрос.Текст = "ВЫБРАТЬ

|	*

|ИЗ

|	РегистрСведений.КурсыВалют КАК КурсыВалют

|

|ГДЕ

|	(КурсыВалют.Период >= ДАТАВРЕМЯ(2005, 1, 1) 

|	 ИЛИ 

|	НЕ(КурсыВалют.Валюта.Наименование ПОДОБНО " "USD" ") 

|	 И 

|	НЕ(КурсыВалют.Валюта.Наименование ПОДОБНО " "EUR" "))";

Источником данных для запроса послужила таблица записей регистра.
Были применены отборы, чтобы в результат попали записи, для которых период более или равен 01 января 2005 года, или наименования не USD и не EUR. Обратите внимание: при составлении условия по периоду, чтобы не пользоваться параметром запроса, прямо в тексте запроса применили литерал даты ДАТАВРЕМЯ(), в котором части даты указываются в «обратном» порядке: год, месяц, порядковый номер дня в месяце.
Результатом запроса будет таблица, в которой по каждой записи заполнены все поля регистра сведений КурсыВалют.

Код 1C v 8.х

 // Выгрузка результата запроса

ТаблицаОставляемыхЗаписей = Запрос.Выполнить().Выгрузить();



НаборЗаписей = РегистрыСведений.КурсыВалют.СоздатьНаборЗаписей();



НаборЗаписей.Загрузить(ТаблицаОставляемыхЗаписей);



НаборЗаписей.Записать();

Далее выполняем запрос, выгружаем результат в таблицу значений ТаблицаОставляемыхЗаписей
Создаем переменную НаборЗаписей, тип значения РегистрСведенийНаборЗаписей.КурсыВалют, выгружаем в нее таблицу значений ТаблицаОставляемыхЗаписей.
Поскольку сама таблица была получена из регистра, то названия ее колонок совпадут с названиями полей регистра, а значит, загрузка пройдет успешно.
Далее записываем заполненный только нужными записями набор записей в регистр с замещением его исходных данных (как вы уже помните, параметр Замещать метода Записать() по умолчанию имеет значение Истина).

Категория: Регистры сведений

Как определяется период регистрации регистра расчета?

Есть три варианта ответов:
1. автоматически в момент ввода информации в регистр из документа-регистратора
2. программно в момент ввода информации в регистр из документа-регистратора
3. вручную после ввода записи в регистр расчета

Считается, что правильный ответ - 2. Да, действительно, видим, что в модуле документа в обработке проведения есть строки:

Код 1C v 8.х

 Движение.ПериодРегистрации = Дата;

Движения.Записать();

Вместе с тем, Максим Радченко пишет в своей книге:
"Для указания факта принадлежности записи к какому-либо периоду регистр имеет служебный реквизит ПериодРегистрации типа Дата. При записи данных в регистр платформа всегда приводит значение этого реквизита к началу того периода, в который он попадает. Например, если в регистр расчета с периодичностью месяц записать данные, где ПериодРегистрации задан как 08.04.2004, то регистр сохранит эти данные со значением поля ПериодРегистрации 01.04.2004."

Получается, что период регистрации определяется в два этапа:
а) программно в модуле документа в момент ввода информации в регистр,
б) автоматически системой при записи данных в регистр.

Ответ 2 соответствует пункту а), но сказать, что он полностью правильный, нельзя, т.к. в нем не отражен пункт б).
Вместе с тем, и ответ 1 в его текущей формулировке тоже не подходит. Ответ 3 не подходит в принципе.

Категория: Регистры расчета

Конструктор схемы компоновки данных - Закладка Настройки Категория: Схема Компоновки Данных

Как получить последнее значение регистра сведений? Категория: Регистры сведений

Функция вычисляет даты начала/конца периодов за интервал в виде таблицы значений

Код 1C v 8.х

  //Начало, Конец - начало и конец периода

//Периодичность - строка "День", "Месяц", "Неделя", "Год", "Квартал"

//Возвращает таблицу значений с колонками:

//	Начало - начало интервала

//	Конец - конец интервала

//	Номер - номер интервала (начиная с единицы)

Функция обПериодыЗаИнтервал(Начало, Конец, Периодичность="День", ВыравниваниеПоПериоду=истина)

	Перем Р, Номер, ТекПериод, СледПериод;

	Р=Новый ТаблицаЗначений();

	Р.Колонки.Добавить("Начало");

	Р.Колонки.Добавить("Конец");

	Р.Колонки.Добавить("Номер");

	

	ТекПериод=Начало;

	Номер=1;

	Пока истина Цикл

		Если Периодичность="День" Тогда

			Если ВыравниваниеПоПериоду Тогда

				ТекПериод=НачалоДня(ТекПериод);

				СледПериод=КонецДня(ТекПериод);

			Иначе

				СледПериод=обДобавитьДни(ТекПериод, 1);

			КонецЕсли;

		ИначеЕсли Периодичность="Месяц" Тогда

			Если ВыравниваниеПоПериоду Тогда

				ТекПериод=НачалоМесяца(ТекПериод);

				СледПериод=КонецМесяца(ТекПериод);

			Иначе

				СледПериод=обДобавитьМесяцы(ТекПериод, 1);

			КонецЕсли;

		ИначеЕсли Периодичность="Год" Тогда

			Если ВыравниваниеПоПериоду Тогда

				ТекПериод=НачалоГода(ТекПериод);

				СледПериод=КонецГода(ТекПериод);

			Иначе

				СледПериод=обДобавитьМесяцы(ТекПериод, 12);

			КонецЕсли;

		ИначеЕсли Периодичность="Квартал" Тогда

			Если ВыравниваниеПоПериоду Тогда

				ТекПериод=НачалоКвартала(ТекПериод);

				СледПериод=КонецКвартала(ТекПериод);

			Иначе

				СледПериод=обДобавитьМесяцы(ТекПериод, 3);

			КонецЕсли;

		ИначеЕсли Периодичность="Неделя" Тогда

			Если ВыравниваниеПоПериоду Тогда

				ТекПериод=НачалоНедели(ТекПериод);

				СледПериод=КонецНедели(ТекПериод);

			Иначе

				СледПериод=обДобавитьДни(ТекПериод, 7);

			КонецЕсли;

		Иначе

			ВызватьИсключение "Неизвестная периодичность времени:"+Периодичность;

		КонецЕсли;

		Если ТекПериод>Конец И НЕ Номер=1 Тогда

			Прервать;

		КонецЕсли;

		

		Стр=Р.Добавить();

		Стр.Начало=ТекПериод;

		Стр.Конец=СледПериод;

		Стр.Номер=Номер;

		ТекПериод=СледПериод+1; //Переходим на следующий период (добавляем одну секунду)

		Номер=Номер+1;

	КонецЦикла;

	Возврат Р;

КонецФункции

Категория: Работа с Датами (Временем)