размерсписка » Поиск

Результаты по ключевому слову: размерсписка

Как удалить Файл, Каталог? Категория: Работа с Файлами и Каталогами

Как выгрузиться в EXCEL со сводными таблицами

Пошаговый рабочий алгоритм выгрузки в EXCEL на примере выгрузки отчетов производства за смену(Автор статьи: Funny):

(1) Нарисовать форму обработки и к кнопке запуска прицепить процедуру:

Код 1C v 8.х

 Процедура КнопкаВыполнитьНажатие(Кнопка)

    

    Если ПроверкаДат() Тогда 

         Состояние("Запущена выгрузка данных");

         ПолучитьДанныеВТаблице();

         Если чОтчетов<>0 Тогда

                СортироватьТаблицу();

              ВыгрузитьТаблицуВФайл();

              ЗакрытьСистему();

              Состояние("Выгрузка завершена");

         Иначе

              //ЗакрытьСистемуАварийно();

 

         КонецЕсли;

    КонецЕсли;    

КонецПроцедуры

(2) Создадим функцию ПроверкаДат() корректного указания дат обработки
(3) Создадим процедуру ПолучитьДанныеВТаблице() выборки требуемых данных из документов в таблицу значений
(4) Создадим процедуру СортироватьТаблицу() для сортировки таблицы значений как нам нужно
(5) Создадим процедуру ВыгрузитьТаблицуВФайл() выгрузки ТЗ в Excel-файл:

Код 1C v 8.х

 Процедура ВыгрузитьТаблицуВФайл()

    

        //1. Open Excel-file 

 

               Если FileOfReports = Неопределено Тогда

            Попытка

                FileOfReports = Новый COMОбъект("Excel.Application");

                MyBook=FileOfReports.WorkBooks.Add(истина); //вместо истина можно вставить имя шаблона

 

                

                FirstSheet=MyBook.Worksheets(1);

                FirstSheet.Name = ОпределитьДату(НачПериода)+"-"+ОпределитьДату(КонПериода);

                FirstSheet.Activate();



                MyBook.SaveAs(КаталогDBF+"ОтчетыПроизводства.xls");

                

            Исключение

                Сообщить("ОШИБКА ЗАПИСИ В EXCEL-ФАЙЛ:"+ОписаниеОшибки());

                Сообщить("Совет: Возможно файл, в который должна быть произведена запись, Вами открыт для просмотра");

                Сообщить("Если это так, то закройте файл и запустите данную обработку повторно!");

            КонецПопытки;

            

            FileOfReports.Visible = 0;

        Иначе

            FileOfReports.Visible = 0;

            //FileOfReports.Visible = 1;

 

        КонецЕсли;

    

        //2.=========================================================================

        //Состояние("Анализ структуры файла...");

         

        чОтчетов = ТаблицаОтчетов.Количество();

        

        ЭлементыФормы.ИндикаторЗагрузки.МинимальноеЗначение = 0;

        ЭлементыФормы.ИндикаторЗагрузки.МаксимальноеЗначение = чОтчетов;

            

        ЭлементыФормы.Logo.Заголовок = "Выгружаю документы";

        лСчетчикИндикатора = 0;

        

        ВыгрузитьЗаголовокТаблицы(26);

        

        //ВЫГРУЖАЮ ТАБЛИЦУ В ФАЙЛ ПО СТРОКАМ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

 

        фСтарт=истина; //флаг первого прохода

 

        чОт=2;         //номер первой строки с данными

         

        Пока чОтчетов >= 1 Цикл //Цикл по строкам Таблицы отчетов

 

              чОтчетов = чОтчетов -1;

              СтрокаОтчетов = ТаблицаОтчетов.Получить(чОтчетов);

             Если (СтрокаОтчетов.ДатаВыпуска=ДатаВыпускаПред) 

                И (СтрокаОтчетов.Принадлежность=ПринадлежностьПред)

                И (СтрокаОтчетов.Типоразмер=ТипоразмерПред)

                И (СтрокаОтчетов.ТипОсновы=ТипОсновыПред)

             Тогда

             Иначе

                ДатаВыпускаПред=СтрокаОтчетов.ДатаВыпуска; 

                ПринадлежностьПред=СтрокаОтчетов.Принадлежность;

                ТипоразмерПред=СтрокаОтчетов.Типоразмер;

                ТипОсновыПред=СтрокаОтчетов.ТипОсновы;

                Если фСтарт Тогда

                     фСтарт = ложь; //Уже не первый проход

 

                Иначе     

                     чДо=глСчетчикСтрок;

                     ВыгрузитьСтрокуИтог(чОт,чДо,26);

                КонецЕсли;

                чОт=глСчетчикСтрок;

             КонецЕсли;

             

             ВыгрузитьСтрокуОтчетовВФайл(СтрокаОтчетов,26);

             

             лСчетчикИндикатора = лСчетчикИндикатора + 1;

             ЭлементыФормы.ИндикаторЗагрузки.Значение = лСчетчикИндикатора;

             

             ОбработкаПрерыванияПользователя();

        

        КонецЦикла;

        чДо=глСчетчикСтрок;

        ВыгрузитьСтрокуИтог(чОт,чДо,26);

 

        //КОНЕЦ ВЫГРУЗКИ СТРОК В ФАЙЛ 

 

        Состояние("Данные файла выгружены");               

        //~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

 

        libСообщитьНК1("ИНФО: ШАГ 1 ВЫПОЛНЕН. Данные файла Отчеты.DBF успешно считаны",1);    

        

        //Состояние("Создание сводных таблиц");

 

        ЭлементыФормы.Logo.Заголовок = "Создание сводных таблиц";

        

        //РазделитьОбласти();

 

            //Range("A2").S_elect

 

            //ActiveWindow.FreezePanes = True

 

        СоздатьТаблицуЛист(MyBook.Worksheets(1).Name,"наим","Дата","Наим","","К");

        СоздатьТаблицуЛист(MyBook.Worksheets(1).Name,"ЮВ","Дата","Наим,Каркас,Вид","","К");

        СоздатьТаблицуЛист(MyBook.Worksheets(1).Name,"В пр(2)","Дата","Наим,Каркас,Основа","","К");

        СоздатьТаблицуЛист(MyBook.Worksheets(1).Name,"В пр","Дата","Каркас,Основа","","К");

        СоздатьТаблицуЛист(MyBook.Worksheets(1).Name,"Основа","Дата","Основа","","кг основы");

        СоздатьТаблицуЛист(MyBook.Worksheets(1).Name,"Напыление","","Напылен","","кг напылен");

        СоздатьТаблицуЛист(MyBook.Worksheets(1).Name,"Клей","","Дата","","кг клея");

            

КонецПроцедуры



Процедура СоздатьТаблицуЛист(стрДанные,стрСводнаяТаблица,стрПоле1,стрПоле2,стрПоле3,стрПоле4);

    

    //Создает сводную таблицу стрСводнаяТаблица с полями (стрПоле4 - поле реквизита) 

     //и размещает ее на одноименном листе

     //Заполняет сводную таблицу данными, взятыми с листа стрДанные

     

    //Поле стрПоле2 может быть полем списка через запятую

   

    //0. Вспомогательный разбор списка значений в стрПоле2 и определение числа значений

 

         лПоля.Очистить(); //сбросим все значения, если таковые весели в памяти

 

         стрПоля=стрПоле2;

         i=1;//число значений в списке

 

         Пока Найти(стрПоля,",")<>0 Цикл

             

              n=Найти(стрПоля,",");

              лПоля.Добавить(Сред(стрПоля,1,n-1));

              стрПоля=Сред(стрПоля,n+1);

              i=i+1;

              

         КонецЦикла;      

         лПоля.Добавить(стрПоля);

         

    //1. Установить диапазон выборки данных

     FirstSheet.Activate();

    дДиапазонДанных=FirstSheet.UsedRange.Address;

    ДиапазонДанных=FirstSheet.Name+"!"+Строка(дДиапазонДанных);    

    

    //2. Создать кэш под сводную таблицу

    //   аргументы не переменные, а текст с именем переменных (crazy)

     

         SourceType = xlDatabase;

         SourceData = ДиапазонДанных;

    

         Cache = MyBook.PivotCaches().Add(SourceType, SourceData);

 

    //для отладки: FileOfReports.Visible = 1;   

           

    //3. Породить из кэша сводную таблицу с именем стрСводнаяТаблица

         TableDestination="";

         TableName=стрСводнаяТаблица;

    

         Cache.CreatePivotTable(TableDestination,TableName);

    

    //4. Определить представление данных в сводной таблице

     //стрПоле1

 

    Если СокрЛП(стрПоле1)<>"" Тогда

         MyBook.ActiveSheet.PivotTables(TableName).PivotFields(стрПоле1).Orientation = 3; //xlRowField=1 то, что указывается справа у таблицы

 

    КонецЕсли;

    

    //стрПоле2

 

    чНомер=0;

    Пока чНомер<i Цикл 

         Если СокрЛП(лПоля[чНомер].Значение)<>"" Тогда

               MyBook.ActiveSheet.PivotTables(TableName).PivotFields(лПоля[чНомер].Значение).Orientation = 1; 

         КонецЕсли;



         чНомер = чНомер + 1;  

    КонецЦикла;      



    //стрПоле3

 

    Если СокрЛП(стрПоле3)<>"" Тогда

         MyBook.ActiveSheet.PivotTables(TableName).PivotFields(стрПоле3).Orientation = 2; //xlColumnField=2 то, что указывается в вепрхней части таблицы

 

    КонецЕсли;

    

    //стрПоле4

 

    Если СокрЛП(стрПоле4)<>"" Тогда

         MyBook.ActiveSheet.PivotTables(TableName).PivotFields(стрПоле4).Orientation = 4; //xlCount=4 data

 

    КонецЕсли;

    

    //5. Скрыть пустые строки в стрПоле2, предварительно проверив, что таковые СУЩЕСТВУЮТ!!!!

    //стрПоле2

 

    чНомер=0;

    Пока чНомер<i Цикл 

         Если СокрЛП(лПоля[чНомер].Значение)<>"" Тогда

              Если IfPivotItemExists(TableName,лПоля[чНомер].Значение,"(пусто)")Тогда

                    MyBook.ActiveSheet.PivotTables(TableName).PivotFields(лПоля[чНомер].Значение).PivotItems("(пусто)").Visible = False;

              КонецЕсли;

         КонецЕсли;

         чНомер = чНомер + 1;  

    КонецЦикла;      

             

    //6. Закрыть вспомогательные панели                                                  

 

        MyBook.ShowPivotTableFieldList = False;

        FileOfReports.CommandBars("PivotTable").Visible = False;

    

    //7. Присвоить активному листу имя, заданное в параметрах процедуры

 

        MyBook.ActiveSheet.Name = стрСводнаяТаблица;

    

    //8. Сохранить файл

 

        MyBook.Save();

    

КонецПроцедуры



Функция IfPivotItemExists(strTableName,strFieldName,strItemName)

//Проверяет существование позиции поля сводной таблицы со значением strItemName    

 

        nItems = MyBook.ActiveSheet.PivotTables(strTableName).PivotFields(strFieldName).PivotItems().Count;

        i = 1;

        Пока i <= nItems Цикл

            Если strItemName=MyBook.ActiveSheet.PivotTables(strTableName).PivotFields(strFieldName).PivotItems(i).Name Тогда

                 //Искомая позиция strItemName существует:

 

                 //Сообщить("Позиция "+strItemName+" найдена");

 

                 Возврат True;

            КонецЕсли;

            i=i+1; 

        КонецЦикла;

        

        //Сообщить("Позиция "+strItemName+" не найдена");

 

        Возврат False;

        

КонецФункции

Код 1C v 7.x

  РабочаяКнига = СоздатьОбъект("Excel.Application");

РабочаяКнига.SheetsInNewWorkbook = 1;

РабочаяКнига.Caption = "Отчет по договорам отгрузки";

NewBook = РабочаяКнига.Workbooks;

List = NewBook.Add;



СписокСтолбцов = СоздатьОбъект("СписокЗначений");

СписокСтолбцов.ДобавитьЗначение("Модель");

СписокСтолбцов.ДобавитьЗначение("Разнорядка");

СписокСтолбцов.ДобавитьЗначение("По договору");

СписокСтолбцов.ДобавитьЗначение("Отгрузили");

СписокСтолбцов.ДобавитьЗначение("Осталось");



//Заполним наименование столбцов: Модель, Разнорядка, Количество

Для Столбец = 1 По СписокСтолбцов.РазмерСписка() Цикл

	Ячейка = РабочаяКнига.Cells(1,Столбец);

	Ячейка.Value = СписокСтолбцов.ПолучитьЗначение(Столбец);

КонецЦикла; 



//Формируем запрос по регистру

//	//Создание объекта типа Запрос

Запрос = СоздатьОбъект("Запрос");

ТекстЗапроса =

"//{{ЗАПРОС(Сформировать)

|Период с ДатаНач по ДатаКон;

|Разнорядка = Регистр.УчетДоговоров.Разнорядка;

|Модель = Регистр.УчетДоговоров.Модель.Группа;

|Колво = Регистр.УчетДоговоров.Количество;

|Функция КолвоПриход = Приход(Колво);

|Функция КолвоРасход = Расход(Колво);

|Функция КолвоОст = КонОст(Колво);

|Группировка Разнорядка;

|Группировка Модель;

|"//}}ЗАПРОС

;



// Если ошибка в запросе, то выход из процедуры

Если Запрос.Выполнить(ТекстЗапроса) = 0 Тогда

	Возврат;

КонецЕсли;



НомерСтроки = 1;

Пока Запрос.Группировка("Разнорядка") = 1 Цикл

	Пока Запрос.Группировка("Модель") = 1 Цикл 

		Модель = Запрос.Модель;

		Разнорядка = Запрос.Разнорядка;

		КолПоДоговору = Запрос.КолвоПриход;

		КолОтгрузили = Запрос.КолвоРасход;

		КолОсталось = Запрос.КолвоОст;

		НомерСтроки = НомерСтроки + 1;

		//Организум заполнение ячеек Excel

		Для Ст = 1 По СписокСтолбцов.РазмерСписка() Цикл

			Ячейка = РабочаяКнига.Cells(НомерСтроки,Ст);

			Если Ст = 1 Тогда

				Ячейка.Value = Модель;

			ИначеЕсли Ст = 2 Тогда

				Ячейка.Value = Строка(Разнорядка);

			ИначеЕсли Ст = 3 Тогда

				Ячейка.Value = КолПоДоговору;

			ИначеЕсли Ст = 4 Тогда

				Ячейка.Value = КолОтгрузили;

			ИначеЕсли Ст = 5 Тогда

				Ячейка.Value = КолОсталось;

			КонецЕсли;

		КонецЦикла;	

	КонецЦикла;

КонецЦикла; 

СводнаяТаблица = РабочаяКнига.ActiveSheet.PivotTableWizard;

//Метод СводнаяТаблица.Name возвращает имя сводной таблицы

//Можно задать имя таблицы СводнаяТаблица.Name = "МояТаблица"

СводнаяТаблица.SmallGrid = 0;

//Разворачивает макет сводной таблицы 



//Обращение к ячейкам сводной таблицы возможно по номеру

//Например, СводнаяТаблица.PivotFields(1).Value 

//возвращает значение "Модель"



//Попробуем с другого конца

//1 - Row

//2 - Column

//3 - Page

//4 - Data

СводнаяТаблица.PivotFields(1).Orientation = 1;    //Модель 

СводнаяТаблица.PivotFields(2).Orientation = 3;    //Разнорядка

СводнаяТаблица.PivotFields(3).Orientation = 4;    //По договору

СводнаяТаблица.PivotFields(4).Orientation = 4;    //Отгрузили

СводнаяТаблица.PivotFields(5).Orientation = 4;    //Осталось



//Пройдемся по форме отчета

СводнаяТаблица.Format(1);



//Попробуем закрыть панель инструментов сводной таблицы

РабочаяКнига.CommandBars("PivotTable").Visible = 0;

РабочаяКнига.Visible = 1;

Категория: Работа с Microsoft Office и OpenOffice

Вывод (печать) таблицы значений в табличный документ

Пример кода быстрая Печать таблицы значений

Код 1C v 8.х

  //ТПОтчета - Табличное поле с формы (Таблица значений) с данными

ПострПечать = Новый ПостроительОтчета;

    ПострПечать.ИсточникДанных = Новый ОписаниеИсточникаДанных(ТПОтчета);

    ПострПечать.МакетОформления = ПолучитьМакетОформления(СтандартноеОформление.Интерфейс);

    ПострПечать.Выполнить();

    Для каждого Колонка Из ПострПечать.ВыбранныеПоля Цикл

        Колонка.Представление = ТПОтчета.Колонки[Колонка.Имя].Заголовок;

    КонецЦикла; 

    ПострПечать.Вывести();

Пример функций Печать таблицы значений с использованием Макета

Код 1C v 8.х

 //Процедура  формирует и выводит отчет по переданной таблице значений

// Параметры :

// ТЗ - ТаблицаЗначений

Процедура УниверсальныйОтчетПоТЗ(ТЗ)



Табл=Новый ТабличныйДокумент;

Макет = ЭтотОбъект.ПолучитьМакет("Макет");

ОбластьШапкаОсновной=Макет.ПолучитьОбласть("Шапка|Основной");

ОбластьСтрокаОсновной=Макет.ПолучитьОбласть("Строка|Основной");

ОбластьИтогОсновной=Макет.ПолучитьОбласть("Итог|Основной");

ОбластьШапкаДОП=Макет.ПолучитьОбласть("Шапка|Показатели");

ОбластьСтрокаДОП=Макет.ПолучитьОбласть("Строка|Показатели");

ОбластьИтогДОП=Макет.ПолучитьОбласть("Итог|Показатели");

Табл.Вывести(ОбластьШапкаОсновной);



Для Каждого Колонка из Тз.Колонки ЦИКЛ

 ОбластьШапкаДОП.Параметры.ИмяПоказателя=Колонка.Имя;

 Табл.Присоединить(ОбластьШапкаДОП);

КонецЦикла;



счетчик=0;

Для каждого стр из Тз Цикл

 счетчик=счетчик+1;

 ОбластьСтрокаОсновной.Параметры.счетчик=счетчик; 

 Табл.Вывести(ОбластьСтрокаОсновной);

  Для Каждого Колонка из Тз.Колонки ЦИКЛ

   ОбластьСтрокаДОП.Параметры.ЗначениеКолонки=стр[Колонка.Имя];

   Табл.Присоединить(ОбластьСтрокаДОП);

  КонецЦикла;

КонецЦикла;

Табл.Вывести(ОбластьИтогОсновной);



Для Каждого Колонка из Тз.Колонки ЦИКЛ

 ОбластьИтогДОП.Параметры.Итог=Тз.Итог(Колонка.Имя);

 Табл.Присоединить(ОбластьИтогДОП);

КонецЦикла;



Табл.Показать();

КонецПроцедуры

Код 1C v 7.x

 

//Вывести таблицу значений

Процедура ПечатьТЗвТаб(ТЗ, Заголовок = "",КолонкиПоНазваниям = 0) Экспорт

	Перем ТТЗ;

	ТЗ.Выгрузить(ТТЗ);

	МаксШирина = 50;    // максимальная ширина колонки 

	СпШирина = СоздатьОбъект("СписокЗначений"); // список ширин колонок по таблице

	Для сч = 1 по ТТЗ.КоличествоКолонок() Цикл

		Если КолонкиПоНазваниям = 0  Тогда

			ИмяРек = ТТЗ.ПолучитьПараметрыКолонки(сч);

		Иначе

			ИмяРек = "";

			ТТЗ.ПолучитьПараметрыКолонки(сч,,,,ИмяРек,);

		КонецЕсли;

		СпШирина.ДобавитьЗначение(СтрДлина(ИмяРек)*1.2); // с поправкой на размер шрифта

	КонецЦикла;	

	

	// просто печать таблицы - вывод всех строк и колонок

	// числовые значения - по правому краю. Автоподбор ширины - в пределах МаксШирина

	Таб=СоздатьОбъект("Таблица");

	Таб.ИсходнаяТаблица("ПечатьТЗ");

	Если СокрЛП(Заголовок) <> "" Тогда

		Таб.ВывестиСекцию("Шапка");

	КонецЕсли;

	// заголовки таблицы

	Таб.ВывестиСекцию("Строка|Общая");

	Для сч=1 по ТТЗ.КоличествоКолонок() Цикл

		Если КолонкиПоНазваниям = 0  Тогда

			ИмяРек = ТТЗ.ПолучитьПараметрыКолонки(сч);

		Иначе

			ИмяРек = ""; 

			Ном = "";

			ТТЗ.ПолучитьПараметрыКолонки(сч,,,,ИмяРек,);

		КонецЕсли;

		Таб.ПрисоединитьСекцию("Строка|Столбец");  

	КонецЦикла;

	ВысотаШапки = Таб.ВысотаТаблицы();

	// данные таблицы по строкам

	ТТЗ.ВыбратьСтроки();

	Пока ТТЗ.ПолучитьСтроку()=1 Цикл

		Ном = ТТЗ.НомерСтроки;

		Таб.ВывестиСекцию("Строка|Общая");

		Выс = Таб.ВысотаТаблицы();

		Для сч=1 по ТТЗ.КоличествоКолонок() Цикл

			ИмяРек=ТТЗ.ПолучитьЗначение(Ном,сч);

			Таб.ПрисоединитьСекцию("Строка|Столбец");

			Если ТипЗначения(ИмяРек) = 1 Тогда

				Обл = Таб.Область("R"+Выс+"C"+(Сч+1)); // ячейка в которую поместили данные

				Обл.ГоризонтальноеПоложение(2); // числа - вправо

			КонецЕсли;

			НачШирина = СпШирина.ПолучитьЗначение(Сч);

			Ширина = СтрДлина(ИмяРек);

			СпШирина.УстановитьЗначение(Сч,Макс(НачШирина,Ширина));

		КонецЦикла;

	КонецЦикла;

	

	Для сч = 1 по СпШирина.РазмерСписка() Цикл

		Обл = Таб.Область("R"+ВысотаШапки+"C"+(Сч+1));

		// форматируем ширину таблицы

		Ширина = Мин(МаксШирина,2+СпШирина.ПолучитьЗначение(Сч));

		Обл.ШиринаСтолбца(Ширина);   

		// форматируем заголовок

		Обл.Полужирный(1);

	КонецЦикла;	

	Таб.Показать(Заголовок);

	Таб.ТолькоПросмотр(1);

КонецПроцедуры

ИЛИ

Код 1C v 7.x

 Процедура глВывестиТаблицуЗначений(ТаблицаЗначений, Заголовок = "") Экспорт

Перем Таб, ИИ, ЖЖ, НазваниеКолонки, ТипКолонки, Ширина, Значение, Сообщение;



Таб = СоздатьОбъект("Таблица");



Если ТипЗначенияСтр(ТаблицаЗначений) <> "ТаблицаЗначений" Тогда

Сообщение = "В процедуру ""глВывестиТаблицуЗначений()"" передана переменная не типа ""ТаблицаЗначений"", "+

"а типа """+СокрЛП(ТипЗначенияСтр(ТаблицаЗначений))+"""";

Таб.Область(1, 1, 1, 1).Текст = Сообщение;

Таб.Область(1, 1, 1, 1).ШиринаСтолбца(СтрДлина(Сообщение));



Таб.ТолькоПросмотр(1);

Таб.Показать("Не таблица значений: "+Заголовок);



Возврат;

КонецЕсли;



Для ЖЖ = 1 по ТаблицаЗначений.КоличествоКолонок() цикл

ТаблицаЗначений.ПолучитьПараметрыКолонки(ЖЖ,,,, НазваниеКолонки);

Таб.Область(1, ЖЖ, 1, ЖЖ).Текст = СокрЛП(НазваниеКолонки);

Таб.Область(1, ЖЖ, 1, ЖЖ).РамкаОбвести(5, 5, 5, 5);

Таб.Область(1, ЖЖ, 1, ЖЖ).ВертикальноеПоложение(3);

Таб.Область(1, ЖЖ, 1, ЖЖ).ГоризонтальноеПоложение(3);

Таб.Область(1, ЖЖ, 1, ЖЖ).РазмерШрифта(7);

Таб.Область(1, ЖЖ, 1, ЖЖ).Полужирный(1);



Ширина = Таб.Область(1, ЖЖ, 1, ЖЖ).ШиринаСтолбца();

Ширина = Макс(Ширина, СтрДлина(СокрЛП(НазваниеКолонки)));

Таб.Область(1, ЖЖ, 1, ЖЖ).ШиринаСтолбца(Ширина);

КонецЦикла;



Для ИИ = 1 по ТаблицаЗначений.КоличествоСтрок() цикл

Для ЖЖ = 1 по ТаблицаЗначений.КоличествоКолонок() цикл

Значение = ТаблицаЗначений.ПолучитьЗначение(ИИ, ЖЖ);

Таб.Область(ИИ+1, ЖЖ, ИИ+1, ЖЖ).Текст = Значение;

Таб.Область(ИИ+1, ЖЖ, ИИ+1, ЖЖ).Расшифровка(Значение, 0);

Таб.Область(ИИ+1, ЖЖ, ИИ+1, ЖЖ).РамкаОбвести(3, 0, 3, 0);



Ширина = Таб.Область(1, ЖЖ, 1, ЖЖ).ШиринаСтолбца();

Ширина = Макс(Ширина, СтрДлина(СокрЛП(Строка(Значение))));

Таб.Область(1, ЖЖ, 1, ЖЖ).ШиринаСтолбца(Ширина);



ТаблицаЗначений.ПолучитьПараметрыКолонки(ЖЖ, ТипКолонки); ;

Если ТипКолонки = "Число" тогда

Таб.Область(ИИ+1, ЖЖ, ИИ+1, ЖЖ).ГоризонтальноеПоложение(2);

КонецЕсли;

Если ИИ = ТаблицаЗначений.ТекущаяСтрока() тогда

Таб.Область(ИИ+1, ЖЖ, ИИ+1, ЖЖ).ЦветФона(255, 0, 0);

КонецЕсли;

КонецЦикла;

КонецЦикла;



Таб.ТолькоПросмотр(1);

Таб.Показать("Таблица значений: "+Заголовок);

КонецПроцедуры

Категория: Работа с Таблицей Значений

Получить список Документов конфигурации

Код 1C v 8.х

  //ЭлементыФормы.ОбъектПоиска - Поле Выбора на форме

	СписокВыбора = ЭлементыФормы.ОбъектПоиска.СписокВыбора;

	Для Каждого Документ Из Метаданные.Документы Цикл

		//Проверим, есть ли права на просмотр? Да- добавляем, Нет - пропускаем

		Если ПравоДоступа("Просмотр", Документ) Тогда

			ИмяДокумента = Документ.Синоним;

			Если ИмяДокумента = "" Тогда

				ИмяДокумента = Документ.Имя;

			КонецЕсли;

			Структура = Новый Структура;

			Структура.Вставить("Тип", "Документ");

			Структура.Вставить("Объект", Документ);

			СписокВыбора.Добавить(Структура, ИмяДокумента, ,ЭлементыФормы.КартинкаДокумента.Картинка);

		КонецЕсли;

	КонецЦикла;

Код 1C v 7.x

 //Выведем список всех документов в окно сообщений

	Для Индекс=1 По Метаданные.Документ() Цикл

		Значение = Метаданные.Документ(Индекс).Идентификатор;

		Представление = Метаданные.Документ(Индекс).Представление();

		Комментарий = Метаданные.Документ(Индекс).Комментарий;

		Сообщить(значение+"  "+Представление+"  "+Комментарий);

	КонецЦикла;

    // Выведем Список документов, ФормРегистр - Поле со списком на форме

	ФормРегистр.УдалитьВсе();

	Для ъ=1 По Метаданные.Регистр() Цикл

		ФормРегистр.ДобавитьЗначение(Метаданные.Регистр(ъ).Идентификатор, Метаданные.Регистр(ъ).Представление());

	КонецЦикла;

	Если ФормРегистр.РазмерСписка()>0 Тогда

		ФормРегистр.ТекущаяСтрока(1);

	КонецЕсли;

	

	//функция создаёт список реквизитов документа

Процедура гСписокРеквизитовДокумента(Список,Документ,ФлагПредставление=0) Экспорт

     //шапка

     Для i=1 По Метаданные.Документ(Документ).РеквизитШапки() Цикл

          Ж=Метаданные.Документ(Документ).РеквизитШапки(i);

          Если ФлагПредставление=0 Тогда

               Представление=Ж.Идентификатор;

          Иначе

               Представление=Ж.Представление();

          КонецЕсли;

          Список.ДобавитьЗначение(Ж.Идентификатор,"Ш: "+Представление);

     КонецЦикла;

     //многострочка

     Для i=1 По Метаданные.Документ(Документ).РеквизитТабличнойЧасти() Цикл

          Ж=Метаданные.Документ(Документ).РеквизитТабличнойЧасти(i);

          Если ФлагПредставление=0 Тогда

               Представление=Ж.Идентификатор;

          Иначе

               Представление=Ж.Представление();

          КонецЕсли;

          Список.ДобавитьЗначение(Ж.Идентификатор,"Т: "+Представление);

     КонецЦикла;

     //общий

     Для i=1 По Метаданные.ОбщийРеквизитДокумента() Цикл

          Ж=Метаданные.ОбщийРеквизитДокумента(i);

          Если ФлагПредставление=0 Тогда

               Представление=Ж.Идентификатор;

          Иначе

               Представление=Ж.Представление();

          КонецЕсли;

          Список.ДобавитьЗначение(Ж.Идентификатор,"О: "+Представление);

     КонецЦикла;

КонецПроцедуры

Категория: Метаданные

Процедура заполняет WORD шаблон из СпискаЗначений

Заполняет Вордовский шаблон из СпискаЗначений
Вставляется в виде обрабтки. При открытии передается СЗ первым значением идет WORD, в строковом представлеии наименование файла шаблона. Затем идентификаторы закладок (поля) в тексте шаблона - в представлении что подставить.
Сперва хотел сделать что-то универсальное Ворд-Ексель, а потом передумал. Отого такой первый параметр в списке значений

Код 1C v 7.x

 Процедура ПриОткрытии()

   Перем Закладка, ТектВывода, сз;

   СтатусВозврата(0);

   сз = Форма.Параметр;

   ФайлШаблон = ""; ОЛЕ_Объект = "";

   Если ТипЗначенияСтр(сз)<>"СписокЗначений" Тогда

       Сообщить("Для формирования документа передайте подготовленный список значений", "!!!"); Возврат;

   ИначеЕсли сз.РазмерСписка()=0 Тогда

       Сообщить("Для формирования документа передайте подготовленный список значений", "!!!"); Возврат;

   Иначе

       ФайлШаблон = сз.ПолучитьЗначение(1, ОЛЕ_Объект);

       

       Если ВРег(ОЛЕ_Объект) <> "WORD" Тогда

           Сообщить("OLE объект "+ОЛЕ_Объект+" не поддерживается", "!!!"); Возврат;

       КонецЕсли;

       

       Если ФС.СуществуетФайл(КаталогИБ()+"Шаблоны" + ФайлШаблон) = 0 Тогда

           Сообщить("Нет файла - шаблона " + ФайлШаблон, "!!!"); Возврат;

       КонецЕсли

           

   КонецЕсли;



   OLE = СоздатьОбъект(ОЛЕ_Объект+".Application");

     OLE.Documents.Add(""""+КаталогИБ()+"Шаблоны" + ФайлШаблон + """");

   Для Индекс = 2 по сз.РазмерСписка() цикл

       ТекстВывода = сз.ПолучитьЗначение(Индекс, Закладка);

       //Если OLE.ActiveDocument.Bookmarks(СокрЛП(Закладка)).Exists()=0 Тогда  // Проверяем - существует ли закладка

       //    Сообщить("Не найдена закладка "+Закладка,"!!!" ); Продолжить;

       //КонецЕсли;

       Попытка

           OLE.ActiveDocument.Bookmarks(СокрЛП(Закладка)).Select();  //выделим выбранную закладку

           OLE.Selection.TypeText(СокрЛП(ТекстВывода));              // выведем на место выделения текст

       Исключение

           Сообщить("Не найдена закладка "+Закладка,"!!!" );

       КонецПопытки;    

   КонецЦикла;



   OLE.Visible=1;  /// видимость - True

   OLE.ActiveDocument.Activate(); /// активизировать!!!

   OLE=""; /// ссылочку прибить

КонецПроцедуры

Автор: GrayT

Категория: Работа с Microsoft Office и OpenOffice

Функция дни рождения сотрудников

Данная функция написана для ЗиК 7.7

Код 1C v 7.x

 

//Функция подбирает окончание для возраста

Функция СтрГода(Возраст) 

	Остаток = Возраст%10;

	Если Остаток = 1 Тогда

		Стр = "год";

	ИначеЕсли ((Остаток > 1) и (Остаток < 5)) Тогда

		Стр = "года";

	Иначе 	     

		Стр = "лет";

	КонецЕсли;

	Возврат Стр;  

КонецФункции	 



//Формируем дни рождения Сотрудников

Процедура ДниРожденияСотрудников()   

	ТекстДР="";

	Именинники = СоздатьОбъект("СписокЗначений");

	СпрСотр = СоздатьОбъект("Справочник.Сотрудники");

	СпрСотр.ВыбратьЭлементы();

	Пока СпрСотр.ПолучитьЭлемент()= 1 Цикл

		ТекЭлем = СпрСотр.ТекущийЭлемент();

		Если ТекЭлем.ЭтоГруппа() = 0 Тогда  

			Если ((ТекЭлем.Родитель <> "Уволенные")) Тогда

				ТекСотр = СпрСотр.ТекущийЭлемент();

				Если (ПустоеЗначение(ТекСотр.СостояниеФизЛица.Получить(НачМесяца(ТекущаяДата()))) =  0) Тогда

					Если (ДатаМесяц(ТекСотр.ДатаРождения) = ДатаМесяц(ТекущаяДата()))  Тогда

						Именинники.ДобавитьЗначение(ТекСотр);

					КонецЕсли;			

				КонецЕсли;		 

			КонецЕсли;		

		КонецЕсли;	

	КонецЦикла;	                                           

	Если Именинники.РазмерСписка() <> 0 Тогда    

		ТекстДР=ТекстДР+"                             ********* СПИСОК ИМЕНИННИКОВ *********"+РазделительСтрок+"                                              за месяц "+Формат(ТекущаяДата(),"ДММММ")+РазделительСтрок;

		ТекстДР=ТекстДР+"-----------------------------------------------------------------------------------------------------------------------------------------------"+РазделительСтрок;

	    Для к = 1 по  Именинники.РазмерСписка() Цикл

			Сотр = Именинники.ПолучитьЗначение(к);

			Возраст = (Число(ДатаГод(ТекущаяДата()))-Число(ДатаГод(Сотр.ДатаРождения)));

			РазницаДней = (Число(ДатаЧисло(Сотр.ДатаРождения))-Число(ДатаЧисло(ТекущаяДата())));

			СтрГода = СтрГода(Возраст);

			Если (ДатаЧисло(Сотр.ДатаРождения) < ДатаЧисло(ТекущаяДата()))  Тогда   

				ТекстДР=ТекстДР+"                              "+Сотр+" "+Сотр.ДатаРождения+" уже исполнилось "+Возраст+" "+СтрГода+"!"+РазделительСтрок;

			Иначе	

				Если (РазницаДней = 2) Тогда  

					ТекстДР=ТекстДР+"ПОСЛЕЗАВТРА!  "+Сотр+" послезавтра "+Сотр.ДатаРождения+" будет праздновать " + Возраст + "-й День Рождения!!!! ";

					

				ИначеЕсли (РазницаДней = 1) Тогда 

					ТекстДР=ТекстДР+"ЗАВТРА!               "+ Сотр + " будет отмечает свой " + Возраст + "-й День рождения!";							   

				ИначеЕсли (РазницаДней = 0) Тогда  

					ТекстДР=ТекстДР+"СЕГОДНЯ!           "+ Сотр + " отмечает свой " + Возраст + "-й День рождения!";

				КонецЕсли;

				ТекстДР=ТекстДР+"    ( "+Сотр.Подразделение.Получить(ТекущаяДата())+" , "+Сотр.Должность.Получить(ТекущаяДата())+" )"+РазделительСтрок;

			КонецЕсли; 			

		КонецЦикла;	

	Иначе              		

		ТекстДР=ТекстДР+"В текущем месяце именинников нет!";		

	КонецЕсли; 

	Сообщить(ТекстДР);

КонецПроцедуры

В файловом архиве есть и сама обработка.

Категория: Полезные, Универсальные Функции

Как разобрать "наименование" сотрудника Ф.И.О. на Фамилию и инициалы сотрудника?

Код 1C v 7.x

 

Функция глРазложить(Знач Стр, Разделитель = ",") Экспорт

	СЗ = СоздатьОбъект("СписокЗначений");

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				СЗ.ДобавитьЗначение(Стр);

				Возврат СЗ;

			КонецЕсли;

			СЗ.ДобавитьЗначение(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				СЗ.ДобавитьЗначение(Стр);

				Возврат СЗ;

			КонецЕсли;

			СЗ.ДобавитьЗначение(Лев(Стр,Поз-1));

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;

КонецФункции 



Функция ФамилияИмяОтчество(Объект,Фамилия="",Имя="",Отчество="") Экспорт

    

	Если ТипЗначения(Объект)=2 Тогда

		ФИО = глРазделить(СокрЛП(Объект),",");

	Иначе

		ФИО = глРазделить(СокрЛП(Объект.Наименование),",");

	КонецЕсли;                             

	ФИО = глРазложить(ФИО," ");

	Фамилия = ""; Имя = ""; Отчество = "";

	Если ФИО.РазмерСписка() > 0 Тогда

		Фамилия = ФИО.ПолучитьЗначение(1);

		Если ФИО.РазмерСписка() > 1 Тогда

			Имя		= ФИО.ПолучитьЗначение(2);

			Если ФИО.РазмерСписка() > 2 Тогда 

				// а вот отчество бывает и не из одного слова				

				Для Сч = 3 По ФИО.РазмерСписка() Цикл

					Отчество = Отчество + ФИО.ПолучитьЗначение(Сч) + " ";

				КонецЦикла;

				Если ПустоеЗНачение(Отчество) = 0 Тогда

					Отчество = Лев(Отчество,СтрДлина(Отчество)-1);

				КонецЕсли;

			КонецЕсли;

		КонецЕсли;

	КонецЕсли;

	

	Возврат Фамилия+?(ПустоеЗначение(Имя)=0," "+Лев(Имя,1)+"."+?(ПустоеЗначение(Отчество)=0,Лев(Отчество,1)+".",""),"")



КонецФункции

Код 1C v 8.х

 

Функция глРазложить(Знач Стр, Разделитель = ",") Экспорт

	СЗ = Новый СписокЗначений;

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				СЗ.Добавить(Стр);

				Возврат СЗ;

			КонецЕсли;

			СЗ.Добавить(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				СЗ.Добавить(Стр);

				Возврат СЗ;

			КонецЕсли;

			СЗ.Добавить(Лев(Стр,Поз-1));

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;

КонецФункции 



Функция РазборФИО(Сотрудник)

	ФИО = глРазложить(Сотрудник," ");

	Фамилия = ""; Имя = ""; Отчество = "";

	Если ФИО.Количество() > 0 Тогда

		Фамилия = Строка(ФИО.Получить(0));

		Если ФИО.Количество() > 1 Тогда

			Имя		= Строка(ФИО.Получить(1));

			Если ФИО.Количество() > 2 Тогда 

				// а вот отчество бывает и не из одного слова				

				Для Сч = 2 По ФИО.Количество()-1 Цикл

					Отчество = Отчество + Строка(ФИО.Получить(Сч)) + " ";

				КонецЦикла;

				Если ЗначениеЗаполнено(Отчество) Тогда  

					Отчество = Лев(Отчество,СтрДлина(Отчество)-1);

				КонецЕсли;

			КонецЕсли;

		КонецЕсли;

	КонецЕсли;

Возврат Фамилия+?(ЗначениеЗаполнено(Имя)," "+Лев(Имя,1)+"."+?(ЗначениеЗаполнено(Отчество),Лев(Отчество,1)+".",""),"")

КонецФункции

Обязательно посмотрите более краткий вариант!

Категория: Полезные, Универсальные Функции