plus%dll » Поиск

Результаты по ключевому слову: plus%dll

v7plus.dll - отсутствует CLSID либо отсутствует интерфейс llnitDone

При выгрузке отчетности в 1С 7.7 программа ругается на v7plus.dll и указывает, что отсутствует интерфейс llritDone. Что делать?

1) Поудалять нафиг все v7plus.dll из каталогов ИБ и папок пользователей
2) Оставить только в bin каталоге и зарегить через ее через regsvr32
3) Зайди на кажной машине в 1С по разу под админом системы (локальным или доменным)

Устранение ошибки при создании объекта из компоненты v7plus.dll (отсутствует CLSID)
Как установить компоненту V7Plus.dll

Категория: Администрирование

Как связать 1C, PHP , MySQL?

В современном мире люди используют Интернет не только для поиска информации, но и для приобретения каких либо товаров и услуг. Поэтому организации, например имеющие статус среднего бизнеса, стараются разместить свои прайс-листы в интернете или даже создать Интернет-магазин. Создать его не так-то просто. Если вы имеете «реальный» бизнес и используете определенную систему учета товаров (или услуг), нужно учитывать несколько немаловажных факторов:
* Каждый уважающий себя Интернет-магазин должен показывать остаток товара на складе, а также не показывать тот товар, которого уже нет в наличии. (а может быть что товар есть на разных региональных складах)
* Цены не должны расходиться с ценами в реальном магазине. Не учитывая доставку, хотя и это уже давно стало бесплатным практически везде.

Я привел только 2 факта, в действительности их может быть гораздо больше, всё зависит от того, какую цель вы ставите перед своим Интернет-проектом.

Многие организации для ведения учета товаров или оказанных услуг используют ПО «1С» и как показывает практика, большая часть организаций работает с версией 7.7, и не торопятся перейти на 8.х. так как это влечет за собой накладные расходы.

Для Реализации работы с WEB в 1С7.7 есть прекрасное решение - WEB-расширение, но оно работает только с Microsoft Internet Information Server (IIS). IIS используют не все хостинг – провайдеры, да и те кто использует вряд ли разрешат подключить свой сервер к чужой БД.

А держать «у себя» IIS сервер достаточно накладно для организаций среднего бизнеса (оборудование + интернет канал + лицензии ОС и ПО = увеличение стоимости товара).

Другое дело «свободное» ПО и ОС: Linux, Apache, PHP, MySQL. Эти четыре продукта использует большинство хостинг – провадеров, поэтому их использование как платформы для создания Интернет-проектов наиболее оптимально.

Как связать 1С 7.7 с MySQL? Можно использовать внешнюю компоненту MySQL,dll, но её использование не всегда возможно, особенно если ваш Веб-сервер находиться удаленно или вы покупаете хостинг у сторонней организации, так как не безопасно открывать доступ к БД из Интернета.

Для решения этой задачи я использовал технологию передачи данных через URL.
Возможно, звучит это немного дико, и многие подумают, что это неправильное решение. Однако эта система работает и работает достаточно хорошо и корректно.
И сейчас я бы хотел поделиться с коллегами приобретенным опытом реализации это технологии.

Кратко о принципе:
Выглядит это так: из 1С вызывается url и через него же передаются данные PHP-скрипу, который в свою очередь делает с ними все, что необходимо.

Например, нам нужно передать остаток товара на складе: из 1С должен будет сформироваться url: http://www.server.com/script.php?good=201&count=302&date=2009-06-09, где:
* http://www.server.com – адрес сервера
* script.php – исполняющий скрипт
* good=201 – переменная и код товара
* count=302 – переменная и количество остатка
* date=2009-06-09 – дата на которую передается остаток
причем для работы данной схемы достаточно лишь иметь доступ в Интернет с того компьютера на котором выполняется операция по передачи данных. (сервер БД нет необходимости подключать к Интернету)
Встреча с возможными ошибками:

Для начала хотелось бы рассказать о тех проблемах, с которыми я столкнулся и о том, как можно их наиболее эффективно решить:
1. Проблема передачи дробных чисел, а именно трудности, возникающие при использовании символа «точка» (.)

Если необходимо передать любое дробное число, то в 1С оно будет храниться виде 1.1. При передаче числа через url точка, отделяющая целую часть от дробной, вызывает ошибку, так как символ «точка» служит для разделения доменов. Следовательно, необходимо преобразовать эту самую «точку» в другой символ наиболее подходящий для этого. И этот символ - «запятая» (,). Для того чтобы осуществить это преобразование, я написал функцию, листинг которой приведен ниже:

Код 1C v 7.x

 Функция ЧислоURL(Стр) 

	Возврат СтрЗаменить(Строка(Стр),".",",");

КонецФункции

Эта функция возвращает строку в которой все символы «.» заменены на «,» в строковой переменной Стр. Применимо это не только к числам, но и к текстовым данным.

Теперь при передаче число 1.1 будет иметь формат 1,1. Далее при получении мы должны привести это число обратно в «привычный» вид, это можно сделать на стороне PHP-скрипта функцией strtr() . краткое её описание я привел ниже:
Описание функции string strtr ( string $str , string $from , string $to ):

Эта функция возвращает строку str , в которой каждое вхождение любого символа из перечисленных в from заменено на соответствующий символ из строки to . (www.php.net)

Т.е. в нашем случае функция будет иметь вид strtr("1,1", ",", ".") и результатом её работы будет: 1.1

2. Проблема передачи даты. В 1С дата имеет вид «ДД.ММ.ГГГГ» например, 01.01.2009. При передаче такого вида данных будет вызвана такая же ошибка, как и при передаче числовых данных. Конечно, для решения и этой проблемы можно использовать указанную выше функцию ЧислоURL, но я решил пойти другим путём и конвертировал дату в формат MySQL, то есть «ГГГГ-ММ-ДД». Для этого я написал функцию МуДата, вот ее листинг:

Код 1C v 7.x

 Функция МуДата(Стр)  //дата в формате MySQL (ГГГГ-ММ-ДД)

	Возврат "" + ДатаГод(Стр) + "-" +ДатаМесяц(Стр) + "-" + ДатаЧисло(Стр);	

КонецФункции

Функция работает следующим образом – опять же выделяет из переменной Стр, Год, Месяц, Число и выстраивает их в формате ГГГГ-ММ-ДД, наиболее привычным при работе с MySQL. Об ошибках все.

Подготовка 1С:
Теперь расскажу о том, как заставить 1С работать с WEB.
Для того, чтобы иметь возможность работать с протоколом HTTP в 1С, я использовал библиотеку V7+, которая поставляется фирмой 1С и служит для расширения возможностей 1С 7.7.

Для начала необходимо подключить внешнюю компоненту (подробнее здесь), используя функцию «ЗагрузитьВнешнююКомпоненту("v7plus.dll")». Далее необходимо создать объект addin.v7httpreader, для этого я использовал переменную НТТР. А для передачи и получения данных используется метод ПолучитьКакСтроку(адрес, СтрокаДляПриёма); который получает данные в переменную СтрокаДляПриёма с адреса указанного в переменной адрес. В целом все это будет выглядеть примерно так:

Код 1C v 7.x

 Процедура Сформировать()

 	ПЕРЕМ СтрокаДляПриёма;

	ЗагрузитьВнешнююКомпоненту("v7plus.dll");

	HTTP=СоздатьОбъект("addin.v7httpreader");

	адрес="http://www.google.ru";

	HTTP. ПолучитьКакСтроку (адрес, СтрокаДляПриёма);

	сообщить (СтрокаДляПриёма);

КонецПроцедуры

Выше указанная процедура выведет в окно сообщений HTML-код заглавной страницы сайта http://www.google.ru
Таким образом, теперь мы знаем, как, из 1С, обратиться к нужному сайту, и получить его HTML-код.

Немного о PHP:
Теперь напишем PHP-скрипт, который просто будет выводить данные полученные методом GET. (ознакомиться с тем, как PHP получает данные можно здесь) Листинг такого скрипта:

Код

<?php
$text=$_GET['text']; // получаем значение переменной text
print $text;
?>

Назовем его test.php и поместим в корневую папку web-сервера. Далее для проверки работы скрипта введем в адресную строку браузера http://localhost/test.php?text=hello%20wolrd В том случае, если все сделано верно, на экране появиться страница с текстом hello world.

«Соединяем» 1С и PHP:
Далее создаем в 1С внешнюю обработку и вставим в её модуль следующий код:

Код 1C v 7.x

 Функция Сформировать()

   	ПЕРЕМ СтрокаДляПриёма;

	ЗагрузитьВнешнююКомпоненту("v7plus.dll");

	HTTP=СоздатьОбъект("addin.v7httpreader");

	адрес="http://localhost/test.php?text="+текст;

	HTTP. ПолучитьКакСтроку(адрес, СтрокаДляПриёма);

	Сообщить(СтрокаДляПриёма);

КонецФункции

Отличается она от алгоритма, который мы создавали выше лишь значением в переменной адрес.
И так в случае успешной работы 1С и РНР-скпипта в окне сообщений 1С мы увидим надпись hello world.

Теперь очевидно, что с помощью 1C можно передать данные PHP-скриптам, а они в свою очередь делают с ними все что необходимо, например, записывают их в БД.

Пример записи данных в БД MySQL:
Запись в БД MYSQL будет производиться средствами PHP, об этом сказано уже не мало. Поэтому чтобы не повторяться, опишу пример из собственной практики.

Для начала создадим обработку в 1С:
На форму положим поле ввода и присвоим ему идентификатор текст, далее немного переделаем процедуру описанную в разделом выше:

Код 1C v 7.x

 Процедура Сформировать()

   	ПЕРЕМ СтрокаДляПриёма;

	ЗагрузитьВнешнююКомпоненту("v7plus.dll");

	HTTP=СоздатьОбъект("addin.v7httpreader");

	адрес=адрес="http://localhost/test.php?text="+Стр;

	HTTP. ПолучитьКакСтроку(адрес, СтрокаДляПриёма);

	возврат(СтрокаДляПриёма);

КонецПроцедуры

Теперь необходимо создать БД в MySQL (как это сделать описано здесь). Создадим БД и присвоим ей имя TESTDB. Далее создадим таблицу с именем TEST:

Код

CREATE TABLE `test` (
`id` INT NOT NULL AUTO_INCREMENT ,
`text` TEXT NOT NULL ,
PRIMARY KEY ( `id` )
);

Как видно из запроса, в таблице всего 2 поля:
* id – уникальный номер сроки;
* text – текстовое поле, куда будут помещаться данные из 1С.

Теперь необходимо написать PHP-скрипт, который и будет записывать данные из 1С в MySQL. Листинг данного скрипта приведен ниже:

Код

<?php
$host='localhost'; //адрес сервера
$db='testdb'; //имя БД
$user='root'; // имя пользователя
$password=''; //пароль к БД
$link = mysql_connect($host, $user, $password); //установка соединения
mysql_S_elect_db($db, $link); //подключения в БД

$text=$_GET['text']; // получаем значение переменной text

$query = "I_nsert into test values (NULL, '$text')"; //генерируем запрос
mysql_query($query, $link); //отправляем запрос
print mysql_error(); //сообщаем об ошибке если ошибок не было то возвращает пустое значение.
?>

Все готово! Теперь открываем Внешнюю обработку в 1С и пишем в поле ввода слово Hello! Нажимаем кнопку «Сформировать». Если все сделано правильно, то в созданной нами таблице появится запись со словом Hello! В противном случае, в окне сообщений 1С появится текст ошибки.

Заключение:
Весь тот опыт, которым я поделился в этой статье, можно использовать не только в Интернет-торговли, но и в корпоративных целях, например для того, чтобы:
* Консолидировать данные в единую БД MySQL;
* Предоставлять отчеты компетентным лицам, где бы они не находились.

И это еще далеко не весь перечень, ведь WEB-технологии - очень гибкий инструмент с неограниченным спектром возможностей, при условии умелого их использования.
В общем-то, мной был не только реализован механизм отправки данных, но и приема через HTTP, но вот это уже совсем другая история!

Автор: Хамитов Руслан

Категория: COM-объекты, WMI, WSH

Как получить уникальный идентификатор объекта, GUID?

GUID (Globally Unique Identifier) — статистически уникальный 128-битный идентификатор. Его главная особенность — уникальность, которая позволяет создавать расширяемые сервисы и приложения без опасения конфликтов, вызванных совпадением идентификаторов. Хотя уникальность каждого отдельного GUID не гарантируется, общее количество уникальных ключей настолько велико (2128 или 3,402 * 10в38), что вероятность того, что в мире будут независимо сгенерированы два совпадающих ключа, крайне мала.

Для получения уникального идентификатора объекта, используйте код вида:

Код 1C v 8.х

 ГУИДССЫЛКИ	= СсылкаНаОбъект.УникальныйИдентификатор();

// или

НоменклатураСсылка = Справочники.Номенклатура.НайтиПоКоду("00013");

Если НЕ НоменклатураСсылка.Пустая() Тогда

   Сообщить("GUID = " + НоменклатураСсылка.УникальныйИдентификатор());

КонецЕсли;

Как с помощью запроса получить уникальный идентификатор:

Код 1C v 8.х

  Запрос = Новый Запрос;

       Запрос.Текст = "ВЫБРАТЬ

                        |    Номенклатура.НаименованиеПолное,

                        |    Номенклатура.ЕдиницаИзмерения,

                        |    Номенклатура.СтавкаНДС,

                        |    Номенклатура.НоменклатурнаяГруппа,

                        |    Номенклатура.СчетУчетаЗапасов,

                        |    Номенклатура.СчетУчетаЗатрат,

                        |    Номенклатура.Ссылка, 

                        |    Номенклатура.ЭтоГруппа

                        | ИЗ

                        |    Справочник.Номенклатура КАК Номенклатура"; 

       РезультатЗапроса = Запрос.Выполнить();

       СпрОбъект = РезультатЗапроса.Выбрать();    

       Пока СпрОбъект.Следующий()  Цикл

          СтрокаУИ = Объект.XMLСтрока(СпрОбъект.Ссылка);

          GUID = Справочники.Номенклатура.ПолучитьСсылку(Новый УникальныйИдентификатор(СокрЛП(СтрокаУИ)));          

        КонецЦикла;

В 1С 7.7 можно получить так

Через v7plus.dll

Код 1C v 7.x

 Инфо = СоздатьОбъект("AddIn.V7SysInfo");

ГлобальноУникальныйИдентификатор = Инфо.СоздатьGUID();

Через WScript

Код 1C v 7.x

 Функция СоздатьGUID()

    TypeLib = CreateObject("Scriptlet.TypeLib");

    NewGUID = TypeLib.Guid();

    TypeLib = "";

    Возврат NewGUID;

КонецФункции    



//******************************************* 

Процедура Сформировать()

    g=СоздатьGUID();

    Сообщить("Создан GUID: "+g);

КонецПроцедуры

при OLE доступе:

Код 1C v 7.x

 Если Док_Источник.ВыбратьДокументы(ВыбНачПериода,ВыбКонПериода) = 1 Тогда

    Пока Док_Источник.ПолучитьДокумент() = 1 Цикл

Объект = БазаОле.ЗначениеВстрокуВнутр(Док_Источник.ТекущийДокумент());

ИдентификаторДокумента = СокрЛП(ПолучитьИД(Объект));



//   Для примера Объект возвращает {"O","0","0","3114","0","0","    258156CB "}, 

//   а ПолучитьИД(объект) = 258156CB

КонецЦикла;

Еще посмотрите метод:
ЗначениеВСтрокуВнутр(<?>);
Синтаксис:
ЗначениеВСтрокуВнутр(<Объект>)
Назначение:
Преобразование значения объекта агрегатного типа в строковое системное представление.
Возвращает: представление значения объекта в строковом системном виде.
Параметры:
<Объект> - значение объекта агрегатного типа данных которое нужно преобразовать.

Категория: Встроенные Функции

Выгрузка / Загрузка данных посредством XML файлов?

В основе работы с XML-файлами лежит технология доступа SAX, которая осуществляет считывание по одному тегу. Для этого существует два типа данных – ЗаписьXML и ЧтениеXML.
Запись данных справочника в XML-файл:

Код 1C v 8.х

 Запись = Новый ЗаписьXML;

Запись.ОткрытьФайл(ПутьКФайлу);

Запись.ЗаписатьОбъявлениеXML();

// формируем корневой элемент

Запись.ЗаписатьНачалоЭлемента("Клиенты");

Выборка = Справочники.Клиенты.Выбрать();

Пока Выборка.Следующий() Цикл

	// для каждого клиента формируем свой элемент

	Запись.ЗаписатьНачалоЭлемента("Клиент");

	// запишем код клиента в атрибут тега

	Запись.ЗаписатьАтрибут("Код", Строка(Выборка.Код));

	// Наименование клиента запишем в текст элемента

	Запись.ЗаписатьТекст(Выборка.Наименование);

	// закрываем элемент клиента

	Запись.ЗаписатьКонецЭлемента();	

КонецЦикла;

// закрываем корневой элемент xml-документа

Запись.ЗаписатьКонецЭлемента();	

// закрыть файл

Запись.Закрыть();

Чтение данных из XML-файла в справочник:

Код 1C v 8.х

 Чтение = Новый ЧтениеXML;

Чтение.ОткрытьФайл(ПутьКФайлу);

Спр="";

// чтение осуществляется по одному тегу

Пока Чтение.Прочитать() Цикл

	// анализируем тип элемента и его имя

	Если Чтение.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда

		Если Чтение.Имя="Клиент" Тогда

			// создаем новый элемент справочника

			Спр = Справочники.Клиенты.СоздатьЭлемент();

// читаем атрибуты

			Пока Чтение.ПрочитатьАтрибут() Цикл

				Если Чтение.Имя="Код" Тогда

					Спр.Код = Число(Чтение.Значение);

				КонецЕсли;

КонецЦикла;

		КонецЕсли;

	ИначеЕсли Чтение.ТипУзла = ТипУзлаXML.Текст Тогда

		// заполняем наименование созданного ранее элемента

		Спр.Наименование = Чтение.Значение;

	ИначеЕсли Чтение.ТипУзла = ТипУзлаXML.КонецЭлемента Тогда

		// требуется записать информацию про клиента

		Спр.Записать();

	КонецЕсли;

КонецЦикла;

Создадим обработку в типовой конфигурации для экспорта плана счетов. Структура xml-файла должна быть такой. Корневой элемент xml-документа соответствует плану счетов в целом. В нем располагаются подчиненные элементы с именем Счет, содержащие информацию о счетах. В качестве содержимого элементов указывается наименование счета. Остальные данные записываются в качестве атрибутов (код, признаки валютного, количественного учета и пр.). В качестве подчиненных элементов для элемента Счет задаются элементы, обозначающие его субсчета с теми же атрибутами. Приведем код процедуры экспорта плана счетов.

Код 1C v 7.x

 Процедура Выполнить()

  Если ЗагрузитьВнешнююКомпоненту(КаталогПрограммы()+"v7plus.dll")<>1 Тогда

    Предупреждение("Компонента не обнаружена");

    Возврат;

  КонецЕсли;

  Анализатор=СоздатьОбъект("AddIn.XMLParser");

  Корень=Анализатор.СоздатьДокумент();

  План=Корень.СоздатьПодчиненныйЭлемент("ПланСчетов");

  Счет=СоздатьОбъект("Счет.Основной");

  Родитель=СоздатьОбъект("Счет.Основной");

  Счет.ВыбратьСчета();

  Пока Счет.ПолучитьСчет()=1 Цикл

    // если это счет, а не субсчет

    Если Счет.Уровень()=1 Тогда

      Родитель.НайтиПоКоду(Счет.Код);

      СчетXML=План.СоздатьПодчиненныйЭлемент("Счет");

      СчетXML.УстановитьАтрибут("Код", Счет.Код);

      СчетXML.УстановитьАтрибут("Валютный", Счет.Валютный);

      СчетXML.УстановитьАтрибут("Количественный", Счет.Количественный);

      СчетXML.УстановитьАтрибут("Забалансовый", Счет.Забалансовый);

      Если Счет.Активный=1 Тогда

        СчетXML.УстановитьАтрибут("вид","активный");

      ИначеЕсли Счет.Активный=2 Тогда

        СчетXML.УстановитьАтрибут("вид","пассивный");

      Иначе

        СчетXML.УстановитьАтрибут("вид","активно-пассивный");

      КонецЕсли;

      СчетXML.Значение=Счет.Наименование;

    Иначе

      Если Счет.ПринадлежитГруппе(Родитель)=1 Тогда

        СубсчетXML=СчетXML.СоздатьПодчиненныйЭлемент("Субсчет");

        СубсчетXML.УстановитьАтрибут("Код", Счет.Код);

        // аналогично устанавливаем все атрибуты на элемент СубсчетXML

        СубсчетXML.Значение=Счет.Наименование;

      КонецЕсли;

    КонецЕсли;

  КонецЦикла;

  Корень.Записать(КаталогПрограммы()+"plan.xml");

КонецПроцедуры

В результате будет получен файл, вот его фрагмент:

Код

<?xml version="1.0" encoding="windows-12Sl" ?> - <ПланСчетов>
<Счет Код="00" Валютный="0" Количественный="0" Забалансовый="0" вид="активно-пассивный">Вспомогательный</Счет>
- <Счет Код="01" Валютный="0" Количественный="0" Забалансовый="0" вид="активный">
Основные средства
<Субсчет Код="01.1" Валютный="0" Количественный="0" Забалансовый="0"
вид="активный">ОС в организации</Субсчет> <Субсчет Код="01.2" Валютный="0" Количественный="0" Забалансовый="0"
вид="активный">Выбытие ОС</Субсчет> </Счет>
- <Счет Код="02" Валютный="0" Количественный="0" Забалансовый="0" вид="пассивный">
Амортизация ОС

А теперь приведем код для импорта плана счетов из xml-файла в новую конфигурацию. Код модуля соответствующей обработки должен содержать процедуру Выполнить(), которая имеет такой вид.

Код 1C v 7.x

 Процедура Выполнить()

  Если ЗагрузитьВнешнююКомпоненту(КаталогПрограммы()+"v7plus.dll")<>1 Тогда

    Предупреждение("Внешняя компонента не найдена");

    Возврат;

  КонецЕсли;

  Анализатор=СоздатьОбъект("AddIn.XMLParser");

  Файл=Анализатор.СоздатьДокумент();

  Файл.Загрузить(КаталогПрограммы()+"plan.xml");

  План=Файл.ВыбратьУзел("ПланСчетов");

  кол=План.КоличествоПодчиненных();

  Счет=СоздатьОбъект("Счет.Основной");

  Для инд=1 по кол Цикл

    СчетXML=План.ПолучитьПодчиненныйПоНомеру(инд);

    КолСубсчетов=СчетXML.КоличествоПодчиненных();

    // подчиненным элементом является и содержимое элемента

    Если КолСубсчетов>1 Тогда

      Счет.Новый(1);

    Иначе

      Счет.Новый(0);

    КонецЕсли;

    Счет.Код=СчетXML.ПолучитьАтрибут("Код");

    Счет.Наименование=СчетXML.Значение;

    Счет.Валютный=СчетXML.ПолучитьАтрибут("Валютный");

    Счет.Количественный=СчетXML.ПолучитьАтрибут("Количественный");

    Счет.Забалансовый=СчетXML.ПолучитьАтрибут("Забалансовый");

    Если СчетXML.ПолучитьАтрибут("вид")="активный" Тогда

      Счет.Активный=1;

    ИначеЕсли СчетXML.ПолучитьАтрибут("вид")="пассивный" Тогда

      Счет.Активный=2;

    Иначе

      Счет.Активный=3;

    КонецЕсли;

    Счет.Записать();

    Если КолСубсчетов>1 Тогда

      Счет1=СоздатьОбъект("Счет.Основной");

      Для инд1=2 По кол_субсчетов Цикл

        Субсчет=СчетXML.ПолучитьПодчиненныйПоНомеру(инд1);

        Счет1.Новый(0);

        Счет1.Код=Субсчет.ПолучитьАтрибут("Код");

        // аналогично устанавливаются все атрибуты создаваемого субсчета

        Счет1.Записать();

      КонецЦикла;

    КонецЕсли;

  КонецЦикла;

Категория: XML, DBF, TXT, CSV

Загрузка данных из XML файла в Таблицу Значений и вывод в Табличный документ

Код 1C v 7.x

 Перем ИмяПути,ИмяФайла;     

Перем xmlParser;



//пример чтения xml файла.

Функция УстановитьКомпоненту()

 Если ЗагрузитьВнешнююКомпоненту(КаталогИБ()+"ExtFormsv7plus.dll")=0 Тогда

  Если ЗагрузитьВнешнююКомпоненту("v7plus.dll")=0 Тогда

   Сообщить("Не удалось обнаружить компоненту V7Plus.dll!"); 

   Возврат 0;

  КонецЕсли;

 КонецЕсли;

 Попытка

  xmlParser = СоздатьОбъект("Addin.XmlParser") ;

 Исключение 

  Сообщить("Не удалось создать объект Addin.XmlParser!");

  Возврат 0;

 КонецПопытки;

 Возврат 1;

КонецФункции  // УстановитьКомпоненту



Процедура Выполнить() 

  стрИмяФайла=ИмяПути+ИмяФайла;  

  таб=СоздатьОбъект("ТаблицаЗначений");

  таб.НоваяКолонка("Ф","Строка",50,0);

  таб.НоваяКолонка("И","Строка",50,0);

  таб.НоваяКолонка("О","Строка",50,0);

  таб.НоваяКолонка("ДатаР","Дата");

  таб.НоваяКолонка("_01","Число",16,2);

  таб.НоваяКолонка("_02","Число",16,2);

  таб.НоваяКолонка("_03","Число",16,2);

  таб.НоваяКолонка("_04","Число",16,2);

  таб.НоваяКолонка("_05","Число",16,2);

  таб.НоваяКолонка("_06","Число",16,2);

  таб.НоваяКолонка("_07","Число",16,2);

  таб.НоваяКолонка("_08","Число",16,2);

  таб.НоваяКолонка("_09","Число",16,2);

  таб.НоваяКолонка("_10","Число",16,2);

  таб.НоваяКолонка("_11","Число",16,2);

  таб.НоваяКолонка("_12","Число",16,2);

  таб.НоваяКолонка("СумГод","Число",18,2);

  таб.НоваяКолонка("ОблГод","Число",18,2);

  таб.НоваяКолонка("УдерГод","Число",18,2);

  таб.НоваяКолонка("Индекс","Строка",6,0);

  таб.НоваяКолонка("Регион","Строка",2,0);

  таб.НоваяКолонка("Город","Строка",20,0);

  таб.НоваяКолонка("Улица","Строка",20,0);

  таб.НоваяКолонка("Дом","Строка",5,0);

  таб.НоваяКолонка("Корпус","Строка",5,0);

  таб.НоваяКолонка("Квартира","Строка",5,0);

  Документ=xmlParser.СоздатьДокумент();  

  Документ.Загрузить(стрИмяФайла);   

   Данные=Документ.ПолучитьПодчиненныйПоНомеру(2);

   Для Сч=1 По Данные.КоличествоПодчиненных() Цикл 

    таб.НоваяСтрока();

    Элем=Данные.ПолучитьПодчиненныйПоНомеру(Сч); 

    УзелПолучДох=Элем.ВыбратьУзлы("ПолучДох");  

    Для Сч3=0 По УзелПолучДох.КоличествоУзлов-1 Цикл 

   //  Сообщить(УзелПолучДох.ПолучитьУзел(Сч3).ПредставлениеXML); 

   //  Сообщить(УзелПолучДох.ПолучитьУзел(Сч3).КоличествоПодчиненных()); 

     ФИО=УзелПолучДох.ПолучитьУзел(Сч3).ПолучитьПодчиненныйПоНомеру(1);

     таб.Ф=ФИО.ПолучитьПодчиненныйПоНомеру(1).Текст;

     таб.И=ФИО.ПолучитьПодчиненныйПоНомеру(2).Текст;

     таб.О=ФИО.ПолучитьПодчиненныйПоНомеру(3).Текст;

     таб.ДатаР=УзелПолучДох.ПолучитьУзел(Сч3).ПолучитьПодчиненныйПоНомеру(3).Значение;

     адр=УзелПолучДох.ПолучитьУзел(Сч3).ПолучитьПодчиненныйПоНомеру(6);

     Для Сч4=1 По адр.КоличествоПодчиненных() Цикл     

      Если адр.ПолучитьПодчиненныйПоНомеру(Сч4).Наименование="Индекс" Тогда

	таб.Индекс=адр.ПолучитьПодчиненныйПоНомеру(Сч4).Текст;

      ИначеЕсли адр.ПолучитьПодчиненныйПоНомеру(Сч4).Наименование="КодРегион" Тогда

       таб.Регион=адр.ПолучитьПодчиненныйПоНомеру(Сч4).Текст;

      ИначеЕсли адр.ПолучитьПодчиненныйПоНомеру(Сч4).Наименование="Город" Тогда

       таб.Город=адр.ПолучитьПодчиненныйПоНомеру(Сч4).Текст; 

      ИначеЕсли адр.ПолучитьПодчиненныйПоНомеру(Сч4).Наименование="Улица" Тогда

       таб.Улица=адр.ПолучитьПодчиненныйПоНомеру(Сч4).Текст; 

      ИначеЕсли адр.ПолучитьПодчиненныйПоНомеру(Сч4).Наименование="Дом" Тогда

       таб.Дом=адр.ПолучитьПодчиненныйПоНомеру(Сч4).Текст; 

      ИначеЕсли адр.ПолучитьПодчиненныйПоНомеру(Сч4).Наименование="Корпус" Тогда

       таб.Корпус=адр.ПолучитьПодчиненныйПоНомеру(Сч4).Текст; 

      ИначеЕсли адр.ПолучитьПодчиненныйПоНомеру(Сч4).Наименование="Кварт" Тогда

       таб.Квартира=адр.ПолучитьПодчиненныйПоНомеру(Сч4).Текст; 

      Иначе

      	/////// 

      КонецЕсли;

     КонецЦикла;

    КонецЦикла;  

    УзелСвДохСтав=Элем.ВыбратьУзлы("СвДохСтав");  

    Для Сч3=0 По УзелСвДохСтав.КоличествоУзлов-1 Цикл     

     //ел=УзелСвДохСтав.ПолучитьУзел(Сч3);

	УзелДохВыч=УзелСвДохСтав.ПолучитьУзел(Сч3).ВыбратьУзлы("ДохВыч");

     Для Сч4=0 По УзелДохВыч.КоличествоУзлов-1 Цикл     

         МесДоход=УзелДохВыч.ПолучитьУзел(Сч4); 

         ИмяМес="";

      СумМес=0;

      Если МесДоход.ПолучитьПодчиненныйПоНомеру(1).Наименование="НомМес" Тогда

           ИмяМес=МесДоход.ПолучитьПодчиненныйПоНомеру(1).Текст;

      КонецЕсли;  

      Если МесДоход.ПолучитьПодчиненныйПоНомеру(3).Наименование="СумДоход" Тогда

           СумМес=МесДоход.ПолучитьПодчиненныйПоНомеру(3).Значение;

      КонецЕсли;  

      Если ПустоеЗначение(ИмяМес)=0 Тогда

       Если ИмяМес="01" Тогда

        таб._01=СумМес;  

       ИначеЕсли ИмяМес="02" Тогда

        таб._02=СумМес;    

       ИначеЕсли ИмяМес="03" Тогда

        таб._03=СумМес;    

       ИначеЕсли ИмяМес="04" Тогда

        таб._04=СумМес;    

       ИначеЕсли ИмяМес="05" Тогда

        таб._05=СумМес;    

       ИначеЕсли ИмяМес="06" Тогда

        таб._06=СумМес;    

       ИначеЕсли ИмяМес="07" Тогда

        таб._07=СумМес;    

       ИначеЕсли ИмяМес="08" Тогда

        таб._08=СумМес;    

       ИначеЕсли ИмяМес="09" Тогда

        таб._09=СумМес;    

       ИначеЕсли ИмяМес="10" Тогда

        таб._10=СумМес;    

       ИначеЕсли ИмяМес="11" Тогда

        таб._11=СумМес;    

       ИначеЕсли ИмяМес="12" Тогда

        таб._12=СумМес;    

       КонецЕсли;

      КонецЕсли;

     КонецЦикла;   

     

УзелНалПер=УзелСвДохСтав.ПолучитьУзел(Сч3).ВыбратьУзлы("СГДНалПер");

НалПер=УзелНалПер.ПолучитьУзел(0);

Если НалПер.Наименование="СГДНалПер" Тогда

      таб.СумГод=НалПер.ПолучитьПодчиненныйПоНомеру(1).Значение;

      таб.ОблГод=НалПер.ПолучитьПодчиненныйПоНомеру(2).Значение;

      таб.УдерГод=НалПер.ПолучитьПодчиненныйПоНомеру(3).Значение;

 КонецЕсли;  

    //тут еще берем данные

 КонецЦикла;  

 Состояние(Сч);

КонецЦикла;          

   Т=СоздатьОбъект("Таблица");

   Т.ИсходнаяТаблица("Таблица");

   таб.выбратьСтроки();          

   Т.ВывестиСекцию("Шапка");    

   нпп=1;

   Пока таб.ПолучитьСтроку()=1 Цикл

    Т.ВывестиСекцию("Текст");    

    нпп=нпп+1;

   КонецЦикла;     

   Т.ТолькоПросмотр(1);

      Т.Опции(0, 0, 1, 0);

  // Т.ОбластьПечати(2);

   Т.ПараметрыСтраницы(2,,,5,5,5,5,,, 1);

   Т.Показать("Прочитали из XML");   

КонецПроцедуры



Процедура Выбрать()

 ФС.ВыбратьФайл(0,ИмяФайла,ИмяПути,"Выберите файл","xml файлы (*.xml) |*.xml|Все файлы (*.*) |*.*","xml", );

 Если ПустоеЗначение(ИмяФайла)=0 Тогда

   PathSbitn=ИмяПути+ИмяФайла;

 КонецЕсли;

КонецПроцедуры //Выбрать       



Процедура ПриОткрытии()

 ИмяФайла ="";

 ИмяПути = "P:";     

 res=УстановитьКомпоненту();  

// Сообщить(res);

КонецПроцедуры //ПриОткрытии

Пример файла XML :

Код

<?xml version="1.0" encoding="windows-1251"?>
<НДФЛ2 xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" ВерсФорм="4.00001" ВерсПрог="НП 10.31" ИдФайл="ДОХОД_2НДФЛ">
<Справка>
<ОбщСвИЧ>
<ГодДох>2006</ГодДох>
<НомСпр>1</НомСпр>
<ДатаСпр>26.03.2007</ДатаСпр>
<ИФНСНА>7777</ИФНСНА>
</ОбщСвИЧ>
<ИстДох>
<СвНАЮЛ>
<ИННЮЛ>1234567890</ИННЮЛ>
<КПП>12345678</КПП>
<НаимОрг>ООО Рога и Копыта</НаимОрг>
<ОКАТО>12345678901</ОКАТО>
</СвНАЮЛ>
</ИстДох>
<ПолучДох>
<ФИО>
<Фамилия>Иванов</Фамилия>
<Имя>Иван</Имя>
<Отчество>Иванович</Отчество>
</ФИО>
<Статус>1</Статус>
<ДатаРожд>24.01.1973</ДатаРожд>
<Гражданство>643</Гражданство>
<УдЛичн>
<КодУдЛичн>21</КодУдЛичн>
<СерНомДок>12 01 012345</СерНомДок>
</УдЛичн>
<АдрМЖРФ>
<Индекс>123456</Индекс>
<КодРегион>77</КодРегион>
<Город>Энн г</Город>
<Улица>Ленина ул</Улица>
<Дом>99</Дом>
<Корпус>5</Корпус>
<Кварт>12</Кварт>
</АдрМЖРФ>
</ПолучДох>
<СвДохСтав>
<Ставка>35</Ставка>
<ДохВыч>
<НомМес>02</НомМес>
<КодДоход>2610</КодДоход>
<СумДоход>252.15</СумДоход>
</ДохВыч>
<ДохВыч>
<НомМес>07</НомМес>
<КодДоход>2760</КодДоход>
<СумДоход>100.00</СумДоход>
<КодВычет>503</КодВычет>
<СумВычет>100.00</СумВычет>
</ДохВыч>
<ДохВыч>
<НомМес>10</НомМес>
<КодДоход>2760</КодДоход>
<СумДоход>100.00</СумДоход>
<КодВычет>503</КодВычет>
<СумВычет>100.00</СумВычет>
</ДохВыч>
<СГДНалПер>
<СГДСумм>252.15</СГДСумм>
<ОблСумм>252.15</ОблСумм>
<НИОблСумм>88</НИОблСумм>
<НУОблСумм>88</НУОблСумм>
<ВозврСуммПЛ>0</ВозврСуммПЛ>
<ЗачСуммПЛ>0</ЗачСуммПЛ>
<УдСуммПЛ>0</УдСуммПЛ>
<ДолгНП>0</ДолгНП>
<ДолгНА>0</ДолгНА>
<ВзыскИФНС>0</ВзыскИФНС>
</СГДНалПер>
</СвДохСтав>
</Справка>
</НДФЛ2>

Категория: XML, DBF, TXT, CSV

Как установить компоненту V7Plus.dll

Для корректной установки компоненты V7Plus необходимо переместить файлы
V7PLUS.ALS
V7PLUS.DLL

Файлы V7PLUS.DLL и V7PLUS.ALS вы можете скачать здесь!

в рабочую директорию 1с:
"C:\Program Files\1Cv77\BIN\"

и зарегистрировать компоненту командой
regsvr32 "C:\Program Files\1Cv77\BIN\V7PLUS.DLL"

или же воспользоваться файлом start.bat(так же прилагается к архиву)
который делает то же самое но автоматически, если 1с установлена в директорию по умолчанию на диск с:

листинг файла start.bat:

Код DOS Batch File

 copy V7PLUS.DLL "c:\Program Files\1Cv77\BIN\"

copy V7PLUS.ALS "c:\Program Files\1Cv77\BIN\"

copy 1CML32.DLL "c:\Program Files\1Cv77\BIN\"

copy UNIZIP32.DLL "c:\Program Files\1Cv77\BIN\"

cd "c:\Program Files\1Cv77\BIN\"

regsvr32 V7PLUS.DLL

Категория: Администрирование

Получения новостей с RSS-канала сайта buh.ru

Код для получения новостей с сайта buh.ru, используется RSS-канал http://www.buh.ru/rss/rss-2.0.jsp
Данный код для 7.7, при использовании в 8-ой версии нужно заменить СоздатьОбъект( на Новый COMОбъект(, остальное вроде так же.

Код 1C v 7.x

 

Функция ВытащитьДату(Стр)

	парсер=СоздатьОбъект("VBScript.RegExp");

	парсер.Global=-1;

	парсер.IgnoreCase =-1;  

	стрМес="Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec";

	парсер.Pattern="(\d\d)\s(("+стрМес+"))\s(\d{4})";

	рез = парсер.Execute(Стр);

	Если рез.Count>0 Тогда

		рез_ = рез.Item(0);

		чч=Число(рез_.Submatches(0));

		мст=рез_.Submatches(1);  

		где=Найти(стрМес,мст);

		мм=цел(где/4)+1;

		гг=Число(рез_.Submatches(3));  

		дат=Дата(гг,мм,чч);

	Иначе

		дат=0;

	КонецЕсли;

	Возврат дат;

КонецФункции



Процедура Сформировать()   

	ТЗ=СоздатьОбъект("ТаблицаЗначений");

	ТЗ.НоваяКолонка("ИД","Число");

	ТЗ.НоваяКолонка("Дата","Дата"); 

	ТЗ.НоваяКолонка("Заголовок","Строка");

	ТЗ.НоваяКолонка("Ссылка","Строка");

	ТЗ.НоваяКолонка("Текст","Строка"); 

	

	Состояние("Получение данных с сайта www.buh.ru");

	

	//ТаймАут поставьте в зависимости от качества подключения

	ТаймАут=100000;

	

	IE=СоздатьОбъект("InternetExplorer.Application");

	IE.navigate("http://www.buh.ru/rss/rss-2.0.jsp");

	Пока IE.readyState<4 Цикл

		ТаймАут=ТаймАут-1;

		Если ТаймАут=0 Тогда

			Предупреждение("Не удалось получить данные с сайта www.buh.ru",10);

			Возврат;

		КонецЕсли;

	КонецЦикла;        

	

	//версия 0.1 для v7plus.dll 

	//ХМЛ=СоздатьОбъект("AddIn.XMLParser");  

	//ХМЛДок=ХМЛ.СоздатьДокумент();

	//ХМЛДок.Загрузить(oIE.document.XMLDocument); 

	//Выборка=ХМЛДок.ВыбратьУзлы("//item");

	//Для ии=0 По Выборка.КоличествоУзлов()-1 Цикл 

	//	ЭлНовость=Выборка.ПолучитьУзел(ии);

	//	ТЗ.НоваяСтрока();

	//	ТЗ.Дата=ВытащитьДату(ЭлНовость.ВыбратьУзел("./pubDate").Текст);

	//	ТЗ.Заголовок=ЭлНовость.ВыбратьУзел("./title").Текст;

	//	ТЗ.Ссылка=ЭлНовость.ВыбратьУзел("./link").Текст;

	//	ТЗ.Текст=ЭлНовость.ВыбратьУзел("./description").Текст;

	//КонецЦикла; 

	

	//версия 0.2 для MSXML

	ХМЛДок=СоздатьОбъект("MSXML2.DOMDocument");;

	ХМЛДок.async=0;

	ХМЛДок.resolveExternals=0;

	ХМЛДок.load(IE.document.XMLDocument); 

	Выборка=ХМЛДок.selectNodes("//item");

	Для ии=0 По Выборка.length-1 Цикл 

		ЭлНовость=Выборка.item(ии);

		ТЗ.НоваяСтрока();

		ТЗ.Дата=ВытащитьДату(ЭлНовость.selectSingleNode("./pubDate").text);

		ТЗ.Заголовок=ЭлНовость.selectSingleNode("./title").text;

		ТЗ.Ссылка=ЭлНовость.selectSingleNode("./link").text;

		ТЗ.Текст=ЭлНовость.selectSingleNode("./description").text;

	КонецЦикла; 

    //Все. Мы получили ТЗ с последними новостями

КонецПроцедуры

К сожалению, автор не известен.

Категория: COM-объекты, WMI, WSH

Обновление базы (конфигурации) 1С 7.7

Для обновления релиза конфигурации следует использовать режим "Объединение конфигураций". Вам потребуется файл метаданных (файл 1Cv7.MD) нового релиза конфигурации.

1. Запустите систему 1С:Предприятие в режиме "Конфигуратор".
title

2. Сделайте архивную копию вашей информационной базы.
"Администрирование – Сохранить данные"
title

Укажите "Сохранить в" и нажмите "Сохранить"
title

3. Вызовите режим "Объединение конфигураций", для этого в меню "Конфигурация" выберите пункт "Объединение конфигураций".
Если "Объединение конфигураций" недоступно - используйте Загрузить измененную конфигурацию и перейдите по инструкции к шагу 7!
title

4. В запросе "Открыть файл конфигурации" выберите файл метаданных 1Cv7.MD нового релиза конфигурации.
title

5. В окне режима "Объединение конфигураций" проверьте:

- в группе "Приоритет конфигурации" был установлен

переключатель "Загружаемая конфигурация";

- в группе "Метод объединения" установлен

переключатель "Замещать объекты".
title

6. Нажмите кнопку "OK" для объединения конфигураций.

7. После завершения будет открыто окно "Конфигурация", содержащее конфигурацию с внесенными изменениями.

8. Выполните сохранение конфигурации. нажав на значок сохранить или Файл - Сохранить
title

Подтвердите сохранение метаданных, нажав Да.
Далее нажмите Принять, и ОК.

9. По окончании установки обновления новые или измененные внешние отчеты, внешние печатные формы и формы календаря бухгалтера располагаются в каталоге ExtForms обновления. Данные отчеты и формы не входят в конфигурацию, поэтому для того, чтобы их обновить, все содержимое данного каталога следует перенести в каталог ExtForms вашей информационной базы.

Узнать Каталог вашей информационной базы, можно нажав на желтый знак вопроса:
title

Каталог Информационной базы = Информационная база: (на картинке это K:\teme\Buh45\)

10. Для обновления компоненты V7Plus файлы UPDATE\SSTDB\V7Plus.dll и UPDATE\SSTDB\V7Plus.als скопируйте в каталог вашей информационной базы.

Автор: Мигачев Евгений

Категория: 1С Общие вопросы - Обычные формы

Неудачная попытка создания объекта (AddIn.XMLParser)?

В чем дело, программа пишет "Неудачная попытка создания объекта (AddIn.XMLParser)"?

Очевидно, что Вы запускаете обработку, которая использует внешнюю библиотеку v7plus.dll. В данном случае для работы с файлами формата XML. Но файл (библиотеку) v7plus.dll, обеспечивающий создание этого объекта (AddIn.XMLParser) программа не нашла...

Для нормальной работы этой библиотеки надо найти файл v7plus.dll (как правило находится в базе данных типовых после инсталяции) и скопировать его в Каталог Вашей информационной базы. А можно в каталог с исполняемыми файлами программы (C:\Program Files\1c77\bin\).
Первый вариант лучше для сетевой установки (не понадобится копировать эту библиотеку на каждый компьютер сети), второй для локальной, особенно, если у Вас установлено несколько баз (не понадобится копировать файл библиотеки во все базы).

Категория: Администрирование

Устранение ошибки при создании объекта из компоненты v7plus.dll (отсутствует CLSID)

В XP или 2000 надо положить v7plus.dll в каталог, где установлена сама 1С (по умолчанию C:\Program Files\1cv77\BIN), удалить dll из каталогов баз и один раз запустить любую из баз под пользователем с правами администратора компьютера.
Все эти действия нужны, чтобы 1С зарегистрировала компоненту в реестре и для всех баз путь к компоненте был одинаковым и не требовалась перерегистрация компоненты для каждой базы при каждом запуске.

Регистрация вручную:
Пуск - Выполнить или в командной строке введите: regsvr32 C:\Program Files\1cv77\BIN\v7plus.dll

При работе в 1C:Предприятие 7.7 под операционнй системой Windows Vista при использованиии компоненты v7plus.dll (например, при выгрузке данных в формате XML) происходит ошибка: "Ошибка при создании объекта из компоненты v7plus.dll (отсутствует CLSID)"

Решение данной проблемы в Vista и 7:
Отключить UAC (Панель управления/Учетные записи пользователей/Включение или отключение контроля учетных записей (UAC).
Перезагрузить компьютер.
Запустить 1С.
Закрыть 1С.
Включить UAC.
Перезагрузить компьютер.
Больше при открытии ошибки не будет.
Данный метод позволяет решить проблему без нарушения безопасности.

СКАЧАТЬ ФАЙЛ V7PLUS.DLL ВЫ МОЖЕТЕ ЗДЕСЬ!

Категория: Администрирование

Как загрузить внешнюю компоненту?

Код 1C v 8.х

 Попытка 

	ЗагрузитьВнешнююКомпоненту("scanopos.dll") 

Исключение 

	Сообщить("Ошибка загрузки внешней компоненты!"); 

КонецПопытки; 



Попытка 

	// Получить объект компоненты. 

	Объект = Новый("AddIn.Scanner"); 



Исключение 

	Сообщить("Не удалось создать объект внешней компоненты"); 

КонецПопытки;

Код 1C v 7.x

 //в качестве аргумента "Значение" в функцию передаётся имя файла внешней компоненты

//функция возвращает "1", если загрузка выполнена успешно, или "0", если внешнюю компоненту загрузить не получилось

Функция гВнешняяКомпонента_Загрузить(Значение) Экспорт

     Состояние("Загрузка компоненты: "+Значение);

     Если ЗагрузитьВнешнююКомпоненту(Значение)=1 Тогда

          Возврат(1);

     Иначе

          Сообщить("Ошибка при загрузке компоненты: "+Значение,"!");

          Возврат(0);

     КонецЕсли;

КонецФункции



//этот код можно разместить в локальном модуле, в котором требуется использовать внешнюю компоненту

Если гВнешняяКомпонента_Загрузить("v7plus.dll")=0 Тогда

     Возврат;

КонецЕсли;

При загрузке полезно проверять, а есть ли в наличии указанный файл DLL (к сожалению, этого не делает сам движок 1С:Предприятие 7.7).

Код 1C v 7.x

 имяф="e:\Events\Events.dll";

    Если фс.СуществуетФайл(имяф)=0 Тогда

        Сообщить("Файл не найден: "+имяф,"!"); 

    КонецЕсли;    

    Если ЗагрузитьВнешнююКомпоненту(имяф)=0 Тогда

        Сообщить("Ошибка загрузки внешней компоненты: "+имяф);

    КонецЕсли;    

    vk=СоздатьОбъект("Addin.Events");

Категория: Внешние компоненты