Процедура ЗагрузитьИзВИБ(ВходнойПараметр,АдресВХранилище) Экспорт

    //Из структуры перегоняем данные в переменные

    ТаблицаДляЗаполнения = ВходнойПараметр.ТаблицаДляЗаполнения;

    ДанныеОбъекта = ВходнойПараметр.ДанныеОбъекта;



    //Тут идет собственно загрузка данных

    ВыполнитьЗагрузку(ТаблицаДляЗаполнения,ДанныеОбъекта);



    //Возвращаем данные из фоновой задачи в хранилище

    ПоместитьВоВременноеХранилище(ТаблицаДляЗаполнения, АдресВХранилище);

КонецПроцедуры   

 МассивАдресовВХранилище = Новый Массив;

МассивЗапущенныхЗаданий = Новый Массив;

Сч = 1;

Пока Сч <=  КоличествоПотоков Цикл

    Ключ = Новый УникальныйИдентификатор;

    ВходнойПараметр = Новый Структура;

    ВходнойПараметр.Вставить("ТаблицаДляЗаполнения",ТаблицаДляЗаполнения);

    ВходнойПараметр.Вставить("ДанныеОбъекта",ДанныеОбъекта);



    //Подготовим адрес в хранилище

    АдресВХранилище = ПоместитьВоВременноеХранилище(Неопределено);

    МассивПараметров = Новый Массив;

    МассивПараметров.Добавить(ВходнойПараметр);

    МассивПараметров.Добавить(АдресВХранилище);

    МассивАдресовВХранилище.Добавить(АдресВХранилище);



    МассивЗапущенныхЗаданий.Добавить(ФоновыеЗадания.Выполнить("ОбщийМодульСервер.ЗагрузитьИзВИБ",МассивПараметров, Ключ, "Загрузка"));

    Сч = Сч + 1;

КонецЦикла;   

 Для Каждого ТекАдресВХранилище Из МассивАдресовВХранилище Цикл

    ТекТаблица = ПолучитьИзВременногоХранилища(ТекАдресВХранилище);





    Для Каждого ТекСтрокаДанные Из ТекТаблица Цикл

        НоваяСтрока = НашаОбщаяТаблица.Добавить();

        ЗаполнитьЗначенияСвойств(НоваяСтрока,ТекСтрокаДанные);

    КонецЦикла;

КонецЦикла;   

 

// Отбор на форме

&НаКлиенте

....

ФМ=Новый ФиксированнаяСтруктура("КлючСвязи",Элементы.ДанныеБезКоррекции.ТекущиеДанные.КлючСвязи);

Элементы.СписокПодразделений.ОтборСтрок=ФМ;   

 //Функция получает записи табличной части согласно установленному отбору

Функция ПолучитьЗаписиСогласноОтбору(ТабличноеПолеИсточник)



ОтборСтрок = ТабличноеПолеИсточник.ОтборСтрок;

ПостроительЗапроса = Новый ПостроительЗапроса;

ПостроительЗапроса.ИсточникДанных = Новый ОписаниеИсточникаДанных(ТабличноеПолеИсточник.Значение); 

Для Каждого ЭлементОтбора Из ОтборСтрок Цикл     

Если ЭлементОтбора.Использование Тогда

НовыйОтбор = ПостроительЗапроса.Отбор.Добавить(ЭлементОтбора.Имя);        

НовыйОтбор.Использование = Истина;         

НовыйОтбор.ВидСравнения = ЭлементОтбора.ВидСравнения;       

НовыйОтбор.ЗначениеС = ЭлементОтбора.ЗначениеС;        

НовыйОтбор.ЗначениеПо = ЭлементОтбора.ЗначениеПо;        

НовыйОтбор.Значение = ЭлементОтбора.Значение;     

КонецЕсли;

КонецЦикла;





Таблица = ПостроительЗапроса.Результат.Выгрузить();

МассивСтрок = Новый Массив;

Для Каждого Стр ИЗ Таблица Цикл

СтруктураПоиска = Новый Структура;

Для Каждого Колонка Из Таблица.Колонки Цикл

СтруктураПоиска.Вставить(Колонка.Имя, Стр[Колонка.Имя]);

КонецЦикла;

НайденыеСтроки = ТабличноеПолеИсточник.Значение.НайтиСтроки(СтруктураПоиска);

Если НайденыеСтроки.Количество() > 0 Тогда

МассивСтрок.Добавить(НайденыеСтроки[0]);

КонецЕсли;

КонецЦикла;



Возврат МассивСтрок;



КонецФункции   

 ПараметрыОтбора = Новый Структура;

	ПараметрыОтбора.Вставить("ДокСсылка", ДанныеПоШК.Объект);

	НайденныеСтроки = ПакетДокументов.НайтиСтроки(ПараметрыОтбора);



// Подробнее

СтруктураОтбора = Новый Структура("ВидДокумента, Контрагент", ПФ, ?(Контр = Неопределено, Справочники.Контрагенты.ПустаяСсылка(), Контр));

ПакетДокументов 		 = ЗадачаОбъект.ПакетДокументов;

МассивСтрок				 = ПакетДокументов.НайтиСтроки(СтруктураОтбора);

Если МассивСтрок.Количество() Тогда

	Для Каждого СтрокаМассива Из МассивСтрок Цикл

		СтрокаМассива.ДобавленоПользователем = Истина;

		СтрокаМассива.Пользователь           = ПараметрыСеанса.ТекущийПользователь;

		СтрокаМассива.ДатаВремя				 = ТекущаяДата();

	КонецЦикла;

КонецЕсли;



//или

ТЧ = ПромежуточнаяНакладная.Выгрузить();

		ТЧ.Свернуть("СхемаПродажи");

		СтрокаСПустойСП = ТЧ.НайтиСтроки(Новый Структура("СхемаПродажи", Справочники.СхемыПродаж.ПустаяСсылка()));

		

		Если ТЧ.Количество() - СтрокаСПустойСП.Количество() > 1 Тогда

			Если Вопрос("Сбросить все схемы в строках?", РежимДиалогаВопрос.ДаНет) = КодВозвратаДиалога.Нет Тогда

				НесколькоСхем = Истина;

				Возврат;

			КонецЕсли;

		КонецЕсли;

		

		Для каждого СтрокаПН из ПромежуточнаяНакладная Цикл

			Если СтрокаПН.Номенклатура.ВидНоменклатуры.ТипНоменклатуры <> Перечисления.ТипыНоменклатуры.Услуга Тогда

				СтрокаПН.СхемаПродажи = СхемаПродажи;

			КонецЕсли;

	КонецЦикла;   

 Функция ПолучитьПотокЧтенияСтрок(Файл)

  Попытка

    // Используется для доступа к параметрам файлов или каталогов. 

    ТекстовыйФайл = Новый Файл(Файл);

    Если ТекстовыйФайл.Существует() = Ложь Тогда

      Сообщить("Файла "+Файл+" не существует!");

      Возврат Неопределено;

    КонецЕсли;



    // Текстовый документ предназначен для работы с текстами. 

    // Объект позволяет получать и сохранять текст в файле, 

    // работать со строками

    ПотокЧтенияСтрок = Новый ТекстовыйДокумент();

    ПотокЧтенияСтрок.Прочитать(ТекстовыйФайл);

  Исключение

    Сообщить("Файл не прочитан.", СтатусСообщения.Внимание);

    Сообщить(ОписаниеОшибки());

    Возврат Неопределено;

  КонецПопытки;



  // Возвращает текст, извлеченный из файла

  Возврат ПотокЧтенияСтрок;



КонецФункции // ПолучитьПотокЧтенияСтрок





// Исходный код функции загрузки строк в табличное поле:



Процедура ЧтениеТХТФайла(Элемент)



  // Проверка на наличие имени файла

  Если ПустаяСтрока(ИмяФайла) Тогда

    Предупреждение("Для запуска обработки необходимо предварительно выбрать файл данных.");

    Возврат;

  КонецЕсли;



  // Открыть файл, создать текстовый документ, прочитать

  ПотокСтрок = ПолучитьПотокЧтенияСтрок(ИмяФайла);



  // Очистить предыдущие значения

  ТаблицаДокумента.Очистить();

  ТаблицаДокумента.Колонки.Очистить();



  // Создать колонки табличного документа

  ТаблицаДокумента.Колонки.Добавить("Номер",,"Номер",5);

  ТаблицаДокумента.Колонки.Добавить("Артикул",,"Артикул",11);

  ТаблицаДокумента.Колонки.Добавить("Номенклатура",,"Номенклатура",25);

  ТаблицаДокумента.Колонки.Добавить("Цена",,"Цена",6);



  // Последовательное чтение строк текстового файла

  КоличествоСтрок = ПотокСтрок.КоличествоСтрок();

  Для Строка = 1 По КоличествоСтрок Цикл



    // Обработка нажатия Ctrl + Break

    ОбработкаПрерыванияПользователя();



    // Чтение строки из файла тхт / csv

    СтрокаИзФайла = ПотокСтрок.ПолучитьСтроку(Строка);



    // Разбор строки в массив, используя в качествен символа-разделителя "|"

    МассивСтрок = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(СтрокаИзФайла,"|");



    // Добавить данные в табличную часть экранной формы

    Стр=ТаблицаДокумента.Добавить();

    Стр.Номер	 = Строка;

    Стр.Артикул = МассивСтрок[0];

    Стр.Номенклатура = МассивСтрок[1];

    Стр.Цена = МассивСтрок[2];

    // Отобразить информацию о ходе выполнения обработки

    Состояние("Обработка строки файла : "

      + "строка " + Строка + " из " + КоличествоСтрок);



  КонецЦикла;



  // Отобразить результаты загрузки в форме элемента

  ЭлементыФормы.ТаблицаДокумента.Значение = ТаблицаДокумента;

  ЭлементыФормы.ТаблицаДокумента.СоздатьКолонки();



КонецПроцедуры // ЧтениеTXTФайла(Элемент)   

 Функция GetClientOrders()

    МассивЗаказовПокупателейТип = ФабрикаXDTO.Тип("http://company.com/1C/ClientOrder", "ArrayOfClientOrders");

    ЗаказПокупателяТип = ФабрикаXDTO.Тип("http://company.com/1C/ClientOrder", "ClientOrder");

    ЗаказПокупателяСтрокаТип = ФабрикаXDTO.Тип("http://company.com/1C/ClientOrder", "ClientOrderRow");

    НоменклатураТип = ФабрикаXDTO.Тип("http://company.com/1C/Nomenclature", "Nomenclature");

    Запрос = Новый Запрос;

    Запрос.Текст = 

        "ВЫБРАТЬ

        |	ЗаказПокупателя.Ссылка,

        |	ЗаказПокупателя.Номер,

        |	ЗаказПокупателя.Дата

        |ИЗ

        |	Документ.ЗаказПокупателя КАК ЗаказПокупателя";

    Результат = Запрос.Выполнить();

    Выборка = Результат.Выбрать();

    Если Выборка.Количество() = 0 Тогда

        Возврат Null;

    КонецЕсли;

    МассивЗаказовПокупателей = ФабрикаXDTO.Создать(МассивЗаказовПокупателейТип);

    

    Пока Выборка.Следующий() Цикл

        ЗаказПокупателя = ФабрикаXDTO.Создать(ЗаказПокупателяТип);

        ЗаказПокупателя.Number = Выборка.Номер;

        ЗаказПокупателя.Date = Выборка.Дата;

            Для каждого Строка Из Выборка.Ссылка.Товары Цикл

            ЗаказПокупателяСтрока = ФабрикаXDTO.Создать(ЗаказПокупателяСтрокаТип);

            Номенклатура = ФабрикаXDTO.Создать(НоменклатураТип);

            Номенклатура.Code = Строка.Номенклатура.Код;

            Номенклатура.Name = Строка.Номенклатура.Наименование;

            ЗаказПокупателяСтрока.Nomenclature = Номенклатура;

            ЗаказПокупателяСтрока.Count = Строка.Количество;

            ЗаказПокупателя.Products.Добавить(ЗаказПокупателяСтрока);

        КонецЦикла;

        МассивЗаказовПокупателей.ClientOrder.Добавить(ЗаказПокупателя);

    КонецЦикла;

    Возврат МассивЗаказовПокупателей;

КонецФункции   

 Перем СтруктураПоставщиковКарт Экспорт;

Перем СтруктураЧисел;



/////////////////////////РАБОТА С JSON //////////////////////////////////////////

Функция СформироватьСтрокуJSONИзМассива(Объект)

	

	СтрокаJSON = "[";

	

	Для каждого Элемент Из Объект Цикл

		СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент) + ",";

	КонецЦикла;

	

	Если Прав(СтрокаJSON, 1) = "," Тогда

		СтрокаJSON = Лев(СтрокаJSON, СтрДлина(СтрокаJSON)-1);

	КонецЕсли;

	

	Возврат СтрокаJSON + "]";

	

КонецФункции



Функция СформироватьСтрокуJSONИзСтруктуры(Объект)

	

	СтрокаJSON = "{";

	

	Для каждого Элемент Из Объект Цикл

		

		Если Элемент.Значение = "" Тогда

			Продолжить;

		КонецЕсли;

		

		СтрокаJSON = СтрокаJSON + """" + Элемент.Ключ + """" + ":";

		

		Если ТипЗнч(Элемент.Значение) = Тип("Строка") Тогда

			СтрокаJSON = СтрокаJSON + """" + URLEncode(Элемент.Значение) + """";

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Число") Тогда

			СтрокаJSON = СтрокаJSON + СтрЗаменить(Строка(Элемент.Значение), Символы.НПП, "");

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Булево") Тогда

			СтрокаJSON = СтрокаJSON + Формат(Элемент.Значение, "БЛ=false; БИ=true");

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Дата") Тогда

			// преобразование в unixtime

			СтрокаJSON = СтрокаJSON + Формат(ТекущаяДата() - Дата(1970,1,1,1,0,0), "ЧГ=0");

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Массив") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент.Значение);

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Структура") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент.Значение);

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("ТаблицаЗначений") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент.Значение);

			

		Иначе

			СтрокаJSON = СтрокаJSON + """" + URLEncode(Строка(Элемент.Значение)) + """";

			

		КонецЕсли;

		

		СтрокаJSON = СтрокаJSON + ",";

		

	КонецЦикла;

	

	Если Прав(СтрокаJSON, 1) = "," Тогда

		СтрокаJSON = Лев(СтрокаJSON, СтрДлина(СтрокаJSON)-1);

	КонецЕсли;

	

	Возврат СтрокаJSON + "}";

	

КонецФункции



Функция СформироватьСтрокуJSON(Объект) Экспорт

	

	СтрокаJSON = "";

	

	Если ТипЗнч(Объект) = Тип("Массив") Тогда

		СтрокаJSON = СформироватьСтрокуJSONИзМассива(Объект);

		

	ИначеЕсли ТипЗнч(Объект) = Тип("Структура") Тогда

		СтрокаJSON = СформироватьСтрокуJSONИзСтруктуры(Объект);

		

	ИначеЕсли ТипЗнч(Объект) = Тип("ТаблицаЗначений") Тогда

		// преобразуем таблицу значений в массив структур - работает дольше, но кода меньше

		// если нужна скорость, то нужно отдельно обработать таблицу значений

		

		СоставСтруктуры = "";

		Для каждого Колонка Из Объект.Колонки Цикл

			СоставСтруктуры = СоставСтруктуры + ?(ЗначениеЗаполнено(СоставСтруктуры), ",", "") + Колонка.Имя;

		КонецЦикла;

		

		МассивСтрок = Новый Массив;

		Для каждого Строка Из Объект Цикл

			СтруктураКолонок = Новый Структура(СоставСтруктуры);

			ЗаполнитьЗначенияСвойств(СтруктураКолонок, Строка);

			МассивСтрок.Добавить(СтруктураКолонок);

		КонецЦикла;

		

		СтрокаJSON = СформироватьСтрокуJSONИзМассива(МассивСтрок);

		

	КонецЕсли;

	

	Возврат СтрокаJSON;

	

КонецФункции



Процедура ЗаполнитьДанныеИзОтветаJSON(Результат, ТекстJSON, ТипДанных)

	

	ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));	// удалим открывающий символ структуры(массива)

	

	НомерЗначения = 0;

	

	Пока ТекстJSON <> "" Цикл

		

		ПервыйСимвол = Лев(ТекстJSON, 1);

		Если ПервыйСимвол = "{" Тогда

			// вложенная структура

			Значение = Новый Структура;

			ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Структура");

			

			Если ТипДанных = "Структура" Тогда

				Результат.Вставить("Значение" + ?(НомерЗначения = 0, "", НомерЗначения), Значение);

				НомерЗначения = НомерЗначения + 1;

			ИначеЕсли ТипДанных = "Массив" Тогда

				Результат.Добавить(Значение);

			КонецЕсли;

		

		ИначеЕсли ПервыйСимвол = "[" Тогда

			// вложенный массив

			Значение = Новый Массив;

			ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Массив");

			

			Если ТипДанных = "Структура" Тогда

				Результат.Вставить("Значение" + ?(НомерЗначения = 0, "", НомерЗначения), Значение);

				НомерЗначения = НомерЗначения + 1;

			Иначе

				Результат.Добавить(Значение);

			КонецЕсли;

			

		ИначеЕсли ПервыйСимвол = "}" И ТипДанных = "Структура" Тогда

			// структура закончилась

			ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			Если Лев(ТекстJSON, 1) = "," Тогда

				ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			КонецЕсли;

			

			Возврат;

			

		ИначеЕсли ПервыйСимвол = "]" И ТипДанных = "Массив" Тогда

			// массив закончился

			ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			Если Лев(ТекстJSON, 1) = "," Тогда

				ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			КонецЕсли;

			

			Возврат;

			

		Иначе

			

			Если ТипДанных = "Структура" Тогда

				//ПервыйКавычка = Ложь;

				//Если Лев(ТекстJSON, 1) = """" Тогда

				//	ПервыйКавычка = Истина;

				//КонецЕсли;

				

				Поз = Найти(ТекстJSON, ":");

				Если Поз = 0 Тогда

					// неверный формат, прервемся

					Прервать;

				КонецЕсли;

				

				//ПредпоследнийКавычка = Ложь;

				//Если Сред(ТекстJSON, Поз - 1, 1) = """" Тогда

				//	ПредпоследнийКавычка = Истина;

				//КонецЕсли;



				

				ИмяЗначения = СокрЛП(Лев(ТекстJSON, Поз - 1));

				ИмяЗначения = СтрЗаменить(ИмяЗначения, """", "");

				

				ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз+1));

								

				Если Лев(ТекстJSON, 1) = "{" Тогда

					// значение является структурой

					Значение = Новый Структура;

					ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Структура");

					

				ИначеЕсли Лев(ТекстJSON, 1) = "[" Тогда

					// значение является массивом

					Значение = Новый Массив;

					ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Массив");

					

				Иначе

					// обычное значение

					ПервыйКавычка = Ложь;

					ПредпоследнийКавычка = Ложь;

					Поз = 0;

					Для Сч = 1 По СтрДлина(ТекстJSON) Цикл

						Символ = Сред(ТекстJSON, Сч, 1);

						

						Если Символ = """" Тогда

							Если ПервыйКавычка Тогда

								ПредпоследнийКавычка = Истина;

							Иначе

								ПервыйКавычка = Истина;

							КонецЕсли;							

						КонецЕсли;

						

						Если (Символ = "," И ((ПервыйКавычка И ПредпоследнийКавычка) Или (Не ПервыйКавычка И Не ПредпоследнийКавычка))) ИЛИ Символ = "]" ИЛИ Символ = "}" Тогда

							Поз = Сч;

							Прервать;

						КонецЕсли;

					КонецЦикла;

					

					//ПредпоследнийКавычка = Ложь;

					//Если Сред(ТекстJSON, Поз - 1, 1) = """" Тогда

					//	ПредпоследнийКавычка = Истина;

					//КонецЕсли;

					

					Если Поз = 0 Тогда

						Значение = ТекстJSON;

						ТекстJSON = "";

						

					Иначе

						Значение = Лев(ТекстJSON, Поз - 1);

						Значение = СтрЗаменить(Значение, """", "");

						ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз + ?(Сред(ТекстJSON, Поз, 1) = ",", 1, 0)));						

					КонецЕсли;

					

					Значение = СокрЛП(Значение);

					

				КонецЕсли;

				

				Результат.Вставить(ИмяЗначения, Значение);

				

			ИначеЕсли ТипДанных = "Массив" Тогда

				

				// обычное значение

				Поз = 0;

				Для Сч = 1 По СтрДлина(ТекстJSON) Цикл

					Символ = Сред(ТекстJSON, Сч, 1);

					Если Символ = "," ИЛИ Символ = "]" ИЛИ Символ = "}" Тогда

						Поз = Сч;

						Прервать;

					КонецЕсли;

				КонецЦикла;

				

				//ПредпоследнийКавычка = Ложь;

				//Если Сред(ТекстJSON, Поз - 1, 1) = """" Тогда

				//	ПредпоследнийКавычка = Истина;

				//КонецЕсли;

				

				Если Поз = 0 Тогда

					Значение = ТекстJSON;

					ТекстJSON = "";

					

				Иначе

					Значение = Лев(ТекстJSON, Поз - 1);

					Значение = СтрЗаменить(Значение, """", "");

					ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз + ?(Сред(ТекстJSON, Поз, 1) = ",", 1, 0)));

					

				КонецЕсли;

				

				Значение = СокрЛП(Значение);

				

				Результат.Добавить(Значение);

				

			КонецЕсли;

				

			

		КонецЕсли;

		

	КонецЦикла;

	

КонецПроцедуры



Функция ЗаполнитьСтруктуруИзОтветаJSON(Знач ТекстJSON) Экспорт

	

	Результат = Новый Структура;

	

	ТекстJSON = СтрЗаменить(ТекстJSON, "\""", """");	// заменим последовательность \" на "

	//ТекстJSON = СтрЗаменить(ТекстJSON, """", "");		// а теперь удалим все кавычки

	

	Если Лев(ТекстJSON, 1) = "{" Тогда

		// начало структуры

		ЗаполнитьДанныеИзОтветаJSON(Результат, ТекстJSON, "Структура");

		

	ИначеЕсли Лев(ТекстJSON, 1) = "[" Тогда

		// начало массива

		МассивДанных = Новый Массив;

		ЗаполнитьДанныеИзОтветаJSON(МассивДанных, ТекстJSON, "Массив");

		

		Результат.Вставить("Значение", МассивДанных);

		

	КонецЕсли;

		

	Возврат Результат;

	

КонецФункции



Функция КодСимволаASCII(Символ) 

   КодUNICODE = КодСимвола(Символ); 

   Если ((КодUNICODE > 1039) И (КодUNICODE < 1104)) Тогда 

       Возврат (КодUNICODE - 848); 

   ИначеЕсли КодUNICODE = 8470 Тогда 

       Возврат 185; 

   ИначеЕсли КодUNICODE = 1105 Тогда 

       Возврат 184; 

   ИначеЕсли КодUNICODE = 1025 Тогда 

       Возврат 168; 

   Иначе 

       Возврат КодUNICODE; 

   КонецЕсли; 

КонецФункции



Функция URLEncode(value)



    table = "%00%01%02%03%04%05%06%07%08%09%0A%0B%0C%0D%0E%0F%10%11%12%13%14" +

            "%15%16%17%18%19%1A%1B%1C%1D%1E%1F%20%21%22%23%24%25%26%27%28" +

            "%29%2A%2B%2C%2D%2E%2F%30%31%32%33%34%35%36%37%38%39%3A%3B%3C" +

            "%3D%3E%3F%40%41%42%43%44%45%46%47%48%49%4A%4B%4C%4D%4E%4F%50" +

            "%51%52%53%54%55%56%57%58%59%5A%5B%5C%5D%5E%5F%60%61%62%63%64" +

            "%65%66%67%68%69%6A%6B%6C%6D%6E%6F%70%71%72%73%74%75%76%77%78" +

            "%79%7A%7B%7C%7D%7E%7F%80%81%82%83%84%85%86%87%88%89%8A%8B%8C" +

            "%8D%8E%8F%90%91%92%93%94%95%96%97%98%99%9A%9B%9C%9D%9E%9F%A0" +

            "%A1%A2%A3%A4%A5%A6%A7%A8%A9%AA%AB%AC%AD%AE%AF%B0%B1%B2%B3%B4" +

            "%B5%B6%B7%B8%B9%BA%BB%BC%BD%BE%BF%C0%C1%C2%C3%C4%C5%C6%C7%C8" +

            "%C9%CA%CB%CC%CD%CE%CF%D0%D1%D2%D3%D4%D5%D6%D7%D8%D9%DA%DB%DC" +

            "%DD%DE%DF%E0%E1%E2%E3%E4%E5%E6%E7%E8%E9%EA%EB%EC%ED%EE%EF%F0" +

            "%F1%F2%F3%F4%F5%F6%F7%F8%F9%FA%FB%FC%FD%FE%FF";

    

    result = "";        

            

    length = СтрДлина( value );        

    

    Для i = 1 По  length Цикл        

        symbol = Сред( value, i, 1 );        

        //code = КодСимвола( symbol );    

        code = КодСимволаASCII( symbol );

        result = result + Сред( table, code*3 + 1, 3 );        

    КонецЦикла;

    

    

    

    Возврат result;

КонецФункции

/////////////////////////РАБОТА С JSON //////////////////////////////////////////



//Функция декодирует полученный unicod текст - из ответа геокодера Рамблера

// в привычный нам

//Параметры:

// Строка

//Возвращаемое значение:

// Строка

Функция UnicodeEncode(Строка) Экспорт 

	Результат = Истина;

	

	Попытка

		//регулярное выражение

		Рег = Новый COMОбъект("VBScript.RegExp");

		Рег.IgnoreCase = Истина;

		Рег.Global = Истина;

		Рег.Multiline = Ложь;

		Рег.Pattern = "u[0-9a-f]+";

		Колекция = Рег.Execute(Строка);

		Для Каждого Элемент Из Колекция Цикл

			Если СтрДЛина(Элемент.value) = 1 Тогда

				Продолжить;

			КонецЕсли;		

			

			КодСимвола = ПереводЧислаИз16в10(Сред(ВРег(Элемент.value), 2));

			Символ = Символ(КодСимвола);

			Строка = СтрЗаменить(Строка, "\" + Элемент.value, Символ); 

		КонецЦикла;	

	Исключение

		Результат = Ложь;

		Сообщить("Ошибка преобразования из Unicode", СтатусСообщения.Информация);

	КонецПопытки;

	

	Возврат Результат;

КонецФункции



Функция ПереводЧислаИз16в10(Знач Значение)

	Результат = 0;

	

	//перевод значения в строку

	Если ТипЗнч(Значение) <> Тип("Строка") Тогда

		Значение = СокрЛП(Строка(Значение));

	КонецЕсли;

	

	МаксРазрядЦелых = 0;

	МаксРазрядЦелых = СтрДлина(Значение) - 1;

	

	н = МаксРазрядЦелых;

	Ин = 1;

	Пока н >= 0 Цикл

		ТекЗначение = СтруктураЧисел.Получить(Сред(Значение, Ин, 1)) * Pow(16, н);

		Результат = Результат + ТекЗначение;

		н = н - 1;

		Ин = Ин + 1;

	КонецЦикла;

	

	Возврат Результат;

КонецФункции



///////////////////////////

СтруктураПоставщиковКарт = Новый Соответствие;

СтруктураПоставщиковКарт.Вставить(0, "Яндекс");

СтруктураПоставщиковКарт.Вставить(1, "Гугл");

СтруктураПоставщиковКарт.Вставить(2, "2ГИС");

СтруктураПоставщиковКарт.Вставить(3, "Рамблер");





СтруктураЧисел = Новый Соответствие;

СтруктураЧисел.Вставить("0", 0);

СтруктураЧисел.Вставить("1", 1);

СтруктураЧисел.Вставить("2", 2);

СтруктураЧисел.Вставить("3", 3);

СтруктураЧисел.Вставить("4", 4);

СтруктураЧисел.Вставить("5", 5);

СтруктураЧисел.Вставить("6", 6);

СтруктураЧисел.Вставить("7", 7);

СтруктураЧисел.Вставить("8", 8);

СтруктураЧисел.Вставить("9", 9);

СтруктураЧисел.Вставить("A", 10);

СтруктураЧисел.Вставить("B", 11);

СтруктураЧисел.Вставить("C", 12);

СтруктураЧисел.Вставить("D", 13);

СтруктураЧисел.Вставить("E", 14);

СтруктураЧисел.Вставить("F", 15);   

 



&НаКлиенте

Процедура НайтиАдрес(Команда)

	НайтиАдресНаКарте(ТекАдрес);

КонецПроцедуры



&НаКлиенте

Процедура ИнициализацияКарты(Команда)

	ИнициализироватьКарту();

КонецПроцедуры



&НаКлиенте

Процедура СправочнаяИнформация(Команда)

	Элементы.ГруппаСправка.Видимость = Не Элементы.ГруппаСправка.Видимость;

КонецПроцедуры



&НаКлиенте

Процедура Разработчик(Команда)

	ЗапуститьПриложение("http://smaylukk.com.ua/?lang=Ru");

КонецПроцедуры



&НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

	Объект.ТипКарты = Параметры.ТипКарты;

	ТекОбъект = РеквизитФормыВЗначение("Объект");

	Поставщик = ТекОбъект.СтруктураПоставщиковКарт.Получить(Объект.ТипКарты);

	

	Макет = ТекОбъект.ПолучитьМакет("Справка");

	ТекстСправки = Макет.ПолучитьОбласть("Справка" + Поставщик).Область().Текст;

	Справка = ТекстСправки;

КонецПроцедуры



&НаКлиенте

Процедура ПриОткрытии(Отказ)

	Элементы.ГруппаСправка.Видимость = Ложь;

	Заголовок = "Работа с картами. Поставщик - " + Поставщик;

	ИнициализироватьКарту();

КонецПроцедуры



&НаКлиенте

Процедура ПриЗакрытии()

	//удаление временных файлов

	Для Каждого ТекЭлемент Из МассивВременныхФайлов Цикл

		УдалитьФайлы(ТекЭлемент.Значение);

	КонецЦикла;

КонецПроцедуры



&НаКлиенте

//Процедура составляет  имя процедуры поставщика

// и запускает ее на исполнение

//Параметры:

// НачалоИмени - Строка

Процедура ВыполнитьПроцедуруПоставщика(ИмяПроцедуры)

	Выполнить ИмяПроцедуры;

КонецПроцедуры



&НаКлиенте

//процедура инициализирует карту постащика из макета

Процедура ИнициализироватьКарту()

	Текст = ПолучитьТекстМакета("Макет" + Поставщик);

	

	Эксплорер = Текст;

КонецПроцедуры



&НаСервере

Функция ПолучитьТекстМакета(ИмяМакета)

	Макет = РеквизитФормыВЗначение("Объект").ПолучитьМакет(ИмяМакета);

	Результат = Макет.ПолучитьТекст();

	Возврат Результат;

КонецФункции



&НаКлиенте

Процедура ОчисткаКарты()

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "Reset()";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



///////////////////////////////////////////////////////////////////////

///////////////////ГЕОКОДИРОВАНИЕ И ПОИСК АДРЕСА///////////////////////

///////////////////////////////////////////////////////////////////////



&НаКлиенте

Процедура НайтиАдресНаКарте(Адрес = "")	

	//поиск адреса

	Если Адрес = "" Тогда

		Адрес = "Москва";		

	КонецЕсли;

	

	// дальше пробуем с помощью геокодинга вывести данные поиска в таблицу

	ТаблицаАдресов.Очистить();

	

	ПоискАдреса(Адрес);

	Если Поставщик = "Яндекс" Тогда

		ПроизвестиГеокодинг_Яндекс();

	ИначеЕсли Поставщик = "Гугл" Тогда

		ПроизвестиГеокодинг_Гугл();

	ИначеЕсли Поставщик = "Рамблер" Тогда

		ПроизвестиГеокодинг_Рамблер();

	КонецЕсли;

КонецПроцедуры



&НаКлиенте

Процедура ПоискАдреса(Адрес)

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "FindAdres(""" + Адрес + """);";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаСервере

//Процедура выводит в таблицу данные геокдинга Яндекса

//

//Параметры:

// ТекАдрес - Строка

Процедура ПроизвестиГеокодинг_Яндекс()

	Яндекс = Новый HTTPСоединение("geocode-maps.yandex.ru");

	

	ВременныйФайл = КаталогВременныхФайлов() + "Yandex_geocode_" + СокрЛП(Новый УникальныйИдентификатор);

	Попытка

		Яндекс.Получить("/1.x/?geocode=" + ТекАдрес + "&results=10", ВременныйФайл);

	Исключение

		Сообщить("Ошибка при попытке геокодировать по яндексу адрес: " + ТекАдрес);

		Сообщить(ОписаниеОшибки());

		Возврат;

	КонецПопытки;

	

	ЧтениеXML = Новый ЧтениеXML;

	ЧтениеXML.ОткрытьФайл(ВременныйФайл);

	

	ПостроительDOM 			= Новый ПостроительDOM;

	ДокументДОМ 			= ПостроительDOM.Прочитать(ЧтениеXML);

	

	СписокText 				= ДокументДОМ.ПолучитьЭлементыПоИмени("text");

	СписокPos 				= ДокументДОМ.ПолучитьЭлементыПоИмени("pos");

		

	Если (СписокText.Количество() = 0) ИЛИ (СписокPos.Количество() = 0) Тогда

		Возврат;	

	КонецЕсли;

	

	Для ъ = 0 по СписокText.Количество()-1 Цикл

		Координаты = СписокPos[Ъ].ТекстовоеСодержимое;

		Разделитель = Найти(Координаты," ");

		Широта = Число(Сред(Координаты, Разделитель + 1));

		Долгота = Число(Лев(Координаты, Разделитель - 1));

		

		Если Широта = 0 ИЛИ Долгота = 0 Тогда

			Продолжить;

		КонецЕсли;

		

		стрАдрес = ТаблицаАдресов.Добавить();

		Если СписокText.Количество() > ъ Тогда

			стрАдрес.Адрес = СписокText[Ъ].ТекстовоеСодержимое;

			стрАдрес.Широта = Широта;

			стрАдрес.Долгота = Долгота;

		КонецЕсли;		

	КонецЦикла;	

	МассивВременныхФайлов.Добавить(ВременныйФайл);

КонецПроцедуры



&НаСервере

//Процедура выводит в таблицу данные геокдинга Гугл

//

//Параметры:

// ТекАдрес - Строка

Процедура ПроизвестиГеокодинг_Гугл()

	Гугл = Новый HTTPСоединение("maps.googleapis.com");

	

	ВременныйФайл = КаталогВременныхФайлов() + "Google_geocode_" + СокрЛП(Новый УникальныйИдентификатор);

	Попытка

		Гугл.Получить("/maps/api/geocode/xml?address=" + ТекАдрес + "&language=ru&sensor=false", ВременныйФайл);

	Исключение

		Сообщить("Ошибка при попытке геокодировать по Google адрес: " + ТекАдрес);

		Сообщить(ОписаниеОшибки());

		Возврат;

	КонецПопытки;

	

	ЧтениеXML = Новый ЧтениеXML;

	ЧтениеXML.ОткрытьФайл(ВременныйФайл);

	

	ПостроительDOM 			= Новый ПостроительDOM;

	ДокументДОМ 			= ПостроительDOM.Прочитать(ЧтениеXML);

	ТаблицаРезультатов = ДокументДОМ.ПолучитьЭлементыПоИмени("result");

	

	Если ДокументДОМ.ПолучитьЭлементыПоИмени("status")[0].ТекстовоеСодержимое <> "OK" ИЛИ ТаблицаРезультатов.Количество() = 0 Тогда 

		Возврат;

	КонецЕсли;

		

	Для ТекРезультат = 0 по ТаблицаРезультатов.Количество() -1 Цикл 

		

		СписокText 				= ТаблицаРезультатов[ТекРезультат].ПолучитьЭлементыПоИмени("formatted_address");

		ЭлементыШиротаДолгота = ТаблицаРезультатов[ТекРезультат].ПолучитьЭлементыПоИмени("location");

		Широта = ЭлементыШиротаДолгота[0].ПолучитьЭлементыПоИмени("lat")[0].ТекстовоеСодержимое;

		Долгота = ЭлементыШиротаДолгота[0].ПолучитьЭлементыПоИмени("lng")[0].ТекстовоеСодержимое;

		Если Широта = 0 ИЛИ Долгота = 0 Тогда

			Продолжить;

		КонецЕсли;

			

		стрАдрес = ТаблицаАдресов.Добавить();

		стрАдрес.Широта = Широта;

		стрАдрес.Долгота = Долгота;

		стрАдрес.Адрес = СписокText[0].ТекстовоеСодержимое;  

	КонецЦикла;

	МассивВременныхФайлов.Добавить(ВременныйФайл);

КонецПроцедуры



&НаСервере

//Процедура выводит в таблицу данные геокдинга Рамблер

//

//Параметры:

// ТекАдрес - Строка

Процедура ПроизвестиГеокодинг_Рамблер()

	ТемпАдрес = СтрЗаменить(ТекАдрес, " ", "+");

	

	Рамблер = Новый HTTPСоединение("maps.rambler.ru");	

	ВременныйФайл = КаталогВременныхФайлов() + "Рамблер_geocode_" + СокрЛП(Новый УникальныйИдентификатор);

	Попытка

		Рамблер.Получить("/search/?&a=search&q=" + ТемпАдрес + "&n=10", ВременныйФайл);

	Исключение

		Сообщить("Ошибка при попытке геокодировать по Рамблер адрес: " + ТекАдрес);

		Сообщить(ОписаниеОшибки());

		Возврат;

	КонецПопытки;

	

	а = 1;

	Т = Новый ТекстовыйДокумент;

	Т.Прочитать(ВременныйФайл);

	СтрокаОтвет = Т.ПолучитьТекст();

	Результат = РеквизитФормыВЗначение("Объект").UnicodeEncode(СтрокаОтвет);

	Если Результат Тогда

		СтруктураJSON = РеквизитФормыВЗначение("Объект").ЗаполнитьСтруктуруИзОтветаJSON(СтрокаОтвет);

	КонецЕсли;

	

	МассивРезультатов = СтруктураJSON.res;

	//обрабатываем элементы массива - только адреса. POI можно обработать отдельно пожеланию

	Для Каждого Результат Из МассивРезультатов Цикл

		Для Каждого ТекРезультат Из Результат.matches Цикл				

			стрАдрес = ТаблицаАдресов.Добавить();

			стрАдрес.Долгота = Число(ТекРезультат.x);

			стрАдрес.Широта = Число(ТекРезультат.y);

			Если Результат.type = "addr" Тогда  //Результат.type = "poi" - содержит в себе список точек интереса

				стрАдрес.Адрес = ТекРезультат.addr;

			Иначе

				стрАдрес.Адрес = ТекРезультат.name + " - " + ТекРезультат.addr;

			КонецЕсли;

		КонецЦикла;

	КонецЦикла;

	МассивВременныхФайлов.Добавить(ВременныйФайл);

КонецПроцедуры



&НаКлиенте

Процедура ОбратнПоискАдреса(Широта, Долгота, Адрес)

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "ReverseSearchAdres(" + Широта + "," + Долгота + ", """ + Адрес + """);";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

Процедура ТаблицаАдресовВыбор(Элемент, ВыбраннаяСтрока, Поле, СтандартнаяОбработка)

	Если ЗначениеЗаполнено(ТаблицаАдресов[ВыбраннаяСтрока].Широта) И ЗначениеЗаполнено(ТаблицаАдресов[ВыбраннаяСтрока].Долгота) Тогда

		СтандартнаяОбработка = Ложь;

	КонецЕсли;

	

	Широта = Формат(ТаблицаАдресов[ВыбраннаяСтрока].Широта, "ЧЦ=10; ЧДЦ=7; ЧРД=.; ЧРГ=");

	Долгота = Формат(ТаблицаАдресов[ВыбраннаяСтрока].Долгота, "ЧЦ=10; ЧДЦ=7; ЧРД=.; ЧРГ=");

	

	ОбратнПоискАдреса(Широта, Долгота, ТаблицаАдресов[ВыбраннаяСтрока].Адрес);

КонецПроцедуры



&НаКлиенте

Процедура ТекАдресПриИзменении(Элемент)

	НайтиАдресНаКарте(ТекАдрес);

КонецПроцедуры





///////////////////////////////////////////////////////////////////////

///////////////////МАРШРУТИЗАЦИЯ, КЛАСТЕРА И ПОЛИГОН///////////////////////////////////////

///////////////////////////////////////////////////////////////////////



&НаКлиенте

Процедура ЭксплорерПриНажатии(Элемент, ДанныеСобытия, СтандартнаяОбработка)

	ПолучитьКоординаты();

КонецПроцедуры



&НаКлиенте

Процедура ПостроитьМаршрут(Команда)

	Если ТаблицаТочек.Количество() <= 1 Тогда

		Предупреждение("Недостаточно точек для построение маршрута!");

		Возврат;

	КонецЕсли;

	

	Если Поставщик = "Яндекс" Тогда

		ПостроитьМаршрут_Яндекс();

	ИначеЕсли Поставщик = "Гугл" Тогда

		ПостроитьМаршрут_Гугл();

	ИначеЕсли Поставщик = "Рамблер" Тогда

		ПостроитьМаршрут_Рамблер();

	КонецЕсли;

КонецПроцедуры



&НаКлиенте

//Процедура выстраивает маршрут для Яндекса

//

//Параметры:

//

Процедура ПостроитьМаршрут_Яндекс()

	ПараметрыМаршрута = ПолучитьПараметрыМаршрутаЯндекс();

	

	ОчисткаКарты();

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "calcRoute(" + ПараметрыМаршрута + ")";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

//Функция получает массив точек, для передачи параметров в Яндекс

//

//Параметры:

//

//Возвращаемое значение:

// Строка

Функция ПолучитьПараметрыМаршрутаЯндекс()

	Результат = "";

	

	Результат = Результат + "[[" + СтрЗаменить(Строка(ТаблицаТочек[0].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[0].Долгота), ",", ".") + "],";

		

	Для Ин = 1 По ТаблицаТочек.Количество() - 2 Цикл

		Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ин].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ин].Долгота), ",", ".") + "],";

	КонецЦикла;

		

	Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Долгота), ",", ".") + "]]";

		

	Возврат Результат;

КонецФункции



&НаКлиенте

//Процедура выстраивает маршрут для Гугл

//

//Параметры:

//

Процедура ПостроитьМаршрут_Гугл()

	ПараметрыМаршрута = ПолучитьПараметрыМаршрутаГугл();

	

	ОчисткаКарты();

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "calcRoute(" + ПараметрыМаршрута + ")";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

//Функция получает массив точек, для передачи параметров в Гугл

//

//Параметры:

//

//Возвращаемое значение:

// Строка

Функция ПолучитьПараметрыМаршрутаГугл()

	Результат = "";

	ВнутрМассив = "";

	

	Результат = Результат + "[[" + СтрЗаменить(Строка(ТаблицаТочек[0].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[0].Долгота), ",", ".") + "],";

	

	Если ТаблицаТочек.Количество() = 2 Тогда

		Результат = Результат + "[],"; 

	Иначе

		Для Ин = 1 По ТаблицаТочек.Количество() - 2 Цикл

			ВнутрМассив = ВнутрМассив + "[" + СтрЗаменить(Строка(ТаблицаТочек[ин].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ин].Долгота), ",", ".") + "],";

		КонецЦикла;

		Результат = Результат + "[" + Сред(ВнутрМассив, 1, СтрДлина(ВнутрМассив) - 1) + "],";

	КонецЕсли;

	

	Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Долгота), ",", ".") + "]]";

		

	Возврат Результат;

КонецФункции



&НаКлиенте

//Процедура выстраивает маршрут для Рамблера

//

//Параметры:

//

Процедура ПостроитьМаршрут_Рамблер()

	ПараметрыМаршрута = ПолучитьПараметрыМаршрутаРамблер();

	

	ОчисткаКарты();

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "calcRoute(" + ПараметрыМаршрута + ")";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

//Функция получает массив точек, для передачи параметров в Рамблер

//

//Параметры:

//

//Возвращаемое значение:

// Строка

Функция ПолучитьПараметрыМаршрутаРамблер()

	Результат = "";

	

	Результат = Результат + "[[" + СтрЗаменить(Строка(ТаблицаТочек[0].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[0].Долгота), ",", ".") + "],";

		

	Для Ин = 1 По ТаблицаТочек.Количество() - 2 Цикл

		Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ин].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ин].Долгота), ",", ".") + "],";

	КонецЦикла;

		

	Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Долгота), ",", ".") + "]]";

		

	Возврат Результат;

КонецФункции



&НаКлиенте

Процедура СоздатьКластер(Команда)

	Если ТаблицаТочек.Количество() <= 1 Тогда

		Предупреждение("Недостаточно точек для построение кластера!");

		Возврат;

	КонецЕсли;

	

	ОчисткаКарты();

	

	ПостроитьКластера();

КонецПроцедуры



&НаКлиенте

Процедура ПостроитьКластера()

	Кол = ТаблицаТочек.Количество();

	Индекс = 1;

	Для Каждого ТекСтрока Из ТаблицаТочек Цикл

		Широта = формат(ТекСтрока.Широта, "ЧРД=.");

		Долгота = формат(ТекСтрока.Долгота, "ЧРД=.");

		СодержимоеТочки = "Содерижмое точки";  //опять же можно вставить свое название

		Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "addToPointArray(" + Широта + "," + Долгота + ", '" + ТекСтрока.Точка + "', """ + СодержимоеТочки + """);";

		Элементы.Эксплорер.document.getElementById("WebClient").click();

		

		Состояние("Обработан " + Индекс + " из " + кол);

		Индекс = Индекс + 1;

	КонецЦикла;

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "drawCluster();";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

Процедура ОчиститьВсе(Команда)

	ОчисткаКарты();

	ТаблицаТочек.Очистить();

КонецПроцедуры



&НаКлиенте

Процедура ОчиститьКарту(Команда)

	ОчисткаКарты();

КонецПроцедуры



&НаКлиенте

Процедура ОчиститьТаблицу(Команда)

	ТаблицаТочек.Очистить();

КонецПроцедуры



&НаКлиенте

//Процедура получает координаты установленной точки

Процедура ПолучитьКоординаты()

	Попытка

		ЧислоТип = Новый ОписаниеТипов("Число", Новый КвалификаторыЧисла(15, 12));

		

		КоординатаX = Элементы.Эксплорер.document.getElementById("CoordX").value;

		КоординатаX = ЧислоТип.ПривестиЗначение(КоординатаX);

		

		КоординатаY = Элементы.Эксплорер.document.getElementById("CoordY").value;

		КоординатаY = ЧислоТип.ПривестиЗначение(КоординатаY);

		

		Кол = ТаблицаТочек.Количество();

		Если КоординатаX > 0 И КоординатаY > 0 И (Кол = 0 Или КоординатаX <> ТаблицаТочек[Кол - 1].Широта И КоординатаY <> ТаблицаТочек[Кол - 1].Долгота) Тогда

			НоваяСтрока = ТаблицаТочек.Добавить();

			НоваяСтрока.Точка = "Точка" + ТаблицаТочек.Количество();

			НоваяСтрока.Широта = КоординатаX;

			НоваяСтрока.Долгота = КоординатаY;

		КонецЕсли;

	Исключение

	КонецПопытки;

КонецПроцедуры



&НаКлиенте

Процедура ПострениеПолигона(Команда)

	Если ТаблицаТочек.Количество() <= 1 Тогда

		Предупреждение("Недостаточно точек для построение полигона!");

		Возврат;

	КонецЕсли;

	

	ОчисткаКарты();

	

	ПостроитьПолигон();

КонецПроцедуры



&НаКлиенте

//Процедура выстраивает маршрут для Рамблера

//

//Параметры:

//

Процедура ПостроитьПолигон()

	МассивТочек = "[";

	Для Каждого ТекТочка Из ТаблицаТочек Цикл

		Широта = формат(ТекТочка.Широта, "ЧРД=.");

		Долгота = формат(ТекТочка.Долгота, "ЧРД=.");

		МассивТочек = МассивТочек + "[" + Широта + "," + Долгота + "],"; 

	КонецЦикла;

	МассивТочек = Сред(МассивТочек, 1, СтрДлина(МассивТочек) - 1) + "]";

	

	Цвет16 = Получить16Цвет();

	

	Название = "Полигон";//вставить свое 

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "createPolygon(" + МассивТочек + ", '" + Название + "', '" + Цвет16 + "');";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаСервере

//Функция возвращает значение случайного цвета в 16-ричном формате

//

//Параметры:

//  нет

//Возвращаемое значение:

//  Строка

Функция Получить16Цвет()

	Результат = "";

	

	Строка16 = "0123456789ABCDEF";

	ГСЧ = Новый ГенераторСлучайныхЧисел;

	Результат = "#";

	Для н = 1 По 6 Цикл

		м = ГСЧ.СлучайноеЧисло(1, 16);

		Результат = Результат + Сред(Строка16, м, 1);

	КонецЦикла;

	

	Возврат Результат;

КонецФункции



   

 МассивДобавляемыхРеквизитов = Новый Массив; 

МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("План", Новый ОписаниеТипов("ТаблицаЗначений")));    

 МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("Номенклатура", Новый ОписаниеТипов("СправочникСсылка.Номенклатура"),"План" ,"Номенклатура")); 

МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("Регион", Новый ОписаниеТипов("Число",Новый КвалификаторыЧисла(10,2)),"План" , "Регион")); 

МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("Разница", Новый ОписаниеТипов("Число",Новый КвалификаторыЧисла(10,2)),"План" , "Осталось распределить"));    

 ИзменитьРеквизиты(МассивДобавляемыхРеквизитов);    

 ТаблицаФормы = Элементы.Добавить("План", Тип("ТаблицаФормы"));

ТаблицаФормы.ПутьКДанным = "План"; 

ТаблицаФормы.ПоложениеКоманднойПанели = ПоложениеКоманднойПанелиЭлементаФормы.Нет; 

ТаблицаФормы.ФиксацияСлева = 3; 

ТаблицаФормы.УстановитьДействие("ПередУдалением", "ПланПередУдалением"); 

ТаблицаФормы.УстановитьДействие("ПередНачаломДобавления", "ПланПередНачаломДобавления");    

 НоваяКолонка = Элементы.Добавить("ПланНоменклатура", Тип("ПолеФормы"), Элементы.План); 

НоваяКолонка.Заголовок = "Номенклатура"; 

НоваяКолонка.ПутьКДанным = "План.Номенклатура";

НоваяКолонка.Вид = ВидПоляФормы.ПолеВвода; 

НоваяКолонка.РежимРедактирования = РежимРедактированияКолонки.ВходПриВводе;    

 ЭлементУсловногоОформления = УсловноеОформление.Элементы.Добавить();

ОформляемоеПоле = ЭлементУсловногоОформления.Поля.Элементы.Добавить();

ОформляемоеПоле.Поле = Новый ПолеКомпоновкиДанных("ПланНоменклатура");

ЭлементОтбора = ЭлементУсловногоОформления.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));

ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("План.Разница");

ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;

ЭлементОтбора.ПравоеЗначение = 100; 

ЭлементУсловногоОформления.Оформление.УстановитьЗначениеПараметра("ЦветФона", WebЦвета.СеребристоСерый);   

 Процедура ОсновныеДействияФормыВыбрать(Кнопка)

 

 ТекущаяСтрока = ЭлементыФормы.СписокЗначений.ТекущиеДанные;

 Если ТекущаяСтрока <> Неопределено Тогда

  Закрыть(ТекущаяСтрока);

 КонецЕсли;

 

КонецПроцедуры



Процедура СписокЗначенийПередНачаломДобавления(Элемент, Отказ, Копирование)

 

 Отказ = Истина;

 

КонецПроцедуры



Процедура СписокЗначенийВыбор(Элемент, ВыбраннаяСтрока, Колонка, СтандартнаяОбработка)

 

 ТекущаяСтрока = ЭлементыФормы.СписокЗначений.ТекущиеДанные;

 Если ТекущаяСтрока <> Неопределено Тогда

  Закрыть(ТекущаяСтрока);

 КонецЕсли;

 

КонецПроцедуры



Процедура ЗакрытьФорму(Кнопка) //процедура действия кнопки закрыть

Закрыть();

КонецПроцедуры   

 //К примеру Пользователю необходимо выбрать Вид расчета по которому в дальнейшем сформировать отчет.

 Массив = ТаблицаНачислений.ВыгрузитьКолонку("Видрасчета"); //Выгружаем из таблицы начислений в Массив Виды Расчетов

 Список = Новый СписокЗначений;    // Создадим Список

 Список.ЗагрузитьЗначения(Массив); // Загрузим в список Виды расчета из массива

 ФормаРаботыСоСпискомЗначений = ПолучитьОбщуюФорму("ФормаРаботыСоСпискомЗначений"); // Получаем Нашу Универсальную Форму

 ФормаРаботыСоСпискомЗначений.СписокЗначений = Список;   // Передаем в нее список Видов Расчетов

 ЭлементСписка = ФормаРаботыСоСпискомЗначений.ОткрытьМодально(); //Отрываем форму, чтобы пользователь выбрал значение из списка

 

 //ЭлементСписка - Выбранный элемент, Если пользователь ничего не выбрал, а нажал Закрыть,

 //то ЭлементСписка = Неопределено и пусть отчет формируется по всем Видам расчетов

 Если ЭлементСписка <> Неопределено Тогда

  ВидРасчета=ЭлементСписка.Значение; //Пользователь Выбрал из списка Вид расчета, формируем отчет по нему.

 иначе

  СписокВидовРасчетов = ФормаРаботыСоСпискомЗначений.СписокЗначений; // Пользователь нажал кнопку Закрыть, формируем по всем Видам Расчетов

 КонецЕсли;

 //----------------------Далее уже ваш модуль обработки...------------------------------------//

   

 Функция УдалитьПовторяющиесяЭлементыМассива(Массив) Экспорт 

 ТекущийИндекс = 0; 

	ВсегоЭлементов = Массив.Количество(); 

	Пока ТекущийИндекс < ВсегоЭлементов Цикл 

		Индекс2 = ТекущийИндекс + 1; 

		Пока Индекс2 < ВсегоЭлементов Цикл 

			Если Массив[Индекс2] = Массив[ТекущийИндекс] Тогда 

				Массив.Удалить(Индекс2); 

				ВсегоЭлементов = ВсегоЭлементов - 1; 

			Иначе 

				Индекс2 = Индекс2 + 1; 

			КонецЕсли; 

		КонецЦикла; 

		ТекущийИндекс = ТекущийИндекс + 1; 

	КонецЦикла; 

Возврат Массив; 

КонецФункции