Как узнать является ли строка числом?

 // Преобразует исходную строку в число без вызова исключений.

//

// Параметры:

//   ИсходнаяСтрока - Строка - Строка, которую необходимо привести к числу.

//

// Возвращаемое значение:

//   Число - Полученное число.

//   Неопределено - Если строка не является числом.

//

Функция СтрокаВЧисло(Знач ИсходнаяСтрока) Экспорт

	ИсходнаяСтрока = СокрЛП(ИсходнаяСтрока);

	Результат = 0;

	ЗнаковПослеЗапятой = -1;

	ЗнакОтрицательный = Ложь;

	Длина = СтрДлина(ИсходнаяСтрока);

	Для НомерСимвола = 1 По Длина Цикл

		КодСимвола = КодСимвола(ИсходнаяСтрока, НомерСимвола);

		Если КодСимвола = 32 Или КодСимвола = 160 Тогда // Пробел или неразрывный пробел.

			// Пропуск (действие не требуется).

		ИначеЕсли КодСимвола = 45 Или КодСимвола = 40 Тогда // Минус или открывающая скобка.

			Если Результат <> 0 Тогда

				Возврат Неопределено;

			КонецЕсли;

			ЗнакОтрицательный = Истина;

		ИначеЕсли КодСимвола = 41 Тогда // Закрывающая скобка.

			Если Не ЗнакОтрицательный Или Результат = 0 Тогда // Не было открывающей скобки или нет числа.

				Возврат Неопределено;

			КонецЕсли;

			// Пропуск (действие не требуется).

		ИначеЕсли КодСимвола = 44 Или КодСимвола = 46 Тогда // Запятая или точка.

			Если ЗнаковПослеЗапятой <> -1 Тогда

				Возврат Неопределено; // Разделитель уже был, следовательно это не число.

			КонецЕсли;

			ЗнаковПослеЗапятой = 0; // Запуск отсчета знаков после запятой.

		ИначеЕсли КодСимвола > 47 И КодСимвола < 58 Тогда // Число.

			Если ЗнаковПослеЗапятой <> -1 Тогда

				ЗнаковПослеЗапятой = ЗнаковПослеЗапятой + 1;

			КонецЕсли;

			Число = КодСимвола - 48;

			Результат = Результат * 10 + Число;

		Иначе

			Возврат Неопределено;

		КонецЕсли;

	КонецЦикла;

	

	Если ЗнаковПослеЗапятой > 0 Тогда

		Результат = Результат / Pow(10, ЗнаковПослеЗапятой);

	КонецЕсли;

	Если ЗнакОтрицательный Тогда

		Результат = -Результат;

	КонецЕсли;

	

	Возврат Результат;

КонецФункции